git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Data::Dumper;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49
  50   Composing:
  51     --from                  <str>  * Email From:
  52     --[no-]to               <str>  * Email To:
  53     --[no-]cc               <str>  * Email Cc:
  54     --[no-]bcc              <str>  * Email Bcc:
  55     --subject               <str>  * Email "Subject:"
  56     --in-reply-to           <str>  * Email "In-Reply-To:"
  57     --annotate                     * Review each patch that will be sent in an editor.
  58     --compose                      * Open an editor for introduction.
  59     --compose-encoding      <str>  * Encoding to assume for introduction.
  60     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  61
  62   Sending:
  63     --envelope-sender       <str>  * Email envelope sender.
  64     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  65                                      is optional. Default 'localhost'.
  66     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  67     --smtp-server-port      <int>  * Outgoing SMTP server port.
  68     --smtp-user             <str>  * Username for SMTP-AUTH.
  69     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  70     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  71     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  72     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  73     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  74
  75   Automating:
  76     --identity              <str>  * Use the sendemail.<id> options.
  77     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  78     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  79     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  80     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  81     --[no-]suppress-from           * Send to self. Default off.
  82     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  83     --[no-]thread                  * Use In-Reply-To: field. Default on.
  84
  85   Administering:
  86     --confirm               <str>  * Confirm recipients before sending;
  87                                      auto, cc, compose, always, or never.
  88     --quiet                        * Output one line of info per email.
  89     --dry-run                      * Don't actually send the emails.
  90     --[no-]validate                * Perform patch sanity checks. Default on.
  91     --[no-]format-patch            * understand any non optional arguments as
  92                                      `git format-patch` ones.
  93     --force                        * Send even if safety checks would prevent it.
  94
  95 EOT
  96         exit(1);
  97 }
  98
  99 # most mail servers generate the Date: header, but not all...
 100 sub format_2822_time {
 101         my ($time) = @_;
 102         my @localtm = localtime($time);
 103         my @gmttm = gmtime($time);
 104         my $localmin = $localtm[1] + $localtm[2] * 60;
 105         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 106         if ($localtm[0] != $gmttm[0]) {
 107                 die "local zone differs from GMT by a non-minute interval\n";
 108         }
 109         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 110                 $localmin += 1440;
 111         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 112                 $localmin -= 1440;
 113         } elsif ($gmttm[6] != $localtm[6]) {
 114                 die "local time offset greater than or equal to 24 hours\n";
 115         }
 116         my $offset = $localmin - $gmtmin;
 117         my $offhour = $offset / 60;
 118         my $offmin = abs($offset % 60);
 119         if (abs($offhour) >= 24) {
 120                 die ("local time offset greater than or equal to 24 hours\n");
 121         }
 122
 123         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 124                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 125                        $localtm[3],
 126                        qw(Jan Feb Mar Apr May Jun
 127                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 128                        $localtm[5]+1900,
 129                        $localtm[2],
 130                        $localtm[1],
 131                        $localtm[0],
 132                        ($offset >= 0) ? '+' : '-',
 133                        abs($offhour),
 134                        $offmin,
 135                        );
 136 }
 137
 138 my $have_email_valid = eval { require Email::Valid; 1 };
 139 my $have_mail_address = eval { require Mail::Address; 1 };
 140 my $smtp;
 141 my $auth;
 142
 143 # Variables we fill in automatically, or via prompting:
 144 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 145         $initial_reply_to,$initial_subject,@files,
 146         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 147
 148 my $envelope_sender;
 149
 150 # Example reply to:
 151 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 152
 153 my $repo = eval { Git->repository() };
 154 my @repo = $repo ? ($repo) : ();
 155 my $term = eval {
 156         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 157                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 158                 : new Term::ReadLine 'git-send-email';
 159 };
 160 if ($@) {
 161         $term = new FakeTerm "$@: going non-interactive";
 162 }
 163
 164 # Behavior modification variables
 165 my ($quiet, $dry_run) = (0, 0);
 166 my $format_patch;
 167 my $compose_filename;
 168 my $force = 0;
 169
 170 # Handle interactive edition of files.
 171 my $multiedit;
 172 my $editor;
 173
 174 sub do_edit {
 175         if (!defined($editor)) {
 176                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 177         }
 178         if (defined($multiedit) && !$multiedit) {
 179                 map {
 180                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 181                         if (($? & 127) || ($? >> 8)) {
 182                                 die("the editor exited uncleanly, aborting everything");
 183                         }
 184                 } @_;
 185         } else {
 186                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 187                 if (($? & 127) || ($? >> 8)) {
 188                         die("the editor exited uncleanly, aborting everything");
 189                 }
 190         }
 191 }
 192
 193 # Variables with corresponding config settings
 194 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 195 my ($to_cmd, $cc_cmd);
 196 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 197 my ($smtp_authuser, $smtp_encryption);
 198 my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
 199 my ($validate, $confirm);
 200 my (@suppress_cc);
 201 my ($auto_8bit_encoding);
 202 my ($compose_encoding);
 203
 204 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 205
 206 my $not_set_by_user = "true but not set by the user";
 207
 208 my %config_bool_settings = (
 209     "thread" => [\$thread, 1],
 210     "chainreplyto" => [\$chain_reply_to, $not_set_by_user],
 211     "suppressfrom" => [\$suppress_from, undef],
 212     "signedoffbycc" => [\$signed_off_by_cc, undef],
 213     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 214     "validate" => [\$validate, 1],
 215     "multiedit" => [\$multiedit, undef]
 216 );
 217
 218 my %config_settings = (
 219     "smtpserver" => \$smtp_server,
 220     "smtpserverport" => \$smtp_server_port,
 221     "smtpserveroption" => \@smtp_server_options,
 222     "smtpuser" => \$smtp_authuser,
 223     "smtppass" => \$smtp_authpass,
 224     "smtpdomain" => \$smtp_domain,
 225     "to" => \@initial_to,
 226     "tocmd" => \$to_cmd,
 227     "cc" => \@initial_cc,
 228     "cccmd" => \$cc_cmd,
 229     "aliasfiletype" => \$aliasfiletype,
 230     "bcc" => \@bcclist,
 231     "suppresscc" => \@suppress_cc,
 232     "envelopesender" => \$envelope_sender,
 233     "confirm"   => \$confirm,
 234     "from" => \$sender,
 235     "assume8bitencoding" => \$auto_8bit_encoding,
 236     "composeencoding" => \$compose_encoding,
 237 );
 238
 239 my %config_path_settings = (
 240     "aliasesfile" => \@alias_files,
 241 );
 242
 243 # Help users prepare for 1.7.0
 244 sub chain_reply_to {
 245         if (defined $chain_reply_to &&
 246             $chain_reply_to eq $not_set_by_user) {
 247                 print STDERR
 248                     "In git 1.7.0, the default has changed to --no-chain-reply-to\n" .
 249                     "Set sendemail.chainreplyto configuration variable to true if\n" .
 250                     "you want to keep --chain-reply-to as your default.\n";
 251                 $chain_reply_to = 0;
 252         }
 253         return $chain_reply_to;
 254 }
 255
 256 # Handle Uncouth Termination
 257 sub signal_handler {
 258
 259         # Make text normal
 260         print color("reset"), "\n";
 261
 262         # SMTP password masked
 263         system "stty echo";
 264
 265         # tmp files from --compose
 266         if (defined $compose_filename) {
 267                 if (-e $compose_filename) {
 268                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 269                 }
 270                 if (-e ($compose_filename . ".final")) {
 271                         print "'$compose_filename.final' contains the composed email.\n"
 272                 }
 273         }
 274
 275         exit;
 276 };
 277
 278 $SIG{TERM} = \&signal_handler;
 279 $SIG{INT}  = \&signal_handler;
 280
 281 # Begin by accumulating all the variables (defined above), that we will end up
 282 # needing, first, from the command line:
 283
 284 my $help;
 285 my $rc = GetOptions("h" => \$help,
 286                     "sender|from=s" => \$sender,
 287                     "in-reply-to=s" => \$initial_reply_to,
 288                     "subject=s" => \$initial_subject,
 289                     "to=s" => \@initial_to,
 290                     "to-cmd=s" => \$to_cmd,
 291                     "no-to" => \$no_to,
 292                     "cc=s" => \@initial_cc,
 293                     "no-cc" => \$no_cc,
 294                     "bcc=s" => \@bcclist,
 295                     "no-bcc" => \$no_bcc,
 296                     "chain-reply-to!" => \$chain_reply_to,
 297                     "smtp-server=s" => \$smtp_server,
 298                     "smtp-server-option=s" => \@smtp_server_options,
 299                     "smtp-server-port=s" => \$smtp_server_port,
 300                     "smtp-user=s" => \$smtp_authuser,
 301                     "smtp-pass:s" => \$smtp_authpass,
 302                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 303                     "smtp-encryption=s" => \$smtp_encryption,
 304                     "smtp-debug:i" => \$debug_net_smtp,
 305                     "smtp-domain:s" => \$smtp_domain,
 306                     "identity=s" => \$identity,
 307                     "annotate" => \$annotate,
 308                     "compose" => \$compose,
 309                     "quiet" => \$quiet,
 310                     "cc-cmd=s" => \$cc_cmd,
 311                     "suppress-from!" => \$suppress_from,
 312                     "suppress-cc=s" => \@suppress_cc,
 313                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 314                     "confirm=s" => \$confirm,
 315                     "dry-run" => \$dry_run,
 316                     "envelope-sender=s" => \$envelope_sender,
 317                     "thread!" => \$thread,
 318                     "validate!" => \$validate,
 319                     "format-patch!" => \$format_patch,
 320                     "8bit-encoding=s" => \$auto_8bit_encoding,
 321                     "compose-encoding=s" => \$compose_encoding,
 322                     "force" => \$force,
 323          );
 324
 325 usage() if $help;
 326 unless ($rc) {
 327     usage();
 328 }
 329
 330 die "Cannot run git format-patch from outside a repository\n"
 331         if $format_patch and not $repo;
 332
 333 # Now, let's fill any that aren't set in with defaults:
 334
 335 sub read_config {
 336         my ($prefix) = @_;
 337
 338         foreach my $setting (keys %config_bool_settings) {
 339                 my $target = $config_bool_settings{$setting}->[0];
 340                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 341         }
 342
 343         foreach my $setting (keys %config_path_settings) {
 344                 my $target = $config_path_settings{$setting};
 345                 if (ref($target) eq "ARRAY") {
 346                         unless (@$target) {
 347                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 348                                 @$target = @values if (@values && defined $values[0]);
 349                         }
 350                 }
 351                 else {
 352                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 353                 }
 354         }
 355
 356         foreach my $setting (keys %config_settings) {
 357                 my $target = $config_settings{$setting};
 358                 next if $setting eq "to" and defined $no_to;
 359                 next if $setting eq "cc" and defined $no_cc;
 360                 next if $setting eq "bcc" and defined $no_bcc;
 361                 if (ref($target) eq "ARRAY") {
 362                         unless (@$target) {
 363                                 my @values = Git::config(@repo, "$prefix.$setting");
 364                                 @$target = @values if (@values && defined $values[0]);
 365                         }
 366                 }
 367                 else {
 368                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 369                 }
 370         }
 371
 372         if (!defined $smtp_encryption) {
 373                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 374                 if (defined $enc) {
 375                         $smtp_encryption = $enc;
 376                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 377                         $smtp_encryption = 'ssl';
 378                 }
 379         }
 380 }
 381
 382 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 383 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 384 read_config("sendemail.$identity") if (defined $identity);
 385 read_config("sendemail");
 386
 387 # fall back on builtin bool defaults
 388 foreach my $setting (values %config_bool_settings) {
 389         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 390 }
 391
 392 # 'default' encryption is none -- this only prevents a warning
 393 $smtp_encryption = '' unless (defined $smtp_encryption);
 394
 395 # Set CC suppressions
 396 my(%suppress_cc);
 397 if (@suppress_cc) {
 398         foreach my $entry (@suppress_cc) {
 399                 die "Unknown --suppress-cc field: '$entry'\n"
 400                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 401                 $suppress_cc{$entry} = 1;
 402         }
 403 }
 404
 405 if ($suppress_cc{'all'}) {
 406         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 407                 $suppress_cc{$entry} = 1;
 408         }
 409         delete $suppress_cc{'all'};
 410 }
 411
 412 # If explicit old-style ones are specified, they trump --suppress-cc.
 413 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 414 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 415
 416 if ($suppress_cc{'body'}) {
 417         foreach my $entry (qw (sob bodycc)) {
 418                 $suppress_cc{$entry} = 1;
 419         }
 420         delete $suppress_cc{'body'};
 421 }
 422
 423 # Set confirm's default value
 424 my $confirm_unconfigured = !defined $confirm;
 425 if ($confirm_unconfigured) {
 426         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 427 };
 428 die "Unknown --confirm setting: '$confirm'\n"
 429         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 430
 431 # Debugging, print out the suppressions.
 432 if (0) {
 433         print "suppressions:\n";
 434         foreach my $entry (keys %suppress_cc) {
 435                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 436         }
 437 }
 438
 439 my ($repoauthor, $repocommitter);
 440 ($repoauthor) = Git::ident_person(@repo, 'author');
 441 ($repocommitter) = Git::ident_person(@repo, 'committer');
 442
 443 # Verify the user input
 444
 445 foreach my $entry (@initial_to) {
 446         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 447 }
 448
 449 foreach my $entry (@initial_cc) {
 450         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 451 }
 452
 453 foreach my $entry (@bcclist) {
 454         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 455 }
 456
 457 sub parse_address_line {
 458         if ($have_mail_address) {
 459                 return map { $_->format } Mail::Address->parse($_[0]);
 460         } else {
 461                 return split_addrs($_[0]);
 462         }
 463 }
 464
 465 sub split_addrs {
 466         return quotewords('\s*,\s*', 1, @_);
 467 }
 468
 469 my %aliases;
 470 my %parse_alias = (
 471         # multiline formats can be supported in the future
 472         mutt => sub { my $fh = shift; while (<$fh>) {
 473                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 474                         my ($alias, $addr) = ($1, $2);
 475                         $addr =~ s/#.*$//; # mutt allows # comments
 476                          # commas delimit multiple addresses
 477                         $aliases{$alias} = [ split_addrs($addr) ];
 478                 }}},
 479         mailrc => sub { my $fh = shift; while (<$fh>) {
 480                 if (/^alias\s+(\S+)\s+(.*)$/) {
 481                         # spaces delimit multiple addresses
 482                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 483                 }}},
 484         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 485                 for (my $x = ''; defined($x); $x = $_) {
 486                         chomp $x;
 487                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 488                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 489                         $aliases{$1} = [ split_addrs($2) ];
 490                 }},
 491         elm => sub  { my $fh = shift;
 492                       while (<$fh>) {
 493                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 494                               my ($alias, $addr) = ($1, $2);
 495                                $aliases{$alias} = [ split_addrs($addr) ];
 496                           }
 497                       } },
 498
 499         gnus => sub { my $fh = shift; while (<$fh>) {
 500                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 501                         $aliases{$1} = [ $2 ];
 502                 }}}
 503 );
 504
 505 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 506         foreach my $file (@alias_files) {
 507                 open my $fh, '<', $file or die "opening $file: $!\n";
 508                 $parse_alias{$aliasfiletype}->($fh);
 509                 close $fh;
 510         }
 511 }
 512
 513 ($sender) = expand_aliases($sender) if defined $sender;
 514
 515 # is_format_patch_arg($f) returns 0 if $f names a patch, or 1 if
 516 # $f is a revision list specification to be passed to format-patch.
 517 sub is_format_patch_arg {
 518         return unless $repo;
 519         my $f = shift;
 520         try {
 521                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 522                 if (defined($format_patch)) {
 523                         return $format_patch;
 524                 }
 525                 die(<<EOF);
 526 File '$f' exists but it could also be the range of commits
 527 to produce patches for.  Please disambiguate by...
 528
 529     * Saying "./$f" if you mean a file; or
 530     * Giving --format-patch option if you mean a range.
 531 EOF
 532         } catch Git::Error::Command with {
 533                 # Not a valid revision.  Treat it as a filename.
 534                 return 0;
 535         }
 536 }
 537
 538 # Now that all the defaults are set, process the rest of the command line
 539 # arguments and collect up the files that need to be processed.
 540 my @rev_list_opts;
 541 while (defined(my $f = shift @ARGV)) {
 542         if ($f eq "--") {
 543                 push @rev_list_opts, "--", @ARGV;
 544                 @ARGV = ();
 545         } elsif (-d $f and !is_format_patch_arg($f)) {
 546                 opendir my $dh, $f
 547                         or die "Failed to opendir $f: $!";
 548
 549                 push @files, grep { -f $_ } map { catfile($f, $_) }
 550                                 sort readdir $dh;
 551                 closedir $dh;
 552         } elsif ((-f $f or -p $f) and !is_format_patch_arg($f)) {
 553                 push @files, $f;
 554         } else {
 555                 push @rev_list_opts, $f;
 556         }
 557 }
 558
 559 if (@rev_list_opts) {
 560         die "Cannot run git format-patch from outside a repository\n"
 561                 unless $repo;
 562         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 563 }
 564
 565 if ($validate) {
 566         foreach my $f (@files) {
 567                 unless (-p $f) {
 568                         my $error = validate_patch($f);
 569                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 570                 }
 571         }
 572 }
 573
 574 if (@files) {
 575         unless ($quiet) {
 576                 print $_,"\n" for (@files);
 577         }
 578 } else {
 579         print STDERR "\nNo patch files specified!\n\n";
 580         usage();
 581 }
 582
 583 sub get_patch_subject {
 584         my $fn = shift;
 585         open (my $fh, '<', $fn);
 586         while (my $line = <$fh>) {
 587                 next unless ($line =~ /^Subject: (.*)$/);
 588                 close $fh;
 589                 return "GIT: $1\n";
 590         }
 591         close $fh;
 592         die "No subject line in $fn ?";
 593 }
 594
 595 if ($compose) {
 596         # Note that this does not need to be secure, but we will make a small
 597         # effort to have it be unique
 598         $compose_filename = ($repo ?
 599                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 600                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 601         open my $c, ">", $compose_filename
 602                 or die "Failed to open for writing $compose_filename: $!";
 603
 604
 605         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 606         my $tpl_subject = $initial_subject || '';
 607         my $tpl_reply_to = $initial_reply_to || '';
 608
 609         print $c <<EOT;
 610 From $tpl_sender # This line is ignored.
 611 GIT: Lines beginning in "GIT:" will be removed.
 612 GIT: Consider including an overall diffstat or table of contents
 613 GIT: for the patch you are writing.
 614 GIT:
 615 GIT: Clear the body content if you don't wish to send a summary.
 616 From: $tpl_sender
 617 Subject: $tpl_subject
 618 In-Reply-To: $tpl_reply_to
 619
 620 EOT
 621         for my $f (@files) {
 622                 print $c get_patch_subject($f);
 623         }
 624         close $c;
 625
 626         if ($annotate) {
 627                 do_edit($compose_filename, @files);
 628         } else {
 629                 do_edit($compose_filename);
 630         }
 631
 632         open my $c2, ">", $compose_filename . ".final"
 633                 or die "Failed to open $compose_filename.final : " . $!;
 634
 635         open $c, "<", $compose_filename
 636                 or die "Failed to open $compose_filename : " . $!;
 637
 638         my $need_8bit_cte = file_has_nonascii($compose_filename);
 639         my $in_body = 0;
 640         my $summary_empty = 1;
 641         if (!defined $compose_encoding) {
 642                 $compose_encoding = "UTF-8";
 643         }
 644         while(<$c>) {
 645                 next if m/^GIT:/;
 646                 if ($in_body) {
 647                         $summary_empty = 0 unless (/^\n$/);
 648                 } elsif (/^\n$/) {
 649                         $in_body = 1;
 650                         if ($need_8bit_cte) {
 651                                 print $c2 "MIME-Version: 1.0\n",
 652                                          "Content-Type: text/plain; ",
 653                                            "charset=$compose_encoding\n",
 654                                          "Content-Transfer-Encoding: 8bit\n";
 655                         }
 656                 } elsif (/^MIME-Version:/i) {
 657                         $need_8bit_cte = 0;
 658                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 659                         $initial_subject = $1;
 660                         my $subject = $initial_subject;
 661                         $_ = "Subject: " .
 662                                 quote_subject($subject, $compose_encoding) .
 663                                 "\n";
 664                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 665                         $initial_reply_to = $1;
 666                         next;
 667                 } elsif (/^From:\s*(.+)\s*$/i) {
 668                         $sender = $1;
 669                         next;
 670                 } elsif (/^(?:To|Cc|Bcc):/i) {
 671                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 672                         next;
 673                 }
 674                 print $c2 $_;
 675         }
 676         close $c;
 677         close $c2;
 678
 679         if ($summary_empty) {
 680                 print "Summary email is empty, skipping it\n";
 681                 $compose = -1;
 682         }
 683 } elsif ($annotate) {
 684         do_edit(@files);
 685 }
 686
 687 sub ask {
 688         my ($prompt, %arg) = @_;
 689         my $valid_re = $arg{valid_re};
 690         my $default = $arg{default};
 691         my $confirm_only = $arg{confirm_only};
 692         my $resp;
 693         my $i = 0;
 694         return defined $default ? $default : undef
 695                 unless defined $term->IN and defined fileno($term->IN) and
 696                        defined $term->OUT and defined fileno($term->OUT);
 697         while ($i++ < 10) {
 698                 $resp = $term->readline($prompt);
 699                 if (!defined $resp) { # EOF
 700                         print "\n";
 701                         return defined $default ? $default : undef;
 702                 }
 703                 if ($resp eq '' and defined $default) {
 704                         return $default;
 705                 }
 706                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 707                         return $resp;
 708                 }
 709                 if ($confirm_only) {
 710                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 711                         if (defined $yesno && $yesno =~ /y/i) {
 712                                 return $resp;
 713                         }
 714                 }
 715         }
 716         return;
 717 }
 718
 719 my %broken_encoding;
 720
 721 sub file_declares_8bit_cte {
 722         my $fn = shift;
 723         open (my $fh, '<', $fn);
 724         while (my $line = <$fh>) {
 725                 last if ($line =~ /^$/);
 726                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 727         }
 728         close $fh;
 729         return 0;
 730 }
 731
 732 foreach my $f (@files) {
 733         next unless (body_or_subject_has_nonascii($f)
 734                      && !file_declares_8bit_cte($f));
 735         $broken_encoding{$f} = 1;
 736 }
 737
 738 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 739         print "The following files are 8bit, but do not declare " .
 740                 "a Content-Transfer-Encoding.\n";
 741         foreach my $f (sort keys %broken_encoding) {
 742                 print "    $f\n";
 743         }
 744         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 745                                   default => "UTF-8");
 746 }
 747
 748 if (!$force) {
 749         for my $f (@files) {
 750                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 751                         die "Refusing to send because the patch\n\t$f\n"
 752                                 . "has the template subject '*** SUBJECT HERE ***'. "
 753                                 . "Pass --force if you really want to send.\n";
 754                 }
 755         }
 756 }
 757
 758 if (!defined $sender) {
 759         $sender = $repoauthor || $repocommitter || '';
 760 }
 761
 762 my $prompting = 0;
 763 if (!@initial_to && !defined $to_cmd) {
 764         my $to = ask("Who should the emails be sent to (if any)? ",
 765                      default => "",
 766                      valid_re => qr/\@.*\./, confirm_only => 1);
 767         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 768         $prompting++;
 769 }
 770
 771 sub expand_aliases {
 772         return map { expand_one_alias($_) } @_;
 773 }
 774
 775 my %EXPANDED_ALIASES;
 776 sub expand_one_alias {
 777         my $alias = shift;
 778         if ($EXPANDED_ALIASES{$alias}) {
 779                 die "fatal: alias '$alias' expands to itself\n";
 780         }
 781         local $EXPANDED_ALIASES{$alias} = 1;
 782         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 783 }
 784
 785 @initial_to = expand_aliases(@initial_to);
 786 @initial_to = validate_address_list(sanitize_address_list(@initial_to));
 787 @initial_cc = expand_aliases(@initial_cc);
 788 @initial_cc = validate_address_list(sanitize_address_list(@initial_cc));
 789 @bcclist = expand_aliases(@bcclist);
 790 @bcclist = validate_address_list(sanitize_address_list(@bcclist));
 791
 792 if ($thread && !defined $initial_reply_to && $prompting) {
 793         $initial_reply_to = ask(
 794                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 795                 default => "",
 796                 valid_re => qr/\@.*\./, confirm_only => 1);
 797 }
 798 if (defined $initial_reply_to) {
 799         $initial_reply_to =~ s/^\s*<?//;
 800         $initial_reply_to =~ s/>?\s*$//;
 801         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 802 }
 803
 804 if (!defined $smtp_server) {
 805         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 806                 if (-x $_) {
 807                         $smtp_server = $_;
 808                         last;
 809                 }
 810         }
 811         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 812 }
 813
 814 if ($compose && $compose > 0) {
 815         @files = ($compose_filename . ".final", @files);
 816 }
 817
 818 # Variables we set as part of the loop over files
 819 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 820         $needs_confirm, $message_num, $ask_default);
 821
 822 sub extract_valid_address {
 823         my $address = shift;
 824         my $local_part_regexp = qr/[^<>"\s@]+/;
 825         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 826
 827         # check for a local address:
 828         return $address if ($address =~ /^($local_part_regexp)$/);
 829
 830         $address =~ s/^\s*<(.*)>\s*$/$1/;
 831         if ($have_email_valid) {
 832                 return scalar Email::Valid->address($address);
 833         }
 834
 835         # less robust/correct than the monster regexp in Email::Valid,
 836         # but still does a 99% job, and one less dependency
 837         return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
 838         return;
 839 }
 840
 841 sub extract_valid_address_or_die {
 842         my $address = shift;
 843         $address = extract_valid_address($address);
 844         die "error: unable to extract a valid address from: $address\n"
 845                 if !$address;
 846         return $address;
 847 }
 848
 849 sub validate_address {
 850         my $address = shift;
 851         while (!extract_valid_address($address)) {
 852                 print STDERR "error: unable to extract a valid address from: $address\n";
 853                 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
 854                         valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
 855                         default => 'q');
 856                 if (/^d/i) {
 857                         return undef;
 858                 } elsif (/^q/i) {
 859                         cleanup_compose_files();
 860                         exit(0);
 861                 }
 862                 $address = ask("Who should the email be sent to (if any)? ",
 863                         default => "",
 864                         valid_re => qr/\@.*\./, confirm_only => 1);
 865         }
 866         return $address;
 867 }
 868
 869 sub validate_address_list {
 870         return (grep { defined $_ }
 871                 map { validate_address($_) } @_);
 872 }
 873
 874 # Usually don't need to change anything below here.
 875
 876 # we make a "fake" message id by taking the current number
 877 # of seconds since the beginning of Unix time and tacking on
 878 # a random number to the end, in case we are called quicker than
 879 # 1 second since the last time we were called.
 880
 881 # We'll setup a template for the message id, using the "from" address:
 882
 883 my ($message_id_stamp, $message_id_serial);
 884 sub make_message_id {
 885         my $uniq;
 886         if (!defined $message_id_stamp) {
 887                 $message_id_stamp = sprintf("%s-%s", time, $$);
 888                 $message_id_serial = 0;
 889         }
 890         $message_id_serial++;
 891         $uniq = "$message_id_stamp-$message_id_serial";
 892
 893         my $du_part;
 894         for ($sender, $repocommitter, $repoauthor) {
 895                 $du_part = extract_valid_address(sanitize_address($_));
 896                 last if (defined $du_part and $du_part ne '');
 897         }
 898         if (not defined $du_part or $du_part eq '') {
 899                 require Sys::Hostname;
 900                 $du_part = 'user@' . Sys::Hostname::hostname();
 901         }
 902         my $message_id_template = "<%s-git-send-email-%s>";
 903         $message_id = sprintf($message_id_template, $uniq, $du_part);
 904         #print "new message id = $message_id\n"; # Was useful for debugging
 905 }
 906
 907
 908
 909 $time = time - scalar $#files;
 910
 911 sub unquote_rfc2047 {
 912         local ($_) = @_;
 913         my $encoding;
 914         s{=\?([^?]+)\?q\?(.*?)\?=}{
 915                 $encoding = $1;
 916                 my $e = $2;
 917                 $e =~ s/_/ /g;
 918                 $e =~ s/=([0-9A-F]{2})/chr(hex($1))/eg;
 919                 $e;
 920         }eg;
 921         return wantarray ? ($_, $encoding) : $_;
 922 }
 923
 924 sub quote_rfc2047 {
 925         local $_ = shift;
 926         my $encoding = shift || 'UTF-8';
 927         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 928         s/(.*)/=\?$encoding\?q\?$1\?=/;
 929         return $_;
 930 }
 931
 932 sub is_rfc2047_quoted {
 933         my $s = shift;
 934         my $token = qr/[^][()<>@,;:"\/?.= \000-\037\177-\377]+/;
 935         my $encoded_text = qr/[!->@-~]+/;
 936         length($s) <= 75 &&
 937         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 938 }
 939
 940 sub subject_needs_rfc2047_quoting {
 941         my $s = shift;
 942
 943         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
 944 }
 945
 946 sub quote_subject {
 947         local $subject = shift;
 948         my $encoding = shift || 'UTF-8';
 949
 950         if (subject_needs_rfc2047_quoting($subject)) {
 951                 return quote_rfc2047($subject, $encoding);
 952         }
 953         return $subject;
 954 }
 955
 956 # use the simplest quoting being able to handle the recipient
 957 sub sanitize_address {
 958         my ($recipient) = @_;
 959
 960         # remove garbage after email address
 961         $recipient =~ s/(.*>).*$/$1/;
 962
 963         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 964
 965         if (not $recipient_name) {
 966                 return $recipient;
 967         }
 968
 969         # if recipient_name is already quoted, do nothing
 970         if (is_rfc2047_quoted($recipient_name)) {
 971                 return $recipient;
 972         }
 973
 974         # rfc2047 is needed if a non-ascii char is included
 975         if ($recipient_name =~ /[^[:ascii:]]/) {
 976                 $recipient_name =~ s/^"(.*)"$/$1/;
 977                 $recipient_name = quote_rfc2047($recipient_name);
 978         }
 979
 980         # double quotes are needed if specials or CTLs are included
 981         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 982                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 983                 $recipient_name = qq["$recipient_name"];
 984         }
 985
 986         return "$recipient_name $recipient_addr";
 987
 988 }
 989
 990 sub sanitize_address_list {
 991         return (map { sanitize_address($_) } @_);
 992 }
 993
 994 # Returns the local Fully Qualified Domain Name (FQDN) if available.
 995 #
 996 # Tightly configured MTAa require that a caller sends a real DNS
 997 # domain name that corresponds the IP address in the HELO/EHLO
 998 # handshake. This is used to verify the connection and prevent
 999 # spammers from trying to hide their identity. If the DNS and IP don't
1000 # match, the receiveing MTA may deny the connection.
1001 #
1002 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
1003 #
1004 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
1005 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
1006 #
1007 # This maildomain*() code is based on ideas in Perl library Test::Reporter
1008 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1009
1010 sub valid_fqdn {
1011         my $domain = shift;
1012         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1013 }
1014
1015 sub maildomain_net {
1016         my $maildomain;
1017
1018         if (eval { require Net::Domain; 1 }) {
1019                 my $domain = Net::Domain::domainname();
1020                 $maildomain = $domain if valid_fqdn($domain);
1021         }
1022
1023         return $maildomain;
1024 }
1025
1026 sub maildomain_mta {
1027         my $maildomain;
1028
1029         if (eval { require Net::SMTP; 1 }) {
1030                 for my $host (qw(mailhost localhost)) {
1031                         my $smtp = Net::SMTP->new($host);
1032                         if (defined $smtp) {
1033                                 my $domain = $smtp->domain;
1034                                 $smtp->quit;
1035
1036                                 $maildomain = $domain if valid_fqdn($domain);
1037
1038                                 last if $maildomain;
1039                         }
1040                 }
1041         }
1042
1043         return $maildomain;
1044 }
1045
1046 sub maildomain {
1047         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1048 }
1049
1050 sub smtp_host_string {
1051         if (defined $smtp_server_port) {
1052                 return "$smtp_server:$smtp_server_port";
1053         } else {
1054                 return $smtp_server;
1055         }
1056 }
1057
1058 # Returns 1 if authentication succeeded or was not necessary
1059 # (smtp_user was not specified), and 0 otherwise.
1060
1061 sub smtp_auth_maybe {
1062         if (!defined $smtp_authuser || $auth) {
1063                 return 1;
1064         }
1065
1066         # Workaround AUTH PLAIN/LOGIN interaction defect
1067         # with Authen::SASL::Cyrus
1068         eval {
1069                 require Authen::SASL;
1070                 Authen::SASL->import(qw(Perl));
1071         };
1072
1073         # TODO: Authentication may fail not because credentials were
1074         # invalid but due to other reasons, in which we should not
1075         # reject credentials.
1076         $auth = Git::credential({
1077                 'protocol' => 'smtp',
1078                 'host' => smtp_host_string(),
1079                 'username' => $smtp_authuser,
1080                 # if there's no password, "git credential fill" will
1081                 # give us one, otherwise it'll just pass this one.
1082                 'password' => $smtp_authpass
1083         }, sub {
1084                 my $cred = shift;
1085                 return !!$smtp->auth($cred->{'username'}, $cred->{'password'});
1086         });
1087
1088         return $auth;
1089 }
1090
1091 # Returns 1 if the message was sent, and 0 otherwise.
1092 # In actuality, the whole program dies when there
1093 # is an error sending a message.
1094
1095 sub send_message {
1096         my @recipients = unique_email_list(@to);
1097         @cc = (grep { my $cc = extract_valid_address_or_die($_);
1098                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1099                     }
1100                @cc);
1101         my $to = join (",\n\t", @recipients);
1102         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1103         @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1104         my $date = format_2822_time($time++);
1105         my $gitversion = '@@GIT_VERSION@@';
1106         if ($gitversion =~ m/..GIT_VERSION../) {
1107             $gitversion = Git::version();
1108         }
1109
1110         my $cc = join(",\n\t", unique_email_list(@cc));
1111         my $ccline = "";
1112         if ($cc ne '') {
1113                 $ccline = "\nCc: $cc";
1114         }
1115         my $sanitized_sender = sanitize_address($sender);
1116         make_message_id() unless defined($message_id);
1117
1118         my $header = "From: $sanitized_sender
1119 To: $to${ccline}
1120 Subject: $subject
1121 Date: $date
1122 Message-Id: $message_id
1123 X-Mailer: git-send-email $gitversion
1124 ";
1125         if ($reply_to) {
1126
1127                 $header .= "In-Reply-To: $reply_to\n";
1128                 $header .= "References: $references\n";
1129         }
1130         if (@xh) {
1131                 $header .= join("\n", @xh) . "\n";
1132         }
1133
1134         my @sendmail_parameters = ('-i', @recipients);
1135         my $raw_from = $sanitized_sender;
1136         if (defined $envelope_sender && $envelope_sender ne "auto") {
1137                 $raw_from = $envelope_sender;
1138         }
1139         $raw_from = extract_valid_address($raw_from);
1140         unshift (@sendmail_parameters,
1141                         '-f', $raw_from) if(defined $envelope_sender);
1142
1143         if ($needs_confirm && !$dry_run) {
1144                 print "\n$header\n";
1145                 if ($needs_confirm eq "inform") {
1146                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1147                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1148                         print "    The Cc list above has been expanded by additional\n";
1149                         print "    addresses found in the patch commit message. By default\n";
1150                         print "    send-email prompts before sending whenever this occurs.\n";
1151                         print "    This behavior is controlled by the sendemail.confirm\n";
1152                         print "    configuration setting.\n";
1153                         print "\n";
1154                         print "    For additional information, run 'git send-email --help'.\n";
1155                         print "    To retain the current behavior, but squelch this message,\n";
1156                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1157                 }
1158                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1159                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1160                          default => $ask_default);
1161                 die "Send this email reply required" unless defined $_;
1162                 if (/^n/i) {
1163                         return 0;
1164                 } elsif (/^q/i) {
1165                         cleanup_compose_files();
1166                         exit(0);
1167                 } elsif (/^a/i) {
1168                         $confirm = 'never';
1169                 }
1170         }
1171
1172         unshift (@sendmail_parameters, @smtp_server_options);
1173
1174         if ($dry_run) {
1175                 # We don't want to send the email.
1176         } elsif ($smtp_server =~ m#^/#) {
1177                 my $pid = open my $sm, '|-';
1178                 defined $pid or die $!;
1179                 if (!$pid) {
1180                         exec($smtp_server, @sendmail_parameters) or die $!;
1181                 }
1182                 print $sm "$header\n$message";
1183                 close $sm or die $!;
1184         } else {
1185
1186                 if (!defined $smtp_server) {
1187                         die "The required SMTP server is not properly defined."
1188                 }
1189
1190                 if ($smtp_encryption eq 'ssl') {
1191                         $smtp_server_port ||= 465; # ssmtp
1192                         require Net::SMTP::SSL;
1193                         $smtp_domain ||= maildomain();
1194                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1195                                                       Hello => $smtp_domain,
1196                                                       Port => $smtp_server_port);
1197                 }
1198                 else {
1199                         require Net::SMTP;
1200                         $smtp_domain ||= maildomain();
1201                         $smtp ||= Net::SMTP->new(smtp_host_string(),
1202                                                  Hello => $smtp_domain,
1203                                                  Debug => $debug_net_smtp);
1204                         if ($smtp_encryption eq 'tls' && $smtp) {
1205                                 require Net::SMTP::SSL;
1206                                 $smtp->command('STARTTLS');
1207                                 $smtp->response();
1208                                 if ($smtp->code == 220) {
1209                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
1210                                                 or die "STARTTLS failed! ".$smtp->message;
1211                                         $smtp_encryption = '';
1212                                         # Send EHLO again to receive fresh
1213                                         # supported commands
1214                                         $smtp->hello($smtp_domain);
1215                                 } else {
1216                                         die "Server does not support STARTTLS! ".$smtp->message;
1217                                 }
1218                         }
1219                 }
1220
1221                 if (!$smtp) {
1222                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1223                             "VALUES: server=$smtp_server ",
1224                             "encryption=$smtp_encryption ",
1225                             "hello=$smtp_domain",
1226                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1227                 }
1228
1229                 smtp_auth_maybe or die $smtp->message;
1230
1231                 $smtp->mail( $raw_from ) or die $smtp->message;
1232                 $smtp->to( @recipients ) or die $smtp->message;
1233                 $smtp->data or die $smtp->message;
1234                 $smtp->datasend("$header\n$message") or die $smtp->message;
1235                 $smtp->dataend() or die $smtp->message;
1236                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1237         }
1238         if ($quiet) {
1239                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1240         } else {
1241                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1242                 if ($smtp_server !~ m#^/#) {
1243                         print "Server: $smtp_server\n";
1244                         print "MAIL FROM:<$raw_from>\n";
1245                         foreach my $entry (@recipients) {
1246                             print "RCPT TO:<$entry>\n";
1247                         }
1248                 } else {
1249                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1250                 }
1251                 print $header, "\n";
1252                 if ($smtp) {
1253                         print "Result: ", $smtp->code, ' ',
1254                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1255                 } else {
1256                         print "Result: OK\n";
1257                 }
1258         }
1259
1260         return 1;
1261 }
1262
1263 $reply_to = $initial_reply_to;
1264 $references = $initial_reply_to || '';
1265 $subject = $initial_subject;
1266 $message_num = 0;
1267
1268 foreach my $t (@files) {
1269         open my $fh, "<", $t or die "can't open file $t";
1270
1271         my $author = undef;
1272         my $author_encoding;
1273         my $has_content_type;
1274         my $body_encoding;
1275         @to = ();
1276         @cc = ();
1277         @xh = ();
1278         my $input_format = undef;
1279         my @header = ();
1280         $message = "";
1281         $message_num++;
1282         # First unfold multiline header fields
1283         while(<$fh>) {
1284                 last if /^\s*$/;
1285                 if (/^\s+\S/ and @header) {
1286                         chomp($header[$#header]);
1287                         s/^\s+/ /;
1288                         $header[$#header] .= $_;
1289             } else {
1290                         push(@header, $_);
1291                 }
1292         }
1293         # Now parse the header
1294         foreach(@header) {
1295                 if (/^From /) {
1296                         $input_format = 'mbox';
1297                         next;
1298                 }
1299                 chomp;
1300                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1301                         $input_format = 'mbox';
1302                 }
1303
1304                 if (defined $input_format && $input_format eq 'mbox') {
1305                         if (/^Subject:\s+(.*)$/i) {
1306                                 $subject = $1;
1307                         }
1308                         elsif (/^From:\s+(.*)$/i) {
1309                                 ($author, $author_encoding) = unquote_rfc2047($1);
1310                                 next if $suppress_cc{'author'};
1311                                 next if $suppress_cc{'self'} and $author eq $sender;
1312                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1313                                         $1, $_) unless $quiet;
1314                                 push @cc, $1;
1315                         }
1316                         elsif (/^To:\s+(.*)$/i) {
1317                                 foreach my $addr (parse_address_line($1)) {
1318                                         printf("(mbox) Adding to: %s from line '%s'\n",
1319                                                 $addr, $_) unless $quiet;
1320                                         push @to, $addr;
1321                                 }
1322                         }
1323                         elsif (/^Cc:\s+(.*)$/i) {
1324                                 foreach my $addr (parse_address_line($1)) {
1325                                         if (unquote_rfc2047($addr) eq $sender) {
1326                                                 next if ($suppress_cc{'self'});
1327                                         } else {
1328                                                 next if ($suppress_cc{'cc'});
1329                                         }
1330                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1331                                                 $addr, $_) unless $quiet;
1332                                         push @cc, $addr;
1333                                 }
1334                         }
1335                         elsif (/^Content-type:/i) {
1336                                 $has_content_type = 1;
1337                                 if (/charset="?([^ "]+)/) {
1338                                         $body_encoding = $1;
1339                                 }
1340                                 push @xh, $_;
1341                         }
1342                         elsif (/^Message-Id: (.*)/i) {
1343                                 $message_id = $1;
1344                         }
1345                         elsif (!/^Date:\s/i && /^[-A-Za-z]+:\s+\S/) {
1346                                 push @xh, $_;
1347                         }
1348
1349                 } else {
1350                         # In the traditional
1351                         # "send lots of email" format,
1352                         # line 1 = cc
1353                         # line 2 = subject
1354                         # So let's support that, too.
1355                         $input_format = 'lots';
1356                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1357                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1358                                         $_, $_) unless $quiet;
1359                                 push @cc, $_;
1360                         } elsif (!defined $subject) {
1361                                 $subject = $_;
1362                         }
1363                 }
1364         }
1365         # Now parse the message body
1366         while(<$fh>) {
1367                 $message .=  $_;
1368                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1369                         chomp;
1370                         my ($what, $c) = ($1, $2);
1371                         chomp $c;
1372                         if ($c eq $sender) {
1373                                 next if ($suppress_cc{'self'});
1374                         } else {
1375                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1376                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1377                         }
1378                         push @cc, $c;
1379                         printf("(body) Adding cc: %s from line '%s'\n",
1380                                 $c, $_) unless $quiet;
1381                 }
1382         }
1383         close $fh;
1384
1385         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1386                 if defined $to_cmd;
1387         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1388                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1389
1390         if ($broken_encoding{$t} && !$has_content_type) {
1391                 $has_content_type = 1;
1392                 push @xh, "MIME-Version: 1.0",
1393                         "Content-Type: text/plain; charset=$auto_8bit_encoding",
1394                         "Content-Transfer-Encoding: 8bit";
1395                 $body_encoding = $auto_8bit_encoding;
1396         }
1397
1398         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1399                 $subject = quote_subject($subject, $auto_8bit_encoding);
1400         }
1401
1402         if (defined $author and $author ne $sender) {
1403                 $message = "From: $author\n\n$message";
1404                 if (defined $author_encoding) {
1405                         if ($has_content_type) {
1406                                 if ($body_encoding eq $author_encoding) {
1407                                         # ok, we already have the right encoding
1408                                 }
1409                                 else {
1410                                         # uh oh, we should re-encode
1411                                 }
1412                         }
1413                         else {
1414                                 $has_content_type = 1;
1415                                 push @xh,
1416                                   'MIME-Version: 1.0',
1417                                   "Content-Type: text/plain; charset=$author_encoding",
1418                                   'Content-Transfer-Encoding: 8bit';
1419                         }
1420                 }
1421         }
1422
1423         $needs_confirm = (
1424                 $confirm eq "always" or
1425                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1426                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1427         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1428
1429         @to = validate_address_list(sanitize_address_list(@to));
1430         @cc = validate_address_list(sanitize_address_list(@cc));
1431
1432         @to = (@initial_to, @to);
1433         @cc = (@initial_cc, @cc);
1434
1435         my $message_was_sent = send_message();
1436
1437         # set up for the next message
1438         if ($thread && $message_was_sent &&
1439                 (chain_reply_to() || !defined $reply_to || length($reply_to) == 0 ||
1440                 $message_num == 1)) {
1441                 $reply_to = $message_id;
1442                 if (length $references > 0) {
1443                         $references .= "\n $message_id";
1444                 } else {
1445                         $references = "$message_id";
1446                 }
1447         }
1448         $message_id = undef;
1449 }
1450
1451 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1452 # and return a results array
1453 sub recipients_cmd {
1454         my ($prefix, $what, $cmd, $file) = @_;
1455
1456         my $sanitized_sender = sanitize_address($sender);
1457         my @addresses = ();
1458         open my $fh, "-|", "$cmd \Q$file\E"
1459             or die "($prefix) Could not execute '$cmd'";
1460         while (my $address = <$fh>) {
1461                 $address =~ s/^\s*//g;
1462                 $address =~ s/\s*$//g;
1463                 $address = sanitize_address($address);
1464                 next if ($address eq $sanitized_sender and $suppress_from);
1465                 push @addresses, $address;
1466                 printf("($prefix) Adding %s: %s from: '%s'\n",
1467                        $what, $address, $cmd) unless $quiet;
1468                 }
1469         close $fh
1470             or die "($prefix) failed to close pipe to '$cmd'";
1471         return @addresses;
1472 }
1473
1474 cleanup_compose_files();
1475
1476 sub cleanup_compose_files {
1477         unlink($compose_filename, $compose_filename . ".final") if $compose;
1478 }
1479
1480 $smtp->quit if $smtp;
1481
1482 sub unique_email_list {
1483         my %seen;
1484         my @emails;
1485
1486         foreach my $entry (@_) {
1487                 my $clean = extract_valid_address_or_die($entry);
1488                 $seen{$clean} ||= 0;
1489                 next if $seen{$clean}++;
1490                 push @emails, $entry;
1491         }
1492         return @emails;
1493 }
1494
1495 sub validate_patch {
1496         my $fn = shift;
1497         open(my $fh, '<', $fn)
1498                 or die "unable to open $fn: $!\n";
1499         while (my $line = <$fh>) {
1500                 if (length($line) > 998) {
1501                         return "$.: patch contains a line longer than 998 characters";
1502                 }
1503         }
1504         return;
1505 }
1506
1507 sub file_has_nonascii {
1508         my $fn = shift;
1509         open(my $fh, '<', $fn)
1510                 or die "unable to open $fn: $!\n";
1511         while (my $line = <$fh>) {
1512                 return 1 if $line =~ /[^[:ascii:]]/;
1513         }
1514         return 0;
1515 }
1516
1517 sub body_or_subject_has_nonascii {
1518         my $fn = shift;
1519         open(my $fh, '<', $fn)
1520                 or die "unable to open $fn: $!\n";
1521         while (my $line = <$fh>) {
1522                 last if $line =~ /^$/;
1523                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1524         }
1525         while (my $line = <$fh>) {
1526                 return 1 if $line =~ /[^[:ascii:]]/;
1527         }
1528         return 0;
1529 }