git.oblomov.eu Git - git/blob - contrib/mw-to-git/git-remote-mediawiki.perl

   1 #! /usr/bin/perl
   2
   3 # Copyright (C) 2011
   4 #     Jérémie Nikaes <jeremie.nikaes@ensimag.imag.fr>
   5 #     Arnaud Lacurie <arnaud.lacurie@ensimag.imag.fr>
   6 #     Claire Fousse <claire.fousse@ensimag.imag.fr>
   7 #     David Amouyal <david.amouyal@ensimag.imag.fr>
   8 #     Matthieu Moy <matthieu.moy@grenoble-inp.fr>
   9 # License: GPL v2 or later
  10
  11 # Gateway between Git and MediaWiki.
  12 # Documentation & bugtracker: https://github.com/moy/Git-Mediawiki/
  13
  14 use strict;
  15 use MediaWiki::API;
  16 use Git;
  17 use DateTime::Format::ISO8601;
  18 use warnings;
  19
  20 # By default, use UTF-8 to communicate with Git and the user
  21 binmode STDERR, ':encoding(UTF-8)';
  22 binmode STDOUT, ':encoding(UTF-8)';
  23
  24 use URI::Escape;
  25
  26 # Mediawiki filenames can contain forward slashes. This variable decides by which pattern they should be replaced
  27 use constant SLASH_REPLACEMENT => '%2F';
  28
  29 # It's not always possible to delete pages (may require some
  30 # privileges). Deleted pages are replaced with this content.
  31 use constant DELETED_CONTENT => "[[Category:Deleted]]\n";
  32
  33 # It's not possible to create empty pages. New empty files in Git are
  34 # sent with this content instead.
  35 use constant EMPTY_CONTENT => "<!-- empty page -->\n";
  36
  37 # used to reflect file creation or deletion in diff.
  38 use constant NULL_SHA1 => '0000000000000000000000000000000000000000';
  39
  40 # Used on Git's side to reflect empty edit messages on the wiki
  41 use constant EMPTY_MESSAGE => '*Empty MediaWiki Message*';
  42
  43 use constant EMPTY => q{};
  44
  45 # Number of pages taken into account at once in submodule get_mw_page_list
  46 use constant SLICE_SIZE => 50;
  47
  48 # Number of linked mediafile to get at once in get_linked_mediafiles
  49 # The query is split in small batches because of the MW API limit of
  50 # the number of links to be returned (500 links max).
  51 use constant BATCH_SIZE => 10;
  52
  53 use constant HTTP_CODE_OK => 200;
  54
  55 my $remotename = $ARGV[0];
  56 my $url = $ARGV[1];
  57
  58 # Accept both space-separated and multiple keys in config file.
  59 # Spaces should be written as _ anyway because we'll use chomp.
  60 my @tracked_pages = split(/[ \n]/, run_git("config --get-all remote.${remotename}.pages"));
  61 chomp(@tracked_pages);
  62
  63 # Just like @tracked_pages, but for MediaWiki categories.
  64 my @tracked_categories = split(/[ \n]/, run_git("config --get-all remote.${remotename}.categories"));
  65 chomp(@tracked_categories);
  66
  67 # Import media files on pull
  68 my $import_media = run_git("config --get --bool remote.${remotename}.mediaimport");
  69 chomp($import_media);
  70 $import_media = ($import_media eq 'true');
  71
  72 # Export media files on push
  73 my $export_media = run_git("config --get --bool remote.${remotename}.mediaexport");
  74 chomp($export_media);
  75 $export_media = !($export_media eq 'false');
  76
  77 my $wiki_login = run_git("config --get remote.${remotename}.mwLogin");
  78 # Note: mwPassword is discourraged. Use the credential system instead.
  79 my $wiki_passwd = run_git("config --get remote.${remotename}.mwPassword");
  80 my $wiki_domain = run_git("config --get remote.${remotename}.mwDomain");
  81 chomp($wiki_login);
  82 chomp($wiki_passwd);
  83 chomp($wiki_domain);
  84
  85 # Import only last revisions (both for clone and fetch)
  86 my $shallow_import = run_git("config --get --bool remote.${remotename}.shallow");
  87 chomp($shallow_import);
  88 $shallow_import = ($shallow_import eq 'true');
  89
  90 # Fetch (clone and pull) by revisions instead of by pages. This behavior
  91 # is more efficient when we have a wiki with lots of pages and we fetch
  92 # the revisions quite often so that they concern only few pages.
  93 # Possible values:
  94 # - by_rev: perform one query per new revision on the remote wiki
  95 # - by_page: query each tracked page for new revision
  96 my $fetch_strategy = run_git("config --get remote.${remotename}.fetchStrategy");
  97 if (!$fetch_strategy) {
  98         $fetch_strategy = run_git('config --get mediawiki.fetchStrategy');
  99 }
 100 chomp($fetch_strategy);
 101 if (!$fetch_strategy) {
 102         $fetch_strategy = 'by_page';
 103 }
 104
 105 # Remember the timestamp corresponding to a revision id.
 106 my %basetimestamps;
 107
 108 # Dumb push: don't update notes and mediawiki ref to reflect the last push.
 109 #
 110 # Configurable with mediawiki.dumbPush, or per-remote with
 111 # remote.<remotename>.dumbPush.
 112 #
 113 # This means the user will have to re-import the just-pushed
 114 # revisions. On the other hand, this means that the Git revisions
 115 # corresponding to MediaWiki revisions are all imported from the wiki,
 116 # regardless of whether they were initially created in Git or from the
 117 # web interface, hence all users will get the same history (i.e. if
 118 # the push from Git to MediaWiki loses some information, everybody
 119 # will get the history with information lost). If the import is
 120 # deterministic, this means everybody gets the same sha1 for each
 121 # MediaWiki revision.
 122 my $dumb_push = run_git("config --get --bool remote.${remotename}.dumbPush");
 123 if (!$dumb_push) {
 124         $dumb_push = run_git('config --get --bool mediawiki.dumbPush');
 125 }
 126 chomp($dumb_push);
 127 $dumb_push = ($dumb_push eq 'true');
 128
 129 my $wiki_name = $url;
 130 $wiki_name =~ s{[^/]*://}{};
 131 # If URL is like http://user:password@example.com/, we clearly don't
 132 # want the password in $wiki_name. While we're there, also remove user
 133 # and '@' sign, to avoid author like MWUser@HTTPUser@host.com
 134 $wiki_name =~ s/^.*@//;
 135
 136 # Commands parser
 137 while (<STDIN>) {
 138         chomp;
 139
 140         if (!parse_command($_)) {
 141                 last;
 142         }
 143
 144         BEGIN { $| = 1 } # flush STDOUT, to make sure the previous
 145                          # command is fully processed.
 146 }
 147
 148 ########################## Functions ##############################
 149
 150 sub parse_command {
 151         my ($line) = @_;
 152         my @cmd = split(/ /, $line);
 153         if (!defined $cmd[0]) {
 154                 return 0;
 155         }
 156         if ($cmd[0] eq 'capabilities') {
 157                 die("Too many arguments for capabilities\n")
 158                     if (defined($cmd[1]));
 159                 mw_capabilities();
 160         } elsif ($cmd[0] eq 'list') {
 161                 die("Too many arguments for list\n") if (defined($cmd[2]));
 162                 mw_list($cmd[1]);
 163         } elsif ($cmd[0] eq 'import') {
 164                 die("Invalid argument for import\n")
 165                     if ($cmd[1] eq EMPTY);
 166                 die("Too many arguments for import\n")
 167                     if (defined($cmd[2]));
 168                 mw_import($cmd[1]);
 169         } elsif ($cmd[0] eq 'option') {
 170                 die("Invalid arguments for option\n")
 171                     if ($cmd[1] eq EMPTY || $cmd[2] eq EMPTY);
 172                 die("Too many arguments for option\n")
 173                     if (defined($cmd[3]));
 174                 mw_option($cmd[1],$cmd[2]);
 175         } elsif ($cmd[0] eq 'push') {
 176                 mw_push($cmd[1]);
 177         } else {
 178                 print {*STDERR} "Unknown command. Aborting...\n";
 179                 return 0;
 180         }
 181         return 1;
 182 }
 183
 184 # MediaWiki API instance, created lazily.
 185 my $mediawiki;
 186
 187 sub mw_connect_maybe {
 188         if ($mediawiki) {
 189                 return;
 190         }
 191         $mediawiki = MediaWiki::API->new;
 192         $mediawiki->{config}->{api_url} = "${url}/api.php";
 193         if ($wiki_login) {
 194                 my %credential = (
 195                         'url' => $url,
 196                         'username' => $wiki_login,
 197                         'password' => $wiki_passwd
 198                 );
 199                 Git::credential(\%credential);
 200                 my $request = {lgname => $credential{username},
 201                                lgpassword => $credential{password},
 202                                lgdomain => $wiki_domain};
 203                 if ($mediawiki->login($request)) {
 204                         Git::credential(\%credential, 'approve');
 205                         print {*STDERR} qq(Logged in mediawiki user "$credential{username}".\n);
 206                 } else {
 207                         print {*STDERR} qq(Failed to log in mediawiki user "$credential{username}" on ${url}\n);
 208                         print {*STDERR} '  (error ' .
 209                                 $mediawiki->{error}->{code} . ': ' .
 210                                 $mediawiki->{error}->{details} . ")\n";
 211                         Git::credential(\%credential, 'reject');
 212                         exit 1;
 213                 }
 214         }
 215         return;
 216 }
 217
 218 sub fatal_mw_error {
 219         my $action = shift;
 220         print STDERR "fatal: could not $action.\n";
 221         print STDERR "fatal: '$url' does not appear to be a mediawiki\n";
 222         if ($url =~ /^https/) {
 223                 print STDERR "fatal: make sure '$url/api.php' is a valid page\n";
 224                 print STDERR "fatal: and the SSL certificate is correct.\n";
 225         } else {
 226                 print STDERR "fatal: make sure '$url/api.php' is a valid page.\n";
 227         }
 228         print STDERR "fatal: (error " .
 229             $mediawiki->{error}->{code} . ': ' .
 230             $mediawiki->{error}->{details} . ")\n";
 231         exit 1;
 232 }
 233
 234 ## Functions for listing pages on the remote wiki
 235 sub get_mw_tracked_pages {
 236         my $pages = shift;
 237         get_mw_page_list(\@tracked_pages, $pages);
 238         return;
 239 }
 240
 241 sub get_mw_page_list {
 242         my $page_list = shift;
 243         my $pages = shift;
 244         my @some_pages = @{$page_list};
 245         while (@some_pages) {
 246                 my $last_page = SLICE_SIZE;
 247                 if ($#some_pages < $last_page) {
 248                         $last_page = $#some_pages;
 249                 }
 250                 my @slice = @some_pages[0..$last_page];
 251                 get_mw_first_pages(\@slice, $pages);
 252                 @some_pages = @some_pages[(SLICE_SIZE + 1)..$#some_pages];
 253         }
 254         return;
 255 }
 256
 257 sub get_mw_tracked_categories {
 258         my $pages = shift;
 259         foreach my $category (@tracked_categories) {
 260                 if (index($category, ':') < 0) {
 261                         # Mediawiki requires the Category
 262                         # prefix, but let's not force the user
 263                         # to specify it.
 264                         $category = "Category:${category}";
 265                 }
 266                 my $mw_pages = $mediawiki->list( {
 267                         action => 'query',
 268                         list => 'categorymembers',
 269                         cmtitle => $category,
 270                         cmlimit => 'max' } )
 271                         || die $mediawiki->{error}->{code} . ': '
 272                                 . $mediawiki->{error}->{details} . "\n";
 273                 foreach my $page (@{$mw_pages}) {
 274                         $pages->{$page->{title}} = $page;
 275                 }
 276         }
 277         return;
 278 }
 279
 280 sub get_mw_all_pages {
 281         my $pages = shift;
 282         # No user-provided list, get the list of pages from the API.
 283         my $mw_pages = $mediawiki->list({
 284                 action => 'query',
 285                 list => 'allpages',
 286                 aplimit => 'max'
 287         });
 288         if (!defined($mw_pages)) {
 289                 fatal_mw_error("get the list of wiki pages");
 290         }
 291         foreach my $page (@{$mw_pages}) {
 292                 $pages->{$page->{title}} = $page;
 293         }
 294         return;
 295 }
 296
 297 # queries the wiki for a set of pages. Meant to be used within a loop
 298 # querying the wiki for slices of page list.
 299 sub get_mw_first_pages {
 300         my $some_pages = shift;
 301         my @some_pages = @{$some_pages};
 302
 303         my $pages = shift;
 304
 305         # pattern 'page1|page2|...' required by the API
 306         my $titles = join('|', @some_pages);
 307
 308         my $mw_pages = $mediawiki->api({
 309                 action => 'query',
 310                 titles => $titles,
 311         });
 312         if (!defined($mw_pages)) {
 313                 fatal_mw_error("query the list of wiki pages");
 314         }
 315         while (my ($id, $page) = each(%{$mw_pages->{query}->{pages}})) {
 316                 if ($id < 0) {
 317                         print {*STDERR} "Warning: page $page->{title} not found on wiki\n";
 318                 } else {
 319                         $pages->{$page->{title}} = $page;
 320                 }
 321         }
 322         return;
 323 }
 324
 325 # Get the list of pages to be fetched according to configuration.
 326 sub get_mw_pages {
 327         mw_connect_maybe();
 328
 329         print {*STDERR} "Listing pages on remote wiki...\n";
 330
 331         my %pages; # hash on page titles to avoid duplicates
 332         my $user_defined;
 333         if (@tracked_pages) {
 334                 $user_defined = 1;
 335                 # The user provided a list of pages titles, but we
 336                 # still need to query the API to get the page IDs.
 337                 get_mw_tracked_pages(\%pages);
 338         }
 339         if (@tracked_categories) {
 340                 $user_defined = 1;
 341                 get_mw_tracked_categories(\%pages);
 342         }
 343         if (!$user_defined) {
 344                 get_mw_all_pages(\%pages);
 345         }
 346         if ($import_media) {
 347                 print {*STDERR} "Getting media files for selected pages...\n";
 348                 if ($user_defined) {
 349                         get_linked_mediafiles(\%pages);
 350                 } else {
 351                         get_all_mediafiles(\%pages);
 352                 }
 353         }
 354         print {*STDERR} (scalar keys %pages) . " pages found.\n";
 355         return %pages;
 356 }
 357
 358 # usage: $out = run_git("command args");
 359 #        $out = run_git("command args", "raw"); # don't interpret output as UTF-8.
 360 sub run_git {
 361         my $args = shift;
 362         my $encoding = (shift || 'encoding(UTF-8)');
 363         open(my $git, "-|:${encoding}", "git ${args}")
 364             or die "Unable to fork: $!\n";
 365         my $res = do {
 366                 local $/ = undef;
 367                 <$git>
 368         };
 369         close($git);
 370
 371         return $res;
 372 }
 373
 374
 375 sub get_all_mediafiles {
 376         my $pages = shift;
 377         # Attach list of all pages for media files from the API,
 378         # they are in a different namespace, only one namespace
 379         # can be queried at the same moment
 380         my $mw_pages = $mediawiki->list({
 381                 action => 'query',
 382                 list => 'allpages',
 383                 apnamespace => get_mw_namespace_id('File'),
 384                 aplimit => 'max'
 385         });
 386         if (!defined($mw_pages)) {
 387                 print {*STDERR} "fatal: could not get the list of pages for media files.\n";
 388                 print {*STDERR} "fatal: '$url' does not appear to be a mediawiki\n";
 389                 print {*STDERR} "fatal: make sure '$url/api.php' is a valid page.\n";
 390                 exit 1;
 391         }
 392         foreach my $page (@{$mw_pages}) {
 393                 $pages->{$page->{title}} = $page;
 394         }
 395         return;
 396 }
 397
 398 sub get_linked_mediafiles {
 399         my $pages = shift;
 400         my @titles = map { $_->{title} } values(%{$pages});
 401
 402         my $batch = BATCH_SIZE;
 403         while (@titles) {
 404                 if ($#titles < $batch) {
 405                         $batch = $#titles;
 406                 }
 407                 my @slice = @titles[0..$batch];
 408
 409                 # pattern 'page1|page2|...' required by the API
 410                 my $mw_titles = join('|', @slice);
 411
 412                 # Media files could be included or linked from
 413                 # a page, get all related
 414                 my $query = {
 415                         action => 'query',
 416                         prop => 'links|images',
 417                         titles => $mw_titles,
 418                         plnamespace => get_mw_namespace_id('File'),
 419                         pllimit => 'max'
 420                 };
 421                 my $result = $mediawiki->api($query);
 422
 423                 while (my ($id, $page) = each(%{$result->{query}->{pages}})) {
 424                         my @media_titles;
 425                         if (defined($page->{links})) {
 426                                 my @link_titles
 427                                     = map { $_->{title} } @{$page->{links}};
 428                                 push(@media_titles, @link_titles);
 429                         }
 430                         if (defined($page->{images})) {
 431                                 my @image_titles
 432                                     = map { $_->{title} } @{$page->{images}};
 433                                 push(@media_titles, @image_titles);
 434                         }
 435                         if (@media_titles) {
 436                                 get_mw_page_list(\@media_titles, $pages);
 437                         }
 438                 }
 439
 440                 @titles = @titles[($batch+1)..$#titles];
 441         }
 442         return;
 443 }
 444
 445 sub get_mw_mediafile_for_page_revision {
 446         # Name of the file on Wiki, with the prefix.
 447         my $filename = shift;
 448         my $timestamp = shift;
 449         my %mediafile;
 450
 451         # Search if on a media file with given timestamp exists on
 452         # MediaWiki. In that case download the file.
 453         my $query = {
 454                 action => 'query',
 455                 prop => 'imageinfo',
 456                 titles => "File:${filename}",
 457                 iistart => $timestamp,
 458                 iiend => $timestamp,
 459                 iiprop => 'timestamp|archivename|url',
 460                 iilimit => 1
 461         };
 462         my $result = $mediawiki->api($query);
 463
 464         my ($fileid, $file) = each( %{$result->{query}->{pages}} );
 465         # If not defined it means there is no revision of the file for
 466         # given timestamp.
 467         if (defined($file->{imageinfo})) {
 468                 $mediafile{title} = $filename;
 469
 470                 my $fileinfo = pop(@{$file->{imageinfo}});
 471                 $mediafile{timestamp} = $fileinfo->{timestamp};
 472                 # Mediawiki::API's download function doesn't support https URLs
 473                 # and can't download old versions of files.
 474                 print {*STDERR} "\tDownloading file $mediafile{title}, version $mediafile{timestamp}\n";
 475                 $mediafile{content} = download_mw_mediafile($fileinfo->{url});
 476         }
 477         return %mediafile;
 478 }
 479
 480 sub download_mw_mediafile {
 481         my $download_url = shift;
 482
 483         my $response = $mediawiki->{ua}->get($download_url);
 484         if ($response->code == HTTP_CODE_OK) {
 485                 return $response->decoded_content;
 486         } else {
 487                 print {*STDERR} "Error downloading mediafile from :\n";
 488                 print {*STDERR} "URL: ${download_url}\n";
 489                 print {*STDERR} 'Server response: ' . $response->code . q{ } . $response->message . "\n";
 490                 exit 1;
 491         }
 492 }
 493
 494 sub get_last_local_revision {
 495         # Get note regarding last mediawiki revision
 496         my $note = run_git("notes --ref=${remotename}/mediawiki show refs/mediawiki/${remotename}/master 2>/dev/null");
 497         my @note_info = split(/ /, $note);
 498
 499         my $lastrevision_number;
 500         if (!(defined($note_info[0]) && $note_info[0] eq 'mediawiki_revision:')) {
 501                 print {*STDERR} 'No previous mediawiki revision found';
 502                 $lastrevision_number = 0;
 503         } else {
 504                 # Notes are formatted : mediawiki_revision: #number
 505                 $lastrevision_number = $note_info[1];
 506                 chomp($lastrevision_number);
 507                 print {*STDERR} "Last local mediawiki revision found is ${lastrevision_number}";
 508         }
 509         return $lastrevision_number;
 510 }
 511
 512 # Get the last remote revision without taking in account which pages are
 513 # tracked or not. This function makes a single request to the wiki thus
 514 # avoid a loop onto all tracked pages. This is useful for the fetch-by-rev
 515 # option.
 516 sub get_last_global_remote_rev {
 517         mw_connect_maybe();
 518
 519         my $query = {
 520                 action => 'query',
 521                 list => 'recentchanges',
 522                 prop => 'revisions',
 523                 rclimit => '1',
 524                 rcdir => 'older',
 525         };
 526         my $result = $mediawiki->api($query);
 527         return $result->{query}->{recentchanges}[0]->{revid};
 528 }
 529
 530 # Get the last remote revision concerning the tracked pages and the tracked
 531 # categories.
 532 sub get_last_remote_revision {
 533         mw_connect_maybe();
 534
 535         my %pages_hash = get_mw_pages();
 536         my @pages = values(%pages_hash);
 537
 538         my $max_rev_num = 0;
 539
 540         print {*STDERR} "Getting last revision id on tracked pages...\n";
 541
 542         foreach my $page (@pages) {
 543                 my $id = $page->{pageid};
 544
 545                 my $query = {
 546                         action => 'query',
 547                         prop => 'revisions',
 548                         rvprop => 'ids|timestamp',
 549                         pageids => $id,
 550                 };
 551
 552                 my $result = $mediawiki->api($query);
 553
 554                 my $lastrev = pop(@{$result->{query}->{pages}->{$id}->{revisions}});
 555
 556                 $basetimestamps{$lastrev->{revid}} = $lastrev->{timestamp};
 557
 558                 $max_rev_num = ($lastrev->{revid} > $max_rev_num ? $lastrev->{revid} : $max_rev_num);
 559         }
 560
 561         print {*STDERR} "Last remote revision found is $max_rev_num.\n";
 562         return $max_rev_num;
 563 }
 564
 565 # Clean content before sending it to MediaWiki
 566 sub mediawiki_clean {
 567         my $string = shift;
 568         my $page_created = shift;
 569         # Mediawiki does not allow blank space at the end of a page and ends with a single \n.
 570         # This function right trims a string and adds a \n at the end to follow this rule
 571         $string =~ s/\s+$//;
 572         if ($string eq EMPTY && $page_created) {
 573                 # Creating empty pages is forbidden.
 574                 $string = EMPTY_CONTENT;
 575         }
 576         return $string."\n";
 577 }
 578
 579 # Filter applied on MediaWiki data before adding them to Git
 580 sub mediawiki_smudge {
 581         my $string = shift;
 582         if ($string eq EMPTY_CONTENT) {
 583                 $string = EMPTY;
 584         }
 585         # This \n is important. This is due to mediawiki's way to handle end of files.
 586         return "${string}\n";
 587 }
 588
 589 sub mediawiki_clean_filename {
 590         my $filename = shift;
 591         $filename =~ s{@{[SLASH_REPLACEMENT]}}{/}g;
 592         # [, ], |, {, and } are forbidden by MediaWiki, even URL-encoded.
 593         # Do a variant of URL-encoding, i.e. looks like URL-encoding,
 594         # but with _ added to prevent MediaWiki from thinking this is
 595         # an actual special character.
 596         $filename =~ s/[\[\]\{\}\|]/sprintf("_%%_%x", ord($&))/ge;
 597         # If we use the uri escape before
 598         # we should unescape here, before anything
 599
 600         return $filename;
 601 }
 602
 603 sub mediawiki_smudge_filename {
 604         my $filename = shift;
 605         $filename =~ s{/}{@{[SLASH_REPLACEMENT]}}g;
 606         $filename =~ s/ /_/g;
 607         # Decode forbidden characters encoded in mediawiki_clean_filename
 608         $filename =~ s/_%_([0-9a-fA-F][0-9a-fA-F])/sprintf('%c', hex($1))/ge;
 609         return $filename;
 610 }
 611
 612 sub literal_data {
 613         my ($content) = @_;
 614         print {*STDOUT} 'data ', bytes::length($content), "\n", $content;
 615         return;
 616 }
 617
 618 sub literal_data_raw {
 619         # Output possibly binary content.
 620         my ($content) = @_;
 621         # Avoid confusion between size in bytes and in characters
 622         utf8::downgrade($content);
 623         binmode {*STDOUT}, ':raw';
 624         print {*STDOUT} 'data ', bytes::length($content), "\n", $content;
 625         binmode {*STDOUT}, ':encoding(UTF-8)';
 626         return;
 627 }
 628
 629 sub mw_capabilities {
 630         # Revisions are imported to the private namespace
 631         # refs/mediawiki/$remotename/ by the helper and fetched into
 632         # refs/remotes/$remotename later by fetch.
 633         print {*STDOUT} "refspec refs/heads/*:refs/mediawiki/${remotename}/*\n";
 634         print {*STDOUT} "import\n";
 635         print {*STDOUT} "list\n";
 636         print {*STDOUT} "push\n";
 637         print {*STDOUT} "\n";
 638         return;
 639 }
 640
 641 sub mw_list {
 642         # MediaWiki do not have branches, we consider one branch arbitrarily
 643         # called master, and HEAD pointing to it.
 644         print {*STDOUT} "? refs/heads/master\n";
 645         print {*STDOUT} "\@refs/heads/master HEAD\n";
 646         print {*STDOUT} "\n";
 647         return;
 648 }
 649
 650 sub mw_option {
 651         print {*STDERR} "remote-helper command 'option $_[0]' not yet implemented\n";
 652         print {*STDOUT} "unsupported\n";
 653         return;
 654 }
 655
 656 sub fetch_mw_revisions_for_page {
 657         my $page = shift;
 658         my $id = shift;
 659         my $fetch_from = shift;
 660         my @page_revs = ();
 661         my $query = {
 662                 action => 'query',
 663                 prop => 'revisions',
 664                 rvprop => 'ids',
 665                 rvdir => 'newer',
 666                 rvstartid => $fetch_from,
 667                 rvlimit => 500,
 668                 pageids => $id,
 669         };
 670
 671         my $revnum = 0;
 672         # Get 500 revisions at a time due to the mediawiki api limit
 673         while (1) {
 674                 my $result = $mediawiki->api($query);
 675
 676                 # Parse each of those 500 revisions
 677                 foreach my $revision (@{$result->{query}->{pages}->{$id}->{revisions}}) {
 678                         my $page_rev_ids;
 679                         $page_rev_ids->{pageid} = $page->{pageid};
 680                         $page_rev_ids->{revid} = $revision->{revid};
 681                         push(@page_revs, $page_rev_ids);
 682                         $revnum++;
 683                 }
 684                 last if (!$result->{'query-continue'});
 685                 $query->{rvstartid} = $result->{'query-continue'}->{revisions}->{rvstartid};
 686         }
 687         if ($shallow_import && @page_revs) {
 688                 print {*STDERR} "  Found 1 revision (shallow import).\n";
 689                 @page_revs = sort {$b->{revid} <=> $a->{revid}} (@page_revs);
 690                 return $page_revs[0];
 691         }
 692         print {*STDERR} "  Found ${revnum} revision(s).\n";
 693         return @page_revs;
 694 }
 695
 696 sub fetch_mw_revisions {
 697         my $pages = shift; my @pages = @{$pages};
 698         my $fetch_from = shift;
 699
 700         my @revisions = ();
 701         my $n = 1;
 702         foreach my $page (@pages) {
 703                 my $id = $page->{pageid};
 704                 print {*STDERR} "page ${n}/", scalar(@pages), ': ', $page->{title}, "\n";
 705                 $n++;
 706                 my @page_revs = fetch_mw_revisions_for_page($page, $id, $fetch_from);
 707                 @revisions = (@page_revs, @revisions);
 708         }
 709
 710         return ($n, @revisions);
 711 }
 712
 713 sub fe_escape_path {
 714     my $path = shift;
 715     $path =~ s/\\/\\\\/g;
 716     $path =~ s/"/\\"/g;
 717     $path =~ s/\n/\\n/g;
 718     return qq("${path}");
 719 }
 720
 721 sub import_file_revision {
 722         my $commit = shift;
 723         my %commit = %{$commit};
 724         my $full_import = shift;
 725         my $n = shift;
 726         my $mediafile = shift;
 727         my %mediafile;
 728         if ($mediafile) {
 729                 %mediafile = %{$mediafile};
 730         }
 731
 732         my $title = $commit{title};
 733         my $comment = $commit{comment};
 734         my $content = $commit{content};
 735         my $author = $commit{author};
 736         my $date = $commit{date};
 737
 738         print {*STDOUT} "commit refs/mediawiki/${remotename}/master\n";
 739         print {*STDOUT} "mark :${n}\n";
 740         print {*STDOUT} "committer ${author} <${author}\@${wiki_name}> " . $date->epoch . " +0000\n";
 741         literal_data($comment);
 742
 743         # If it's not a clone, we need to know where to start from
 744         if (!$full_import && $n == 1) {
 745                 print {*STDOUT} "from refs/mediawiki/${remotename}/master^0\n";
 746         }
 747         if ($content ne DELETED_CONTENT) {
 748                 print {*STDOUT} 'M 644 inline ' .
 749                     fe_escape_path("${title}.mw") . "\n";
 750                 literal_data($content);
 751                 if (%mediafile) {
 752                         print {*STDOUT} 'M 644 inline '
 753                             . fe_escape_path($mediafile{title}) . "\n";
 754                         literal_data_raw($mediafile{content});
 755                 }
 756                 print {*STDOUT} "\n\n";
 757         } else {
 758                 print {*STDOUT} 'D ' . fe_escape_path("${title}.mw") . "\n";
 759         }
 760
 761         # mediawiki revision number in the git note
 762         if ($full_import && $n == 1) {
 763                 print {*STDOUT} "reset refs/notes/${remotename}/mediawiki\n";
 764         }
 765         print {*STDOUT} "commit refs/notes/${remotename}/mediawiki\n";
 766         print {*STDOUT} "committer ${author} <${author}\@${wiki_name}> " . $date->epoch . " +0000\n";
 767         literal_data('Note added by git-mediawiki during import');
 768         if (!$full_import && $n == 1) {
 769                 print {*STDOUT} "from refs/notes/${remotename}/mediawiki^0\n";
 770         }
 771         print {*STDOUT} "N inline :${n}\n";
 772         literal_data("mediawiki_revision: $commit{mw_revision}");
 773         print {*STDOUT} "\n\n";
 774         return;
 775 }
 776
 777 # parse a sequence of
 778 # <cmd> <arg1>
 779 # <cmd> <arg2>
 780 # \n
 781 # (like batch sequence of import and sequence of push statements)
 782 sub get_more_refs {
 783         my $cmd = shift;
 784         my @refs;
 785         while (1) {
 786                 my $line = <STDIN>;
 787                 if ($line =~ /^$cmd (.*)$/) {
 788                         push(@refs, $1);
 789                 } elsif ($line eq "\n") {
 790                         return @refs;
 791                 } else {
 792                         die("Invalid command in a '$cmd' batch: $_\n");
 793                 }
 794         }
 795         return;
 796 }
 797
 798 sub mw_import {
 799         # multiple import commands can follow each other.
 800         my @refs = (shift, get_more_refs('import'));
 801         foreach my $ref (@refs) {
 802                 mw_import_ref($ref);
 803         }
 804         print {*STDOUT} "done\n";
 805         return;
 806 }
 807
 808 sub mw_import_ref {
 809         my $ref = shift;
 810         # The remote helper will call "import HEAD" and
 811         # "import refs/heads/master".
 812         # Since HEAD is a symbolic ref to master (by convention,
 813         # followed by the output of the command "list" that we gave),
 814         # we don't need to do anything in this case.
 815         if ($ref eq 'HEAD') {
 816                 return;
 817         }
 818
 819         mw_connect_maybe();
 820
 821         print {*STDERR} "Searching revisions...\n";
 822         my $last_local = get_last_local_revision();
 823         my $fetch_from = $last_local + 1;
 824         if ($fetch_from == 1) {
 825                 print {*STDERR} ", fetching from beginning.\n";
 826         } else {
 827                 print {*STDERR} ", fetching from here.\n";
 828         }
 829
 830         my $n = 0;
 831         if ($fetch_strategy eq 'by_rev') {
 832                 print {*STDERR} "Fetching & writing export data by revs...\n";
 833                 $n = mw_import_ref_by_revs($fetch_from);
 834         } elsif ($fetch_strategy eq 'by_page') {
 835                 print {*STDERR} "Fetching & writing export data by pages...\n";
 836                 $n = mw_import_ref_by_pages($fetch_from);
 837         } else {
 838                 print {*STDERR} qq(fatal: invalid fetch strategy "${fetch_strategy}".\n);
 839                 print {*STDERR} "Check your configuration variables remote.${remotename}.fetchStrategy and mediawiki.fetchStrategy\n";
 840                 exit 1;
 841         }
 842
 843         if ($fetch_from == 1 && $n == 0) {
 844                 print {*STDERR} "You appear to have cloned an empty MediaWiki.\n";
 845                 # Something has to be done remote-helper side. If nothing is done, an error is
 846                 # thrown saying that HEAD is referring to unknown object 0000000000000000000
 847                 # and the clone fails.
 848         }
 849         return;
 850 }
 851
 852 sub mw_import_ref_by_pages {
 853
 854         my $fetch_from = shift;
 855         my %pages_hash = get_mw_pages();
 856         my @pages = values(%pages_hash);
 857
 858         my ($n, @revisions) = fetch_mw_revisions(\@pages, $fetch_from);
 859
 860         @revisions = sort {$a->{revid} <=> $b->{revid}} @revisions;
 861         my @revision_ids = map { $_->{revid} } @revisions;
 862
 863         return mw_import_revids($fetch_from, \@revision_ids, \%pages_hash);
 864 }
 865
 866 sub mw_import_ref_by_revs {
 867
 868         my $fetch_from = shift;
 869         my %pages_hash = get_mw_pages();
 870
 871         my $last_remote = get_last_global_remote_rev();
 872         my @revision_ids = $fetch_from..$last_remote;
 873         return mw_import_revids($fetch_from, \@revision_ids, \%pages_hash);
 874 }
 875
 876 # Import revisions given in second argument (array of integers).
 877 # Only pages appearing in the third argument (hash indexed by page titles)
 878 # will be imported.
 879 sub mw_import_revids {
 880         my $fetch_from = shift;
 881         my $revision_ids = shift;
 882         my $pages = shift;
 883
 884         my $n = 0;
 885         my $n_actual = 0;
 886         my $last_timestamp = 0; # Placeholer in case $rev->timestamp is undefined
 887
 888         foreach my $pagerevid (@{$revision_ids}) {
 889                 # Count page even if we skip it, since we display
 890                 # $n/$total and $total includes skipped pages.
 891                 $n++;
 892
 893                 # fetch the content of the pages
 894                 my $query = {
 895                         action => 'query',
 896                         prop => 'revisions',
 897                         rvprop => 'content|timestamp|comment|user|ids',
 898                         revids => $pagerevid,
 899                 };
 900
 901                 my $result = $mediawiki->api($query);
 902
 903                 if (!$result) {
 904                         die "Failed to retrieve modified page for revision $pagerevid\n";
 905                 }
 906
 907                 if (defined($result->{query}->{badrevids}->{$pagerevid})) {
 908                         # The revision id does not exist on the remote wiki.
 909                         next;
 910                 }
 911
 912                 if (!defined($result->{query}->{pages})) {
 913                         die "Invalid revision ${pagerevid}.\n";
 914                 }
 915
 916                 my @result_pages = values(%{$result->{query}->{pages}});
 917                 my $result_page = $result_pages[0];
 918                 my $rev = $result_pages[0]->{revisions}->[0];
 919
 920                 my $page_title = $result_page->{title};
 921
 922                 if (!exists($pages->{$page_title})) {
 923                         print {*STDERR} "${n}/", scalar(@{$revision_ids}),
 924                                 ": Skipping revision #$rev->{revid} of ${page_title}\n";
 925                         next;
 926                 }
 927
 928                 $n_actual++;
 929
 930                 my %commit;
 931                 $commit{author} = $rev->{user} || 'Anonymous';
 932                 $commit{comment} = $rev->{comment} || EMPTY_MESSAGE;
 933                 $commit{title} = mediawiki_smudge_filename($page_title);
 934                 $commit{mw_revision} = $rev->{revid};
 935                 $commit{content} = mediawiki_smudge($rev->{'*'});
 936
 937                 if (!defined($rev->{timestamp})) {
 938                         $last_timestamp++;
 939                 } else {
 940                         $last_timestamp = $rev->{timestamp};
 941                 }
 942                 $commit{date} = DateTime::Format::ISO8601->parse_datetime($last_timestamp);
 943
 944                 # Differentiates classic pages and media files.
 945                 my ($namespace, $filename) = $page_title =~ /^([^:]*):(.*)$/;
 946                 my %mediafile;
 947                 if ($namespace) {
 948                         my $id = get_mw_namespace_id($namespace);
 949                         if ($id && $id == get_mw_namespace_id('File')) {
 950                                 %mediafile = get_mw_mediafile_for_page_revision($filename, $rev->{timestamp});
 951                         }
 952                 }
 953                 # If this is a revision of the media page for new version
 954                 # of a file do one common commit for both file and media page.
 955                 # Else do commit only for that page.
 956                 print {*STDERR} "${n}/", scalar(@{$revision_ids}), ": Revision #$rev->{revid} of $commit{title}\n";
 957                 import_file_revision(\%commit, ($fetch_from == 1), $n_actual, \%mediafile);
 958         }
 959
 960         return $n_actual;
 961 }
 962
 963 sub error_non_fast_forward {
 964         my $advice = run_git('config --bool advice.pushNonFastForward');
 965         chomp($advice);
 966         if ($advice ne 'false') {
 967                 # Native git-push would show this after the summary.
 968                 # We can't ask it to display it cleanly, so print it
 969                 # ourselves before.
 970                 print {*STDERR} "To prevent you from losing history, non-fast-forward updates were rejected\n";
 971                 print {*STDERR} "Merge the remote changes (e.g. 'git pull') before pushing again. See the\n";
 972                 print {*STDERR} "'Note about fast-forwards' section of 'git push --help' for details.\n";
 973         }
 974         print {*STDOUT} qq(error $_[0] "non-fast-forward"\n);
 975         return 0;
 976 }
 977
 978 sub mw_upload_file {
 979         my $complete_file_name = shift;
 980         my $new_sha1 = shift;
 981         my $extension = shift;
 982         my $file_deleted = shift;
 983         my $summary = shift;
 984         my $newrevid;
 985         my $path = "File:${complete_file_name}";
 986         my %hashFiles = get_allowed_file_extensions();
 987         if (!exists($hashFiles{$extension})) {
 988                 print {*STDERR} "${complete_file_name} is not a permitted file on this wiki.\n";
 989                 print {*STDERR} "Check the configuration of file uploads in your mediawiki.\n";
 990                 return $newrevid;
 991         }
 992         # Deleting and uploading a file requires a priviledged user
 993         if ($file_deleted) {
 994                 mw_connect_maybe();
 995                 my $query = {
 996                         action => 'delete',
 997                         title => $path,
 998                         reason => $summary
 999                 };
1000                 if (!$mediawiki->edit($query)) {
1001                         print {*STDERR} "Failed to delete file on remote wiki\n";
1002                         print {*STDERR} "Check your permissions on the remote site. Error code:\n";
1003                         print {*STDERR} $mediawiki->{error}->{code} . ':' . $mediawiki->{error}->{details};
1004                         exit 1;
1005                 }
1006         } else {
1007                 # Don't let perl try to interpret file content as UTF-8 => use "raw"
1008                 my $content = run_git("cat-file blob ${new_sha1}", 'raw');
1009                 if ($content ne EMPTY) {
1010                         mw_connect_maybe();
1011                         $mediawiki->{config}->{upload_url} =
1012                                 "${url}/index.php/Special:Upload";
1013                         $mediawiki->edit({
1014                                 action => 'upload',
1015                                 filename => $complete_file_name,
1016                                 comment => $summary,
1017                                 file => [undef,
1018                                          $complete_file_name,
1019                                          Content => $content],
1020                                 ignorewarnings => 1,
1021                         }, {
1022                                 skip_encoding => 1
1023                         } ) || die $mediawiki->{error}->{code} . ':'
1024                                  . $mediawiki->{error}->{details} . "\n";
1025                         my $last_file_page = $mediawiki->get_page({title => $path});
1026                         $newrevid = $last_file_page->{revid};
1027                         print {*STDERR} "Pushed file: ${new_sha1} - ${complete_file_name}.\n";
1028                 } else {
1029                         print {*STDERR} "Empty file ${complete_file_name} not pushed.\n";
1030                 }
1031         }
1032         return $newrevid;
1033 }
1034
1035 sub mw_push_file {
1036         my $diff_info = shift;
1037         # $diff_info contains a string in this format:
1038         # 100644 100644 <sha1_of_blob_before_commit> <sha1_of_blob_now> <status>
1039         my @diff_info_split = split(/[ \t]/, $diff_info);
1040
1041         # Filename, including .mw extension
1042         my $complete_file_name = shift;
1043         # Commit message
1044         my $summary = shift;
1045         # MediaWiki revision number. Keep the previous one by default,
1046         # in case there's no edit to perform.
1047         my $oldrevid = shift;
1048         my $newrevid;
1049
1050         if ($summary eq EMPTY_MESSAGE) {
1051                 $summary = EMPTY;
1052         }
1053
1054         my $new_sha1 = $diff_info_split[3];
1055         my $old_sha1 = $diff_info_split[2];
1056         my $page_created = ($old_sha1 eq NULL_SHA1);
1057         my $page_deleted = ($new_sha1 eq NULL_SHA1);
1058         $complete_file_name = mediawiki_clean_filename($complete_file_name);
1059
1060         my ($title, $extension) = $complete_file_name =~ /^(.*)\.([^\.]*)$/;
1061         if (!defined($extension)) {
1062                 $extension = EMPTY;
1063         }
1064         if ($extension eq 'mw') {
1065                 my $ns = get_mw_namespace_id_for_page($complete_file_name);
1066                 if ($ns && $ns == get_mw_namespace_id('File') && (!$export_media)) {
1067                         print {*STDERR} "Ignoring media file related page: ${complete_file_name}\n";
1068                         return ($oldrevid, 'ok');
1069                 }
1070                 my $file_content;
1071                 if ($page_deleted) {
1072                         # Deleting a page usually requires
1073                         # special privileges. A common
1074                         # convention is to replace the page
1075                         # with this content instead:
1076                         $file_content = DELETED_CONTENT;
1077                 } else {
1078                         $file_content = run_git("cat-file blob ${new_sha1}");
1079                 }
1080
1081                 mw_connect_maybe();
1082
1083                 my $result = $mediawiki->edit( {
1084                         action => 'edit',
1085                         summary => $summary,
1086                         title => $title,
1087                         basetimestamp => $basetimestamps{$oldrevid},
1088                         text => mediawiki_clean($file_content, $page_created),
1089                                   }, {
1090                                           skip_encoding => 1 # Helps with names with accentuated characters
1091                                   });
1092                 if (!$result) {
1093                         if ($mediawiki->{error}->{code} == 3) {
1094                                 # edit conflicts, considered as non-fast-forward
1095                                 print {*STDERR} 'Warning: Error ' .
1096                                     $mediawiki->{error}->{code} .
1097                                     ' from mediawiki: ' . $mediawiki->{error}->{details} .
1098                                     ".\n";
1099                                 return ($oldrevid, 'non-fast-forward');
1100                         } else {
1101                                 # Other errors. Shouldn't happen => just die()
1102                                 die 'Fatal: Error ' .
1103                                     $mediawiki->{error}->{code} .
1104                                     ' from mediawiki: ' . $mediawiki->{error}->{details} . "\n";
1105                         }
1106                 }
1107                 $newrevid = $result->{edit}->{newrevid};
1108                 print {*STDERR} "Pushed file: ${new_sha1} - ${title}\n";
1109         } elsif ($export_media) {
1110                 $newrevid = mw_upload_file($complete_file_name, $new_sha1,
1111                                            $extension, $page_deleted,
1112                                            $summary);
1113         } else {
1114                 print {*STDERR} "Ignoring media file ${title}\n";
1115         }
1116         $newrevid = ($newrevid or $oldrevid);
1117         return ($newrevid, 'ok');
1118 }
1119
1120 sub mw_push {
1121         # multiple push statements can follow each other
1122         my @refsspecs = (shift, get_more_refs('push'));
1123         my $pushed;
1124         for my $refspec (@refsspecs) {
1125                 my ($force, $local, $remote) = $refspec =~ /^(\+)?([^:]*):([^:]*)$/
1126                     or die("Invalid refspec for push. Expected <src>:<dst> or +<src>:<dst>\n");
1127                 if ($force) {
1128                         print {*STDERR} "Warning: forced push not allowed on a MediaWiki.\n";
1129                 }
1130                 if ($local eq EMPTY) {
1131                         print {*STDERR} "Cannot delete remote branch on a MediaWiki\n";
1132                         print {*STDOUT} "error ${remote} cannot delete\n";
1133                         next;
1134                 }
1135                 if ($remote ne 'refs/heads/master') {
1136                         print {*STDERR} "Only push to the branch 'master' is supported on a MediaWiki\n";
1137                         print {*STDOUT} "error ${remote} only master allowed\n";
1138                         next;
1139                 }
1140                 if (mw_push_revision($local, $remote)) {
1141                         $pushed = 1;
1142                 }
1143         }
1144
1145         # Notify Git that the push is done
1146         print {*STDOUT} "\n";
1147
1148         if ($pushed && $dumb_push) {
1149                 print {*STDERR} "Just pushed some revisions to MediaWiki.\n";
1150                 print {*STDERR} "The pushed revisions now have to be re-imported, and your current branch\n";
1151                 print {*STDERR} "needs to be updated with these re-imported commits. You can do this with\n";
1152                 print {*STDERR} "\n";
1153                 print {*STDERR} "  git pull --rebase\n";
1154                 print {*STDERR} "\n";
1155         }
1156         return;
1157 }
1158
1159 sub mw_push_revision {
1160         my $local = shift;
1161         my $remote = shift; # actually, this has to be "refs/heads/master" at this point.
1162         my $last_local_revid = get_last_local_revision();
1163         print {*STDERR} ".\n"; # Finish sentence started by get_last_local_revision()
1164         my $last_remote_revid = get_last_remote_revision();
1165         my $mw_revision = $last_remote_revid;
1166
1167         # Get sha1 of commit pointed by local HEAD
1168         my $HEAD_sha1 = run_git("rev-parse ${local} 2>/dev/null");
1169         chomp($HEAD_sha1);
1170         # Get sha1 of commit pointed by remotes/$remotename/master
1171         my $remoteorigin_sha1 = run_git("rev-parse refs/remotes/${remotename}/master 2>/dev/null");
1172         chomp($remoteorigin_sha1);
1173
1174         if ($last_local_revid > 0 &&
1175             $last_local_revid < $last_remote_revid) {
1176                 return error_non_fast_forward($remote);
1177         }
1178
1179         if ($HEAD_sha1 eq $remoteorigin_sha1) {
1180                 # nothing to push
1181                 return 0;
1182         }
1183
1184         # Get every commit in between HEAD and refs/remotes/origin/master,
1185         # including HEAD and refs/remotes/origin/master
1186         my @commit_pairs = ();
1187         if ($last_local_revid > 0) {
1188                 my $parsed_sha1 = $remoteorigin_sha1;
1189                 # Find a path from last MediaWiki commit to pushed commit
1190                 print {*STDERR} "Computing path from local to remote ...\n";
1191                 my @local_ancestry = split(/\n/, run_git("rev-list --boundary --parents ${local} ^${parsed_sha1}"));
1192                 my %local_ancestry;
1193                 foreach my $line (@local_ancestry) {
1194                         if (my ($child, $parents) = $line =~ /^-?([a-f0-9]+) ([a-f0-9 ]+)/) {
1195                                 foreach my $parent (split(/ /, $parents)) {
1196                                         $local_ancestry{$parent} = $child;
1197                                 }
1198                         } elsif (!$line =~ /^([a-f0-9]+)/) {
1199                                 die "Unexpected output from git rev-list: ${line}\n";
1200                         }
1201                 }
1202                 while ($parsed_sha1 ne $HEAD_sha1) {
1203                         my $child = $local_ancestry{$parsed_sha1};
1204                         if (!$child) {
1205                                 print {*STDERR} "Cannot find a path in history from remote commit to last commit\n";
1206                                 return error_non_fast_forward($remote);
1207                         }
1208                         push(@commit_pairs, [$parsed_sha1, $child]);
1209                         $parsed_sha1 = $child;
1210                 }
1211         } else {
1212                 # No remote mediawiki revision. Export the whole
1213                 # history (linearized with --first-parent)
1214                 print {*STDERR} "Warning: no common ancestor, pushing complete history\n";
1215                 my $history = run_git("rev-list --first-parent --children ${local}");
1216                 my @history = split(/\n/, $history);
1217                 @history = @history[1..$#history];
1218                 foreach my $line (reverse @history) {
1219                         my @commit_info_split = split(/[ \n]/, $line);
1220                         push(@commit_pairs, \@commit_info_split);
1221                 }
1222         }
1223
1224         foreach my $commit_info_split (@commit_pairs) {
1225                 my $sha1_child = @{$commit_info_split}[0];
1226                 my $sha1_commit = @{$commit_info_split}[1];
1227                 my $diff_infos = run_git("diff-tree -r --raw -z ${sha1_child} ${sha1_commit}");
1228                 # TODO: we could detect rename, and encode them with a #redirect on the wiki.
1229                 # TODO: for now, it's just a delete+add
1230                 my @diff_info_list = split(/\0/, $diff_infos);
1231                 # Keep the subject line of the commit message as mediawiki comment for the revision
1232                 my $commit_msg = run_git(qq(log --no-walk --format="%s" ${sha1_commit}));
1233                 chomp($commit_msg);
1234                 # Push every blob
1235                 while (@diff_info_list) {
1236                         my $status;
1237                         # git diff-tree -z gives an output like
1238                         # <metadata>\0<filename1>\0
1239                         # <metadata>\0<filename2>\0
1240                         # and we've split on \0.
1241                         my $info = shift(@diff_info_list);
1242                         my $file = shift(@diff_info_list);
1243                         ($mw_revision, $status) = mw_push_file($info, $file, $commit_msg, $mw_revision);
1244                         if ($status eq 'non-fast-forward') {
1245                                 # we may already have sent part of the
1246                                 # commit to MediaWiki, but it's too
1247                                 # late to cancel it. Stop the push in
1248                                 # the middle, but still give an
1249                                 # accurate error message.
1250                                 return error_non_fast_forward($remote);
1251                         }
1252                         if ($status ne 'ok') {
1253                                 die("Unknown error from mw_push_file()\n");
1254                         }
1255                 }
1256                 if (!$dumb_push) {
1257                         run_git(qq(notes --ref=${remotename}/mediawiki add -f -m "mediawiki_revision: ${mw_revision}" ${sha1_commit}));
1258                         run_git(qq(update-ref -m "Git-MediaWiki push" refs/mediawiki/${remotename}/master ${sha1_commit} ${sha1_child}));
1259                 }
1260         }
1261
1262         print {*STDOUT} "ok ${remote}\n";
1263         return 1;
1264 }
1265
1266 sub get_allowed_file_extensions {
1267         mw_connect_maybe();
1268
1269         my $query = {
1270                 action => 'query',
1271                 meta => 'siteinfo',
1272                 siprop => 'fileextensions'
1273                 };
1274         my $result = $mediawiki->api($query);
1275         my @file_extensions = map { $_->{ext}} @{$result->{query}->{fileextensions}};
1276         my %hashFile = map { $_ => 1 } @file_extensions;
1277
1278         return %hashFile;
1279 }
1280
1281 # In memory cache for MediaWiki namespace ids.
1282 my %namespace_id;
1283
1284 # Namespaces whose id is cached in the configuration file
1285 # (to avoid duplicates)
1286 my %cached_mw_namespace_id;
1287
1288 # Return MediaWiki id for a canonical namespace name.
1289 # Ex.: "File", "Project".
1290 sub get_mw_namespace_id {
1291         mw_connect_maybe();
1292         my $name = shift;
1293
1294         if (!exists $namespace_id{$name}) {
1295                 # Look at configuration file, if the record for that namespace is
1296                 # already cached. Namespaces are stored in form:
1297                 # "Name_of_namespace:Id_namespace", ex.: "File:6".
1298                 my @temp = split(/\n/,
1299                                  run_git("config --get-all remote.${remotename}.namespaceCache"));
1300                 chomp(@temp);
1301                 foreach my $ns (@temp) {
1302                         my ($n, $id) = split(/:/, $ns);
1303                         if ($id eq 'notANameSpace') {
1304                                 $namespace_id{$n} = {is_namespace => 0};
1305                         } else {
1306                                 $namespace_id{$n} = {is_namespace => 1, id => $id};
1307                         }
1308                         $cached_mw_namespace_id{$n} = 1;
1309                 }
1310         }
1311
1312         if (!exists $namespace_id{$name}) {
1313                 print {*STDERR} "Namespace ${name} not found in cache, querying the wiki ...\n";
1314                 # NS not found => get namespace id from MW and store it in
1315                 # configuration file.
1316                 my $query = {
1317                         action => 'query',
1318                         meta => 'siteinfo',
1319                         siprop => 'namespaces'
1320                 };
1321                 my $result = $mediawiki->api($query);
1322
1323                 while (my ($id, $ns) = each(%{$result->{query}->{namespaces}})) {
1324                         if (defined($ns->{id}) && defined($ns->{canonical})) {
1325                                 $namespace_id{$ns->{canonical}} = {is_namespace => 1, id => $ns->{id}};
1326                                 if ($ns->{'*'}) {
1327                                         # alias (e.g. french Fichier: as alias for canonical File:)
1328                                         $namespace_id{$ns->{'*'}} = {is_namespace => 1, id => $ns->{id}};
1329                                 }
1330                         }
1331                 }
1332         }
1333
1334         my $ns = $namespace_id{$name};
1335         my $id;
1336
1337         if (!defined $ns) {
1338                 print {*STDERR} "No such namespace ${name} on MediaWiki.\n";
1339                 $ns = {is_namespace => 0};
1340                 $namespace_id{$name} = $ns;
1341         }
1342
1343         if ($ns->{is_namespace}) {
1344                 $id = $ns->{id};
1345         }
1346
1347         # Store "notANameSpace" as special value for inexisting namespaces
1348         my $store_id = ($id || 'notANameSpace');
1349
1350         # Store explicitely requested namespaces on disk
1351         if (!exists $cached_mw_namespace_id{$name}) {
1352                 run_git(qq(config --add remote.${remotename}.namespaceCache "${name}:${store_id}"));
1353                 $cached_mw_namespace_id{$name} = 1;
1354         }
1355         return $id;
1356 }
1357
1358 sub get_mw_namespace_id_for_page {
1359         my $namespace = shift;
1360         if ($namespace =~ /^([^:]*):/) {
1361                 return get_mw_namespace_id($namespace);
1362         } else {
1363                 return;
1364         }
1365 }