git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Data::Dumper;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49
  50   Composing:
  51     --from                  <str>  * Email From:
  52     --[no-]to               <str>  * Email To:
  53     --[no-]cc               <str>  * Email Cc:
  54     --[no-]bcc              <str>  * Email Bcc:
  55     --subject               <str>  * Email "Subject:"
  56     --in-reply-to           <str>  * Email "In-Reply-To:"
  57     --[no-]xmailer                 * Add "X-Mailer:" header (default).
  58     --[no-]annotate                * Review each patch that will be sent in an editor.
  59     --compose                      * Open an editor for introduction.
  60     --compose-encoding      <str>  * Encoding to assume for introduction.
  61     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  62     --transfer-encoding     <str>  * Transfer encoding to use (quoted-printable, 8bit, base64)
  63
  64   Sending:
  65     --envelope-sender       <str>  * Email envelope sender.
  66     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  67                                      is optional. Default 'localhost'.
  68     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  69     --smtp-server-port      <int>  * Outgoing SMTP server port.
  70     --smtp-user             <str>  * Username for SMTP-AUTH.
  71     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  72     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  73     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  74     --smtp-ssl-cert-path    <str>  * Path to ca-certificates (either directory or file).
  75                                      Pass an empty string to disable certificate
  76                                      verification.
  77     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  78     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  79
  80   Automating:
  81     --identity              <str>  * Use the sendemail.<id> options.
  82     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  83     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  84     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  85     --[no-]cc-cover                * Email Cc: addresses in the cover letter.
  86     --[no-]to-cover                * Email To: addresses in the cover letter.
  87     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  88     --[no-]suppress-from           * Send to self. Default off.
  89     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  90     --[no-]thread                  * Use In-Reply-To: field. Default on.
  91
  92   Administering:
  93     --confirm               <str>  * Confirm recipients before sending;
  94                                      auto, cc, compose, always, or never.
  95     --quiet                        * Output one line of info per email.
  96     --dry-run                      * Don't actually send the emails.
  97     --[no-]validate                * Perform patch sanity checks. Default on.
  98     --[no-]format-patch            * understand any non optional arguments as
  99                                      `git format-patch` ones.
 100     --force                        * Send even if safety checks would prevent it.
 101
 102 EOT
 103         exit(1);
 104 }
 105
 106 # most mail servers generate the Date: header, but not all...
 107 sub format_2822_time {
 108         my ($time) = @_;
 109         my @localtm = localtime($time);
 110         my @gmttm = gmtime($time);
 111         my $localmin = $localtm[1] + $localtm[2] * 60;
 112         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 113         if ($localtm[0] != $gmttm[0]) {
 114                 die "local zone differs from GMT by a non-minute interval\n";
 115         }
 116         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 117                 $localmin += 1440;
 118         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 119                 $localmin -= 1440;
 120         } elsif ($gmttm[6] != $localtm[6]) {
 121                 die "local time offset greater than or equal to 24 hours\n";
 122         }
 123         my $offset = $localmin - $gmtmin;
 124         my $offhour = $offset / 60;
 125         my $offmin = abs($offset % 60);
 126         if (abs($offhour) >= 24) {
 127                 die ("local time offset greater than or equal to 24 hours\n");
 128         }
 129
 130         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 131                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 132                        $localtm[3],
 133                        qw(Jan Feb Mar Apr May Jun
 134                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 135                        $localtm[5]+1900,
 136                        $localtm[2],
 137                        $localtm[1],
 138                        $localtm[0],
 139                        ($offset >= 0) ? '+' : '-',
 140                        abs($offhour),
 141                        $offmin,
 142                        );
 143 }
 144
 145 my $have_email_valid = eval { require Email::Valid; 1 };
 146 my $have_mail_address = eval { require Mail::Address; 1 };
 147 my $smtp;
 148 my $auth;
 149
 150 # Regexes for RFC 2047 productions.
 151 my $re_token = qr/[^][()<>@,;:\\"\/?.= \000-\037\177-\377]+/;
 152 my $re_encoded_text = qr/[^? \000-\037\177-\377]+/;
 153 my $re_encoded_word = qr/=\?($re_token)\?($re_token)\?($re_encoded_text)\?=/;
 154
 155 # Variables we fill in automatically, or via prompting:
 156 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 157         $initial_reply_to,$initial_subject,@files,
 158         $author,$sender,$smtp_authpass,$annotate,$use_xmailer,$compose,$time);
 159
 160 my $envelope_sender;
 161
 162 # Example reply to:
 163 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 164
 165 my $repo = eval { Git->repository() };
 166 my @repo = $repo ? ($repo) : ();
 167 my $term = eval {
 168         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 169                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 170                 : new Term::ReadLine 'git-send-email';
 171 };
 172 if ($@) {
 173         $term = new FakeTerm "$@: going non-interactive";
 174 }
 175
 176 # Behavior modification variables
 177 my ($quiet, $dry_run) = (0, 0);
 178 my $format_patch;
 179 my $compose_filename;
 180 my $force = 0;
 181
 182 # Handle interactive edition of files.
 183 my $multiedit;
 184 my $editor;
 185
 186 sub do_edit {
 187         if (!defined($editor)) {
 188                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 189         }
 190         if (defined($multiedit) && !$multiedit) {
 191                 map {
 192                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 193                         if (($? & 127) || ($? >> 8)) {
 194                                 die("the editor exited uncleanly, aborting everything");
 195                         }
 196                 } @_;
 197         } else {
 198                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 199                 if (($? & 127) || ($? >> 8)) {
 200                         die("the editor exited uncleanly, aborting everything");
 201                 }
 202         }
 203 }
 204
 205 # Variables with corresponding config settings
 206 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 207 my ($cover_cc, $cover_to);
 208 my ($to_cmd, $cc_cmd);
 209 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 210 my ($smtp_authuser, $smtp_encryption, $smtp_ssl_cert_path);
 211 my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
 212 my ($validate, $confirm);
 213 my (@suppress_cc);
 214 my ($auto_8bit_encoding);
 215 my ($compose_encoding);
 216 my ($target_xfer_encoding);
 217
 218 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 219
 220 my %config_bool_settings = (
 221     "thread" => [\$thread, 1],
 222     "chainreplyto" => [\$chain_reply_to, 0],
 223     "suppressfrom" => [\$suppress_from, undef],
 224     "signedoffbycc" => [\$signed_off_by_cc, undef],
 225     "cccover" => [\$cover_cc, undef],
 226     "tocover" => [\$cover_to, undef],
 227     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 228     "validate" => [\$validate, 1],
 229     "multiedit" => [\$multiedit, undef],
 230     "annotate" => [\$annotate, undef],
 231     "xmailer" => [\$use_xmailer, 1]
 232 );
 233
 234 my %config_settings = (
 235     "smtpserver" => \$smtp_server,
 236     "smtpserverport" => \$smtp_server_port,
 237     "smtpserveroption" => \@smtp_server_options,
 238     "smtpuser" => \$smtp_authuser,
 239     "smtppass" => \$smtp_authpass,
 240     "smtpsslcertpath" => \$smtp_ssl_cert_path,
 241     "smtpdomain" => \$smtp_domain,
 242     "to" => \@initial_to,
 243     "tocmd" => \$to_cmd,
 244     "cc" => \@initial_cc,
 245     "cccmd" => \$cc_cmd,
 246     "aliasfiletype" => \$aliasfiletype,
 247     "bcc" => \@bcclist,
 248     "suppresscc" => \@suppress_cc,
 249     "envelopesender" => \$envelope_sender,
 250     "confirm"   => \$confirm,
 251     "from" => \$sender,
 252     "assume8bitencoding" => \$auto_8bit_encoding,
 253     "composeencoding" => \$compose_encoding,
 254     "transferencoding" => \$target_xfer_encoding,
 255 );
 256
 257 my %config_path_settings = (
 258     "aliasesfile" => \@alias_files,
 259 );
 260
 261 # Handle Uncouth Termination
 262 sub signal_handler {
 263
 264         # Make text normal
 265         print color("reset"), "\n";
 266
 267         # SMTP password masked
 268         system "stty echo";
 269
 270         # tmp files from --compose
 271         if (defined $compose_filename) {
 272                 if (-e $compose_filename) {
 273                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 274                 }
 275                 if (-e ($compose_filename . ".final")) {
 276                         print "'$compose_filename.final' contains the composed email.\n"
 277                 }
 278         }
 279
 280         exit;
 281 };
 282
 283 $SIG{TERM} = \&signal_handler;
 284 $SIG{INT}  = \&signal_handler;
 285
 286 # Begin by accumulating all the variables (defined above), that we will end up
 287 # needing, first, from the command line:
 288
 289 my $help;
 290 my $rc = GetOptions("h" => \$help,
 291                     "sender|from=s" => \$sender,
 292                     "in-reply-to=s" => \$initial_reply_to,
 293                     "subject=s" => \$initial_subject,
 294                     "to=s" => \@initial_to,
 295                     "to-cmd=s" => \$to_cmd,
 296                     "no-to" => \$no_to,
 297                     "cc=s" => \@initial_cc,
 298                     "no-cc" => \$no_cc,
 299                     "bcc=s" => \@bcclist,
 300                     "no-bcc" => \$no_bcc,
 301                     "chain-reply-to!" => \$chain_reply_to,
 302                     "no-chain-reply-to" => sub {$chain_reply_to = 0},
 303                     "smtp-server=s" => \$smtp_server,
 304                     "smtp-server-option=s" => \@smtp_server_options,
 305                     "smtp-server-port=s" => \$smtp_server_port,
 306                     "smtp-user=s" => \$smtp_authuser,
 307                     "smtp-pass:s" => \$smtp_authpass,
 308                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 309                     "smtp-encryption=s" => \$smtp_encryption,
 310                     "smtp-ssl-cert-path=s" => \$smtp_ssl_cert_path,
 311                     "smtp-debug:i" => \$debug_net_smtp,
 312                     "smtp-domain:s" => \$smtp_domain,
 313                     "identity=s" => \$identity,
 314                     "annotate!" => \$annotate,
 315                     "no-annotate" => sub {$annotate = 0},
 316                     "compose" => \$compose,
 317                     "quiet" => \$quiet,
 318                     "cc-cmd=s" => \$cc_cmd,
 319                     "suppress-from!" => \$suppress_from,
 320                     "no-suppress-from" => sub {$suppress_from = 0},
 321                     "suppress-cc=s" => \@suppress_cc,
 322                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 323                     "no-signed-off-cc|no-signed-off-by-cc" => sub {$signed_off_by_cc = 0},
 324                     "cc-cover|cc-cover!" => \$cover_cc,
 325                     "no-cc-cover" => sub {$cover_cc = 0},
 326                     "to-cover|to-cover!" => \$cover_to,
 327                     "no-to-cover" => sub {$cover_to = 0},
 328                     "confirm=s" => \$confirm,
 329                     "dry-run" => \$dry_run,
 330                     "envelope-sender=s" => \$envelope_sender,
 331                     "thread!" => \$thread,
 332                     "no-thread" => sub {$thread = 0},
 333                     "validate!" => \$validate,
 334                     "no-validate" => sub {$validate = 0},
 335                     "transfer-encoding=s" => \$target_xfer_encoding,
 336                     "format-patch!" => \$format_patch,
 337                     "no-format-patch" => sub {$format_patch = 0},
 338                     "8bit-encoding=s" => \$auto_8bit_encoding,
 339                     "compose-encoding=s" => \$compose_encoding,
 340                     "force" => \$force,
 341                     "xmailer!" => \$use_xmailer,
 342                     "no-xmailer" => sub {$use_xmailer = 0},
 343          );
 344
 345 usage() if $help;
 346 unless ($rc) {
 347     usage();
 348 }
 349
 350 die "Cannot run git format-patch from outside a repository\n"
 351         if $format_patch and not $repo;
 352
 353 # Now, let's fill any that aren't set in with defaults:
 354
 355 sub read_config {
 356         my ($prefix) = @_;
 357
 358         foreach my $setting (keys %config_bool_settings) {
 359                 my $target = $config_bool_settings{$setting}->[0];
 360                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 361         }
 362
 363         foreach my $setting (keys %config_path_settings) {
 364                 my $target = $config_path_settings{$setting};
 365                 if (ref($target) eq "ARRAY") {
 366                         unless (@$target) {
 367                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 368                                 @$target = @values if (@values && defined $values[0]);
 369                         }
 370                 }
 371                 else {
 372                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 373                 }
 374         }
 375
 376         foreach my $setting (keys %config_settings) {
 377                 my $target = $config_settings{$setting};
 378                 next if $setting eq "to" and defined $no_to;
 379                 next if $setting eq "cc" and defined $no_cc;
 380                 next if $setting eq "bcc" and defined $no_bcc;
 381                 if (ref($target) eq "ARRAY") {
 382                         unless (@$target) {
 383                                 my @values = Git::config(@repo, "$prefix.$setting");
 384                                 @$target = @values if (@values && defined $values[0]);
 385                         }
 386                 }
 387                 else {
 388                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 389                 }
 390         }
 391
 392         if (!defined $smtp_encryption) {
 393                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 394                 if (defined $enc) {
 395                         $smtp_encryption = $enc;
 396                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 397                         $smtp_encryption = 'ssl';
 398                 }
 399         }
 400 }
 401
 402 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 403 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 404 read_config("sendemail.$identity") if (defined $identity);
 405 read_config("sendemail");
 406
 407 # fall back on builtin bool defaults
 408 foreach my $setting (values %config_bool_settings) {
 409         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 410 }
 411
 412 # 'default' encryption is none -- this only prevents a warning
 413 $smtp_encryption = '' unless (defined $smtp_encryption);
 414
 415 # Set CC suppressions
 416 my(%suppress_cc);
 417 if (@suppress_cc) {
 418         foreach my $entry (@suppress_cc) {
 419                 die "Unknown --suppress-cc field: '$entry'\n"
 420                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 421                 $suppress_cc{$entry} = 1;
 422         }
 423 }
 424
 425 if ($suppress_cc{'all'}) {
 426         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 427                 $suppress_cc{$entry} = 1;
 428         }
 429         delete $suppress_cc{'all'};
 430 }
 431
 432 # If explicit old-style ones are specified, they trump --suppress-cc.
 433 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 434 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 435
 436 if ($suppress_cc{'body'}) {
 437         foreach my $entry (qw (sob bodycc)) {
 438                 $suppress_cc{$entry} = 1;
 439         }
 440         delete $suppress_cc{'body'};
 441 }
 442
 443 # Set confirm's default value
 444 my $confirm_unconfigured = !defined $confirm;
 445 if ($confirm_unconfigured) {
 446         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 447 };
 448 die "Unknown --confirm setting: '$confirm'\n"
 449         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 450
 451 # Debugging, print out the suppressions.
 452 if (0) {
 453         print "suppressions:\n";
 454         foreach my $entry (keys %suppress_cc) {
 455                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 456         }
 457 }
 458
 459 my ($repoauthor, $repocommitter);
 460 ($repoauthor) = Git::ident_person(@repo, 'author');
 461 ($repocommitter) = Git::ident_person(@repo, 'committer');
 462
 463 sub parse_address_line {
 464         if ($have_mail_address) {
 465                 return map { $_->format } Mail::Address->parse($_[0]);
 466         } else {
 467                 return Git::parse_mailboxes($_[0]);
 468         }
 469 }
 470
 471 sub split_addrs {
 472         return quotewords('\s*,\s*', 1, @_);
 473 }
 474
 475 my %aliases;
 476 my %parse_alias = (
 477         # multiline formats can be supported in the future
 478         mutt => sub { my $fh = shift; while (<$fh>) {
 479                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 480                         my ($alias, $addr) = ($1, $2);
 481                         $addr =~ s/#.*$//; # mutt allows # comments
 482                          # commas delimit multiple addresses
 483                         $aliases{$alias} = [ split_addrs($addr) ];
 484                 }}},
 485         mailrc => sub { my $fh = shift; while (<$fh>) {
 486                 if (/^alias\s+(\S+)\s+(.*)$/) {
 487                         # spaces delimit multiple addresses
 488                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 489                 }}},
 490         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 491                 for (my $x = ''; defined($x); $x = $_) {
 492                         chomp $x;
 493                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 494                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 495                         $aliases{$1} = [ split_addrs($2) ];
 496                 }},
 497         elm => sub  { my $fh = shift;
 498                       while (<$fh>) {
 499                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 500                               my ($alias, $addr) = ($1, $2);
 501                                $aliases{$alias} = [ split_addrs($addr) ];
 502                           }
 503                       } },
 504
 505         gnus => sub { my $fh = shift; while (<$fh>) {
 506                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 507                         $aliases{$1} = [ $2 ];
 508                 }}}
 509 );
 510
 511 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 512         foreach my $file (@alias_files) {
 513                 open my $fh, '<', $file or die "opening $file: $!\n";
 514                 $parse_alias{$aliasfiletype}->($fh);
 515                 close $fh;
 516         }
 517 }
 518
 519 # is_format_patch_arg($f) returns 0 if $f names a patch, or 1 if
 520 # $f is a revision list specification to be passed to format-patch.
 521 sub is_format_patch_arg {
 522         return unless $repo;
 523         my $f = shift;
 524         try {
 525                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 526                 if (defined($format_patch)) {
 527                         return $format_patch;
 528                 }
 529                 die(<<EOF);
 530 File '$f' exists but it could also be the range of commits
 531 to produce patches for.  Please disambiguate by...
 532
 533     * Saying "./$f" if you mean a file; or
 534     * Giving --format-patch option if you mean a range.
 535 EOF
 536         } catch Git::Error::Command with {
 537                 # Not a valid revision.  Treat it as a filename.
 538                 return 0;
 539         }
 540 }
 541
 542 # Now that all the defaults are set, process the rest of the command line
 543 # arguments and collect up the files that need to be processed.
 544 my @rev_list_opts;
 545 while (defined(my $f = shift @ARGV)) {
 546         if ($f eq "--") {
 547                 push @rev_list_opts, "--", @ARGV;
 548                 @ARGV = ();
 549         } elsif (-d $f and !is_format_patch_arg($f)) {
 550                 opendir my $dh, $f
 551                         or die "Failed to opendir $f: $!";
 552
 553                 push @files, grep { -f $_ } map { catfile($f, $_) }
 554                                 sort readdir $dh;
 555                 closedir $dh;
 556         } elsif ((-f $f or -p $f) and !is_format_patch_arg($f)) {
 557                 push @files, $f;
 558         } else {
 559                 push @rev_list_opts, $f;
 560         }
 561 }
 562
 563 if (@rev_list_opts) {
 564         die "Cannot run git format-patch from outside a repository\n"
 565                 unless $repo;
 566         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 567 }
 568
 569 if ($validate) {
 570         foreach my $f (@files) {
 571                 unless (-p $f) {
 572                         my $error = validate_patch($f);
 573                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 574                 }
 575         }
 576 }
 577
 578 if (@files) {
 579         unless ($quiet) {
 580                 print $_,"\n" for (@files);
 581         }
 582 } else {
 583         print STDERR "\nNo patch files specified!\n\n";
 584         usage();
 585 }
 586
 587 sub get_patch_subject {
 588         my $fn = shift;
 589         open (my $fh, '<', $fn);
 590         while (my $line = <$fh>) {
 591                 next unless ($line =~ /^Subject: (.*)$/);
 592                 close $fh;
 593                 return "GIT: $1\n";
 594         }
 595         close $fh;
 596         die "No subject line in $fn ?";
 597 }
 598
 599 if ($compose) {
 600         # Note that this does not need to be secure, but we will make a small
 601         # effort to have it be unique
 602         $compose_filename = ($repo ?
 603                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 604                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 605         open my $c, ">", $compose_filename
 606                 or die "Failed to open for writing $compose_filename: $!";
 607
 608
 609         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 610         my $tpl_subject = $initial_subject || '';
 611         my $tpl_reply_to = $initial_reply_to || '';
 612
 613         print $c <<EOT;
 614 From $tpl_sender # This line is ignored.
 615 GIT: Lines beginning in "GIT:" will be removed.
 616 GIT: Consider including an overall diffstat or table of contents
 617 GIT: for the patch you are writing.
 618 GIT:
 619 GIT: Clear the body content if you don't wish to send a summary.
 620 From: $tpl_sender
 621 Subject: $tpl_subject
 622 In-Reply-To: $tpl_reply_to
 623
 624 EOT
 625         for my $f (@files) {
 626                 print $c get_patch_subject($f);
 627         }
 628         close $c;
 629
 630         if ($annotate) {
 631                 do_edit($compose_filename, @files);
 632         } else {
 633                 do_edit($compose_filename);
 634         }
 635
 636         open my $c2, ">", $compose_filename . ".final"
 637                 or die "Failed to open $compose_filename.final : " . $!;
 638
 639         open $c, "<", $compose_filename
 640                 or die "Failed to open $compose_filename : " . $!;
 641
 642         my $need_8bit_cte = file_has_nonascii($compose_filename);
 643         my $in_body = 0;
 644         my $summary_empty = 1;
 645         if (!defined $compose_encoding) {
 646                 $compose_encoding = "UTF-8";
 647         }
 648         while(<$c>) {
 649                 next if m/^GIT:/;
 650                 if ($in_body) {
 651                         $summary_empty = 0 unless (/^\n$/);
 652                 } elsif (/^\n$/) {
 653                         $in_body = 1;
 654                         if ($need_8bit_cte) {
 655                                 print $c2 "MIME-Version: 1.0\n",
 656                                          "Content-Type: text/plain; ",
 657                                            "charset=$compose_encoding\n",
 658                                          "Content-Transfer-Encoding: 8bit\n";
 659                         }
 660                 } elsif (/^MIME-Version:/i) {
 661                         $need_8bit_cte = 0;
 662                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 663                         $initial_subject = $1;
 664                         my $subject = $initial_subject;
 665                         $_ = "Subject: " .
 666                                 quote_subject($subject, $compose_encoding) .
 667                                 "\n";
 668                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 669                         $initial_reply_to = $1;
 670                         next;
 671                 } elsif (/^From:\s*(.+)\s*$/i) {
 672                         $sender = $1;
 673                         next;
 674                 } elsif (/^(?:To|Cc|Bcc):/i) {
 675                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 676                         next;
 677                 }
 678                 print $c2 $_;
 679         }
 680         close $c;
 681         close $c2;
 682
 683         if ($summary_empty) {
 684                 print "Summary email is empty, skipping it\n";
 685                 $compose = -1;
 686         }
 687 } elsif ($annotate) {
 688         do_edit(@files);
 689 }
 690
 691 sub ask {
 692         my ($prompt, %arg) = @_;
 693         my $valid_re = $arg{valid_re};
 694         my $default = $arg{default};
 695         my $confirm_only = $arg{confirm_only};
 696         my $resp;
 697         my $i = 0;
 698         return defined $default ? $default : undef
 699                 unless defined $term->IN and defined fileno($term->IN) and
 700                        defined $term->OUT and defined fileno($term->OUT);
 701         while ($i++ < 10) {
 702                 $resp = $term->readline($prompt);
 703                 if (!defined $resp) { # EOF
 704                         print "\n";
 705                         return defined $default ? $default : undef;
 706                 }
 707                 if ($resp eq '' and defined $default) {
 708                         return $default;
 709                 }
 710                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 711                         return $resp;
 712                 }
 713                 if ($confirm_only) {
 714                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 715                         if (defined $yesno && $yesno =~ /y/i) {
 716                                 return $resp;
 717                         }
 718                 }
 719         }
 720         return;
 721 }
 722
 723 my %broken_encoding;
 724
 725 sub file_declares_8bit_cte {
 726         my $fn = shift;
 727         open (my $fh, '<', $fn);
 728         while (my $line = <$fh>) {
 729                 last if ($line =~ /^$/);
 730                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 731         }
 732         close $fh;
 733         return 0;
 734 }
 735
 736 foreach my $f (@files) {
 737         next unless (body_or_subject_has_nonascii($f)
 738                      && !file_declares_8bit_cte($f));
 739         $broken_encoding{$f} = 1;
 740 }
 741
 742 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 743         print "The following files are 8bit, but do not declare " .
 744                 "a Content-Transfer-Encoding.\n";
 745         foreach my $f (sort keys %broken_encoding) {
 746                 print "    $f\n";
 747         }
 748         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 749                                   valid_re => qr/.{4}/, confirm_only => 1,
 750                                   default => "UTF-8");
 751 }
 752
 753 if (!$force) {
 754         for my $f (@files) {
 755                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 756                         die "Refusing to send because the patch\n\t$f\n"
 757                                 . "has the template subject '*** SUBJECT HERE ***'. "
 758                                 . "Pass --force if you really want to send.\n";
 759                 }
 760         }
 761 }
 762
 763 if (defined $sender) {
 764         $sender =~ s/^\s+|\s+$//g;
 765         ($sender) = expand_aliases($sender);
 766 } else {
 767         $sender = $repoauthor || $repocommitter || '';
 768 }
 769
 770 # $sender could be an already sanitized address
 771 # (e.g. sendemail.from could be manually sanitized by user).
 772 # But it's a no-op to run sanitize_address on an already sanitized address.
 773 $sender = sanitize_address($sender);
 774
 775 my $prompting = 0;
 776 if (!@initial_to && !defined $to_cmd) {
 777         my $to = ask("Who should the emails be sent to (if any)? ",
 778                      default => "",
 779                      valid_re => qr/\@.*\./, confirm_only => 1);
 780         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 781         $prompting++;
 782 }
 783
 784 sub expand_aliases {
 785         return map { expand_one_alias($_) } @_;
 786 }
 787
 788 my %EXPANDED_ALIASES;
 789 sub expand_one_alias {
 790         my $alias = shift;
 791         if ($EXPANDED_ALIASES{$alias}) {
 792                 die "fatal: alias '$alias' expands to itself\n";
 793         }
 794         local $EXPANDED_ALIASES{$alias} = 1;
 795         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 796 }
 797
 798 @initial_to = process_address_list(@initial_to);
 799 @initial_cc = process_address_list(@initial_cc);
 800 @bcclist = process_address_list(@bcclist);
 801
 802 if ($thread && !defined $initial_reply_to && $prompting) {
 803         $initial_reply_to = ask(
 804                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 805                 default => "",
 806                 valid_re => qr/\@.*\./, confirm_only => 1);
 807 }
 808 if (defined $initial_reply_to) {
 809         $initial_reply_to =~ s/^\s*<?//;
 810         $initial_reply_to =~ s/>?\s*$//;
 811         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 812 }
 813
 814 if (!defined $smtp_server) {
 815         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 816                 if (-x $_) {
 817                         $smtp_server = $_;
 818                         last;
 819                 }
 820         }
 821         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 822 }
 823
 824 if ($compose && $compose > 0) {
 825         @files = ($compose_filename . ".final", @files);
 826 }
 827
 828 # Variables we set as part of the loop over files
 829 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 830         $needs_confirm, $message_num, $ask_default);
 831
 832 sub extract_valid_address {
 833         my $address = shift;
 834         my $local_part_regexp = qr/[^<>"\s@]+/;
 835         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 836
 837         # check for a local address:
 838         return $address if ($address =~ /^($local_part_regexp)$/);
 839
 840         $address =~ s/^\s*<(.*)>\s*$/$1/;
 841         if ($have_email_valid) {
 842                 return scalar Email::Valid->address($address);
 843         }
 844
 845         # less robust/correct than the monster regexp in Email::Valid,
 846         # but still does a 99% job, and one less dependency
 847         return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
 848         return;
 849 }
 850
 851 sub extract_valid_address_or_die {
 852         my $address = shift;
 853         $address = extract_valid_address($address);
 854         die "error: unable to extract a valid address from: $address\n"
 855                 if !$address;
 856         return $address;
 857 }
 858
 859 sub validate_address {
 860         my $address = shift;
 861         while (!extract_valid_address($address)) {
 862                 print STDERR "error: unable to extract a valid address from: $address\n";
 863                 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
 864                         valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
 865                         default => 'q');
 866                 if (/^d/i) {
 867                         return undef;
 868                 } elsif (/^q/i) {
 869                         cleanup_compose_files();
 870                         exit(0);
 871                 }
 872                 $address = ask("Who should the email be sent to (if any)? ",
 873                         default => "",
 874                         valid_re => qr/\@.*\./, confirm_only => 1);
 875         }
 876         return $address;
 877 }
 878
 879 sub validate_address_list {
 880         return (grep { defined $_ }
 881                 map { validate_address($_) } @_);
 882 }
 883
 884 # Usually don't need to change anything below here.
 885
 886 # we make a "fake" message id by taking the current number
 887 # of seconds since the beginning of Unix time and tacking on
 888 # a random number to the end, in case we are called quicker than
 889 # 1 second since the last time we were called.
 890
 891 # We'll setup a template for the message id, using the "from" address:
 892
 893 my ($message_id_stamp, $message_id_serial);
 894 sub make_message_id {
 895         my $uniq;
 896         if (!defined $message_id_stamp) {
 897                 $message_id_stamp = sprintf("%s-%s", time, $$);
 898                 $message_id_serial = 0;
 899         }
 900         $message_id_serial++;
 901         $uniq = "$message_id_stamp-$message_id_serial";
 902
 903         my $du_part;
 904         for ($sender, $repocommitter, $repoauthor) {
 905                 $du_part = extract_valid_address(sanitize_address($_));
 906                 last if (defined $du_part and $du_part ne '');
 907         }
 908         if (not defined $du_part or $du_part eq '') {
 909                 require Sys::Hostname;
 910                 $du_part = 'user@' . Sys::Hostname::hostname();
 911         }
 912         my $message_id_template = "<%s-git-send-email-%s>";
 913         $message_id = sprintf($message_id_template, $uniq, $du_part);
 914         #print "new message id = $message_id\n"; # Was useful for debugging
 915 }
 916
 917
 918
 919 $time = time - scalar $#files;
 920
 921 sub unquote_rfc2047 {
 922         local ($_) = @_;
 923         my $charset;
 924         my $sep = qr/[ \t]+/;
 925         s{$re_encoded_word(?:$sep$re_encoded_word)*}{
 926                 my @words = split $sep, $&;
 927                 foreach (@words) {
 928                         m/$re_encoded_word/;
 929                         $charset = $1;
 930                         my $encoding = $2;
 931                         my $text = $3;
 932                         if ($encoding eq 'q' || $encoding eq 'Q') {
 933                                 $_ = $text;
 934                                 s/_/ /g;
 935                                 s/=([0-9A-F]{2})/chr(hex($1))/egi;
 936                         } else {
 937                                 # other encodings not supported yet
 938                         }
 939                 }
 940                 join '', @words;
 941         }eg;
 942         return wantarray ? ($_, $charset) : $_;
 943 }
 944
 945 sub quote_rfc2047 {
 946         local $_ = shift;
 947         my $encoding = shift || 'UTF-8';
 948         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 949         s/(.*)/=\?$encoding\?q\?$1\?=/;
 950         return $_;
 951 }
 952
 953 sub is_rfc2047_quoted {
 954         my $s = shift;
 955         length($s) <= 75 &&
 956         $s =~ m/^(?:"[[:ascii:]]*"|$re_encoded_word)$/o;
 957 }
 958
 959 sub subject_needs_rfc2047_quoting {
 960         my $s = shift;
 961
 962         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
 963 }
 964
 965 sub quote_subject {
 966         local $subject = shift;
 967         my $encoding = shift || 'UTF-8';
 968
 969         if (subject_needs_rfc2047_quoting($subject)) {
 970                 return quote_rfc2047($subject, $encoding);
 971         }
 972         return $subject;
 973 }
 974
 975 # use the simplest quoting being able to handle the recipient
 976 sub sanitize_address {
 977         my ($recipient) = @_;
 978
 979         # remove garbage after email address
 980         $recipient =~ s/(.*>).*$/$1/;
 981
 982         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 983
 984         if (not $recipient_name) {
 985                 return $recipient;
 986         }
 987
 988         # if recipient_name is already quoted, do nothing
 989         if (is_rfc2047_quoted($recipient_name)) {
 990                 return $recipient;
 991         }
 992
 993         # remove non-escaped quotes
 994         $recipient_name =~ s/(^|[^\\])"/$1/g;
 995
 996         # rfc2047 is needed if a non-ascii char is included
 997         if ($recipient_name =~ /[^[:ascii:]]/) {
 998                 $recipient_name = quote_rfc2047($recipient_name);
 999         }
1000
1001         # double quotes are needed if specials or CTLs are included
1002         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
1003                 $recipient_name =~ s/([\\\r])/\\$1/g;
1004                 $recipient_name = qq["$recipient_name"];
1005         }
1006
1007         return "$recipient_name $recipient_addr";
1008
1009 }
1010
1011 sub sanitize_address_list {
1012         return (map { sanitize_address($_) } @_);
1013 }
1014
1015 sub process_address_list {
1016         my @addr_list = map { parse_address_line($_) } @_;
1017         @addr_list = expand_aliases(@addr_list);
1018         @addr_list = sanitize_address_list(@addr_list);
1019         @addr_list = validate_address_list(@addr_list);
1020         return @addr_list;
1021 }
1022
1023 # Returns the local Fully Qualified Domain Name (FQDN) if available.
1024 #
1025 # Tightly configured MTAa require that a caller sends a real DNS
1026 # domain name that corresponds the IP address in the HELO/EHLO
1027 # handshake. This is used to verify the connection and prevent
1028 # spammers from trying to hide their identity. If the DNS and IP don't
1029 # match, the receiveing MTA may deny the connection.
1030 #
1031 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
1032 #
1033 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
1034 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
1035 #
1036 # This maildomain*() code is based on ideas in Perl library Test::Reporter
1037 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1038
1039 sub valid_fqdn {
1040         my $domain = shift;
1041         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1042 }
1043
1044 sub maildomain_net {
1045         my $maildomain;
1046
1047         if (eval { require Net::Domain; 1 }) {
1048                 my $domain = Net::Domain::domainname();
1049                 $maildomain = $domain if valid_fqdn($domain);
1050         }
1051
1052         return $maildomain;
1053 }
1054
1055 sub maildomain_mta {
1056         my $maildomain;
1057
1058         if (eval { require Net::SMTP; 1 }) {
1059                 for my $host (qw(mailhost localhost)) {
1060                         my $smtp = Net::SMTP->new($host);
1061                         if (defined $smtp) {
1062                                 my $domain = $smtp->domain;
1063                                 $smtp->quit;
1064
1065                                 $maildomain = $domain if valid_fqdn($domain);
1066
1067                                 last if $maildomain;
1068                         }
1069                 }
1070         }
1071
1072         return $maildomain;
1073 }
1074
1075 sub maildomain {
1076         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1077 }
1078
1079 sub smtp_host_string {
1080         if (defined $smtp_server_port) {
1081                 return "$smtp_server:$smtp_server_port";
1082         } else {
1083                 return $smtp_server;
1084         }
1085 }
1086
1087 # Returns 1 if authentication succeeded or was not necessary
1088 # (smtp_user was not specified), and 0 otherwise.
1089
1090 sub smtp_auth_maybe {
1091         if (!defined $smtp_authuser || $auth) {
1092                 return 1;
1093         }
1094
1095         # Workaround AUTH PLAIN/LOGIN interaction defect
1096         # with Authen::SASL::Cyrus
1097         eval {
1098                 require Authen::SASL;
1099                 Authen::SASL->import(qw(Perl));
1100         };
1101
1102         # TODO: Authentication may fail not because credentials were
1103         # invalid but due to other reasons, in which we should not
1104         # reject credentials.
1105         $auth = Git::credential({
1106                 'protocol' => 'smtp',
1107                 'host' => smtp_host_string(),
1108                 'username' => $smtp_authuser,
1109                 # if there's no password, "git credential fill" will
1110                 # give us one, otherwise it'll just pass this one.
1111                 'password' => $smtp_authpass
1112         }, sub {
1113                 my $cred = shift;
1114                 return !!$smtp->auth($cred->{'username'}, $cred->{'password'});
1115         });
1116
1117         return $auth;
1118 }
1119
1120 sub ssl_verify_params {
1121         eval {
1122                 require IO::Socket::SSL;
1123                 IO::Socket::SSL->import(qw/SSL_VERIFY_PEER SSL_VERIFY_NONE/);
1124         };
1125         if ($@) {
1126                 print STDERR "Not using SSL_VERIFY_PEER due to out-of-date IO::Socket::SSL.\n";
1127                 return;
1128         }
1129
1130         if (!defined $smtp_ssl_cert_path) {
1131                 # use the OpenSSL defaults
1132                 return (SSL_verify_mode => SSL_VERIFY_PEER());
1133         }
1134
1135         if ($smtp_ssl_cert_path eq "") {
1136                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1137         } elsif (-d $smtp_ssl_cert_path) {
1138                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1139                         SSL_ca_path => $smtp_ssl_cert_path);
1140         } elsif (-f $smtp_ssl_cert_path) {
1141                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1142                         SSL_ca_file => $smtp_ssl_cert_path);
1143         } else {
1144                 print STDERR "Not using SSL_VERIFY_PEER because the CA path does not exist.\n";
1145                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1146         }
1147 }
1148
1149 sub file_name_is_absolute {
1150         my ($path) = @_;
1151
1152         # msys does not grok DOS drive-prefixes
1153         if ($^O eq 'msys') {
1154                 return ($path =~ m#^/# || $path =~ m#^[a-zA-Z]\:#)
1155         }
1156
1157         require File::Spec::Functions;
1158         return File::Spec::Functions::file_name_is_absolute($path);
1159 }
1160
1161 # Returns 1 if the message was sent, and 0 otherwise.
1162 # In actuality, the whole program dies when there
1163 # is an error sending a message.
1164
1165 sub send_message {
1166         my @recipients = unique_email_list(@to);
1167         @cc = (grep { my $cc = extract_valid_address_or_die($_);
1168                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1169                     }
1170                @cc);
1171         my $to = join (",\n\t", @recipients);
1172         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1173         @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1174         my $date = format_2822_time($time++);
1175         my $gitversion = '@@GIT_VERSION@@';
1176         if ($gitversion =~ m/..GIT_VERSION../) {
1177             $gitversion = Git::version();
1178         }
1179
1180         my $cc = join(",\n\t", unique_email_list(@cc));
1181         my $ccline = "";
1182         if ($cc ne '') {
1183                 $ccline = "\nCc: $cc";
1184         }
1185         make_message_id() unless defined($message_id);
1186
1187         my $header = "From: $sender
1188 To: $to${ccline}
1189 Subject: $subject
1190 Date: $date
1191 Message-Id: $message_id
1192 ";
1193         if ($use_xmailer) {
1194                 $header .= "X-Mailer: git-send-email $gitversion\n";
1195         }
1196         if ($reply_to) {
1197
1198                 $header .= "In-Reply-To: $reply_to\n";
1199                 $header .= "References: $references\n";
1200         }
1201         if (@xh) {
1202                 $header .= join("\n", @xh) . "\n";
1203         }
1204
1205         my @sendmail_parameters = ('-i', @recipients);
1206         my $raw_from = $sender;
1207         if (defined $envelope_sender && $envelope_sender ne "auto") {
1208                 $raw_from = $envelope_sender;
1209         }
1210         $raw_from = extract_valid_address($raw_from);
1211         unshift (@sendmail_parameters,
1212                         '-f', $raw_from) if(defined $envelope_sender);
1213
1214         if ($needs_confirm && !$dry_run) {
1215                 print "\n$header\n";
1216                 if ($needs_confirm eq "inform") {
1217                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1218                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1219                         print "    The Cc list above has been expanded by additional\n";
1220                         print "    addresses found in the patch commit message. By default\n";
1221                         print "    send-email prompts before sending whenever this occurs.\n";
1222                         print "    This behavior is controlled by the sendemail.confirm\n";
1223                         print "    configuration setting.\n";
1224                         print "\n";
1225                         print "    For additional information, run 'git send-email --help'.\n";
1226                         print "    To retain the current behavior, but squelch this message,\n";
1227                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1228                 }
1229                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1230                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1231                          default => $ask_default);
1232                 die "Send this email reply required" unless defined $_;
1233                 if (/^n/i) {
1234                         return 0;
1235                 } elsif (/^q/i) {
1236                         cleanup_compose_files();
1237                         exit(0);
1238                 } elsif (/^a/i) {
1239                         $confirm = 'never';
1240                 }
1241         }
1242
1243         unshift (@sendmail_parameters, @smtp_server_options);
1244
1245         if ($dry_run) {
1246                 # We don't want to send the email.
1247         } elsif (file_name_is_absolute($smtp_server)) {
1248                 my $pid = open my $sm, '|-';
1249                 defined $pid or die $!;
1250                 if (!$pid) {
1251                         exec($smtp_server, @sendmail_parameters) or die $!;
1252                 }
1253                 print $sm "$header\n$message";
1254                 close $sm or die $!;
1255         } else {
1256
1257                 if (!defined $smtp_server) {
1258                         die "The required SMTP server is not properly defined."
1259                 }
1260
1261                 if ($smtp_encryption eq 'ssl') {
1262                         $smtp_server_port ||= 465; # ssmtp
1263                         require Net::SMTP::SSL;
1264                         $smtp_domain ||= maildomain();
1265                         require IO::Socket::SSL;
1266                         # Net::SMTP::SSL->new() does not forward any SSL options
1267                         IO::Socket::SSL::set_client_defaults(
1268                                 ssl_verify_params());
1269                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1270                                                       Hello => $smtp_domain,
1271                                                       Port => $smtp_server_port,
1272                                                       Debug => $debug_net_smtp);
1273                 }
1274                 else {
1275                         require Net::SMTP;
1276                         $smtp_domain ||= maildomain();
1277                         $smtp_server_port ||= 25;
1278                         $smtp ||= Net::SMTP->new($smtp_server,
1279                                                  Hello => $smtp_domain,
1280                                                  Debug => $debug_net_smtp,
1281                                                  Port => $smtp_server_port);
1282                         if ($smtp_encryption eq 'tls' && $smtp) {
1283                                 require Net::SMTP::SSL;
1284                                 $smtp->command('STARTTLS');
1285                                 $smtp->response();
1286                                 if ($smtp->code == 220) {
1287                                         $smtp = Net::SMTP::SSL->start_SSL($smtp,
1288                                                                           ssl_verify_params())
1289                                                 or die "STARTTLS failed! ".IO::Socket::SSL::errstr();
1290                                         $smtp_encryption = '';
1291                                         # Send EHLO again to receive fresh
1292                                         # supported commands
1293                                         $smtp->hello($smtp_domain);
1294                                 } else {
1295                                         die "Server does not support STARTTLS! ".$smtp->message;
1296                                 }
1297                         }
1298                 }
1299
1300                 if (!$smtp) {
1301                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1302                             "VALUES: server=$smtp_server ",
1303                             "encryption=$smtp_encryption ",
1304                             "hello=$smtp_domain",
1305                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1306                 }
1307
1308                 smtp_auth_maybe or die $smtp->message;
1309
1310                 $smtp->mail( $raw_from ) or die $smtp->message;
1311                 $smtp->to( @recipients ) or die $smtp->message;
1312                 $smtp->data or die $smtp->message;
1313                 $smtp->datasend("$header\n$message") or die $smtp->message;
1314                 $smtp->dataend() or die $smtp->message;
1315                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1316         }
1317         if ($quiet) {
1318                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1319         } else {
1320                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1321                 if (!file_name_is_absolute($smtp_server)) {
1322                         print "Server: $smtp_server\n";
1323                         print "MAIL FROM:<$raw_from>\n";
1324                         foreach my $entry (@recipients) {
1325                             print "RCPT TO:<$entry>\n";
1326                         }
1327                 } else {
1328                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1329                 }
1330                 print $header, "\n";
1331                 if ($smtp) {
1332                         print "Result: ", $smtp->code, ' ',
1333                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1334                 } else {
1335                         print "Result: OK\n";
1336                 }
1337         }
1338
1339         return 1;
1340 }
1341
1342 $reply_to = $initial_reply_to;
1343 $references = $initial_reply_to || '';
1344 $subject = $initial_subject;
1345 $message_num = 0;
1346
1347 foreach my $t (@files) {
1348         open my $fh, "<", $t or die "can't open file $t";
1349
1350         my $author = undef;
1351         my $sauthor = undef;
1352         my $author_encoding;
1353         my $has_content_type;
1354         my $body_encoding;
1355         my $xfer_encoding;
1356         my $has_mime_version;
1357         @to = ();
1358         @cc = ();
1359         @xh = ();
1360         my $input_format = undef;
1361         my @header = ();
1362         $message = "";
1363         $message_num++;
1364         # First unfold multiline header fields
1365         while(<$fh>) {
1366                 last if /^\s*$/;
1367                 if (/^\s+\S/ and @header) {
1368                         chomp($header[$#header]);
1369                         s/^\s+/ /;
1370                         $header[$#header] .= $_;
1371             } else {
1372                         push(@header, $_);
1373                 }
1374         }
1375         # Now parse the header
1376         foreach(@header) {
1377                 if (/^From /) {
1378                         $input_format = 'mbox';
1379                         next;
1380                 }
1381                 chomp;
1382                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1383                         $input_format = 'mbox';
1384                 }
1385
1386                 if (defined $input_format && $input_format eq 'mbox') {
1387                         if (/^Subject:\s+(.*)$/i) {
1388                                 $subject = $1;
1389                         }
1390                         elsif (/^From:\s+(.*)$/i) {
1391                                 ($author, $author_encoding) = unquote_rfc2047($1);
1392                                 $sauthor = sanitize_address($author);
1393                                 next if $suppress_cc{'author'};
1394                                 next if $suppress_cc{'self'} and $sauthor eq $sender;
1395                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1396                                         $1, $_) unless $quiet;
1397                                 push @cc, $1;
1398                         }
1399                         elsif (/^To:\s+(.*)$/i) {
1400                                 foreach my $addr (parse_address_line($1)) {
1401                                         printf("(mbox) Adding to: %s from line '%s'\n",
1402                                                 $addr, $_) unless $quiet;
1403                                         push @to, $addr;
1404                                 }
1405                         }
1406                         elsif (/^Cc:\s+(.*)$/i) {
1407                                 foreach my $addr (parse_address_line($1)) {
1408                                         my $qaddr = unquote_rfc2047($addr);
1409                                         my $saddr = sanitize_address($qaddr);
1410                                         if ($saddr eq $sender) {
1411                                                 next if ($suppress_cc{'self'});
1412                                         } else {
1413                                                 next if ($suppress_cc{'cc'});
1414                                         }
1415                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1416                                                 $addr, $_) unless $quiet;
1417                                         push @cc, $addr;
1418                                 }
1419                         }
1420                         elsif (/^Content-type:/i) {
1421                                 $has_content_type = 1;
1422                                 if (/charset="?([^ "]+)/) {
1423                                         $body_encoding = $1;
1424                                 }
1425                                 push @xh, $_;
1426                         }
1427                         elsif (/^MIME-Version/i) {
1428                                 $has_mime_version = 1;
1429                                 push @xh, $_;
1430                         }
1431                         elsif (/^Message-Id: (.*)/i) {
1432                                 $message_id = $1;
1433                         }
1434                         elsif (/^Content-Transfer-Encoding: (.*)/i) {
1435                                 $xfer_encoding = $1 if not defined $xfer_encoding;
1436                         }
1437                         elsif (!/^Date:\s/i && /^[-A-Za-z]+:\s+\S/) {
1438                                 push @xh, $_;
1439                         }
1440
1441                 } else {
1442                         # In the traditional
1443                         # "send lots of email" format,
1444                         # line 1 = cc
1445                         # line 2 = subject
1446                         # So let's support that, too.
1447                         $input_format = 'lots';
1448                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1449                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1450                                         $_, $_) unless $quiet;
1451                                 push @cc, $_;
1452                         } elsif (!defined $subject) {
1453                                 $subject = $_;
1454                         }
1455                 }
1456         }
1457         # Now parse the message body
1458         while(<$fh>) {
1459                 $message .=  $_;
1460                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1461                         chomp;
1462                         my ($what, $c) = ($1, $2);
1463                         chomp $c;
1464                         my $sc = sanitize_address($c);
1465                         if ($sc eq $sender) {
1466                                 next if ($suppress_cc{'self'});
1467                         } else {
1468                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1469                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1470                         }
1471                         push @cc, $c;
1472                         printf("(body) Adding cc: %s from line '%s'\n",
1473                                 $c, $_) unless $quiet;
1474                 }
1475         }
1476         close $fh;
1477
1478         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1479                 if defined $to_cmd;
1480         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1481                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1482
1483         if ($broken_encoding{$t} && !$has_content_type) {
1484                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1485                 $has_content_type = 1;
1486                 push @xh, "Content-Type: text/plain; charset=$auto_8bit_encoding";
1487                 $body_encoding = $auto_8bit_encoding;
1488         }
1489
1490         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1491                 $subject = quote_subject($subject, $auto_8bit_encoding);
1492         }
1493
1494         if (defined $sauthor and $sauthor ne $sender) {
1495                 $message = "From: $author\n\n$message";
1496                 if (defined $author_encoding) {
1497                         if ($has_content_type) {
1498                                 if ($body_encoding eq $author_encoding) {
1499                                         # ok, we already have the right encoding
1500                                 }
1501                                 else {
1502                                         # uh oh, we should re-encode
1503                                 }
1504                         }
1505                         else {
1506                                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1507                                 $has_content_type = 1;
1508                                 push @xh,
1509                                   "Content-Type: text/plain; charset=$author_encoding";
1510                         }
1511                 }
1512         }
1513         if (defined $target_xfer_encoding) {
1514                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1515                 $message = apply_transfer_encoding(
1516                         $message, $xfer_encoding, $target_xfer_encoding);
1517                 $xfer_encoding = $target_xfer_encoding;
1518         }
1519         if (defined $xfer_encoding) {
1520                 push @xh, "Content-Transfer-Encoding: $xfer_encoding";
1521         }
1522         if (defined $xfer_encoding or $has_content_type) {
1523                 unshift @xh, 'MIME-Version: 1.0' unless $has_mime_version;
1524         }
1525
1526         $needs_confirm = (
1527                 $confirm eq "always" or
1528                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1529                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1530         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1531
1532         @to = process_address_list(@to);
1533         @cc = process_address_list(@cc);
1534
1535         @to = (@initial_to, @to);
1536         @cc = (@initial_cc, @cc);
1537
1538         if ($message_num == 1) {
1539                 if (defined $cover_cc and $cover_cc) {
1540                         @initial_cc = @cc;
1541                 }
1542                 if (defined $cover_to and $cover_to) {
1543                         @initial_to = @to;
1544                 }
1545         }
1546
1547         my $message_was_sent = send_message();
1548
1549         # set up for the next message
1550         if ($thread && $message_was_sent &&
1551                 ($chain_reply_to || !defined $reply_to || length($reply_to) == 0 ||
1552                 $message_num == 1)) {
1553                 $reply_to = $message_id;
1554                 if (length $references > 0) {
1555                         $references .= "\n $message_id";
1556                 } else {
1557                         $references = "$message_id";
1558                 }
1559         }
1560         $message_id = undef;
1561 }
1562
1563 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1564 # and return a results array
1565 sub recipients_cmd {
1566         my ($prefix, $what, $cmd, $file) = @_;
1567
1568         my @addresses = ();
1569         open my $fh, "-|", "$cmd \Q$file\E"
1570             or die "($prefix) Could not execute '$cmd'";
1571         while (my $address = <$fh>) {
1572                 $address =~ s/^\s*//g;
1573                 $address =~ s/\s*$//g;
1574                 $address = sanitize_address($address);
1575                 next if ($address eq $sender and $suppress_cc{'self'});
1576                 push @addresses, $address;
1577                 printf("($prefix) Adding %s: %s from: '%s'\n",
1578                        $what, $address, $cmd) unless $quiet;
1579                 }
1580         close $fh
1581             or die "($prefix) failed to close pipe to '$cmd'";
1582         return @addresses;
1583 }
1584
1585 cleanup_compose_files();
1586
1587 sub cleanup_compose_files {
1588         unlink($compose_filename, $compose_filename . ".final") if $compose;
1589 }
1590
1591 $smtp->quit if $smtp;
1592
1593 sub apply_transfer_encoding {
1594         my $message = shift;
1595         my $from = shift;
1596         my $to = shift;
1597
1598         return $message if ($from eq $to and $from ne '7bit');
1599
1600         require MIME::QuotedPrint;
1601         require MIME::Base64;
1602
1603         $message = MIME::QuotedPrint::decode($message)
1604                 if ($from eq 'quoted-printable');
1605         $message = MIME::Base64::decode($message)
1606                 if ($from eq 'base64');
1607
1608         die "cannot send message as 7bit"
1609                 if ($to eq '7bit' and $message =~ /[^[:ascii:]]/);
1610         return $message
1611                 if ($to eq '7bit' or $to eq '8bit');
1612         return MIME::QuotedPrint::encode($message, "\n", 0)
1613                 if ($to eq 'quoted-printable');
1614         return MIME::Base64::encode($message, "\n")
1615                 if ($to eq 'base64');
1616         die "invalid transfer encoding";
1617 }
1618
1619 sub unique_email_list {
1620         my %seen;
1621         my @emails;
1622
1623         foreach my $entry (@_) {
1624                 my $clean = extract_valid_address_or_die($entry);
1625                 $seen{$clean} ||= 0;
1626                 next if $seen{$clean}++;
1627                 push @emails, $entry;
1628         }
1629         return @emails;
1630 }
1631
1632 sub validate_patch {
1633         my $fn = shift;
1634         open(my $fh, '<', $fn)
1635                 or die "unable to open $fn: $!\n";
1636         while (my $line = <$fh>) {
1637                 if (length($line) > 998) {
1638                         return "$.: patch contains a line longer than 998 characters";
1639                 }
1640         }
1641         return;
1642 }
1643
1644 sub file_has_nonascii {
1645         my $fn = shift;
1646         open(my $fh, '<', $fn)
1647                 or die "unable to open $fn: $!\n";
1648         while (my $line = <$fh>) {
1649                 return 1 if $line =~ /[^[:ascii:]]/;
1650         }
1651         return 0;
1652 }
1653
1654 sub body_or_subject_has_nonascii {
1655         my $fn = shift;
1656         open(my $fh, '<', $fn)
1657                 or die "unable to open $fn: $!\n";
1658         while (my $line = <$fh>) {
1659                 last if $line =~ /^$/;
1660                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1661         }
1662         while (my $line = <$fh>) {
1663                 return 1 if $line =~ /[^[:ascii:]]/;
1664         }
1665         return 0;
1666 }