git.oblomov.eu Git - git/blob - contrib/completion/git-completion.zsh

   1 #compdef git gitk
   2
   3 # zsh completion wrapper for git
   4 #
   5 # Copyright (c) 2012-2013 Felipe Contreras <felipe.contreras@gmail.com>
   6 #
   7 # You need git's bash completion script installed somewhere, by default it
   8 # would be the location bash-completion uses.
   9 #
  10 # If your script is somewhere else, you can configure it on your ~/.zshrc:
  11 #
  12 #  zstyle ':completion:*:*:git:*' script ~/.git-completion.zsh
  13 #
  14 # The recommended way to install this script is to copy to '~/.zsh/_git', and
  15 # then add the following to your ~/.zshrc file:
  16 #
  17 #  fpath=(~/.zsh $fpath)
  18
  19 complete ()
  20 {
  21         # do nothing
  22         return 0
  23 }
  24
  25 zstyle -T ':completion:*:*:git:*' tag-order && \
  26         zstyle ':completion:*:*:git:*' tag-order 'common-commands'
  27
  28 zstyle -s ":completion:*:*:git:*" script script
  29 if [ -z "$script" ]; then
  30         local -a locations
  31         local e
  32         locations=(
  33                 $(dirname ${funcsourcetrace[1]%:*})/git-completion.bash
  34                 '/etc/bash_completion.d/git' # fedora, old debian
  35                 '/usr/share/bash-completion/completions/git' # arch, ubuntu, new debian
  36                 '/usr/share/bash-completion/git' # gentoo
  37                 )
  38         for e in $locations; do
  39                 test -f $e && script="$e" && break
  40         done
  41 fi
  42 ZSH_VERSION='' . "$script"
  43
  44 __gitcomp ()
  45 {
  46         emulate -L zsh
  47
  48         local cur_="${3-$cur}"
  49
  50         case "$cur_" in
  51         --*=)
  52                 ;;
  53         *)
  54                 local c IFS=$' \t\n'
  55                 local -a array
  56                 for c in ${=1}; do
  57                         c="$c${4-}"
  58                         case $c in
  59                         --*=*|*.) ;;
  60                         *) c="$c " ;;
  61                         esac
  62                         array+=("$c")
  63                 done
  64                 compset -P '*[=:]'
  65                 compadd -Q -S '' -p "${2-}" -a -- array && _ret=0
  66                 ;;
  67         esac
  68 }
  69
  70 __gitcomp_direct ()
  71 {
  72         emulate -L zsh
  73
  74         local IFS=$'\n'
  75         compset -P '*[=:]'
  76         compadd -Q -- ${=1} && _ret=0
  77 }
  78
  79 __gitcomp_nl ()
  80 {
  81         emulate -L zsh
  82
  83         local IFS=$'\n'
  84         compset -P '*[=:]'
  85         compadd -Q -S "${4- }" -p "${2-}" -- ${=1} && _ret=0
  86 }
  87
  88 __gitcomp_nl_append ()
  89 {
  90         emulate -L zsh
  91
  92         local IFS=$'\n'
  93         compadd -Q -S "${4- }" -p "${2-}" -- ${=1} && _ret=0
  94 }
  95
  96 __gitcomp_file ()
  97 {
  98         emulate -L zsh
  99
 100         local IFS=$'\n'
 101         compset -P '*[=:]'
 102         compadd -Q -p "${2-}" -f -- ${=1} && _ret=0
 103 }
 104
 105 __git_zsh_bash_func ()
 106 {
 107         emulate -L ksh
 108
 109         local command=$1
 110
 111         local completion_func="_git_${command//-/_}"
 112         declare -f $completion_func >/dev/null && $completion_func && return
 113
 114         local expansion=$(__git_aliased_command "$command")
 115         if [ -n "$expansion" ]; then
 116                 words[1]=$expansion
 117                 completion_func="_git_${expansion//-/_}"
 118                 declare -f $completion_func >/dev/null && $completion_func
 119         fi
 120 }
 121
 122 __git_zsh_cmd_common ()
 123 {
 124         local -a list
 125         list=(
 126         add:'add file contents to the index'
 127         bisect:'find by binary search the change that introduced a bug'
 128         branch:'list, create, or delete branches'
 129         checkout:'checkout a branch or paths to the working tree'
 130         clone:'clone a repository into a new directory'
 131         commit:'record changes to the repository'
 132         diff:'show changes between commits, commit and working tree, etc'
 133         fetch:'download objects and refs from another repository'
 134         grep:'print lines matching a pattern'
 135         init:'create an empty Git repository or reinitialize an existing one'
 136         log:'show commit logs'
 137         merge:'join two or more development histories together'
 138         mv:'move or rename a file, a directory, or a symlink'
 139         pull:'fetch from and merge with another repository or a local branch'
 140         push:'update remote refs along with associated objects'
 141         rebase:'forward-port local commits to the updated upstream head'
 142         reset:'reset current HEAD to the specified state'
 143         rm:'remove files from the working tree and from the index'
 144         show:'show various types of objects'
 145         status:'show the working tree status'
 146         tag:'create, list, delete or verify a tag object signed with GPG')
 147         _describe -t common-commands 'common commands' list && _ret=0
 148 }
 149
 150 __git_zsh_cmd_alias ()
 151 {
 152         local -a list
 153         list=(${${${(0)"$(git config -z --get-regexp '^alias\.')"}#alias.}%$'\n'*})
 154         _describe -t alias-commands 'aliases' list $* && _ret=0
 155 }
 156
 157 __git_zsh_cmd_all ()
 158 {
 159         local -a list
 160         emulate ksh -c __git_compute_all_commands
 161         list=( ${=__git_all_commands} )
 162         _describe -t all-commands 'all commands' list && _ret=0
 163 }
 164
 165 __git_zsh_main ()
 166 {
 167         local curcontext="$curcontext" state state_descr line
 168         typeset -A opt_args
 169         local -a orig_words
 170
 171         orig_words=( ${words[@]} )
 172
 173         _arguments -C \
 174                 '(-p --paginate --no-pager)'{-p,--paginate}'[pipe all output into ''less'']' \
 175                 '(-p --paginate)--no-pager[do not pipe git output into a pager]' \
 176                 '--git-dir=-[set the path to the repository]: :_directories' \
 177                 '--bare[treat the repository as a bare repository]' \
 178                 '(- :)--version[prints the git suite version]' \
 179                 '--exec-path=-[path to where your core git programs are installed]:: :_directories' \
 180                 '--html-path[print the path where git''s HTML documentation is installed]' \
 181                 '--info-path[print the path where the Info files are installed]' \
 182                 '--man-path[print the manpath (see `man(1)`) for the man pages]' \
 183                 '--work-tree=-[set the path to the working tree]: :_directories' \
 184                 '--namespace=-[set the git namespace]' \
 185                 '--no-replace-objects[do not use replacement refs to replace git objects]' \
 186                 '(- :)--help[prints the synopsis and a list of the most commonly used commands]: :->arg' \
 187                 '(-): :->command' \
 188                 '(-)*:: :->arg' && return
 189
 190         case $state in
 191         (command)
 192                 _alternative \
 193                          'alias-commands:alias:__git_zsh_cmd_alias' \
 194                          'common-commands:common:__git_zsh_cmd_common' \
 195                          'all-commands:all:__git_zsh_cmd_all' && _ret=0
 196                 ;;
 197         (arg)
 198                 local command="${words[1]}" __git_dir
 199
 200                 if (( $+opt_args[--bare] )); then
 201                         __git_dir='.'
 202                 else
 203                         __git_dir=${opt_args[--git-dir]}
 204                 fi
 205
 206                 (( $+opt_args[--help] )) && command='help'
 207
 208                 words=( ${orig_words[@]} )
 209
 210                 __git_zsh_bash_func $command
 211                 ;;
 212         esac
 213 }
 214
 215 _git ()
 216 {
 217         local _ret=1
 218         local cur cword prev
 219
 220         cur=${words[CURRENT]}
 221         prev=${words[CURRENT-1]}
 222         let cword=CURRENT-1
 223
 224         if (( $+functions[__${service}_zsh_main] )); then
 225                 __${service}_zsh_main
 226         else
 227                 emulate ksh -c __${service}_main
 228         fi
 229
 230         let _ret && _default && _ret=0
 231         return _ret
 232 }
 233
 234 _git