git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Data::Dumper;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49
  50   Composing:
  51     --from                  <str>  * Email From:
  52     --[no-]to               <str>  * Email To:
  53     --[no-]cc               <str>  * Email Cc:
  54     --[no-]bcc              <str>  * Email Bcc:
  55     --subject               <str>  * Email "Subject:"
  56     --in-reply-to           <str>  * Email "In-Reply-To:"
  57     --[no-]xmailer                 * Add "X-Mailer:" header (default).
  58     --[no-]annotate                * Review each patch that will be sent in an editor.
  59     --compose                      * Open an editor for introduction.
  60     --compose-encoding      <str>  * Encoding to assume for introduction.
  61     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  62     --transfer-encoding     <str>  * Transfer encoding to use (quoted-printable, 8bit, base64)
  63
  64   Sending:
  65     --envelope-sender       <str>  * Email envelope sender.
  66     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  67                                      is optional. Default 'localhost'.
  68     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  69     --smtp-server-port      <int>  * Outgoing SMTP server port.
  70     --smtp-user             <str>  * Username for SMTP-AUTH.
  71     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  72     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  73     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  74     --smtp-ssl-cert-path    <str>  * Path to ca-certificates (either directory or file).
  75                                      Pass an empty string to disable certificate
  76                                      verification.
  77     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  78     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  79
  80   Automating:
  81     --identity              <str>  * Use the sendemail.<id> options.
  82     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  83     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  84     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  85     --[no-]cc-cover                * Email Cc: addresses in the cover letter.
  86     --[no-]to-cover                * Email To: addresses in the cover letter.
  87     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  88     --[no-]suppress-from           * Send to self. Default off.
  89     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  90     --[no-]thread                  * Use In-Reply-To: field. Default on.
  91
  92   Administering:
  93     --confirm               <str>  * Confirm recipients before sending;
  94                                      auto, cc, compose, always, or never.
  95     --quiet                        * Output one line of info per email.
  96     --dry-run                      * Don't actually send the emails.
  97     --[no-]validate                * Perform patch sanity checks. Default on.
  98     --[no-]format-patch            * understand any non optional arguments as
  99                                      `git format-patch` ones.
 100     --force                        * Send even if safety checks would prevent it.
 101
 102 EOT
 103         exit(1);
 104 }
 105
 106 # most mail servers generate the Date: header, but not all...
 107 sub format_2822_time {
 108         my ($time) = @_;
 109         my @localtm = localtime($time);
 110         my @gmttm = gmtime($time);
 111         my $localmin = $localtm[1] + $localtm[2] * 60;
 112         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 113         if ($localtm[0] != $gmttm[0]) {
 114                 die "local zone differs from GMT by a non-minute interval\n";
 115         }
 116         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 117                 $localmin += 1440;
 118         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 119                 $localmin -= 1440;
 120         } elsif ($gmttm[6] != $localtm[6]) {
 121                 die "local time offset greater than or equal to 24 hours\n";
 122         }
 123         my $offset = $localmin - $gmtmin;
 124         my $offhour = $offset / 60;
 125         my $offmin = abs($offset % 60);
 126         if (abs($offhour) >= 24) {
 127                 die ("local time offset greater than or equal to 24 hours\n");
 128         }
 129
 130         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 131                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 132                        $localtm[3],
 133                        qw(Jan Feb Mar Apr May Jun
 134                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 135                        $localtm[5]+1900,
 136                        $localtm[2],
 137                        $localtm[1],
 138                        $localtm[0],
 139                        ($offset >= 0) ? '+' : '-',
 140                        abs($offhour),
 141                        $offmin,
 142                        );
 143 }
 144
 145 my $have_email_valid = eval { require Email::Valid; 1 };
 146 my $have_mail_address = eval { require Mail::Address; 1 };
 147 my $smtp;
 148 my $auth;
 149
 150 # Regexes for RFC 2047 productions.
 151 my $re_token = qr/[^][()<>@,;:\\"\/?.= \000-\037\177-\377]+/;
 152 my $re_encoded_text = qr/[^? \000-\037\177-\377]+/;
 153 my $re_encoded_word = qr/=\?($re_token)\?($re_token)\?($re_encoded_text)\?=/;
 154
 155 # Variables we fill in automatically, or via prompting:
 156 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 157         $initial_reply_to,$initial_subject,@files,
 158         $author,$sender,$smtp_authpass,$annotate,$use_xmailer,$compose,$time);
 159
 160 my $envelope_sender;
 161
 162 # Example reply to:
 163 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 164
 165 my $repo = eval { Git->repository() };
 166 my @repo = $repo ? ($repo) : ();
 167 my $term = eval {
 168         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 169                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 170                 : new Term::ReadLine 'git-send-email';
 171 };
 172 if ($@) {
 173         $term = new FakeTerm "$@: going non-interactive";
 174 }
 175
 176 # Behavior modification variables
 177 my ($quiet, $dry_run) = (0, 0);
 178 my $format_patch;
 179 my $compose_filename;
 180 my $force = 0;
 181
 182 # Handle interactive edition of files.
 183 my $multiedit;
 184 my $editor;
 185
 186 sub do_edit {
 187         if (!defined($editor)) {
 188                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 189         }
 190         if (defined($multiedit) && !$multiedit) {
 191                 map {
 192                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 193                         if (($? & 127) || ($? >> 8)) {
 194                                 die("the editor exited uncleanly, aborting everything");
 195                         }
 196                 } @_;
 197         } else {
 198                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 199                 if (($? & 127) || ($? >> 8)) {
 200                         die("the editor exited uncleanly, aborting everything");
 201                 }
 202         }
 203 }
 204
 205 # Variables with corresponding config settings
 206 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 207 my ($cover_cc, $cover_to);
 208 my ($to_cmd, $cc_cmd);
 209 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 210 my ($smtp_authuser, $smtp_encryption, $smtp_ssl_cert_path);
 211 my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
 212 my ($validate, $confirm);
 213 my (@suppress_cc);
 214 my ($auto_8bit_encoding);
 215 my ($compose_encoding);
 216 my ($target_xfer_encoding);
 217
 218 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 219
 220 my %config_bool_settings = (
 221     "thread" => [\$thread, 1],
 222     "chainreplyto" => [\$chain_reply_to, 0],
 223     "suppressfrom" => [\$suppress_from, undef],
 224     "signedoffbycc" => [\$signed_off_by_cc, undef],
 225     "cccover" => [\$cover_cc, undef],
 226     "tocover" => [\$cover_to, undef],
 227     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 228     "validate" => [\$validate, 1],
 229     "multiedit" => [\$multiedit, undef],
 230     "annotate" => [\$annotate, undef],
 231     "xmailer" => [\$use_xmailer, 1]
 232 );
 233
 234 my %config_settings = (
 235     "smtpserver" => \$smtp_server,
 236     "smtpserverport" => \$smtp_server_port,
 237     "smtpserveroption" => \@smtp_server_options,
 238     "smtpuser" => \$smtp_authuser,
 239     "smtppass" => \$smtp_authpass,
 240     "smtpsslcertpath" => \$smtp_ssl_cert_path,
 241     "smtpdomain" => \$smtp_domain,
 242     "to" => \@initial_to,
 243     "tocmd" => \$to_cmd,
 244     "cc" => \@initial_cc,
 245     "cccmd" => \$cc_cmd,
 246     "aliasfiletype" => \$aliasfiletype,
 247     "bcc" => \@bcclist,
 248     "suppresscc" => \@suppress_cc,
 249     "envelopesender" => \$envelope_sender,
 250     "confirm"   => \$confirm,
 251     "from" => \$sender,
 252     "assume8bitencoding" => \$auto_8bit_encoding,
 253     "composeencoding" => \$compose_encoding,
 254     "transferencoding" => \$target_xfer_encoding,
 255 );
 256
 257 my %config_path_settings = (
 258     "aliasesfile" => \@alias_files,
 259 );
 260
 261 # Handle Uncouth Termination
 262 sub signal_handler {
 263
 264         # Make text normal
 265         print color("reset"), "\n";
 266
 267         # SMTP password masked
 268         system "stty echo";
 269
 270         # tmp files from --compose
 271         if (defined $compose_filename) {
 272                 if (-e $compose_filename) {
 273                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 274                 }
 275                 if (-e ($compose_filename . ".final")) {
 276                         print "'$compose_filename.final' contains the composed email.\n"
 277                 }
 278         }
 279
 280         exit;
 281 };
 282
 283 $SIG{TERM} = \&signal_handler;
 284 $SIG{INT}  = \&signal_handler;
 285
 286 # Begin by accumulating all the variables (defined above), that we will end up
 287 # needing, first, from the command line:
 288
 289 my $help;
 290 my $rc = GetOptions("h" => \$help,
 291                     "sender|from=s" => \$sender,
 292                     "in-reply-to=s" => \$initial_reply_to,
 293                     "subject=s" => \$initial_subject,
 294                     "to=s" => \@initial_to,
 295                     "to-cmd=s" => \$to_cmd,
 296                     "no-to" => \$no_to,
 297                     "cc=s" => \@initial_cc,
 298                     "no-cc" => \$no_cc,
 299                     "bcc=s" => \@bcclist,
 300                     "no-bcc" => \$no_bcc,
 301                     "chain-reply-to!" => \$chain_reply_to,
 302                     "no-chain-reply-to" => sub {$chain_reply_to = 0},
 303                     "smtp-server=s" => \$smtp_server,
 304                     "smtp-server-option=s" => \@smtp_server_options,
 305                     "smtp-server-port=s" => \$smtp_server_port,
 306                     "smtp-user=s" => \$smtp_authuser,
 307                     "smtp-pass:s" => \$smtp_authpass,
 308                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 309                     "smtp-encryption=s" => \$smtp_encryption,
 310                     "smtp-ssl-cert-path=s" => \$smtp_ssl_cert_path,
 311                     "smtp-debug:i" => \$debug_net_smtp,
 312                     "smtp-domain:s" => \$smtp_domain,
 313                     "identity=s" => \$identity,
 314                     "annotate!" => \$annotate,
 315                     "no-annotate" => sub {$annotate = 0},
 316                     "compose" => \$compose,
 317                     "quiet" => \$quiet,
 318                     "cc-cmd=s" => \$cc_cmd,
 319                     "suppress-from!" => \$suppress_from,
 320                     "no-suppress-from" => sub {$suppress_from = 0},
 321                     "suppress-cc=s" => \@suppress_cc,
 322                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 323                     "no-signed-off-cc|no-signed-off-by-cc" => sub {$signed_off_by_cc = 0},
 324                     "cc-cover|cc-cover!" => \$cover_cc,
 325                     "no-cc-cover" => sub {$cover_cc = 0},
 326                     "to-cover|to-cover!" => \$cover_to,
 327                     "no-to-cover" => sub {$cover_to = 0},
 328                     "confirm=s" => \$confirm,
 329                     "dry-run" => \$dry_run,
 330                     "envelope-sender=s" => \$envelope_sender,
 331                     "thread!" => \$thread,
 332                     "no-thread" => sub {$thread = 0},
 333                     "validate!" => \$validate,
 334                     "no-validate" => sub {$validate = 0},
 335                     "transfer-encoding=s" => \$target_xfer_encoding,
 336                     "format-patch!" => \$format_patch,
 337                     "no-format-patch" => sub {$format_patch = 0},
 338                     "8bit-encoding=s" => \$auto_8bit_encoding,
 339                     "compose-encoding=s" => \$compose_encoding,
 340                     "force" => \$force,
 341                     "xmailer!" => \$use_xmailer,
 342                     "no-xmailer" => sub {$use_xmailer = 0},
 343          );
 344
 345 usage() if $help;
 346 unless ($rc) {
 347     usage();
 348 }
 349
 350 die "Cannot run git format-patch from outside a repository\n"
 351         if $format_patch and not $repo;
 352
 353 # Now, let's fill any that aren't set in with defaults:
 354
 355 sub read_config {
 356         my ($prefix) = @_;
 357
 358         foreach my $setting (keys %config_bool_settings) {
 359                 my $target = $config_bool_settings{$setting}->[0];
 360                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 361         }
 362
 363         foreach my $setting (keys %config_path_settings) {
 364                 my $target = $config_path_settings{$setting};
 365                 if (ref($target) eq "ARRAY") {
 366                         unless (@$target) {
 367                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 368                                 @$target = @values if (@values && defined $values[0]);
 369                         }
 370                 }
 371                 else {
 372                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 373                 }
 374         }
 375
 376         foreach my $setting (keys %config_settings) {
 377                 my $target = $config_settings{$setting};
 378                 next if $setting eq "to" and defined $no_to;
 379                 next if $setting eq "cc" and defined $no_cc;
 380                 next if $setting eq "bcc" and defined $no_bcc;
 381                 if (ref($target) eq "ARRAY") {
 382                         unless (@$target) {
 383                                 my @values = Git::config(@repo, "$prefix.$setting");
 384                                 @$target = @values if (@values && defined $values[0]);
 385                         }
 386                 }
 387                 else {
 388                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 389                 }
 390         }
 391
 392         if (!defined $smtp_encryption) {
 393                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 394                 if (defined $enc) {
 395                         $smtp_encryption = $enc;
 396                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 397                         $smtp_encryption = 'ssl';
 398                 }
 399         }
 400 }
 401
 402 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 403 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 404 read_config("sendemail.$identity") if (defined $identity);
 405 read_config("sendemail");
 406
 407 # fall back on builtin bool defaults
 408 foreach my $setting (values %config_bool_settings) {
 409         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 410 }
 411
 412 # 'default' encryption is none -- this only prevents a warning
 413 $smtp_encryption = '' unless (defined $smtp_encryption);
 414
 415 # Set CC suppressions
 416 my(%suppress_cc);
 417 if (@suppress_cc) {
 418         foreach my $entry (@suppress_cc) {
 419                 die "Unknown --suppress-cc field: '$entry'\n"
 420                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 421                 $suppress_cc{$entry} = 1;
 422         }
 423 }
 424
 425 if ($suppress_cc{'all'}) {
 426         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 427                 $suppress_cc{$entry} = 1;
 428         }
 429         delete $suppress_cc{'all'};
 430 }
 431
 432 # If explicit old-style ones are specified, they trump --suppress-cc.
 433 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 434 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 435
 436 if ($suppress_cc{'body'}) {
 437         foreach my $entry (qw (sob bodycc)) {
 438                 $suppress_cc{$entry} = 1;
 439         }
 440         delete $suppress_cc{'body'};
 441 }
 442
 443 # Set confirm's default value
 444 my $confirm_unconfigured = !defined $confirm;
 445 if ($confirm_unconfigured) {
 446         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 447 };
 448 die "Unknown --confirm setting: '$confirm'\n"
 449         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 450
 451 # Debugging, print out the suppressions.
 452 if (0) {
 453         print "suppressions:\n";
 454         foreach my $entry (keys %suppress_cc) {
 455                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 456         }
 457 }
 458
 459 my ($repoauthor, $repocommitter);
 460 ($repoauthor) = Git::ident_person(@repo, 'author');
 461 ($repocommitter) = Git::ident_person(@repo, 'committer');
 462
 463 # Verify the user input
 464
 465 foreach my $entry (@initial_to) {
 466         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 467 }
 468
 469 foreach my $entry (@initial_cc) {
 470         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 471 }
 472
 473 foreach my $entry (@bcclist) {
 474         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 475 }
 476
 477 sub parse_address_line {
 478         if ($have_mail_address) {
 479                 return map { $_->format } Mail::Address->parse($_[0]);
 480         } else {
 481                 return split_addrs($_[0]);
 482         }
 483 }
 484
 485 sub split_addrs {
 486         return quotewords('\s*,\s*', 1, @_);
 487 }
 488
 489 my %aliases;
 490
 491 sub parse_sendmail_alias {
 492         local $_ = shift;
 493         if (/"/) {
 494                 print STDERR "warning: sendmail alias with quotes is not supported: $_\n";
 495         } elsif (/:include:/) {
 496                 print STDERR "warning: `:include:` not supported: $_\n";
 497         } elsif (/[\/|]/) {
 498                 print STDERR "warning: `/file` or `|pipe` redirection not supported: $_\n";
 499         } elsif (/^(\S+?)\s*:\s*(.+)$/) {
 500                 my ($alias, $addr) = ($1, $2);
 501                 $aliases{$alias} = [ split_addrs($addr) ];
 502         } else {
 503                 print STDERR "warning: sendmail line is not recognized: $_\n";
 504         }
 505 }
 506
 507 sub parse_sendmail_aliases {
 508         my $fh = shift;
 509         my $s = '';
 510         while (<$fh>) {
 511                 chomp;
 512                 next if /^\s*$/ || /^\s*#/;
 513                 $s .= $_, next if $s =~ s/\\$// || s/^\s+//;
 514                 parse_sendmail_alias($s) if $s;
 515                 $s = $_;
 516         }
 517         $s =~ s/\\$//; # silently tolerate stray '\' on last line
 518         parse_sendmail_alias($s) if $s;
 519 }
 520
 521 my %parse_alias = (
 522         # multiline formats can be supported in the future
 523         mutt => sub { my $fh = shift; while (<$fh>) {
 524                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 525                         my ($alias, $addr) = ($1, $2);
 526                         $addr =~ s/#.*$//; # mutt allows # comments
 527                          # commas delimit multiple addresses
 528                         $aliases{$alias} = [ split_addrs($addr) ];
 529                 }}},
 530         mailrc => sub { my $fh = shift; while (<$fh>) {
 531                 if (/^alias\s+(\S+)\s+(.*)$/) {
 532                         # spaces delimit multiple addresses
 533                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 534                 }}},
 535         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 536                 for (my $x = ''; defined($x); $x = $_) {
 537                         chomp $x;
 538                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 539                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 540                         $aliases{$1} = [ split_addrs($2) ];
 541                 }},
 542         elm => sub  { my $fh = shift;
 543                       while (<$fh>) {
 544                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 545                               my ($alias, $addr) = ($1, $2);
 546                                $aliases{$alias} = [ split_addrs($addr) ];
 547                           }
 548                       } },
 549         sendmail => \&parse_sendmail_aliases,
 550         gnus => sub { my $fh = shift; while (<$fh>) {
 551                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 552                         $aliases{$1} = [ $2 ];
 553                 }}}
 554 );
 555
 556 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 557         foreach my $file (@alias_files) {
 558                 open my $fh, '<', $file or die "opening $file: $!\n";
 559                 $parse_alias{$aliasfiletype}->($fh);
 560                 close $fh;
 561         }
 562 }
 563
 564 ($sender) = expand_aliases($sender) if defined $sender;
 565
 566 # is_format_patch_arg($f) returns 0 if $f names a patch, or 1 if
 567 # $f is a revision list specification to be passed to format-patch.
 568 sub is_format_patch_arg {
 569         return unless $repo;
 570         my $f = shift;
 571         try {
 572                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 573                 if (defined($format_patch)) {
 574                         return $format_patch;
 575                 }
 576                 die(<<EOF);
 577 File '$f' exists but it could also be the range of commits
 578 to produce patches for.  Please disambiguate by...
 579
 580     * Saying "./$f" if you mean a file; or
 581     * Giving --format-patch option if you mean a range.
 582 EOF
 583         } catch Git::Error::Command with {
 584                 # Not a valid revision.  Treat it as a filename.
 585                 return 0;
 586         }
 587 }
 588
 589 # Now that all the defaults are set, process the rest of the command line
 590 # arguments and collect up the files that need to be processed.
 591 my @rev_list_opts;
 592 while (defined(my $f = shift @ARGV)) {
 593         if ($f eq "--") {
 594                 push @rev_list_opts, "--", @ARGV;
 595                 @ARGV = ();
 596         } elsif (-d $f and !is_format_patch_arg($f)) {
 597                 opendir my $dh, $f
 598                         or die "Failed to opendir $f: $!";
 599
 600                 push @files, grep { -f $_ } map { catfile($f, $_) }
 601                                 sort readdir $dh;
 602                 closedir $dh;
 603         } elsif ((-f $f or -p $f) and !is_format_patch_arg($f)) {
 604                 push @files, $f;
 605         } else {
 606                 push @rev_list_opts, $f;
 607         }
 608 }
 609
 610 if (@rev_list_opts) {
 611         die "Cannot run git format-patch from outside a repository\n"
 612                 unless $repo;
 613         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 614 }
 615
 616 if ($validate) {
 617         foreach my $f (@files) {
 618                 unless (-p $f) {
 619                         my $error = validate_patch($f);
 620                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 621                 }
 622         }
 623 }
 624
 625 if (@files) {
 626         unless ($quiet) {
 627                 print $_,"\n" for (@files);
 628         }
 629 } else {
 630         print STDERR "\nNo patch files specified!\n\n";
 631         usage();
 632 }
 633
 634 sub get_patch_subject {
 635         my $fn = shift;
 636         open (my $fh, '<', $fn);
 637         while (my $line = <$fh>) {
 638                 next unless ($line =~ /^Subject: (.*)$/);
 639                 close $fh;
 640                 return "GIT: $1\n";
 641         }
 642         close $fh;
 643         die "No subject line in $fn ?";
 644 }
 645
 646 if ($compose) {
 647         # Note that this does not need to be secure, but we will make a small
 648         # effort to have it be unique
 649         $compose_filename = ($repo ?
 650                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 651                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 652         open my $c, ">", $compose_filename
 653                 or die "Failed to open for writing $compose_filename: $!";
 654
 655
 656         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 657         my $tpl_subject = $initial_subject || '';
 658         my $tpl_reply_to = $initial_reply_to || '';
 659
 660         print $c <<EOT;
 661 From $tpl_sender # This line is ignored.
 662 GIT: Lines beginning in "GIT:" will be removed.
 663 GIT: Consider including an overall diffstat or table of contents
 664 GIT: for the patch you are writing.
 665 GIT:
 666 GIT: Clear the body content if you don't wish to send a summary.
 667 From: $tpl_sender
 668 Subject: $tpl_subject
 669 In-Reply-To: $tpl_reply_to
 670
 671 EOT
 672         for my $f (@files) {
 673                 print $c get_patch_subject($f);
 674         }
 675         close $c;
 676
 677         if ($annotate) {
 678                 do_edit($compose_filename, @files);
 679         } else {
 680                 do_edit($compose_filename);
 681         }
 682
 683         open my $c2, ">", $compose_filename . ".final"
 684                 or die "Failed to open $compose_filename.final : " . $!;
 685
 686         open $c, "<", $compose_filename
 687                 or die "Failed to open $compose_filename : " . $!;
 688
 689         my $need_8bit_cte = file_has_nonascii($compose_filename);
 690         my $in_body = 0;
 691         my $summary_empty = 1;
 692         if (!defined $compose_encoding) {
 693                 $compose_encoding = "UTF-8";
 694         }
 695         while(<$c>) {
 696                 next if m/^GIT:/;
 697                 if ($in_body) {
 698                         $summary_empty = 0 unless (/^\n$/);
 699                 } elsif (/^\n$/) {
 700                         $in_body = 1;
 701                         if ($need_8bit_cte) {
 702                                 print $c2 "MIME-Version: 1.0\n",
 703                                          "Content-Type: text/plain; ",
 704                                            "charset=$compose_encoding\n",
 705                                          "Content-Transfer-Encoding: 8bit\n";
 706                         }
 707                 } elsif (/^MIME-Version:/i) {
 708                         $need_8bit_cte = 0;
 709                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 710                         $initial_subject = $1;
 711                         my $subject = $initial_subject;
 712                         $_ = "Subject: " .
 713                                 quote_subject($subject, $compose_encoding) .
 714                                 "\n";
 715                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 716                         $initial_reply_to = $1;
 717                         next;
 718                 } elsif (/^From:\s*(.+)\s*$/i) {
 719                         $sender = $1;
 720                         next;
 721                 } elsif (/^(?:To|Cc|Bcc):/i) {
 722                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 723                         next;
 724                 }
 725                 print $c2 $_;
 726         }
 727         close $c;
 728         close $c2;
 729
 730         if ($summary_empty) {
 731                 print "Summary email is empty, skipping it\n";
 732                 $compose = -1;
 733         }
 734 } elsif ($annotate) {
 735         do_edit(@files);
 736 }
 737
 738 sub ask {
 739         my ($prompt, %arg) = @_;
 740         my $valid_re = $arg{valid_re};
 741         my $default = $arg{default};
 742         my $confirm_only = $arg{confirm_only};
 743         my $resp;
 744         my $i = 0;
 745         return defined $default ? $default : undef
 746                 unless defined $term->IN and defined fileno($term->IN) and
 747                        defined $term->OUT and defined fileno($term->OUT);
 748         while ($i++ < 10) {
 749                 $resp = $term->readline($prompt);
 750                 if (!defined $resp) { # EOF
 751                         print "\n";
 752                         return defined $default ? $default : undef;
 753                 }
 754                 if ($resp eq '' and defined $default) {
 755                         return $default;
 756                 }
 757                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 758                         return $resp;
 759                 }
 760                 if ($confirm_only) {
 761                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 762                         if (defined $yesno && $yesno =~ /y/i) {
 763                                 return $resp;
 764                         }
 765                 }
 766         }
 767         return;
 768 }
 769
 770 my %broken_encoding;
 771
 772 sub file_declares_8bit_cte {
 773         my $fn = shift;
 774         open (my $fh, '<', $fn);
 775         while (my $line = <$fh>) {
 776                 last if ($line =~ /^$/);
 777                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 778         }
 779         close $fh;
 780         return 0;
 781 }
 782
 783 foreach my $f (@files) {
 784         next unless (body_or_subject_has_nonascii($f)
 785                      && !file_declares_8bit_cte($f));
 786         $broken_encoding{$f} = 1;
 787 }
 788
 789 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 790         print "The following files are 8bit, but do not declare " .
 791                 "a Content-Transfer-Encoding.\n";
 792         foreach my $f (sort keys %broken_encoding) {
 793                 print "    $f\n";
 794         }
 795         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 796                                   valid_re => qr/.{4}/, confirm_only => 1,
 797                                   default => "UTF-8");
 798 }
 799
 800 if (!$force) {
 801         for my $f (@files) {
 802                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 803                         die "Refusing to send because the patch\n\t$f\n"
 804                                 . "has the template subject '*** SUBJECT HERE ***'. "
 805                                 . "Pass --force if you really want to send.\n";
 806                 }
 807         }
 808 }
 809
 810 if (!defined $sender) {
 811         $sender = $repoauthor || $repocommitter || '';
 812 }
 813
 814 # $sender could be an already sanitized address
 815 # (e.g. sendemail.from could be manually sanitized by user).
 816 # But it's a no-op to run sanitize_address on an already sanitized address.
 817 $sender = sanitize_address($sender);
 818
 819 my $prompting = 0;
 820 if (!@initial_to && !defined $to_cmd) {
 821         my $to = ask("Who should the emails be sent to (if any)? ",
 822                      default => "",
 823                      valid_re => qr/\@.*\./, confirm_only => 1);
 824         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 825         $prompting++;
 826 }
 827
 828 sub expand_aliases {
 829         return map { expand_one_alias($_) } @_;
 830 }
 831
 832 my %EXPANDED_ALIASES;
 833 sub expand_one_alias {
 834         my $alias = shift;
 835         if ($EXPANDED_ALIASES{$alias}) {
 836                 die "fatal: alias '$alias' expands to itself\n";
 837         }
 838         local $EXPANDED_ALIASES{$alias} = 1;
 839         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 840 }
 841
 842 @initial_to = expand_aliases(@initial_to);
 843 @initial_to = validate_address_list(sanitize_address_list(@initial_to));
 844 @initial_cc = expand_aliases(@initial_cc);
 845 @initial_cc = validate_address_list(sanitize_address_list(@initial_cc));
 846 @bcclist = expand_aliases(@bcclist);
 847 @bcclist = validate_address_list(sanitize_address_list(@bcclist));
 848
 849 if ($thread && !defined $initial_reply_to && $prompting) {
 850         $initial_reply_to = ask(
 851                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 852                 default => "",
 853                 valid_re => qr/\@.*\./, confirm_only => 1);
 854 }
 855 if (defined $initial_reply_to) {
 856         $initial_reply_to =~ s/^\s*<?//;
 857         $initial_reply_to =~ s/>?\s*$//;
 858         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 859 }
 860
 861 if (!defined $smtp_server) {
 862         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 863                 if (-x $_) {
 864                         $smtp_server = $_;
 865                         last;
 866                 }
 867         }
 868         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 869 }
 870
 871 if ($compose && $compose > 0) {
 872         @files = ($compose_filename . ".final", @files);
 873 }
 874
 875 # Variables we set as part of the loop over files
 876 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 877         $needs_confirm, $message_num, $ask_default);
 878
 879 sub extract_valid_address {
 880         my $address = shift;
 881         my $local_part_regexp = qr/[^<>"\s@]+/;
 882         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 883
 884         # check for a local address:
 885         return $address if ($address =~ /^($local_part_regexp)$/);
 886
 887         $address =~ s/^\s*<(.*)>\s*$/$1/;
 888         if ($have_email_valid) {
 889                 return scalar Email::Valid->address($address);
 890         }
 891
 892         # less robust/correct than the monster regexp in Email::Valid,
 893         # but still does a 99% job, and one less dependency
 894         return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
 895         return;
 896 }
 897
 898 sub extract_valid_address_or_die {
 899         my $address = shift;
 900         $address = extract_valid_address($address);
 901         die "error: unable to extract a valid address from: $address\n"
 902                 if !$address;
 903         return $address;
 904 }
 905
 906 sub validate_address {
 907         my $address = shift;
 908         while (!extract_valid_address($address)) {
 909                 print STDERR "error: unable to extract a valid address from: $address\n";
 910                 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
 911                         valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
 912                         default => 'q');
 913                 if (/^d/i) {
 914                         return undef;
 915                 } elsif (/^q/i) {
 916                         cleanup_compose_files();
 917                         exit(0);
 918                 }
 919                 $address = ask("Who should the email be sent to (if any)? ",
 920                         default => "",
 921                         valid_re => qr/\@.*\./, confirm_only => 1);
 922         }
 923         return $address;
 924 }
 925
 926 sub validate_address_list {
 927         return (grep { defined $_ }
 928                 map { validate_address($_) } @_);
 929 }
 930
 931 # Usually don't need to change anything below here.
 932
 933 # we make a "fake" message id by taking the current number
 934 # of seconds since the beginning of Unix time and tacking on
 935 # a random number to the end, in case we are called quicker than
 936 # 1 second since the last time we were called.
 937
 938 # We'll setup a template for the message id, using the "from" address:
 939
 940 my ($message_id_stamp, $message_id_serial);
 941 sub make_message_id {
 942         my $uniq;
 943         if (!defined $message_id_stamp) {
 944                 $message_id_stamp = sprintf("%s-%s", time, $$);
 945                 $message_id_serial = 0;
 946         }
 947         $message_id_serial++;
 948         $uniq = "$message_id_stamp-$message_id_serial";
 949
 950         my $du_part;
 951         for ($sender, $repocommitter, $repoauthor) {
 952                 $du_part = extract_valid_address(sanitize_address($_));
 953                 last if (defined $du_part and $du_part ne '');
 954         }
 955         if (not defined $du_part or $du_part eq '') {
 956                 require Sys::Hostname;
 957                 $du_part = 'user@' . Sys::Hostname::hostname();
 958         }
 959         my $message_id_template = "<%s-git-send-email-%s>";
 960         $message_id = sprintf($message_id_template, $uniq, $du_part);
 961         #print "new message id = $message_id\n"; # Was useful for debugging
 962 }
 963
 964
 965
 966 $time = time - scalar $#files;
 967
 968 sub unquote_rfc2047 {
 969         local ($_) = @_;
 970         my $charset;
 971         my $sep = qr/[ \t]+/;
 972         s{$re_encoded_word(?:$sep$re_encoded_word)*}{
 973                 my @words = split $sep, $&;
 974                 foreach (@words) {
 975                         m/$re_encoded_word/;
 976                         $charset = $1;
 977                         my $encoding = $2;
 978                         my $text = $3;
 979                         if ($encoding eq 'q' || $encoding eq 'Q') {
 980                                 $_ = $text;
 981                                 s/_/ /g;
 982                                 s/=([0-9A-F]{2})/chr(hex($1))/egi;
 983                         } else {
 984                                 # other encodings not supported yet
 985                         }
 986                 }
 987                 join '', @words;
 988         }eg;
 989         return wantarray ? ($_, $charset) : $_;
 990 }
 991
 992 sub quote_rfc2047 {
 993         local $_ = shift;
 994         my $encoding = shift || 'UTF-8';
 995         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 996         s/(.*)/=\?$encoding\?q\?$1\?=/;
 997         return $_;
 998 }
 999
1000 sub is_rfc2047_quoted {
1001         my $s = shift;
1002         length($s) <= 75 &&
1003         $s =~ m/^(?:"[[:ascii:]]*"|$re_encoded_word)$/o;
1004 }
1005
1006 sub subject_needs_rfc2047_quoting {
1007         my $s = shift;
1008
1009         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
1010 }
1011
1012 sub quote_subject {
1013         local $subject = shift;
1014         my $encoding = shift || 'UTF-8';
1015
1016         if (subject_needs_rfc2047_quoting($subject)) {
1017                 return quote_rfc2047($subject, $encoding);
1018         }
1019         return $subject;
1020 }
1021
1022 # use the simplest quoting being able to handle the recipient
1023 sub sanitize_address {
1024         my ($recipient) = @_;
1025
1026         # remove garbage after email address
1027         $recipient =~ s/(.*>).*$/$1/;
1028
1029         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
1030
1031         if (not $recipient_name) {
1032                 return $recipient;
1033         }
1034
1035         # if recipient_name is already quoted, do nothing
1036         if (is_rfc2047_quoted($recipient_name)) {
1037                 return $recipient;
1038         }
1039
1040         # rfc2047 is needed if a non-ascii char is included
1041         if ($recipient_name =~ /[^[:ascii:]]/) {
1042                 $recipient_name =~ s/^"(.*)"$/$1/;
1043                 $recipient_name = quote_rfc2047($recipient_name);
1044         }
1045
1046         # double quotes are needed if specials or CTLs are included
1047         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
1048                 $recipient_name =~ s/(["\\\r])/\\$1/g;
1049                 $recipient_name = qq["$recipient_name"];
1050         }
1051
1052         return "$recipient_name $recipient_addr";
1053
1054 }
1055
1056 sub sanitize_address_list {
1057         return (map { sanitize_address($_) } @_);
1058 }
1059
1060 # Returns the local Fully Qualified Domain Name (FQDN) if available.
1061 #
1062 # Tightly configured MTAa require that a caller sends a real DNS
1063 # domain name that corresponds the IP address in the HELO/EHLO
1064 # handshake. This is used to verify the connection and prevent
1065 # spammers from trying to hide their identity. If the DNS and IP don't
1066 # match, the receiveing MTA may deny the connection.
1067 #
1068 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
1069 #
1070 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
1071 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
1072 #
1073 # This maildomain*() code is based on ideas in Perl library Test::Reporter
1074 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1075
1076 sub valid_fqdn {
1077         my $domain = shift;
1078         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1079 }
1080
1081 sub maildomain_net {
1082         my $maildomain;
1083
1084         if (eval { require Net::Domain; 1 }) {
1085                 my $domain = Net::Domain::domainname();
1086                 $maildomain = $domain if valid_fqdn($domain);
1087         }
1088
1089         return $maildomain;
1090 }
1091
1092 sub maildomain_mta {
1093         my $maildomain;
1094
1095         if (eval { require Net::SMTP; 1 }) {
1096                 for my $host (qw(mailhost localhost)) {
1097                         my $smtp = Net::SMTP->new($host);
1098                         if (defined $smtp) {
1099                                 my $domain = $smtp->domain;
1100                                 $smtp->quit;
1101
1102                                 $maildomain = $domain if valid_fqdn($domain);
1103
1104                                 last if $maildomain;
1105                         }
1106                 }
1107         }
1108
1109         return $maildomain;
1110 }
1111
1112 sub maildomain {
1113         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1114 }
1115
1116 sub smtp_host_string {
1117         if (defined $smtp_server_port) {
1118                 return "$smtp_server:$smtp_server_port";
1119         } else {
1120                 return $smtp_server;
1121         }
1122 }
1123
1124 # Returns 1 if authentication succeeded or was not necessary
1125 # (smtp_user was not specified), and 0 otherwise.
1126
1127 sub smtp_auth_maybe {
1128         if (!defined $smtp_authuser || $auth) {
1129                 return 1;
1130         }
1131
1132         # Workaround AUTH PLAIN/LOGIN interaction defect
1133         # with Authen::SASL::Cyrus
1134         eval {
1135                 require Authen::SASL;
1136                 Authen::SASL->import(qw(Perl));
1137         };
1138
1139         # TODO: Authentication may fail not because credentials were
1140         # invalid but due to other reasons, in which we should not
1141         # reject credentials.
1142         $auth = Git::credential({
1143                 'protocol' => 'smtp',
1144                 'host' => smtp_host_string(),
1145                 'username' => $smtp_authuser,
1146                 # if there's no password, "git credential fill" will
1147                 # give us one, otherwise it'll just pass this one.
1148                 'password' => $smtp_authpass
1149         }, sub {
1150                 my $cred = shift;
1151                 return !!$smtp->auth($cred->{'username'}, $cred->{'password'});
1152         });
1153
1154         return $auth;
1155 }
1156
1157 sub ssl_verify_params {
1158         eval {
1159                 require IO::Socket::SSL;
1160                 IO::Socket::SSL->import(qw/SSL_VERIFY_PEER SSL_VERIFY_NONE/);
1161         };
1162         if ($@) {
1163                 print STDERR "Not using SSL_VERIFY_PEER due to out-of-date IO::Socket::SSL.\n";
1164                 return;
1165         }
1166
1167         if (!defined $smtp_ssl_cert_path) {
1168                 # use the OpenSSL defaults
1169                 return (SSL_verify_mode => SSL_VERIFY_PEER());
1170         }
1171
1172         if ($smtp_ssl_cert_path eq "") {
1173                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1174         } elsif (-d $smtp_ssl_cert_path) {
1175                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1176                         SSL_ca_path => $smtp_ssl_cert_path);
1177         } elsif (-f $smtp_ssl_cert_path) {
1178                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1179                         SSL_ca_file => $smtp_ssl_cert_path);
1180         } else {
1181                 print STDERR "Not using SSL_VERIFY_PEER because the CA path does not exist.\n";
1182                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1183         }
1184 }
1185
1186 sub file_name_is_absolute {
1187         my ($path) = @_;
1188
1189         # msys does not grok DOS drive-prefixes
1190         if ($^O eq 'msys') {
1191                 return ($path =~ m#^/# || $path =~ m#^[a-zA-Z]\:#)
1192         }
1193
1194         require File::Spec::Functions;
1195         return File::Spec::Functions::file_name_is_absolute($path);
1196 }
1197
1198 # Returns 1 if the message was sent, and 0 otherwise.
1199 # In actuality, the whole program dies when there
1200 # is an error sending a message.
1201
1202 sub send_message {
1203         my @recipients = unique_email_list(@to);
1204         @cc = (grep { my $cc = extract_valid_address_or_die($_);
1205                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1206                     }
1207                @cc);
1208         my $to = join (",\n\t", @recipients);
1209         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1210         @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1211         my $date = format_2822_time($time++);
1212         my $gitversion = '@@GIT_VERSION@@';
1213         if ($gitversion =~ m/..GIT_VERSION../) {
1214             $gitversion = Git::version();
1215         }
1216
1217         my $cc = join(",\n\t", unique_email_list(@cc));
1218         my $ccline = "";
1219         if ($cc ne '') {
1220                 $ccline = "\nCc: $cc";
1221         }
1222         make_message_id() unless defined($message_id);
1223
1224         my $header = "From: $sender
1225 To: $to${ccline}
1226 Subject: $subject
1227 Date: $date
1228 Message-Id: $message_id
1229 ";
1230         if ($use_xmailer) {
1231                 $header .= "X-Mailer: git-send-email $gitversion\n";
1232         }
1233         if ($reply_to) {
1234
1235                 $header .= "In-Reply-To: $reply_to\n";
1236                 $header .= "References: $references\n";
1237         }
1238         if (@xh) {
1239                 $header .= join("\n", @xh) . "\n";
1240         }
1241
1242         my @sendmail_parameters = ('-i', @recipients);
1243         my $raw_from = $sender;
1244         if (defined $envelope_sender && $envelope_sender ne "auto") {
1245                 $raw_from = $envelope_sender;
1246         }
1247         $raw_from = extract_valid_address($raw_from);
1248         unshift (@sendmail_parameters,
1249                         '-f', $raw_from) if(defined $envelope_sender);
1250
1251         if ($needs_confirm && !$dry_run) {
1252                 print "\n$header\n";
1253                 if ($needs_confirm eq "inform") {
1254                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1255                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1256                         print "    The Cc list above has been expanded by additional\n";
1257                         print "    addresses found in the patch commit message. By default\n";
1258                         print "    send-email prompts before sending whenever this occurs.\n";
1259                         print "    This behavior is controlled by the sendemail.confirm\n";
1260                         print "    configuration setting.\n";
1261                         print "\n";
1262                         print "    For additional information, run 'git send-email --help'.\n";
1263                         print "    To retain the current behavior, but squelch this message,\n";
1264                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1265                 }
1266                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1267                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1268                          default => $ask_default);
1269                 die "Send this email reply required" unless defined $_;
1270                 if (/^n/i) {
1271                         return 0;
1272                 } elsif (/^q/i) {
1273                         cleanup_compose_files();
1274                         exit(0);
1275                 } elsif (/^a/i) {
1276                         $confirm = 'never';
1277                 }
1278         }
1279
1280         unshift (@sendmail_parameters, @smtp_server_options);
1281
1282         if ($dry_run) {
1283                 # We don't want to send the email.
1284         } elsif (file_name_is_absolute($smtp_server)) {
1285                 my $pid = open my $sm, '|-';
1286                 defined $pid or die $!;
1287                 if (!$pid) {
1288                         exec($smtp_server, @sendmail_parameters) or die $!;
1289                 }
1290                 print $sm "$header\n$message";
1291                 close $sm or die $!;
1292         } else {
1293
1294                 if (!defined $smtp_server) {
1295                         die "The required SMTP server is not properly defined."
1296                 }
1297
1298                 if ($smtp_encryption eq 'ssl') {
1299                         $smtp_server_port ||= 465; # ssmtp
1300                         require Net::SMTP::SSL;
1301                         $smtp_domain ||= maildomain();
1302                         require IO::Socket::SSL;
1303                         # Net::SMTP::SSL->new() does not forward any SSL options
1304                         IO::Socket::SSL::set_client_defaults(
1305                                 ssl_verify_params());
1306                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1307                                                       Hello => $smtp_domain,
1308                                                       Port => $smtp_server_port,
1309                                                       Debug => $debug_net_smtp);
1310                 }
1311                 else {
1312                         require Net::SMTP;
1313                         $smtp_domain ||= maildomain();
1314                         $smtp_server_port ||= 25;
1315                         $smtp ||= Net::SMTP->new($smtp_server,
1316                                                  Hello => $smtp_domain,
1317                                                  Debug => $debug_net_smtp,
1318                                                  Port => $smtp_server_port);
1319                         if ($smtp_encryption eq 'tls' && $smtp) {
1320                                 require Net::SMTP::SSL;
1321                                 $smtp->command('STARTTLS');
1322                                 $smtp->response();
1323                                 if ($smtp->code == 220) {
1324                                         $smtp = Net::SMTP::SSL->start_SSL($smtp,
1325                                                                           ssl_verify_params())
1326                                                 or die "STARTTLS failed! ".IO::Socket::SSL::errstr();
1327                                         $smtp_encryption = '';
1328                                         # Send EHLO again to receive fresh
1329                                         # supported commands
1330                                         $smtp->hello($smtp_domain);
1331                                 } else {
1332                                         die "Server does not support STARTTLS! ".$smtp->message;
1333                                 }
1334                         }
1335                 }
1336
1337                 if (!$smtp) {
1338                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1339                             "VALUES: server=$smtp_server ",
1340                             "encryption=$smtp_encryption ",
1341                             "hello=$smtp_domain",
1342                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1343                 }
1344
1345                 smtp_auth_maybe or die $smtp->message;
1346
1347                 $smtp->mail( $raw_from ) or die $smtp->message;
1348                 $smtp->to( @recipients ) or die $smtp->message;
1349                 $smtp->data or die $smtp->message;
1350                 $smtp->datasend("$header\n$message") or die $smtp->message;
1351                 $smtp->dataend() or die $smtp->message;
1352                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1353         }
1354         if ($quiet) {
1355                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1356         } else {
1357                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1358                 if (!file_name_is_absolute($smtp_server)) {
1359                         print "Server: $smtp_server\n";
1360                         print "MAIL FROM:<$raw_from>\n";
1361                         foreach my $entry (@recipients) {
1362                             print "RCPT TO:<$entry>\n";
1363                         }
1364                 } else {
1365                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1366                 }
1367                 print $header, "\n";
1368                 if ($smtp) {
1369                         print "Result: ", $smtp->code, ' ',
1370                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1371                 } else {
1372                         print "Result: OK\n";
1373                 }
1374         }
1375
1376         return 1;
1377 }
1378
1379 $reply_to = $initial_reply_to;
1380 $references = $initial_reply_to || '';
1381 $subject = $initial_subject;
1382 $message_num = 0;
1383
1384 foreach my $t (@files) {
1385         open my $fh, "<", $t or die "can't open file $t";
1386
1387         my $author = undef;
1388         my $sauthor = undef;
1389         my $author_encoding;
1390         my $has_content_type;
1391         my $body_encoding;
1392         my $xfer_encoding;
1393         my $has_mime_version;
1394         @to = ();
1395         @cc = ();
1396         @xh = ();
1397         my $input_format = undef;
1398         my @header = ();
1399         $message = "";
1400         $message_num++;
1401         # First unfold multiline header fields
1402         while(<$fh>) {
1403                 last if /^\s*$/;
1404                 if (/^\s+\S/ and @header) {
1405                         chomp($header[$#header]);
1406                         s/^\s+/ /;
1407                         $header[$#header] .= $_;
1408             } else {
1409                         push(@header, $_);
1410                 }
1411         }
1412         # Now parse the header
1413         foreach(@header) {
1414                 if (/^From /) {
1415                         $input_format = 'mbox';
1416                         next;
1417                 }
1418                 chomp;
1419                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1420                         $input_format = 'mbox';
1421                 }
1422
1423                 if (defined $input_format && $input_format eq 'mbox') {
1424                         if (/^Subject:\s+(.*)$/i) {
1425                                 $subject = $1;
1426                         }
1427                         elsif (/^From:\s+(.*)$/i) {
1428                                 ($author, $author_encoding) = unquote_rfc2047($1);
1429                                 $sauthor = sanitize_address($author);
1430                                 next if $suppress_cc{'author'};
1431                                 next if $suppress_cc{'self'} and $sauthor eq $sender;
1432                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1433                                         $1, $_) unless $quiet;
1434                                 push @cc, $1;
1435                         }
1436                         elsif (/^To:\s+(.*)$/i) {
1437                                 foreach my $addr (parse_address_line($1)) {
1438                                         printf("(mbox) Adding to: %s from line '%s'\n",
1439                                                 $addr, $_) unless $quiet;
1440                                         push @to, $addr;
1441                                 }
1442                         }
1443                         elsif (/^Cc:\s+(.*)$/i) {
1444                                 foreach my $addr (parse_address_line($1)) {
1445                                         my $qaddr = unquote_rfc2047($addr);
1446                                         my $saddr = sanitize_address($qaddr);
1447                                         if ($saddr eq $sender) {
1448                                                 next if ($suppress_cc{'self'});
1449                                         } else {
1450                                                 next if ($suppress_cc{'cc'});
1451                                         }
1452                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1453                                                 $addr, $_) unless $quiet;
1454                                         push @cc, $addr;
1455                                 }
1456                         }
1457                         elsif (/^Content-type:/i) {
1458                                 $has_content_type = 1;
1459                                 if (/charset="?([^ "]+)/) {
1460                                         $body_encoding = $1;
1461                                 }
1462                                 push @xh, $_;
1463                         }
1464                         elsif (/^MIME-Version/i) {
1465                                 $has_mime_version = 1;
1466                                 push @xh, $_;
1467                         }
1468                         elsif (/^Message-Id: (.*)/i) {
1469                                 $message_id = $1;
1470                         }
1471                         elsif (/^Content-Transfer-Encoding: (.*)/i) {
1472                                 $xfer_encoding = $1 if not defined $xfer_encoding;
1473                         }
1474                         elsif (!/^Date:\s/i && /^[-A-Za-z]+:\s+\S/) {
1475                                 push @xh, $_;
1476                         }
1477
1478                 } else {
1479                         # In the traditional
1480                         # "send lots of email" format,
1481                         # line 1 = cc
1482                         # line 2 = subject
1483                         # So let's support that, too.
1484                         $input_format = 'lots';
1485                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1486                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1487                                         $_, $_) unless $quiet;
1488                                 push @cc, $_;
1489                         } elsif (!defined $subject) {
1490                                 $subject = $_;
1491                         }
1492                 }
1493         }
1494         # Now parse the message body
1495         while(<$fh>) {
1496                 $message .=  $_;
1497                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1498                         chomp;
1499                         my ($what, $c) = ($1, $2);
1500                         chomp $c;
1501                         my $sc = sanitize_address($c);
1502                         if ($sc eq $sender) {
1503                                 next if ($suppress_cc{'self'});
1504                         } else {
1505                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1506                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1507                         }
1508                         push @cc, $c;
1509                         printf("(body) Adding cc: %s from line '%s'\n",
1510                                 $c, $_) unless $quiet;
1511                 }
1512         }
1513         close $fh;
1514
1515         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1516                 if defined $to_cmd;
1517         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1518                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1519
1520         if ($broken_encoding{$t} && !$has_content_type) {
1521                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1522                 $has_content_type = 1;
1523                 push @xh, "Content-Type: text/plain; charset=$auto_8bit_encoding";
1524                 $body_encoding = $auto_8bit_encoding;
1525         }
1526
1527         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1528                 $subject = quote_subject($subject, $auto_8bit_encoding);
1529         }
1530
1531         if (defined $sauthor and $sauthor ne $sender) {
1532                 $message = "From: $author\n\n$message";
1533                 if (defined $author_encoding) {
1534                         if ($has_content_type) {
1535                                 if ($body_encoding eq $author_encoding) {
1536                                         # ok, we already have the right encoding
1537                                 }
1538                                 else {
1539                                         # uh oh, we should re-encode
1540                                 }
1541                         }
1542                         else {
1543                                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1544                                 $has_content_type = 1;
1545                                 push @xh,
1546                                   "Content-Type: text/plain; charset=$author_encoding";
1547                         }
1548                 }
1549         }
1550         if (defined $target_xfer_encoding) {
1551                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1552                 $message = apply_transfer_encoding(
1553                         $message, $xfer_encoding, $target_xfer_encoding);
1554                 $xfer_encoding = $target_xfer_encoding;
1555         }
1556         if (defined $xfer_encoding) {
1557                 push @xh, "Content-Transfer-Encoding: $xfer_encoding";
1558         }
1559         if (defined $xfer_encoding or $has_content_type) {
1560                 unshift @xh, 'MIME-Version: 1.0' unless $has_mime_version;
1561         }
1562
1563         $needs_confirm = (
1564                 $confirm eq "always" or
1565                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1566                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1567         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1568
1569         @to = validate_address_list(sanitize_address_list(@to));
1570         @cc = validate_address_list(sanitize_address_list(@cc));
1571
1572         @to = (@initial_to, @to);
1573         @cc = (@initial_cc, @cc);
1574
1575         if ($message_num == 1) {
1576                 if (defined $cover_cc and $cover_cc) {
1577                         @initial_cc = @cc;
1578                 }
1579                 if (defined $cover_to and $cover_to) {
1580                         @initial_to = @to;
1581                 }
1582         }
1583
1584         my $message_was_sent = send_message();
1585
1586         # set up for the next message
1587         if ($thread && $message_was_sent &&
1588                 ($chain_reply_to || !defined $reply_to || length($reply_to) == 0 ||
1589                 $message_num == 1)) {
1590                 $reply_to = $message_id;
1591                 if (length $references > 0) {
1592                         $references .= "\n $message_id";
1593                 } else {
1594                         $references = "$message_id";
1595                 }
1596         }
1597         $message_id = undef;
1598 }
1599
1600 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1601 # and return a results array
1602 sub recipients_cmd {
1603         my ($prefix, $what, $cmd, $file) = @_;
1604
1605         my @addresses = ();
1606         open my $fh, "-|", "$cmd \Q$file\E"
1607             or die "($prefix) Could not execute '$cmd'";
1608         while (my $address = <$fh>) {
1609                 $address =~ s/^\s*//g;
1610                 $address =~ s/\s*$//g;
1611                 $address = sanitize_address($address);
1612                 next if ($address eq $sender and $suppress_cc{'self'});
1613                 push @addresses, $address;
1614                 printf("($prefix) Adding %s: %s from: '%s'\n",
1615                        $what, $address, $cmd) unless $quiet;
1616                 }
1617         close $fh
1618             or die "($prefix) failed to close pipe to '$cmd'";
1619         return @addresses;
1620 }
1621
1622 cleanup_compose_files();
1623
1624 sub cleanup_compose_files {
1625         unlink($compose_filename, $compose_filename . ".final") if $compose;
1626 }
1627
1628 $smtp->quit if $smtp;
1629
1630 sub apply_transfer_encoding {
1631         my $message = shift;
1632         my $from = shift;
1633         my $to = shift;
1634
1635         return $message if ($from eq $to and $from ne '7bit');
1636
1637         require MIME::QuotedPrint;
1638         require MIME::Base64;
1639
1640         $message = MIME::QuotedPrint::decode($message)
1641                 if ($from eq 'quoted-printable');
1642         $message = MIME::Base64::decode($message)
1643                 if ($from eq 'base64');
1644
1645         die "cannot send message as 7bit"
1646                 if ($to eq '7bit' and $message =~ /[^[:ascii:]]/);
1647         return $message
1648                 if ($to eq '7bit' or $to eq '8bit');
1649         return MIME::QuotedPrint::encode($message, "\n", 0)
1650                 if ($to eq 'quoted-printable');
1651         return MIME::Base64::encode($message, "\n")
1652                 if ($to eq 'base64');
1653         die "invalid transfer encoding";
1654 }
1655
1656 sub unique_email_list {
1657         my %seen;
1658         my @emails;
1659
1660         foreach my $entry (@_) {
1661                 my $clean = extract_valid_address_or_die($entry);
1662                 $seen{$clean} ||= 0;
1663                 next if $seen{$clean}++;
1664                 push @emails, $entry;
1665         }
1666         return @emails;
1667 }
1668
1669 sub validate_patch {
1670         my $fn = shift;
1671         open(my $fh, '<', $fn)
1672                 or die "unable to open $fn: $!\n";
1673         while (my $line = <$fh>) {
1674                 if (length($line) > 998) {
1675                         return "$.: patch contains a line longer than 998 characters";
1676                 }
1677         }
1678         return;
1679 }
1680
1681 sub file_has_nonascii {
1682         my $fn = shift;
1683         open(my $fh, '<', $fn)
1684                 or die "unable to open $fn: $!\n";
1685         while (my $line = <$fh>) {
1686                 return 1 if $line =~ /[^[:ascii:]]/;
1687         }
1688         return 0;
1689 }
1690
1691 sub body_or_subject_has_nonascii {
1692         my $fn = shift;
1693         open(my $fh, '<', $fn)
1694                 or die "unable to open $fn: $!\n";
1695         while (my $line = <$fh>) {
1696                 last if $line =~ /^$/;
1697                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1698         }
1699         while (my $line = <$fh>) {
1700                 return 1 if $line =~ /[^[:ascii:]]/;
1701         }
1702         return 0;
1703 }