git.oblomov.eu Git - git/blob - gitweb/gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 our $t0 = [ gettimeofday() ];
  24 our $number_of_git_cmds = 0;
  25
  26 BEGIN {
  27         CGI->compile() if $ENV{'MOD_PERL'};
  28 }
  29
  30 our $version = "++GIT_VERSION++";
  31
  32 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  33 sub evaluate_uri {
  34         our $cgi;
  35
  36         our $my_url = $cgi->url();
  37         our $my_uri = $cgi->url(-absolute => 1);
  38
  39         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  40         # needed and used only for URLs with nonempty PATH_INFO
  41         our $base_url = $my_url;
  42
  43         # When the script is used as DirectoryIndex, the URL does not contain the name
  44         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  45         # have to do it ourselves. We make $path_info global because it's also used
  46         # later on.
  47         #
  48         # Another issue with the script being the DirectoryIndex is that the resulting
  49         # $my_url data is not the full script URL: this is good, because we want
  50         # generated links to keep implying the script name if it wasn't explicitly
  51         # indicated in the URL we're handling, but it means that $my_url cannot be used
  52         # as base URL.
  53         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  54         # to build the base URL ourselves:
  55         our $path_info = $ENV{"PATH_INFO"};
  56         if ($path_info) {
  57                 if ($my_url =~ s,\Q$path_info\E$,, &&
  58                     $my_uri =~ s,\Q$path_info\E$,, &&
  59                     defined $ENV{'SCRIPT_NAME'}) {
  60                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  61                 }
  62         }
  63
  64         # target of the home link on top of all pages
  65         our $home_link = $my_uri || "/";
  66 }
  67
  68 # core git executable to use
  69 # this can just be "git" if your webserver has a sensible PATH
  70 our $GIT = "++GIT_BINDIR++/git";
  71
  72 # absolute fs-path which will be prepended to the project path
  73 #our $projectroot = "/pub/scm";
  74 our $projectroot = "++GITWEB_PROJECTROOT++";
  75
  76 # fs traversing limit for getting project list
  77 # the number is relative to the projectroot
  78 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  79
  80 # string of the home link on top of all pages
  81 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  82
  83 # name of your site or organization to appear in page titles
  84 # replace this with something more descriptive for clearer bookmarks
  85 our $site_name = "++GITWEB_SITENAME++"
  86                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  87
  88 # filename of html text to include at top of each page
  89 our $site_header = "++GITWEB_SITE_HEADER++";
  90 # html text to include at home page
  91 our $home_text = "++GITWEB_HOMETEXT++";
  92 # filename of html text to include at bottom of each page
  93 our $site_footer = "++GITWEB_SITE_FOOTER++";
  94
  95 # URI of stylesheets
  96 our @stylesheets = ("++GITWEB_CSS++");
  97 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
  98 our $stylesheet = undef;
  99 # URI of GIT logo (72x27 size)
 100 our $logo = "++GITWEB_LOGO++";
 101 # URI of GIT favicon, assumed to be image/png type
 102 our $favicon = "++GITWEB_FAVICON++";
 103 # URI of gitweb.js (JavaScript code for gitweb)
 104 our $javascript = "++GITWEB_JS++";
 105
 106 # URI and label (title) of GIT logo link
 107 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 108 #our $logo_label = "git documentation";
 109 our $logo_url = "http://git-scm.com/";
 110 our $logo_label = "git homepage";
 111
 112 # source of projects list
 113 our $projects_list = "++GITWEB_LIST++";
 114
 115 # the width (in characters) of the projects list "Description" column
 116 our $projects_list_description_width = 25;
 117
 118 # default order of projects list
 119 # valid values are none, project, descr, owner, and age
 120 our $default_projects_order = "project";
 121
 122 # show repository only if this file exists
 123 # (only effective if this variable evaluates to true)
 124 our $export_ok = "++GITWEB_EXPORT_OK++";
 125
 126 # show repository only if this subroutine returns true
 127 # when given the path to the project, for example:
 128 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 129 our $export_auth_hook = undef;
 130
 131 # only allow viewing of repositories also shown on the overview page
 132 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 133
 134 # list of git base URLs used for URL to where fetch project from,
 135 # i.e. full URL is "$git_base_url/$project"
 136 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 137
 138 # default blob_plain mimetype and default charset for text/plain blob
 139 our $default_blob_plain_mimetype = 'text/plain';
 140 our $default_text_plain_charset  = undef;
 141
 142 # file to use for guessing MIME types before trying /etc/mime.types
 143 # (relative to the current git repository)
 144 our $mimetypes_file = undef;
 145
 146 # assume this charset if line contains non-UTF-8 characters;
 147 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 148 # for which encoding all byte sequences are valid, for example
 149 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 150 # could be even 'utf-8' for the old behavior)
 151 our $fallback_encoding = 'latin1';
 152
 153 # rename detection options for git-diff and git-diff-tree
 154 # - default is '-M', with the cost proportional to
 155 #   (number of removed files) * (number of new files).
 156 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 157 #   (number of changed files + number of removed files) * (number of new files)
 158 # - even more costly is '-C', '--find-copies-harder' with cost
 159 #   (number of files in the original tree) * (number of new files)
 160 # - one might want to include '-B' option, e.g. '-B', '-M'
 161 our @diff_opts = ('-M'); # taken from git_commit
 162
 163 # Disables features that would allow repository owners to inject script into
 164 # the gitweb domain.
 165 our $prevent_xss = 0;
 166
 167 # Path to the highlight executable to use (must be the one from
 168 # http://www.andre-simon.de due to assumptions about parameters and output).
 169 # Useful if highlight is not installed on your webserver's PATH.
 170 # [Default: highlight]
 171 our $highlight_bin = "++HIGHLIGHT_BIN++";
 172
 173 # information about snapshot formats that gitweb is capable of serving
 174 our %known_snapshot_formats = (
 175         # name => {
 176         #       'display' => display name,
 177         #       'type' => mime type,
 178         #       'suffix' => filename suffix,
 179         #       'format' => --format for git-archive,
 180         #       'compressor' => [compressor command and arguments]
 181         #                       (array reference, optional)
 182         #       'disabled' => boolean (optional)}
 183         #
 184         'tgz' => {
 185                 'display' => 'tar.gz',
 186                 'type' => 'application/x-gzip',
 187                 'suffix' => '.tar.gz',
 188                 'format' => 'tar',
 189                 'compressor' => ['gzip']},
 190
 191         'tbz2' => {
 192                 'display' => 'tar.bz2',
 193                 'type' => 'application/x-bzip2',
 194                 'suffix' => '.tar.bz2',
 195                 'format' => 'tar',
 196                 'compressor' => ['bzip2']},
 197
 198         'txz' => {
 199                 'display' => 'tar.xz',
 200                 'type' => 'application/x-xz',
 201                 'suffix' => '.tar.xz',
 202                 'format' => 'tar',
 203                 'compressor' => ['xz'],
 204                 'disabled' => 1},
 205
 206         'zip' => {
 207                 'display' => 'zip',
 208                 'type' => 'application/x-zip',
 209                 'suffix' => '.zip',
 210                 'format' => 'zip'},
 211 );
 212
 213 # Aliases so we understand old gitweb.snapshot values in repository
 214 # configuration.
 215 our %known_snapshot_format_aliases = (
 216         'gzip'  => 'tgz',
 217         'bzip2' => 'tbz2',
 218         'xz'    => 'txz',
 219
 220         # backward compatibility: legacy gitweb config support
 221         'x-gzip' => undef, 'gz' => undef,
 222         'x-bzip2' => undef, 'bz2' => undef,
 223         'x-zip' => undef, '' => undef,
 224 );
 225
 226 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 227 # are changed, it may be appropriate to change these values too via
 228 # $GITWEB_CONFIG.
 229 our %avatar_size = (
 230         'default' => 16,
 231         'double'  => 32
 232 );
 233
 234 # Used to set the maximum load that we will still respond to gitweb queries.
 235 # If server load exceed this value then return "503 server busy" error.
 236 # If gitweb cannot determined server load, it is taken to be 0.
 237 # Leave it undefined (or set to 'undef') to turn off load checking.
 238 our $maxload = 300;
 239
 240 # configuration for 'highlight' (http://www.andre-simon.de/)
 241 # match by basename
 242 our %highlight_basename = (
 243         #'Program' => 'py',
 244         #'Library' => 'py',
 245         'SConstruct' => 'py', # SCons equivalent of Makefile
 246         'Makefile' => 'make',
 247 );
 248 # match by extension
 249 our %highlight_ext = (
 250         # main extensions, defining name of syntax;
 251         # see files in /usr/share/highlight/langDefs/ directory
 252         map { $_ => $_ }
 253                 qw(py c cpp rb java css php sh pl js tex bib xml awk bat ini spec tcl),
 254         # alternate extensions, see /etc/highlight/filetypes.conf
 255         'h' => 'c',
 256         map { $_ => 'cpp' } qw(cxx c++ cc),
 257         map { $_ => 'php' } qw(php3 php4),
 258         map { $_ => 'pl'  } qw(perl pm), # perhaps also 'cgi'
 259         'mak' => 'make',
 260         map { $_ => 'xml' } qw(xhtml html htm),
 261 );
 262
 263 # You define site-wide feature defaults here; override them with
 264 # $GITWEB_CONFIG as necessary.
 265 our %feature = (
 266         # feature => {
 267         #       'sub' => feature-sub (subroutine),
 268         #       'override' => allow-override (boolean),
 269         #       'default' => [ default options...] (array reference)}
 270         #
 271         # if feature is overridable (it means that allow-override has true value),
 272         # then feature-sub will be called with default options as parameters;
 273         # return value of feature-sub indicates if to enable specified feature
 274         #
 275         # if there is no 'sub' key (no feature-sub), then feature cannot be
 276         # overridden
 277         #
 278         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 279         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 280         # is enabled
 281
 282         # Enable the 'blame' blob view, showing the last commit that modified
 283         # each line in the file. This can be very CPU-intensive.
 284
 285         # To enable system wide have in $GITWEB_CONFIG
 286         # $feature{'blame'}{'default'} = [1];
 287         # To have project specific config enable override in $GITWEB_CONFIG
 288         # $feature{'blame'}{'override'} = 1;
 289         # and in project config gitweb.blame = 0|1;
 290         'blame' => {
 291                 'sub' => sub { feature_bool('blame', @_) },
 292                 'override' => 0,
 293                 'default' => [0]},
 294
 295         # Enable the 'snapshot' link, providing a compressed archive of any
 296         # tree. This can potentially generate high traffic if you have large
 297         # project.
 298
 299         # Value is a list of formats defined in %known_snapshot_formats that
 300         # you wish to offer.
 301         # To disable system wide have in $GITWEB_CONFIG
 302         # $feature{'snapshot'}{'default'} = [];
 303         # To have project specific config enable override in $GITWEB_CONFIG
 304         # $feature{'snapshot'}{'override'} = 1;
 305         # and in project config, a comma-separated list of formats or "none"
 306         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 307         'snapshot' => {
 308                 'sub' => \&feature_snapshot,
 309                 'override' => 0,
 310                 'default' => ['tgz']},
 311
 312         # Enable text search, which will list the commits which match author,
 313         # committer or commit text to a given string.  Enabled by default.
 314         # Project specific override is not supported.
 315         'search' => {
 316                 'override' => 0,
 317                 'default' => [1]},
 318
 319         # Enable grep search, which will list the files in currently selected
 320         # tree containing the given string. Enabled by default. This can be
 321         # potentially CPU-intensive, of course.
 322
 323         # To enable system wide have in $GITWEB_CONFIG
 324         # $feature{'grep'}{'default'} = [1];
 325         # To have project specific config enable override in $GITWEB_CONFIG
 326         # $feature{'grep'}{'override'} = 1;
 327         # and in project config gitweb.grep = 0|1;
 328         'grep' => {
 329                 'sub' => sub { feature_bool('grep', @_) },
 330                 'override' => 0,
 331                 'default' => [1]},
 332
 333         # Enable the pickaxe search, which will list the commits that modified
 334         # a given string in a file. This can be practical and quite faster
 335         # alternative to 'blame', but still potentially CPU-intensive.
 336
 337         # To enable system wide have in $GITWEB_CONFIG
 338         # $feature{'pickaxe'}{'default'} = [1];
 339         # To have project specific config enable override in $GITWEB_CONFIG
 340         # $feature{'pickaxe'}{'override'} = 1;
 341         # and in project config gitweb.pickaxe = 0|1;
 342         'pickaxe' => {
 343                 'sub' => sub { feature_bool('pickaxe', @_) },
 344                 'override' => 0,
 345                 'default' => [1]},
 346
 347         # Enable showing size of blobs in a 'tree' view, in a separate
 348         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 349
 350         # To disable system wide have in $GITWEB_CONFIG
 351         # $feature{'show-sizes'}{'default'} = [0];
 352         # To have project specific config enable override in $GITWEB_CONFIG
 353         # $feature{'show-sizes'}{'override'} = 1;
 354         # and in project config gitweb.showsizes = 0|1;
 355         'show-sizes' => {
 356                 'sub' => sub { feature_bool('showsizes', @_) },
 357                 'override' => 0,
 358                 'default' => [1]},
 359
 360         # Make gitweb use an alternative format of the URLs which can be
 361         # more readable and natural-looking: project name is embedded
 362         # directly in the path and the query string contains other
 363         # auxiliary information. All gitweb installations recognize
 364         # URL in either format; this configures in which formats gitweb
 365         # generates links.
 366
 367         # To enable system wide have in $GITWEB_CONFIG
 368         # $feature{'pathinfo'}{'default'} = [1];
 369         # Project specific override is not supported.
 370
 371         # Note that you will need to change the default location of CSS,
 372         # favicon, logo and possibly other files to an absolute URL. Also,
 373         # if gitweb.cgi serves as your indexfile, you will need to force
 374         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 375         'pathinfo' => {
 376                 'override' => 0,
 377                 'default' => [0]},
 378
 379         # Make gitweb consider projects in project root subdirectories
 380         # to be forks of existing projects. Given project $projname.git,
 381         # projects matching $projname/*.git will not be shown in the main
 382         # projects list, instead a '+' mark will be added to $projname
 383         # there and a 'forks' view will be enabled for the project, listing
 384         # all the forks. If project list is taken from a file, forks have
 385         # to be listed after the main project.
 386
 387         # To enable system wide have in $GITWEB_CONFIG
 388         # $feature{'forks'}{'default'} = [1];
 389         # Project specific override is not supported.
 390         'forks' => {
 391                 'override' => 0,
 392                 'default' => [0]},
 393
 394         # Insert custom links to the action bar of all project pages.
 395         # This enables you mainly to link to third-party scripts integrating
 396         # into gitweb; e.g. git-browser for graphical history representation
 397         # or custom web-based repository administration interface.
 398
 399         # The 'default' value consists of a list of triplets in the form
 400         # (label, link, position) where position is the label after which
 401         # to insert the link and link is a format string where %n expands
 402         # to the project name, %f to the project path within the filesystem,
 403         # %h to the current hash (h gitweb parameter) and %b to the current
 404         # hash base (hb gitweb parameter); %% expands to %.
 405
 406         # To enable system wide have in $GITWEB_CONFIG e.g.
 407         # $feature{'actions'}{'default'} = [('graphiclog',
 408         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 409         # Project specific override is not supported.
 410         'actions' => {
 411                 'override' => 0,
 412                 'default' => []},
 413
 414         # Allow gitweb scan project content tags described in ctags/
 415         # of project repository, and display the popular Web 2.0-ish
 416         # "tag cloud" near the project list. Note that this is something
 417         # COMPLETELY different from the normal Git tags.
 418
 419         # gitweb by itself can show existing tags, but it does not handle
 420         # tagging itself; you need an external application for that.
 421         # For an example script, check Girocco's cgi/tagproj.cgi.
 422         # You may want to install the HTML::TagCloud Perl module to get
 423         # a pretty tag cloud instead of just a list of tags.
 424
 425         # To enable system wide have in $GITWEB_CONFIG
 426         # $feature{'ctags'}{'default'} = ['path_to_tag_script'];
 427         # Project specific override is not supported.
 428         'ctags' => {
 429                 'override' => 0,
 430                 'default' => [0]},
 431
 432         # The maximum number of patches in a patchset generated in patch
 433         # view. Set this to 0 or undef to disable patch view, or to a
 434         # negative number to remove any limit.
 435
 436         # To disable system wide have in $GITWEB_CONFIG
 437         # $feature{'patches'}{'default'} = [0];
 438         # To have project specific config enable override in $GITWEB_CONFIG
 439         # $feature{'patches'}{'override'} = 1;
 440         # and in project config gitweb.patches = 0|n;
 441         # where n is the maximum number of patches allowed in a patchset.
 442         'patches' => {
 443                 'sub' => \&feature_patches,
 444                 'override' => 0,
 445                 'default' => [16]},
 446
 447         # Avatar support. When this feature is enabled, views such as
 448         # shortlog or commit will display an avatar associated with
 449         # the email of the committer(s) and/or author(s).
 450
 451         # Currently available providers are gravatar and picon.
 452         # If an unknown provider is specified, the feature is disabled.
 453
 454         # Gravatar depends on Digest::MD5.
 455         # Picon currently relies on the indiana.edu database.
 456
 457         # To enable system wide have in $GITWEB_CONFIG
 458         # $feature{'avatar'}{'default'} = ['<provider>'];
 459         # where <provider> is either gravatar or picon.
 460         # To have project specific config enable override in $GITWEB_CONFIG
 461         # $feature{'avatar'}{'override'} = 1;
 462         # and in project config gitweb.avatar = <provider>;
 463         'avatar' => {
 464                 'sub' => \&feature_avatar,
 465                 'override' => 0,
 466                 'default' => ['']},
 467
 468         # Enable displaying how much time and how many git commands
 469         # it took to generate and display page.  Disabled by default.
 470         # Project specific override is not supported.
 471         'timed' => {
 472                 'override' => 0,
 473                 'default' => [0]},
 474
 475         # Enable turning some links into links to actions which require
 476         # JavaScript to run (like 'blame_incremental').  Not enabled by
 477         # default.  Project specific override is currently not supported.
 478         'javascript-actions' => {
 479                 'override' => 0,
 480                 'default' => [0]},
 481
 482         # Syntax highlighting support. This is based on Daniel Svensson's
 483         # and Sham Chukoury's work in gitweb-xmms2.git.
 484         # It requires the 'highlight' program present in $PATH,
 485         # and therefore is disabled by default.
 486
 487         # To enable system wide have in $GITWEB_CONFIG
 488         # $feature{'highlight'}{'default'} = [1];
 489
 490         'highlight' => {
 491                 'sub' => sub { feature_bool('highlight', @_) },
 492                 'override' => 0,
 493                 'default' => [0]},
 494
 495         # Enable displaying of remote heads in the heads list
 496
 497         # To enable system wide have in $GITWEB_CONFIG
 498         # $feature{'remote_heads'}{'default'} = [1];
 499         # To have project specific config enable override in $GITWEB_CONFIG
 500         # $feature{'remote_heads'}{'override'} = 1;
 501         # and in project config gitweb.remote_heads = 0|1;
 502         'remote_heads' => {
 503                 'sub' => sub { feature_bool('remote_heads', @_) },
 504                 'override' => 0,
 505                 'default' => [0]},
 506 );
 507
 508 sub gitweb_get_feature {
 509         my ($name) = @_;
 510         return unless exists $feature{$name};
 511         my ($sub, $override, @defaults) = (
 512                 $feature{$name}{'sub'},
 513                 $feature{$name}{'override'},
 514                 @{$feature{$name}{'default'}});
 515         # project specific override is possible only if we have project
 516         our $git_dir; # global variable, declared later
 517         if (!$override || !defined $git_dir) {
 518                 return @defaults;
 519         }
 520         if (!defined $sub) {
 521                 warn "feature $name is not overridable";
 522                 return @defaults;
 523         }
 524         return $sub->(@defaults);
 525 }
 526
 527 # A wrapper to check if a given feature is enabled.
 528 # With this, you can say
 529 #
 530 #   my $bool_feat = gitweb_check_feature('bool_feat');
 531 #   gitweb_check_feature('bool_feat') or somecode;
 532 #
 533 # instead of
 534 #
 535 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 536 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 537 #
 538 sub gitweb_check_feature {
 539         return (gitweb_get_feature(@_))[0];
 540 }
 541
 542
 543 sub feature_bool {
 544         my $key = shift;
 545         my ($val) = git_get_project_config($key, '--bool');
 546
 547         if (!defined $val) {
 548                 return ($_[0]);
 549         } elsif ($val eq 'true') {
 550                 return (1);
 551         } elsif ($val eq 'false') {
 552                 return (0);
 553         }
 554 }
 555
 556 sub feature_snapshot {
 557         my (@fmts) = @_;
 558
 559         my ($val) = git_get_project_config('snapshot');
 560
 561         if ($val) {
 562                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 563         }
 564
 565         return @fmts;
 566 }
 567
 568 sub feature_patches {
 569         my @val = (git_get_project_config('patches', '--int'));
 570
 571         if (@val) {
 572                 return @val;
 573         }
 574
 575         return ($_[0]);
 576 }
 577
 578 sub feature_avatar {
 579         my @val = (git_get_project_config('avatar'));
 580
 581         return @val ? @val : @_;
 582 }
 583
 584 # checking HEAD file with -e is fragile if the repository was
 585 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 586 # and then pruned.
 587 sub check_head_link {
 588         my ($dir) = @_;
 589         my $headfile = "$dir/HEAD";
 590         return ((-e $headfile) ||
 591                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 592 }
 593
 594 sub check_export_ok {
 595         my ($dir) = @_;
 596         return (check_head_link($dir) &&
 597                 (!$export_ok || -e "$dir/$export_ok") &&
 598                 (!$export_auth_hook || $export_auth_hook->($dir)));
 599 }
 600
 601 # process alternate names for backward compatibility
 602 # filter out unsupported (unknown) snapshot formats
 603 sub filter_snapshot_fmts {
 604         my @fmts = @_;
 605
 606         @fmts = map {
 607                 exists $known_snapshot_format_aliases{$_} ?
 608                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 609         @fmts = grep {
 610                 exists $known_snapshot_formats{$_} &&
 611                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 612 }
 613
 614 # If it is set to code reference, it is code that it is to be run once per
 615 # request, allowing updating configurations that change with each request,
 616 # while running other code in config file only once.
 617 #
 618 # Otherwise, if it is false then gitweb would process config file only once;
 619 # if it is true then gitweb config would be run for each request.
 620 our $per_request_config = 1;
 621
 622 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM);
 623 sub evaluate_gitweb_config {
 624         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 625         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 626         # die if there are errors parsing config file
 627         if (-e $GITWEB_CONFIG) {
 628                 do $GITWEB_CONFIG;
 629                 die $@ if $@;
 630         } elsif (-e $GITWEB_CONFIG_SYSTEM) {
 631                 do $GITWEB_CONFIG_SYSTEM;
 632                 die $@ if $@;
 633         }
 634 }
 635
 636 # Get loadavg of system, to compare against $maxload.
 637 # Currently it requires '/proc/loadavg' present to get loadavg;
 638 # if it is not present it returns 0, which means no load checking.
 639 sub get_loadavg {
 640         if( -e '/proc/loadavg' ){
 641                 open my $fd, '<', '/proc/loadavg'
 642                         or return 0;
 643                 my @load = split(/\s+/, scalar <$fd>);
 644                 close $fd;
 645
 646                 # The first three columns measure CPU and IO utilization of the last one,
 647                 # five, and 10 minute periods.  The fourth column shows the number of
 648                 # currently running processes and the total number of processes in the m/n
 649                 # format.  The last column displays the last process ID used.
 650                 return $load[0] || 0;
 651         }
 652         # additional checks for load average should go here for things that don't export
 653         # /proc/loadavg
 654
 655         return 0;
 656 }
 657
 658 # version of the core git binary
 659 our $git_version;
 660 sub evaluate_git_version {
 661         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 662         $number_of_git_cmds++;
 663 }
 664
 665 sub check_loadavg {
 666         if (defined $maxload && get_loadavg() > $maxload) {
 667                 die_error(503, "The load average on the server is too high");
 668         }
 669 }
 670
 671 # ======================================================================
 672 # input validation and dispatch
 673
 674 # input parameters can be collected from a variety of sources (presently, CGI
 675 # and PATH_INFO), so we define an %input_params hash that collects them all
 676 # together during validation: this allows subsequent uses (e.g. href()) to be
 677 # agnostic of the parameter origin
 678
 679 our %input_params = ();
 680
 681 # input parameters are stored with the long parameter name as key. This will
 682 # also be used in the href subroutine to convert parameters to their CGI
 683 # equivalent, and since the href() usage is the most frequent one, we store
 684 # the name -> CGI key mapping here, instead of the reverse.
 685 #
 686 # XXX: Warning: If you touch this, check the search form for updating,
 687 # too.
 688
 689 our @cgi_param_mapping = (
 690         project => "p",
 691         action => "a",
 692         file_name => "f",
 693         file_parent => "fp",
 694         hash => "h",
 695         hash_parent => "hp",
 696         hash_base => "hb",
 697         hash_parent_base => "hpb",
 698         page => "pg",
 699         order => "o",
 700         searchtext => "s",
 701         searchtype => "st",
 702         snapshot_format => "sf",
 703         extra_options => "opt",
 704         search_use_regexp => "sr",
 705         # this must be last entry (for manipulation from JavaScript)
 706         javascript => "js"
 707 );
 708 our %cgi_param_mapping = @cgi_param_mapping;
 709
 710 # we will also need to know the possible actions, for validation
 711 our %actions = (
 712         "blame" => \&git_blame,
 713         "blame_incremental" => \&git_blame_incremental,
 714         "blame_data" => \&git_blame_data,
 715         "blobdiff" => \&git_blobdiff,
 716         "blobdiff_plain" => \&git_blobdiff_plain,
 717         "blob" => \&git_blob,
 718         "blob_plain" => \&git_blob_plain,
 719         "commitdiff" => \&git_commitdiff,
 720         "commitdiff_plain" => \&git_commitdiff_plain,
 721         "commit" => \&git_commit,
 722         "forks" => \&git_forks,
 723         "heads" => \&git_heads,
 724         "history" => \&git_history,
 725         "log" => \&git_log,
 726         "patch" => \&git_patch,
 727         "patches" => \&git_patches,
 728         "remotes" => \&git_remotes,
 729         "rss" => \&git_rss,
 730         "atom" => \&git_atom,
 731         "search" => \&git_search,
 732         "search_help" => \&git_search_help,
 733         "shortlog" => \&git_shortlog,
 734         "summary" => \&git_summary,
 735         "tag" => \&git_tag,
 736         "tags" => \&git_tags,
 737         "tree" => \&git_tree,
 738         "snapshot" => \&git_snapshot,
 739         "object" => \&git_object,
 740         # those below don't need $project
 741         "opml" => \&git_opml,
 742         "project_list" => \&git_project_list,
 743         "project_index" => \&git_project_index,
 744 );
 745
 746 # finally, we have the hash of allowed extra_options for the commands that
 747 # allow them
 748 our %allowed_options = (
 749         "--no-merges" => [ qw(rss atom log shortlog history) ],
 750 );
 751
 752 # fill %input_params with the CGI parameters. All values except for 'opt'
 753 # should be single values, but opt can be an array. We should probably
 754 # build an array of parameters that can be multi-valued, but since for the time
 755 # being it's only this one, we just single it out
 756 sub evaluate_query_params {
 757         our $cgi;
 758
 759         while (my ($name, $symbol) = each %cgi_param_mapping) {
 760                 if ($symbol eq 'opt') {
 761                         $input_params{$name} = [ $cgi->param($symbol) ];
 762                 } else {
 763                         $input_params{$name} = $cgi->param($symbol);
 764                 }
 765         }
 766 }
 767
 768 # now read PATH_INFO and update the parameter list for missing parameters
 769 sub evaluate_path_info {
 770         return if defined $input_params{'project'};
 771         return if !$path_info;
 772         $path_info =~ s,^/+,,;
 773         return if !$path_info;
 774
 775         # find which part of PATH_INFO is project
 776         my $project = $path_info;
 777         $project =~ s,/+$,,;
 778         while ($project && !check_head_link("$projectroot/$project")) {
 779                 $project =~ s,/*[^/]*$,,;
 780         }
 781         return unless $project;
 782         $input_params{'project'} = $project;
 783
 784         # do not change any parameters if an action is given using the query string
 785         return if $input_params{'action'};
 786         $path_info =~ s,^\Q$project\E/*,,;
 787
 788         # next, check if we have an action
 789         my $action = $path_info;
 790         $action =~ s,/.*$,,;
 791         if (exists $actions{$action}) {
 792                 $path_info =~ s,^$action/*,,;
 793                 $input_params{'action'} = $action;
 794         }
 795
 796         # list of actions that want hash_base instead of hash, but can have no
 797         # pathname (f) parameter
 798         my @wants_base = (
 799                 'tree',
 800                 'history',
 801         );
 802
 803         # we want to catch, among others
 804         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 805         my ($parentrefname, $parentpathname, $refname, $pathname) =
 806                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 807
 808         # first, analyze the 'current' part
 809         if (defined $pathname) {
 810                 # we got "branch:filename" or "branch:dir/"
 811                 # we could use git_get_type(branch:pathname), but:
 812                 # - it needs $git_dir
 813                 # - it does a git() call
 814                 # - the convention of terminating directories with a slash
 815                 #   makes it superfluous
 816                 # - embedding the action in the PATH_INFO would make it even
 817                 #   more superfluous
 818                 $pathname =~ s,^/+,,;
 819                 if (!$pathname || substr($pathname, -1) eq "/") {
 820                         $input_params{'action'} ||= "tree";
 821                         $pathname =~ s,/$,,;
 822                 } else {
 823                         # the default action depends on whether we had parent info
 824                         # or not
 825                         if ($parentrefname) {
 826                                 $input_params{'action'} ||= "blobdiff_plain";
 827                         } else {
 828                                 $input_params{'action'} ||= "blob_plain";
 829                         }
 830                 }
 831                 $input_params{'hash_base'} ||= $refname;
 832                 $input_params{'file_name'} ||= $pathname;
 833         } elsif (defined $refname) {
 834                 # we got "branch". In this case we have to choose if we have to
 835                 # set hash or hash_base.
 836                 #
 837                 # Most of the actions without a pathname only want hash to be
 838                 # set, except for the ones specified in @wants_base that want
 839                 # hash_base instead. It should also be noted that hand-crafted
 840                 # links having 'history' as an action and no pathname or hash
 841                 # set will fail, but that happens regardless of PATH_INFO.
 842                 if (defined $parentrefname) {
 843                         # if there is parent let the default be 'shortlog' action
 844                         # (for http://git.example.com/repo.git/A..B links); if there
 845                         # is no parent, dispatch will detect type of object and set
 846                         # action appropriately if required (if action is not set)
 847                         $input_params{'action'} ||= "shortlog";
 848                 }
 849                 if ($input_params{'action'} &&
 850                     grep { $_ eq $input_params{'action'} } @wants_base) {
 851                         $input_params{'hash_base'} ||= $refname;
 852                 } else {
 853                         $input_params{'hash'} ||= $refname;
 854                 }
 855         }
 856
 857         # next, handle the 'parent' part, if present
 858         if (defined $parentrefname) {
 859                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 860                 # someproject/blobdiff/oldrev..newrev:/filename
 861                 if ($parentpathname) {
 862                         $parentpathname =~ s,^/+,,;
 863                         $parentpathname =~ s,/$,,;
 864                         $input_params{'file_parent'} ||= $parentpathname;
 865                 } else {
 866                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 867                 }
 868                 # we assume that hash_parent_base is wanted if a path was specified,
 869                 # or if the action wants hash_base instead of hash
 870                 if (defined $input_params{'file_parent'} ||
 871                         grep { $_ eq $input_params{'action'} } @wants_base) {
 872                         $input_params{'hash_parent_base'} ||= $parentrefname;
 873                 } else {
 874                         $input_params{'hash_parent'} ||= $parentrefname;
 875                 }
 876         }
 877
 878         # for the snapshot action, we allow URLs in the form
 879         # $project/snapshot/$hash.ext
 880         # where .ext determines the snapshot and gets removed from the
 881         # passed $refname to provide the $hash.
 882         #
 883         # To be able to tell that $refname includes the format extension, we
 884         # require the following two conditions to be satisfied:
 885         # - the hash input parameter MUST have been set from the $refname part
 886         #   of the URL (i.e. they must be equal)
 887         # - the snapshot format MUST NOT have been defined already (e.g. from
 888         #   CGI parameter sf)
 889         # It's also useless to try any matching unless $refname has a dot,
 890         # so we check for that too
 891         if (defined $input_params{'action'} &&
 892                 $input_params{'action'} eq 'snapshot' &&
 893                 defined $refname && index($refname, '.') != -1 &&
 894                 $refname eq $input_params{'hash'} &&
 895                 !defined $input_params{'snapshot_format'}) {
 896                 # We loop over the known snapshot formats, checking for
 897                 # extensions. Allowed extensions are both the defined suffix
 898                 # (which includes the initial dot already) and the snapshot
 899                 # format key itself, with a prepended dot
 900                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
 901                         my $hash = $refname;
 902                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 903                                 next;
 904                         }
 905                         my $sfx = $1;
 906                         # a valid suffix was found, so set the snapshot format
 907                         # and reset the hash parameter
 908                         $input_params{'snapshot_format'} = $fmt;
 909                         $input_params{'hash'} = $hash;
 910                         # we also set the format suffix to the one requested
 911                         # in the URL: this way a request for e.g. .tgz returns
 912                         # a .tgz instead of a .tar.gz
 913                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 914                         last;
 915                 }
 916         }
 917 }
 918
 919 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
 920      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
 921      $searchtext, $search_regexp);
 922 sub evaluate_and_validate_params {
 923         our $action = $input_params{'action'};
 924         if (defined $action) {
 925                 if (!validate_action($action)) {
 926                         die_error(400, "Invalid action parameter");
 927                 }
 928         }
 929
 930         # parameters which are pathnames
 931         our $project = $input_params{'project'};
 932         if (defined $project) {
 933                 if (!validate_project($project)) {
 934                         undef $project;
 935                         die_error(404, "No such project");
 936                 }
 937         }
 938
 939         our $file_name = $input_params{'file_name'};
 940         if (defined $file_name) {
 941                 if (!validate_pathname($file_name)) {
 942                         die_error(400, "Invalid file parameter");
 943                 }
 944         }
 945
 946         our $file_parent = $input_params{'file_parent'};
 947         if (defined $file_parent) {
 948                 if (!validate_pathname($file_parent)) {
 949                         die_error(400, "Invalid file parent parameter");
 950                 }
 951         }
 952
 953         # parameters which are refnames
 954         our $hash = $input_params{'hash'};
 955         if (defined $hash) {
 956                 if (!validate_refname($hash)) {
 957                         die_error(400, "Invalid hash parameter");
 958                 }
 959         }
 960
 961         our $hash_parent = $input_params{'hash_parent'};
 962         if (defined $hash_parent) {
 963                 if (!validate_refname($hash_parent)) {
 964                         die_error(400, "Invalid hash parent parameter");
 965                 }
 966         }
 967
 968         our $hash_base = $input_params{'hash_base'};
 969         if (defined $hash_base) {
 970                 if (!validate_refname($hash_base)) {
 971                         die_error(400, "Invalid hash base parameter");
 972                 }
 973         }
 974
 975         our @extra_options = @{$input_params{'extra_options'}};
 976         # @extra_options is always defined, since it can only be (currently) set from
 977         # CGI, and $cgi->param() returns the empty array in array context if the param
 978         # is not set
 979         foreach my $opt (@extra_options) {
 980                 if (not exists $allowed_options{$opt}) {
 981                         die_error(400, "Invalid option parameter");
 982                 }
 983                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
 984                         die_error(400, "Invalid option parameter for this action");
 985                 }
 986         }
 987
 988         our $hash_parent_base = $input_params{'hash_parent_base'};
 989         if (defined $hash_parent_base) {
 990                 if (!validate_refname($hash_parent_base)) {
 991                         die_error(400, "Invalid hash parent base parameter");
 992                 }
 993         }
 994
 995         # other parameters
 996         our $page = $input_params{'page'};
 997         if (defined $page) {
 998                 if ($page =~ m/[^0-9]/) {
 999                         die_error(400, "Invalid page parameter");
1000                 }
1001         }
1002
1003         our $searchtype = $input_params{'searchtype'};
1004         if (defined $searchtype) {
1005                 if ($searchtype =~ m/[^a-z]/) {
1006                         die_error(400, "Invalid searchtype parameter");
1007                 }
1008         }
1009
1010         our $search_use_regexp = $input_params{'search_use_regexp'};
1011
1012         our $searchtext = $input_params{'searchtext'};
1013         our $search_regexp;
1014         if (defined $searchtext) {
1015                 if (length($searchtext) < 2) {
1016                         die_error(403, "At least two characters are required for search parameter");
1017                 }
1018                 $search_regexp = $search_use_regexp ? $searchtext : quotemeta $searchtext;
1019         }
1020 }
1021
1022 # path to the current git repository
1023 our $git_dir;
1024 sub evaluate_git_dir {
1025         our $git_dir = "$projectroot/$project" if $project;
1026 }
1027
1028 our (@snapshot_fmts, $git_avatar);
1029 sub configure_gitweb_features {
1030         # list of supported snapshot formats
1031         our @snapshot_fmts = gitweb_get_feature('snapshot');
1032         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1033
1034         # check that the avatar feature is set to a known provider name,
1035         # and for each provider check if the dependencies are satisfied.
1036         # if the provider name is invalid or the dependencies are not met,
1037         # reset $git_avatar to the empty string.
1038         our ($git_avatar) = gitweb_get_feature('avatar');
1039         if ($git_avatar eq 'gravatar') {
1040                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1041         } elsif ($git_avatar eq 'picon') {
1042                 # no dependencies
1043         } else {
1044                 $git_avatar = '';
1045         }
1046 }
1047
1048 # custom error handler: 'die <message>' is Internal Server Error
1049 sub handle_errors_html {
1050         my $msg = shift; # it is already HTML escaped
1051
1052         # to avoid infinite loop where error occurs in die_error,
1053         # change handler to default handler, disabling handle_errors_html
1054         set_message("Error occured when inside die_error:\n$msg");
1055
1056         # you cannot jump out of die_error when called as error handler;
1057         # the subroutine set via CGI::Carp::set_message is called _after_
1058         # HTTP headers are already written, so it cannot write them itself
1059         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1060 }
1061 set_message(\&handle_errors_html);
1062
1063 # dispatch
1064 sub dispatch {
1065         if (!defined $action) {
1066                 if (defined $hash) {
1067                         $action = git_get_type($hash);
1068                 } elsif (defined $hash_base && defined $file_name) {
1069                         $action = git_get_type("$hash_base:$file_name");
1070                 } elsif (defined $project) {
1071                         $action = 'summary';
1072                 } else {
1073                         $action = 'project_list';
1074                 }
1075         }
1076         if (!defined($actions{$action})) {
1077                 die_error(400, "Unknown action");
1078         }
1079         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1080             !$project) {
1081                 die_error(400, "Project needed");
1082         }
1083         $actions{$action}->();
1084 }
1085
1086 sub reset_timer {
1087         our $t0 = [ gettimeofday() ]
1088                 if defined $t0;
1089         our $number_of_git_cmds = 0;
1090 }
1091
1092 our $first_request = 1;
1093 sub run_request {
1094         reset_timer();
1095
1096         evaluate_uri();
1097         if ($first_request) {
1098                 evaluate_gitweb_config();
1099                 evaluate_git_version();
1100         }
1101         if ($per_request_config) {
1102                 if (ref($per_request_config) eq 'CODE') {
1103                         $per_request_config->();
1104                 } elsif (!$first_request) {
1105                         evaluate_gitweb_config();
1106                 }
1107         }
1108         check_loadavg();
1109
1110         # $projectroot and $projects_list might be set in gitweb config file
1111         $projects_list ||= $projectroot;
1112
1113         evaluate_query_params();
1114         evaluate_path_info();
1115         evaluate_and_validate_params();
1116         evaluate_git_dir();
1117
1118         configure_gitweb_features();
1119
1120         dispatch();
1121 }
1122
1123 our $is_last_request = sub { 1 };
1124 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1125 our $CGI = 'CGI';
1126 our $cgi;
1127 sub configure_as_fcgi {
1128         require CGI::Fast;
1129         our $CGI = 'CGI::Fast';
1130
1131         my $request_number = 0;
1132         # let each child service 100 requests
1133         our $is_last_request = sub { ++$request_number > 100 };
1134 }
1135 sub evaluate_argv {
1136         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1137         configure_as_fcgi()
1138                 if $script_name =~ /\.fcgi$/;
1139
1140         return unless (@ARGV);
1141
1142         require Getopt::Long;
1143         Getopt::Long::GetOptions(
1144                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1145                 'nproc|n=i' => sub {
1146                         my ($arg, $val) = @_;
1147                         return unless eval { require FCGI::ProcManager; 1; };
1148                         my $proc_manager = FCGI::ProcManager->new({
1149                                 n_processes => $val,
1150                         });
1151                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1152                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1153                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1154                 },
1155         );
1156 }
1157
1158 sub run {
1159         evaluate_argv();
1160
1161         $first_request = 1;
1162         $pre_listen_hook->()
1163                 if $pre_listen_hook;
1164
1165  REQUEST:
1166         while ($cgi = $CGI->new()) {
1167                 $pre_dispatch_hook->()
1168                         if $pre_dispatch_hook;
1169
1170                 run_request();
1171
1172                 $post_dispatch_hook->()
1173                         if $post_dispatch_hook;
1174                 $first_request = 0;
1175
1176                 last REQUEST if ($is_last_request->());
1177         }
1178
1179  DONE_GITWEB:
1180         1;
1181 }
1182
1183 run();
1184
1185 if (defined caller) {
1186         # wrapped in a subroutine processing requests,
1187         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1188         return;
1189 } else {
1190         # pure CGI script, serving single request
1191         exit;
1192 }
1193
1194 ## ======================================================================
1195 ## action links
1196
1197 # possible values of extra options
1198 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1199 # -replay => 1      - start from a current view (replay with modifications)
1200 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1201 sub href {
1202         my %params = @_;
1203         # default is to use -absolute url() i.e. $my_uri
1204         my $href = $params{-full} ? $my_url : $my_uri;
1205
1206         $params{'project'} = $project unless exists $params{'project'};
1207
1208         if ($params{-replay}) {
1209                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1210                         if (!exists $params{$name}) {
1211                                 $params{$name} = $input_params{$name};
1212                         }
1213                 }
1214         }
1215
1216         my $use_pathinfo = gitweb_check_feature('pathinfo');
1217         if (defined $params{'project'} &&
1218             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1219                 # try to put as many parameters as possible in PATH_INFO:
1220                 #   - project name
1221                 #   - action
1222                 #   - hash_parent or hash_parent_base:/file_parent
1223                 #   - hash or hash_base:/filename
1224                 #   - the snapshot_format as an appropriate suffix
1225
1226                 # When the script is the root DirectoryIndex for the domain,
1227                 # $href here would be something like http://gitweb.example.com/
1228                 # Thus, we strip any trailing / from $href, to spare us double
1229                 # slashes in the final URL
1230                 $href =~ s,/$,,;
1231
1232                 # Then add the project name, if present
1233                 $href .= "/".esc_path_info($params{'project'});
1234                 delete $params{'project'};
1235
1236                 # since we destructively absorb parameters, we keep this
1237                 # boolean that remembers if we're handling a snapshot
1238                 my $is_snapshot = $params{'action'} eq 'snapshot';
1239
1240                 # Summary just uses the project path URL, any other action is
1241                 # added to the URL
1242                 if (defined $params{'action'}) {
1243                         $href .= "/".esc_path_info($params{'action'})
1244                                 unless $params{'action'} eq 'summary';
1245                         delete $params{'action'};
1246                 }
1247
1248                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1249                 # stripping nonexistent or useless pieces
1250                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1251                         || $params{'hash_parent'} || $params{'hash'});
1252                 if (defined $params{'hash_base'}) {
1253                         if (defined $params{'hash_parent_base'}) {
1254                                 $href .= esc_path_info($params{'hash_parent_base'});
1255                                 # skip the file_parent if it's the same as the file_name
1256                                 if (defined $params{'file_parent'}) {
1257                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1258                                                 delete $params{'file_parent'};
1259                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1260                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1261                                                 delete $params{'file_parent'};
1262                                         }
1263                                 }
1264                                 $href .= "..";
1265                                 delete $params{'hash_parent'};
1266                                 delete $params{'hash_parent_base'};
1267                         } elsif (defined $params{'hash_parent'}) {
1268                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1269                                 delete $params{'hash_parent'};
1270                         }
1271
1272                         $href .= esc_path_info($params{'hash_base'});
1273                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1274                                 $href .= ":/".esc_path_info($params{'file_name'});
1275                                 delete $params{'file_name'};
1276                         }
1277                         delete $params{'hash'};
1278                         delete $params{'hash_base'};
1279                 } elsif (defined $params{'hash'}) {
1280                         $href .= esc_path_info($params{'hash'});
1281                         delete $params{'hash'};
1282                 }
1283
1284                 # If the action was a snapshot, we can absorb the
1285                 # snapshot_format parameter too
1286                 if ($is_snapshot) {
1287                         my $fmt = $params{'snapshot_format'};
1288                         # snapshot_format should always be defined when href()
1289                         # is called, but just in case some code forgets, we
1290                         # fall back to the default
1291                         $fmt ||= $snapshot_fmts[0];
1292                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1293                         delete $params{'snapshot_format'};
1294                 }
1295         }
1296
1297         # now encode the parameters explicitly
1298         my @result = ();
1299         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1300                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1301                 if (defined $params{$name}) {
1302                         if (ref($params{$name}) eq "ARRAY") {
1303                                 foreach my $par (@{$params{$name}}) {
1304                                         push @result, $symbol . "=" . esc_param($par);
1305                                 }
1306                         } else {
1307                                 push @result, $symbol . "=" . esc_param($params{$name});
1308                         }
1309                 }
1310         }
1311         $href .= "?" . join(';', @result) if scalar @result;
1312
1313         # final transformation: trailing spaces must be escaped (URI-encoded)
1314         $href =~ s/(\s+)$/CGI::escape($1)/e;
1315
1316         return $href;
1317 }
1318
1319
1320 ## ======================================================================
1321 ## validation, quoting/unquoting and escaping
1322
1323 sub validate_action {
1324         my $input = shift || return undef;
1325         return undef unless exists $actions{$input};
1326         return $input;
1327 }
1328
1329 sub validate_project {
1330         my $input = shift || return undef;
1331         if (!validate_pathname($input) ||
1332                 !(-d "$projectroot/$input") ||
1333                 !check_export_ok("$projectroot/$input") ||
1334                 ($strict_export && !project_in_list($input))) {
1335                 return undef;
1336         } else {
1337                 return $input;
1338         }
1339 }
1340
1341 sub validate_pathname {
1342         my $input = shift || return undef;
1343
1344         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1345         # at the beginning, at the end, and between slashes.
1346         # also this catches doubled slashes
1347         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1348                 return undef;
1349         }
1350         # no null characters
1351         if ($input =~ m!\0!) {
1352                 return undef;
1353         }
1354         return $input;
1355 }
1356
1357 sub validate_refname {
1358         my $input = shift || return undef;
1359
1360         # textual hashes are O.K.
1361         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1362                 return $input;
1363         }
1364         # it must be correct pathname
1365         $input = validate_pathname($input)
1366                 or return undef;
1367         # restrictions on ref name according to git-check-ref-format
1368         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1369                 return undef;
1370         }
1371         return $input;
1372 }
1373
1374 # decode sequences of octets in utf8 into Perl's internal form,
1375 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1376 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1377 sub to_utf8 {
1378         my $str = shift;
1379         return undef unless defined $str;
1380         if (utf8::valid($str)) {
1381                 utf8::decode($str);
1382                 return $str;
1383         } else {
1384                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1385         }
1386 }
1387
1388 # quote unsafe chars, but keep the slash, even when it's not
1389 # correct, but quoted slashes look too horrible in bookmarks
1390 sub esc_param {
1391         my $str = shift;
1392         return undef unless defined $str;
1393         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1394         $str =~ s/ /\+/g;
1395         return $str;
1396 }
1397
1398 # the quoting rules for path_info fragment are slightly different
1399 sub esc_path_info {
1400         my $str = shift;
1401         return undef unless defined $str;
1402
1403         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1404         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1405
1406         return $str;
1407 }
1408
1409 # quote unsafe chars in whole URL, so some characters cannot be quoted
1410 sub esc_url {
1411         my $str = shift;
1412         return undef unless defined $str;
1413         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1414         $str =~ s/ /\+/g;
1415         return $str;
1416 }
1417
1418 # quote unsafe characters in HTML attributes
1419 sub esc_attr {
1420
1421         # for XHTML conformance escaping '"' to '&quot;' is not enough
1422         return esc_html(@_);
1423 }
1424
1425 # replace invalid utf8 character with SUBSTITUTION sequence
1426 sub esc_html {
1427         my $str = shift;
1428         my %opts = @_;
1429
1430         return undef unless defined $str;
1431
1432         $str = to_utf8($str);
1433         $str = $cgi->escapeHTML($str);
1434         if ($opts{'-nbsp'}) {
1435                 $str =~ s/ /&nbsp;/g;
1436         }
1437         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1438         return $str;
1439 }
1440
1441 # quote control characters and escape filename to HTML
1442 sub esc_path {
1443         my $str = shift;
1444         my %opts = @_;
1445
1446         return undef unless defined $str;
1447
1448         $str = to_utf8($str);
1449         $str = $cgi->escapeHTML($str);
1450         if ($opts{'-nbsp'}) {
1451                 $str =~ s/ /&nbsp;/g;
1452         }
1453         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1454         return $str;
1455 }
1456
1457 # Make control characters "printable", using character escape codes (CEC)
1458 sub quot_cec {
1459         my $cntrl = shift;
1460         my %opts = @_;
1461         my %es = ( # character escape codes, aka escape sequences
1462                 "\t" => '\t',   # tab            (HT)
1463                 "\n" => '\n',   # line feed      (LF)
1464                 "\r" => '\r',   # carrige return (CR)
1465                 "\f" => '\f',   # form feed      (FF)
1466                 "\b" => '\b',   # backspace      (BS)
1467                 "\a" => '\a',   # alarm (bell)   (BEL)
1468                 "\e" => '\e',   # escape         (ESC)
1469                 "\013" => '\v', # vertical tab   (VT)
1470                 "\000" => '\0', # nul character  (NUL)
1471         );
1472         my $chr = ( (exists $es{$cntrl})
1473                     ? $es{$cntrl}
1474                     : sprintf('\%2x', ord($cntrl)) );
1475         if ($opts{-nohtml}) {
1476                 return $chr;
1477         } else {
1478                 return "<span class=\"cntrl\">$chr</span>";
1479         }
1480 }
1481
1482 # Alternatively use unicode control pictures codepoints,
1483 # Unicode "printable representation" (PR)
1484 sub quot_upr {
1485         my $cntrl = shift;
1486         my %opts = @_;
1487
1488         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1489         if ($opts{-nohtml}) {
1490                 return $chr;
1491         } else {
1492                 return "<span class=\"cntrl\">$chr</span>";
1493         }
1494 }
1495
1496 # git may return quoted and escaped filenames
1497 sub unquote {
1498         my $str = shift;
1499
1500         sub unq {
1501                 my $seq = shift;
1502                 my %es = ( # character escape codes, aka escape sequences
1503                         't' => "\t",   # tab            (HT, TAB)
1504                         'n' => "\n",   # newline        (NL)
1505                         'r' => "\r",   # return         (CR)
1506                         'f' => "\f",   # form feed      (FF)
1507                         'b' => "\b",   # backspace      (BS)
1508                         'a' => "\a",   # alarm (bell)   (BEL)
1509                         'e' => "\e",   # escape         (ESC)
1510                         'v' => "\013", # vertical tab   (VT)
1511                 );
1512
1513                 if ($seq =~ m/^[0-7]{1,3}$/) {
1514                         # octal char sequence
1515                         return chr(oct($seq));
1516                 } elsif (exists $es{$seq}) {
1517                         # C escape sequence, aka character escape code
1518                         return $es{$seq};
1519                 }
1520                 # quoted ordinary character
1521                 return $seq;
1522         }
1523
1524         if ($str =~ m/^"(.*)"$/) {
1525                 # needs unquoting
1526                 $str = $1;
1527                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1528         }
1529         return $str;
1530 }
1531
1532 # escape tabs (convert tabs to spaces)
1533 sub untabify {
1534         my $line = shift;
1535
1536         while ((my $pos = index($line, "\t")) != -1) {
1537                 if (my $count = (8 - ($pos % 8))) {
1538                         my $spaces = ' ' x $count;
1539                         $line =~ s/\t/$spaces/;
1540                 }
1541         }
1542
1543         return $line;
1544 }
1545
1546 sub project_in_list {
1547         my $project = shift;
1548         my @list = git_get_projects_list();
1549         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1550 }
1551
1552 ## ----------------------------------------------------------------------
1553 ## HTML aware string manipulation
1554
1555 # Try to chop given string on a word boundary between position
1556 # $len and $len+$add_len. If there is no word boundary there,
1557 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1558 # (marking chopped part) would be longer than given string.
1559 sub chop_str {
1560         my $str = shift;
1561         my $len = shift;
1562         my $add_len = shift || 10;
1563         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1564
1565         # Make sure perl knows it is utf8 encoded so we don't
1566         # cut in the middle of a utf8 multibyte char.
1567         $str = to_utf8($str);
1568
1569         # allow only $len chars, but don't cut a word if it would fit in $add_len
1570         # if it doesn't fit, cut it if it's still longer than the dots we would add
1571         # remove chopped character entities entirely
1572
1573         # when chopping in the middle, distribute $len into left and right part
1574         # return early if chopping wouldn't make string shorter
1575         if ($where eq 'center') {
1576                 return $str if ($len + 5 >= length($str)); # filler is length 5
1577                 $len = int($len/2);
1578         } else {
1579                 return $str if ($len + 4 >= length($str)); # filler is length 4
1580         }
1581
1582         # regexps: ending and beginning with word part up to $add_len
1583         my $endre = qr/.{$len}\w{0,$add_len}/;
1584         my $begre = qr/\w{0,$add_len}.{$len}/;
1585
1586         if ($where eq 'left') {
1587                 $str =~ m/^(.*?)($begre)$/;
1588                 my ($lead, $body) = ($1, $2);
1589                 if (length($lead) > 4) {
1590                         $lead = " ...";
1591                 }
1592                 return "$lead$body";
1593
1594         } elsif ($where eq 'center') {
1595                 $str =~ m/^($endre)(.*)$/;
1596                 my ($left, $str)  = ($1, $2);
1597                 $str =~ m/^(.*?)($begre)$/;
1598                 my ($mid, $right) = ($1, $2);
1599                 if (length($mid) > 5) {
1600                         $mid = " ... ";
1601                 }
1602                 return "$left$mid$right";
1603
1604         } else {
1605                 $str =~ m/^($endre)(.*)$/;
1606                 my $body = $1;
1607                 my $tail = $2;
1608                 if (length($tail) > 4) {
1609                         $tail = "... ";
1610                 }
1611                 return "$body$tail";
1612         }
1613 }
1614
1615 # takes the same arguments as chop_str, but also wraps a <span> around the
1616 # result with a title attribute if it does get chopped. Additionally, the
1617 # string is HTML-escaped.
1618 sub chop_and_escape_str {
1619         my ($str) = @_;
1620
1621         my $chopped = chop_str(@_);
1622         if ($chopped eq $str) {
1623                 return esc_html($chopped);
1624         } else {
1625                 $str =~ s/[[:cntrl:]]/?/g;
1626                 return $cgi->span({-title=>$str}, esc_html($chopped));
1627         }
1628 }
1629
1630 ## ----------------------------------------------------------------------
1631 ## functions returning short strings
1632
1633 # CSS class for given age value (in seconds)
1634 sub age_class {
1635         my $age = shift;
1636
1637         if (!defined $age) {
1638                 return "noage";
1639         } elsif ($age < 60*60*2) {
1640                 return "age0";
1641         } elsif ($age < 60*60*24*2) {
1642                 return "age1";
1643         } else {
1644                 return "age2";
1645         }
1646 }
1647
1648 # convert age in seconds to "nn units ago" string
1649 sub age_string {
1650         my $age = shift;
1651         my $age_str;
1652
1653         if ($age > 60*60*24*365*2) {
1654                 $age_str = (int $age/60/60/24/365);
1655                 $age_str .= " years ago";
1656         } elsif ($age > 60*60*24*(365/12)*2) {
1657                 $age_str = int $age/60/60/24/(365/12);
1658                 $age_str .= " months ago";
1659         } elsif ($age > 60*60*24*7*2) {
1660                 $age_str = int $age/60/60/24/7;
1661                 $age_str .= " weeks ago";
1662         } elsif ($age > 60*60*24*2) {
1663                 $age_str = int $age/60/60/24;
1664                 $age_str .= " days ago";
1665         } elsif ($age > 60*60*2) {
1666                 $age_str = int $age/60/60;
1667                 $age_str .= " hours ago";
1668         } elsif ($age > 60*2) {
1669                 $age_str = int $age/60;
1670                 $age_str .= " min ago";
1671         } elsif ($age > 2) {
1672                 $age_str = int $age;
1673                 $age_str .= " sec ago";
1674         } else {
1675                 $age_str .= " right now";
1676         }
1677         return $age_str;
1678 }
1679
1680 use constant {
1681         S_IFINVALID => 0030000,
1682         S_IFGITLINK => 0160000,
1683 };
1684
1685 # submodule/subproject, a commit object reference
1686 sub S_ISGITLINK {
1687         my $mode = shift;
1688
1689         return (($mode & S_IFMT) == S_IFGITLINK)
1690 }
1691
1692 # convert file mode in octal to symbolic file mode string
1693 sub mode_str {
1694         my $mode = oct shift;
1695
1696         if (S_ISGITLINK($mode)) {
1697                 return 'm---------';
1698         } elsif (S_ISDIR($mode & S_IFMT)) {
1699                 return 'drwxr-xr-x';
1700         } elsif (S_ISLNK($mode)) {
1701                 return 'lrwxrwxrwx';
1702         } elsif (S_ISREG($mode)) {
1703                 # git cares only about the executable bit
1704                 if ($mode & S_IXUSR) {
1705                         return '-rwxr-xr-x';
1706                 } else {
1707                         return '-rw-r--r--';
1708                 };
1709         } else {
1710                 return '----------';
1711         }
1712 }
1713
1714 # convert file mode in octal to file type string
1715 sub file_type {
1716         my $mode = shift;
1717
1718         if ($mode !~ m/^[0-7]+$/) {
1719                 return $mode;
1720         } else {
1721                 $mode = oct $mode;
1722         }
1723
1724         if (S_ISGITLINK($mode)) {
1725                 return "submodule";
1726         } elsif (S_ISDIR($mode & S_IFMT)) {
1727                 return "directory";
1728         } elsif (S_ISLNK($mode)) {
1729                 return "symlink";
1730         } elsif (S_ISREG($mode)) {
1731                 return "file";
1732         } else {
1733                 return "unknown";
1734         }
1735 }
1736
1737 # convert file mode in octal to file type description string
1738 sub file_type_long {
1739         my $mode = shift;
1740
1741         if ($mode !~ m/^[0-7]+$/) {
1742                 return $mode;
1743         } else {
1744                 $mode = oct $mode;
1745         }
1746
1747         if (S_ISGITLINK($mode)) {
1748                 return "submodule";
1749         } elsif (S_ISDIR($mode & S_IFMT)) {
1750                 return "directory";
1751         } elsif (S_ISLNK($mode)) {
1752                 return "symlink";
1753         } elsif (S_ISREG($mode)) {
1754                 if ($mode & S_IXUSR) {
1755                         return "executable";
1756                 } else {
1757                         return "file";
1758                 };
1759         } else {
1760                 return "unknown";
1761         }
1762 }
1763
1764
1765 ## ----------------------------------------------------------------------
1766 ## functions returning short HTML fragments, or transforming HTML fragments
1767 ## which don't belong to other sections
1768
1769 # format line of commit message.
1770 sub format_log_line_html {
1771         my $line = shift;
1772
1773         $line = esc_html($line, -nbsp=>1);
1774         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1775                 $cgi->a({-href => href(action=>"object", hash=>$1),
1776                                         -class => "text"}, $1);
1777         }eg;
1778
1779         return $line;
1780 }
1781
1782 # format marker of refs pointing to given object
1783
1784 # the destination action is chosen based on object type and current context:
1785 # - for annotated tags, we choose the tag view unless it's the current view
1786 #   already, in which case we go to shortlog view
1787 # - for other refs, we keep the current view if we're in history, shortlog or
1788 #   log view, and select shortlog otherwise
1789 sub format_ref_marker {
1790         my ($refs, $id) = @_;
1791         my $markers = '';
1792
1793         if (defined $refs->{$id}) {
1794                 foreach my $ref (@{$refs->{$id}}) {
1795                         # this code exploits the fact that non-lightweight tags are the
1796                         # only indirect objects, and that they are the only objects for which
1797                         # we want to use tag instead of shortlog as action
1798                         my ($type, $name) = qw();
1799                         my $indirect = ($ref =~ s/\^\{\}$//);
1800                         # e.g. tags/v2.6.11 or heads/next
1801                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
1802                                 $type = $1;
1803                                 $name = $2;
1804                         } else {
1805                                 $type = "ref";
1806                                 $name = $ref;
1807                         }
1808
1809                         my $class = $type;
1810                         $class .= " indirect" if $indirect;
1811
1812                         my $dest_action = "shortlog";
1813
1814                         if ($indirect) {
1815                                 $dest_action = "tag" unless $action eq "tag";
1816                         } elsif ($action =~ /^(history|(short)?log)$/) {
1817                                 $dest_action = $action;
1818                         }
1819
1820                         my $dest = "";
1821                         $dest .= "refs/" unless $ref =~ m!^refs/!;
1822                         $dest .= $ref;
1823
1824                         my $link = $cgi->a({
1825                                 -href => href(
1826                                         action=>$dest_action,
1827                                         hash=>$dest
1828                                 )}, $name);
1829
1830                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
1831                                 $link . "</span>";
1832                 }
1833         }
1834
1835         if ($markers) {
1836                 return ' <span class="refs">'. $markers . '</span>';
1837         } else {
1838                 return "";
1839         }
1840 }
1841
1842 # format, perhaps shortened and with markers, title line
1843 sub format_subject_html {
1844         my ($long, $short, $href, $extra) = @_;
1845         $extra = '' unless defined($extra);
1846
1847         if (length($short) < length($long)) {
1848                 $long =~ s/[[:cntrl:]]/?/g;
1849                 return $cgi->a({-href => $href, -class => "list subject",
1850                                 -title => to_utf8($long)},
1851                        esc_html($short)) . $extra;
1852         } else {
1853                 return $cgi->a({-href => $href, -class => "list subject"},
1854                        esc_html($long)) . $extra;
1855         }
1856 }
1857
1858 # Rather than recomputing the url for an email multiple times, we cache it
1859 # after the first hit. This gives a visible benefit in views where the avatar
1860 # for the same email is used repeatedly (e.g. shortlog).
1861 # The cache is shared by all avatar engines (currently gravatar only), which
1862 # are free to use it as preferred. Since only one avatar engine is used for any
1863 # given page, there's no risk for cache conflicts.
1864 our %avatar_cache = ();
1865
1866 # Compute the picon url for a given email, by using the picon search service over at
1867 # http://www.cs.indiana.edu/picons/search.html
1868 sub picon_url {
1869         my $email = lc shift;
1870         if (!$avatar_cache{$email}) {
1871                 my ($user, $domain) = split('@', $email);
1872                 $avatar_cache{$email} =
1873                         "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
1874                         "$domain/$user/" .
1875                         "users+domains+unknown/up/single";
1876         }
1877         return $avatar_cache{$email};
1878 }
1879
1880 # Compute the gravatar url for a given email, if it's not in the cache already.
1881 # Gravatar stores only the part of the URL before the size, since that's the
1882 # one computationally more expensive. This also allows reuse of the cache for
1883 # different sizes (for this particular engine).
1884 sub gravatar_url {
1885         my $email = lc shift;
1886         my $size = shift;
1887         $avatar_cache{$email} ||=
1888                 "http://www.gravatar.com/avatar/" .
1889                         Digest::MD5::md5_hex($email) . "?s=";
1890         return $avatar_cache{$email} . $size;
1891 }
1892
1893 # Insert an avatar for the given $email at the given $size if the feature
1894 # is enabled.
1895 sub git_get_avatar {
1896         my ($email, %opts) = @_;
1897         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
1898         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
1899         $opts{-size} ||= 'default';
1900         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
1901         my $url = "";
1902         if ($git_avatar eq 'gravatar') {
1903                 $url = gravatar_url($email, $size);
1904         } elsif ($git_avatar eq 'picon') {
1905                 $url = picon_url($email);
1906         }
1907         # Other providers can be added by extending the if chain, defining $url
1908         # as needed. If no variant puts something in $url, we assume avatars
1909         # are completely disabled/unavailable.
1910         if ($url) {
1911                 return $pre_white .
1912                        "<img width=\"$size\" " .
1913                             "class=\"avatar\" " .
1914                             "src=\"".esc_url($url)."\" " .
1915                             "alt=\"\" " .
1916                        "/>" . $post_white;
1917         } else {
1918                 return "";
1919         }
1920 }
1921
1922 sub format_search_author {
1923         my ($author, $searchtype, $displaytext) = @_;
1924         my $have_search = gitweb_check_feature('search');
1925
1926         if ($have_search) {
1927                 my $performed = "";
1928                 if ($searchtype eq 'author') {
1929                         $performed = "authored";
1930                 } elsif ($searchtype eq 'committer') {
1931                         $performed = "committed";
1932                 }
1933
1934                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
1935                                 searchtext=>$author,
1936                                 searchtype=>$searchtype), class=>"list",
1937                                 title=>"Search for commits $performed by $author"},
1938                                 $displaytext);
1939
1940         } else {
1941                 return $displaytext;
1942         }
1943 }
1944
1945 # format the author name of the given commit with the given tag
1946 # the author name is chopped and escaped according to the other
1947 # optional parameters (see chop_str).
1948 sub format_author_html {
1949         my $tag = shift;
1950         my $co = shift;
1951         my $author = chop_and_escape_str($co->{'author_name'}, @_);
1952         return "<$tag class=\"author\">" .
1953                format_search_author($co->{'author_name'}, "author",
1954                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
1955                        $author) .
1956                "</$tag>";
1957 }
1958
1959 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
1960 sub format_git_diff_header_line {
1961         my $line = shift;
1962         my $diffinfo = shift;
1963         my ($from, $to) = @_;
1964
1965         if ($diffinfo->{'nparents'}) {
1966                 # combined diff
1967                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
1968                 if ($to->{'href'}) {
1969                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
1970                                          esc_path($to->{'file'}));
1971                 } else { # file was deleted (no href)
1972                         $line .= esc_path($to->{'file'});
1973                 }
1974         } else {
1975                 # "ordinary" diff
1976                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
1977                 if ($from->{'href'}) {
1978                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
1979                                          'a/' . esc_path($from->{'file'}));
1980                 } else { # file was added (no href)
1981                         $line .= 'a/' . esc_path($from->{'file'});
1982                 }
1983                 $line .= ' ';
1984                 if ($to->{'href'}) {
1985                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
1986                                          'b/' . esc_path($to->{'file'}));
1987                 } else { # file was deleted
1988                         $line .= 'b/' . esc_path($to->{'file'});
1989                 }
1990         }
1991
1992         return "<div class=\"diff header\">$line</div>\n";
1993 }
1994
1995 # format extended diff header line, before patch itself
1996 sub format_extended_diff_header_line {
1997         my $line = shift;
1998         my $diffinfo = shift;
1999         my ($from, $to) = @_;
2000
2001         # match <path>
2002         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2003                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2004                                        esc_path($from->{'file'}));
2005         }
2006         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2007                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2008                                  esc_path($to->{'file'}));
2009         }
2010         # match single <mode>
2011         if ($line =~ m/\s(\d{6})$/) {
2012                 $line .= '<span class="info"> (' .
2013                          file_type_long($1) .
2014                          ')</span>';
2015         }
2016         # match <hash>
2017         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2018                 # can match only for combined diff
2019                 $line = 'index ';
2020                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2021                         if ($from->{'href'}[$i]) {
2022                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2023                                                   -class=>"hash"},
2024                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2025                         } else {
2026                                 $line .= '0' x 7;
2027                         }
2028                         # separator
2029                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2030                 }
2031                 $line .= '..';
2032                 if ($to->{'href'}) {
2033                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2034                                          substr($diffinfo->{'to_id'},0,7));
2035                 } else {
2036                         $line .= '0' x 7;
2037                 }
2038
2039         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2040                 # can match only for ordinary diff
2041                 my ($from_link, $to_link);
2042                 if ($from->{'href'}) {
2043                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2044                                              substr($diffinfo->{'from_id'},0,7));
2045                 } else {
2046                         $from_link = '0' x 7;
2047                 }
2048                 if ($to->{'href'}) {
2049                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2050                                            substr($diffinfo->{'to_id'},0,7));
2051                 } else {
2052                         $to_link = '0' x 7;
2053                 }
2054                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2055                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2056         }
2057
2058         return $line . "<br/>\n";
2059 }
2060
2061 # format from-file/to-file diff header
2062 sub format_diff_from_to_header {
2063         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2064         my $line;
2065         my $result = '';
2066
2067         $line = $from_line;
2068         #assert($line =~ m/^---/) if DEBUG;
2069         # no extra formatting for "^--- /dev/null"
2070         if (! $diffinfo->{'nparents'}) {
2071                 # ordinary (single parent) diff
2072                 if ($line =~ m!^--- "?a/!) {
2073                         if ($from->{'href'}) {
2074                                 $line = '--- a/' .
2075                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2076                                                 esc_path($from->{'file'}));
2077                         } else {
2078                                 $line = '--- a/' .
2079                                         esc_path($from->{'file'});
2080                         }
2081                 }
2082                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2083
2084         } else {
2085                 # combined diff (merge commit)
2086                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2087                         if ($from->{'href'}[$i]) {
2088                                 $line = '--- ' .
2089                                         $cgi->a({-href=>href(action=>"blobdiff",
2090                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2091                                                              hash_parent_base=>$parents[$i],
2092                                                              file_parent=>$from->{'file'}[$i],
2093                                                              hash=>$diffinfo->{'to_id'},
2094                                                              hash_base=>$hash,
2095                                                              file_name=>$to->{'file'}),
2096                                                  -class=>"path",
2097                                                  -title=>"diff" . ($i+1)},
2098                                                 $i+1) .
2099                                         '/' .
2100                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2101                                                 esc_path($from->{'file'}[$i]));
2102                         } else {
2103                                 $line = '--- /dev/null';
2104                         }
2105                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2106                 }
2107         }
2108
2109         $line = $to_line;
2110         #assert($line =~ m/^\+\+\+/) if DEBUG;
2111         # no extra formatting for "^+++ /dev/null"
2112         if ($line =~ m!^\+\+\+ "?b/!) {
2113                 if ($to->{'href'}) {
2114                         $line = '+++ b/' .
2115                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2116                                         esc_path($to->{'file'}));
2117                 } else {
2118                         $line = '+++ b/' .
2119                                 esc_path($to->{'file'});
2120                 }
2121         }
2122         $result .= qq!<div class="diff to_file">$line</div>\n!;
2123
2124         return $result;
2125 }
2126
2127 # create note for patch simplified by combined diff
2128 sub format_diff_cc_simplified {
2129         my ($diffinfo, @parents) = @_;
2130         my $result = '';
2131
2132         $result .= "<div class=\"diff header\">" .
2133                    "diff --cc ";
2134         if (!is_deleted($diffinfo)) {
2135                 $result .= $cgi->a({-href => href(action=>"blob",
2136                                                   hash_base=>$hash,
2137                                                   hash=>$diffinfo->{'to_id'},
2138                                                   file_name=>$diffinfo->{'to_file'}),
2139                                     -class => "path"},
2140                                    esc_path($diffinfo->{'to_file'}));
2141         } else {
2142                 $result .= esc_path($diffinfo->{'to_file'});
2143         }
2144         $result .= "</div>\n" . # class="diff header"
2145                    "<div class=\"diff nodifferences\">" .
2146                    "Simple merge" .
2147                    "</div>\n"; # class="diff nodifferences"
2148
2149         return $result;
2150 }
2151
2152 # format patch (diff) line (not to be used for diff headers)
2153 sub format_diff_line {
2154         my $line = shift;
2155         my ($from, $to) = @_;
2156         my $diff_class = "";
2157
2158         chomp $line;
2159
2160         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2161                 # combined diff
2162                 my $prefix = substr($line, 0, scalar @{$from->{'href'}});
2163                 if ($line =~ m/^\@{3}/) {
2164                         $diff_class = " chunk_header";
2165                 } elsif ($line =~ m/^\\/) {
2166                         $diff_class = " incomplete";
2167                 } elsif ($prefix =~ tr/+/+/) {
2168                         $diff_class = " add";
2169                 } elsif ($prefix =~ tr/-/-/) {
2170                         $diff_class = " rem";
2171                 }
2172         } else {
2173                 # assume ordinary diff
2174                 my $char = substr($line, 0, 1);
2175                 if ($char eq '+') {
2176                         $diff_class = " add";
2177                 } elsif ($char eq '-') {
2178                         $diff_class = " rem";
2179                 } elsif ($char eq '@') {
2180                         $diff_class = " chunk_header";
2181                 } elsif ($char eq "\\") {
2182                         $diff_class = " incomplete";
2183                 }
2184         }
2185         $line = untabify($line);
2186         if ($from && $to && $line =~ m/^\@{2} /) {
2187                 my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2188                         $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2189
2190                 $from_lines = 0 unless defined $from_lines;
2191                 $to_lines   = 0 unless defined $to_lines;
2192
2193                 if ($from->{'href'}) {
2194                         $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2195                                              -class=>"list"}, $from_text);
2196                 }
2197                 if ($to->{'href'}) {
2198                         $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2199                                              -class=>"list"}, $to_text);
2200                 }
2201                 $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2202                         "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2203                 return "<div class=\"diff$diff_class\">$line</div>\n";
2204         } elsif ($from && $to && $line =~ m/^\@{3}/) {
2205                 my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2206                 my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2207
2208                 @from_text = split(' ', $ranges);
2209                 for (my $i = 0; $i < @from_text; ++$i) {
2210                         ($from_start[$i], $from_nlines[$i]) =
2211                                 (split(',', substr($from_text[$i], 1)), 0);
2212                 }
2213
2214                 $to_text   = pop @from_text;
2215                 $to_start  = pop @from_start;
2216                 $to_nlines = pop @from_nlines;
2217
2218                 $line = "<span class=\"chunk_info\">$prefix ";
2219                 for (my $i = 0; $i < @from_text; ++$i) {
2220                         if ($from->{'href'}[$i]) {
2221                                 $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2222                                                   -class=>"list"}, $from_text[$i]);
2223                         } else {
2224                                 $line .= $from_text[$i];
2225                         }
2226                         $line .= " ";
2227                 }
2228                 if ($to->{'href'}) {
2229                         $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2230                                           -class=>"list"}, $to_text);
2231                 } else {
2232                         $line .= $to_text;
2233                 }
2234                 $line .= " $prefix</span>" .
2235                          "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2236                 return "<div class=\"diff$diff_class\">$line</div>\n";
2237         }
2238         return "<div class=\"diff$diff_class\">" . esc_html($line, -nbsp=>1) . "</div>\n";
2239 }
2240
2241 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2242 # linked.  Pass the hash of the tree/commit to snapshot.
2243 sub format_snapshot_links {
2244         my ($hash) = @_;
2245         my $num_fmts = @snapshot_fmts;
2246         if ($num_fmts > 1) {
2247                 # A parenthesized list of links bearing format names.
2248                 # e.g. "snapshot (_tar.gz_ _zip_)"
2249                 return "snapshot (" . join(' ', map
2250                         $cgi->a({
2251                                 -href => href(
2252                                         action=>"snapshot",
2253                                         hash=>$hash,
2254                                         snapshot_format=>$_
2255                                 )
2256                         }, $known_snapshot_formats{$_}{'display'})
2257                 , @snapshot_fmts) . ")";
2258         } elsif ($num_fmts == 1) {
2259                 # A single "snapshot" link whose tooltip bears the format name.
2260                 # i.e. "_snapshot_"
2261                 my ($fmt) = @snapshot_fmts;
2262                 return
2263                         $cgi->a({
2264                                 -href => href(
2265                                         action=>"snapshot",
2266                                         hash=>$hash,
2267                                         snapshot_format=>$fmt
2268                                 ),
2269                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2270                         }, "snapshot");
2271         } else { # $num_fmts == 0
2272                 return undef;
2273         }
2274 }
2275
2276 ## ......................................................................
2277 ## functions returning values to be passed, perhaps after some
2278 ## transformation, to other functions; e.g. returning arguments to href()
2279
2280 # returns hash to be passed to href to generate gitweb URL
2281 # in -title key it returns description of link
2282 sub get_feed_info {
2283         my $format = shift || 'Atom';
2284         my %res = (action => lc($format));
2285
2286         # feed links are possible only for project views
2287         return unless (defined $project);
2288         # some views should link to OPML, or to generic project feed,
2289         # or don't have specific feed yet (so they should use generic)
2290         return if ($action =~ /^(?:tags|heads|forks|tag|search)$/x);
2291
2292         my $branch;
2293         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2294         # from tag links; this also makes possible to detect branch links
2295         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2296             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2297                 $branch = $1;
2298         }
2299         # find log type for feed description (title)
2300         my $type = 'log';
2301         if (defined $file_name) {
2302                 $type  = "history of $file_name";
2303                 $type .= "/" if ($action eq 'tree');
2304                 $type .= " on '$branch'" if (defined $branch);
2305         } else {
2306                 $type = "log of $branch" if (defined $branch);
2307         }
2308
2309         $res{-title} = $type;
2310         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2311         $res{'file_name'} = $file_name;
2312
2313         return %res;
2314 }
2315
2316 ## ----------------------------------------------------------------------
2317 ## git utility subroutines, invoking git commands
2318
2319 # returns path to the core git executable and the --git-dir parameter as list
2320 sub git_cmd {
2321         $number_of_git_cmds++;
2322         return $GIT, '--git-dir='.$git_dir;
2323 }
2324
2325 # quote the given arguments for passing them to the shell
2326 # quote_command("command", "arg 1", "arg with ' and ! characters")
2327 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2328 # Try to avoid using this function wherever possible.
2329 sub quote_command {
2330         return join(' ',
2331                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2332 }
2333
2334 # get HEAD ref of given project as hash
2335 sub git_get_head_hash {
2336         return git_get_full_hash(shift, 'HEAD');
2337 }
2338
2339 sub git_get_full_hash {
2340         return git_get_hash(@_);
2341 }
2342
2343 sub git_get_short_hash {
2344         return git_get_hash(@_, '--short=7');
2345 }
2346
2347 sub git_get_hash {
2348         my ($project, $hash, @options) = @_;
2349         my $o_git_dir = $git_dir;
2350         my $retval = undef;
2351         $git_dir = "$projectroot/$project";
2352         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2353             '--verify', '-q', @options, $hash) {
2354                 $retval = <$fd>;
2355                 chomp $retval if defined $retval;
2356                 close $fd;
2357         }
2358         if (defined $o_git_dir) {
2359                 $git_dir = $o_git_dir;
2360         }
2361         return $retval;
2362 }
2363
2364 # get type of given object
2365 sub git_get_type {
2366         my $hash = shift;
2367
2368         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2369         my $type = <$fd>;
2370         close $fd or return;
2371         chomp $type;
2372         return $type;
2373 }
2374
2375 # repository configuration
2376 our $config_file = '';
2377 our %config;
2378
2379 # store multiple values for single key as anonymous array reference
2380 # single values stored directly in the hash, not as [ <value> ]
2381 sub hash_set_multi {
2382         my ($hash, $key, $value) = @_;
2383
2384         if (!exists $hash->{$key}) {
2385                 $hash->{$key} = $value;
2386         } elsif (!ref $hash->{$key}) {
2387                 $hash->{$key} = [ $hash->{$key}, $value ];
2388         } else {
2389                 push @{$hash->{$key}}, $value;
2390         }
2391 }
2392
2393 # return hash of git project configuration
2394 # optionally limited to some section, e.g. 'gitweb'
2395 sub git_parse_project_config {
2396         my $section_regexp = shift;
2397         my %config;
2398
2399         local $/ = "\0";
2400
2401         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2402                 or return;
2403
2404         while (my $keyval = <$fh>) {
2405                 chomp $keyval;
2406                 my ($key, $value) = split(/\n/, $keyval, 2);
2407
2408                 hash_set_multi(\%config, $key, $value)
2409                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2410         }
2411         close $fh;
2412
2413         return %config;
2414 }
2415
2416 # convert config value to boolean: 'true' or 'false'
2417 # no value, number > 0, 'true' and 'yes' values are true
2418 # rest of values are treated as false (never as error)
2419 sub config_to_bool {
2420         my $val = shift;
2421
2422         return 1 if !defined $val;             # section.key
2423
2424         # strip leading and trailing whitespace
2425         $val =~ s/^\s+//;
2426         $val =~ s/\s+$//;
2427
2428         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2429                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2430 }
2431
2432 # convert config value to simple decimal number
2433 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2434 # to be multiplied by 1024, 1048576, or 1073741824
2435 sub config_to_int {
2436         my $val = shift;
2437
2438         # strip leading and trailing whitespace
2439         $val =~ s/^\s+//;
2440         $val =~ s/\s+$//;
2441
2442         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2443                 $unit = lc($unit);
2444                 # unknown unit is treated as 1
2445                 return $num * ($unit eq 'g' ? 1073741824 :
2446                                $unit eq 'm' ?    1048576 :
2447                                $unit eq 'k' ?       1024 : 1);
2448         }
2449         return $val;
2450 }
2451
2452 # convert config value to array reference, if needed
2453 sub config_to_multi {
2454         my $val = shift;
2455
2456         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2457 }
2458
2459 sub git_get_project_config {
2460         my ($key, $type) = @_;
2461
2462         return unless defined $git_dir;
2463
2464         # key sanity check
2465         return unless ($key);
2466         $key =~ s/^gitweb\.//;
2467         return if ($key =~ m/\W/);
2468
2469         # type sanity check
2470         if (defined $type) {
2471                 $type =~ s/^--//;
2472                 $type = undef
2473                         unless ($type eq 'bool' || $type eq 'int');
2474         }
2475
2476         # get config
2477         if (!defined $config_file ||
2478             $config_file ne "$git_dir/config") {
2479                 %config = git_parse_project_config('gitweb');
2480                 $config_file = "$git_dir/config";
2481         }
2482
2483         # check if config variable (key) exists
2484         return unless exists $config{"gitweb.$key"};
2485
2486         # ensure given type
2487         if (!defined $type) {
2488                 return $config{"gitweb.$key"};
2489         } elsif ($type eq 'bool') {
2490                 # backward compatibility: 'git config --bool' returns true/false
2491                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2492         } elsif ($type eq 'int') {
2493                 return config_to_int($config{"gitweb.$key"});
2494         }
2495         return $config{"gitweb.$key"};
2496 }
2497
2498 # get hash of given path at given ref
2499 sub git_get_hash_by_path {
2500         my $base = shift;
2501         my $path = shift || return undef;
2502         my $type = shift;
2503
2504         $path =~ s,/+$,,;
2505
2506         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2507                 or die_error(500, "Open git-ls-tree failed");
2508         my $line = <$fd>;
2509         close $fd or return undef;
2510
2511         if (!defined $line) {
2512                 # there is no tree or hash given by $path at $base
2513                 return undef;
2514         }
2515
2516         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2517         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2518         if (defined $type && $type ne $2) {
2519                 # type doesn't match
2520                 return undef;
2521         }
2522         return $3;
2523 }
2524
2525 # get path of entry with given hash at given tree-ish (ref)
2526 # used to get 'from' filename for combined diff (merge commit) for renames
2527 sub git_get_path_by_hash {
2528         my $base = shift || return;
2529         my $hash = shift || return;
2530
2531         local $/ = "\0";
2532
2533         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2534                 or return undef;
2535         while (my $line = <$fd>) {
2536                 chomp $line;
2537
2538                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2539                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2540                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2541                         close $fd;
2542                         return $1;
2543                 }
2544         }
2545         close $fd;
2546         return undef;
2547 }
2548
2549 ## ......................................................................
2550 ## git utility functions, directly accessing git repository
2551
2552 sub git_get_project_description {
2553         my $path = shift;
2554
2555         $git_dir = "$projectroot/$path";
2556         open my $fd, '<', "$git_dir/description"
2557                 or return git_get_project_config('description');
2558         my $descr = <$fd>;
2559         close $fd;
2560         if (defined $descr) {
2561                 chomp $descr;
2562         }
2563         return $descr;
2564 }
2565
2566 sub git_get_project_ctags {
2567         my $path = shift;
2568         my $ctags = {};
2569
2570         $git_dir = "$projectroot/$path";
2571         opendir my $dh, "$git_dir/ctags"
2572                 or return $ctags;
2573         foreach (grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh)) {
2574                 open my $ct, '<', $_ or next;
2575                 my $val = <$ct>;
2576                 chomp $val;
2577                 close $ct;
2578                 my $ctag = $_; $ctag =~ s#.*/##;
2579                 $ctags->{$ctag} = $val;
2580         }
2581         closedir $dh;
2582         $ctags;
2583 }
2584
2585 sub git_populate_project_tagcloud {
2586         my $ctags = shift;
2587
2588         # First, merge different-cased tags; tags vote on casing
2589         my %ctags_lc;
2590         foreach (keys %$ctags) {
2591                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2592                 if (not $ctags_lc{lc $_}->{topcount}
2593                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2594                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2595                         $ctags_lc{lc $_}->{topname} = $_;
2596                 }
2597         }
2598
2599         my $cloud;
2600         if (eval { require HTML::TagCloud; 1; }) {
2601                 $cloud = HTML::TagCloud->new;
2602                 foreach (sort keys %ctags_lc) {
2603                         # Pad the title with spaces so that the cloud looks
2604                         # less crammed.
2605                         my $title = $ctags_lc{$_}->{topname};
2606                         $title =~ s/ /&nbsp;/g;
2607                         $title =~ s/^/&nbsp;/g;
2608                         $title =~ s/$/&nbsp;/g;
2609                         $cloud->add($title, $home_link."?by_tag=".$_, $ctags_lc{$_}->{count});
2610                 }
2611         } else {
2612                 $cloud = \%ctags_lc;
2613         }
2614         $cloud;
2615 }
2616
2617 sub git_show_project_tagcloud {
2618         my ($cloud, $count) = @_;
2619         print STDERR ref($cloud)."..\n";
2620         if (ref $cloud eq 'HTML::TagCloud') {
2621                 return $cloud->html_and_css($count);
2622         } else {
2623                 my @tags = sort { $cloud->{$a}->{count} <=> $cloud->{$b}->{count} } keys %$cloud;
2624                 return '<p align="center">' . join (', ', map {
2625                         $cgi->a({-href=>"$home_link?by_tag=$_"}, $cloud->{$_}->{topname})
2626                 } splice(@tags, 0, $count)) . '</p>';
2627         }
2628 }
2629
2630 sub git_get_project_url_list {
2631         my $path = shift;
2632
2633         $git_dir = "$projectroot/$path";
2634         open my $fd, '<', "$git_dir/cloneurl"
2635                 or return wantarray ?
2636                 @{ config_to_multi(git_get_project_config('url')) } :
2637                    config_to_multi(git_get_project_config('url'));
2638         my @git_project_url_list = map { chomp; $_ } <$fd>;
2639         close $fd;
2640
2641         return wantarray ? @git_project_url_list : \@git_project_url_list;
2642 }
2643
2644 sub git_get_projects_list {
2645         my ($filter) = @_;
2646         my @list;
2647
2648         $filter ||= '';
2649         $filter =~ s/\.git$//;
2650
2651         my $check_forks = gitweb_check_feature('forks');
2652
2653         if (-d $projects_list) {
2654                 # search in directory
2655                 my $dir = $projects_list . ($filter ? "/$filter" : '');
2656                 # remove the trailing "/"
2657                 $dir =~ s!/+$!!;
2658                 my $pfxlen = length("$dir");
2659                 my $pfxdepth = ($dir =~ tr!/!!);
2660
2661                 File::Find::find({
2662                         follow_fast => 1, # follow symbolic links
2663                         follow_skip => 2, # ignore duplicates
2664                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2665                         wanted => sub {
2666                                 # global variables
2667                                 our $project_maxdepth;
2668                                 our $projectroot;
2669                                 # skip project-list toplevel, if we get it.
2670                                 return if (m!^[/.]$!);
2671                                 # only directories can be git repositories
2672                                 return unless (-d $_);
2673                                 # don't traverse too deep (Find is super slow on os x)
2674                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2675                                         $File::Find::prune = 1;
2676                                         return;
2677                                 }
2678
2679                                 my $subdir = substr($File::Find::name, $pfxlen + 1);
2680                                 # we check related file in $projectroot
2681                                 my $path = ($filter ? "$filter/" : '') . $subdir;
2682                                 if (check_export_ok("$projectroot/$path")) {
2683                                         push @list, { path => $path };
2684                                         $File::Find::prune = 1;
2685                                 }
2686                         },
2687                 }, "$dir");
2688
2689         } elsif (-f $projects_list) {
2690                 # read from file(url-encoded):
2691                 # 'git%2Fgit.git Linus+Torvalds'
2692                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2693                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2694                 my %paths;
2695                 open my $fd, '<', $projects_list or return;
2696         PROJECT:
2697                 while (my $line = <$fd>) {
2698                         chomp $line;
2699                         my ($path, $owner) = split ' ', $line;
2700                         $path = unescape($path);
2701                         $owner = unescape($owner);
2702                         if (!defined $path) {
2703                                 next;
2704                         }
2705                         if ($filter ne '') {
2706                                 # looking for forks;
2707                                 my $pfx = substr($path, 0, length($filter));
2708                                 if ($pfx ne $filter) {
2709                                         next PROJECT;
2710                                 }
2711                                 my $sfx = substr($path, length($filter));
2712                                 if ($sfx !~ /^\/.*\.git$/) {
2713                                         next PROJECT;
2714                                 }
2715                         } elsif ($check_forks) {
2716                         PATH:
2717                                 foreach my $filter (keys %paths) {
2718                                         # looking for forks;
2719                                         my $pfx = substr($path, 0, length($filter));
2720                                         if ($pfx ne $filter) {
2721                                                 next PATH;
2722                                         }
2723                                         my $sfx = substr($path, length($filter));
2724                                         if ($sfx !~ /^\/.*\.git$/) {
2725                                                 next PATH;
2726                                         }
2727                                         # is a fork, don't include it in
2728                                         # the list
2729                                         next PROJECT;
2730                                 }
2731                         }
2732                         if (check_export_ok("$projectroot/$path")) {
2733                                 my $pr = {
2734                                         path => $path,
2735                                         owner => to_utf8($owner),
2736                                 };
2737                                 push @list, $pr;
2738                                 (my $forks_path = $path) =~ s/\.git$//;
2739                                 $paths{$forks_path}++;
2740                         }
2741                 }
2742                 close $fd;
2743         }
2744         return @list;
2745 }
2746
2747 our $gitweb_project_owner = undef;
2748 sub git_get_project_list_from_file {
2749
2750         return if (defined $gitweb_project_owner);
2751
2752         $gitweb_project_owner = {};
2753         # read from file (url-encoded):
2754         # 'git%2Fgit.git Linus+Torvalds'
2755         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2756         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2757         if (-f $projects_list) {
2758                 open(my $fd, '<', $projects_list);
2759                 while (my $line = <$fd>) {
2760                         chomp $line;
2761                         my ($pr, $ow) = split ' ', $line;
2762                         $pr = unescape($pr);
2763                         $ow = unescape($ow);
2764                         $gitweb_project_owner->{$pr} = to_utf8($ow);
2765                 }
2766                 close $fd;
2767         }
2768 }
2769
2770 sub git_get_project_owner {
2771         my $project = shift;
2772         my $owner;
2773
2774         return undef unless $project;
2775         $git_dir = "$projectroot/$project";
2776
2777         if (!defined $gitweb_project_owner) {
2778                 git_get_project_list_from_file();
2779         }
2780
2781         if (exists $gitweb_project_owner->{$project}) {
2782                 $owner = $gitweb_project_owner->{$project};
2783         }
2784         if (!defined $owner){
2785                 $owner = git_get_project_config('owner');
2786         }
2787         if (!defined $owner) {
2788                 $owner = get_file_owner("$git_dir");
2789         }
2790
2791         return $owner;
2792 }
2793
2794 sub git_get_last_activity {
2795         my ($path) = @_;
2796         my $fd;
2797
2798         $git_dir = "$projectroot/$path";
2799         open($fd, "-|", git_cmd(), 'for-each-ref',
2800              '--format=%(committer)',
2801              '--sort=-committerdate',
2802              '--count=1',
2803              'refs/heads') or return;
2804         my $most_recent = <$fd>;
2805         close $fd or return;
2806         if (defined $most_recent &&
2807             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
2808                 my $timestamp = $1;
2809                 my $age = time - $timestamp;
2810                 return ($age, age_string($age));
2811         }
2812         return (undef, undef);
2813 }
2814
2815 # Implementation note: when a single remote is wanted, we cannot use 'git
2816 # remote show -n' because that command always work (assuming it's a remote URL
2817 # if it's not defined), and we cannot use 'git remote show' because that would
2818 # try to make a network roundtrip. So the only way to find if that particular
2819 # remote is defined is to walk the list provided by 'git remote -v' and stop if
2820 # and when we find what we want.
2821 sub git_get_remotes_list {
2822         my $wanted = shift;
2823         my %remotes = ();
2824
2825         open my $fd, '-|' , git_cmd(), 'remote', '-v';
2826         return unless $fd;
2827         while (my $remote = <$fd>) {
2828                 chomp $remote;
2829                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
2830                 next if $wanted and not $remote eq $wanted;
2831                 my ($url, $key) = ($1, $2);
2832
2833                 $remotes{$remote} ||= { 'heads' => () };
2834                 $remotes{$remote}{$key} = $url;
2835         }
2836         close $fd or return;
2837         return wantarray ? %remotes : \%remotes;
2838 }
2839
2840 # Takes a hash of remotes as first parameter and fills it by adding the
2841 # available remote heads for each of the indicated remotes.
2842 sub fill_remote_heads {
2843         my $remotes = shift;
2844         my @heads = map { "remotes/$_" } keys %$remotes;
2845         my @remoteheads = git_get_heads_list(undef, @heads);
2846         foreach my $remote (keys %$remotes) {
2847                 $remotes->{$remote}{'heads'} = [ grep {
2848                         $_->{'name'} =~ s!^$remote/!!
2849                         } @remoteheads ];
2850         }
2851 }
2852
2853 sub git_get_references {
2854         my $type = shift || "";
2855         my %refs;
2856         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
2857         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
2858         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
2859                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
2860                 or return;
2861
2862         while (my $line = <$fd>) {
2863                 chomp $line;
2864                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
2865                         if (defined $refs{$1}) {
2866                                 push @{$refs{$1}}, $2;
2867                         } else {
2868                                 $refs{$1} = [ $2 ];
2869                         }
2870                 }
2871         }
2872         close $fd or return;
2873         return \%refs;
2874 }
2875
2876 sub git_get_rev_name_tags {
2877         my $hash = shift || return undef;
2878
2879         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
2880                 or return;
2881         my $name_rev = <$fd>;
2882         close $fd;
2883
2884         if ($name_rev =~ m|^$hash tags/(.*)$|) {
2885                 return $1;
2886         } else {
2887                 # catches also '$hash undefined' output
2888                 return undef;
2889         }
2890 }
2891
2892 ## ----------------------------------------------------------------------
2893 ## parse to hash functions
2894
2895 sub parse_date {
2896         my $epoch = shift;
2897         my $tz = shift || "-0000";
2898
2899         my %date;
2900         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
2901         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
2902         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
2903         $date{'hour'} = $hour;
2904         $date{'minute'} = $min;
2905         $date{'mday'} = $mday;
2906         $date{'day'} = $days[$wday];
2907         $date{'month'} = $months[$mon];
2908         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
2909                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
2910         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
2911                              $mday, $months[$mon], $hour ,$min;
2912         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
2913                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
2914
2915         $tz =~ m/^([+\-][0-9][0-9])([0-9][0-9])$/;
2916         my $local = $epoch + ((int $1 + ($2/60)) * 3600);
2917         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
2918         $date{'hour_local'} = $hour;
2919         $date{'minute_local'} = $min;
2920         $date{'tz_local'} = $tz;
2921         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
2922                                   1900+$year, $mon+1, $mday,
2923                                   $hour, $min, $sec, $tz);
2924         return %date;
2925 }
2926
2927 sub parse_tag {
2928         my $tag_id = shift;
2929         my %tag;
2930         my @comment;
2931
2932         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
2933         $tag{'id'} = $tag_id;
2934         while (my $line = <$fd>) {
2935                 chomp $line;
2936                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
2937                         $tag{'object'} = $1;
2938                 } elsif ($line =~ m/^type (.+)$/) {
2939                         $tag{'type'} = $1;
2940                 } elsif ($line =~ m/^tag (.+)$/) {
2941                         $tag{'name'} = $1;
2942                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
2943                         $tag{'author'} = $1;
2944                         $tag{'author_epoch'} = $2;
2945                         $tag{'author_tz'} = $3;
2946                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
2947                                 $tag{'author_name'}  = $1;
2948                                 $tag{'author_email'} = $2;
2949                         } else {
2950                                 $tag{'author_name'} = $tag{'author'};
2951                         }
2952                 } elsif ($line =~ m/--BEGIN/) {
2953                         push @comment, $line;
2954                         last;
2955                 } elsif ($line eq "") {
2956                         last;
2957                 }
2958         }
2959         push @comment, <$fd>;
2960         $tag{'comment'} = \@comment;
2961         close $fd or return;
2962         if (!defined $tag{'name'}) {
2963                 return
2964         };
2965         return %tag
2966 }
2967
2968 sub parse_commit_text {
2969         my ($commit_text, $withparents) = @_;
2970         my @commit_lines = split '\n', $commit_text;
2971         my %co;
2972
2973         pop @commit_lines; # Remove '\0'
2974
2975         if (! @commit_lines) {
2976                 return;
2977         }
2978
2979         my $header = shift @commit_lines;
2980         if ($header !~ m/^[0-9a-fA-F]{40}/) {
2981                 return;
2982         }
2983         ($co{'id'}, my @parents) = split ' ', $header;
2984         while (my $line = shift @commit_lines) {
2985                 last if $line eq "\n";
2986                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
2987                         $co{'tree'} = $1;
2988                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
2989                         push @parents, $1;
2990                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
2991                         $co{'author'} = to_utf8($1);
2992                         $co{'author_epoch'} = $2;
2993                         $co{'author_tz'} = $3;
2994                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
2995                                 $co{'author_name'}  = $1;
2996                                 $co{'author_email'} = $2;
2997                         } else {
2998                                 $co{'author_name'} = $co{'author'};
2999                         }
3000                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3001                         $co{'committer'} = to_utf8($1);
3002                         $co{'committer_epoch'} = $2;
3003                         $co{'committer_tz'} = $3;
3004                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3005                                 $co{'committer_name'}  = $1;
3006                                 $co{'committer_email'} = $2;
3007                         } else {
3008                                 $co{'committer_name'} = $co{'committer'};
3009                         }
3010                 }
3011         }
3012         if (!defined $co{'tree'}) {
3013                 return;
3014         };
3015         $co{'parents'} = \@parents;
3016         $co{'parent'} = $parents[0];
3017
3018         foreach my $title (@commit_lines) {
3019                 $title =~ s/^    //;
3020                 if ($title ne "") {
3021                         $co{'title'} = chop_str($title, 80, 5);
3022                         # remove leading stuff of merges to make the interesting part visible
3023                         if (length($title) > 50) {
3024                                 $title =~ s/^Automatic //;
3025                                 $title =~ s/^merge (of|with) /Merge ... /i;
3026                                 if (length($title) > 50) {
3027                                         $title =~ s/(http|rsync):\/\///;
3028                                 }
3029                                 if (length($title) > 50) {
3030                                         $title =~ s/(master|www|rsync)\.//;
3031                                 }
3032                                 if (length($title) > 50) {
3033                                         $title =~ s/kernel.org:?//;
3034                                 }
3035                                 if (length($title) > 50) {
3036                                         $title =~ s/\/pub\/scm//;
3037                                 }
3038                         }
3039                         $co{'title_short'} = chop_str($title, 50, 5);
3040                         last;
3041                 }
3042         }
3043         if (! defined $co{'title'} || $co{'title'} eq "") {
3044                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3045         }
3046         # remove added spaces
3047         foreach my $line (@commit_lines) {
3048                 $line =~ s/^    //;
3049         }
3050         $co{'comment'} = \@commit_lines;
3051
3052         my $age = time - $co{'committer_epoch'};
3053         $co{'age'} = $age;
3054         $co{'age_string'} = age_string($age);
3055         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3056         if ($age > 60*60*24*7*2) {
3057                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3058                 $co{'age_string_age'} = $co{'age_string'};
3059         } else {
3060                 $co{'age_string_date'} = $co{'age_string'};
3061                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3062         }
3063         return %co;
3064 }
3065
3066 sub parse_commit {
3067         my ($commit_id) = @_;
3068         my %co;
3069
3070         local $/ = "\0";
3071
3072         open my $fd, "-|", git_cmd(), "rev-list",
3073                 "--parents",
3074                 "--header",
3075                 "--max-count=1",
3076                 $commit_id,
3077                 "--",
3078                 or die_error(500, "Open git-rev-list failed");
3079         %co = parse_commit_text(<$fd>, 1);
3080         close $fd;
3081
3082         return %co;
3083 }
3084
3085 sub parse_commits {
3086         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3087         my @cos;
3088
3089         $maxcount ||= 1;
3090         $skip ||= 0;
3091
3092         local $/ = "\0";
3093
3094         open my $fd, "-|", git_cmd(), "rev-list",
3095                 "--header",
3096                 @args,
3097                 ("--max-count=" . $maxcount),
3098                 ("--skip=" . $skip),
3099                 @extra_options,
3100                 $commit_id,
3101                 "--",
3102                 ($filename ? ($filename) : ())
3103                 or die_error(500, "Open git-rev-list failed");
3104         while (my $line = <$fd>) {
3105                 my %co = parse_commit_text($line);
3106                 push @cos, \%co;
3107         }
3108         close $fd;
3109
3110         return wantarray ? @cos : \@cos;
3111 }
3112
3113 # parse line of git-diff-tree "raw" output
3114 sub parse_difftree_raw_line {
3115         my $line = shift;
3116         my %res;
3117
3118         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3119         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3120         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3121                 $res{'from_mode'} = $1;
3122                 $res{'to_mode'} = $2;
3123                 $res{'from_id'} = $3;
3124                 $res{'to_id'} = $4;
3125                 $res{'status'} = $5;
3126                 $res{'similarity'} = $6;
3127                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3128                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3129                 } else {
3130                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3131                 }
3132         }
3133         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3134         # combined diff (for merge commit)
3135         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3136                 $res{'nparents'}  = length($1);
3137                 $res{'from_mode'} = [ split(' ', $2) ];
3138                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3139                 $res{'from_id'} = [ split(' ', $3) ];
3140                 $res{'to_id'} = pop @{$res{'from_id'}};
3141                 $res{'status'} = [ split('', $4) ];
3142                 $res{'to_file'} = unquote($5);
3143         }
3144         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3145         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3146                 $res{'commit'} = $1;
3147         }
3148
3149         return wantarray ? %res : \%res;
3150 }
3151
3152 # wrapper: return parsed line of git-diff-tree "raw" output
3153 # (the argument might be raw line, or parsed info)
3154 sub parsed_difftree_line {
3155         my $line_or_ref = shift;
3156
3157         if (ref($line_or_ref) eq "HASH") {
3158                 # pre-parsed (or generated by hand)
3159                 return $line_or_ref;
3160         } else {
3161                 return parse_difftree_raw_line($line_or_ref);
3162         }
3163 }
3164
3165 # parse line of git-ls-tree output
3166 sub parse_ls_tree_line {
3167         my $line = shift;
3168         my %opts = @_;
3169         my %res;
3170
3171         if ($opts{'-l'}) {
3172                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3173                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3174
3175                 $res{'mode'} = $1;
3176                 $res{'type'} = $2;
3177                 $res{'hash'} = $3;
3178                 $res{'size'} = $4;
3179                 if ($opts{'-z'}) {
3180                         $res{'name'} = $5;
3181                 } else {
3182                         $res{'name'} = unquote($5);
3183                 }
3184         } else {
3185                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3186                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3187
3188                 $res{'mode'} = $1;
3189                 $res{'type'} = $2;
3190                 $res{'hash'} = $3;
3191                 if ($opts{'-z'}) {
3192                         $res{'name'} = $4;
3193                 } else {
3194                         $res{'name'} = unquote($4);
3195                 }
3196         }
3197
3198         return wantarray ? %res : \%res;
3199 }
3200
3201 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3202 sub parse_from_to_diffinfo {
3203         my ($diffinfo, $from, $to, @parents) = @_;
3204
3205         if ($diffinfo->{'nparents'}) {
3206                 # combined diff
3207                 $from->{'file'} = [];
3208                 $from->{'href'} = [];
3209                 fill_from_file_info($diffinfo, @parents)
3210                         unless exists $diffinfo->{'from_file'};
3211                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3212                         $from->{'file'}[$i] =
3213                                 defined $diffinfo->{'from_file'}[$i] ?
3214                                         $diffinfo->{'from_file'}[$i] :
3215                                         $diffinfo->{'to_file'};
3216                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3217                                 $from->{'href'}[$i] = href(action=>"blob",
3218                                                            hash_base=>$parents[$i],
3219                                                            hash=>$diffinfo->{'from_id'}[$i],
3220                                                            file_name=>$from->{'file'}[$i]);
3221                         } else {
3222                                 $from->{'href'}[$i] = undef;
3223                         }
3224                 }
3225         } else {
3226                 # ordinary (not combined) diff
3227                 $from->{'file'} = $diffinfo->{'from_file'};
3228                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3229                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3230                                                hash=>$diffinfo->{'from_id'},
3231                                                file_name=>$from->{'file'});
3232                 } else {
3233                         delete $from->{'href'};
3234                 }
3235         }
3236
3237         $to->{'file'} = $diffinfo->{'to_file'};
3238         if (!is_deleted($diffinfo)) { # file exists in result
3239                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3240                                      hash=>$diffinfo->{'to_id'},
3241                                      file_name=>$to->{'file'});
3242         } else {
3243                 delete $to->{'href'};
3244         }
3245 }
3246
3247 ## ......................................................................
3248 ## parse to array of hashes functions
3249
3250 sub git_get_heads_list {
3251         my ($limit, @classes) = @_;
3252         @classes = ('heads') unless @classes;
3253         my @patterns = map { "refs/$_" } @classes;
3254         my @headslist;
3255
3256         open my $fd, '-|', git_cmd(), 'for-each-ref',
3257                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3258                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3259                 @patterns
3260                 or return;
3261         while (my $line = <$fd>) {
3262                 my %ref_item;
3263
3264                 chomp $line;
3265                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3266                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3267                 my ($committer, $epoch, $tz) =
3268                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3269                 $ref_item{'fullname'}  = $name;
3270                 $name =~ s!^refs/(?:head|remote)s/!!;
3271
3272                 $ref_item{'name'}  = $name;
3273                 $ref_item{'id'}    = $hash;
3274                 $ref_item{'title'} = $title || '(no commit message)';
3275                 $ref_item{'epoch'} = $epoch;
3276                 if ($epoch) {
3277                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3278                 } else {
3279                         $ref_item{'age'} = "unknown";
3280                 }
3281
3282                 push @headslist, \%ref_item;
3283         }
3284         close $fd;
3285
3286         return wantarray ? @headslist : \@headslist;
3287 }
3288
3289 sub git_get_tags_list {
3290         my $limit = shift;
3291         my @tagslist;
3292
3293         open my $fd, '-|', git_cmd(), 'for-each-ref',
3294                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3295                 '--format=%(objectname) %(objecttype) %(refname) '.
3296                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3297                 'refs/tags'
3298                 or return;
3299         while (my $line = <$fd>) {
3300                 my %ref_item;
3301
3302                 chomp $line;
3303                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3304                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3305                 my ($creator, $epoch, $tz) =
3306                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3307                 $ref_item{'fullname'} = $name;
3308                 $name =~ s!^refs/tags/!!;
3309
3310                 $ref_item{'type'} = $type;
3311                 $ref_item{'id'} = $id;
3312                 $ref_item{'name'} = $name;
3313                 if ($type eq "tag") {
3314                         $ref_item{'subject'} = $title;
3315                         $ref_item{'reftype'} = $reftype;
3316                         $ref_item{'refid'}   = $refid;
3317                 } else {
3318                         $ref_item{'reftype'} = $type;
3319                         $ref_item{'refid'}   = $id;
3320                 }
3321
3322                 if ($type eq "tag" || $type eq "commit") {
3323                         $ref_item{'epoch'} = $epoch;
3324                         if ($epoch) {
3325                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3326                         } else {
3327                                 $ref_item{'age'} = "unknown";
3328                         }
3329                 }
3330
3331                 push @tagslist, \%ref_item;
3332         }
3333         close $fd;
3334
3335         return wantarray ? @tagslist : \@tagslist;
3336 }
3337
3338 ## ----------------------------------------------------------------------
3339 ## filesystem-related functions
3340
3341 sub get_file_owner {
3342         my $path = shift;
3343
3344         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3345         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3346         if (!defined $gcos) {
3347                 return undef;
3348         }
3349         my $owner = $gcos;
3350         $owner =~ s/[,;].*$//;
3351         return to_utf8($owner);
3352 }
3353
3354 # assume that file exists
3355 sub insert_file {
3356         my $filename = shift;
3357
3358         open my $fd, '<', $filename;
3359         print map { to_utf8($_) } <$fd>;
3360         close $fd;
3361 }
3362
3363 ## ......................................................................
3364 ## mimetype related functions
3365
3366 sub mimetype_guess_file {
3367         my $filename = shift;
3368         my $mimemap = shift;
3369         -r $mimemap or return undef;
3370
3371         my %mimemap;
3372         open(my $mh, '<', $mimemap) or return undef;
3373         while (<$mh>) {
3374                 next if m/^#/; # skip comments
3375                 my ($mimetype, $exts) = split(/\t+/);
3376                 if (defined $exts) {
3377                         my @exts = split(/\s+/, $exts);
3378                         foreach my $ext (@exts) {
3379                                 $mimemap{$ext} = $mimetype;
3380                         }
3381                 }
3382         }
3383         close($mh);
3384
3385         $filename =~ /\.([^.]*)$/;
3386         return $mimemap{$1};
3387 }
3388
3389 sub mimetype_guess {
3390         my $filename = shift;
3391         my $mime;
3392         $filename =~ /\./ or return undef;
3393
3394         if ($mimetypes_file) {
3395                 my $file = $mimetypes_file;
3396                 if ($file !~ m!^/!) { # if it is relative path
3397                         # it is relative to project
3398                         $file = "$projectroot/$project/$file";
3399                 }
3400                 $mime = mimetype_guess_file($filename, $file);
3401         }
3402         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3403         return $mime;
3404 }
3405
3406 sub blob_mimetype {
3407         my $fd = shift;
3408         my $filename = shift;
3409
3410         if ($filename) {
3411                 my $mime = mimetype_guess($filename);
3412                 $mime and return $mime;
3413         }
3414
3415         # just in case
3416         return $default_blob_plain_mimetype unless $fd;
3417
3418         if (-T $fd) {
3419                 return 'text/plain';
3420         } elsif (! $filename) {
3421                 return 'application/octet-stream';
3422         } elsif ($filename =~ m/\.png$/i) {
3423                 return 'image/png';
3424         } elsif ($filename =~ m/\.gif$/i) {
3425                 return 'image/gif';
3426         } elsif ($filename =~ m/\.jpe?g$/i) {
3427                 return 'image/jpeg';
3428         } else {
3429                 return 'application/octet-stream';
3430         }
3431 }
3432
3433 sub blob_contenttype {
3434         my ($fd, $file_name, $type) = @_;
3435
3436         $type ||= blob_mimetype($fd, $file_name);
3437         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3438                 $type .= "; charset=$default_text_plain_charset";
3439         }
3440
3441         return $type;
3442 }
3443
3444 # guess file syntax for syntax highlighting; return undef if no highlighting
3445 # the name of syntax can (in the future) depend on syntax highlighter used
3446 sub guess_file_syntax {
3447         my ($highlight, $mimetype, $file_name) = @_;
3448         return undef unless ($highlight && defined $file_name);
3449         my $basename = basename($file_name, '.in');
3450         return $highlight_basename{$basename}
3451                 if exists $highlight_basename{$basename};
3452
3453         $basename =~ /\.([^.]*)$/;
3454         my $ext = $1 or return undef;
3455         return $highlight_ext{$ext}
3456                 if exists $highlight_ext{$ext};
3457
3458         return undef;
3459 }
3460
3461 # run highlighter and return FD of its output,
3462 # or return original FD if no highlighting
3463 sub run_highlighter {
3464         my ($fd, $highlight, $syntax) = @_;
3465         return $fd unless ($highlight && defined $syntax);
3466
3467         close $fd
3468                 or die_error(404, "Reading blob failed");
3469         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3470                   quote_command($highlight_bin).
3471                   " --xhtml --fragment --syntax $syntax |"
3472                 or die_error(500, "Couldn't open file or run syntax highlighter");
3473         return $fd;
3474 }
3475
3476 ## ======================================================================
3477 ## functions printing HTML: header, footer, error page
3478
3479 sub get_page_title {
3480         my $title = to_utf8($site_name);
3481
3482         return $title unless (defined $project);
3483         $title .= " - " . to_utf8($project);
3484
3485         return $title unless (defined $action);
3486         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3487
3488         return $title unless (defined $file_name);
3489         $title .= " - " . esc_path($file_name);
3490         if ($action eq "tree" && $file_name !~ m|/$|) {
3491                 $title .= "/";
3492         }
3493
3494         return $title;
3495 }
3496
3497 sub print_feed_meta {
3498         if (defined $project) {
3499                 my %href_params = get_feed_info();
3500                 if (!exists $href_params{'-title'}) {
3501                         $href_params{'-title'} = 'log';
3502                 }
3503
3504                 foreach my $format qw(RSS Atom) {
3505                         my $type = lc($format);
3506                         my %link_attr = (
3507                                 '-rel' => 'alternate',
3508                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
3509                                 '-type' => "application/$type+xml"
3510                         );
3511
3512                         $href_params{'action'} = $type;
3513                         $link_attr{'-href'} = href(%href_params);
3514                         print "<link ".
3515                               "rel=\"$link_attr{'-rel'}\" ".
3516                               "title=\"$link_attr{'-title'}\" ".
3517                               "href=\"$link_attr{'-href'}\" ".
3518                               "type=\"$link_attr{'-type'}\" ".
3519                               "/>\n";
3520
3521                         $href_params{'extra_options'} = '--no-merges';
3522                         $link_attr{'-href'} = href(%href_params);
3523                         $link_attr{'-title'} .= ' (no merges)';
3524                         print "<link ".
3525                               "rel=\"$link_attr{'-rel'}\" ".
3526                               "title=\"$link_attr{'-title'}\" ".
3527                               "href=\"$link_attr{'-href'}\" ".
3528                               "type=\"$link_attr{'-type'}\" ".
3529                               "/>\n";
3530                 }
3531
3532         } else {
3533                 printf('<link rel="alternate" title="%s projects list" '.
3534                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
3535                        esc_attr($site_name), href(project=>undef, action=>"project_index"));
3536                 printf('<link rel="alternate" title="%s projects feeds" '.
3537                        'href="%s" type="text/x-opml" />'."\n",
3538                        esc_attr($site_name), href(project=>undef, action=>"opml"));
3539         }
3540 }
3541
3542 sub git_header_html {
3543         my $status = shift || "200 OK";
3544         my $expires = shift;
3545         my %opts = @_;
3546
3547         my $title = get_page_title();
3548         my $content_type;
3549         # require explicit support from the UA if we are to send the page as
3550         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3551         # we have to do this because MSIE sometimes globs '*/*', pretending to
3552         # support xhtml+xml but choking when it gets what it asked for.
3553         if (defined $cgi->http('HTTP_ACCEPT') &&
3554             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3555             $cgi->Accept('application/xhtml+xml') != 0) {
3556                 $content_type = 'application/xhtml+xml';
3557         } else {
3558                 $content_type = 'text/html';
3559         }
3560         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
3561                            -status=> $status, -expires => $expires)
3562                 unless ($opts{'-no_http_header'});
3563         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
3564         print <<EOF;
3565 <?xml version="1.0" encoding="utf-8"?>
3566 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
3567 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
3568 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
3569 <!-- git core binaries version $git_version -->
3570 <head>
3571 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
3572 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
3573 <meta name="robots" content="index, nofollow"/>
3574 <title>$title</title>
3575 EOF
3576         # the stylesheet, favicon etc urls won't work correctly with path_info
3577         # unless we set the appropriate base URL
3578         if ($ENV{'PATH_INFO'}) {
3579                 print "<base href=\"".esc_url($base_url)."\" />\n";
3580         }
3581         # print out each stylesheet that exist, providing backwards capability
3582         # for those people who defined $stylesheet in a config file
3583         if (defined $stylesheet) {
3584                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3585         } else {
3586                 foreach my $stylesheet (@stylesheets) {
3587                         next unless $stylesheet;
3588                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3589                 }
3590         }
3591         print_feed_meta()
3592                 if ($status eq '200 OK');
3593         if (defined $favicon) {
3594                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
3595         }
3596
3597         print "</head>\n" .
3598               "<body>\n";
3599
3600         if (defined $site_header && -f $site_header) {
3601                 insert_file($site_header);
3602         }
3603
3604         print "<div class=\"page_header\">\n" .
3605               $cgi->a({-href => esc_url($logo_url),
3606                        -title => $logo_label},
3607                       qq(<img src=").esc_url($logo).qq(" width="72" height="27" alt="git" class="logo"/>));
3608         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
3609         if (defined $project) {
3610                 print $cgi->a({-href => href(action=>"summary")}, esc_html($project));
3611                 if (defined $action) {
3612                         my $action_print = $action ;
3613                         if (defined $opts{-action_extra}) {
3614                                 $action_print = $cgi->a({-href => href(action=>$action)},
3615                                         $action);
3616                         }
3617                         print " / $action_print";
3618                 }
3619                 if (defined $opts{-action_extra}) {
3620                         print " / $opts{-action_extra}";
3621                 }
3622                 print "\n";
3623         }
3624         print "</div>\n";
3625
3626         my $have_search = gitweb_check_feature('search');
3627         if (defined $project && $have_search) {
3628                 if (!defined $searchtext) {
3629                         $searchtext = "";
3630                 }
3631                 my $search_hash;
3632                 if (defined $hash_base) {
3633                         $search_hash = $hash_base;
3634                 } elsif (defined $hash) {
3635                         $search_hash = $hash;
3636                 } else {
3637                         $search_hash = "HEAD";
3638                 }
3639                 my $action = $my_uri;
3640                 my $use_pathinfo = gitweb_check_feature('pathinfo');
3641                 if ($use_pathinfo) {
3642                         $action .= "/".esc_url($project);
3643                 }
3644                 print $cgi->startform(-method => "get", -action => $action) .
3645                       "<div class=\"search\">\n" .
3646                       (!$use_pathinfo &&
3647                       $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
3648                       $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
3649                       $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
3650                       $cgi->popup_menu(-name => 'st', -default => 'commit',
3651                                        -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
3652                       $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
3653                       " search:\n",
3654                       $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
3655                       "<span title=\"Extended regular expression\">" .
3656                       $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
3657                                      -checked => $search_use_regexp) .
3658                       "</span>" .
3659                       "</div>" .
3660                       $cgi->end_form() . "\n";
3661         }
3662 }
3663
3664 sub git_footer_html {
3665         my $feed_class = 'rss_logo';
3666
3667         print "<div class=\"page_footer\">\n";
3668         if (defined $project) {
3669                 my $descr = git_get_project_description($project);
3670                 if (defined $descr) {
3671                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
3672                 }
3673
3674                 my %href_params = get_feed_info();
3675                 if (!%href_params) {
3676                         $feed_class .= ' generic';
3677                 }
3678                 $href_params{'-title'} ||= 'log';
3679
3680                 foreach my $format qw(RSS Atom) {
3681                         $href_params{'action'} = lc($format);
3682                         print $cgi->a({-href => href(%href_params),
3683                                       -title => "$href_params{'-title'} $format feed",
3684                                       -class => $feed_class}, $format)."\n";
3685                 }
3686
3687         } else {
3688                 print $cgi->a({-href => href(project=>undef, action=>"opml"),
3689                               -class => $feed_class}, "OPML") . " ";
3690                 print $cgi->a({-href => href(project=>undef, action=>"project_index"),
3691                               -class => $feed_class}, "TXT") . "\n";
3692         }
3693         print "</div>\n"; # class="page_footer"
3694
3695         if (defined $t0 && gitweb_check_feature('timed')) {
3696                 print "<div id=\"generating_info\">\n";
3697                 print 'This page took '.
3698                       '<span id="generating_time" class="time_span">'.
3699                       tv_interval($t0, [ gettimeofday() ]).
3700                       ' seconds </span>'.
3701                       ' and '.
3702                       '<span id="generating_cmd">'.
3703                       $number_of_git_cmds.
3704                       '</span> git commands '.
3705                       " to generate.\n";
3706                 print "</div>\n"; # class="page_footer"
3707         }
3708
3709         if (defined $site_footer && -f $site_footer) {
3710                 insert_file($site_footer);
3711         }
3712
3713         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
3714         if (defined $action &&
3715             $action eq 'blame_incremental') {
3716                 print qq!<script type="text/javascript">\n!.
3717                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
3718                       qq!           "!. href() .qq!");\n!.
3719                       qq!</script>\n!;
3720         } elsif (gitweb_check_feature('javascript-actions')) {
3721                 print qq!<script type="text/javascript">\n!.
3722                       qq!window.onload = fixLinks;\n!.
3723                       qq!</script>\n!;
3724         }
3725
3726         print "</body>\n" .
3727               "</html>";
3728 }
3729
3730 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
3731 # Example: die_error(404, 'Hash not found')
3732 # By convention, use the following status codes (as defined in RFC 2616):
3733 # 400: Invalid or missing CGI parameters, or
3734 #      requested object exists but has wrong type.
3735 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
3736 #      this server or project.
3737 # 404: Requested object/revision/project doesn't exist.
3738 # 500: The server isn't configured properly, or
3739 #      an internal error occurred (e.g. failed assertions caused by bugs), or
3740 #      an unknown error occurred (e.g. the git binary died unexpectedly).
3741 # 503: The server is currently unavailable (because it is overloaded,
3742 #      or down for maintenance).  Generally, this is a temporary state.
3743 sub die_error {
3744         my $status = shift || 500;
3745         my $error = esc_html(shift) || "Internal Server Error";
3746         my $extra = shift;
3747         my %opts = @_;
3748
3749         my %http_responses = (
3750                 400 => '400 Bad Request',
3751                 403 => '403 Forbidden',
3752                 404 => '404 Not Found',
3753                 500 => '500 Internal Server Error',
3754                 503 => '503 Service Unavailable',
3755         );
3756         git_header_html($http_responses{$status}, undef, %opts);
3757         print <<EOF;
3758 <div class="page_body">
3759 <br /><br />
3760 $status - $error
3761 <br />
3762 EOF
3763         if (defined $extra) {
3764                 print "<hr />\n" .
3765                       "$extra\n";
3766         }
3767         print "</div>\n";
3768
3769         git_footer_html();
3770         goto DONE_GITWEB
3771                 unless ($opts{'-error_handler'});
3772 }
3773
3774 ## ----------------------------------------------------------------------
3775 ## functions printing or outputting HTML: navigation
3776
3777 sub git_print_page_nav {
3778         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
3779         $extra = '' if !defined $extra; # pager or formats
3780
3781         my @navs = qw(summary shortlog log commit commitdiff tree);
3782         if ($suppress) {
3783                 @navs = grep { $_ ne $suppress } @navs;
3784         }
3785
3786         my %arg = map { $_ => {action=>$_} } @navs;
3787         if (defined $head) {
3788                 for (qw(commit commitdiff)) {
3789                         $arg{$_}{'hash'} = $head;
3790                 }
3791                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
3792                         for (qw(shortlog log)) {
3793                                 $arg{$_}{'hash'} = $head;
3794                         }
3795                 }
3796         }
3797
3798         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
3799         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
3800
3801         my @actions = gitweb_get_feature('actions');
3802         my %repl = (
3803                 '%' => '%',
3804                 'n' => $project,         # project name
3805                 'f' => $git_dir,         # project path within filesystem
3806                 'h' => $treehead || '',  # current hash ('h' parameter)
3807                 'b' => $treebase || '',  # hash base ('hb' parameter)
3808         );
3809         while (@actions) {
3810                 my ($label, $link, $pos) = splice(@actions,0,3);
3811                 # insert
3812                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
3813                 # munch munch
3814                 $link =~ s/%([%nfhb])/$repl{$1}/g;
3815                 $arg{$label}{'_href'} = $link;
3816         }
3817
3818         print "<div class=\"page_nav\">\n" .
3819                 (join " | ",
3820                  map { $_ eq $current ?
3821                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
3822                  } @navs);
3823         print "<br/>\n$extra<br/>\n" .
3824               "</div>\n";
3825 }
3826
3827 # returns a submenu for the nagivation of the refs views (tags, heads,
3828 # remotes) with the current view disabled and the remotes view only
3829 # available if the feature is enabled
3830 sub format_ref_views {
3831         my ($current) = @_;
3832         my @ref_views = qw{tags heads};
3833         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
3834         return join " | ", map {
3835                 $_ eq $current ? $_ :
3836                 $cgi->a({-href => href(action=>$_)}, $_)
3837         } @ref_views
3838 }
3839
3840 sub format_paging_nav {
3841         my ($action, $page, $has_next_link) = @_;
3842         my $paging_nav;
3843
3844
3845         if ($page > 0) {
3846                 $paging_nav .=
3847                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
3848                         " &sdot; " .
3849                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
3850                                  -accesskey => "p", -title => "Alt-p"}, "prev");
3851         } else {
3852                 $paging_nav .= "first &sdot; prev";
3853         }
3854
3855         if ($has_next_link) {
3856                 $paging_nav .= " &sdot; " .
3857                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
3858                                  -accesskey => "n", -title => "Alt-n"}, "next");
3859         } else {
3860                 $paging_nav .= " &sdot; next";
3861         }
3862
3863         return $paging_nav;
3864 }
3865
3866 ## ......................................................................
3867 ## functions printing or outputting HTML: div
3868
3869 sub git_print_header_div {
3870         my ($action, $title, $hash, $hash_base) = @_;
3871         my %args = ();
3872
3873         $args{'action'} = $action;
3874         $args{'hash'} = $hash if $hash;
3875         $args{'hash_base'} = $hash_base if $hash_base;
3876
3877         print "<div class=\"header\">\n" .
3878               $cgi->a({-href => href(%args), -class => "title"},
3879               $title ? $title : $action) .
3880               "\n</div>\n";
3881 }
3882
3883 sub format_repo_url {
3884         my ($name, $url) = @_;
3885         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
3886 }
3887
3888 # Group output by placing it in a DIV element and adding a header.
3889 # Options for start_div() can be provided by passing a hash reference as the
3890 # first parameter to the function.
3891 # Options to git_print_header_div() can be provided by passing an array
3892 # reference. This must follow the options to start_div if they are present.
3893 # The content can be a scalar, which is output as-is, a scalar reference, which
3894 # is output after html escaping, an IO handle passed either as *handle or
3895 # *handle{IO}, or a function reference. In the latter case all following
3896 # parameters will be taken as argument to the content function call.
3897 sub git_print_section {
3898         my ($div_args, $header_args, $content);
3899         my $arg = shift;
3900         if (ref($arg) eq 'HASH') {
3901                 $div_args = $arg;
3902                 $arg = shift;
3903         }
3904         if (ref($arg) eq 'ARRAY') {
3905                 $header_args = $arg;
3906                 $arg = shift;
3907         }
3908         $content = $arg;
3909
3910         print $cgi->start_div($div_args);
3911         git_print_header_div(@$header_args);
3912
3913         if (ref($content) eq 'CODE') {
3914                 $content->(@_);
3915         } elsif (ref($content) eq 'SCALAR') {
3916                 print esc_html($$content);
3917         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
3918                 print <$content>;
3919         } elsif (!ref($content) && defined($content)) {
3920                 print $content;
3921         }
3922
3923         print $cgi->end_div;
3924 }
3925
3926 sub print_local_time {
3927         print format_local_time(@_);
3928 }
3929
3930 sub format_local_time {
3931         my $localtime = '';
3932         my %date = @_;
3933         if ($date{'hour_local'} < 6) {
3934                 $localtime .= sprintf(" (<span class=\"atnight\">%02d:%02d</span> %s)",
3935                         $date{'hour_local'}, $date{'minute_local'}, $date{'tz_local'});
3936         } else {
3937                 $localtime .= sprintf(" (%02d:%02d %s)",
3938                         $date{'hour_local'}, $date{'minute_local'}, $date{'tz_local'});
3939         }
3940
3941         return $localtime;
3942 }
3943
3944 # Outputs the author name and date in long form
3945 sub git_print_authorship {
3946         my $co = shift;
3947         my %opts = @_;
3948         my $tag = $opts{-tag} || 'div';
3949         my $author = $co->{'author_name'};
3950
3951         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
3952         print "<$tag class=\"author_date\">" .
3953               format_search_author($author, "author", esc_html($author)) .
3954               " [$ad{'rfc2822'}";
3955         print_local_time(%ad) if ($opts{-localtime});
3956         print "]" . git_get_avatar($co->{'author_email'}, -pad_before => 1)
3957                   . "</$tag>\n";
3958 }
3959
3960 # Outputs table rows containing the full author or committer information,
3961 # in the format expected for 'commit' view (& similar).
3962 # Parameters are a commit hash reference, followed by the list of people
3963 # to output information for. If the list is empty it defaults to both
3964 # author and committer.
3965 sub git_print_authorship_rows {
3966         my $co = shift;
3967         # too bad we can't use @people = @_ || ('author', 'committer')
3968         my @people = @_;
3969         @people = ('author', 'committer') unless @people;
3970         foreach my $who (@people) {
3971                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
3972                 print "<tr><td>$who</td><td>" .
3973                       format_search_author($co->{"${who}_name"}, $who,
3974                                esc_html($co->{"${who}_name"})) . " " .
3975                       format_search_author($co->{"${who}_email"}, $who,
3976                                esc_html("<" . $co->{"${who}_email"} . ">")) .
3977                       "</td><td rowspan=\"2\">" .
3978                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
3979                       "</td></tr>\n" .
3980                       "<tr>" .
3981                       "<td></td><td> $wd{'rfc2822'}";
3982                 print_local_time(%wd);
3983                 print "</td>" .
3984                       "</tr>\n";
3985         }
3986 }
3987
3988 sub git_print_page_path {
3989         my $name = shift;
3990         my $type = shift;
3991         my $hb = shift;
3992
3993
3994         print "<div class=\"page_path\">";
3995         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
3996                       -title => 'tree root'}, to_utf8("[$project]"));
3997         print " / ";
3998         if (defined $name) {
3999                 my @dirname = split '/', $name;
4000                 my $basename = pop @dirname;
4001                 my $fullname = '';
4002
4003                 foreach my $dir (@dirname) {
4004                         $fullname .= ($fullname ? '/' : '') . $dir;
4005                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4006                                                      hash_base=>$hb),
4007                                       -title => $fullname}, esc_path($dir));
4008                         print " / ";
4009                 }
4010                 if (defined $type && $type eq 'blob') {
4011                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4012                                                      hash_base=>$hb),
4013                                       -title => $name}, esc_path($basename));
4014                 } elsif (defined $type && $type eq 'tree') {
4015                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4016                                                      hash_base=>$hb),
4017                                       -title => $name}, esc_path($basename));
4018                         print " / ";
4019                 } else {
4020                         print esc_path($basename);
4021                 }
4022         }
4023         print "<br/></div>\n";
4024 }
4025
4026 sub git_print_log {
4027         my $log = shift;
4028         my %opts = @_;
4029
4030         if ($opts{'-remove_title'}) {
4031                 # remove title, i.e. first line of log
4032                 shift @$log;
4033         }
4034         # remove leading empty lines
4035         while (defined $log->[0] && $log->[0] eq "") {
4036                 shift @$log;
4037         }
4038
4039         # print log
4040         my $signoff = 0;
4041         my $empty = 0;
4042         foreach my $line (@$log) {
4043                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
4044                         $signoff = 1;
4045                         $empty = 0;
4046                         if (! $opts{'-remove_signoff'}) {
4047                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4048                                 next;
4049                         } else {
4050                                 # remove signoff lines
4051                                 next;
4052                         }
4053                 } else {
4054                         $signoff = 0;
4055                 }
4056
4057                 # print only one empty line
4058                 # do not print empty line after signoff
4059                 if ($line eq "") {
4060                         next if ($empty || $signoff);
4061                         $empty = 1;
4062                 } else {
4063                         $empty = 0;
4064                 }
4065
4066                 print format_log_line_html($line) . "<br/>\n";
4067         }
4068
4069         if ($opts{'-final_empty_line'}) {
4070                 # end with single empty line
4071                 print "<br/>\n" unless $empty;
4072         }
4073 }
4074
4075 # return link target (what link points to)
4076 sub git_get_link_target {
4077         my $hash = shift;
4078         my $link_target;
4079
4080         # read link
4081         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4082                 or return;
4083         {
4084                 local $/ = undef;
4085                 $link_target = <$fd>;
4086         }
4087         close $fd
4088                 or return;
4089
4090         return $link_target;
4091 }
4092
4093 # given link target, and the directory (basedir) the link is in,
4094 # return target of link relative to top directory (top tree);
4095 # return undef if it is not possible (including absolute links).
4096 sub normalize_link_target {
4097         my ($link_target, $basedir) = @_;
4098
4099         # absolute symlinks (beginning with '/') cannot be normalized
4100         return if (substr($link_target, 0, 1) eq '/');
4101
4102         # normalize link target to path from top (root) tree (dir)
4103         my $path;
4104         if ($basedir) {
4105                 $path = $basedir . '/' . $link_target;
4106         } else {
4107                 # we are in top (root) tree (dir)
4108                 $path = $link_target;
4109         }
4110
4111         # remove //, /./, and /../
4112         my @path_parts;
4113         foreach my $part (split('/', $path)) {
4114                 # discard '.' and ''
4115                 next if (!$part || $part eq '.');
4116                 # handle '..'
4117                 if ($part eq '..') {
4118                         if (@path_parts) {
4119                                 pop @path_parts;
4120                         } else {
4121                                 # link leads outside repository (outside top dir)
4122                                 return;
4123                         }
4124                 } else {
4125                         push @path_parts, $part;
4126                 }
4127         }
4128         $path = join('/', @path_parts);
4129
4130         return $path;
4131 }
4132
4133 # print tree entry (row of git_tree), but without encompassing <tr> element
4134 sub git_print_tree_entry {
4135         my ($t, $basedir, $hash_base, $have_blame) = @_;
4136
4137         my %base_key = ();
4138         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4139
4140         # The format of a table row is: mode list link.  Where mode is
4141         # the mode of the entry, list is the name of the entry, an href,
4142         # and link is the action links of the entry.
4143
4144         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4145         if (exists $t->{'size'}) {
4146                 print "<td class=\"size\">$t->{'size'}</td>\n";
4147         }
4148         if ($t->{'type'} eq "blob") {
4149                 print "<td class=\"list\">" .
4150                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4151                                                file_name=>"$basedir$t->{'name'}", %base_key),
4152                                 -class => "list"}, esc_path($t->{'name'}));
4153                 if (S_ISLNK(oct $t->{'mode'})) {
4154                         my $link_target = git_get_link_target($t->{'hash'});
4155                         if ($link_target) {
4156                                 my $norm_target = normalize_link_target($link_target, $basedir);
4157                                 if (defined $norm_target) {
4158                                         print " -> " .
4159                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4160                                                                      file_name=>$norm_target),
4161                                                        -title => $norm_target}, esc_path($link_target));
4162                                 } else {
4163                                         print " -> " . esc_path($link_target);
4164                                 }
4165                         }
4166                 }
4167                 print "</td>\n";
4168                 print "<td class=\"link\">";
4169                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4170                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4171                               "blob");
4172                 if ($have_blame) {
4173                         print " | " .
4174                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4175                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4176                                       "blame");
4177                 }
4178                 if (defined $hash_base) {
4179                         print " | " .
4180                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4181                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4182                                       "history");
4183                 }
4184                 print " | " .
4185                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4186                                                file_name=>"$basedir$t->{'name'}")},
4187                                 "raw");
4188                 print "</td>\n";
4189
4190         } elsif ($t->{'type'} eq "tree") {
4191                 print "<td class=\"list\">";
4192                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4193                                              file_name=>"$basedir$t->{'name'}",
4194                                              %base_key)},
4195                               esc_path($t->{'name'}));
4196                 print "</td>\n";
4197                 print "<td class=\"link\">";
4198                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4199                                              file_name=>"$basedir$t->{'name'}",
4200                                              %base_key)},
4201                               "tree");
4202                 if (defined $hash_base) {
4203                         print " | " .
4204                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4205                                                      file_name=>"$basedir$t->{'name'}")},
4206                                       "history");
4207                 }
4208                 print "</td>\n";
4209         } else {
4210                 # unknown object: we can only present history for it
4211                 # (this includes 'commit' object, i.e. submodule support)
4212                 print "<td class=\"list\">" .
4213                       esc_path($t->{'name'}) .
4214                       "</td>\n";
4215                 print "<td class=\"link\">";
4216                 if (defined $hash_base) {
4217                         print $cgi->a({-href => href(action=>"history",
4218                                                      hash_base=>$hash_base,
4219                                                      file_name=>"$basedir$t->{'name'}")},
4220                                       "history");
4221                 }
4222                 print "</td>\n";
4223         }
4224 }
4225
4226 ## ......................................................................
4227 ## functions printing large fragments of HTML
4228
4229 # get pre-image filenames for merge (combined) diff
4230 sub fill_from_file_info {
4231         my ($diff, @parents) = @_;
4232
4233         $diff->{'from_file'} = [ ];
4234         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4235         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4236                 if ($diff->{'status'}[$i] eq 'R' ||
4237                     $diff->{'status'}[$i] eq 'C') {
4238                         $diff->{'from_file'}[$i] =
4239                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4240                 }
4241         }
4242
4243         return $diff;
4244 }
4245
4246 # is current raw difftree line of file deletion
4247 sub is_deleted {
4248         my $diffinfo = shift;
4249
4250         return $diffinfo->{'to_id'} eq ('0' x 40);
4251 }
4252
4253 # does patch correspond to [previous] difftree raw line
4254 # $diffinfo  - hashref of parsed raw diff format
4255 # $patchinfo - hashref of parsed patch diff format
4256 #              (the same keys as in $diffinfo)
4257 sub is_patch_split {
4258         my ($diffinfo, $patchinfo) = @_;
4259
4260         return defined $diffinfo && defined $patchinfo
4261                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4262 }
4263
4264
4265 sub git_difftree_body {
4266         my ($difftree, $hash, @parents) = @_;
4267         my ($parent) = $parents[0];
4268         my $have_blame = gitweb_check_feature('blame');
4269         print "<div class=\"list_head\">\n";
4270         if ($#{$difftree} > 10) {
4271                 print(($#{$difftree} + 1) . " files changed:\n");
4272         }
4273         print "</div>\n";
4274
4275         print "<table class=\"" .
4276               (@parents > 1 ? "combined " : "") .
4277               "diff_tree\">\n";
4278
4279         # header only for combined diff in 'commitdiff' view
4280         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4281         if ($has_header) {
4282                 # table header
4283                 print "<thead><tr>\n" .
4284                        "<th></th><th></th>\n"; # filename, patchN link
4285                 for (my $i = 0; $i < @parents; $i++) {
4286                         my $par = $parents[$i];
4287                         print "<th>" .
4288                               $cgi->a({-href => href(action=>"commitdiff",
4289                                                      hash=>$hash, hash_parent=>$par),
4290                                        -title => 'commitdiff to parent number ' .
4291                                                   ($i+1) . ': ' . substr($par,0,7)},
4292                                       $i+1) .
4293                               "&nbsp;</th>\n";
4294                 }
4295                 print "</tr></thead>\n<tbody>\n";
4296         }
4297
4298         my $alternate = 1;
4299         my $patchno = 0;
4300         foreach my $line (@{$difftree}) {
4301                 my $diff = parsed_difftree_line($line);
4302
4303                 if ($alternate) {
4304                         print "<tr class=\"dark\">\n";
4305                 } else {
4306                         print "<tr class=\"light\">\n";
4307                 }
4308                 $alternate ^= 1;
4309
4310                 if (exists $diff->{'nparents'}) { # combined diff
4311
4312                         fill_from_file_info($diff, @parents)
4313                                 unless exists $diff->{'from_file'};
4314
4315                         if (!is_deleted($diff)) {
4316                                 # file exists in the result (child) commit
4317                                 print "<td>" .
4318                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4319                                                              file_name=>$diff->{'to_file'},
4320                                                              hash_base=>$hash),
4321                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4322                                       "</td>\n";
4323                         } else {
4324                                 print "<td>" .
4325                                       esc_path($diff->{'to_file'}) .
4326                                       "</td>\n";
4327                         }
4328
4329                         if ($action eq 'commitdiff') {
4330                                 # link to patch
4331                                 $patchno++;
4332                                 print "<td class=\"link\">" .
4333                                       $cgi->a({-href => "#patch$patchno"}, "patch") .
4334                                       " | " .
4335                                       "</td>\n";
4336                         }
4337
4338                         my $has_history = 0;
4339                         my $not_deleted = 0;
4340                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4341                                 my $hash_parent = $parents[$i];
4342                                 my $from_hash = $diff->{'from_id'}[$i];
4343                                 my $from_path = $diff->{'from_file'}[$i];
4344                                 my $status = $diff->{'status'}[$i];
4345
4346                                 $has_history ||= ($status ne 'A');
4347                                 $not_deleted ||= ($status ne 'D');
4348
4349                                 if ($status eq 'A') {
4350                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4351                                 } elsif ($status eq 'D') {
4352                                         print "<td class=\"link\">" .
4353                                               $cgi->a({-href => href(action=>"blob",
4354                                                                      hash_base=>$hash,
4355                                                                      hash=>$from_hash,
4356                                                                      file_name=>$from_path)},
4357                                                       "blob" . ($i+1)) .
4358                                               " | </td>\n";
4359                                 } else {
4360                                         if ($diff->{'to_id'} eq $from_hash) {
4361                                                 print "<td class=\"link nochange\">";
4362                                         } else {
4363                                                 print "<td class=\"link\">";
4364                                         }
4365                                         print $cgi->a({-href => href(action=>"blobdiff",
4366                                                                      hash=>$diff->{'to_id'},
4367                                                                      hash_parent=>$from_hash,
4368                                                                      hash_base=>$hash,
4369                                                                      hash_parent_base=>$hash_parent,
4370                                                                      file_name=>$diff->{'to_file'},
4371                                                                      file_parent=>$from_path)},
4372                                                       "diff" . ($i+1)) .
4373                                               " | </td>\n";
4374                                 }
4375                         }
4376
4377                         print "<td class=\"link\">";
4378                         if ($not_deleted) {
4379                                 print $cgi->a({-href => href(action=>"blob",
4380                                                              hash=>$diff->{'to_id'},
4381                                                              file_name=>$diff->{'to_file'},
4382                                                              hash_base=>$hash)},
4383                                               "blob");
4384                                 print " | " if ($has_history);
4385                         }
4386                         if ($has_history) {
4387                                 print $cgi->a({-href => href(action=>"history",
4388                                                              file_name=>$diff->{'to_file'},
4389                                                              hash_base=>$hash)},
4390                                               "history");
4391                         }
4392                         print "</td>\n";
4393
4394                         print "</tr>\n";
4395                         next; # instead of 'else' clause, to avoid extra indent
4396                 }
4397                 # else ordinary diff
4398
4399                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4400                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4401                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4402                         $to_mode_oct = oct $diff->{'to_mode'};
4403                         if (S_ISREG($to_mode_oct)) { # only for regular file
4404                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4405                         }
4406                         $to_file_type = file_type($diff->{'to_mode'});
4407                 }
4408                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4409                         $from_mode_oct = oct $diff->{'from_mode'};
4410                         if (S_ISREG($to_mode_oct)) { # only for regular file
4411                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4412                         }
4413                         $from_file_type = file_type($diff->{'from_mode'});
4414                 }
4415
4416                 if ($diff->{'status'} eq "A") { # created
4417                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4418                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4419                         $mode_chng   .= "]</span>";
4420                         print "<td>";
4421                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4422                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4423                                       -class => "list"}, esc_path($diff->{'file'}));
4424                         print "</td>\n";
4425                         print "<td>$mode_chng</td>\n";
4426                         print "<td class=\"link\">";
4427                         if ($action eq 'commitdiff') {
4428                                 # link to patch
4429                                 $patchno++;
4430                                 print $cgi->a({-href => "#patch$patchno"}, "patch");
4431                                 print " | ";
4432                         }
4433                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4434                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4435                                       "blob");
4436                         print "</td>\n";
4437
4438                 } elsif ($diff->{'status'} eq "D") { # deleted
4439                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4440                         print "<td>";
4441                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4442                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4443                                        -class => "list"}, esc_path($diff->{'file'}));
4444                         print "</td>\n";
4445                         print "<td>$mode_chng</td>\n";
4446                         print "<td class=\"link\">";
4447                         if ($action eq 'commitdiff') {
4448                                 # link to patch
4449                                 $patchno++;
4450                                 print $cgi->a({-href => "#patch$patchno"}, "patch");
4451                                 print " | ";
4452                         }
4453                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4454                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
4455                                       "blob") . " | ";
4456                         if ($have_blame) {
4457                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4458                                                              file_name=>$diff->{'file'})},
4459                                               "blame") . " | ";
4460                         }
4461                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4462                                                      file_name=>$diff->{'file'})},
4463                                       "history");
4464                         print "</td>\n";
4465
4466                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4467                         my $mode_chnge = "";
4468                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4469                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4470                                 if ($from_file_type ne $to_file_type) {
4471                                         $mode_chnge .= " from $from_file_type to $to_file_type";
4472                                 }
4473                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4474                                         if ($from_mode_str && $to_mode_str) {
4475                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4476                                         } elsif ($to_mode_str) {
4477                                                 $mode_chnge .= " mode: $to_mode_str";
4478                                         }
4479                                 }
4480                                 $mode_chnge .= "]</span>\n";
4481                         }
4482                         print "<td>";
4483                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4484                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4485                                       -class => "list"}, esc_path($diff->{'file'}));
4486                         print "</td>\n";
4487                         print "<td>$mode_chnge</td>\n";
4488                         print "<td class=\"link\">";
4489                         if ($action eq 'commitdiff') {
4490                                 # link to patch
4491                                 $patchno++;
4492                                 print $cgi->a({-href => "#patch$patchno"}, "patch") .
4493                                       " | ";
4494                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4495                                 # "commit" view and modified file (not onlu mode changed)
4496                                 print $cgi->a({-href => href(action=>"blobdiff",
4497                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4498                                                              hash_base=>$hash, hash_parent_base=>$parent,
4499                                                              file_name=>$diff->{'file'})},
4500                                               "diff") .
4501                                       " | ";
4502                         }
4503                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4504                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4505                                        "blob") . " | ";
4506                         if ($have_blame) {
4507                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4508                                                              file_name=>$diff->{'file'})},
4509                                               "blame") . " | ";
4510                         }
4511                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4512                                                      file_name=>$diff->{'file'})},
4513                                       "history");
4514                         print "</td>\n";
4515
4516                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4517                         my %status_name = ('R' => 'moved', 'C' => 'copied');
4518                         my $nstatus = $status_name{$diff->{'status'}};
4519                         my $mode_chng = "";
4520                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4521                                 # mode also for directories, so we cannot use $to_mode_str
4522                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
4523                         }
4524                         print "<td>" .
4525                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
4526                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
4527                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
4528                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
4529                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
4530                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
4531                                       -class => "list"}, esc_path($diff->{'from_file'})) .
4532                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
4533                               "<td class=\"link\">";
4534                         if ($action eq 'commitdiff') {
4535                                 # link to patch
4536                                 $patchno++;
4537                                 print $cgi->a({-href => "#patch$patchno"}, "patch") .
4538                                       " | ";
4539                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4540                                 # "commit" view and modified file (not only pure rename or copy)
4541                                 print $cgi->a({-href => href(action=>"blobdiff",
4542                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4543                                                              hash_base=>$hash, hash_parent_base=>$parent,
4544                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
4545                                               "diff") .
4546                                       " | ";
4547                         }
4548                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4549                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
4550                                       "blob") . " | ";
4551                         if ($have_blame) {
4552                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4553                                                              file_name=>$diff->{'to_file'})},
4554                                               "blame") . " | ";
4555                         }
4556                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4557                                                     file_name=>$diff->{'to_file'})},
4558                                       "history");
4559                         print "</td>\n";
4560
4561                 } # we should not encounter Unmerged (U) or Unknown (X) status
4562                 print "</tr>\n";
4563         }
4564         print "</tbody>" if $has_header;
4565         print "</table>\n";
4566 }
4567
4568 sub git_patchset_body {
4569         my ($fd, $difftree, $hash, @hash_parents) = @_;
4570         my ($hash_parent) = $hash_parents[0];
4571
4572         my $is_combined = (@hash_parents > 1);
4573         my $patch_idx = 0;
4574         my $patch_number = 0;
4575         my $patch_line;
4576         my $diffinfo;
4577         my $to_name;
4578         my (%from, %to);
4579
4580         print "<div class=\"patchset\">\n";
4581
4582         # skip to first patch
4583         while ($patch_line = <$fd>) {
4584                 chomp $patch_line;
4585
4586                 last if ($patch_line =~ m/^diff /);
4587         }
4588
4589  PATCH:
4590         while ($patch_line) {
4591
4592                 # parse "git diff" header line
4593                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
4594                         # $1 is from_name, which we do not use
4595                         $to_name = unquote($2);
4596                         $to_name =~ s!^b/!!;
4597                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
4598                         # $1 is 'cc' or 'combined', which we do not use
4599                         $to_name = unquote($2);
4600                 } else {
4601                         $to_name = undef;
4602                 }
4603
4604                 # check if current patch belong to current raw line
4605                 # and parse raw git-diff line if needed
4606                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
4607                         # this is continuation of a split patch
4608                         print "<div class=\"patch cont\">\n";
4609                 } else {
4610                         # advance raw git-diff output if needed
4611                         $patch_idx++ if defined $diffinfo;
4612
4613                         # read and prepare patch information
4614                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4615
4616                         # compact combined diff output can have some patches skipped
4617                         # find which patch (using pathname of result) we are at now;
4618                         if ($is_combined) {
4619                                 while ($to_name ne $diffinfo->{'to_file'}) {
4620                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
4621                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
4622                                               "</div>\n";  # class="patch"
4623
4624                                         $patch_idx++;
4625                                         $patch_number++;
4626
4627                                         last if $patch_idx > $#$difftree;
4628                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4629                                 }
4630                         }
4631
4632                         # modifies %from, %to hashes
4633                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
4634
4635                         # this is first patch for raw difftree line with $patch_idx index
4636                         # we index @$difftree array from 0, but number patches from 1
4637                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
4638                 }
4639
4640                 # git diff header
4641                 #assert($patch_line =~ m/^diff /) if DEBUG;
4642                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
4643                 $patch_number++;
4644                 # print "git diff" header
4645                 print format_git_diff_header_line($patch_line, $diffinfo,
4646                                                   \%from, \%to);
4647
4648                 # print extended diff header
4649                 print "<div class=\"diff extended_header\">\n";
4650         EXTENDED_HEADER:
4651                 while ($patch_line = <$fd>) {
4652                         chomp $patch_line;
4653
4654                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
4655
4656                         print format_extended_diff_header_line($patch_line, $diffinfo,
4657                                                                \%from, \%to);
4658                 }
4659                 print "</div>\n"; # class="diff extended_header"
4660
4661                 # from-file/to-file diff header
4662                 if (! $patch_line) {
4663                         print "</div>\n"; # class="patch"
4664                         last PATCH;
4665                 }
4666                 next PATCH if ($patch_line =~ m/^diff /);
4667                 #assert($patch_line =~ m/^---/) if DEBUG;
4668
4669                 my $last_patch_line = $patch_line;
4670                 $patch_line = <$fd>;
4671                 chomp $patch_line;
4672                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
4673
4674                 print format_diff_from_to_header($last_patch_line, $patch_line,
4675                                                  $diffinfo, \%from, \%to,
4676                                                  @hash_parents);
4677
4678                 # the patch itself
4679         LINE:
4680                 while ($patch_line = <$fd>) {
4681                         chomp $patch_line;
4682
4683                         next PATCH if ($patch_line =~ m/^diff /);
4684
4685                         print format_diff_line($patch_line, \%from, \%to);
4686                 }
4687
4688         } continue {
4689                 print "</div>\n"; # class="patch"
4690         }
4691
4692         # for compact combined (--cc) format, with chunk and patch simplification
4693         # the patchset might be empty, but there might be unprocessed raw lines
4694         for (++$patch_idx if $patch_number > 0;
4695              $patch_idx < @$difftree;
4696              ++$patch_idx) {
4697                 # read and prepare patch information
4698                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4699
4700                 # generate anchor for "patch" links in difftree / whatchanged part
4701                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
4702                       format_diff_cc_simplified($diffinfo, @hash_parents) .
4703                       "</div>\n";  # class="patch"
4704
4705                 $patch_number++;
4706         }
4707
4708         if ($patch_number == 0) {
4709                 if (@hash_parents > 1) {
4710                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
4711                 } else {
4712                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
4713                 }
4714         }
4715
4716         print "</div>\n"; # class="patchset"
4717 }
4718
4719 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
4720
4721 # fills project list info (age, description, owner, forks) for each
4722 # project in the list, removing invalid projects from returned list
4723 # NOTE: modifies $projlist, but does not remove entries from it
4724 sub fill_project_list_info {
4725         my ($projlist, $check_forks) = @_;
4726         my @projects;
4727
4728         my $show_ctags = gitweb_check_feature('ctags');
4729  PROJECT:
4730         foreach my $pr (@$projlist) {
4731                 my (@activity) = git_get_last_activity($pr->{'path'});
4732                 unless (@activity) {
4733                         next PROJECT;
4734                 }
4735                 ($pr->{'age'}, $pr->{'age_string'}) = @activity;
4736                 if (!defined $pr->{'descr'}) {
4737                         my $descr = git_get_project_description($pr->{'path'}) || "";
4738                         $descr = to_utf8($descr);
4739                         $pr->{'descr_long'} = $descr;
4740                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
4741                 }
4742                 if (!defined $pr->{'owner'}) {
4743                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
4744                 }
4745                 if ($check_forks) {
4746                         my $pname = $pr->{'path'};
4747                         if (($pname =~ s/\.git$//) &&
4748                             ($pname !~ /\/$/) &&
4749                             (-d "$projectroot/$pname")) {
4750                                 $pr->{'forks'} = "-d $projectroot/$pname";
4751                         } else {
4752                                 $pr->{'forks'} = 0;
4753                         }
4754                 }
4755                 $show_ctags and $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
4756                 push @projects, $pr;
4757         }
4758
4759         return @projects;
4760 }
4761
4762 # print 'sort by' <th> element, generating 'sort by $name' replay link
4763 # if that order is not selected
4764 sub print_sort_th {
4765         print format_sort_th(@_);
4766 }
4767
4768 sub format_sort_th {
4769         my ($name, $order, $header) = @_;
4770         my $sort_th = "";
4771         $header ||= ucfirst($name);
4772
4773         if ($order eq $name) {
4774                 $sort_th .= "<th>$header</th>\n";
4775         } else {
4776                 $sort_th .= "<th>" .
4777                             $cgi->a({-href => href(-replay=>1, order=>$name),
4778                                      -class => "header"}, $header) .
4779                             "</th>\n";
4780         }
4781
4782         return $sort_th;
4783 }
4784
4785 sub git_project_list_body {
4786         # actually uses global variable $project
4787         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
4788
4789         my $check_forks = gitweb_check_feature('forks');
4790         my @projects = fill_project_list_info($projlist, $check_forks);
4791
4792         $order ||= $default_projects_order;
4793         $from = 0 unless defined $from;
4794         $to = $#projects if (!defined $to || $#projects < $to);
4795
4796         my %order_info = (
4797                 project => { key => 'path', type => 'str' },
4798                 descr => { key => 'descr_long', type => 'str' },
4799                 owner => { key => 'owner', type => 'str' },
4800                 age => { key => 'age', type => 'num' }
4801         );
4802         my $oi = $order_info{$order};
4803         if ($oi->{'type'} eq 'str') {
4804                 @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @projects;
4805         } else {
4806                 @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @projects;
4807         }
4808
4809         my $show_ctags = gitweb_check_feature('ctags');
4810         if ($show_ctags) {
4811                 my %ctags;
4812                 foreach my $p (@projects) {
4813                         foreach my $ct (keys %{$p->{'ctags'}}) {
4814                                 $ctags{$ct} += $p->{'ctags'}->{$ct};
4815                         }
4816                 }
4817                 my $cloud = git_populate_project_tagcloud(\%ctags);
4818                 print git_show_project_tagcloud($cloud, 64);
4819         }
4820
4821         print "<table class=\"project_list\">\n";
4822         unless ($no_header) {
4823                 print "<tr>\n";
4824                 if ($check_forks) {
4825                         print "<th></th>\n";
4826                 }
4827                 print_sort_th('project', $order, 'Project');
4828                 print_sort_th('descr', $order, 'Description');
4829                 print_sort_th('owner', $order, 'Owner');
4830                 print_sort_th('age', $order, 'Last Change');
4831                 print "<th></th>\n" . # for links
4832                       "</tr>\n";
4833         }
4834         my $alternate = 1;
4835         my $tagfilter = $cgi->param('by_tag');
4836         for (my $i = $from; $i <= $to; $i++) {
4837                 my $pr = $projects[$i];
4838
4839                 next if $tagfilter and $show_ctags and not grep { lc $_ eq lc $tagfilter } keys %{$pr->{'ctags'}};
4840                 next if $searchtext and not $pr->{'path'} =~ /$searchtext/
4841                         and not $pr->{'descr_long'} =~ /$searchtext/;
4842                 # Weed out forks or non-matching entries of search
4843                 if ($check_forks) {
4844                         my $forkbase = $project; $forkbase ||= ''; $forkbase =~ s#\.git$#/#;
4845                         $forkbase="^$forkbase" if $forkbase;
4846                         next if not $searchtext and not $tagfilter and $show_ctags
4847                                 and $pr->{'path'} =~ m#$forkbase.*/.*#; # regexp-safe
4848                 }
4849
4850                 if ($alternate) {
4851                         print "<tr class=\"dark\">\n";
4852                 } else {
4853                         print "<tr class=\"light\">\n";
4854                 }
4855                 $alternate ^= 1;
4856                 if ($check_forks) {
4857                         print "<td>";
4858                         if ($pr->{'forks'}) {
4859                                 print "<!-- $pr->{'forks'} -->\n";
4860                                 print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "+");
4861                         }
4862                         print "</td>\n";
4863                 }
4864                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
4865                                         -class => "list"}, esc_html($pr->{'path'})) . "</td>\n" .
4866                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
4867                                         -class => "list", -title => $pr->{'descr_long'}},
4868                                         esc_html($pr->{'descr'})) . "</td>\n" .
4869                       "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
4870                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
4871                       (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n" .
4872                       "<td class=\"link\">" .
4873                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
4874                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
4875                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
4876                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
4877                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
4878                       "</td>\n" .
4879                       "</tr>\n";
4880         }
4881         if (defined $extra) {
4882                 print "<tr>\n";
4883                 if ($check_forks) {
4884                         print "<td></td>\n";
4885                 }
4886                 print "<td colspan=\"5\">$extra</td>\n" .
4887                       "</tr>\n";
4888         }
4889         print "</table>\n";
4890 }
4891
4892 sub git_log_body {
4893         # uses global variable $project
4894         my ($commitlist, $from, $to, $refs, $extra) = @_;
4895
4896         $from = 0 unless defined $from;
4897         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
4898
4899         for (my $i = 0; $i <= $to; $i++) {
4900                 my %co = %{$commitlist->[$i]};
4901                 next if !%co;
4902                 my $commit = $co{'id'};
4903                 my $ref = format_ref_marker($refs, $commit);
4904                 my %ad = parse_date($co{'author_epoch'});
4905                 git_print_header_div('commit',
4906                                "<span class=\"age\">$co{'age_string'}</span>" .
4907                                esc_html($co{'title'}) . $ref,
4908                                $commit);
4909                 print "<div class=\"title_text\">\n" .
4910                       "<div class=\"log_link\">\n" .
4911                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
4912                       " | " .
4913                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
4914                       " | " .
4915                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
4916                       "<br/>\n" .
4917                       "</div>\n";
4918                       git_print_authorship(\%co, -tag => 'span');
4919                       print "<br/>\n</div>\n";
4920
4921                 print "<div class=\"log_body\">\n";
4922                 git_print_log($co{'comment'}, -final_empty_line=> 1);
4923                 print "</div>\n";
4924         }
4925         if ($extra) {
4926                 print "<div class=\"page_nav\">\n";
4927                 print "$extra\n";
4928                 print "</div>\n";
4929         }
4930 }
4931
4932 sub git_shortlog_body {
4933         # uses global variable $project
4934         my ($commitlist, $from, $to, $refs, $extra) = @_;
4935
4936         $from = 0 unless defined $from;
4937         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
4938
4939         print "<table class=\"shortlog\">\n";
4940         my $alternate = 1;
4941         for (my $i = $from; $i <= $to; $i++) {
4942                 my %co = %{$commitlist->[$i]};
4943                 my $commit = $co{'id'};
4944                 my $ref = format_ref_marker($refs, $commit);
4945                 if ($alternate) {
4946                         print "<tr class=\"dark\">\n";
4947                 } else {
4948                         print "<tr class=\"light\">\n";
4949                 }
4950                 $alternate ^= 1;
4951                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
4952                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
4953                       format_author_html('td', \%co, 10) . "<td>";
4954                 print format_subject_html($co{'title'}, $co{'title_short'},
4955                                           href(action=>"commit", hash=>$commit), $ref);
4956                 print "</td>\n" .
4957                       "<td class=\"link\">" .
4958                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
4959                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
4960                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
4961                 my $snapshot_links = format_snapshot_links($commit);
4962                 if (defined $snapshot_links) {
4963                         print " | " . $snapshot_links;
4964                 }
4965                 print "</td>\n" .
4966                       "</tr>\n";
4967         }
4968         if (defined $extra) {
4969                 print "<tr>\n" .
4970                       "<td colspan=\"4\">$extra</td>\n" .
4971                       "</tr>\n";
4972         }
4973         print "</table>\n";
4974 }
4975
4976 sub git_history_body {
4977         # Warning: assumes constant type (blob or tree) during history
4978         my ($commitlist, $from, $to, $refs, $extra,
4979             $file_name, $file_hash, $ftype) = @_;
4980
4981         $from = 0 unless defined $from;
4982         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
4983
4984         print "<table class=\"history\">\n";
4985         my $alternate = 1;
4986         for (my $i = $from; $i <= $to; $i++) {
4987                 my %co = %{$commitlist->[$i]};
4988                 if (!%co) {
4989                         next;
4990                 }
4991                 my $commit = $co{'id'};
4992
4993                 my $ref = format_ref_marker($refs, $commit);
4994
4995                 if ($alternate) {
4996                         print "<tr class=\"dark\">\n";
4997                 } else {
4998                         print "<tr class=\"light\">\n";
4999                 }
5000                 $alternate ^= 1;
5001                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5002         # shortlog:   format_author_html('td', \%co, 10)
5003                       format_author_html('td', \%co, 15, 3) . "<td>";
5004                 # originally git_history used chop_str($co{'title'}, 50)
5005                 print format_subject_html($co{'title'}, $co{'title_short'},
5006                                           href(action=>"commit", hash=>$commit), $ref);
5007                 print "</td>\n" .
5008                       "<td class=\"link\">" .
5009                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5010                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5011
5012                 if ($ftype eq 'blob') {
5013                         my $blob_current = $file_hash;
5014                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5015                         if (defined $blob_current && defined $blob_parent &&
5016                                         $blob_current ne $blob_parent) {
5017                                 print " | " .
5018                                         $cgi->a({-href => href(action=>"blobdiff",
5019                                                                hash=>$blob_current, hash_parent=>$blob_parent,
5020                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
5021                                                                file_name=>$file_name)},
5022                                                 "diff to current");
5023                         }
5024                 }
5025                 print "</td>\n" .
5026                       "</tr>\n";
5027         }
5028         if (defined $extra) {
5029                 print "<tr>\n" .
5030                       "<td colspan=\"4\">$extra</td>\n" .
5031                       "</tr>\n";
5032         }
5033         print "</table>\n";
5034 }
5035
5036 sub git_tags_body {
5037         # uses global variable $project
5038         my ($taglist, $from, $to, $extra) = @_;
5039         $from = 0 unless defined $from;
5040         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
5041
5042         print "<table class=\"tags\">\n";
5043         my $alternate = 1;
5044         for (my $i = $from; $i <= $to; $i++) {
5045                 my $entry = $taglist->[$i];
5046                 my %tag = %$entry;
5047                 my $comment = $tag{'subject'};
5048                 my $comment_short;
5049                 if (defined $comment) {
5050                         $comment_short = chop_str($comment, 30, 5);
5051                 }
5052                 if ($alternate) {
5053                         print "<tr class=\"dark\">\n";
5054                 } else {
5055                         print "<tr class=\"light\">\n";
5056                 }
5057                 $alternate ^= 1;
5058                 if (defined $tag{'age'}) {
5059                         print "<td><i>$tag{'age'}</i></td>\n";
5060                 } else {
5061                         print "<td></td>\n";
5062                 }
5063                 print "<td>" .
5064                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
5065                                -class => "list name"}, esc_html($tag{'name'})) .
5066                       "</td>\n" .
5067                       "<td>";
5068                 if (defined $comment) {
5069                         print format_subject_html($comment, $comment_short,
5070                                                   href(action=>"tag", hash=>$tag{'id'}));
5071                 }
5072                 print "</td>\n" .
5073                       "<td class=\"selflink\">";
5074                 if ($tag{'type'} eq "tag") {
5075                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
5076                 } else {
5077                         print "&nbsp;";
5078                 }
5079                 print "</td>\n" .
5080                       "<td class=\"link\">" . " | " .
5081                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
5082                 if ($tag{'reftype'} eq "commit") {
5083                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
5084                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
5085                 } elsif ($tag{'reftype'} eq "blob") {
5086                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
5087                 }
5088                 print "</td>\n" .
5089                       "</tr>";
5090         }
5091         if (defined $extra) {
5092                 print "<tr>\n" .
5093                       "<td colspan=\"5\">$extra</td>\n" .
5094                       "</tr>\n";
5095         }
5096         print "</table>\n";
5097 }
5098
5099 sub git_heads_body {
5100         # uses global variable $project
5101         my ($headlist, $head, $from, $to, $extra) = @_;
5102         $from = 0 unless defined $from;
5103         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
5104
5105         print "<table class=\"heads\">\n";
5106         my $alternate = 1;
5107         for (my $i = $from; $i <= $to; $i++) {
5108                 my $entry = $headlist->[$i];
5109                 my %ref = %$entry;
5110                 my $curr = $ref{'id'} eq $head;
5111                 if ($alternate) {
5112                         print "<tr class=\"dark\">\n";
5113                 } else {
5114                         print "<tr class=\"light\">\n";
5115                 }
5116                 $alternate ^= 1;
5117                 print "<td><i>$ref{'age'}</i></td>\n" .
5118                       ($curr ? "<td class=\"current_head\">" : "<td>") .
5119                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
5120                                -class => "list name"},esc_html($ref{'name'})) .
5121                       "</td>\n" .
5122                       "<td class=\"link\">" .
5123                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
5124                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
5125                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
5126                       "</td>\n" .
5127                       "</tr>";
5128         }
5129         if (defined $extra) {
5130                 print "<tr>\n" .
5131                       "<td colspan=\"3\">$extra</td>\n" .
5132                       "</tr>\n";
5133         }
5134         print "</table>\n";
5135 }
5136
5137 # Display a single remote block
5138 sub git_remote_block {
5139         my ($remote, $rdata, $limit, $head) = @_;
5140
5141         my $heads = $rdata->{'heads'};
5142         my $fetch = $rdata->{'fetch'};
5143         my $push = $rdata->{'push'};
5144
5145         my $urls_table = "<table class=\"projects_list\">\n" ;
5146
5147         if (defined $fetch) {
5148                 if ($fetch eq $push) {
5149                         $urls_table .= format_repo_url("URL", $fetch);
5150                 } else {
5151                         $urls_table .= format_repo_url("Fetch URL", $fetch);
5152                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
5153                 }
5154         } elsif (defined $push) {
5155                 $urls_table .= format_repo_url("Push URL", $push);
5156         } else {
5157                 $urls_table .= format_repo_url("", "No remote URL");
5158         }
5159
5160         $urls_table .= "</table>\n";
5161
5162         my $dots;
5163         if (defined $limit && $limit < @$heads) {
5164                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
5165         }
5166
5167         print $urls_table;
5168         git_heads_body($heads, $head, 0, $limit, $dots);
5169 }
5170
5171 # Display a list of remote names with the respective fetch and push URLs
5172 sub git_remotes_list {
5173         my ($remotedata, $limit) = @_;
5174         print "<table class=\"heads\">\n";
5175         my $alternate = 1;
5176         my @remotes = sort keys %$remotedata;
5177
5178         my $limited = $limit && $limit < @remotes;
5179
5180         $#remotes = $limit - 1 if $limited;
5181
5182         while (my $remote = shift @remotes) {
5183                 my $rdata = $remotedata->{$remote};
5184                 my $fetch = $rdata->{'fetch'};
5185                 my $push = $rdata->{'push'};
5186                 if ($alternate) {
5187                         print "<tr class=\"dark\">\n";
5188                 } else {
5189                         print "<tr class=\"light\">\n";
5190                 }
5191                 $alternate ^= 1;
5192                 print "<td>" .
5193                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
5194                                -class=> "list name"},esc_html($remote)) .
5195                       "</td>";
5196                 print "<td class=\"link\">" .
5197                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
5198                       " | " .
5199                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
5200                       "</td>";
5201
5202                 print "</tr>\n";
5203         }
5204
5205         if ($limited) {
5206                 print "<tr>\n" .
5207                       "<td colspan=\"3\">" .
5208                       $cgi->a({-href => href(action=>"remotes")}, "...") .
5209                       "</td>\n" . "</tr>\n";
5210         }
5211
5212         print "</table>";
5213 }
5214
5215 # Display remote heads grouped by remote, unless there are too many
5216 # remotes, in which case we only display the remote names
5217 sub git_remotes_body {
5218         my ($remotedata, $limit, $head) = @_;
5219         if ($limit and $limit < keys %$remotedata) {
5220                 git_remotes_list($remotedata, $limit);
5221         } else {
5222                 fill_remote_heads($remotedata);
5223                 while (my ($remote, $rdata) = each %$remotedata) {
5224                         git_print_section({-class=>"remote", -id=>$remote},
5225                                 ["remotes", $remote, $remote], sub {
5226                                         git_remote_block($remote, $rdata, $limit, $head);
5227                                 });
5228                 }
5229         }
5230 }
5231
5232 sub git_search_grep_body {
5233         my ($commitlist, $from, $to, $extra) = @_;
5234         $from = 0 unless defined $from;
5235         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5236
5237         print "<table class=\"commit_search\">\n";
5238         my $alternate = 1;
5239         for (my $i = $from; $i <= $to; $i++) {
5240                 my %co = %{$commitlist->[$i]};
5241                 if (!%co) {
5242                         next;
5243                 }
5244                 my $commit = $co{'id'};
5245                 if ($alternate) {
5246                         print "<tr class=\"dark\">\n";
5247                 } else {
5248                         print "<tr class=\"light\">\n";
5249                 }
5250                 $alternate ^= 1;
5251                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5252                       format_author_html('td', \%co, 15, 5) .
5253                       "<td>" .
5254                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
5255                                -class => "list subject"},
5256                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
5257                 my $comment = $co{'comment'};
5258                 foreach my $line (@$comment) {
5259                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
5260                                 my ($lead, $match, $trail) = ($1, $2, $3);
5261                                 $match = chop_str($match, 70, 5, 'center');
5262                                 my $contextlen = int((80 - length($match))/2);
5263                                 $contextlen = 30 if ($contextlen > 30);
5264                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
5265                                 $trail = chop_str($trail, $contextlen, 10, 'right');
5266
5267                                 $lead  = esc_html($lead);
5268                                 $match = esc_html($match);
5269                                 $trail = esc_html($trail);
5270
5271                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
5272                         }
5273                 }
5274                 print "</td>\n" .
5275                       "<td class=\"link\">" .
5276                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
5277                       " | " .
5278                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
5279                       " | " .
5280                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
5281                 print "</td>\n" .
5282                       "</tr>\n";
5283         }
5284         if (defined $extra) {
5285                 print "<tr>\n" .
5286                       "<td colspan=\"3\">$extra</td>\n" .
5287                       "</tr>\n";
5288         }
5289         print "</table>\n";
5290 }
5291
5292 ## ======================================================================
5293 ## ======================================================================
5294 ## actions
5295
5296 sub git_project_list {
5297         my $order = $input_params{'order'};
5298         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5299                 die_error(400, "Unknown order parameter");
5300         }
5301
5302         my @list = git_get_projects_list();
5303         if (!@list) {
5304                 die_error(404, "No projects found");
5305         }
5306
5307         git_header_html();
5308         if (defined $home_text && -f $home_text) {
5309                 print "<div class=\"index_include\">\n";
5310                 insert_file($home_text);
5311                 print "</div>\n";
5312         }
5313         print $cgi->startform(-method => "get") .
5314               "<p class=\"projsearch\">Search:\n" .
5315               $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
5316               "</p>" .
5317               $cgi->end_form() . "\n";
5318         git_project_list_body(\@list, $order);
5319         git_footer_html();
5320 }
5321
5322 sub git_forks {
5323         my $order = $input_params{'order'};
5324         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5325                 die_error(400, "Unknown order parameter");
5326         }
5327
5328         my @list = git_get_projects_list($project);
5329         if (!@list) {
5330                 die_error(404, "No forks found");
5331         }
5332
5333         git_header_html();
5334         git_print_page_nav('','');
5335         git_print_header_div('summary', "$project forks");
5336         git_project_list_body(\@list, $order);
5337         git_footer_html();
5338 }
5339
5340 sub git_project_index {
5341         my @projects = git_get_projects_list($project);
5342
5343         print $cgi->header(
5344                 -type => 'text/plain',
5345                 -charset => 'utf-8',
5346                 -content_disposition => 'inline; filename="index.aux"');
5347
5348         foreach my $pr (@projects) {
5349                 if (!exists $pr->{'owner'}) {
5350                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
5351                 }
5352
5353                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
5354                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
5355                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
5356                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
5357                 $path  =~ s/ /\+/g;
5358                 $owner =~ s/ /\+/g;
5359
5360                 print "$path $owner\n";
5361         }
5362 }
5363
5364 sub git_summary {
5365         my $descr = git_get_project_description($project) || "none";
5366         my %co = parse_commit("HEAD");
5367         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
5368         my $head = $co{'id'};
5369         my $remote_heads = gitweb_check_feature('remote_heads');
5370
5371         my $owner = git_get_project_owner($project);
5372
5373         my $refs = git_get_references();
5374         # These get_*_list functions return one more to allow us to see if
5375         # there are more ...
5376         my @taglist  = git_get_tags_list(16);
5377         my @headlist = git_get_heads_list(16);
5378         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
5379         my @forklist;
5380         my $check_forks = gitweb_check_feature('forks');
5381
5382         if ($check_forks) {
5383                 @forklist = git_get_projects_list($project);
5384         }
5385
5386         git_header_html();
5387         git_print_page_nav('summary','', $head);
5388
5389         print "<div class=\"title\">&nbsp;</div>\n";
5390         print "<table class=\"projects_list\">\n" .
5391               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
5392               "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
5393         if (defined $cd{'rfc2822'}) {
5394                 print "<tr id=\"metadata_lchange\"><td>last change</td><td>$cd{'rfc2822'}</td></tr>\n";
5395         }
5396
5397         # use per project git URL list in $projectroot/$project/cloneurl
5398         # or make project git URL from git base URL and project name
5399         my $url_tag = "URL";
5400         my @url_list = git_get_project_url_list($project);
5401         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
5402         foreach my $git_url (@url_list) {
5403                 next unless $git_url;
5404                 print format_repo_url($url_tag, $git_url);
5405                 $url_tag = "";
5406         }
5407
5408         # Tag cloud
5409         my $show_ctags = gitweb_check_feature('ctags');
5410         if ($show_ctags) {
5411                 my $ctags = git_get_project_ctags($project);
5412                 my $cloud = git_populate_project_tagcloud($ctags);
5413                 print "<tr id=\"metadata_ctags\"><td>Content tags:<br />";
5414                 print "</td>\n<td>" unless %$ctags;
5415                 print "<form action=\"$show_ctags\" method=\"post\"><input type=\"hidden\" name=\"p\" value=\"$project\" />Add: <input type=\"text\" name=\"t\" size=\"8\" /></form>";
5416                 print "</td>\n<td>" if %$ctags;
5417                 print git_show_project_tagcloud($cloud, 48);
5418                 print "</td></tr>";
5419         }
5420
5421         print "</table>\n";
5422
5423         # If XSS prevention is on, we don't include README.html.
5424         # TODO: Allow a readme in some safe format.
5425         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
5426                 print "<div class=\"title\">readme</div>\n" .
5427                       "<div class=\"readme\">\n";
5428                 insert_file("$projectroot/$project/README.html");
5429                 print "\n</div>\n"; # class="readme"
5430         }
5431
5432         # we need to request one more than 16 (0..15) to check if
5433         # those 16 are all
5434         my @commitlist = $head ? parse_commits($head, 17) : ();
5435         if (@commitlist) {
5436                 git_print_header_div('shortlog');
5437                 git_shortlog_body(\@commitlist, 0, 15, $refs,
5438                                   $#commitlist <=  15 ? undef :
5439                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
5440         }
5441
5442         if (@taglist) {
5443                 git_print_header_div('tags');
5444                 git_tags_body(\@taglist, 0, 15,
5445                               $#taglist <=  15 ? undef :
5446                               $cgi->a({-href => href(action=>"tags")}, "..."));
5447         }
5448
5449         if (@headlist) {
5450                 git_print_header_div('heads');
5451                 git_heads_body(\@headlist, $head, 0, 15,
5452                                $#headlist <= 15 ? undef :
5453                                $cgi->a({-href => href(action=>"heads")}, "..."));
5454         }
5455
5456         if (%remotedata) {
5457                 git_print_header_div('remotes');
5458                 git_remotes_body(\%remotedata, 15, $head);
5459         }
5460
5461         if (@forklist) {
5462                 git_print_header_div('forks');
5463                 git_project_list_body(\@forklist, 'age', 0, 15,
5464                                       $#forklist <= 15 ? undef :
5465                                       $cgi->a({-href => href(action=>"forks")}, "..."),
5466                                       'no_header');
5467         }
5468
5469         git_footer_html();
5470 }
5471
5472 sub git_tag {
5473         my %tag = parse_tag($hash);
5474
5475         if (! %tag) {
5476                 die_error(404, "Unknown tag object");
5477         }
5478
5479         my $head = git_get_head_hash($project);
5480         git_header_html();
5481         git_print_page_nav('','', $head,undef,$head);
5482         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
5483         print "<div class=\"title_text\">\n" .
5484               "<table class=\"object_header\">\n" .
5485               "<tr>\n" .
5486               "<td>object</td>\n" .
5487               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
5488                                $tag{'object'}) . "</td>\n" .
5489               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
5490                                               $tag{'type'}) . "</td>\n" .
5491               "</tr>\n";
5492         if (defined($tag{'author'})) {
5493                 git_print_authorship_rows(\%tag, 'author');
5494         }
5495         print "</table>\n\n" .
5496               "</div>\n";
5497         print "<div class=\"page_body\">";
5498         my $comment = $tag{'comment'};
5499         foreach my $line (@$comment) {
5500                 chomp $line;
5501                 print esc_html($line, -nbsp=>1) . "<br/>\n";
5502         }
5503         print "</div>\n";
5504         git_footer_html();
5505 }
5506
5507 sub git_blame_common {
5508         my $format = shift || 'porcelain';
5509         if ($format eq 'porcelain' && $cgi->param('js')) {
5510                 $format = 'incremental';
5511                 $action = 'blame_incremental'; # for page title etc
5512         }
5513
5514         # permissions
5515         gitweb_check_feature('blame')
5516                 or die_error(403, "Blame view not allowed");
5517
5518         # error checking
5519         die_error(400, "No file name given") unless $file_name;
5520         $hash_base ||= git_get_head_hash($project);
5521         die_error(404, "Couldn't find base commit") unless $hash_base;
5522         my %co = parse_commit($hash_base)
5523                 or die_error(404, "Commit not found");
5524         my $ftype = "blob";
5525         if (!defined $hash) {
5526                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
5527                         or die_error(404, "Error looking up file");
5528         } else {
5529                 $ftype = git_get_type($hash);
5530                 if ($ftype !~ "blob") {
5531                         die_error(400, "Object is not a blob");
5532                 }
5533         }
5534
5535         my $fd;
5536         if ($format eq 'incremental') {
5537                 # get file contents (as base)
5538                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
5539                         or die_error(500, "Open git-cat-file failed");
5540         } elsif ($format eq 'data') {
5541                 # run git-blame --incremental
5542                 open $fd, "-|", git_cmd(), "blame", "--incremental",
5543                         $hash_base, "--", $file_name
5544                         or die_error(500, "Open git-blame --incremental failed");
5545         } else {
5546                 # run git-blame --porcelain
5547                 open $fd, "-|", git_cmd(), "blame", '-p',
5548                         $hash_base, '--', $file_name
5549                         or die_error(500, "Open git-blame --porcelain failed");
5550         }
5551
5552         # incremental blame data returns early
5553         if ($format eq 'data') {
5554                 print $cgi->header(
5555                         -type=>"text/plain", -charset => "utf-8",
5556                         -status=> "200 OK");
5557                 local $| = 1; # output autoflush
5558                 print while <$fd>;
5559                 close $fd
5560                         or print "ERROR $!\n";
5561
5562                 print 'END';
5563                 if (defined $t0 && gitweb_check_feature('timed')) {
5564                         print ' '.
5565                               tv_interval($t0, [ gettimeofday() ]).
5566                               ' '.$number_of_git_cmds;
5567                 }
5568                 print "\n";
5569
5570                 return;
5571         }
5572
5573         # page header
5574         git_header_html();
5575         my $formats_nav =
5576                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
5577                         "blob") .
5578                 " | ";
5579         if ($format eq 'incremental') {
5580                 $formats_nav .=
5581                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
5582                                 "blame") . " (non-incremental)";
5583         } else {
5584                 $formats_nav .=
5585                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
5586                                 "blame") . " (incremental)";
5587         }
5588         $formats_nav .=
5589                 " | " .
5590                 $cgi->a({-href => href(action=>"history", -replay=>1)},
5591                         "history") .
5592                 " | " .
5593                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
5594                         "HEAD");
5595         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
5596         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
5597         git_print_page_path($file_name, $ftype, $hash_base);
5598
5599         # page body
5600         if ($format eq 'incremental') {
5601                 print "<noscript>\n<div class=\"error\"><center><b>\n".
5602                       "This page requires JavaScript to run.\n Use ".
5603                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
5604                               'this page').
5605                       " instead.\n".
5606                       "</b></center></div>\n</noscript>\n";
5607
5608                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
5609         }
5610
5611         print qq!<div class="page_body">\n!;
5612         print qq!<div id="progress_info">... / ...</div>\n!
5613                 if ($format eq 'incremental');
5614         print qq!<table id="blame_table" class="blame" width="100%">\n!.
5615               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
5616               qq!<thead>\n!.
5617               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
5618               qq!</thead>\n!.
5619               qq!<tbody>\n!;
5620
5621         my @rev_color = qw(light dark);
5622         my $num_colors = scalar(@rev_color);
5623         my $current_color = 0;
5624
5625         if ($format eq 'incremental') {
5626                 my $color_class = $rev_color[$current_color];
5627
5628                 #contents of a file
5629                 my $linenr = 0;
5630         LINE:
5631                 while (my $line = <$fd>) {
5632                         chomp $line;
5633                         $linenr++;
5634
5635                         print qq!<tr id="l$linenr" class="$color_class">!.
5636                               qq!<td class="sha1"><a href=""> </a></td>!.
5637                               qq!<td class="linenr">!.
5638                               qq!<a class="linenr" href="">$linenr</a></td>!;
5639                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
5640                         print qq!</tr>\n!;
5641                 }
5642
5643         } else { # porcelain, i.e. ordinary blame
5644                 my %metainfo = (); # saves information about commits
5645
5646                 # blame data
5647         LINE:
5648                 while (my $line = <$fd>) {
5649                         chomp $line;
5650                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
5651                         # no <lines in group> for subsequent lines in group of lines
5652                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
5653                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
5654                         if (!exists $metainfo{$full_rev}) {
5655                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
5656                         }
5657                         my $meta = $metainfo{$full_rev};
5658                         my $data;
5659                         while ($data = <$fd>) {
5660                                 chomp $data;
5661                                 last if ($data =~ s/^\t//); # contents of line
5662                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
5663                                         $meta->{$1} = $2 unless exists $meta->{$1};
5664                                 }
5665                                 if ($data =~ /^previous /) {
5666                                         $meta->{'nprevious'}++;
5667                                 }
5668                         }
5669                         my $short_rev = substr($full_rev, 0, 8);
5670                         my $author = $meta->{'author'};
5671                         my %date =
5672                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
5673                         my $date = $date{'iso-tz'};
5674                         if ($group_size) {
5675                                 $current_color = ($current_color + 1) % $num_colors;
5676                         }
5677                         my $tr_class = $rev_color[$current_color];
5678                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
5679                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
5680                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
5681                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
5682                         if ($group_size) {
5683                                 print "<td class=\"sha1\"";
5684                                 print " title=\"". esc_html($author) . ", $date\"";
5685                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
5686                                 print ">";
5687                                 print $cgi->a({-href => href(action=>"commit",
5688                                                              hash=>$full_rev,
5689                                                              file_name=>$file_name)},
5690                                               esc_html($short_rev));
5691                                 if ($group_size >= 2) {
5692                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
5693                                         if (@author_initials) {
5694                                                 print "<br />" .
5695                                                       esc_html(join('', @author_initials));
5696                                                 #           or join('.', ...)
5697                                         }
5698                                 }
5699                                 print "</td>\n";
5700                         }
5701                         # 'previous' <sha1 of parent commit> <filename at commit>
5702                         if (exists $meta->{'previous'} &&
5703                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
5704                                 $meta->{'parent'} = $1;
5705                                 $meta->{'file_parent'} = unquote($2);
5706                         }
5707                         my $linenr_commit =
5708                                 exists($meta->{'parent'}) ?
5709                                 $meta->{'parent'} : $full_rev;
5710                         my $linenr_filename =
5711                                 exists($meta->{'file_parent'}) ?
5712                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
5713                         my $blamed = href(action => 'blame',
5714                                           file_name => $linenr_filename,
5715                                           hash_base => $linenr_commit);
5716                         print "<td class=\"linenr\">";
5717                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
5718                                         -class => "linenr" },
5719                                       esc_html($lineno));
5720                         print "</td>";
5721                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
5722                         print "</tr>\n";
5723                 } # end while
5724
5725         }
5726
5727         # footer
5728         print "</tbody>\n".
5729               "</table>\n"; # class="blame"
5730         print "</div>\n";   # class="blame_body"
5731         close $fd
5732                 or print "Reading blob failed\n";
5733
5734         git_footer_html();
5735 }
5736
5737 sub git_blame {
5738         git_blame_common();
5739 }
5740
5741 sub git_blame_incremental {
5742         git_blame_common('incremental');
5743 }
5744
5745 sub git_blame_data {
5746         git_blame_common('data');
5747 }
5748
5749 sub git_tags {
5750         my $head = git_get_head_hash($project);
5751         git_header_html();
5752         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
5753         git_print_header_div('summary', $project);
5754
5755         my @tagslist = git_get_tags_list();
5756         if (@tagslist) {
5757                 git_tags_body(\@tagslist);
5758         }
5759         git_footer_html();
5760 }
5761
5762 sub git_heads {
5763         my $head = git_get_head_hash($project);
5764         git_header_html();
5765         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
5766         git_print_header_div('summary', $project);
5767
5768         my @headslist = git_get_heads_list();
5769         if (@headslist) {
5770                 git_heads_body(\@headslist, $head);
5771         }
5772         git_footer_html();
5773 }
5774
5775 # used both for single remote view and for list of all the remotes
5776 sub git_remotes {
5777         gitweb_check_feature('remote_heads')
5778                 or die_error(403, "Remote heads view is disabled");
5779
5780         my $head = git_get_head_hash($project);
5781         my $remote = $input_params{'hash'};
5782
5783         my $remotedata = git_get_remotes_list($remote);
5784         die_error(500, "Unable to get remote information") unless defined $remotedata;
5785
5786         unless (%$remotedata) {
5787                 die_error(404, defined $remote ?
5788                         "Remote $remote not found" :
5789                         "No remotes found");
5790         }
5791
5792         git_header_html(undef, undef, -action_extra => $remote);
5793         git_print_page_nav('', '',  $head, undef, $head,
5794                 format_ref_views($remote ? '' : 'remotes'));
5795
5796         fill_remote_heads($remotedata);
5797         if (defined $remote) {
5798                 git_print_header_div('remotes', "$remote remote for $project");
5799                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
5800         } else {
5801                 git_print_header_div('summary', "$project remotes");
5802                 git_remotes_body($remotedata, undef, $head);
5803         }
5804
5805         git_footer_html();
5806 }
5807
5808 sub git_blob_plain {
5809         my $type = shift;
5810         my $expires;
5811
5812         if (!defined $hash) {
5813                 if (defined $file_name) {
5814                         my $base = $hash_base || git_get_head_hash($project);
5815                         $hash = git_get_hash_by_path($base, $file_name, "blob")
5816                                 or die_error(404, "Cannot find file");
5817                 } else {
5818                         die_error(400, "No file name defined");
5819                 }
5820         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
5821                 # blobs defined by non-textual hash id's can be cached
5822                 $expires = "+1d";
5823         }
5824
5825         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
5826                 or die_error(500, "Open git-cat-file blob '$hash' failed");
5827
5828         # content-type (can include charset)
5829         $type = blob_contenttype($fd, $file_name, $type);
5830
5831         # "save as" filename, even when no $file_name is given
5832         my $save_as = "$hash";
5833         if (defined $file_name) {
5834                 $save_as = $file_name;
5835         } elsif ($type =~ m/^text\//) {
5836                 $save_as .= '.txt';
5837         }
5838
5839         # With XSS prevention on, blobs of all types except a few known safe
5840         # ones are served with "Content-Disposition: attachment" to make sure
5841         # they don't run in our security domain.  For certain image types,
5842         # blob view writes an <img> tag referring to blob_plain view, and we
5843         # want to be sure not to break that by serving the image as an
5844         # attachment (though Firefox 3 doesn't seem to care).
5845         my $sandbox = $prevent_xss &&
5846                 $type !~ m!^(?:text/plain|image/(?:gif|png|jpeg))$!;
5847
5848         print $cgi->header(
5849                 -type => $type,
5850                 -expires => $expires,
5851                 -content_disposition =>
5852                         ($sandbox ? 'attachment' : 'inline')
5853                         . '; filename="' . $save_as . '"');
5854         local $/ = undef;
5855         binmode STDOUT, ':raw';
5856         print <$fd>;
5857         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
5858         close $fd;
5859 }
5860
5861 sub git_blob {
5862         my $expires;
5863
5864         if (!defined $hash) {
5865                 if (defined $file_name) {
5866                         my $base = $hash_base || git_get_head_hash($project);
5867                         $hash = git_get_hash_by_path($base, $file_name, "blob")
5868                                 or die_error(404, "Cannot find file");
5869                 } else {
5870                         die_error(400, "No file name defined");
5871                 }
5872         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
5873                 # blobs defined by non-textual hash id's can be cached
5874                 $expires = "+1d";
5875         }
5876
5877         my $have_blame = gitweb_check_feature('blame');
5878         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
5879                 or die_error(500, "Couldn't cat $file_name, $hash");
5880         my $mimetype = blob_mimetype($fd, $file_name);
5881         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
5882         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
5883                 close $fd;
5884                 return git_blob_plain($mimetype);
5885         }
5886         # we can have blame only for text/* mimetype
5887         $have_blame &&= ($mimetype =~ m!^text/!);
5888
5889         my $highlight = gitweb_check_feature('highlight');
5890         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
5891         $fd = run_highlighter($fd, $highlight, $syntax)
5892                 if $syntax;
5893
5894         git_header_html(undef, $expires);
5895         my $formats_nav = '';
5896         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
5897                 if (defined $file_name) {
5898                         if ($have_blame) {
5899                                 $formats_nav .=
5900                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
5901                                                 "blame") .
5902                                         " | ";
5903                         }
5904                         $formats_nav .=
5905                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
5906                                         "history") .
5907                                 " | " .
5908                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
5909                                         "raw") .
5910                                 " | " .
5911                                 $cgi->a({-href => href(action=>"blob",
5912                                                        hash_base=>"HEAD", file_name=>$file_name)},
5913                                         "HEAD");
5914                 } else {
5915                         $formats_nav .=
5916                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
5917                                         "raw");
5918                 }
5919                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
5920                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
5921         } else {
5922                 print "<div class=\"page_nav\">\n" .
5923                       "<br/><br/></div>\n" .
5924                       "<div class=\"title\">".esc_html($hash)."</div>\n";
5925         }
5926         git_print_page_path($file_name, "blob", $hash_base);
5927         print "<div class=\"page_body\">\n";
5928         if ($mimetype =~ m!^image/!) {
5929                 print qq!<img type="!.esc_attr($mimetype).qq!"!;
5930                 if ($file_name) {
5931                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
5932                 }
5933                 print qq! src="! .
5934                       href(action=>"blob_plain", hash=>$hash,
5935                            hash_base=>$hash_base, file_name=>$file_name) .
5936                       qq!" />\n!;
5937         } else {
5938                 my $nr;
5939                 while (my $line = <$fd>) {
5940                         chomp $line;
5941                         $nr++;
5942                         $line = untabify($line);
5943                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
5944                                $nr, esc_attr(href(-replay => 1)), $nr, $nr, $syntax ? $line : esc_html($line, -nbsp=>1);
5945                 }
5946         }
5947         close $fd
5948                 or print "Reading blob failed.\n";
5949         print "</div>";
5950         git_footer_html();
5951 }
5952
5953 sub git_tree {
5954         if (!defined $hash_base) {
5955                 $hash_base = "HEAD";
5956         }
5957         if (!defined $hash) {
5958                 if (defined $file_name) {
5959                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
5960                 } else {
5961                         $hash = $hash_base;
5962                 }
5963         }
5964         die_error(404, "No such tree") unless defined($hash);
5965
5966         my $show_sizes = gitweb_check_feature('show-sizes');
5967         my $have_blame = gitweb_check_feature('blame');
5968
5969         my @entries = ();
5970         {
5971                 local $/ = "\0";
5972                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
5973                         ($show_sizes ? '-l' : ()), @extra_options, $hash
5974                         or die_error(500, "Open git-ls-tree failed");
5975                 @entries = map { chomp; $_ } <$fd>;
5976                 close $fd
5977                         or die_error(404, "Reading tree failed");
5978         }
5979
5980         my $refs = git_get_references();
5981         my $ref = format_ref_marker($refs, $hash_base);
5982         git_header_html();
5983         my $basedir = '';
5984         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
5985                 my @views_nav = ();
5986                 if (defined $file_name) {
5987                         push @views_nav,
5988                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
5989                                         "history"),
5990                                 $cgi->a({-href => href(action=>"tree",
5991                                                        hash_base=>"HEAD", file_name=>$file_name)},
5992                                         "HEAD"),
5993                 }
5994                 my $snapshot_links = format_snapshot_links($hash);
5995                 if (defined $snapshot_links) {
5996                         # FIXME: Should be available when we have no hash base as well.
5997                         push @views_nav, $snapshot_links;
5998                 }
5999                 git_print_page_nav('tree','', $hash_base, undef, undef,
6000                                    join(' | ', @views_nav));
6001                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
6002         } else {
6003                 undef $hash_base;
6004                 print "<div class=\"page_nav\">\n";
6005                 print "<br/><br/></div>\n";
6006                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
6007         }
6008         if (defined $file_name) {
6009                 $basedir = $file_name;
6010                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
6011                         $basedir .= '/';
6012                 }
6013                 git_print_page_path($file_name, 'tree', $hash_base);
6014         }
6015         print "<div class=\"page_body\">\n";
6016         print "<table class=\"tree\">\n";
6017         my $alternate = 1;
6018         # '..' (top directory) link if possible
6019         if (defined $hash_base &&
6020             defined $file_name && $file_name =~ m![^/]+$!) {
6021                 if ($alternate) {
6022                         print "<tr class=\"dark\">\n";
6023                 } else {
6024                         print "<tr class=\"light\">\n";
6025                 }
6026                 $alternate ^= 1;
6027
6028                 my $up = $file_name;
6029                 $up =~ s!/?[^/]+$!!;
6030                 undef $up unless $up;
6031                 # based on git_print_tree_entry
6032                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
6033                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
6034                 print '<td class="list">';
6035                 print $cgi->a({-href => href(action=>"tree",
6036                                              hash_base=>$hash_base,
6037                                              file_name=>$up)},
6038                               "..");
6039                 print "</td>\n";
6040                 print "<td class=\"link\"></td>\n";
6041
6042                 print "</tr>\n";
6043         }
6044         foreach my $line (@entries) {
6045                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
6046
6047                 if ($alternate) {
6048                         print "<tr class=\"dark\">\n";
6049                 } else {
6050                         print "<tr class=\"light\">\n";
6051                 }
6052                 $alternate ^= 1;
6053
6054                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
6055
6056                 print "</tr>\n";
6057         }
6058         print "</table>\n" .
6059               "</div>";
6060         git_footer_html();
6061 }
6062
6063 sub snapshot_name {
6064         my ($project, $hash) = @_;
6065
6066         # path/to/project.git  -> project
6067         # path/to/project/.git -> project
6068         my $name = to_utf8($project);
6069         $name =~ s,([^/])/*\.git$,$1,;
6070         $name = basename($name);
6071         # sanitize name
6072         $name =~ s/[[:cntrl:]]/?/g;
6073
6074         my $ver = $hash;
6075         if ($hash =~ /^[0-9a-fA-F]+$/) {
6076                 # shorten SHA-1 hash
6077                 my $full_hash = git_get_full_hash($project, $hash);
6078                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
6079                         $ver = git_get_short_hash($project, $hash);
6080                 }
6081         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
6082                 # tags don't need shortened SHA-1 hash
6083                 $ver = $1;
6084         } else {
6085                 # branches and other need shortened SHA-1 hash
6086                 if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
6087                         $ver = $1;
6088                 }
6089                 $ver .= '-' . git_get_short_hash($project, $hash);
6090         }
6091         # in case of hierarchical branch names
6092         $ver =~ s!/!.!g;
6093
6094         # name = project-version_string
6095         $name = "$name-$ver";
6096
6097         return wantarray ? ($name, $name) : $name;
6098 }
6099
6100 sub git_snapshot {
6101         my $format = $input_params{'snapshot_format'};
6102         if (!@snapshot_fmts) {
6103                 die_error(403, "Snapshots not allowed");
6104         }
6105         # default to first supported snapshot format
6106         $format ||= $snapshot_fmts[0];
6107         if ($format !~ m/^[a-z0-9]+$/) {
6108                 die_error(400, "Invalid snapshot format parameter");
6109         } elsif (!exists($known_snapshot_formats{$format})) {
6110                 die_error(400, "Unknown snapshot format");
6111         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
6112                 die_error(403, "Snapshot format not allowed");
6113         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
6114                 die_error(403, "Unsupported snapshot format");
6115         }
6116
6117         my $type = git_get_type("$hash^{}");
6118         if (!$type) {
6119                 die_error(404, 'Object does not exist');
6120         }  elsif ($type eq 'blob') {
6121                 die_error(400, 'Object is not a tree-ish');
6122         }
6123
6124         my ($name, $prefix) = snapshot_name($project, $hash);
6125         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
6126         my $cmd = quote_command(
6127                 git_cmd(), 'archive',
6128                 "--format=$known_snapshot_formats{$format}{'format'}",
6129                 "--prefix=$prefix/", $hash);
6130         if (exists $known_snapshot_formats{$format}{'compressor'}) {
6131                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
6132         }
6133
6134         $filename =~ s/(["\\])/\\$1/g;
6135         print $cgi->header(
6136                 -type => $known_snapshot_formats{$format}{'type'},
6137                 -content_disposition => 'inline; filename="' . $filename . '"',
6138                 -status => '200 OK');
6139
6140         open my $fd, "-|", $cmd
6141                 or die_error(500, "Execute git-archive failed");
6142         binmode STDOUT, ':raw';
6143         print <$fd>;
6144         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6145         close $fd;
6146 }
6147
6148 sub git_log_generic {
6149         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
6150
6151         my $head = git_get_head_hash($project);
6152         if (!defined $base) {
6153                 $base = $head;
6154         }
6155         if (!defined $page) {
6156                 $page = 0;
6157         }
6158         my $refs = git_get_references();
6159
6160         my $commit_hash = $base;
6161         if (defined $parent) {
6162                 $commit_hash = "$parent..$base";
6163         }
6164         my @commitlist =
6165                 parse_commits($commit_hash, 101, (100 * $page),
6166                               defined $file_name ? ($file_name, "--full-history") : ());
6167
6168         my $ftype;
6169         if (!defined $file_hash && defined $file_name) {
6170                 # some commits could have deleted file in question,
6171                 # and not have it in tree, but one of them has to have it
6172                 for (my $i = 0; $i < @commitlist; $i++) {
6173                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
6174                         last if defined $file_hash;
6175                 }
6176         }
6177         if (defined $file_hash) {
6178                 $ftype = git_get_type($file_hash);
6179         }
6180         if (defined $file_name && !defined $ftype) {
6181                 die_error(500, "Unknown type of object");
6182         }
6183         my %co;
6184         if (defined $file_name) {
6185                 %co = parse_commit($base)
6186                         or die_error(404, "Unknown commit object");
6187         }
6188
6189
6190         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
6191         my $next_link = '';
6192         if ($#commitlist >= 100) {
6193                 $next_link =
6194                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
6195                                  -accesskey => "n", -title => "Alt-n"}, "next");
6196         }
6197         my $patch_max = gitweb_get_feature('patches');
6198         if ($patch_max && !defined $file_name) {
6199                 if ($patch_max < 0 || @commitlist <= $patch_max) {
6200                         $paging_nav .= " &sdot; " .
6201                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
6202                                         "patches");
6203                 }
6204         }
6205
6206         git_header_html();
6207         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
6208         if (defined $file_name) {
6209                 git_print_header_div('commit', esc_html($co{'title'}), $base);
6210         } else {
6211                 git_print_header_div('summary', $project)
6212         }
6213         git_print_page_path($file_name, $ftype, $hash_base)
6214                 if (defined $file_name);
6215
6216         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
6217                      $file_name, $file_hash, $ftype);
6218
6219         git_footer_html();
6220 }
6221
6222 sub git_log {
6223         git_log_generic('log', \&git_log_body,
6224                         $hash, $hash_parent);
6225 }
6226
6227 sub git_commit {
6228         $hash ||= $hash_base || "HEAD";
6229         my %co = parse_commit($hash)
6230             or die_error(404, "Unknown commit object");
6231
6232         my $parent  = $co{'parent'};
6233         my $parents = $co{'parents'}; # listref
6234
6235         # we need to prepare $formats_nav before any parameter munging
6236         my $formats_nav;
6237         if (!defined $parent) {
6238                 # --root commitdiff
6239                 $formats_nav .= '(initial)';
6240         } elsif (@$parents == 1) {
6241                 # single parent commit
6242                 $formats_nav .=
6243                         '(parent: ' .
6244                         $cgi->a({-href => href(action=>"commit",
6245                                                hash=>$parent)},
6246                                 esc_html(substr($parent, 0, 7))) .
6247                         ')';
6248         } else {
6249                 # merge commit
6250                 $formats_nav .=
6251                         '(merge: ' .
6252                         join(' ', map {
6253                                 $cgi->a({-href => href(action=>"commit",
6254                                                        hash=>$_)},
6255                                         esc_html(substr($_, 0, 7)));
6256                         } @$parents ) .
6257                         ')';
6258         }
6259         if (gitweb_check_feature('patches') && @$parents <= 1) {
6260                 $formats_nav .= " | " .
6261                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
6262                                 "patch");
6263         }
6264
6265         if (!defined $parent) {
6266                 $parent = "--root";
6267         }
6268         my @difftree;
6269         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
6270                 @diff_opts,
6271                 (@$parents <= 1 ? $parent : '-c'),
6272                 $hash, "--"
6273                 or die_error(500, "Open git-diff-tree failed");
6274         @difftree = map { chomp; $_ } <$fd>;
6275         close $fd or die_error(404, "Reading git-diff-tree failed");
6276
6277         # non-textual hash id's can be cached
6278         my $expires;
6279         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6280                 $expires = "+1d";
6281         }
6282         my $refs = git_get_references();
6283         my $ref = format_ref_marker($refs, $co{'id'});
6284
6285         git_header_html(undef, $expires);
6286         git_print_page_nav('commit', '',
6287                            $hash, $co{'tree'}, $hash,
6288                            $formats_nav);
6289
6290         if (defined $co{'parent'}) {
6291                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
6292         } else {
6293                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
6294         }
6295         print "<div class=\"title_text\">\n" .
6296               "<table class=\"object_header\">\n";
6297         git_print_authorship_rows(\%co);
6298         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
6299         print "<tr>" .
6300               "<td>tree</td>" .
6301               "<td class=\"sha1\">" .
6302               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
6303                        class => "list"}, $co{'tree'}) .
6304               "</td>" .
6305               "<td class=\"link\">" .
6306               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
6307                       "tree");
6308         my $snapshot_links = format_snapshot_links($hash);
6309         if (defined $snapshot_links) {
6310                 print " | " . $snapshot_links;
6311         }
6312         print "</td>" .
6313               "</tr>\n";
6314
6315         foreach my $par (@$parents) {
6316                 print "<tr>" .
6317                       "<td>parent</td>" .
6318                       "<td class=\"sha1\">" .
6319                       $cgi->a({-href => href(action=>"commit", hash=>$par),
6320                                class => "list"}, $par) .
6321                       "</td>" .
6322                       "<td class=\"link\">" .
6323                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
6324                       " | " .
6325                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
6326                       "</td>" .
6327                       "</tr>\n";
6328         }
6329         print "</table>".
6330               "</div>\n";
6331
6332         print "<div class=\"page_body\">\n";
6333         git_print_log($co{'comment'});
6334         print "</div>\n";
6335
6336         git_difftree_body(\@difftree, $hash, @$parents);
6337
6338         git_footer_html();
6339 }
6340
6341 sub git_object {
6342         # object is defined by:
6343         # - hash or hash_base alone
6344         # - hash_base and file_name
6345         my $type;
6346
6347         # - hash or hash_base alone
6348         if ($hash || ($hash_base && !defined $file_name)) {
6349                 my $object_id = $hash || $hash_base;
6350
6351                 open my $fd, "-|", quote_command(
6352                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
6353                         or die_error(404, "Object does not exist");
6354                 $type = <$fd>;
6355                 chomp $type;
6356                 close $fd
6357                         or die_error(404, "Object does not exist");
6358
6359         # - hash_base and file_name
6360         } elsif ($hash_base && defined $file_name) {
6361                 $file_name =~ s,/+$,,;
6362
6363                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
6364                         or die_error(404, "Base object does not exist");
6365
6366                 # here errors should not hapen
6367                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
6368                         or die_error(500, "Open git-ls-tree failed");
6369                 my $line = <$fd>;
6370                 close $fd;
6371
6372                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
6373                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
6374                         die_error(404, "File or directory for given base does not exist");
6375                 }
6376                 $type = $2;
6377                 $hash = $3;
6378         } else {
6379                 die_error(400, "Not enough information to find object");
6380         }
6381
6382         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
6383                                           hash=>$hash, hash_base=>$hash_base,
6384                                           file_name=>$file_name),
6385                              -status => '302 Found');
6386 }
6387
6388 sub git_blobdiff {
6389         my $format = shift || 'html';
6390
6391         my $fd;
6392         my @difftree;
6393         my %diffinfo;
6394         my $expires;
6395
6396         # preparing $fd and %diffinfo for git_patchset_body
6397         # new style URI
6398         if (defined $hash_base && defined $hash_parent_base) {
6399                 if (defined $file_name) {
6400                         # read raw output
6401                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6402                                 $hash_parent_base, $hash_base,
6403                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
6404                                 or die_error(500, "Open git-diff-tree failed");
6405                         @difftree = map { chomp; $_ } <$fd>;
6406                         close $fd
6407                                 or die_error(404, "Reading git-diff-tree failed");
6408                         @difftree
6409                                 or die_error(404, "Blob diff not found");
6410
6411                 } elsif (defined $hash &&
6412                          $hash =~ /[0-9a-fA-F]{40}/) {
6413                         # try to find filename from $hash
6414
6415                         # read filtered raw output
6416                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6417                                 $hash_parent_base, $hash_base, "--"
6418                                 or die_error(500, "Open git-diff-tree failed");
6419                         @difftree =
6420                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
6421                                 # $hash == to_id
6422                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
6423                                 map { chomp; $_ } <$fd>;
6424                         close $fd
6425                                 or die_error(404, "Reading git-diff-tree failed");
6426                         @difftree
6427                                 or die_error(404, "Blob diff not found");
6428
6429                 } else {
6430                         die_error(400, "Missing one of the blob diff parameters");
6431                 }
6432
6433                 if (@difftree > 1) {
6434                         die_error(400, "Ambiguous blob diff specification");
6435                 }
6436
6437                 %diffinfo = parse_difftree_raw_line($difftree[0]);
6438                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
6439                 $file_name   ||= $diffinfo{'to_file'};
6440
6441                 $hash_parent ||= $diffinfo{'from_id'};
6442                 $hash        ||= $diffinfo{'to_id'};
6443
6444                 # non-textual hash id's can be cached
6445                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
6446                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
6447                         $expires = '+1d';
6448                 }
6449
6450                 # open patch output
6451                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6452                         '-p', ($format eq 'html' ? "--full-index" : ()),
6453                         $hash_parent_base, $hash_base,
6454                         "--", (defined $file_parent ? $file_parent : ()), $file_name
6455                         or die_error(500, "Open git-diff-tree failed");
6456         }
6457
6458         # old/legacy style URI -- not generated anymore since 1.4.3.
6459         if (!%diffinfo) {
6460                 die_error('404 Not Found', "Missing one of the blob diff parameters")
6461         }
6462
6463         # header
6464         if ($format eq 'html') {
6465                 my $formats_nav =
6466                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
6467                                 "raw");
6468                 git_header_html(undef, $expires);
6469                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6470                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6471                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6472                 } else {
6473                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
6474                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
6475                 }
6476                 if (defined $file_name) {
6477                         git_print_page_path($file_name, "blob", $hash_base);
6478                 } else {
6479                         print "<div class=\"page_path\"></div>\n";
6480                 }
6481
6482         } elsif ($format eq 'plain') {
6483                 print $cgi->header(
6484                         -type => 'text/plain',
6485                         -charset => 'utf-8',
6486                         -expires => $expires,
6487                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
6488
6489                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
6490
6491         } else {
6492                 die_error(400, "Unknown blobdiff format");
6493         }
6494
6495         # patch
6496         if ($format eq 'html') {
6497                 print "<div class=\"page_body\">\n";
6498
6499                 git_patchset_body($fd, [ \%diffinfo ], $hash_base, $hash_parent_base);
6500                 close $fd;
6501
6502                 print "</div>\n"; # class="page_body"
6503                 git_footer_html();
6504
6505         } else {
6506                 while (my $line = <$fd>) {
6507                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
6508                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
6509
6510                         print $line;
6511
6512                         last if $line =~ m!^\+\+\+!;
6513                 }
6514                 local $/ = undef;
6515                 print <$fd>;
6516                 close $fd;
6517         }
6518 }
6519
6520 sub git_blobdiff_plain {
6521         git_blobdiff('plain');
6522 }
6523
6524 sub git_commitdiff {
6525         my %params = @_;
6526         my $format = $params{-format} || 'html';
6527
6528         my ($patch_max) = gitweb_get_feature('patches');
6529         if ($format eq 'patch') {
6530                 die_error(403, "Patch view not allowed") unless $patch_max;
6531         }
6532
6533         $hash ||= $hash_base || "HEAD";
6534         my %co = parse_commit($hash)
6535             or die_error(404, "Unknown commit object");
6536
6537         # choose format for commitdiff for merge
6538         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
6539                 $hash_parent = '--cc';
6540         }
6541         # we need to prepare $formats_nav before almost any parameter munging
6542         my $formats_nav;
6543         if ($format eq 'html') {
6544                 $formats_nav =
6545                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
6546                                 "raw");
6547                 if ($patch_max && @{$co{'parents'}} <= 1) {
6548                         $formats_nav .= " | " .
6549                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
6550                                         "patch");
6551                 }
6552
6553                 if (defined $hash_parent &&
6554                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
6555                         # commitdiff with two commits given
6556                         my $hash_parent_short = $hash_parent;
6557                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
6558                                 $hash_parent_short = substr($hash_parent, 0, 7);
6559                         }
6560                         $formats_nav .=
6561                                 ' (from';
6562                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
6563                                 if ($co{'parents'}[$i] eq $hash_parent) {
6564                                         $formats_nav .= ' parent ' . ($i+1);
6565                                         last;
6566                                 }
6567                         }
6568                         $formats_nav .= ': ' .
6569                                 $cgi->a({-href => href(action=>"commitdiff",
6570                                                        hash=>$hash_parent)},
6571                                         esc_html($hash_parent_short)) .
6572                                 ')';
6573                 } elsif (!$co{'parent'}) {
6574                         # --root commitdiff
6575                         $formats_nav .= ' (initial)';
6576                 } elsif (scalar @{$co{'parents'}} == 1) {
6577                         # single parent commit
6578                         $formats_nav .=
6579                                 ' (parent: ' .
6580                                 $cgi->a({-href => href(action=>"commitdiff",
6581                                                        hash=>$co{'parent'})},
6582                                         esc_html(substr($co{'parent'}, 0, 7))) .
6583                                 ')';
6584                 } else {
6585                         # merge commit
6586                         if ($hash_parent eq '--cc') {
6587                                 $formats_nav .= ' | ' .
6588                                         $cgi->a({-href => href(action=>"commitdiff",
6589                                                                hash=>$hash, hash_parent=>'-c')},
6590                                                 'combined');
6591                         } else { # $hash_parent eq '-c'
6592                                 $formats_nav .= ' | ' .
6593                                         $cgi->a({-href => href(action=>"commitdiff",
6594                                                                hash=>$hash, hash_parent=>'--cc')},
6595                                                 'compact');
6596                         }
6597                         $formats_nav .=
6598                                 ' (merge: ' .
6599                                 join(' ', map {
6600                                         $cgi->a({-href => href(action=>"commitdiff",
6601                                                                hash=>$_)},
6602                                                 esc_html(substr($_, 0, 7)));
6603                                 } @{$co{'parents'}} ) .
6604                                 ')';
6605                 }
6606         }
6607
6608         my $hash_parent_param = $hash_parent;
6609         if (!defined $hash_parent_param) {
6610                 # --cc for multiple parents, --root for parentless
6611                 $hash_parent_param =
6612                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
6613         }
6614
6615         # read commitdiff
6616         my $fd;
6617         my @difftree;
6618         if ($format eq 'html') {
6619                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6620                         "--no-commit-id", "--patch-with-raw", "--full-index",
6621                         $hash_parent_param, $hash, "--"
6622                         or die_error(500, "Open git-diff-tree failed");
6623
6624                 while (my $line = <$fd>) {
6625                         chomp $line;
6626                         # empty line ends raw part of diff-tree output
6627                         last unless $line;
6628                         push @difftree, scalar parse_difftree_raw_line($line);
6629                 }
6630
6631         } elsif ($format eq 'plain') {
6632                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6633                         '-p', $hash_parent_param, $hash, "--"
6634                         or die_error(500, "Open git-diff-tree failed");
6635         } elsif ($format eq 'patch') {
6636                 # For commit ranges, we limit the output to the number of
6637                 # patches specified in the 'patches' feature.
6638                 # For single commits, we limit the output to a single patch,
6639                 # diverging from the git-format-patch default.
6640                 my @commit_spec = ();
6641                 if ($hash_parent) {
6642                         if ($patch_max > 0) {
6643                                 push @commit_spec, "-$patch_max";
6644                         }
6645                         push @commit_spec, '-n', "$hash_parent..$hash";
6646                 } else {
6647                         if ($params{-single}) {
6648                                 push @commit_spec, '-1';
6649                         } else {
6650                                 if ($patch_max > 0) {
6651                                         push @commit_spec, "-$patch_max";
6652                                 }
6653                                 push @commit_spec, "-n";
6654                         }
6655                         push @commit_spec, '--root', $hash;
6656                 }
6657                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
6658                         '--encoding=utf8', '--stdout', @commit_spec
6659                         or die_error(500, "Open git-format-patch failed");
6660         } else {
6661                 die_error(400, "Unknown commitdiff format");
6662         }
6663
6664         # non-textual hash id's can be cached
6665         my $expires;
6666         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6667                 $expires = "+1d";
6668         }
6669
6670         # write commit message
6671         if ($format eq 'html') {
6672                 my $refs = git_get_references();
6673                 my $ref = format_ref_marker($refs, $co{'id'});
6674
6675                 git_header_html(undef, $expires);
6676                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
6677                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
6678                 print "<div class=\"title_text\">\n" .
6679                       "<table class=\"object_header\">\n";
6680                 git_print_authorship_rows(\%co);
6681                 print "</table>".
6682                       "</div>\n";
6683                 print "<div class=\"page_body\">\n";
6684                 if (@{$co{'comment'}} > 1) {
6685                         print "<div class=\"log\">\n";
6686                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
6687                         print "</div>\n"; # class="log"
6688                 }
6689
6690         } elsif ($format eq 'plain') {
6691                 my $refs = git_get_references("tags");
6692                 my $tagname = git_get_rev_name_tags($hash);
6693                 my $filename = basename($project) . "-$hash.patch";
6694
6695                 print $cgi->header(
6696                         -type => 'text/plain',
6697                         -charset => 'utf-8',
6698                         -expires => $expires,
6699                         -content_disposition => 'inline; filename="' . "$filename" . '"');
6700                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
6701                 print "From: " . to_utf8($co{'author'}) . "\n";
6702                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
6703                 print "Subject: " . to_utf8($co{'title'}) . "\n";
6704
6705                 print "X-Git-Tag: $tagname\n" if $tagname;
6706                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
6707
6708                 foreach my $line (@{$co{'comment'}}) {
6709                         print to_utf8($line) . "\n";
6710                 }
6711                 print "---\n\n";
6712         } elsif ($format eq 'patch') {
6713                 my $filename = basename($project) . "-$hash.patch";
6714
6715                 print $cgi->header(
6716                         -type => 'text/plain',
6717                         -charset => 'utf-8',
6718                         -expires => $expires,
6719                         -content_disposition => 'inline; filename="' . "$filename" . '"');
6720         }
6721
6722         # write patch
6723         if ($format eq 'html') {
6724                 my $use_parents = !defined $hash_parent ||
6725                         $hash_parent eq '-c' || $hash_parent eq '--cc';
6726                 git_difftree_body(\@difftree, $hash,
6727                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
6728                 print "<br/>\n";
6729
6730                 git_patchset_body($fd, \@difftree, $hash,
6731                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
6732                 close $fd;
6733                 print "</div>\n"; # class="page_body"
6734                 git_footer_html();
6735
6736         } elsif ($format eq 'plain') {
6737                 local $/ = undef;
6738                 print <$fd>;
6739                 close $fd
6740                         or print "Reading git-diff-tree failed\n";
6741         } elsif ($format eq 'patch') {
6742                 local $/ = undef;
6743                 print <$fd>;
6744                 close $fd
6745                         or print "Reading git-format-patch failed\n";
6746         }
6747 }
6748
6749 sub git_commitdiff_plain {
6750         git_commitdiff(-format => 'plain');
6751 }
6752
6753 # format-patch-style patches
6754 sub git_patch {
6755         git_commitdiff(-format => 'patch', -single => 1);
6756 }
6757
6758 sub git_patches {
6759         git_commitdiff(-format => 'patch');
6760 }
6761
6762 sub git_history {
6763         git_log_generic('history', \&git_history_body,
6764                         $hash_base, $hash_parent_base,
6765                         $file_name, $hash);
6766 }
6767
6768 sub git_search {
6769         gitweb_check_feature('search') or die_error(403, "Search is disabled");
6770         if (!defined $searchtext) {
6771                 die_error(400, "Text field is empty");
6772         }
6773         if (!defined $hash) {
6774                 $hash = git_get_head_hash($project);
6775         }
6776         my %co = parse_commit($hash);
6777         if (!%co) {
6778                 die_error(404, "Unknown commit object");
6779         }
6780         if (!defined $page) {
6781                 $page = 0;
6782         }
6783
6784         $searchtype ||= 'commit';
6785         if ($searchtype eq 'pickaxe') {
6786                 # pickaxe may take all resources of your box and run for several minutes
6787                 # with every query - so decide by yourself how public you make this feature
6788                 gitweb_check_feature('pickaxe')
6789                     or die_error(403, "Pickaxe is disabled");
6790         }
6791         if ($searchtype eq 'grep') {
6792                 gitweb_check_feature('grep')
6793                     or die_error(403, "Grep is disabled");
6794         }
6795
6796         git_header_html();
6797
6798         if ($searchtype eq 'commit' or $searchtype eq 'author' or $searchtype eq 'committer') {
6799                 my $greptype;
6800                 if ($searchtype eq 'commit') {
6801                         $greptype = "--grep=";
6802                 } elsif ($searchtype eq 'author') {
6803                         $greptype = "--author=";
6804                 } elsif ($searchtype eq 'committer') {
6805                         $greptype = "--committer=";
6806                 }
6807                 $greptype .= $searchtext;
6808                 my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
6809                                                $greptype, '--regexp-ignore-case',
6810                                                $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
6811
6812                 my $paging_nav = '';
6813                 if ($page > 0) {
6814                         $paging_nav .=
6815                                 $cgi->a({-href => href(action=>"search", hash=>$hash,
6816                                                        searchtext=>$searchtext,
6817                                                        searchtype=>$searchtype)},
6818                                         "first");
6819                         $paging_nav .= " &sdot; " .
6820                                 $cgi->a({-href => href(-replay=>1, page=>$page-1),
6821                                          -accesskey => "p", -title => "Alt-p"}, "prev");
6822                 } else {
6823                         $paging_nav .= "first";
6824                         $paging_nav .= " &sdot; prev";
6825                 }
6826                 my $next_link = '';
6827                 if ($#commitlist >= 100) {
6828                         $next_link =
6829                                 $cgi->a({-href => href(-replay=>1, page=>$page+1),
6830                                          -accesskey => "n", -title => "Alt-n"}, "next");
6831                         $paging_nav .= " &sdot; $next_link";
6832                 } else {
6833                         $paging_nav .= " &sdot; next";
6834                 }
6835
6836                 git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
6837                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
6838                 if ($page == 0 && !@commitlist) {
6839                         print "<p>No match.</p>\n";
6840                 } else {
6841                         git_search_grep_body(\@commitlist, 0, 99, $next_link);
6842                 }
6843         }
6844
6845         if ($searchtype eq 'pickaxe') {
6846                 git_print_page_nav('','', $hash,$co{'tree'},$hash);
6847                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
6848
6849                 print "<table class=\"pickaxe search\">\n";
6850                 my $alternate = 1;
6851                 local $/ = "\n";
6852                 open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
6853                         '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
6854                         ($search_use_regexp ? '--pickaxe-regex' : ());
6855                 undef %co;
6856                 my @files;
6857                 while (my $line = <$fd>) {
6858                         chomp $line;
6859                         next unless $line;
6860
6861                         my %set = parse_difftree_raw_line($line);
6862                         if (defined $set{'commit'}) {
6863                                 # finish previous commit
6864                                 if (%co) {
6865                                         print "</td>\n" .
6866                                               "<td class=\"link\">" .
6867                                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6868                                               " | " .
6869                                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6870                                         print "</td>\n" .
6871                                               "</tr>\n";
6872                                 }
6873
6874                                 if ($alternate) {
6875                                         print "<tr class=\"dark\">\n";
6876                                 } else {
6877                                         print "<tr class=\"light\">\n";
6878                                 }
6879                                 $alternate ^= 1;
6880                                 %co = parse_commit($set{'commit'});
6881                                 my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
6882                                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6883                                       "<td><i>$author</i></td>\n" .
6884                                       "<td>" .
6885                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6886                                               -class => "list subject"},
6887                                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
6888                         } elsif (defined $set{'to_id'}) {
6889                                 next if ($set{'to_id'} =~ m/^0{40}$/);
6890
6891                                 print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
6892                                                              hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
6893                                               -class => "list"},
6894                                               "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
6895                                       "<br/>\n";
6896                         }
6897                 }
6898                 close $fd;
6899
6900                 # finish last commit (warning: repetition!)
6901                 if (%co) {
6902                         print "</td>\n" .
6903                               "<td class=\"link\">" .
6904                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6905                               " | " .
6906                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6907                         print "</td>\n" .
6908                               "</tr>\n";
6909                 }
6910
6911                 print "</table>\n";
6912         }
6913
6914         if ($searchtype eq 'grep') {
6915                 git_print_page_nav('','', $hash,$co{'tree'},$hash);
6916                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
6917
6918                 print "<table class=\"grep_search\">\n";
6919                 my $alternate = 1;
6920                 my $matches = 0;
6921                 local $/ = "\n";
6922                 open my $fd, "-|", git_cmd(), 'grep', '-n',
6923                         $search_use_regexp ? ('-E', '-i') : '-F',
6924                         $searchtext, $co{'tree'};
6925                 my $lastfile = '';
6926                 while (my $line = <$fd>) {
6927                         chomp $line;
6928                         my ($file, $lno, $ltext, $binary);
6929                         last if ($matches++ > 1000);
6930                         if ($line =~ /^Binary file (.+) matches$/) {
6931                                 $file = $1;
6932                                 $binary = 1;
6933                         } else {
6934                                 (undef, $file, $lno, $ltext) = split(/:/, $line, 4);
6935                         }
6936                         if ($file ne $lastfile) {
6937                                 $lastfile and print "</td></tr>\n";
6938                                 if ($alternate++) {
6939                                         print "<tr class=\"dark\">\n";
6940                                 } else {
6941                                         print "<tr class=\"light\">\n";
6942                                 }
6943                                 print "<td class=\"list\">".
6944                                         $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
6945                                                                file_name=>"$file"),
6946                                                 -class => "list"}, esc_path($file));
6947                                 print "</td><td>\n";
6948                                 $lastfile = $file;
6949                         }
6950                         if ($binary) {
6951                                 print "<div class=\"binary\">Binary file</div>\n";
6952                         } else {
6953                                 $ltext = untabify($ltext);
6954                                 if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
6955                                         $ltext = esc_html($1, -nbsp=>1);
6956                                         $ltext .= '<span class="match">';
6957                                         $ltext .= esc_html($2, -nbsp=>1);
6958                                         $ltext .= '</span>';
6959                                         $ltext .= esc_html($3, -nbsp=>1);
6960                                 } else {
6961                                         $ltext = esc_html($ltext, -nbsp=>1);
6962                                 }
6963                                 print "<div class=\"pre\">" .
6964                                         $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
6965                                                                file_name=>"$file").'#l'.$lno,
6966                                                 -class => "linenr"}, sprintf('%4i', $lno))
6967                                         . ' ' .  $ltext . "</div>\n";
6968                         }
6969                 }
6970                 if ($lastfile) {
6971                         print "</td></tr>\n";
6972                         if ($matches > 1000) {
6973                                 print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
6974                         }
6975                 } else {
6976                         print "<div class=\"diff nodifferences\">No matches found</div>\n";
6977                 }
6978                 close $fd;
6979
6980                 print "</table>\n";
6981         }
6982         git_footer_html();
6983 }
6984
6985 sub git_search_help {
6986         git_header_html();
6987         git_print_page_nav('','', $hash,$hash,$hash);
6988         print <<EOT;
6989 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
6990 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
6991 the pattern entered is recognized as the POSIX extended
6992 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
6993 insensitive).</p>
6994 <dl>
6995 <dt><b>commit</b></dt>
6996 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
6997 EOT
6998         my $have_grep = gitweb_check_feature('grep');
6999         if ($have_grep) {
7000                 print <<EOT;
7001 <dt><b>grep</b></dt>
7002 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
7003     a different one) are searched for the given pattern. On large trees, this search can take
7004 a while and put some strain on the server, so please use it with some consideration. Note that
7005 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
7006 case-sensitive.</dd>
7007 EOT
7008         }
7009         print <<EOT;
7010 <dt><b>author</b></dt>
7011 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
7012 <dt><b>committer</b></dt>
7013 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
7014 EOT
7015         my $have_pickaxe = gitweb_check_feature('pickaxe');
7016         if ($have_pickaxe) {
7017                 print <<EOT;
7018 <dt><b>pickaxe</b></dt>
7019 <dd>All commits that caused the string to appear or disappear from any file (changes that
7020 added, removed or "modified" the string) will be listed. This search can take a while and
7021 takes a lot of strain on the server, so please use it wisely. Note that since you may be
7022 interested even in changes just changing the case as well, this search is case sensitive.</dd>
7023 EOT
7024         }
7025         print "</dl>\n";
7026         git_footer_html();
7027 }
7028
7029 sub git_shortlog {
7030         git_log_generic('shortlog', \&git_shortlog_body,
7031                         $hash, $hash_parent);
7032 }
7033
7034 ## ......................................................................
7035 ## feeds (RSS, Atom; OPML)
7036
7037 sub git_feed {
7038         my $format = shift || 'atom';
7039         my $have_blame = gitweb_check_feature('blame');
7040
7041         # Atom: http://www.atomenabled.org/developers/syndication/
7042         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
7043         if ($format ne 'rss' && $format ne 'atom') {
7044                 die_error(400, "Unknown web feed format");
7045         }
7046
7047         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
7048         my $head = $hash || 'HEAD';
7049         my @commitlist = parse_commits($head, 150, 0, $file_name);
7050
7051         my %latest_commit;
7052         my %latest_date;
7053         my $content_type = "application/$format+xml";
7054         if (defined $cgi->http('HTTP_ACCEPT') &&
7055                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
7056                 # browser (feed reader) prefers text/xml
7057                 $content_type = 'text/xml';
7058         }
7059         if (defined($commitlist[0])) {
7060                 %latest_commit = %{$commitlist[0]};
7061                 my $latest_epoch = $latest_commit{'committer_epoch'};
7062                 %latest_date   = parse_date($latest_epoch);
7063                 my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7064                 if (defined $if_modified) {
7065                         my $since;
7066                         if (eval { require HTTP::Date; 1; }) {
7067                                 $since = HTTP::Date::str2time($if_modified);
7068                         } elsif (eval { require Time::ParseDate; 1; }) {
7069                                 $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7070                         }
7071                         if (defined $since && $latest_epoch <= $since) {
7072                                 print $cgi->header(
7073                                         -type => $content_type,
7074                                         -charset => 'utf-8',
7075                                         -last_modified => $latest_date{'rfc2822'},
7076                                         -status => '304 Not Modified');
7077                                 return;
7078                         }
7079                 }
7080                 print $cgi->header(
7081                         -type => $content_type,
7082                         -charset => 'utf-8',
7083                         -last_modified => $latest_date{'rfc2822'});
7084         } else {
7085                 print $cgi->header(
7086                         -type => $content_type,
7087                         -charset => 'utf-8');
7088         }
7089
7090         # Optimization: skip generating the body if client asks only
7091         # for Last-Modified date.
7092         return if ($cgi->request_method() eq 'HEAD');
7093
7094         # header variables
7095         my $title = "$site_name - $project/$action";
7096         my $feed_type = 'log';
7097         if (defined $hash) {
7098                 $title .= " - '$hash'";
7099                 $feed_type = 'branch log';
7100                 if (defined $file_name) {
7101                         $title .= " :: $file_name";
7102                         $feed_type = 'history';
7103                 }
7104         } elsif (defined $file_name) {
7105                 $title .= " - $file_name";
7106                 $feed_type = 'history';
7107         }
7108         $title .= " $feed_type";
7109         my $descr = git_get_project_description($project);
7110         if (defined $descr) {
7111                 $descr = esc_html($descr);
7112         } else {
7113                 $descr = "$project " .
7114                          ($format eq 'rss' ? 'RSS' : 'Atom') .
7115                          " feed";
7116         }
7117         my $owner = git_get_project_owner($project);
7118         $owner = esc_html($owner);
7119
7120         #header
7121         my $alt_url;
7122         if (defined $file_name) {
7123                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
7124         } elsif (defined $hash) {
7125                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
7126         } else {
7127                 $alt_url = href(-full=>1, action=>"summary");
7128         }
7129         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
7130         if ($format eq 'rss') {
7131                 print <<XML;
7132 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
7133 <channel>
7134 XML
7135                 print "<title>$title</title>\n" .
7136                       "<link>$alt_url</link>\n" .
7137                       "<description>$descr</description>\n" .
7138                       "<language>en</language>\n" .
7139                       # project owner is responsible for 'editorial' content
7140                       "<managingEditor>$owner</managingEditor>\n";
7141                 if (defined $logo || defined $favicon) {
7142                         # prefer the logo to the favicon, since RSS
7143                         # doesn't allow both
7144                         my $img = esc_url($logo || $favicon);
7145                         print "<image>\n" .
7146                               "<url>$img</url>\n" .
7147                               "<title>$title</title>\n" .
7148                               "<link>$alt_url</link>\n" .
7149                               "</image>\n";
7150                 }
7151                 if (%latest_date) {
7152                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
7153                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
7154                 }
7155                 print "<generator>gitweb v.$version/$git_version</generator>\n";
7156         } elsif ($format eq 'atom') {
7157                 print <<XML;
7158 <feed xmlns="http://www.w3.org/2005/Atom">
7159 XML
7160                 print "<title>$title</title>\n" .
7161                       "<subtitle>$descr</subtitle>\n" .
7162                       '<link rel="alternate" type="text/html" href="' .
7163                       $alt_url . '" />' . "\n" .
7164                       '<link rel="self" type="' . $content_type . '" href="' .
7165                       $cgi->self_url() . '" />' . "\n" .
7166                       "<id>" . href(-full=>1) . "</id>\n" .
7167                       # use project owner for feed author
7168                       "<author><name>$owner</name></author>\n";
7169                 if (defined $favicon) {
7170                         print "<icon>" . esc_url($favicon) . "</icon>\n";
7171                 }
7172                 if (defined $logo_url) {
7173                         # not twice as wide as tall: 72 x 27 pixels
7174                         print "<logo>" . esc_url($logo) . "</logo>\n";
7175                 }
7176                 if (! %latest_date) {
7177                         # dummy date to keep the feed valid until commits trickle in:
7178                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
7179                 } else {
7180                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
7181                 }
7182                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
7183         }
7184
7185         # contents
7186         for (my $i = 0; $i <= $#commitlist; $i++) {
7187                 my %co = %{$commitlist[$i]};
7188                 my $commit = $co{'id'};
7189                 # we read 150, we always show 30 and the ones more recent than 48 hours
7190                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
7191                         last;
7192                 }
7193                 my %cd = parse_date($co{'author_epoch'});
7194
7195                 # get list of changed files
7196                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7197                         $co{'parent'} || "--root",
7198                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
7199                         or next;
7200                 my @difftree = map { chomp; $_ } <$fd>;
7201                 close $fd
7202                         or next;
7203
7204                 # print element (entry, item)
7205                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
7206                 if ($format eq 'rss') {
7207                         print "<item>\n" .
7208                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
7209                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
7210                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
7211                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
7212                               "<link>$co_url</link>\n" .
7213                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
7214                               "<content:encoded>" .
7215                               "<![CDATA[\n";
7216                 } elsif ($format eq 'atom') {
7217                         print "<entry>\n" .
7218                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
7219                               "<updated>$cd{'iso-8601'}</updated>\n" .
7220                               "<author>\n" .
7221                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
7222                         if ($co{'author_email'}) {
7223                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
7224                         }
7225                         print "</author>\n" .
7226                               # use committer for contributor
7227                               "<contributor>\n" .
7228                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
7229                         if ($co{'committer_email'}) {
7230                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
7231                         }
7232                         print "</contributor>\n" .
7233                               "<published>$cd{'iso-8601'}</published>\n" .
7234                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
7235                               "<id>$co_url</id>\n" .
7236                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
7237                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
7238                 }
7239                 my $comment = $co{'comment'};
7240                 print "<pre>\n";
7241                 foreach my $line (@$comment) {
7242                         $line = esc_html($line);
7243                         print "$line\n";
7244                 }
7245                 print "</pre><ul>\n";
7246                 foreach my $difftree_line (@difftree) {
7247                         my %difftree = parse_difftree_raw_line($difftree_line);
7248                         next if !$difftree{'from_id'};
7249
7250                         my $file = $difftree{'file'} || $difftree{'to_file'};
7251
7252                         print "<li>" .
7253                               "[" .
7254                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
7255                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
7256                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
7257                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
7258                                       -title => "diff"}, 'D');
7259                         if ($have_blame) {
7260                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
7261                                                              file_name=>$file, hash_base=>$commit),
7262                                               -title => "blame"}, 'B');
7263                         }
7264                         # if this is not a feed of a file history
7265                         if (!defined $file_name || $file_name ne $file) {
7266                                 print $cgi->a({-href => href(-full=>1, action=>"history",
7267                                                              file_name=>$file, hash=>$commit),
7268                                               -title => "history"}, 'H');
7269                         }
7270                         $file = esc_path($file);
7271                         print "] ".
7272                               "$file</li>\n";
7273                 }
7274                 if ($format eq 'rss') {
7275                         print "</ul>]]>\n" .
7276                               "</content:encoded>\n" .
7277                               "</item>\n";
7278                 } elsif ($format eq 'atom') {
7279                         print "</ul>\n</div>\n" .
7280                               "</content>\n" .
7281                               "</entry>\n";
7282                 }
7283         }
7284
7285         # end of feed
7286         if ($format eq 'rss') {
7287                 print "</channel>\n</rss>\n";
7288         } elsif ($format eq 'atom') {
7289                 print "</feed>\n";
7290         }
7291 }
7292
7293 sub git_rss {
7294         git_feed('rss');
7295 }
7296
7297 sub git_atom {
7298         git_feed('atom');
7299 }
7300
7301 sub git_opml {
7302         my @list = git_get_projects_list();
7303
7304         print $cgi->header(
7305                 -type => 'text/xml',
7306                 -charset => 'utf-8',
7307                 -content_disposition => 'inline; filename="opml.xml"');
7308
7309         print <<XML;
7310 <?xml version="1.0" encoding="utf-8"?>
7311 <opml version="1.0">
7312 <head>
7313   <title>$site_name OPML Export</title>
7314 </head>
7315 <body>
7316 <outline text="git RSS feeds">
7317 XML
7318
7319         foreach my $pr (@list) {
7320                 my %proj = %$pr;
7321                 my $head = git_get_head_hash($proj{'path'});
7322                 if (!defined $head) {
7323                         next;
7324                 }
7325                 $git_dir = "$projectroot/$proj{'path'}";
7326                 my %co = parse_commit($head);
7327                 if (!%co) {
7328                         next;
7329                 }
7330
7331                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
7332                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
7333                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
7334                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
7335         }
7336         print <<XML;
7337 </outline>
7338 </body>
7339 </opml>
7340 XML
7341 }