git.oblomov.eu Git - git/blob - git-cvsimport.perl

   1 #!/usr/bin/perl -w
   2
   3 # This tool is copyright (c) 2005, Matthias Urlichs.
   4 # It is released under the Gnu Public License, version 2.
   5 #
   6 # The basic idea is to aggregate CVS check-ins into related changes.
   7 # Fortunately, "cvsps" does that for us; all we have to do is to parse
   8 # its output.
   9 #
  10 # Checking out the files is done by a single long-running CVS connection
  11 # / server process.
  12 #
  13 # The head revision is on branch "origin" by default.
  14 # You can change that with the '-o' option.
  15
  16 use strict;
  17 use warnings;
  18 use Getopt::Std;
  19 use File::Spec;
  20 use File::Temp qw(tempfile tmpnam);
  21 use File::Path qw(mkpath);
  22 use File::Basename qw(basename dirname);
  23 use Time::Local;
  24 use IO::Socket;
  25 use IO::Pipe;
  26 use POSIX qw(strftime dup2 ENOENT);
  27 use IPC::Open2;
  28
  29 $SIG{'PIPE'}="IGNORE";
  30 $ENV{'TZ'}="UTC";
  31
  32 our ($opt_h,$opt_o,$opt_v,$opt_k,$opt_u,$opt_d,$opt_p,$opt_C,$opt_z,$opt_i,$opt_P, $opt_s,$opt_m,$opt_M,$opt_A,$opt_S,$opt_L, $opt_a);
  33 my (%conv_author_name, %conv_author_email);
  34
  35 sub usage() {
  36         print STDERR <<END;
  37 Usage: ${\basename $0}     # fetch/update GIT from CVS
  38        [-o branch-for-HEAD] [-h] [-v] [-d CVSROOT] [-A author-conv-file]
  39        [-p opts-for-cvsps] [-C GIT_repository] [-z fuzz] [-i] [-k] [-u]
  40        [-s subst] [-a] [-m] [-M regex] [-S regex] [CVS_module]
  41 END
  42         exit(1);
  43 }
  44
  45 sub read_author_info($) {
  46         my ($file) = @_;
  47         my $user;
  48         open my $f, '<', "$file" or die("Failed to open $file: $!\n");
  49
  50         while (<$f>) {
  51                 # Expected format is this:
  52                 #   exon=Andreas Ericsson <ae@op5.se>
  53                 if (m/^(\S+?)\s*=\s*(.+?)\s*<(.+)>\s*$/) {
  54                         $user = $1;
  55                         $conv_author_name{$user} = $2;
  56                         $conv_author_email{$user} = $3;
  57                 }
  58                 # However, we also read from CVSROOT/users format
  59                 # to ease migration.
  60                 elsif (/^(\w+):(['"]?)(.+?)\2\s*$/) {
  61                         my $mapped;
  62                         ($user, $mapped) = ($1, $3);
  63                         if ($mapped =~ /^\s*(.*?)\s*<(.*)>\s*$/) {
  64                                 $conv_author_name{$user} = $1;
  65                                 $conv_author_email{$user} = $2;
  66                         }
  67                         elsif ($mapped =~ /^<?(.*)>?$/) {
  68                                 $conv_author_name{$user} = $user;
  69                                 $conv_author_email{$user} = $1;
  70                         }
  71                 }
  72                 # NEEDSWORK: Maybe warn on unrecognized lines?
  73         }
  74         close ($f);
  75 }
  76
  77 sub write_author_info($) {
  78         my ($file) = @_;
  79         open my $f, '>', $file or
  80           die("Failed to open $file for writing: $!");
  81
  82         foreach (keys %conv_author_name) {
  83                 print $f "$_=$conv_author_name{$_} <$conv_author_email{$_}>\n";
  84         }
  85         close ($f);
  86 }
  87
  88 getopts("hivmkuo:d:p:C:z:s:M:P:A:S:L:") or usage();
  89 usage if $opt_h;
  90
  91 @ARGV <= 1 or usage();
  92
  93 if ($opt_d) {
  94         $ENV{"CVSROOT"} = $opt_d;
  95 } elsif (-f 'CVS/Root') {
  96         open my $f, '<', 'CVS/Root' or die 'Failed to open CVS/Root';
  97         $opt_d = <$f>;
  98         chomp $opt_d;
  99         close $f;
 100         $ENV{"CVSROOT"} = $opt_d;
 101 } elsif ($ENV{"CVSROOT"}) {
 102         $opt_d = $ENV{"CVSROOT"};
 103 } else {
 104         die "CVSROOT needs to be set";
 105 }
 106 $opt_o ||= "origin";
 107 $opt_s ||= "-";
 108 $opt_a ||= 0;
 109
 110 my $git_tree = $opt_C;
 111 $git_tree ||= ".";
 112
 113 my $cvs_tree;
 114 if ($#ARGV == 0) {
 115         $cvs_tree = $ARGV[0];
 116 } elsif (-f 'CVS/Repository') {
 117         open my $f, '<', 'CVS/Repository' or
 118             die 'Failed to open CVS/Repository';
 119         $cvs_tree = <$f>;
 120         chomp $cvs_tree;
 121         close $f;
 122 } else {
 123         usage();
 124 }
 125
 126 our @mergerx = ();
 127 if ($opt_m) {
 128         @mergerx = ( qr/\W(?:from|of|merge|merging|merged) (\w+)/i );
 129 }
 130 if ($opt_M) {
 131         push (@mergerx, qr/$opt_M/);
 132 }
 133
 134 # Remember UTC of our starting time
 135 # we'll want to avoid importing commits
 136 # that are too recent
 137 our $starttime = time();
 138
 139 select(STDERR); $|=1; select(STDOUT);
 140
 141
 142 package CVSconn;
 143 # Basic CVS dialog.
 144 # We're only interested in connecting and downloading, so ...
 145
 146 use File::Spec;
 147 use File::Temp qw(tempfile);
 148 use POSIX qw(strftime dup2);
 149
 150 sub new {
 151         my ($what,$repo,$subdir) = @_;
 152         $what=ref($what) if ref($what);
 153
 154         my $self = {};
 155         $self->{'buffer'} = "";
 156         bless($self,$what);
 157
 158         $repo =~ s#/+$##;
 159         $self->{'fullrep'} = $repo;
 160         $self->conn();
 161
 162         $self->{'subdir'} = $subdir;
 163         $self->{'lines'} = undef;
 164
 165         return $self;
 166 }
 167
 168 sub conn {
 169         my $self = shift;
 170         my $repo = $self->{'fullrep'};
 171         if ($repo =~ s/^:pserver(?:([^:]*)):(?:(.*?)(?::(.*?))?@)?([^:\/]*)(?::(\d*))?//) {
 172                 my ($param,$user,$pass,$serv,$port) = ($1,$2,$3,$4,$5);
 173
 174                 my ($proxyhost,$proxyport);
 175                 if ($param && ($param =~ m/proxy=([^;]+)/)) {
 176                         $proxyhost = $1;
 177                         # Default proxyport, if not specified, is 8080.
 178                         $proxyport = 8080;
 179                         if ($ENV{"CVS_PROXY_PORT"}) {
 180                                 $proxyport = $ENV{"CVS_PROXY_PORT"};
 181                         }
 182                         if ($param =~ m/proxyport=([^;]+)/) {
 183                                 $proxyport = $1;
 184                         }
 185                 }
 186
 187                 $user="anonymous" unless defined $user;
 188                 my $rr2 = "-";
 189                 unless ($port) {
 190                         $rr2 = ":pserver:$user\@$serv:$repo";
 191                         $port=2401;
 192                 }
 193                 my $rr = ":pserver:$user\@$serv:$port$repo";
 194
 195                 unless ($pass) {
 196                         open(H,$ENV{'HOME'}."/.cvspass") and do {
 197                                 # :pserver:cvs@mea.tmt.tele.fi:/cvsroot/zmailer Ah<Z
 198                                 while (<H>) {
 199                                         chomp;
 200                                         s/^\/\d+\s+//;
 201                                         my ($w,$p) = split(/\s/,$_,2);
 202                                         if ($w eq $rr or $w eq $rr2) {
 203                                                 $pass = $p;
 204                                                 last;
 205                                         }
 206                                 }
 207                         };
 208                 }
 209                 $pass="A" unless $pass;
 210
 211                 my ($s, $rep);
 212                 if ($proxyhost) {
 213
 214                         # Use a HTTP Proxy. Only works for HTTP proxies that
 215                         # don't require user authentication
 216                         #
 217                         # See: http://www.ietf.org/rfc/rfc2817.txt
 218
 219                         $s = IO::Socket::INET->new(PeerHost => $proxyhost, PeerPort => $proxyport);
 220                         die "Socket to $proxyhost: $!\n" unless defined $s;
 221                         $s->write("CONNECT $serv:$port HTTP/1.1\r\nHost: $serv:$port\r\n\r\n")
 222                                 or die "Write to $proxyhost: $!\n";
 223                         $s->flush();
 224
 225                         $rep = <$s>;
 226
 227                         # The answer should look like 'HTTP/1.x 2yy ....'
 228                         if (!($rep =~ m#^HTTP/1\.. 2[0-9][0-9]#)) {
 229                                 die "Proxy connect: $rep\n";
 230                         }
 231                         # Skip up to the empty line of the proxy server output
 232                         # including the response headers.
 233                         while ($rep = <$s>) {
 234                                 last if (!defined $rep ||
 235                                          $rep eq "\n" ||
 236                                          $rep eq "\r\n");
 237                         }
 238                 } else {
 239                         $s = IO::Socket::INET->new(PeerHost => $serv, PeerPort => $port);
 240                         die "Socket to $serv: $!\n" unless defined $s;
 241                 }
 242
 243                 $s->write("BEGIN AUTH REQUEST\n$repo\n$user\n$pass\nEND AUTH REQUEST\n")
 244                         or die "Write to $serv: $!\n";
 245                 $s->flush();
 246
 247                 $rep = <$s>;
 248
 249                 if ($rep ne "I LOVE YOU\n") {
 250                         $rep="<unknown>" unless $rep;
 251                         die "AuthReply: $rep\n";
 252                 }
 253                 $self->{'socketo'} = $s;
 254                 $self->{'socketi'} = $s;
 255         } else { # local or ext: Fork off our own cvs server.
 256                 my $pr = IO::Pipe->new();
 257                 my $pw = IO::Pipe->new();
 258                 my $pid = fork();
 259                 die "Fork: $!\n" unless defined $pid;
 260                 my $cvs = 'cvs';
 261                 $cvs = $ENV{CVS_SERVER} if exists $ENV{CVS_SERVER};
 262                 my $rsh = 'rsh';
 263                 $rsh = $ENV{CVS_RSH} if exists $ENV{CVS_RSH};
 264
 265                 my @cvs = ($cvs, 'server');
 266                 my ($local, $user, $host);
 267                 $local = $repo =~ s/:local://;
 268                 if (!$local) {
 269                     $repo =~ s/:ext://;
 270                     $local = !($repo =~ s/^(?:([^\@:]+)\@)?([^:]+)://);
 271                     ($user, $host) = ($1, $2);
 272                 }
 273                 if (!$local) {
 274                     if ($user) {
 275                         unshift @cvs, $rsh, '-l', $user, $host;
 276                     } else {
 277                         unshift @cvs, $rsh, $host;
 278                     }
 279                 }
 280
 281                 unless ($pid) {
 282                         $pr->writer();
 283                         $pw->reader();
 284                         dup2($pw->fileno(),0);
 285                         dup2($pr->fileno(),1);
 286                         $pr->close();
 287                         $pw->close();
 288                         exec(@cvs);
 289                 }
 290                 $pw->writer();
 291                 $pr->reader();
 292                 $self->{'socketo'} = $pw;
 293                 $self->{'socketi'} = $pr;
 294         }
 295         $self->{'socketo'}->write("Root $repo\n");
 296
 297         # Trial and error says that this probably is the minimum set
 298         $self->{'socketo'}->write("Valid-responses ok error Valid-requests Mode M Mbinary E Checked-in Created Updated Merged Removed\n");
 299
 300         $self->{'socketo'}->write("valid-requests\n");
 301         $self->{'socketo'}->flush();
 302
 303         chomp(my $rep=$self->readline());
 304         if ($rep !~ s/^Valid-requests\s*//) {
 305                 $rep="<unknown>" unless $rep;
 306                 die "Expected Valid-requests from server, but got: $rep\n";
 307         }
 308         chomp(my $res=$self->readline());
 309         die "validReply: $res\n" if $res ne "ok";
 310
 311         $self->{'socketo'}->write("UseUnchanged\n") if $rep =~ /\bUseUnchanged\b/;
 312         $self->{'repo'} = $repo;
 313 }
 314
 315 sub readline {
 316         my ($self) = @_;
 317         return $self->{'socketi'}->getline();
 318 }
 319
 320 sub _file {
 321         # Request a file with a given revision.
 322         # Trial and error says this is a good way to do it. :-/
 323         my ($self,$fn,$rev) = @_;
 324         $self->{'socketo'}->write("Argument -N\n") or return undef;
 325         $self->{'socketo'}->write("Argument -P\n") or return undef;
 326         # -kk: Linus' version doesn't use it - defaults to off
 327         if ($opt_k) {
 328             $self->{'socketo'}->write("Argument -kk\n") or return undef;
 329         }
 330         $self->{'socketo'}->write("Argument -r\n") or return undef;
 331         $self->{'socketo'}->write("Argument $rev\n") or return undef;
 332         $self->{'socketo'}->write("Argument --\n") or return undef;
 333         $self->{'socketo'}->write("Argument $self->{'subdir'}/$fn\n") or return undef;
 334         $self->{'socketo'}->write("Directory .\n") or return undef;
 335         $self->{'socketo'}->write("$self->{'repo'}\n") or return undef;
 336         # $self->{'socketo'}->write("Sticky T1.0\n") or return undef;
 337         $self->{'socketo'}->write("co\n") or return undef;
 338         $self->{'socketo'}->flush() or return undef;
 339         $self->{'lines'} = 0;
 340         return 1;
 341 }
 342 sub _line {
 343         # Read a line from the server.
 344         # ... except that 'line' may be an entire file. ;-)
 345         my ($self, $fh) = @_;
 346         die "Not in lines" unless defined $self->{'lines'};
 347
 348         my $line;
 349         my $res=0;
 350         while (defined($line = $self->readline())) {
 351                 # M U gnupg-cvs-rep/AUTHORS
 352                 # Updated gnupg-cvs-rep/
 353                 # /daten/src/rsync/gnupg-cvs-rep/AUTHORS
 354                 # /AUTHORS/1.1///T1.1
 355                 # u=rw,g=rw,o=rw
 356                 # 0
 357                 # ok
 358
 359                 if ($line =~ s/^(?:Created|Updated) //) {
 360                         $line = $self->readline(); # path
 361                         $line = $self->readline(); # Entries line
 362                         my $mode = $self->readline(); chomp $mode;
 363                         $self->{'mode'} = $mode;
 364                         defined (my $cnt = $self->readline())
 365                                 or die "EOF from server after 'Changed'\n";
 366                         chomp $cnt;
 367                         die "Duh: Filesize $cnt" if $cnt !~ /^\d+$/;
 368                         $line="";
 369                         $res = $self->_fetchfile($fh, $cnt);
 370                 } elsif ($line =~ s/^ //) {
 371                         print $fh $line;
 372                         $res += length($line);
 373                 } elsif ($line =~ /^M\b/) {
 374                         # output, do nothing
 375                 } elsif ($line =~ /^Mbinary\b/) {
 376                         my $cnt;
 377                         die "EOF from server after 'Mbinary'" unless defined ($cnt = $self->readline());
 378                         chomp $cnt;
 379                         die "Duh: Mbinary $cnt" if $cnt !~ /^\d+$/ or $cnt<1;
 380                         $line="";
 381                         $res += $self->_fetchfile($fh, $cnt);
 382                 } else {
 383                         chomp $line;
 384                         if ($line eq "ok") {
 385                                 # print STDERR "S: ok (".length($res).")\n";
 386                                 return $res;
 387                         } elsif ($line =~ s/^E //) {
 388                                 # print STDERR "S: $line\n";
 389                         } elsif ($line =~ /^(Remove-entry|Removed) /i) {
 390                                 $line = $self->readline(); # filename
 391                                 $line = $self->readline(); # OK
 392                                 chomp $line;
 393                                 die "Unknown: $line" if $line ne "ok";
 394                                 return -1;
 395                         } else {
 396                                 die "Unknown: $line\n";
 397                         }
 398                 }
 399         }
 400         return undef;
 401 }
 402 sub file {
 403         my ($self,$fn,$rev) = @_;
 404         my $res;
 405
 406         my ($fh, $name) = tempfile('gitcvs.XXXXXX',
 407                     DIR => File::Spec->tmpdir(), UNLINK => 1);
 408
 409         $self->_file($fn,$rev) and $res = $self->_line($fh);
 410
 411         if (!defined $res) {
 412             print STDERR "Server has gone away while fetching $fn $rev, retrying...\n";
 413             truncate $fh, 0;
 414             $self->conn();
 415             $self->_file($fn,$rev) or die "No file command send";
 416             $res = $self->_line($fh);
 417             die "Retry failed" unless defined $res;
 418         }
 419         close ($fh);
 420
 421         return ($name, $res);
 422 }
 423 sub _fetchfile {
 424         my ($self, $fh, $cnt) = @_;
 425         my $res = 0;
 426         my $bufsize = 1024 * 1024;
 427         while ($cnt) {
 428             if ($bufsize > $cnt) {
 429                 $bufsize = $cnt;
 430             }
 431             my $buf;
 432             my $num = $self->{'socketi'}->read($buf,$bufsize);
 433             die "Server: Filesize $cnt: $num: $!\n" if not defined $num or $num<=0;
 434             print $fh $buf;
 435             $res += $num;
 436             $cnt -= $num;
 437         }
 438         return $res;
 439 }
 440
 441
 442 package main;
 443
 444 my $cvs = CVSconn->new($opt_d, $cvs_tree);
 445
 446
 447 sub pdate($) {
 448         my ($d) = @_;
 449         m#(\d{2,4})/(\d\d)/(\d\d)\s(\d\d):(\d\d)(?::(\d\d))?#
 450                 or die "Unparseable date: $d\n";
 451         my $y=$1; $y-=1900 if $y>1900;
 452         return timegm($6||0,$5,$4,$3,$2-1,$y);
 453 }
 454
 455 sub pmode($) {
 456         my ($mode) = @_;
 457         my $m = 0;
 458         my $mm = 0;
 459         my $um = 0;
 460         for my $x(split(//,$mode)) {
 461                 if ($x eq ",") {
 462                         $m |= $mm&$um;
 463                         $mm = 0;
 464                         $um = 0;
 465                 } elsif ($x eq "u") { $um |= 0700;
 466                 } elsif ($x eq "g") { $um |= 0070;
 467                 } elsif ($x eq "o") { $um |= 0007;
 468                 } elsif ($x eq "r") { $mm |= 0444;
 469                 } elsif ($x eq "w") { $mm |= 0222;
 470                 } elsif ($x eq "x") { $mm |= 0111;
 471                 } elsif ($x eq "=") { # do nothing
 472                 } else { die "Unknown mode: $mode\n";
 473                 }
 474         }
 475         $m |= $mm&$um;
 476         return $m;
 477 }
 478
 479 sub getwd() {
 480         my $pwd = `pwd`;
 481         chomp $pwd;
 482         return $pwd;
 483 }
 484
 485 sub is_sha1 {
 486         my $s = shift;
 487         return $s =~ /^[a-f0-9]{40}$/;
 488 }
 489
 490 sub get_headref ($$) {
 491     my $name    = shift;
 492     my $git_dir = shift;
 493
 494     my $f = "$git_dir/refs/heads/$name";
 495     if (open(my $fh, $f)) {
 496             chomp(my $r = <$fh>);
 497             is_sha1($r) or die "Cannot get head id for $name ($r): $!";
 498             return $r;
 499     }
 500     die "unable to open $f: $!" unless $! == POSIX::ENOENT;
 501     return undef;
 502 }
 503
 504 -d $git_tree
 505         or mkdir($git_tree,0777)
 506         or die "Could not create $git_tree: $!";
 507 chdir($git_tree);
 508
 509 my $last_branch = "";
 510 my $orig_branch = "";
 511 my %branch_date;
 512 my $tip_at_start = undef;
 513
 514 my $git_dir = $ENV{"GIT_DIR"} || ".git";
 515 $git_dir = getwd()."/".$git_dir unless $git_dir =~ m#^/#;
 516 $ENV{"GIT_DIR"} = $git_dir;
 517 my $orig_git_index;
 518 $orig_git_index = $ENV{GIT_INDEX_FILE} if exists $ENV{GIT_INDEX_FILE};
 519
 520 my %index; # holds filenames of one index per branch
 521
 522 unless (-d $git_dir) {
 523         system("git-init-db");
 524         die "Cannot init the GIT db at $git_tree: $?\n" if $?;
 525         system("git-read-tree");
 526         die "Cannot init an empty tree: $?\n" if $?;
 527
 528         $last_branch = $opt_o;
 529         $orig_branch = "";
 530 } else {
 531         -f "$git_dir/refs/heads/$opt_o"
 532                 or die "Branch '$opt_o' does not exist.\n".
 533                        "Either use the correct '-o branch' option,\n".
 534                        "or import to a new repository.\n";
 535
 536         open(F, "git-symbolic-ref HEAD |") or
 537                 die "Cannot run git-symbolic-ref: $!\n";
 538         chomp ($last_branch = <F>);
 539         $last_branch = basename($last_branch);
 540         close(F);
 541         unless ($last_branch) {
 542                 warn "Cannot read the last branch name: $! -- assuming 'master'\n";
 543                 $last_branch = "master";
 544         }
 545         $orig_branch = $last_branch;
 546         $tip_at_start = `git-rev-parse --verify HEAD`;
 547
 548         # Get the last import timestamps
 549         my $fmt = '($ref, $author) = (%(refname), %(author));';
 550         open(H, "git-for-each-ref --perl --format='$fmt' refs/heads |") or
 551                 die "Cannot run git-for-each-ref: $!\n";
 552         while (defined(my $entry = <H>)) {
 553                 my ($ref, $author);
 554                 eval($entry) || die "cannot eval refs list: $@";
 555                 my ($head) = ($ref =~ m|^refs/heads/(.*)|);
 556                 $author =~ /^.*\s(\d+)\s[-+]\d{4}$/;
 557                 $branch_date{$head} = $1;
 558         }
 559         close(H);
 560 }
 561
 562 -d $git_dir
 563         or die "Could not create git subdir ($git_dir).\n";
 564
 565 # now we read (and possibly save) author-info as well
 566 -f "$git_dir/cvs-authors" and
 567   read_author_info("$git_dir/cvs-authors");
 568 if ($opt_A) {
 569         read_author_info($opt_A);
 570         write_author_info("$git_dir/cvs-authors");
 571 }
 572
 573
 574 #
 575 # run cvsps into a file unless we are getting
 576 # it passed as a file via $opt_P
 577 #
 578 unless ($opt_P) {
 579         print "Running cvsps...\n" if $opt_v;
 580         my $pid = open(CVSPS,"-|");
 581         die "Cannot fork: $!\n" unless defined $pid;
 582         unless ($pid) {
 583                 my @opt;
 584                 @opt = split(/,/,$opt_p) if defined $opt_p;
 585                 unshift @opt, '-z', $opt_z if defined $opt_z;
 586                 unshift @opt, '-q'         unless defined $opt_v;
 587                 unless (defined($opt_p) && $opt_p =~ m/--no-cvs-direct/) {
 588                         push @opt, '--cvs-direct';
 589                 }
 590                 exec("cvsps","--norc",@opt,"-u","-A",'--root',$opt_d,$cvs_tree);
 591                 die "Could not start cvsps: $!\n";
 592         }
 593         my ($cvspsfh, $cvspsfile) = tempfile('gitXXXXXX', SUFFIX => '.cvsps',
 594                                              DIR => File::Spec->tmpdir());
 595         while (<CVSPS>) {
 596             print $cvspsfh $_;
 597         }
 598         close CVSPS;
 599         close $cvspsfh;
 600         $opt_P = $cvspsfile;
 601 }
 602
 603
 604 open(CVS, "<$opt_P") or die $!;
 605
 606 ## cvsps output:
 607 #---------------------
 608 #PatchSet 314
 609 #Date: 1999/09/18 13:03:59
 610 #Author: wkoch
 611 #Branch: STABLE-BRANCH-1-0
 612 #Ancestor branch: HEAD
 613 #Tag: (none)
 614 #Log:
 615 #    See ChangeLog: Sat Sep 18 13:03:28 CEST 1999  Werner Koch
 616 #Members:
 617 #       README:1.57->1.57.2.1
 618 #       VERSION:1.96->1.96.2.1
 619 #
 620 #---------------------
 621
 622 my $state = 0;
 623
 624 sub update_index (\@\@) {
 625         my $old = shift;
 626         my $new = shift;
 627         open(my $fh, '|-', qw(git-update-index -z --index-info))
 628                 or die "unable to open git-update-index: $!";
 629         print $fh
 630                 (map { "0 0000000000000000000000000000000000000000\t$_\0" }
 631                         @$old),
 632                 (map { '100' . sprintf('%o', $_->[0]) . " $_->[1]\t$_->[2]\0" }
 633                         @$new)
 634                 or die "unable to write to git-update-index: $!";
 635         close $fh
 636                 or die "unable to write to git-update-index: $!";
 637         $? and die "git-update-index reported error: $?";
 638 }
 639
 640 sub write_tree () {
 641         open(my $fh, '-|', qw(git-write-tree))
 642                 or die "unable to open git-write-tree: $!";
 643         chomp(my $tree = <$fh>);
 644         is_sha1($tree)
 645                 or die "Cannot get tree id ($tree): $!";
 646         close($fh)
 647                 or die "Error running git-write-tree: $?\n";
 648         print "Tree ID $tree\n" if $opt_v;
 649         return $tree;
 650 }
 651
 652 my ($patchset,$date,$author_name,$author_email,$branch,$ancestor,$tag,$logmsg);
 653 my (@old,@new,@skipped,%ignorebranch);
 654
 655 # commits that cvsps cannot place anywhere...
 656 $ignorebranch{'#CVSPS_NO_BRANCH'} = 1;
 657
 658 sub commit {
 659         if ($branch eq $opt_o && !$index{branch} && !get_headref($branch, $git_dir)) {
 660             # looks like an initial commit
 661             # use the index primed by git-init-db
 662             $ENV{GIT_INDEX_FILE} = '.git/index';
 663             $index{$branch} = '.git/index';
 664         } else {
 665             # use an index per branch to speed up
 666             # imports of projects with many branches
 667             unless ($index{$branch}) {
 668                 $index{$branch} = tmpnam();
 669                 $ENV{GIT_INDEX_FILE} = $index{$branch};
 670                 if ($ancestor) {
 671                     system("git-read-tree", $ancestor);
 672                 } else {
 673                     system("git-read-tree", $branch);
 674                 }
 675                 die "read-tree failed: $?\n" if $?;
 676             }
 677         }
 678         $ENV{GIT_INDEX_FILE} = $index{$branch};
 679
 680         update_index(@old, @new);
 681         @old = @new = ();
 682         my $tree = write_tree();
 683         my $parent = get_headref($last_branch, $git_dir);
 684         print "Parent ID " . ($parent ? $parent : "(empty)") . "\n" if $opt_v;
 685
 686         my @commit_args;
 687         push @commit_args, ("-p", $parent) if $parent;
 688
 689         # loose detection of merges
 690         # based on the commit msg
 691         foreach my $rx (@mergerx) {
 692                 next unless $logmsg =~ $rx && $1;
 693                 my $mparent = $1 eq 'HEAD' ? $opt_o : $1;
 694                 if (my $sha1 = get_headref($mparent, $git_dir)) {
 695                         push @commit_args, '-p', $mparent;
 696                         print "Merge parent branch: $mparent\n" if $opt_v;
 697                 }
 698         }
 699
 700         my $commit_date = strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date));
 701         $ENV{GIT_AUTHOR_NAME} = $author_name;
 702         $ENV{GIT_AUTHOR_EMAIL} = $author_email;
 703         $ENV{GIT_AUTHOR_DATE} = $commit_date;
 704         $ENV{GIT_COMMITTER_NAME} = $author_name;
 705         $ENV{GIT_COMMITTER_EMAIL} = $author_email;
 706         $ENV{GIT_COMMITTER_DATE} = $commit_date;
 707         my $pid = open2(my $commit_read, my $commit_write,
 708                 'git-commit-tree', $tree, @commit_args);
 709
 710         # compatibility with git2cvs
 711         substr($logmsg,32767) = "" if length($logmsg) > 32767;
 712         $logmsg =~ s/[\s\n]+\z//;
 713
 714         if (@skipped) {
 715             $logmsg .= "\n\n\nSKIPPED:\n\t";
 716             $logmsg .= join("\n\t", @skipped) . "\n";
 717             @skipped = ();
 718         }
 719
 720         print($commit_write "$logmsg\n") && close($commit_write)
 721                 or die "Error writing to git-commit-tree: $!\n";
 722
 723         print "Committed patch $patchset ($branch $commit_date)\n" if $opt_v;
 724         chomp(my $cid = <$commit_read>);
 725         is_sha1($cid) or die "Cannot get commit id ($cid): $!\n";
 726         print "Commit ID $cid\n" if $opt_v;
 727         close($commit_read);
 728
 729         waitpid($pid,0);
 730         die "Error running git-commit-tree: $?\n" if $?;
 731
 732         system("git-update-ref refs/heads/$branch $cid") == 0
 733                 or die "Cannot write branch $branch for update: $!\n";
 734
 735         if ($tag) {
 736                 my ($in, $out) = ('','');
 737                 my ($xtag) = $tag;
 738                 $xtag =~ s/\s+\*\*.*$//; # Remove stuff like ** INVALID ** and ** FUNKY **
 739                 $xtag =~ tr/_/\./ if ( $opt_u );
 740                 $xtag =~ s/[\/]/$opt_s/g;
 741
 742                 my $pid = open2($in, $out, 'git-mktag');
 743                 print $out "object $cid\n".
 744                     "type commit\n".
 745                     "tag $xtag\n".
 746                     "tagger $author_name <$author_email>\n"
 747                     or die "Cannot create tag object $xtag: $!\n";
 748                 close($out)
 749                     or die "Cannot create tag object $xtag: $!\n";
 750
 751                 my $tagobj = <$in>;
 752                 chomp $tagobj;
 753
 754                 if ( !close($in) or waitpid($pid, 0) != $pid or
 755                      $? != 0 or $tagobj !~ /^[0123456789abcdef]{40}$/ ) {
 756                     die "Cannot create tag object $xtag: $!\n";
 757                 }
 758
 759
 760                 open(C,">$git_dir/refs/tags/$xtag")
 761                         or die "Cannot create tag $xtag: $!\n";
 762                 print C "$tagobj\n"
 763                         or die "Cannot write tag $xtag: $!\n";
 764                 close(C)
 765                         or die "Cannot write tag $xtag: $!\n";
 766
 767                 print "Created tag '$xtag' on '$branch'\n" if $opt_v;
 768         }
 769 };
 770
 771 my $commitcount = 1;
 772 while (<CVS>) {
 773         chomp;
 774         if ($state == 0 and /^-+$/) {
 775                 $state = 1;
 776         } elsif ($state == 0) {
 777                 $state = 1;
 778                 redo;
 779         } elsif (($state==0 or $state==1) and s/^PatchSet\s+//) {
 780                 $patchset = 0+$_;
 781                 $state=2;
 782         } elsif ($state == 2 and s/^Date:\s+//) {
 783                 $date = pdate($_);
 784                 unless ($date) {
 785                         print STDERR "Could not parse date: $_\n";
 786                         $state=0;
 787                         next;
 788                 }
 789                 $state=3;
 790         } elsif ($state == 3 and s/^Author:\s+//) {
 791                 s/\s+$//;
 792                 if (/^(.*?)\s+<(.*)>/) {
 793                     ($author_name, $author_email) = ($1, $2);
 794                 } elsif ($conv_author_name{$_}) {
 795                         $author_name = $conv_author_name{$_};
 796                         $author_email = $conv_author_email{$_};
 797                 } else {
 798                     $author_name = $author_email = $_;
 799                 }
 800                 $state = 4;
 801         } elsif ($state == 4 and s/^Branch:\s+//) {
 802                 s/\s+$//;
 803                 s/[\/]/$opt_s/g;
 804                 $branch = $_;
 805                 $state = 5;
 806         } elsif ($state == 5 and s/^Ancestor branch:\s+//) {
 807                 s/\s+$//;
 808                 $ancestor = $_;
 809                 $ancestor = $opt_o if $ancestor eq "HEAD";
 810                 $state = 6;
 811         } elsif ($state == 5) {
 812                 $ancestor = undef;
 813                 $state = 6;
 814                 redo;
 815         } elsif ($state == 6 and s/^Tag:\s+//) {
 816                 s/\s+$//;
 817                 if ($_ eq "(none)") {
 818                         $tag = undef;
 819                 } else {
 820                         $tag = $_;
 821                 }
 822                 $state = 7;
 823         } elsif ($state == 7 and /^Log:/) {
 824                 $logmsg = "";
 825                 $state = 8;
 826         } elsif ($state == 8 and /^Members:/) {
 827                 $branch = $opt_o if $branch eq "HEAD";
 828                 if (defined $branch_date{$branch} and $branch_date{$branch} >= $date) {
 829                         # skip
 830                         print "skip patchset $patchset: $date before $branch_date{$branch}\n" if $opt_v;
 831                         $state = 11;
 832                         next;
 833                 }
 834                 if (!$opt_a && $starttime - 300 - (defined $opt_z ? $opt_z : 300) <= $date) {
 835                         # skip if the commit is too recent
 836                         # that the cvsps default fuzz is 300s, we give ourselves another
 837                         # 300s just in case -- this also prevents skipping commits
 838                         # due to server clock drift
 839                         print "skip patchset $patchset: $date too recent\n" if $opt_v;
 840                         $state = 11;
 841                         next;
 842                 }
 843                 if (exists $ignorebranch{$branch}) {
 844                         print STDERR "Skipping $branch\n";
 845                         $state = 11;
 846                         next;
 847                 }
 848                 if ($ancestor) {
 849                         if ($ancestor eq $branch) {
 850                                 print STDERR "Branch $branch erroneously stems from itself -- changed ancestor to $opt_o\n";
 851                                 $ancestor = $opt_o;
 852                         }
 853                         if (-f "$git_dir/refs/heads/$branch") {
 854                                 print STDERR "Branch $branch already exists!\n";
 855                                 $state=11;
 856                                 next;
 857                         }
 858                         unless (open(H,"$git_dir/refs/heads/$ancestor")) {
 859                                 print STDERR "Branch $ancestor does not exist!\n";
 860                                 $ignorebranch{$branch} = 1;
 861                                 $state=11;
 862                                 next;
 863                         }
 864                         chomp(my $id = <H>);
 865                         close(H);
 866                         unless (open(H,"> $git_dir/refs/heads/$branch")) {
 867                                 print STDERR "Could not create branch $branch: $!\n";
 868                                 $ignorebranch{$branch} = 1;
 869                                 $state=11;
 870                                 next;
 871                         }
 872                         print H "$id\n"
 873                                 or die "Could not write branch $branch: $!";
 874                         close(H)
 875                                 or die "Could not write branch $branch: $!";
 876                 }
 877                 $last_branch = $branch if $branch ne $last_branch;
 878                 $state = 9;
 879         } elsif ($state == 8) {
 880                 $logmsg .= "$_\n";
 881         } elsif ($state == 9 and /^\s+(.+?):(INITIAL|\d+(?:\.\d+)+)->(\d+(?:\.\d+)+)\s*$/) {
 882 #       VERSION:1.96->1.96.2.1
 883                 my $init = ($2 eq "INITIAL");
 884                 my $fn = $1;
 885                 my $rev = $3;
 886                 $fn =~ s#^/+##;
 887                 if ($opt_S && $fn =~ m/$opt_S/) {
 888                     print "SKIPPING $fn v $rev\n";
 889                     push(@skipped, $fn);
 890                     next;
 891                 }
 892                 print "Fetching $fn   v $rev\n" if $opt_v;
 893                 my ($tmpname, $size) = $cvs->file($fn,$rev);
 894                 if ($size == -1) {
 895                         push(@old,$fn);
 896                         print "Drop $fn\n" if $opt_v;
 897                 } else {
 898                         print "".($init ? "New" : "Update")." $fn: $size bytes\n" if $opt_v;
 899                         my $pid = open(my $F, '-|');
 900                         die $! unless defined $pid;
 901                         if (!$pid) {
 902                             exec("git-hash-object", "-w", $tmpname)
 903                                 or die "Cannot create object: $!\n";
 904                         }
 905                         my $sha = <$F>;
 906                         chomp $sha;
 907                         close $F;
 908                         my $mode = pmode($cvs->{'mode'});
 909                         push(@new,[$mode, $sha, $fn]); # may be resurrected!
 910                 }
 911                 unlink($tmpname);
 912         } elsif ($state == 9 and /^\s+(.+?):\d+(?:\.\d+)+->(\d+(?:\.\d+)+)\(DEAD\)\s*$/) {
 913                 my $fn = $1;
 914                 $fn =~ s#^/+##;
 915                 push(@old,$fn);
 916                 print "Delete $fn\n" if $opt_v;
 917         } elsif ($state == 9 and /^\s*$/) {
 918                 $state = 10;
 919         } elsif (($state == 9 or $state == 10) and /^-+$/) {
 920                 $commitcount++;
 921                 if ($opt_L && $commitcount > $opt_L) {
 922                         last;
 923                 }
 924                 commit();
 925                 if (($commitcount & 1023) == 0) {
 926                         system("git repack -a -d");
 927                 }
 928                 $state = 1;
 929         } elsif ($state == 11 and /^-+$/) {
 930                 $state = 1;
 931         } elsif (/^-+$/) { # end of unknown-line processing
 932                 $state = 1;
 933         } elsif ($state != 11) { # ignore stuff when skipping
 934                 print "* UNKNOWN LINE * $_\n";
 935         }
 936 }
 937 commit() if $branch and $state != 11;
 938
 939 # The heuristic of repacking every 1024 commits can leave a
 940 # lot of unpacked data.  If there is more than 1MB worth of
 941 # not-packed objects, repack once more.
 942 my $line = `git-count-objects`;
 943 if ($line =~ /^(\d+) objects, (\d+) kilobytes$/) {
 944   my ($n_objects, $kb) = ($1, $2);
 945   1024 < $kb
 946     and system("git repack -a -d");
 947 }
 948
 949 foreach my $git_index (values %index) {
 950     if ($git_index ne '.git/index') {
 951         unlink($git_index);
 952     }
 953 }
 954
 955 if (defined $orig_git_index) {
 956         $ENV{GIT_INDEX_FILE} = $orig_git_index;
 957 } else {
 958         delete $ENV{GIT_INDEX_FILE};
 959 }
 960
 961 # Now switch back to the branch we were in before all of this happened
 962 if ($orig_branch) {
 963         print "DONE.\n" if $opt_v;
 964         if ($opt_i) {
 965                 exit 0;
 966         }
 967         my $tip_at_end = `git-rev-parse --verify HEAD`;
 968         if ($tip_at_start ne $tip_at_end) {
 969                 for ($tip_at_start, $tip_at_end) { chomp; }
 970                 print "Fetched into the current branch.\n" if $opt_v;
 971                 system(qw(git-read-tree -u -m),
 972                        $tip_at_start, $tip_at_end);
 973                 die "Fast-forward update failed: $?\n" if $?;
 974         }
 975         else {
 976                 system(qw(git-merge cvsimport HEAD), "refs/heads/$opt_o");
 977                 die "Could not merge $opt_o into the current branch.\n" if $?;
 978         }
 979 } else {
 980         $orig_branch = "master";
 981         print "DONE; creating $orig_branch branch\n" if $opt_v;
 982         system("git-update-ref", "refs/heads/master", "refs/heads/$opt_o")
 983                 unless -f "$git_dir/refs/heads/master";
 984         system('git-update-ref', 'HEAD', "$orig_branch");
 985         unless ($opt_i) {
 986                 system('git checkout');
 987                 die "checkout failed: $?\n" if $?;
 988         }
 989 }