git.oblomov.eu Git - git/blob - git-cvsimport.perl

   1 #!/usr/bin/perl -w
   2
   3 # This tool is copyright (c) 2005, Matthias Urlichs.
   4 # It is released under the Gnu Public License, version 2.
   5 #
   6 # The basic idea is to aggregate CVS check-ins into related changes.
   7 # Fortunately, "cvsps" does that for us; all we have to do is to parse
   8 # its output.
   9 #
  10 # Checking out the files is done by a single long-running CVS connection
  11 # / server process.
  12 #
  13 # The head revision is on branch "origin" by default.
  14 # You can change that with the '-o' option.
  15
  16 use strict;
  17 use warnings;
  18 use Getopt::Std;
  19 use File::Spec;
  20 use File::Temp qw(tempfile tmpnam);
  21 use File::Path qw(mkpath);
  22 use File::Basename qw(basename dirname);
  23 use Time::Local;
  24 use IO::Socket;
  25 use IO::Pipe;
  26 use POSIX qw(strftime dup2 ENOENT);
  27 use IPC::Open2;
  28
  29 $SIG{'PIPE'}="IGNORE";
  30 $ENV{'TZ'}="UTC";
  31
  32 our ($opt_h,$opt_o,$opt_v,$opt_k,$opt_u,$opt_d,$opt_p,$opt_C,$opt_z,$opt_i,$opt_P, $opt_s,$opt_m,$opt_M,$opt_A,$opt_S,$opt_L, $opt_a, $opt_r);
  33 my (%conv_author_name, %conv_author_email);
  34
  35 sub usage(;$) {
  36         my $msg = shift;
  37         print(STDERR "Error: $msg\n") if $msg;
  38         print STDERR <<END;
  39 Usage: ${\basename $0}     # fetch/update GIT from CVS
  40        [-o branch-for-HEAD] [-h] [-v] [-d CVSROOT] [-A author-conv-file]
  41        [-p opts-for-cvsps] [-P file] [-C GIT_repository] [-z fuzz] [-i] [-k]
  42        [-u] [-s subst] [-a] [-m] [-M regex] [-S regex] [-L commitlimit]
  43        [-r remote] [CVS_module]
  44 END
  45         exit(1);
  46 }
  47
  48 sub read_author_info($) {
  49         my ($file) = @_;
  50         my $user;
  51         open my $f, '<', "$file" or die("Failed to open $file: $!\n");
  52
  53         while (<$f>) {
  54                 # Expected format is this:
  55                 #   exon=Andreas Ericsson <ae@op5.se>
  56                 if (m/^(\S+?)\s*=\s*(.+?)\s*<(.+)>\s*$/) {
  57                         $user = $1;
  58                         $conv_author_name{$user} = $2;
  59                         $conv_author_email{$user} = $3;
  60                 }
  61                 # However, we also read from CVSROOT/users format
  62                 # to ease migration.
  63                 elsif (/^(\w+):(['"]?)(.+?)\2\s*$/) {
  64                         my $mapped;
  65                         ($user, $mapped) = ($1, $3);
  66                         if ($mapped =~ /^\s*(.*?)\s*<(.*)>\s*$/) {
  67                                 $conv_author_name{$user} = $1;
  68                                 $conv_author_email{$user} = $2;
  69                         }
  70                         elsif ($mapped =~ /^<?(.*)>?$/) {
  71                                 $conv_author_name{$user} = $user;
  72                                 $conv_author_email{$user} = $1;
  73                         }
  74                 }
  75                 # NEEDSWORK: Maybe warn on unrecognized lines?
  76         }
  77         close ($f);
  78 }
  79
  80 sub write_author_info($) {
  81         my ($file) = @_;
  82         open my $f, '>', $file or
  83           die("Failed to open $file for writing: $!");
  84
  85         foreach (keys %conv_author_name) {
  86                 print $f "$_=$conv_author_name{$_} <$conv_author_email{$_}>\n";
  87         }
  88         close ($f);
  89 }
  90
  91 # convert getopts specs for use by git-repo-config
  92 sub read_repo_config {
  93     # Split the string between characters, unless there is a ':'
  94     # So "abc:de" becomes ["a", "b", "c:", "d", "e"]
  95         my @opts = split(/ *(?!:)/, shift);
  96         foreach my $o (@opts) {
  97                 my $key = $o;
  98                 $key =~ s/://g;
  99                 my $arg = 'git-repo-config';
 100                 $arg .= ' --bool' if ($o !~ /:$/);
 101
 102         chomp(my $tmp = `$arg --get cvsimport.$key`);
 103                 if ($tmp && !($arg =~ /--bool/ && $tmp eq 'false')) {
 104             no strict 'refs';
 105             my $opt_name = "opt_" . $key;
 106             if (!$$opt_name) {
 107                 $$opt_name = $tmp;
 108             }
 109                 }
 110         }
 111     if (@ARGV == 0) {
 112         chomp(my $module = `git-repo-config --get cvsimport.module`);
 113         push(@ARGV, $module);
 114     }
 115 }
 116
 117 my $opts = "haivmkuo:d:p:r:C:z:s:M:P:A:S:L:";
 118 read_repo_config($opts);
 119 getopts($opts) or usage();
 120 usage if $opt_h;
 121
 122 @ARGV <= 1 or usage("You can't specify more than one CVS module");
 123
 124 if ($opt_d) {
 125         $ENV{"CVSROOT"} = $opt_d;
 126 } elsif (-f 'CVS/Root') {
 127         open my $f, '<', 'CVS/Root' or die 'Failed to open CVS/Root';
 128         $opt_d = <$f>;
 129         chomp $opt_d;
 130         close $f;
 131         $ENV{"CVSROOT"} = $opt_d;
 132 } elsif ($ENV{"CVSROOT"}) {
 133         $opt_d = $ENV{"CVSROOT"};
 134 } else {
 135         usage("CVSROOT needs to be set");
 136 }
 137 $opt_s ||= "-";
 138 $opt_a ||= 0;
 139
 140 my $git_tree = $opt_C;
 141 $git_tree ||= ".";
 142
 143 my $remote;
 144 if (defined $opt_r) {
 145         $remote = 'refs/remotes/' . $opt_r;
 146         $opt_o ||= "master";
 147 } else {
 148         $opt_o ||= "origin";
 149         $remote = 'refs/heads';
 150 }
 151
 152 my $cvs_tree;
 153 if ($#ARGV == 0) {
 154         $cvs_tree = $ARGV[0];
 155 } elsif (-f 'CVS/Repository') {
 156         open my $f, '<', 'CVS/Repository' or
 157             die 'Failed to open CVS/Repository';
 158         $cvs_tree = <$f>;
 159         chomp $cvs_tree;
 160         close $f;
 161 } else {
 162         usage("CVS module has to be specified");
 163 }
 164
 165 our @mergerx = ();
 166 if ($opt_m) {
 167         @mergerx = ( qr/\W(?:from|of|merge|merging|merged) (\w+)/i );
 168 }
 169 if ($opt_M) {
 170         push (@mergerx, qr/$opt_M/);
 171 }
 172
 173 # Remember UTC of our starting time
 174 # we'll want to avoid importing commits
 175 # that are too recent
 176 our $starttime = time();
 177
 178 select(STDERR); $|=1; select(STDOUT);
 179
 180
 181 package CVSconn;
 182 # Basic CVS dialog.
 183 # We're only interested in connecting and downloading, so ...
 184
 185 use File::Spec;
 186 use File::Temp qw(tempfile);
 187 use POSIX qw(strftime dup2);
 188
 189 sub new {
 190         my ($what,$repo,$subdir) = @_;
 191         $what=ref($what) if ref($what);
 192
 193         my $self = {};
 194         $self->{'buffer'} = "";
 195         bless($self,$what);
 196
 197         $repo =~ s#/+$##;
 198         $self->{'fullrep'} = $repo;
 199         $self->conn();
 200
 201         $self->{'subdir'} = $subdir;
 202         $self->{'lines'} = undef;
 203
 204         return $self;
 205 }
 206
 207 sub conn {
 208         my $self = shift;
 209         my $repo = $self->{'fullrep'};
 210         if ($repo =~ s/^:pserver(?:([^:]*)):(?:(.*?)(?::(.*?))?@)?([^:\/]*)(?::(\d*))?//) {
 211                 my ($param,$user,$pass,$serv,$port) = ($1,$2,$3,$4,$5);
 212
 213                 my ($proxyhost,$proxyport);
 214                 if ($param && ($param =~ m/proxy=([^;]+)/)) {
 215                         $proxyhost = $1;
 216                         # Default proxyport, if not specified, is 8080.
 217                         $proxyport = 8080;
 218                         if ($ENV{"CVS_PROXY_PORT"}) {
 219                                 $proxyport = $ENV{"CVS_PROXY_PORT"};
 220                         }
 221                         if ($param =~ m/proxyport=([^;]+)/) {
 222                                 $proxyport = $1;
 223                         }
 224                 }
 225
 226                 $user="anonymous" unless defined $user;
 227                 my $rr2 = "-";
 228                 unless ($port) {
 229                         $rr2 = ":pserver:$user\@$serv:$repo";
 230                         $port=2401;
 231                 }
 232                 my $rr = ":pserver:$user\@$serv:$port$repo";
 233
 234                 unless ($pass) {
 235                         open(H,$ENV{'HOME'}."/.cvspass") and do {
 236                                 # :pserver:cvs@mea.tmt.tele.fi:/cvsroot/zmailer Ah<Z
 237                                 while (<H>) {
 238                                         chomp;
 239                                         s/^\/\d+\s+//;
 240                                         my ($w,$p) = split(/\s/,$_,2);
 241                                         if ($w eq $rr or $w eq $rr2) {
 242                                                 $pass = $p;
 243                                                 last;
 244                                         }
 245                                 }
 246                         };
 247                 }
 248                 $pass="A" unless $pass;
 249
 250                 my ($s, $rep);
 251                 if ($proxyhost) {
 252
 253                         # Use a HTTP Proxy. Only works for HTTP proxies that
 254                         # don't require user authentication
 255                         #
 256                         # See: http://www.ietf.org/rfc/rfc2817.txt
 257
 258                         $s = IO::Socket::INET->new(PeerHost => $proxyhost, PeerPort => $proxyport);
 259                         die "Socket to $proxyhost: $!\n" unless defined $s;
 260                         $s->write("CONNECT $serv:$port HTTP/1.1\r\nHost: $serv:$port\r\n\r\n")
 261                                 or die "Write to $proxyhost: $!\n";
 262                         $s->flush();
 263
 264                         $rep = <$s>;
 265
 266                         # The answer should look like 'HTTP/1.x 2yy ....'
 267                         if (!($rep =~ m#^HTTP/1\.. 2[0-9][0-9]#)) {
 268                                 die "Proxy connect: $rep\n";
 269                         }
 270                         # Skip up to the empty line of the proxy server output
 271                         # including the response headers.
 272                         while ($rep = <$s>) {
 273                                 last if (!defined $rep ||
 274                                          $rep eq "\n" ||
 275                                          $rep eq "\r\n");
 276                         }
 277                 } else {
 278                         $s = IO::Socket::INET->new(PeerHost => $serv, PeerPort => $port);
 279                         die "Socket to $serv: $!\n" unless defined $s;
 280                 }
 281
 282                 $s->write("BEGIN AUTH REQUEST\n$repo\n$user\n$pass\nEND AUTH REQUEST\n")
 283                         or die "Write to $serv: $!\n";
 284                 $s->flush();
 285
 286                 $rep = <$s>;
 287
 288                 if ($rep ne "I LOVE YOU\n") {
 289                         $rep="<unknown>" unless $rep;
 290                         die "AuthReply: $rep\n";
 291                 }
 292                 $self->{'socketo'} = $s;
 293                 $self->{'socketi'} = $s;
 294         } else { # local or ext: Fork off our own cvs server.
 295                 my $pr = IO::Pipe->new();
 296                 my $pw = IO::Pipe->new();
 297                 my $pid = fork();
 298                 die "Fork: $!\n" unless defined $pid;
 299                 my $cvs = 'cvs';
 300                 $cvs = $ENV{CVS_SERVER} if exists $ENV{CVS_SERVER};
 301                 my $rsh = 'rsh';
 302                 $rsh = $ENV{CVS_RSH} if exists $ENV{CVS_RSH};
 303
 304                 my @cvs = ($cvs, 'server');
 305                 my ($local, $user, $host);
 306                 $local = $repo =~ s/:local://;
 307                 if (!$local) {
 308                     $repo =~ s/:ext://;
 309                     $local = !($repo =~ s/^(?:([^\@:]+)\@)?([^:]+)://);
 310                     ($user, $host) = ($1, $2);
 311                 }
 312                 if (!$local) {
 313                     if ($user) {
 314                         unshift @cvs, $rsh, '-l', $user, $host;
 315                     } else {
 316                         unshift @cvs, $rsh, $host;
 317                     }
 318                 }
 319
 320                 unless ($pid) {
 321                         $pr->writer();
 322                         $pw->reader();
 323                         dup2($pw->fileno(),0);
 324                         dup2($pr->fileno(),1);
 325                         $pr->close();
 326                         $pw->close();
 327                         exec(@cvs);
 328                 }
 329                 $pw->writer();
 330                 $pr->reader();
 331                 $self->{'socketo'} = $pw;
 332                 $self->{'socketi'} = $pr;
 333         }
 334         $self->{'socketo'}->write("Root $repo\n");
 335
 336         # Trial and error says that this probably is the minimum set
 337         $self->{'socketo'}->write("Valid-responses ok error Valid-requests Mode M Mbinary E Checked-in Created Updated Merged Removed\n");
 338
 339         $self->{'socketo'}->write("valid-requests\n");
 340         $self->{'socketo'}->flush();
 341
 342         chomp(my $rep=$self->readline());
 343         if ($rep !~ s/^Valid-requests\s*//) {
 344                 $rep="<unknown>" unless $rep;
 345                 die "Expected Valid-requests from server, but got: $rep\n";
 346         }
 347         chomp(my $res=$self->readline());
 348         die "validReply: $res\n" if $res ne "ok";
 349
 350         $self->{'socketo'}->write("UseUnchanged\n") if $rep =~ /\bUseUnchanged\b/;
 351         $self->{'repo'} = $repo;
 352 }
 353
 354 sub readline {
 355         my ($self) = @_;
 356         return $self->{'socketi'}->getline();
 357 }
 358
 359 sub _file {
 360         # Request a file with a given revision.
 361         # Trial and error says this is a good way to do it. :-/
 362         my ($self,$fn,$rev) = @_;
 363         $self->{'socketo'}->write("Argument -N\n") or return undef;
 364         $self->{'socketo'}->write("Argument -P\n") or return undef;
 365         # -kk: Linus' version doesn't use it - defaults to off
 366         if ($opt_k) {
 367             $self->{'socketo'}->write("Argument -kk\n") or return undef;
 368         }
 369         $self->{'socketo'}->write("Argument -r\n") or return undef;
 370         $self->{'socketo'}->write("Argument $rev\n") or return undef;
 371         $self->{'socketo'}->write("Argument --\n") or return undef;
 372         $self->{'socketo'}->write("Argument $self->{'subdir'}/$fn\n") or return undef;
 373         $self->{'socketo'}->write("Directory .\n") or return undef;
 374         $self->{'socketo'}->write("$self->{'repo'}\n") or return undef;
 375         # $self->{'socketo'}->write("Sticky T1.0\n") or return undef;
 376         $self->{'socketo'}->write("co\n") or return undef;
 377         $self->{'socketo'}->flush() or return undef;
 378         $self->{'lines'} = 0;
 379         return 1;
 380 }
 381 sub _line {
 382         # Read a line from the server.
 383         # ... except that 'line' may be an entire file. ;-)
 384         my ($self, $fh) = @_;
 385         die "Not in lines" unless defined $self->{'lines'};
 386
 387         my $line;
 388         my $res=0;
 389         while (defined($line = $self->readline())) {
 390                 # M U gnupg-cvs-rep/AUTHORS
 391                 # Updated gnupg-cvs-rep/
 392                 # /daten/src/rsync/gnupg-cvs-rep/AUTHORS
 393                 # /AUTHORS/1.1///T1.1
 394                 # u=rw,g=rw,o=rw
 395                 # 0
 396                 # ok
 397
 398                 if ($line =~ s/^(?:Created|Updated) //) {
 399                         $line = $self->readline(); # path
 400                         $line = $self->readline(); # Entries line
 401                         my $mode = $self->readline(); chomp $mode;
 402                         $self->{'mode'} = $mode;
 403                         defined (my $cnt = $self->readline())
 404                                 or die "EOF from server after 'Changed'\n";
 405                         chomp $cnt;
 406                         die "Duh: Filesize $cnt" if $cnt !~ /^\d+$/;
 407                         $line="";
 408                         $res = $self->_fetchfile($fh, $cnt);
 409                 } elsif ($line =~ s/^ //) {
 410                         print $fh $line;
 411                         $res += length($line);
 412                 } elsif ($line =~ /^M\b/) {
 413                         # output, do nothing
 414                 } elsif ($line =~ /^Mbinary\b/) {
 415                         my $cnt;
 416                         die "EOF from server after 'Mbinary'" unless defined ($cnt = $self->readline());
 417                         chomp $cnt;
 418                         die "Duh: Mbinary $cnt" if $cnt !~ /^\d+$/ or $cnt<1;
 419                         $line="";
 420                         $res += $self->_fetchfile($fh, $cnt);
 421                 } else {
 422                         chomp $line;
 423                         if ($line eq "ok") {
 424                                 # print STDERR "S: ok (".length($res).")\n";
 425                                 return $res;
 426                         } elsif ($line =~ s/^E //) {
 427                                 # print STDERR "S: $line\n";
 428                         } elsif ($line =~ /^(Remove-entry|Removed) /i) {
 429                                 $line = $self->readline(); # filename
 430                                 $line = $self->readline(); # OK
 431                                 chomp $line;
 432                                 die "Unknown: $line" if $line ne "ok";
 433                                 return -1;
 434                         } else {
 435                                 die "Unknown: $line\n";
 436                         }
 437                 }
 438         }
 439         return undef;
 440 }
 441 sub file {
 442         my ($self,$fn,$rev) = @_;
 443         my $res;
 444
 445         my ($fh, $name) = tempfile('gitcvs.XXXXXX',
 446                     DIR => File::Spec->tmpdir(), UNLINK => 1);
 447
 448         $self->_file($fn,$rev) and $res = $self->_line($fh);
 449
 450         if (!defined $res) {
 451             print STDERR "Server has gone away while fetching $fn $rev, retrying...\n";
 452             truncate $fh, 0;
 453             $self->conn();
 454             $self->_file($fn,$rev) or die "No file command send";
 455             $res = $self->_line($fh);
 456             die "Retry failed" unless defined $res;
 457         }
 458         close ($fh);
 459
 460         return ($name, $res);
 461 }
 462 sub _fetchfile {
 463         my ($self, $fh, $cnt) = @_;
 464         my $res = 0;
 465         my $bufsize = 1024 * 1024;
 466         while ($cnt) {
 467             if ($bufsize > $cnt) {
 468                 $bufsize = $cnt;
 469             }
 470             my $buf;
 471             my $num = $self->{'socketi'}->read($buf,$bufsize);
 472             die "Server: Filesize $cnt: $num: $!\n" if not defined $num or $num<=0;
 473             print $fh $buf;
 474             $res += $num;
 475             $cnt -= $num;
 476         }
 477         return $res;
 478 }
 479
 480
 481 package main;
 482
 483 my $cvs = CVSconn->new($opt_d, $cvs_tree);
 484
 485
 486 sub pdate($) {
 487         my ($d) = @_;
 488         m#(\d{2,4})/(\d\d)/(\d\d)\s(\d\d):(\d\d)(?::(\d\d))?#
 489                 or die "Unparseable date: $d\n";
 490         my $y=$1; $y-=1900 if $y>1900;
 491         return timegm($6||0,$5,$4,$3,$2-1,$y);
 492 }
 493
 494 sub pmode($) {
 495         my ($mode) = @_;
 496         my $m = 0;
 497         my $mm = 0;
 498         my $um = 0;
 499         for my $x(split(//,$mode)) {
 500                 if ($x eq ",") {
 501                         $m |= $mm&$um;
 502                         $mm = 0;
 503                         $um = 0;
 504                 } elsif ($x eq "u") { $um |= 0700;
 505                 } elsif ($x eq "g") { $um |= 0070;
 506                 } elsif ($x eq "o") { $um |= 0007;
 507                 } elsif ($x eq "r") { $mm |= 0444;
 508                 } elsif ($x eq "w") { $mm |= 0222;
 509                 } elsif ($x eq "x") { $mm |= 0111;
 510                 } elsif ($x eq "=") { # do nothing
 511                 } else { die "Unknown mode: $mode\n";
 512                 }
 513         }
 514         $m |= $mm&$um;
 515         return $m;
 516 }
 517
 518 sub getwd() {
 519         my $pwd = `pwd`;
 520         chomp $pwd;
 521         return $pwd;
 522 }
 523
 524 sub is_sha1 {
 525         my $s = shift;
 526         return $s =~ /^[a-f0-9]{40}$/;
 527 }
 528
 529 sub get_headref ($$) {
 530     my $name    = shift;
 531     my $git_dir = shift;
 532
 533     my $f = "$git_dir/$remote/$name";
 534     if (open(my $fh, $f)) {
 535             chomp(my $r = <$fh>);
 536             is_sha1($r) or die "Cannot get head id for $name ($r): $!";
 537             return $r;
 538     }
 539     die "unable to open $f: $!" unless $! == POSIX::ENOENT;
 540     return undef;
 541 }
 542
 543 -d $git_tree
 544         or mkdir($git_tree,0777)
 545         or die "Could not create $git_tree: $!";
 546 chdir($git_tree);
 547
 548 my $last_branch = "";
 549 my $orig_branch = "";
 550 my %branch_date;
 551 my $tip_at_start = undef;
 552
 553 my $git_dir = $ENV{"GIT_DIR"} || ".git";
 554 $git_dir = getwd()."/".$git_dir unless $git_dir =~ m#^/#;
 555 $ENV{"GIT_DIR"} = $git_dir;
 556 my $orig_git_index;
 557 $orig_git_index = $ENV{GIT_INDEX_FILE} if exists $ENV{GIT_INDEX_FILE};
 558
 559 my %index; # holds filenames of one index per branch
 560
 561 unless (-d $git_dir) {
 562         system("git-init");
 563         die "Cannot init the GIT db at $git_tree: $?\n" if $?;
 564         system("git-read-tree");
 565         die "Cannot init an empty tree: $?\n" if $?;
 566
 567         $last_branch = $opt_o;
 568         $orig_branch = "";
 569 } else {
 570         open(F, "git-symbolic-ref HEAD |") or
 571                 die "Cannot run git-symbolic-ref: $!\n";
 572         chomp ($last_branch = <F>);
 573         $last_branch = basename($last_branch);
 574         close(F);
 575         unless ($last_branch) {
 576                 warn "Cannot read the last branch name: $! -- assuming 'master'\n";
 577                 $last_branch = "master";
 578         }
 579         $orig_branch = $last_branch;
 580         $tip_at_start = `git-rev-parse --verify HEAD`;
 581
 582         # Get the last import timestamps
 583         my $fmt = '($ref, $author) = (%(refname), %(author));';
 584         open(H, "git-for-each-ref --perl --format='$fmt' $remote |") or
 585                 die "Cannot run git-for-each-ref: $!\n";
 586         while (defined(my $entry = <H>)) {
 587                 my ($ref, $author);
 588                 eval($entry) || die "cannot eval refs list: $@";
 589                 my ($head) = ($ref =~ m|^$remote/(.*)|);
 590                 $author =~ /^.*\s(\d+)\s[-+]\d{4}$/;
 591                 $branch_date{$head} = $1;
 592         }
 593         close(H);
 594         if (!exists $branch_date{$opt_o}) {
 595                 die "Branch '$opt_o' does not exist.\n".
 596                        "Either use the correct '-o branch' option,\n".
 597                        "or import to a new repository.\n";
 598         }
 599 }
 600
 601 -d $git_dir
 602         or die "Could not create git subdir ($git_dir).\n";
 603
 604 # now we read (and possibly save) author-info as well
 605 -f "$git_dir/cvs-authors" and
 606   read_author_info("$git_dir/cvs-authors");
 607 if ($opt_A) {
 608         read_author_info($opt_A);
 609         write_author_info("$git_dir/cvs-authors");
 610 }
 611
 612
 613 #
 614 # run cvsps into a file unless we are getting
 615 # it passed as a file via $opt_P
 616 #
 617 my $cvspsfile;
 618 unless ($opt_P) {
 619         print "Running cvsps...\n" if $opt_v;
 620         my $pid = open(CVSPS,"-|");
 621         my $cvspsfh;
 622         die "Cannot fork: $!\n" unless defined $pid;
 623         unless ($pid) {
 624                 my @opt;
 625                 @opt = split(/,/,$opt_p) if defined $opt_p;
 626                 unshift @opt, '-z', $opt_z if defined $opt_z;
 627                 unshift @opt, '-q'         unless defined $opt_v;
 628                 unless (defined($opt_p) && $opt_p =~ m/--no-cvs-direct/) {
 629                         push @opt, '--cvs-direct';
 630                 }
 631                 exec("cvsps","--norc",@opt,"-u","-A",'--root',$opt_d,$cvs_tree);
 632                 die "Could not start cvsps: $!\n";
 633         }
 634         ($cvspsfh, $cvspsfile) = tempfile('gitXXXXXX', SUFFIX => '.cvsps',
 635                                           DIR => File::Spec->tmpdir());
 636         while (<CVSPS>) {
 637             print $cvspsfh $_;
 638         }
 639         close CVSPS;
 640         close $cvspsfh;
 641 } else {
 642         $cvspsfile = $opt_P;
 643 }
 644
 645 open(CVS, "<$cvspsfile") or die $!;
 646
 647 ## cvsps output:
 648 #---------------------
 649 #PatchSet 314
 650 #Date: 1999/09/18 13:03:59
 651 #Author: wkoch
 652 #Branch: STABLE-BRANCH-1-0
 653 #Ancestor branch: HEAD
 654 #Tag: (none)
 655 #Log:
 656 #    See ChangeLog: Sat Sep 18 13:03:28 CEST 1999  Werner Koch
 657 #Members:
 658 #       README:1.57->1.57.2.1
 659 #       VERSION:1.96->1.96.2.1
 660 #
 661 #---------------------
 662
 663 my $state = 0;
 664
 665 sub update_index (\@\@) {
 666         my $old = shift;
 667         my $new = shift;
 668         open(my $fh, '|-', qw(git-update-index -z --index-info))
 669                 or die "unable to open git-update-index: $!";
 670         print $fh
 671                 (map { "0 0000000000000000000000000000000000000000\t$_\0" }
 672                         @$old),
 673                 (map { '100' . sprintf('%o', $_->[0]) . " $_->[1]\t$_->[2]\0" }
 674                         @$new)
 675                 or die "unable to write to git-update-index: $!";
 676         close $fh
 677                 or die "unable to write to git-update-index: $!";
 678         $? and die "git-update-index reported error: $?";
 679 }
 680
 681 sub write_tree () {
 682         open(my $fh, '-|', qw(git-write-tree))
 683                 or die "unable to open git-write-tree: $!";
 684         chomp(my $tree = <$fh>);
 685         is_sha1($tree)
 686                 or die "Cannot get tree id ($tree): $!";
 687         close($fh)
 688                 or die "Error running git-write-tree: $?\n";
 689         print "Tree ID $tree\n" if $opt_v;
 690         return $tree;
 691 }
 692
 693 my ($patchset,$date,$author_name,$author_email,$branch,$ancestor,$tag,$logmsg);
 694 my (@old,@new,@skipped,%ignorebranch);
 695
 696 # commits that cvsps cannot place anywhere...
 697 $ignorebranch{'#CVSPS_NO_BRANCH'} = 1;
 698
 699 sub commit {
 700         if ($branch eq $opt_o && !$index{branch} && !get_headref($branch, $git_dir)) {
 701             # looks like an initial commit
 702             # use the index primed by git-init
 703             $ENV{GIT_INDEX_FILE} = "$git_dir/index";
 704             $index{$branch} = "$git_dir/index";
 705         } else {
 706             # use an index per branch to speed up
 707             # imports of projects with many branches
 708             unless ($index{$branch}) {
 709                 $index{$branch} = tmpnam();
 710                 $ENV{GIT_INDEX_FILE} = $index{$branch};
 711                 if ($ancestor) {
 712                     system("git-read-tree", "$remote/$ancestor");
 713                 } else {
 714                     system("git-read-tree", "$remote/$branch");
 715                 }
 716                 die "read-tree failed: $?\n" if $?;
 717             }
 718         }
 719         $ENV{GIT_INDEX_FILE} = $index{$branch};
 720
 721         update_index(@old, @new);
 722         @old = @new = ();
 723         my $tree = write_tree();
 724         my $parent = get_headref($last_branch, $git_dir);
 725         print "Parent ID " . ($parent ? $parent : "(empty)") . "\n" if $opt_v;
 726
 727         my @commit_args;
 728         push @commit_args, ("-p", $parent) if $parent;
 729
 730         # loose detection of merges
 731         # based on the commit msg
 732         foreach my $rx (@mergerx) {
 733                 next unless $logmsg =~ $rx && $1;
 734                 my $mparent = $1 eq 'HEAD' ? $opt_o : $1;
 735                 if (my $sha1 = get_headref($mparent, $git_dir)) {
 736                         push @commit_args, '-p', $mparent;
 737                         print "Merge parent branch: $mparent\n" if $opt_v;
 738                 }
 739         }
 740
 741         my $commit_date = strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date));
 742         $ENV{GIT_AUTHOR_NAME} = $author_name;
 743         $ENV{GIT_AUTHOR_EMAIL} = $author_email;
 744         $ENV{GIT_AUTHOR_DATE} = $commit_date;
 745         $ENV{GIT_COMMITTER_NAME} = $author_name;
 746         $ENV{GIT_COMMITTER_EMAIL} = $author_email;
 747         $ENV{GIT_COMMITTER_DATE} = $commit_date;
 748         my $pid = open2(my $commit_read, my $commit_write,
 749                 'git-commit-tree', $tree, @commit_args);
 750
 751         # compatibility with git2cvs
 752         substr($logmsg,32767) = "" if length($logmsg) > 32767;
 753         $logmsg =~ s/[\s\n]+\z//;
 754
 755         if (@skipped) {
 756             $logmsg .= "\n\n\nSKIPPED:\n\t";
 757             $logmsg .= join("\n\t", @skipped) . "\n";
 758             @skipped = ();
 759         }
 760
 761         print($commit_write "$logmsg\n") && close($commit_write)
 762                 or die "Error writing to git-commit-tree: $!\n";
 763
 764         print "Committed patch $patchset ($branch $commit_date)\n" if $opt_v;
 765         chomp(my $cid = <$commit_read>);
 766         is_sha1($cid) or die "Cannot get commit id ($cid): $!\n";
 767         print "Commit ID $cid\n" if $opt_v;
 768         close($commit_read);
 769
 770         waitpid($pid,0);
 771         die "Error running git-commit-tree: $?\n" if $?;
 772
 773         system("git-update-ref $remote/$branch $cid") == 0
 774                 or die "Cannot write branch $branch for update: $!\n";
 775
 776         if ($tag) {
 777                 my ($xtag) = $tag;
 778                 $xtag =~ s/\s+\*\*.*$//; # Remove stuff like ** INVALID ** and ** FUNKY **
 779                 $xtag =~ tr/_/\./ if ( $opt_u );
 780                 $xtag =~ s/[\/]/$opt_s/g;
 781
 782                 system('git-tag', '-f', $xtag, $cid) == 0
 783                         or die "Cannot create tag $xtag: $!\n";
 784
 785                 print "Created tag '$xtag' on '$branch'\n" if $opt_v;
 786         }
 787 };
 788
 789 my $commitcount = 1;
 790 while (<CVS>) {
 791         chomp;
 792         if ($state == 0 and /^-+$/) {
 793                 $state = 1;
 794         } elsif ($state == 0) {
 795                 $state = 1;
 796                 redo;
 797         } elsif (($state==0 or $state==1) and s/^PatchSet\s+//) {
 798                 $patchset = 0+$_;
 799                 $state=2;
 800         } elsif ($state == 2 and s/^Date:\s+//) {
 801                 $date = pdate($_);
 802                 unless ($date) {
 803                         print STDERR "Could not parse date: $_\n";
 804                         $state=0;
 805                         next;
 806                 }
 807                 $state=3;
 808         } elsif ($state == 3 and s/^Author:\s+//) {
 809                 s/\s+$//;
 810                 if (/^(.*?)\s+<(.*)>/) {
 811                     ($author_name, $author_email) = ($1, $2);
 812                 } elsif ($conv_author_name{$_}) {
 813                         $author_name = $conv_author_name{$_};
 814                         $author_email = $conv_author_email{$_};
 815                 } else {
 816                     $author_name = $author_email = $_;
 817                 }
 818                 $state = 4;
 819         } elsif ($state == 4 and s/^Branch:\s+//) {
 820                 s/\s+$//;
 821                 tr/_/\./ if ( $opt_u );
 822                 s/[\/]/$opt_s/g;
 823                 $branch = $_;
 824                 $state = 5;
 825         } elsif ($state == 5 and s/^Ancestor branch:\s+//) {
 826                 s/\s+$//;
 827                 $ancestor = $_;
 828                 $ancestor = $opt_o if $ancestor eq "HEAD";
 829                 $state = 6;
 830         } elsif ($state == 5) {
 831                 $ancestor = undef;
 832                 $state = 6;
 833                 redo;
 834         } elsif ($state == 6 and s/^Tag:\s+//) {
 835                 s/\s+$//;
 836                 if ($_ eq "(none)") {
 837                         $tag = undef;
 838                 } else {
 839                         $tag = $_;
 840                 }
 841                 $state = 7;
 842         } elsif ($state == 7 and /^Log:/) {
 843                 $logmsg = "";
 844                 $state = 8;
 845         } elsif ($state == 8 and /^Members:/) {
 846                 $branch = $opt_o if $branch eq "HEAD";
 847                 if (defined $branch_date{$branch} and $branch_date{$branch} >= $date) {
 848                         # skip
 849                         print "skip patchset $patchset: $date before $branch_date{$branch}\n" if $opt_v;
 850                         $state = 11;
 851                         next;
 852                 }
 853                 if (!$opt_a && $starttime - 300 - (defined $opt_z ? $opt_z : 300) <= $date) {
 854                         # skip if the commit is too recent
 855                         # that the cvsps default fuzz is 300s, we give ourselves another
 856                         # 300s just in case -- this also prevents skipping commits
 857                         # due to server clock drift
 858                         print "skip patchset $patchset: $date too recent\n" if $opt_v;
 859                         $state = 11;
 860                         next;
 861                 }
 862                 if (exists $ignorebranch{$branch}) {
 863                         print STDERR "Skipping $branch\n";
 864                         $state = 11;
 865                         next;
 866                 }
 867                 if ($ancestor) {
 868                         if ($ancestor eq $branch) {
 869                                 print STDERR "Branch $branch erroneously stems from itself -- changed ancestor to $opt_o\n";
 870                                 $ancestor = $opt_o;
 871                         }
 872                         if (-f "$git_dir/$remote/$branch") {
 873                                 print STDERR "Branch $branch already exists!\n";
 874                                 $state=11;
 875                                 next;
 876                         }
 877                         unless (open(H,"$git_dir/$remote/$ancestor")) {
 878                                 print STDERR "Branch $ancestor does not exist!\n";
 879                                 $ignorebranch{$branch} = 1;
 880                                 $state=11;
 881                                 next;
 882                         }
 883                         chomp(my $id = <H>);
 884                         close(H);
 885                         unless (open(H,"> $git_dir/$remote/$branch")) {
 886                                 print STDERR "Could not create branch $branch: $!\n";
 887                                 $ignorebranch{$branch} = 1;
 888                                 $state=11;
 889                                 next;
 890                         }
 891                         print H "$id\n"
 892                                 or die "Could not write branch $branch: $!";
 893                         close(H)
 894                                 or die "Could not write branch $branch: $!";
 895                 }
 896                 $last_branch = $branch if $branch ne $last_branch;
 897                 $state = 9;
 898         } elsif ($state == 8) {
 899                 $logmsg .= "$_\n";
 900         } elsif ($state == 9 and /^\s+(.+?):(INITIAL|\d+(?:\.\d+)+)->(\d+(?:\.\d+)+)\s*$/) {
 901 #       VERSION:1.96->1.96.2.1
 902                 my $init = ($2 eq "INITIAL");
 903                 my $fn = $1;
 904                 my $rev = $3;
 905                 $fn =~ s#^/+##;
 906                 if ($opt_S && $fn =~ m/$opt_S/) {
 907                     print "SKIPPING $fn v $rev\n";
 908                     push(@skipped, $fn);
 909                     next;
 910                 }
 911                 print "Fetching $fn   v $rev\n" if $opt_v;
 912                 my ($tmpname, $size) = $cvs->file($fn,$rev);
 913                 if ($size == -1) {
 914                         push(@old,$fn);
 915                         print "Drop $fn\n" if $opt_v;
 916                 } else {
 917                         print "".($init ? "New" : "Update")." $fn: $size bytes\n" if $opt_v;
 918                         my $pid = open(my $F, '-|');
 919                         die $! unless defined $pid;
 920                         if (!$pid) {
 921                             exec("git-hash-object", "-w", $tmpname)
 922                                 or die "Cannot create object: $!\n";
 923                         }
 924                         my $sha = <$F>;
 925                         chomp $sha;
 926                         close $F;
 927                         my $mode = pmode($cvs->{'mode'});
 928                         push(@new,[$mode, $sha, $fn]); # may be resurrected!
 929                 }
 930                 unlink($tmpname);
 931         } elsif ($state == 9 and /^\s+(.+?):\d+(?:\.\d+)+->(\d+(?:\.\d+)+)\(DEAD\)\s*$/) {
 932                 my $fn = $1;
 933                 $fn =~ s#^/+##;
 934                 push(@old,$fn);
 935                 print "Delete $fn\n" if $opt_v;
 936         } elsif ($state == 9 and /^\s*$/) {
 937                 $state = 10;
 938         } elsif (($state == 9 or $state == 10) and /^-+$/) {
 939                 $commitcount++;
 940                 if ($opt_L && $commitcount > $opt_L) {
 941                         last;
 942                 }
 943                 commit();
 944                 if (($commitcount & 1023) == 0) {
 945                         system("git repack -a -d");
 946                 }
 947                 $state = 1;
 948         } elsif ($state == 11 and /^-+$/) {
 949                 $state = 1;
 950         } elsif (/^-+$/) { # end of unknown-line processing
 951                 $state = 1;
 952         } elsif ($state != 11) { # ignore stuff when skipping
 953                 print "* UNKNOWN LINE * $_\n";
 954         }
 955 }
 956 commit() if $branch and $state != 11;
 957
 958 unless ($opt_P) {
 959         unlink($cvspsfile);
 960 }
 961
 962 # The heuristic of repacking every 1024 commits can leave a
 963 # lot of unpacked data.  If there is more than 1MB worth of
 964 # not-packed objects, repack once more.
 965 my $line = `git-count-objects`;
 966 if ($line =~ /^(\d+) objects, (\d+) kilobytes$/) {
 967   my ($n_objects, $kb) = ($1, $2);
 968   1024 < $kb
 969     and system("git repack -a -d");
 970 }
 971
 972 foreach my $git_index (values %index) {
 973     if ($git_index ne "$git_dir/index") {
 974         unlink($git_index);
 975     }
 976 }
 977
 978 if (defined $orig_git_index) {
 979         $ENV{GIT_INDEX_FILE} = $orig_git_index;
 980 } else {
 981         delete $ENV{GIT_INDEX_FILE};
 982 }
 983
 984 # Now switch back to the branch we were in before all of this happened
 985 if ($orig_branch) {
 986         print "DONE.\n" if $opt_v;
 987         if ($opt_i) {
 988                 exit 0;
 989         }
 990         my $tip_at_end = `git-rev-parse --verify HEAD`;
 991         if ($tip_at_start ne $tip_at_end) {
 992                 for ($tip_at_start, $tip_at_end) { chomp; }
 993                 print "Fetched into the current branch.\n" if $opt_v;
 994                 system(qw(git-read-tree -u -m),
 995                        $tip_at_start, $tip_at_end);
 996                 die "Fast-forward update failed: $?\n" if $?;
 997         }
 998         else {
 999                 system(qw(git-merge cvsimport HEAD), "$remote/$opt_o");
1000                 die "Could not merge $opt_o into the current branch.\n" if $?;
1001         }
1002 } else {
1003         $orig_branch = "master";
1004         print "DONE; creating $orig_branch branch\n" if $opt_v;
1005         system("git-update-ref", "refs/heads/master", "$remote/$opt_o")
1006                 unless -f "$git_dir/refs/heads/master";
1007         system("git-symbolic-ref", "$remote/HEAD", "$remote/$opt_o")
1008                 if ($opt_r && $opt_o ne 'HEAD');
1009         system('git-update-ref', 'HEAD', "$orig_branch");
1010         unless ($opt_i) {
1011                 system('git checkout -f');
1012                 die "checkout failed: $?\n" if $?;
1013         }
1014 }