git.oblomov.eu Git - git/blob - git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use warnings;
   5 use strict;
   6 use vars qw/    $AUTHOR $VERSION
   7                 $SVN_URL
   8                 $GIT_SVN_INDEX $GIT_SVN
   9                 $GIT_DIR $GIT_SVN_DIR $REVDB
  10                 $_follow_parent $sha1 $sha1_short $_revision
  11                 $_cp_remote $_upgrade $_rmdir $_q $_cp_similarity
  12                 $_find_copies_harder $_l $_authors %users/;
  13 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  14 $VERSION = '@@GIT_VERSION@@';
  15
  16 $ENV{GIT_DIR} ||= '.git';
  17 $Git::SVN::default_repo_id = 'git-svn';
  18 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  19
  20 my $LC_ALL = $ENV{LC_ALL};
  21 $Git::SVN::Log::TZ = $ENV{TZ};
  22 # make sure the svn binary gives consistent output between locales and TZs:
  23 $ENV{TZ} = 'UTC';
  24 $ENV{LC_ALL} = 'C';
  25 $| = 1; # unbuffer STDOUT
  26
  27 sub fatal (@) { print STDERR @_; exit 1 }
  28 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  29 require SVN::Ra;
  30 require SVN::Delta;
  31 if ($SVN::Core::VERSION lt '1.1.0') {
  32         fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)\n";
  33 }
  34 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  35 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  36 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  37 use Carp qw/croak/;
  38 use IO::File qw//;
  39 use File::Basename qw/dirname basename/;
  40 use File::Path qw/mkpath/;
  41 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev pass_through/;
  42 use IPC::Open3;
  43 use Git;
  44
  45 BEGIN {
  46         my $s;
  47         foreach (qw/command command_oneline command_noisy command_output_pipe
  48                     command_input_pipe command_close_pipe/) {
  49                 $s .= "*SVN::Git::Editor::$_ = *SVN::Git::Fetcher::$_ = ".
  50                       "*Git::SVN::Migration::$_ = ".
  51                       "*Git::SVN::Log::$_ = *Git::SVN::$_ = *$_ = *Git::$_; ";
  52         }
  53         eval $s;
  54 }
  55
  56 my ($SVN);
  57
  58 my $_optimize_commits = 1 unless $ENV{GIT_SVN_NO_OPTIMIZE_COMMITS};
  59 $sha1 = qr/[a-f\d]{40}/;
  60 $sha1_short = qr/[a-f\d]{4,40}/;
  61 my ($_stdin, $_help, $_edit,
  62         $_repack, $_repack_nr, $_repack_flags,
  63         $_message, $_file, $_no_metadata,
  64         $_template, $_shared,
  65         $_version, $_upgrade,
  66         $_merge, $_strategy, $_dry_run,
  67         $_prefix);
  68
  69 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  70                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  71                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
  72 my %fc_opts = ( 'follow-parent|follow' => \$_follow_parent,
  73                 'authors-file|A=s' => \$_authors,
  74                 'repack:i' => \$_repack,
  75                 'no-metadata' => \$_no_metadata,
  76                 'quiet|q' => \$_q,
  77                 'repack-flags|repack-args|repack-opts=s' => \$_repack_flags,
  78                 %remote_opts );
  79
  80 my ($_trunk, $_tags, $_branches);
  81 my %multi_opts = ( 'trunk|T=s' => \$_trunk,
  82                 'tags|t=s' => \$_tags,
  83                 'branches|b=s' => \$_branches );
  84 my %init_opts = ( 'template=s' => \$_template, 'shared' => \$_shared );
  85 my %cmt_opts = ( 'edit|e' => \$_edit,
  86                 'rmdir' => \$_rmdir,
  87                 'find-copies-harder' => \$_find_copies_harder,
  88                 'l=i' => \$_l,
  89                 'copy-similarity|C=i'=> \$_cp_similarity
  90 );
  91
  92 my %cmd = (
  93         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
  94                         { 'revision|r=s' => \$_revision, %fc_opts } ],
  95         init => [ \&cmd_init, "Initialize a repo for tracking" .
  96                           " (requires URL argument)",
  97                           \%init_opts ],
  98         dcommit => [ \&cmd_dcommit,
  99                      'Commit several diffs to merge with upstream',
 100                         { 'merge|m|M' => \$_merge,
 101                           'strategy|s=s' => \$_strategy,
 102                           'dry-run|n' => \$_dry_run,
 103                         %cmt_opts, %fc_opts } ],
 104         'set-tree' => [ \&cmd_set_tree,
 105                         "Set an SVN repository to a git tree-ish",
 106                         { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
 107         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 108                         { 'revision|r=i' => \$_revision } ],
 109         rebuild => [ \&cmd_rebuild, "Rebuild git-svn metadata (after git clone)",
 110                         { 'copy-remote|remote=s' => \$_cp_remote,
 111                           'upgrade' => \$_upgrade } ],
 112         'multi-init' => [ \&cmd_multi_init,
 113                         'Initialize multiple trees (like git-svnimport)',
 114                         { %multi_opts, %init_opts, %remote_opts,
 115                          'revision|r=i' => \$_revision,
 116                          'prefix=s' => \$_prefix,
 117                         } ],
 118         'multi-fetch' => [ \&cmd_multi_fetch,
 119                         'Fetch multiple trees (like git-svnimport)',
 120                         \%fc_opts ],
 121         'migrate' => [ sub { },
 122                        # no-op, we automatically run this anyways,
 123                        'Migrate configuration/metadata/layout from
 124                         previous versions of git-svn',
 125                         \%remote_opts ],
 126         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 127                         { 'limit=i' => \$Git::SVN::Log::limit,
 128                           'revision|r=s' => \$_revision,
 129                           'verbose|v' => \$Git::SVN::Log::verbose,
 130                           'incremental' => \$Git::SVN::Log::incremental,
 131                           'oneline' => \$Git::SVN::Log::oneline,
 132                           'show-commit' => \$Git::SVN::Log::show_commit,
 133                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 134                           'authors-file|A=s' => \$_authors,
 135                           'color' => \$Git::SVN::Log::color,
 136                           'pager=s' => \$Git::SVN::Log::pager,
 137                         } ],
 138         'commit-diff' => [ \&cmd_commit_diff,
 139                            'Commit a diff between two trees',
 140                         { 'message|m=s' => \$_message,
 141                           'file|F=s' => \$_file,
 142                           'revision|r=s' => \$_revision,
 143                         %cmt_opts } ],
 144 );
 145
 146 my $cmd;
 147 for (my $i = 0; $i < @ARGV; $i++) {
 148         if (defined $cmd{$ARGV[$i]}) {
 149                 $cmd = $ARGV[$i];
 150                 splice @ARGV, $i, 1;
 151                 last;
 152         }
 153 };
 154
 155 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 156
 157 read_repo_config(\%opts);
 158 my $rv = GetOptions(%opts, 'help|H|h' => \$_help,
 159                                 'version|V' => \$_version,
 160                                 'minimize-connections' =>
 161                                   \$Git::SVN::Migration::_minimize,
 162                                 'id|i=s' => \$Git::SVN::default_ref_id);
 163 exit 1 if (!$rv && $cmd ne 'log');
 164
 165 usage(0) if $_help;
 166 version() if $_version;
 167 usage(1) unless defined $cmd;
 168 load_authors() if $_authors;
 169 unless ($cmd =~ /^(?:init|rebuild|multi-init|commit-diff)$/) {
 170         Git::SVN::Migration::migration_check();
 171 }
 172 eval {
 173         Git::SVN::verify_remotes_sanity();
 174         $cmd{$cmd}->[0]->(@ARGV);
 175 };
 176 fatal $@ if $@;
 177 exit 0;
 178
 179 ####################### primary functions ######################
 180 sub usage {
 181         my $exit = shift || 0;
 182         my $fd = $exit ? \*STDERR : \*STDOUT;
 183         print $fd <<"";
 184 git-svn - bidirectional operations between a single Subversion tree and git
 185 Usage: $0 <command> [options] [arguments]\n
 186
 187         print $fd "Available commands:\n" unless $cmd;
 188
 189         foreach (sort keys %cmd) {
 190                 next if $cmd && $cmd ne $_;
 191                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 192                 foreach (keys %{$cmd{$_}->[2]}) {
 193                         # prints out arguments as they should be passed:
 194                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 195                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 196                                                         "--$_" : "-$_" }
 197                                                 split /\|/,$_)," $x\n";
 198                 }
 199         }
 200         print $fd <<"";
 201 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 202 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 203 one git repository and want to keep them separate.  See git-svn(1) for more
 204 information.
 205
 206         exit $exit;
 207 }
 208
 209 sub version {
 210         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 211         exit 0;
 212 }
 213
 214 sub cmd_rebuild {
 215         my $url = shift;
 216         my $gs = $url ? Git::SVN->init($url)
 217                       : eval { Git::SVN->new };
 218         $gs ||= Git::SVN->_new;
 219         if (!verify_ref($gs->refname.'^0')) {
 220                 $gs->copy_remote_ref;
 221         }
 222
 223         my ($rev_list, $ctx) = command_output_pipe("rev-list", $gs->refname);
 224         my $latest;
 225         my $svn_uuid;
 226         while (<$rev_list>) {
 227                 chomp;
 228                 my $c = $_;
 229                 fatal "Non-SHA1: $c\n" unless $c =~ /^$sha1$/o;
 230                 my ($url, $rev, $uuid) = cmt_metadata($c);
 231
 232                 # ignore merges (from set-tree)
 233                 next if (!defined $rev || !$uuid);
 234
 235                 # if we merged or otherwise started elsewhere, this is
 236                 # how we break out of it
 237                 if ((defined $svn_uuid && ($uuid ne $svn_uuid)) ||
 238                     ($gs->{url} && $url && ($url ne $gs->{url}))) {
 239                         next;
 240                 }
 241
 242                 unless (defined $latest) {
 243                         if (!$gs->{url} && !$url) {
 244                                 fatal "SVN repository location required\n";
 245                         }
 246                         $gs = Git::SVN->init($url);
 247                         $latest = $rev;
 248                 }
 249                 $gs->rev_db_set($rev, $c);
 250                 print "r$rev = $c\n";
 251         }
 252         command_close_pipe($rev_list, $ctx);
 253 }
 254
 255 sub do_git_init_db {
 256         unless (-d $ENV{GIT_DIR}) {
 257                 my @init_db = ('init');
 258                 push @init_db, "--template=$_template" if defined $_template;
 259                 push @init_db, "--shared" if defined $_shared;
 260                 command_noisy(@init_db);
 261         }
 262 }
 263
 264 sub cmd_init {
 265         my $url = shift or die "SVN repository location required " .
 266                                 "as a command-line argument\n";
 267         if (my $repo_path = shift) {
 268                 unless (-d $repo_path) {
 269                         mkpath([$repo_path]);
 270                 }
 271                 chdir $repo_path or croak $!;
 272                 $ENV{GIT_DIR} = $repo_path . "/.git";
 273         }
 274         do_git_init_db();
 275
 276         Git::SVN->init($url);
 277 }
 278
 279 sub cmd_fetch {
 280         if (@_) {
 281                 die "Additional fetch arguments are no longer supported.\n",
 282                     "Use --follow-parent if you have moved/copied directories
 283                     instead.\n";
 284         }
 285         my $gs = Git::SVN->new;
 286         $gs->fetch;
 287         if ($gs->{last_commit} && !verify_ref('refs/heads/master^0')) {
 288                 command_noisy(qw(update-ref refs/heads/master),
 289                               $gs->{last_commit});
 290         }
 291 }
 292
 293 sub cmd_set_tree {
 294         my (@commits) = @_;
 295         if ($_stdin || !@commits) {
 296                 print "Reading from stdin...\n";
 297                 @commits = ();
 298                 while (<STDIN>) {
 299                         if (/\b($sha1_short)\b/o) {
 300                                 unshift @commits, $1;
 301                         }
 302                 }
 303         }
 304         my @revs;
 305         foreach my $c (@commits) {
 306                 my @tmp = command('rev-parse',$c);
 307                 if (scalar @tmp == 1) {
 308                         push @revs, $tmp[0];
 309                 } elsif (scalar @tmp > 1) {
 310                         push @revs, reverse(command('rev-list',@tmp));
 311                 } else {
 312                         fatal "Failed to rev-parse $c\n";
 313                 }
 314         }
 315         my $gs = Git::SVN->new;
 316         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 317         $gs->fetch;
 318         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 319                 fatal "There are new revisions that were fetched ",
 320                       "and need to be merged (or acknowledged) ",
 321                       "before committing.\nlast rev: $r_last\n",
 322                       " current: $gs->{last_rev}\n";
 323         }
 324         $gs->set_tree($_) foreach @revs;
 325         print "Done committing ",scalar @revs," revisions to SVN\n";
 326 }
 327
 328 sub cmd_dcommit {
 329         my $head = shift;
 330         my $gs = Git::SVN->new;
 331         $head ||= 'HEAD';
 332         my @refs = command(qw/rev-list --no-merges/, $gs->refname."..$head");
 333         my $last_rev;
 334         foreach my $d (reverse @refs) {
 335                 if (!verify_ref("$d~1")) {
 336                         fatal "Commit $d\n",
 337                               "has no parent commit, and therefore ",
 338                               "nothing to diff against.\n",
 339                               "You should be working from a repository ",
 340                               "originally created by git-svn\n";
 341                 }
 342                 unless (defined $last_rev) {
 343                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 344                         unless (defined $last_rev) {
 345                                 fatal "Unable to extract revision information ",
 346                                       "from commit $d~1\n";
 347                         }
 348                 }
 349                 if ($_dry_run) {
 350                         print "diff-tree $d~1 $d\n";
 351                 } else {
 352                         my $log = get_commit_entry($d)->{log};
 353                         my $ra = $gs->ra;
 354                         my $pool = SVN::Pool->new;
 355                         my %ed_opts = ( r => $last_rev,
 356                                         ra => $ra->dup,
 357                                         svn_path => $ra->{svn_path} );
 358                         my $ed = SVN::Git::Editor->new(\%ed_opts,
 359                                          $ra->get_commit_editor($log,
 360                                          sub { print "Committed r$_[0]\n";
 361                                                $last_rev = $_[0]; }),
 362                                          $pool);
 363                         my $mods = $ed->apply_diff("$d~1", $d);
 364                         if (@$mods == 0) {
 365                                 print "No changes\n$d~1 == $d\n";
 366                         }
 367                 }
 368         }
 369         return if $_dry_run;
 370         $gs->fetch;
 371         # we always want to rebase against the current HEAD, not any
 372         # head that was passed to us
 373         my @diff = command('diff-tree', 'HEAD', $gs->refname, '--');
 374         my @finish;
 375         if (@diff) {
 376                 @finish = qw/rebase/;
 377                 push @finish, qw/--merge/ if $_merge;
 378                 push @finish, "--strategy=$_strategy" if $_strategy;
 379                 print STDERR "W: HEAD and ", $gs->refname, " differ, ",
 380                              "using @finish:\n", "@diff";
 381         } else {
 382                 print "No changes between current HEAD and ",
 383                       $gs->refname, "\nResetting to the latest ",
 384                       $gs->refname, "\n";
 385                 @finish = qw/reset --mixed/;
 386         }
 387         command_noisy(@finish, $gs->refname);
 388 }
 389
 390 sub cmd_show_ignore {
 391         my $gs = Git::SVN->new;
 392         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 393         $gs->traverse_ignore(\*STDOUT, '', $r);
 394 }
 395
 396 sub cmd_multi_init {
 397         my $url = shift;
 398         unless (defined $_trunk || defined $_branches || defined $_tags) {
 399                 usage(1);
 400         }
 401         do_git_init_db();
 402         $_prefix = '' unless defined $_prefix;
 403         $url =~ s#/+$## if defined $url;
 404         if (defined $_trunk) {
 405                 my $trunk_ref = $_prefix . 'trunk';
 406                 # try both old-style and new-style lookups:
 407                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 408                 unless ($gs_trunk) {
 409                         my ($trunk_url, $trunk_path) =
 410                                               complete_svn_url($url, $_trunk);
 411                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 412                                                    undef, $trunk_ref);
 413                 }
 414         }
 415         return unless defined $_branches || defined $_tags;
 416         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 417         complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
 418         complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
 419 }
 420
 421 sub cmd_multi_fetch {
 422         my @gs;
 423         foreach (command(qw/config -l/)) {
 424                 next unless m!^svn-remote\.(.+)\.fetch=
 425                               \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
 426                 my ($repo_id, $path, $ref_id) = ($1, $2, $3);
 427                 push @gs, Git::SVN->new($ref_id, $repo_id, $path);
 428         }
 429         foreach (@gs) {
 430                 $_->fetch;
 431         }
 432 }
 433
 434 # this command is special because it requires no metadata
 435 sub cmd_commit_diff {
 436         my ($ta, $tb, $url) = @_;
 437         my $usage = "Usage: $0 commit-diff -r<revision> ".
 438                     "<tree-ish> <tree-ish> [<URL>]\n";
 439         fatal($usage) if (!defined $ta || !defined $tb);
 440         if (!defined $url) {
 441                 my $gs = eval { Git::SVN->new };
 442                 if (!$gs) {
 443                         fatal("Needed URL or usable git-svn --id in ",
 444                               "the command-line\n", $usage);
 445                 }
 446                 $url = $gs->{url};
 447         }
 448         unless (defined $_revision) {
 449                 fatal("-r|--revision is a required argument\n", $usage);
 450         }
 451         if (defined $_message && defined $_file) {
 452                 fatal("Both --message/-m and --file/-F specified ",
 453                       "for the commit message.\n",
 454                       "I have no idea what you mean\n");
 455         }
 456         if (defined $_file) {
 457                 $_message = file_to_s($_file);
 458         } else {
 459                 $_message ||= get_commit_entry($tb)->{log};
 460         }
 461         my $ra ||= Git::SVN::Ra->new($url);
 462         my $r = $_revision;
 463         if ($r eq 'HEAD') {
 464                 $r = $ra->get_latest_revnum;
 465         } elsif ($r !~ /^\d+$/) {
 466                 die "revision argument: $r not understood by git-svn\n";
 467         }
 468         my $pool = SVN::Pool->new;
 469         my %ed_opts = ( r => $r,
 470                         ra => $ra->dup,
 471                         svn_path => $ra->{svn_path} );
 472         my $ed = SVN::Git::Editor->new(\%ed_opts,
 473                                        $ra->get_commit_editor($_message,
 474                                          sub { print "Committed r$_[0]\n" }),
 475                                        $pool);
 476         my $mods = $ed->apply_diff($ta, $tb);
 477         if (@$mods == 0) {
 478                 print "No changes\n$ta == $tb\n";
 479         }
 480         $pool->clear;
 481 }
 482
 483 ########################### utility functions #########################
 484
 485 sub complete_svn_url {
 486         my ($url, $path) = @_;
 487         $path =~ s#/+$##;
 488         if ($path !~ m#^[a-z\+]+://#) {
 489                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
 490                         fatal("E: '$path' is not a complete URL ",
 491                               "and a separate URL is not specified\n");
 492                 }
 493                 return ($url, $path);
 494         }
 495         return ($path, '');
 496 }
 497
 498 sub complete_url_ls_init {
 499         my ($ra, $repo_path, $switch, $pfx) = @_;
 500         unless ($repo_path) {
 501                 print STDERR "W: $switch not specified\n";
 502                 return;
 503         }
 504         $repo_path =~ s#/+$##;
 505         if ($repo_path =~ m#^[a-z\+]+://#) {
 506                 $ra = Git::SVN::Ra->new($repo_path);
 507                 $repo_path = '';
 508         } else {
 509                 $repo_path =~ s#^/+##;
 510                 unless ($ra) {
 511                         fatal("E: '$repo_path' is not a complete URL ",
 512                               "and a separate URL is not specified\n");
 513                 }
 514         }
 515         my $r = defined $_revision ? $_revision : $ra->get_latest_revnum;
 516         my ($dirent, undef, undef) = $ra->get_dir($repo_path, $r);
 517         my $url = $ra->{url};
 518         foreach my $d (sort keys %$dirent) {
 519                 next if ($dirent->{$d}->kind != $SVN::Node::dir);
 520                 my $path =  "$repo_path/$d";
 521                 my $ref = "$pfx$d";
 522                 my $gs = eval { Git::SVN->new($ref) };
 523                 # don't try to init already existing refs
 524                 unless ($gs) {
 525                         print "init $url/$path => $ref\n";
 526                         Git::SVN->init($url, $path, undef, $ref);
 527                 }
 528         }
 529 }
 530
 531 sub verify_ref {
 532         my ($ref) = @_;
 533         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
 534                                { STDERR => 0 }); };
 535 }
 536
 537 sub get_tree_from_treeish {
 538         my ($treeish) = @_;
 539         # $treeish can be a symbolic ref, too:
 540         my $type = command_oneline(qw/cat-file -t/, $treeish);
 541         my $expected;
 542         while ($type eq 'tag') {
 543                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
 544         }
 545         if ($type eq 'commit') {
 546                 $expected = (grep /^tree /, command(qw/cat-file commit/,
 547                                                     $treeish))[0];
 548                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
 549                 die "Unable to get tree from $treeish\n" unless $expected;
 550         } elsif ($type eq 'tree') {
 551                 $expected = $treeish;
 552         } else {
 553                 die "$treeish is a $type, expected tree, tag or commit\n";
 554         }
 555         return $expected;
 556 }
 557
 558 sub get_commit_entry {
 559         my ($treeish) = shift;
 560         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
 561         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
 562         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
 563         open my $log_fh, '>', $commit_editmsg or croak $!;
 564
 565         my $type = command_oneline(qw/cat-file -t/, $treeish);
 566         if ($type eq 'commit' || $type eq 'tag') {
 567                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
 568                                                          $type, $treeish);
 569                 my $in_msg = 0;
 570                 while (<$msg_fh>) {
 571                         if (!$in_msg) {
 572                                 $in_msg = 1 if (/^\s*$/);
 573                         } elsif (/^git-svn-id: /) {
 574                                 # skip this for now, we regenerate the
 575                                 # correct one on re-fetch anyways
 576                                 # TODO: set *:merge properties or like...
 577                         } else {
 578                                 print $log_fh $_ or croak $!;
 579                         }
 580                 }
 581                 command_close_pipe($msg_fh, $ctx);
 582         }
 583         close $log_fh or croak $!;
 584
 585         if ($_edit || ($type eq 'tree')) {
 586                 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
 587                 # TODO: strip out spaces, comments, like git-commit.sh
 588                 system($editor, $commit_editmsg);
 589         }
 590         rename $commit_editmsg, $commit_msg or croak $!;
 591         open $log_fh, '<', $commit_msg or croak $!;
 592         { local $/; chomp($log_entry{log} = <$log_fh>); }
 593         close $log_fh or croak $!;
 594         unlink $commit_msg;
 595         \%log_entry;
 596 }
 597
 598 sub s_to_file {
 599         my ($str, $file, $mode) = @_;
 600         open my $fd,'>',$file or croak $!;
 601         print $fd $str,"\n" or croak $!;
 602         close $fd or croak $!;
 603         chmod ($mode &~ umask, $file) if (defined $mode);
 604 }
 605
 606 sub file_to_s {
 607         my $file = shift;
 608         open my $fd,'<',$file or croak "$!: file: $file\n";
 609         local $/;
 610         my $ret = <$fd>;
 611         close $fd or croak $!;
 612         $ret =~ s/\s*$//s;
 613         return $ret;
 614 }
 615
 616 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
 617 sub load_authors {
 618         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
 619         my $log = $cmd eq 'log';
 620         while (<$authors>) {
 621                 chomp;
 622                 next unless /^(\S+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
 623                 my ($user, $name, $email) = ($1, $2, $3);
 624                 if ($log) {
 625                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
 626                 } else {
 627                         $users{$user} = [$name, $email];
 628                 }
 629         }
 630         close $authors or croak $!;
 631 }
 632
 633 # convert GetOpt::Long specs for use by git-config
 634 sub read_repo_config {
 635         return unless -d $ENV{GIT_DIR};
 636         my $opts = shift;
 637         foreach my $o (keys %$opts) {
 638                 my $v = $opts->{$o};
 639                 my ($key) = ($o =~ /^([a-z\-]+)/);
 640                 $key =~ s/-//g;
 641                 my $arg = 'git-config';
 642                 $arg .= ' --int' if ($o =~ /[:=]i$/);
 643                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
 644                 if (ref $v eq 'ARRAY') {
 645                         chomp(my @tmp = `$arg --get-all svn.$key`);
 646                         @$v = @tmp if @tmp;
 647                 } else {
 648                         chomp(my $tmp = `$arg --get svn.$key`);
 649                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
 650                                 $$v = $tmp;
 651                         }
 652                 }
 653         }
 654 }
 655
 656 sub extract_metadata {
 657         my $id = shift or return (undef, undef, undef);
 658         my ($url, $rev, $uuid) = ($id =~ /^git-svn-id:\s(\S+?)\@(\d+)
 659                                                         \s([a-f\d\-]+)$/x);
 660         if (!defined $rev || !$uuid || !$url) {
 661                 # some of the original repositories I made had
 662                 # identifiers like this:
 663                 ($rev, $uuid) = ($id =~/^git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
 664         }
 665         return ($url, $rev, $uuid);
 666 }
 667
 668 sub cmt_metadata {
 669         return extract_metadata((grep(/^git-svn-id: /,
 670                 command(qw/cat-file commit/, shift)))[-1]);
 671 }
 672
 673 sub get_commit_time {
 674         my $cmt = shift;
 675         my $fh = command_output_pipe(qw/rev-list --pretty=raw -n1/, $cmt);
 676         while (<$fh>) {
 677                 /^committer\s(?:.+) (\d+) ([\-\+]?\d+)$/ or next;
 678                 my ($s, $tz) = ($1, $2);
 679                 if ($tz =~ s/^\+//) {
 680                         $s += tz_to_s_offset($tz);
 681                 } elsif ($tz =~ s/^\-//) {
 682                         $s -= tz_to_s_offset($tz);
 683                 }
 684                 close $fh;
 685                 return $s;
 686         }
 687         die "Can't get commit time for commit: $cmt\n";
 688 }
 689
 690 sub tz_to_s_offset {
 691         my ($tz) = @_;
 692         $tz =~ s/(\d\d)$//;
 693         return ($1 * 60) + ($tz * 3600);
 694 }
 695
 696 package Git::SVN;
 697 use strict;
 698 use warnings;
 699 use vars qw/$default_repo_id $default_ref_id/;
 700 use Carp qw/croak/;
 701 use File::Path qw/mkpath/;
 702 use IPC::Open3;
 703
 704 # properties that we do not log:
 705 my %SKIP_PROP;
 706 BEGIN {
 707         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
 708                                         svn:special svn:executable
 709                                         svn:entry:committed-rev
 710                                         svn:entry:last-author
 711                                         svn:entry:uuid
 712                                         svn:entry:committed-date/;
 713 }
 714
 715 sub read_all_remotes {
 716         my $r = {};
 717         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
 718                 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
 719                         $r->{$1}->{fetch}->{$2} = $3;
 720                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
 721                         $r->{$1}->{url} = $2;
 722                 }
 723         }
 724         $r;
 725 }
 726
 727 sub verify_remotes_sanity {
 728         return unless -d $ENV{GIT_DIR};
 729         my %seen;
 730         foreach (command(qw/config -l/)) {
 731                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
 732                         if ($seen{$1}) {
 733                                 die "Remote ref refs/remote/$1 is tracked by",
 734                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
 735                                     "Please resolve this ambiguity in ",
 736                                     "your git configuration file before ",
 737                                     "continuing\n";
 738                         }
 739                         $seen{$1} = $_;
 740                 }
 741         }
 742 }
 743
 744 # we allow more chars than remotes2config.sh...
 745 sub sanitize_remote_name {
 746         my ($name) = @_;
 747         $name =~ tr{A-Za-z0-9:,/+-}{.}c;
 748         $name;
 749 }
 750
 751 sub find_existing_remote {
 752         my ($url, $remotes) = @_;
 753         my $existing;
 754         foreach my $repo_id (keys %$remotes) {
 755                 my $u = $remotes->{$repo_id}->{url} or next;
 756                 next if $u ne $url;
 757                 $existing = $repo_id;
 758                 last;
 759         }
 760         $existing;
 761 }
 762
 763 sub init_remote_config {
 764         my ($self, $url) = @_;
 765         $url =~ s!/+$!!; # strip trailing slash
 766         my $r = read_all_remotes();
 767         my $existing = find_existing_remote($url, $r);
 768         if ($existing) {
 769                 print STDERR "Using existing ",
 770                              "[svn-remote \"$existing\"]\n";
 771                 $self->{repo_id} = $existing;
 772         } else {
 773                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
 774                 $existing = find_existing_remote($min_url, $r);
 775                 if ($existing) {
 776                         print STDERR "Using existing ",
 777                                      "[svn-remote \"$existing\"]\n";
 778                         $self->{repo_id} = $existing;
 779                 }
 780                 if ($min_url ne $url) {
 781                         print STDERR "Using higher level of URL: ",
 782                                      "$url => $min_url\n";
 783                         my $old_path = $self->{path};
 784                         $self->{path} = $url;
 785                         $self->{path} =~ s!^\Q$min_url\E/*!!;
 786                         if (length $old_path) {
 787                                 $self->{path} .= "/$old_path";
 788                         }
 789                         $url = $min_url;
 790                 }
 791         }
 792         my $orig_url;
 793         if (!$existing) {
 794                 # verify that we aren't overwriting anything:
 795                 $orig_url = eval {
 796                         command_oneline('config', '--get',
 797                                         "svn-remote.$self->{repo_id}.url")
 798                 };
 799                 if ($orig_url && ($orig_url ne $url)) {
 800                         die "svn-remote.$self->{repo_id}.url already set: ",
 801                             "$orig_url\nwanted to set to: $url\n";
 802                 }
 803         }
 804         my ($xrepo_id, $xpath) = find_ref($self->refname);
 805         if (defined $xpath) {
 806                 die "svn-remote.$xrepo_id.fetch already set to track ",
 807                     "$xpath:refs/remotes/", $self->refname, "\n";
 808         }
 809         command_noisy('config',
 810                       "svn-remote.$self->{repo_id}.url", $url);
 811         command_noisy('config', '--add',
 812                       "svn-remote.$self->{repo_id}.fetch",
 813                       "$self->{path}:".$self->refname);
 814         $self->{url} = $url;
 815 }
 816
 817 sub init {
 818         my ($class, $url, $path, $repo_id, $ref_id) = @_;
 819         my $self = _new($class, $repo_id, $ref_id, $path);
 820         if (defined $url) {
 821                 $self->init_remote_config($url);
 822         }
 823         $self;
 824 }
 825
 826 sub find_ref {
 827         my ($ref_id) = @_;
 828         foreach (command(qw/config -l/)) {
 829                 next unless m!^svn-remote\.(.+)\.fetch=
 830                               \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
 831                 my ($repo_id, $path, $ref) = ($1, $2, $3);
 832                 if ($ref eq $ref_id) {
 833                         $path = '' if ($path =~ m#^\./?#);
 834                         return ($repo_id, $path);
 835                 }
 836         }
 837         (undef, undef, undef);
 838 }
 839
 840 sub new {
 841         my ($class, $ref_id, $repo_id, $path) = @_;
 842         if (defined $ref_id && !defined $repo_id && !defined $path) {
 843                 ($repo_id, $path) = find_ref($ref_id);
 844                 if (!defined $repo_id) {
 845                         die "Could not find a \"svn-remote.*.fetch\" key ",
 846                             "in the repository configuration matching: ",
 847                             "refs/remotes/$ref_id\n";
 848                 }
 849         }
 850         my $self = _new($class, $repo_id, $ref_id, $path);
 851         if (!defined $self->{path} || !length $self->{path}) {
 852                 my $fetch = command_oneline('config', '--get',
 853                                             "svn-remote.$repo_id.fetch",
 854                                             ":refs/remotes/$ref_id\$") or
 855                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
 856                          "\":refs/remotes/$ref_id\$\" in config\n";
 857                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
 858         }
 859         $self->{url} = command_oneline('config', '--get',
 860                                        "svn-remote.$repo_id.url") or
 861                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
 862         $self;
 863 }
 864
 865 sub refname { "refs/remotes/$_[0]->{ref_id}" }
 866
 867 sub ra {
 868         my ($self) = shift;
 869         $self->{ra} ||= Git::SVN::Ra->new($self->{url});
 870 }
 871
 872 sub rel_path {
 873         my ($self) = @_;
 874         my $repos_root = $self->ra->{repos_root};
 875         return $self->{path} if ($self->{url} eq $repos_root);
 876         my $url = $self->{url} .
 877                   (length $self->{path} ? "/$self->{path}" : $self->{path});
 878         $url =~ s!^\Q$repos_root\E/*!!g;
 879         $url;
 880 }
 881
 882 sub copy_remote_ref {
 883         my ($self) = @_;
 884         my $origin = $::_cp_remote ? $::_cp_remote : 'origin';
 885         my $ref = $self->refname;
 886         if (command('ls-remote', $origin, $ref)) {
 887                 command_noisy('fetch', $origin, "$ref:$ref");
 888         } elsif ($::_cp_remote && !$::_upgrade) {
 889                 die "Unable to find remote reference: $ref on $origin\n";
 890         }
 891 }
 892
 893 sub traverse_ignore {
 894         my ($self, $fh, $path, $r) = @_;
 895         $path =~ s#^/+##g;
 896         my ($dirent, undef, $props) = $self->ra->get_dir($path, $r);
 897         my $p = $path;
 898         $p =~ s#^\Q$self->{ra}->{svn_path}\E/##;
 899         print $fh length $p ? "\n# $p\n" : "\n# /\n";
 900         if (my $s = $props->{'svn:ignore'}) {
 901                 $s =~ s/[\r\n]+/\n/g;
 902                 chomp $s;
 903                 if (length $p == 0) {
 904                         $s =~ s#\n#\n/$p#g;
 905                         print $fh "/$s\n";
 906                 } else {
 907                         $s =~ s#\n#\n/$p/#g;
 908                         print $fh "/$p/$s\n";
 909                 }
 910         }
 911         foreach (sort keys %$dirent) {
 912                 next if $dirent->{$_}->kind != $SVN::Node::dir;
 913                 $self->traverse_ignore($fh, "$path/$_", $r);
 914         }
 915 }
 916
 917 # returns the newest SVN revision number and newest commit SHA1
 918 sub last_rev_commit {
 919         my ($self) = @_;
 920         if (defined $self->{last_rev} && defined $self->{last_commit}) {
 921                 return ($self->{last_rev}, $self->{last_commit});
 922         }
 923         my $c = ::verify_ref($self->refname.'^0');
 924         if ($c) {
 925                 my $rev = (::cmt_metadata($c))[1];
 926                 if (defined $rev) {
 927                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
 928                         return ($rev, $c);
 929                 }
 930         }
 931         my $offset = -41; # from tail
 932         my $rl;
 933         open my $fh, '<', $self->{db_path} or
 934                                  croak "$self->{db_path} not readable: $!\n";
 935         seek $fh, $offset, 2;
 936         $rl = readline $fh;
 937         defined $rl or return (undef, undef);
 938         chomp $rl;
 939         while ($c ne $rl && tell $fh != 0) {
 940                 $offset -= 41;
 941                 seek $fh, $offset, 2;
 942                 $rl = readline $fh;
 943                 defined $rl or return (undef, undef);
 944                 chomp $rl;
 945         }
 946         my $rev = tell $fh;
 947         croak $! if ($rev < 0);
 948         $rev =  ($rev - 41) / 41;
 949         close $fh or croak $!;
 950         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
 951         return ($rev, $c);
 952 }
 953
 954 sub parse_revision {
 955         my ($self, $base) = @_;
 956         my $head = $self->ra->get_latest_revnum;
 957         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
 958                 return ($base + 1, $head) if (defined $base);
 959                 return (0, $head);
 960         }
 961         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
 962         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
 963         if ($::_revision =~ /^BASE:(\d+)$/) {
 964                 return ($base + 1, $1) if (defined $base);
 965                 return (0, $head);
 966         }
 967         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
 968         die "revision argument: $::_revision not understood by git-svn\n",
 969                 "Try using the command-line svn client instead\n";
 970 }
 971
 972 sub tmp_index_do {
 973         my ($self, $sub) = @_;
 974         my $old_index = $ENV{GIT_INDEX_FILE};
 975         $ENV{GIT_INDEX_FILE} = $self->{index};
 976         my @ret = &$sub;
 977         if ($old_index) {
 978                 $ENV{GIT_INDEX_FILE} = $old_index;
 979         } else {
 980                 delete $ENV{GIT_INDEX_FILE};
 981         }
 982         wantarray ? @ret : $ret[0];
 983 }
 984
 985 sub assert_index_clean {
 986         my ($self, $treeish) = @_;
 987
 988         $self->tmp_index_do(sub {
 989                 command_noisy('read-tree', $treeish) unless -e $self->{index};
 990                 my $x = command_oneline('write-tree');
 991                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
 992                            /^tree ($::sha1)/mo);
 993                 if ($y ne $x) {
 994                         unlink $self->{index} or croak $!;
 995                         command_noisy('read-tree', $treeish);
 996                 }
 997                 $x = command_oneline('write-tree');
 998                 if ($y ne $x) {
 999                         ::fatal "trees ($treeish) $y != $x\n",
1000                                 "Something is seriously wrong...\n";
1001                 }
1002         });
1003 }
1004
1005 sub get_commit_parents {
1006         my ($self, $log_entry, @parents) = @_;
1007         my (%seen, @ret, @tmp);
1008         # commit parents can be conditionally bound to a particular
1009         # svn revision via: "svn_revno=commit_sha1", filter them out here:
1010         foreach my $p (@parents) {
1011                 next unless defined $p;
1012                 if ($p =~ /^(\d+)=($::sha1_short)$/o) {
1013                         push @tmp, $2 if $1 == $log_entry->{revision};
1014                 } else {
1015                         push @tmp, $p if $p =~ /^$::sha1_short$/o;
1016                 }
1017         }
1018         if (my $cur = ::verify_ref($self->refname.'^0')) {
1019                 push @tmp, $cur;
1020         }
1021         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
1022         while (my $p = shift @tmp) {
1023                 next if $seen{$p};
1024                 $seen{$p} = 1;
1025                 push @ret, $p;
1026                 # MAXPARENT is defined to 16 in commit-tree.c:
1027                 last if @ret >= 16;
1028         }
1029         if (@tmp) {
1030                 die "r$log_entry->{revision}: No room for parents:\n\t",
1031                     join("\n\t", @tmp), "\n";
1032         }
1033         @ret;
1034 }
1035
1036 sub full_url {
1037         my ($self) = @_;
1038         $self->ra->{url} . (length $self->{path} ? '/' . $self->{path} : '');
1039 }
1040
1041 sub do_git_commit {
1042         my ($self, $log_entry, @parents) = @_;
1043         if (my $c = $self->rev_db_get($log_entry->{revision})) {
1044                 croak "$log_entry->{revision} = $c already exists! ",
1045                       "Why are we refetching it?\n";
1046         }
1047         my $author = $log_entry->{author};
1048         my ($name, $email) = (defined $::users{$author} ? @{$::users{$author}}
1049                            : ($author, "$author\@".$self->ra->uuid));
1050         $ENV{GIT_AUTHOR_NAME} = $ENV{GIT_COMMITTER_NAME} = $name;
1051         $ENV{GIT_AUTHOR_EMAIL} = $ENV{GIT_COMMITTER_EMAIL} = $email;
1052         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
1053
1054         my $tree = $log_entry->{tree};
1055         if (!defined $tree) {
1056                 $tree = $self->tmp_index_do(sub {
1057                                             command_oneline('write-tree') });
1058         }
1059         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
1060
1061         my @exec = ('git-commit-tree', $tree);
1062         foreach ($self->get_commit_parents($log_entry, @parents)) {
1063                 push @exec, '-p', $_;
1064         }
1065         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
1066                                                                    or croak $!;
1067         print $msg_fh $log_entry->{log} or croak $!;
1068         print $msg_fh "\ngit-svn-id: ", $self->full_url, '@',
1069                       $log_entry->{revision}, ' ',
1070                       $self->ra->uuid, "\n" or croak $!;
1071         $msg_fh->flush == 0 or croak $!;
1072         close $msg_fh or croak $!;
1073         chomp(my $commit = do { local $/; <$out_fh> });
1074         close $out_fh or croak $!;
1075         waitpid $pid, 0;
1076         croak $? if $?;
1077         if ($commit !~ /^$::sha1$/o) {
1078                 die "Failed to commit, invalid sha1: $commit\n";
1079         }
1080
1081         command_noisy('update-ref',$self->refname, $commit);
1082         $self->rev_db_set($log_entry->{revision}, $commit);
1083
1084         $self->{last_rev} = $log_entry->{revision};
1085         $self->{last_commit} = $commit;
1086         print "r$log_entry->{revision} = $commit\n";
1087         return $commit;
1088 }
1089
1090 sub revisions_eq {
1091         my ($self, $r0, $r1) = @_;
1092         return 1 if $r0 == $r1;
1093         my $nr = 0;
1094         $self->ra->get_log([$self->{path}], $r0, $r1,
1095                            0, 0, 1, sub { $nr++ });
1096         return 0 if ($nr > 1);
1097         return 1;
1098 }
1099
1100 sub find_parent_branch {
1101         my ($self, $paths, $rev) = @_;
1102         return undef unless $::_follow_parent;
1103         unless (defined $paths) {
1104                 $self->ra->get_log([''], $rev, $rev, 0, 1, 1,
1105                                    sub { $paths = $_[0] });
1106         }
1107         return undef unless defined $paths;
1108
1109         # look for a parent from another branch:
1110         my @b_path_components = split m#/#, $self->rel_path;
1111         my @a_path_components;
1112         my $i;
1113         while (@b_path_components) {
1114                 $i = $paths->{'/'.join('/', @b_path_components)};
1115                 last if $i;
1116                 unshift(@a_path_components, pop(@b_path_components));
1117         }
1118         goto not_found unless defined $i;
1119         my $branch_from = $i->copyfrom_path or goto not_found;
1120         if (@a_path_components) {
1121                 print STDERR "branch_from: $branch_from => ";
1122                 $branch_from .= '/'.join('/', @a_path_components);
1123                 print STDERR $branch_from, "\n";
1124         }
1125         my $r = $i->copyfrom_rev;
1126         my $repos_root = $self->ra->{repos_root};
1127         my $url = $self->ra->{url};
1128         my $new_url = $repos_root . $branch_from;
1129         print STDERR  "Found possible branch point: ",
1130                       "$new_url => ", $self->full_url, ", $r\n";
1131         $branch_from =~ s#^/##;
1132         my $remotes = read_all_remotes();
1133         my $gs;
1134         foreach my $repo_id (keys %$remotes) {
1135                 my $u = $remotes->{$repo_id}->{url} or next;
1136                 next if $url ne $u;
1137                 my $fetch = $remotes->{$repo_id}->{fetch};
1138                 foreach my $f (keys %$fetch) {
1139                         next if $f ne $branch_from;
1140                         $gs = Git::SVN->new($fetch->{$f}, $repo_id, $f);
1141                         last;
1142                 }
1143                 last if $gs;
1144         }
1145         unless ($gs) {
1146                 my $ref_id = $branch_from;
1147                 $ref_id .= "\@$r" if find_ref($ref_id);
1148                 # just grow a tail if we're not unique enough :x
1149                 $ref_id .= '-' while find_ref($ref_id);
1150                 $gs = Git::SVN->init($new_url, '', $ref_id, $ref_id);
1151         }
1152         my ($r0, $parent) = $gs->find_rev_before($r, 1);
1153         if ($::_follow_parent && (!defined $r0 || !defined $parent)) {
1154                 foreach (1 .. $r) {
1155                         if (my $log_entry = $gs->do_fetch(undef, $_)) {
1156                                 $gs->do_git_commit($log_entry);
1157                         }
1158                 }
1159                 ($r0, $parent) = $gs->last_rev_commit;
1160         }
1161         if (defined $r0 && defined $parent && $gs->revisions_eq($r0, $r)) {
1162                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
1163                 $self->assert_index_clean($parent);
1164                 my $ed;
1165                 if ($self->ra->can_do_switch) {
1166                         print STDERR "Following parent with do_switch\n";
1167                         # do_switch works with svn/trunk >= r22312, but that
1168                         # is not included with SVN 1.4.2 (the latest version
1169                         # at the moment), so we can't rely on it
1170                         $self->{last_commit} = $parent;
1171                         $ed = SVN::Git::Fetcher->new($self);
1172                         $gs->ra->gs_do_switch($r0, $rev, $gs->{path}, 1,
1173                                               $self->full_url, $ed)
1174                           or die "SVN connection failed somewhere...\n";
1175                 } else {
1176                         print STDERR "Following parent with do_update\n";
1177                         $ed = SVN::Git::Fetcher->new($self);
1178                         $self->ra->gs_do_update($rev, $rev, $self->{path},
1179                                                 1, $ed)
1180                           or die "SVN connection failed somewhere...\n";
1181                 }
1182                 return $self->make_log_entry($rev, [$parent], $ed);
1183         }
1184 not_found:
1185         print STDERR "Branch parent for path: '/",
1186                      $self->rel_path, "' @ $rev not found\n";
1187         print STDERR '  ', $_, "\n" foreach (sort keys %$paths);
1188         return undef;
1189 }
1190
1191 sub do_fetch {
1192         my ($self, $paths, $rev) = @_;
1193         my $ed;
1194         my ($last_rev, @parents);
1195         if ($self->{last_commit}) {
1196                 $ed = SVN::Git::Fetcher->new($self);
1197                 $last_rev = $self->{last_rev};
1198                 $ed->{c} = $self->{last_commit};
1199                 @parents = ($self->{last_commit});
1200         } else {
1201                 $last_rev = $rev;
1202                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1203                         return $log_entry;
1204                 }
1205                 $ed = SVN::Git::Fetcher->new($self);
1206         }
1207         unless ($self->ra->gs_do_update($last_rev, $rev,
1208                                         $self->{path}, 1, $ed)) {
1209                 die "SVN connection failed somewhere...\n";
1210         }
1211         $self->make_log_entry($rev, \@parents, $ed);
1212 }
1213
1214 sub get_untracked {
1215         my ($self, $ed) = @_;
1216         my @out;
1217         my $h = $ed->{empty};
1218         foreach (sort keys %$h) {
1219                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
1220                 push @out, "  $act: " . uri_encode($_);
1221                 warn "W: $act: $_\n";
1222         }
1223         foreach my $t (qw/dir_prop file_prop/) {
1224                 $h = $ed->{$t} or next;
1225                 foreach my $path (sort keys %$h) {
1226                         my $ppath = $path eq '' ? '.' : $path;
1227                         foreach my $prop (sort keys %{$h->{$path}}) {
1228                                 next if $SKIP_PROP{$prop};
1229                                 my $v = $h->{$path}->{$prop};
1230                                 my $t_ppath_prop = "$t: " .
1231                                                     uri_encode($ppath) . ' ' .
1232                                                     uri_encode($prop);
1233                                 if (defined $v) {
1234                                         push @out, "  +$t_ppath_prop " .
1235                                                    uri_encode($v);
1236                                 } else {
1237                                         push @out, "  -$t_ppath_prop";
1238                                 }
1239                         }
1240                 }
1241         }
1242         foreach my $t (qw/absent_file absent_directory/) {
1243                 $h = $ed->{$t} or next;
1244                 foreach my $parent (sort keys %$h) {
1245                         foreach my $path (sort @{$h->{$parent}}) {
1246                                 push @out, "  $t: " .
1247                                            uri_encode("$parent/$path");
1248                                 warn "W: $t: $parent/$path ",
1249                                      "Insufficient permissions?\n";
1250                         }
1251                 }
1252         }
1253         \@out;
1254 }
1255
1256 sub parse_svn_date {
1257         my $date = shift || return '+0000 1970-01-01 00:00:00';
1258         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
1259                                             (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
1260                                          croak "Unable to parse date: $date\n";
1261         "+0000 $Y-$m-$d $H:$M:$S";
1262 }
1263
1264 sub check_author {
1265         my ($author) = @_;
1266         if (!defined $author || length $author == 0) {
1267                 $author = '(no author)';
1268         }
1269         if (defined $::_authors && ! defined $::users{$author}) {
1270                 die "Author: $author not defined in $::_authors file\n";
1271         }
1272         $author;
1273 }
1274
1275 sub make_log_entry {
1276         my ($self, $rev, $parents, $ed) = @_;
1277         my $untracked = $self->get_untracked($ed);
1278
1279         return undef if ($ed->{nr} == 0 && scalar @$untracked == 0);
1280
1281         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
1282         print $un "r$rev\n" or croak $!;
1283         print $un $_, "\n" foreach @$untracked;
1284         my %log_entry = ( parents => $parents || [], revision => $rev,
1285                           log => '');
1286         my $rp = $self->ra->rev_proplist($rev);
1287         foreach (sort keys %$rp) {
1288                 my $v = $rp->{$_};
1289                 if (/^svn:(author|date|log)$/) {
1290                         $log_entry{$1} = $v;
1291                 } else {
1292                         print $un "  rev_prop: ", uri_encode($_), ' ',
1293                                   uri_encode($v), "\n";
1294                 }
1295         }
1296         close $un or croak $!;
1297
1298         $log_entry{date} = parse_svn_date($log_entry{date});
1299         $log_entry{author} = check_author($log_entry{author});
1300         $log_entry{log} .= "\n";
1301         \%log_entry;
1302 }
1303
1304 sub fetch {
1305         my ($self, @parents) = @_;
1306         my ($last_rev, $last_commit) = $self->last_rev_commit;
1307         my ($base, $head) = $self->parse_revision($last_rev);
1308         return if ($base > $head);
1309         if (defined $last_commit) {
1310                 $self->assert_index_clean($last_commit);
1311         }
1312         my $inc = 1000;
1313         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
1314         my $err_handler = $SVN::Error::handler;
1315         my $err;
1316         $SVN::Error::handler = sub { ($err) = @_; skip_unknown_revs($err); } ;
1317         while (1) {
1318                 my @revs;
1319                 $self->ra->get_log([$self->{path}], $min, $max, 0, 1, 1, sub {
1320                         my ($paths, $rev, $author, $date, $log) = @_;
1321                         push @revs, [ $paths, $rev ] });
1322                 if (! @revs && $err) {
1323                         print STDERR "Branch probably deleted:\n  ",
1324                                      $err->expanded_message,
1325                                      "\nWill attempt to follow revisions ",
1326                                      "committed before the deletion\n";
1327                         @revs = map { [ undef, $_ ] } ($min .. $max);
1328                 }
1329                 foreach (@revs) {
1330                         if (my $log_entry = $self->do_fetch(@$_)) {
1331                                 $self->do_git_commit($log_entry, @parents);
1332                         }
1333                 }
1334                 last if $max >= $head || $err;
1335                 $min = $max + 1;
1336                 $max += $inc;
1337                 $max = $head if ($max > $head);
1338         }
1339         $SVN::Error::handler = $err_handler;
1340 }
1341
1342 sub set_tree_cb {
1343         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
1344         # TODO: enable and test optimized commits:
1345         if (0 && $rev == ($self->{last_rev} + 1)) {
1346                 $log_entry->{revision} = $rev;
1347                 $log_entry->{author} = $author;
1348                 $self->do_git_commit($log_entry, "$rev=$tree");
1349         } else {
1350                 $self->fetch("$rev=$tree");
1351         }
1352 }
1353
1354 sub set_tree {
1355         my ($self, $tree) = (shift, shift);
1356         my $log_entry = ::get_commit_entry($tree);
1357         unless ($self->{last_rev}) {
1358                 fatal("Must have an existing revision to commit\n");
1359         }
1360         my $pool = SVN::Pool->new;
1361         my $ed = SVN::Git::Editor->new({ r => $self->{last_rev},
1362                                          ra => $self->ra->dup,
1363                                          svn_path => $self->ra->{svn_path}
1364                                        },
1365                                        $self->ra->get_commit_editor(
1366                                          $log_entry->{log}, sub {
1367                                            $self->set_tree_cb($log_entry,
1368                                                               $tree, @_);
1369                                        }),
1370                                        $pool);
1371         my $mods = $ed->apply_diff($self->{last_commit}, $tree);
1372         if (@$mods == 0) {
1373                 print "No changes\nr$self->{last_rev} = $tree\n";
1374         }
1375         $pool->clear;
1376 }
1377
1378 sub skip_unknown_revs {
1379         my ($err) = @_;
1380         my $errno = $err->apr_err();
1381         # Maybe the branch we're tracking didn't
1382         # exist when the repo started, so it's
1383         # not an error if it doesn't, just continue
1384         #
1385         # Wonderfully consistent library, eh?
1386         # 160013 - svn:// and file://
1387         # 175002 - http(s)://
1388         # 175007 - http(s):// (this repo required authorization, too...)
1389         #   More codes may be discovered later...
1390         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
1391                 return;
1392         }
1393         croak "Error from SVN, ($errno): ", $err->expanded_message,"\n";
1394 }
1395
1396 # rev_db:
1397 # Tie::File seems to be prone to offset errors if revisions get sparse,
1398 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
1399 # one of my favorite modules is out :<  Next up would be one of the DBM
1400 # modules, but I'm not sure which is most portable...  So I'll just
1401 # go with something that's plain-text, but still capable of
1402 # being randomly accessed.  So here's my ultra-simple fixed-width
1403 # database.  All records are 40 characters + "\n", so it's easy to seek
1404 # to a revision: (41 * rev) is the byte offset.
1405 # A record of 40 0s denotes an empty revision.
1406 # And yes, it's still pretty fast (faster than Tie::File).
1407
1408 sub rev_db_set {
1409         my ($self, $rev, $commit) = @_;
1410         length $commit == 40 or croak "arg3 must be a full SHA1 hexsum\n";
1411         open my $fh, '+<', $self->{db_path} or croak $!;
1412         my $offset = $rev * 41;
1413         # assume that append is the common case:
1414         seek $fh, 0, 2 or croak $!;
1415         my $pos = tell $fh;
1416         if ($pos < $offset) {
1417                 print $fh (('0' x 40),"\n") x (($offset - $pos) / 41)
1418                   or croak $!;
1419         }
1420         seek $fh, $offset, 0 or croak $!;
1421         print $fh $commit,"\n" or croak $!;
1422         close $fh or croak $!;
1423 }
1424
1425 sub rev_db_get {
1426         my ($self, $rev) = @_;
1427         my $ret;
1428         my $offset = $rev * 41;
1429         open my $fh, '<', $self->{db_path} or croak $!;
1430         if (seek $fh, $offset, 0) {
1431                 $ret = readline $fh;
1432                 if (defined $ret) {
1433                         chomp $ret;
1434                         $ret = undef if ($ret =~ /^0{40}$/);
1435                 }
1436         }
1437         close $fh or croak $!;
1438         $ret;
1439 }
1440
1441 sub find_rev_before {
1442         my ($self, $rev, $eq_ok) = @_;
1443         --$rev unless $eq_ok;
1444         while ($rev > 0) {
1445                 if (my $c = $self->rev_db_get($rev)) {
1446                         return ($rev, $c);
1447                 }
1448                 --$rev;
1449         }
1450         return (undef, undef);
1451 }
1452
1453 sub _new {
1454         my ($class, $repo_id, $ref_id, $path) = @_;
1455         unless (defined $repo_id && length $repo_id) {
1456                 $repo_id = $Git::SVN::default_repo_id;
1457         }
1458         unless (defined $ref_id && length $ref_id) {
1459                 $_[2] = $ref_id = $Git::SVN::default_ref_id;
1460         }
1461         $_[1] = $repo_id = sanitize_remote_name($repo_id);
1462         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
1463         $_[3] = $path = '' unless (defined $path);
1464         mkpath([$dir]);
1465         unless (-f "$dir/.rev_db") {
1466                 open my $fh, '>>', "$dir/.rev_db" or croak $!;
1467                 close $fh or croak $!;
1468         }
1469         bless { ref_id => $ref_id, dir => $dir, index => "$dir/index",
1470                 path => $path,
1471                 db_path => "$dir/.rev_db", repo_id => $repo_id }, $class;
1472 }
1473
1474 sub uri_encode {
1475         my ($f) = @_;
1476         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
1477         $f
1478 }
1479
1480 package Git::SVN::Prompt;
1481 use strict;
1482 use warnings;
1483 require SVN::Core;
1484 use vars qw/$_no_auth_cache $_username/;
1485
1486 sub simple {
1487         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
1488         $may_save = undef if $_no_auth_cache;
1489         $default_username = $_username if defined $_username;
1490         if (defined $default_username && length $default_username) {
1491                 if (defined $realm && length $realm) {
1492                         print STDERR "Authentication realm: $realm\n";
1493                         STDERR->flush;
1494                 }
1495                 $cred->username($default_username);
1496         } else {
1497                 username($cred, $realm, $may_save, $pool);
1498         }
1499         $cred->password(_read_password("Password for '" .
1500                                        $cred->username . "': ", $realm));
1501         $cred->may_save($may_save);
1502         $SVN::_Core::SVN_NO_ERROR;
1503 }
1504
1505 sub ssl_server_trust {
1506         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
1507         $may_save = undef if $_no_auth_cache;
1508         print STDERR "Error validating server certificate for '$realm':\n";
1509         if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
1510                 print STDERR " - The certificate is not issued by a trusted ",
1511                       "authority. Use the\n",
1512                       "   fingerprint to validate the certificate manually!\n";
1513         }
1514         if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
1515                 print STDERR " - The certificate hostname does not match.\n";
1516         }
1517         if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
1518                 print STDERR " - The certificate is not yet valid.\n";
1519         }
1520         if ($failures & $SVN::Auth::SSL::EXPIRED) {
1521                 print STDERR " - The certificate has expired.\n";
1522         }
1523         if ($failures & $SVN::Auth::SSL::OTHER) {
1524                 print STDERR " - The certificate has an unknown error.\n";
1525         }
1526         printf STDERR
1527                 "Certificate information:\n".
1528                 " - Hostname: %s\n".
1529                 " - Valid: from %s until %s\n".
1530                 " - Issuer: %s\n".
1531                 " - Fingerprint: %s\n",
1532                 map $cert_info->$_, qw(hostname valid_from valid_until
1533                                        issuer_dname fingerprint);
1534         my $choice;
1535 prompt:
1536         print STDERR $may_save ?
1537               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
1538               "(R)eject or accept (t)emporarily? ";
1539         STDERR->flush;
1540         $choice = lc(substr(<STDIN> || 'R', 0, 1));
1541         if ($choice =~ /^t$/i) {
1542                 $cred->may_save(undef);
1543         } elsif ($choice =~ /^r$/i) {
1544                 return -1;
1545         } elsif ($may_save && $choice =~ /^p$/i) {
1546                 $cred->may_save($may_save);
1547         } else {
1548                 goto prompt;
1549         }
1550         $cred->accepted_failures($failures);
1551         $SVN::_Core::SVN_NO_ERROR;
1552 }
1553
1554 sub ssl_client_cert {
1555         my ($cred, $realm, $may_save, $pool) = @_;
1556         $may_save = undef if $_no_auth_cache;
1557         print STDERR "Client certificate filename: ";
1558         STDERR->flush;
1559         chomp(my $filename = <STDIN>);
1560         $cred->cert_file($filename);
1561         $cred->may_save($may_save);
1562         $SVN::_Core::SVN_NO_ERROR;
1563 }
1564
1565 sub ssl_client_cert_pw {
1566         my ($cred, $realm, $may_save, $pool) = @_;
1567         $may_save = undef if $_no_auth_cache;
1568         $cred->password(_read_password("Password: ", $realm));
1569         $cred->may_save($may_save);
1570         $SVN::_Core::SVN_NO_ERROR;
1571 }
1572
1573 sub username {
1574         my ($cred, $realm, $may_save, $pool) = @_;
1575         $may_save = undef if $_no_auth_cache;
1576         if (defined $realm && length $realm) {
1577                 print STDERR "Authentication realm: $realm\n";
1578         }
1579         my $username;
1580         if (defined $_username) {
1581                 $username = $_username;
1582         } else {
1583                 print STDERR "Username: ";
1584                 STDERR->flush;
1585                 chomp($username = <STDIN>);
1586         }
1587         $cred->username($username);
1588         $cred->may_save($may_save);
1589         $SVN::_Core::SVN_NO_ERROR;
1590 }
1591
1592 sub _read_password {
1593         my ($prompt, $realm) = @_;
1594         print STDERR $prompt;
1595         STDERR->flush;
1596         require Term::ReadKey;
1597         Term::ReadKey::ReadMode('noecho');
1598         my $password = '';
1599         while (defined(my $key = Term::ReadKey::ReadKey(0))) {
1600                 last if $key =~ /[\012\015]/; # \n\r
1601                 $password .= $key;
1602         }
1603         Term::ReadKey::ReadMode('restore');
1604         print STDERR "\n";
1605         STDERR->flush;
1606         $password;
1607 }
1608
1609 package main;
1610
1611 sub uri_encode {
1612         my ($f) = @_;
1613         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
1614         $f
1615 }
1616
1617 sub uri_decode {
1618         my ($f) = @_;
1619         $f =~ tr/+/ /;
1620         $f =~ s/%([A-F0-9]{2})/chr hex($1)/ge;
1621         $f
1622 }
1623
1624 {
1625         my $kill_stupid_warnings = $SVN::Node::none.$SVN::Node::file.
1626                                 $SVN::Node::dir.$SVN::Node::unknown.
1627                                 $SVN::Node::none.$SVN::Node::file.
1628                                 $SVN::Node::dir.$SVN::Node::unknown.
1629                                 $SVN::Auth::SSL::CNMISMATCH.
1630                                 $SVN::Auth::SSL::NOTYETVALID.
1631                                 $SVN::Auth::SSL::EXPIRED.
1632                                 $SVN::Auth::SSL::UNKNOWNCA.
1633                                 $SVN::Auth::SSL::OTHER;
1634 }
1635
1636 package SVN::Git::Fetcher;
1637 use vars qw/@ISA/;
1638 use strict;
1639 use warnings;
1640 use Carp qw/croak/;
1641 use IO::File qw//;
1642
1643 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
1644 sub new {
1645         my ($class, $git_svn) = @_;
1646         my $self = SVN::Delta::Editor->new;
1647         bless $self, $class;
1648         $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
1649         $self->{empty} = {};
1650         $self->{dir_prop} = {};
1651         $self->{file_prop} = {};
1652         $self->{absent_dir} = {};
1653         $self->{absent_file} = {};
1654         $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
1655         require Digest::MD5;
1656         $self;
1657 }
1658
1659 sub set_path_strip {
1660         my ($self, $path) = @_;
1661         $self->{path_strip} = qr/^\Q$path\E\/?/;
1662 }
1663
1664 sub open_root {
1665         { path => '' };
1666 }
1667
1668 sub open_directory {
1669         my ($self, $path, $pb, $rev) = @_;
1670         { path => $path };
1671 }
1672
1673 sub git_path {
1674         my ($self, $path) = @_;
1675         $path =~ s!$self->{path_strip}!! if $self->{path_strip};
1676         $path;
1677 }
1678
1679 sub delete_entry {
1680         my ($self, $path, $rev, $pb) = @_;
1681
1682         my $gpath = $self->git_path($path);
1683         # remove entire directories.
1684         if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
1685                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
1686                                                      -r --name-only -z/,
1687                                                      $self->{c}, '--', $gpath);
1688                 local $/ = "\0";
1689                 while (<$ls>) {
1690                         chomp;
1691                         $self->{gii}->remove($_);
1692                         print "\tD\t$_\n" unless $self->{q};
1693                 }
1694                 print "\tD\t$gpath/\n" unless $self->{q};
1695                 command_close_pipe($ls, $ctx);
1696                 $self->{empty}->{$path} = 0
1697         } else {
1698                 $self->{gii}->remove($gpath);
1699                 print "\tD\t$gpath\n" unless $self->{q};
1700         }
1701         undef;
1702 }
1703
1704 sub open_file {
1705         my ($self, $path, $pb, $rev) = @_;
1706         my $gpath = $self->git_path($path);
1707         my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
1708                              =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
1709         unless (defined $mode && defined $blob) {
1710                 die "$path was not found in commit $self->{c} (r$rev)\n";
1711         }
1712         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
1713           pool => SVN::Pool->new, action => 'M' };
1714 }
1715
1716 sub add_file {
1717         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
1718         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
1719         delete $self->{empty}->{$dir};
1720         { path => $path, mode_a => 100644, mode_b => 100644,
1721           pool => SVN::Pool->new, action => 'A' };
1722 }
1723
1724 sub add_directory {
1725         my ($self, $path, $cp_path, $cp_rev) = @_;
1726         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
1727         delete $self->{empty}->{$dir};
1728         $self->{empty}->{$path} = 1;
1729         { path => $path };
1730 }
1731
1732 sub change_dir_prop {
1733         my ($self, $db, $prop, $value) = @_;
1734         $self->{dir_prop}->{$db->{path}} ||= {};
1735         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
1736         undef;
1737 }
1738
1739 sub absent_directory {
1740         my ($self, $path, $pb) = @_;
1741         $self->{absent_dir}->{$pb->{path}} ||= [];
1742         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
1743         undef;
1744 }
1745
1746 sub absent_file {
1747         my ($self, $path, $pb) = @_;
1748         $self->{absent_file}->{$pb->{path}} ||= [];
1749         push @{$self->{absent_file}->{$pb->{path}}}, $path;
1750         undef;
1751 }
1752
1753 sub change_file_prop {
1754         my ($self, $fb, $prop, $value) = @_;
1755         if ($prop eq 'svn:executable') {
1756                 if ($fb->{mode_b} != 120000) {
1757                         $fb->{mode_b} = defined $value ? 100755 : 100644;
1758                 }
1759         } elsif ($prop eq 'svn:special') {
1760                 $fb->{mode_b} = defined $value ? 120000 : 100644;
1761         } else {
1762                 $self->{file_prop}->{$fb->{path}} ||= {};
1763                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
1764         }
1765         undef;
1766 }
1767
1768 sub apply_textdelta {
1769         my ($self, $fb, $exp) = @_;
1770         my $fh = IO::File->new_tmpfile;
1771         $fh->autoflush(1);
1772         # $fh gets auto-closed() by SVN::TxDelta::apply(),
1773         # (but $base does not,) so dup() it for reading in close_file
1774         open my $dup, '<&', $fh or croak $!;
1775         my $base = IO::File->new_tmpfile;
1776         $base->autoflush(1);
1777         if ($fb->{blob}) {
1778                 defined (my $pid = fork) or croak $!;
1779                 if (!$pid) {
1780                         open STDOUT, '>&', $base or croak $!;
1781                         print STDOUT 'link ' if ($fb->{mode_a} == 120000);
1782                         exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
1783                 }
1784                 waitpid $pid, 0;
1785                 croak $? if $?;
1786
1787                 if (defined $exp) {
1788                         seek $base, 0, 0 or croak $!;
1789                         my $md5 = Digest::MD5->new;
1790                         $md5->addfile($base);
1791                         my $got = $md5->hexdigest;
1792                         die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
1793                             "expected: $exp\n",
1794                             "     got: $got\n" if ($got ne $exp);
1795                 }
1796         }
1797         seek $base, 0, 0 or croak $!;
1798         $fb->{fh} = $dup;
1799         $fb->{base} = $base;
1800         [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
1801 }
1802
1803 sub close_file {
1804         my ($self, $fb, $exp) = @_;
1805         my $hash;
1806         my $path = $self->git_path($fb->{path});
1807         if (my $fh = $fb->{fh}) {
1808                 seek($fh, 0, 0) or croak $!;
1809                 my $md5 = Digest::MD5->new;
1810                 $md5->addfile($fh);
1811                 my $got = $md5->hexdigest;
1812                 die "Checksum mismatch: $path\n",
1813                     "expected: $exp\n    got: $got\n" if ($got ne $exp);
1814                 seek($fh, 0, 0) or croak $!;
1815                 if ($fb->{mode_b} == 120000) {
1816                         read($fh, my $buf, 5) == 5 or croak $!;
1817                         $buf eq 'link ' or die "$path has mode 120000",
1818                                                "but is not a link\n";
1819                 }
1820                 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
1821                 if (!$pid) {
1822                         open STDIN, '<&', $fh or croak $!;
1823                         exec qw/git-hash-object -w --stdin/ or croak $!;
1824                 }
1825                 chomp($hash = do { local $/; <$out> });
1826                 close $out or croak $!;
1827                 close $fh or croak $!;
1828                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
1829                 close $fb->{base} or croak $!;
1830         } else {
1831                 $hash = $fb->{blob} or die "no blob information\n";
1832         }
1833         $fb->{pool}->clear;
1834         $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
1835         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $self->{q};
1836         undef;
1837 }
1838
1839 sub abort_edit {
1840         my $self = shift;
1841         $self->{nr} = $self->{gii}->{nr};
1842         delete $self->{gii};
1843         $self->SUPER::abort_edit(@_);
1844 }
1845
1846 sub close_edit {
1847         my $self = shift;
1848         $self->{git_commit_ok} = 1;
1849         $self->{nr} = $self->{gii}->{nr};
1850         delete $self->{gii};
1851         $self->SUPER::close_edit(@_);
1852 }
1853
1854 package SVN::Git::Editor;
1855 use vars qw/@ISA/;
1856 use strict;
1857 use warnings;
1858 use Carp qw/croak/;
1859 use IO::File;
1860
1861 sub new {
1862         my $class = shift;
1863         my $git_svn = shift;
1864         my $self = SVN::Delta::Editor->new(@_);
1865         bless $self, $class;
1866         foreach (qw/svn_path r ra/) {
1867                 die "$_ required!\n" unless (defined $git_svn->{$_});
1868                 $self->{$_} = $git_svn->{$_};
1869         }
1870         $self->{pool} = SVN::Pool->new;
1871         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
1872         $self->{rm} = { };
1873         require Digest::MD5;
1874         return $self;
1875 }
1876
1877 sub split_path {
1878         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
1879 }
1880
1881 sub repo_path {
1882         (defined $_[1] && length $_[1]) ? $_[1] : ''
1883 }
1884
1885 sub url_path {
1886         my ($self, $path) = @_;
1887         $self->{ra}->{url} . '/' . $self->repo_path($path);
1888 }
1889
1890 sub rmdirs {
1891         my ($self, $tree_b) = @_;
1892         my $rm = $self->{rm};
1893         delete $rm->{''}; # we never delete the url we're tracking
1894         return unless %$rm;
1895
1896         foreach (keys %$rm) {
1897                 my @d = split m#/#, $_;
1898                 my $c = shift @d;
1899                 $rm->{$c} = 1;
1900                 while (@d) {
1901                         $c .= '/' . shift @d;
1902                         $rm->{$c} = 1;
1903                 }
1904         }
1905         delete $rm->{$self->{svn_path}};
1906         delete $rm->{''}; # we never delete the url we're tracking
1907         return unless %$rm;
1908
1909         my ($fh, $ctx) = command_output_pipe(
1910                                    qw/ls-tree --name-only -r -z/, $tree_b);
1911         local $/ = "\0";
1912         while (<$fh>) {
1913                 chomp;
1914                 my @dn = split m#/#, $_;
1915                 while (pop @dn) {
1916                         delete $rm->{join '/', @dn};
1917                 }
1918                 unless (%$rm) {
1919                         close $fh;
1920                         return;
1921                 }
1922         }
1923         command_close_pipe($fh, $ctx);
1924
1925         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
1926         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
1927                 $self->close_directory($bat->{$d}, $p);
1928                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
1929                 print "\tD+\t$d/\n" unless $::_q;
1930                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
1931                 delete $bat->{$d};
1932         }
1933 }
1934
1935 sub open_or_add_dir {
1936         my ($self, $full_path, $baton) = @_;
1937         my $t = $self->{ra}->check_path($full_path, $self->{r});
1938         if ($t == $SVN::Node::none) {
1939                 return $self->add_directory($full_path, $baton,
1940                                                 undef, -1, $self->{pool});
1941         } elsif ($t == $SVN::Node::dir) {
1942                 return $self->open_directory($full_path, $baton,
1943                                                 $self->{r}, $self->{pool});
1944         }
1945         print STDERR "$full_path already exists in repository at ",
1946                 "r$self->{r} and it is not a directory (",
1947                 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
1948         exit 1;
1949 }
1950
1951 sub ensure_path {
1952         my ($self, $path) = @_;
1953         my $bat = $self->{bat};
1954         $path = $self->repo_path($path);
1955         return $bat->{''} unless (length $path);
1956         my @p = split m#/+#, $path;
1957         my $c = shift @p;
1958         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
1959         while (@p) {
1960                 my $c0 = $c;
1961                 $c .= '/' . shift @p;
1962                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
1963         }
1964         return $bat->{$c};
1965 }
1966
1967 sub A {
1968         my ($self, $m) = @_;
1969         my ($dir, $file) = split_path($m->{file_b});
1970         my $pbat = $self->ensure_path($dir);
1971         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
1972                                         undef, -1);
1973         print "\tA\t$m->{file_b}\n" unless $::_q;
1974         $self->chg_file($fbat, $m);
1975         $self->close_file($fbat,undef,$self->{pool});
1976 }
1977
1978 sub C {
1979         my ($self, $m) = @_;
1980         my ($dir, $file) = split_path($m->{file_b});
1981         my $pbat = $self->ensure_path($dir);
1982         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
1983                                 $self->url_path($m->{file_a}), $self->{r});
1984         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
1985         $self->chg_file($fbat, $m);
1986         $self->close_file($fbat,undef,$self->{pool});
1987 }
1988
1989 sub delete_entry {
1990         my ($self, $path, $pbat) = @_;
1991         my $rpath = $self->repo_path($path);
1992         my ($dir, $file) = split_path($rpath);
1993         $self->{rm}->{$dir} = 1;
1994         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
1995 }
1996
1997 sub R {
1998         my ($self, $m) = @_;
1999         my ($dir, $file) = split_path($m->{file_b});
2000         my $pbat = $self->ensure_path($dir);
2001         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2002                                 $self->url_path($m->{file_a}), $self->{r});
2003         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
2004         $self->chg_file($fbat, $m);
2005         $self->close_file($fbat,undef,$self->{pool});
2006
2007         ($dir, $file) = split_path($m->{file_a});
2008         $pbat = $self->ensure_path($dir);
2009         $self->delete_entry($m->{file_a}, $pbat);
2010 }
2011
2012 sub M {
2013         my ($self, $m) = @_;
2014         my ($dir, $file) = split_path($m->{file_b});
2015         my $pbat = $self->ensure_path($dir);
2016         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
2017                                 $pbat,$self->{r},$self->{pool});
2018         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
2019         $self->chg_file($fbat, $m);
2020         $self->close_file($fbat,undef,$self->{pool});
2021 }
2022
2023 sub T { shift->M(@_) }
2024
2025 sub change_file_prop {
2026         my ($self, $fbat, $pname, $pval) = @_;
2027         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
2028 }
2029
2030 sub chg_file {
2031         my ($self, $fbat, $m) = @_;
2032         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
2033                 $self->change_file_prop($fbat,'svn:executable','*');
2034         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
2035                 $self->change_file_prop($fbat,'svn:executable',undef);
2036         }
2037         my $fh = IO::File->new_tmpfile or croak $!;
2038         if ($m->{mode_b} =~ /^120/) {
2039                 print $fh 'link ' or croak $!;
2040                 $self->change_file_prop($fbat,'svn:special','*');
2041         } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
2042                 $self->change_file_prop($fbat,'svn:special',undef);
2043         }
2044         defined(my $pid = fork) or croak $!;
2045         if (!$pid) {
2046                 open STDOUT, '>&', $fh or croak $!;
2047                 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
2048         }
2049         waitpid $pid, 0;
2050         croak $? if $?;
2051         $fh->flush == 0 or croak $!;
2052         seek $fh, 0, 0 or croak $!;
2053
2054         my $md5 = Digest::MD5->new;
2055         $md5->addfile($fh) or croak $!;
2056         seek $fh, 0, 0 or croak $!;
2057
2058         my $exp = $md5->hexdigest;
2059         my $pool = SVN::Pool->new;
2060         my $atd = $self->apply_textdelta($fbat, undef, $pool);
2061         my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
2062         die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
2063         $pool->clear;
2064
2065         close $fh or croak $!;
2066 }
2067
2068 sub D {
2069         my ($self, $m) = @_;
2070         my ($dir, $file) = split_path($m->{file_b});
2071         my $pbat = $self->ensure_path($dir);
2072         print "\tD\t$m->{file_b}\n" unless $::_q;
2073         $self->delete_entry($m->{file_b}, $pbat);
2074 }
2075
2076 sub close_edit {
2077         my ($self) = @_;
2078         my ($p,$bat) = ($self->{pool}, $self->{bat});
2079         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
2080                 $self->close_directory($bat->{$_}, $p);
2081         }
2082         $self->SUPER::close_edit($p);
2083         $p->clear;
2084 }
2085
2086 sub abort_edit {
2087         my ($self) = @_;
2088         $self->SUPER::abort_edit($self->{pool});
2089         $self->{pool}->clear;
2090 }
2091
2092 # this drives the editor
2093 sub apply_diff {
2094         my ($self, $tree_a, $tree_b) = @_;
2095         my @diff_tree = qw(diff-tree -z -r);
2096         if ($::_cp_similarity) {
2097                 push @diff_tree, "-C$::_cp_similarity";
2098         } else {
2099                 push @diff_tree, '-C';
2100         }
2101         push @diff_tree, '--find-copies-harder' if $::_find_copies_harder;
2102         push @diff_tree, "-l$::_l" if defined $::_l;
2103         push @diff_tree, $tree_a, $tree_b;
2104         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
2105         my $nl = $/;
2106         local $/ = "\0";
2107         my $state = 'meta';
2108         my @mods;
2109         while (<$diff_fh>) {
2110                 chomp $_; # this gets rid of the trailing "\0"
2111                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
2112                                         $::sha1\s($::sha1)\s
2113                                         ([MTCRAD])\d*$/xo) {
2114                         push @mods, {   mode_a => $1, mode_b => $2,
2115                                         sha1_b => $3, chg => $4 };
2116                         if ($4 =~ /^(?:C|R)$/) {
2117                                 $state = 'file_a';
2118                         } else {
2119                                 $state = 'file_b';
2120                         }
2121                 } elsif ($state eq 'file_a') {
2122                         my $x = $mods[$#mods] or croak "Empty array\n";
2123                         if ($x->{chg} !~ /^(?:C|R)$/) {
2124                                 croak "Error parsing $_, $x->{chg}\n";
2125                         }
2126                         $x->{file_a} = $_;
2127                         $state = 'file_b';
2128                 } elsif ($state eq 'file_b') {
2129                         my $x = $mods[$#mods] or croak "Empty array\n";
2130                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
2131                                 croak "Error parsing $_, $x->{chg}\n";
2132                         }
2133                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
2134                                 croak "Error parsing $_, $x->{chg}\n";
2135                         }
2136                         $x->{file_b} = $_;
2137                         $state = 'meta';
2138                 } else {
2139                         croak "Error parsing $_\n";
2140                 }
2141         }
2142         command_close_pipe($diff_fh, $ctx);
2143         $/ = $nl;
2144
2145         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
2146         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @mods) {
2147                 my $f = $m->{chg};
2148                 if (defined $o{$f}) {
2149                         $self->$f($m);
2150                 } else {
2151                         fatal("Invalid change type: $f\n");
2152                 }
2153         }
2154         $self->rmdirs($tree_b) if $::_rmdir;
2155         if (@mods == 0) {
2156                 $self->abort_edit;
2157         } else {
2158                 $self->close_edit;
2159         }
2160         \@mods;
2161 }
2162
2163 package Git::SVN::Ra;
2164 use vars qw/@ISA $config_dir/;
2165 use strict;
2166 use warnings;
2167 my ($can_do_switch);
2168 my %RA;
2169
2170 BEGIN {
2171         # enforce temporary pool usage for some simple functions
2172         my $e;
2173         foreach (qw/get_latest_revnum rev_proplist get_file
2174                     check_path get_dir get_uuid get_repos_root/) {
2175                 $e .= "sub $_ {
2176                         my \$self = shift;
2177                         my \$pool = SVN::Pool->new;
2178                         my \@ret = \$self->SUPER::$_(\@_,\$pool);
2179                         \$pool->clear;
2180                         wantarray ? \@ret : \$ret[0]; }\n";
2181         }
2182         eval $e;
2183 }
2184
2185 sub new {
2186         my ($class, $url) = @_;
2187         $url =~ s!/+$!!;
2188         return $RA{$url} if $RA{$url};
2189
2190         SVN::_Core::svn_config_ensure($config_dir, undef);
2191         my ($baton, $callbacks) = SVN::Core::auth_open_helper([
2192             SVN::Client::get_simple_provider(),
2193             SVN::Client::get_ssl_server_trust_file_provider(),
2194             SVN::Client::get_simple_prompt_provider(
2195               \&Git::SVN::Prompt::simple, 2),
2196             SVN::Client::get_ssl_client_cert_prompt_provider(
2197               \&Git::SVN::Prompt::ssl_client_cert, 2),
2198             SVN::Client::get_ssl_client_cert_pw_prompt_provider(
2199               \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
2200             SVN::Client::get_username_provider(),
2201             SVN::Client::get_ssl_server_trust_prompt_provider(
2202               \&Git::SVN::Prompt::ssl_server_trust),
2203             SVN::Client::get_username_prompt_provider(
2204               \&Git::SVN::Prompt::username, 2),
2205           ]);
2206         my $config = SVN::Core::config_get_config($config_dir);
2207         my $self = SVN::Ra->new(url => $url, auth => $baton,
2208                               config => $config,
2209                               pool => SVN::Pool->new,
2210                               auth_provider_callbacks => $callbacks);
2211         $self->{svn_path} = $url;
2212         $self->{repos_root} = $self->get_repos_root;
2213         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E/*##;
2214         $RA{$url} = bless $self, $class;
2215 }
2216
2217 sub DESTROY {
2218         # do not call the real DESTROY since we store ourselves in %RA
2219 }
2220
2221 sub dup {
2222         my ($self) = @_;
2223         my $dup = SVN::Ra->new(pool => SVN::Pool->new,
2224                                 map { $_ => $self->{$_} } qw/config url
2225                      auth auth_provider_callbacks repos_root svn_path/);
2226         bless $dup, ref $self;
2227 }
2228
2229 sub get_log {
2230         my ($self, @args) = @_;
2231         my $pool = SVN::Pool->new;
2232         splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
2233         my $ret = $self->SUPER::get_log(@args, $pool);
2234         $pool->clear;
2235         $ret;
2236 }
2237
2238 sub get_commit_editor {
2239         my ($self, $log, $cb, $pool) = @_;
2240         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
2241         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
2242 }
2243
2244 sub uuid {
2245         my ($self) = @_;
2246         $self->{uuid} ||= $self->get_uuid;
2247 }
2248
2249 sub gs_do_update {
2250         my ($self, $rev_a, $rev_b, $path, $recurse, $editor) = @_;
2251         my $pool = SVN::Pool->new;
2252         $editor->set_path_strip($path);
2253         my $reporter = $self->do_update($rev_b, $path, $recurse,
2254                                         $editor, $pool);
2255         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
2256         my $new = ($rev_a == $rev_b);
2257         $reporter->set_path('', $rev_a, $new, @lock, $pool);
2258         $reporter->finish_report($pool);
2259         $pool->clear;
2260         $editor->{git_commit_ok};
2261 }
2262
2263 sub gs_do_switch {
2264         my ($self, $rev_a, $rev_b, $path, $recurse, $url_b, $editor) = @_;
2265         my $pool = SVN::Pool->new;
2266         $editor->set_path_strip($path);
2267         my $reporter = $self->do_switch($rev_b, $path, $recurse,
2268                                         $url_b, $editor, $pool);
2269         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
2270         $reporter->set_path('', $rev_a, 0, @lock, $pool);
2271         $reporter->finish_report($pool);
2272         $pool->clear;
2273         $editor->{git_commit_ok};
2274 }
2275
2276 sub minimize_url {
2277         my ($self) = @_;
2278         return $self->{url} if ($self->{url} eq $self->{repos_root});
2279         my $url = $self->{repos_root};
2280         my @components = split(m!/!, $self->{svn_path});
2281         my $c = '';
2282         do {
2283                 $url .= "/$c" if length $c;
2284                 eval { (ref $self)->new($url)->get_latest_revnum };
2285         } while ($@ && ($c = shift @components));
2286         $url;
2287 }
2288
2289 sub can_do_switch {
2290         my $self = shift;
2291         unless (defined $can_do_switch) {
2292                 my $pool = SVN::Pool->new;
2293                 my $rep = eval {
2294                         $self->do_switch(1, '', 0, $self->{url},
2295                                          SVN::Delta::Editor->new, $pool);
2296                 };
2297                 if ($@) {
2298                         $can_do_switch = 0;
2299                 } else {
2300                         $rep->abort_report($pool);
2301                         $can_do_switch = 1;
2302                 }
2303                 $pool->clear;
2304         }
2305         $can_do_switch;
2306 }
2307
2308 package Git::SVN::Log;
2309 use strict;
2310 use warnings;
2311 use POSIX qw/strftime/;
2312 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
2313             %rusers $show_commit $incremental/;
2314 my $l_fmt;
2315
2316 sub cmt_showable {
2317         my ($c) = @_;
2318         return 1 if defined $c->{r};
2319         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
2320                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
2321                 my @log = command(qw/cat-file commit/, $c->{c});
2322                 shift @log while ($log[0] ne "\n");
2323                 shift @log;
2324                 @{$c->{l}} = grep !/^git-svn-id: /, @log;
2325
2326                 (undef, $c->{r}, undef) = ::extract_metadata(
2327                                 (grep(/^git-svn-id: /, @log))[-1]);
2328         }
2329         return defined $c->{r};
2330 }
2331
2332 sub log_use_color {
2333         return 1 if $color;
2334         my ($dc, $dcvar);
2335         $dcvar = 'color.diff';
2336         $dc = `git-config --get $dcvar`;
2337         if ($dc eq '') {
2338                 # nothing at all; fallback to "diff.color"
2339                 $dcvar = 'diff.color';
2340                 $dc = `git-config --get $dcvar`;
2341         }
2342         chomp($dc);
2343         if ($dc eq 'auto') {
2344                 my $pc;
2345                 $pc = `git-config --get color.pager`;
2346                 if ($pc eq '') {
2347                         # does not have it -- fallback to pager.color
2348                         $pc = `git-config --bool --get pager.color`;
2349                 }
2350                 else {
2351                         $pc = `git-config --bool --get color.pager`;
2352                         if ($?) {
2353                                 $pc = 'false';
2354                         }
2355                 }
2356                 chomp($pc);
2357                 if (-t *STDOUT || (defined $pager && $pc eq 'true')) {
2358                         return ($ENV{TERM} && $ENV{TERM} ne 'dumb');
2359                 }
2360                 return 0;
2361         }
2362         return 0 if $dc eq 'never';
2363         return 1 if $dc eq 'always';
2364         chomp($dc = `git-config --bool --get $dcvar`);
2365         return ($dc eq 'true');
2366 }
2367
2368 sub git_svn_log_cmd {
2369         my ($r_min, $r_max) = @_;
2370         my $gs = Git::SVN->_new;
2371         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
2372                    $gs->refname);
2373         push @cmd, '-r' unless $non_recursive;
2374         push @cmd, qw/--raw --name-status/ if $verbose;
2375         push @cmd, '--color' if log_use_color();
2376         return @cmd unless defined $r_max;
2377         if ($r_max == $r_min) {
2378                 push @cmd, '--max-count=1';
2379                 if (my $c = $gs->rev_db_get($r_max)) {
2380                         push @cmd, $c;
2381                 }
2382         } else {
2383                 my ($c_min, $c_max);
2384                 $c_max = $gs->rev_db_get($r_max);
2385                 $c_min = $gs->rev_db_get($r_min);
2386                 if (defined $c_min && defined $c_max) {
2387                         if ($r_max > $r_max) {
2388                                 push @cmd, "$c_min..$c_max";
2389                         } else {
2390                                 push @cmd, "$c_max..$c_min";
2391                         }
2392                 } elsif ($r_max > $r_min) {
2393                         push @cmd, $c_max;
2394                 } else {
2395                         push @cmd, $c_min;
2396                 }
2397         }
2398         return @cmd;
2399 }
2400
2401 # adapted from pager.c
2402 sub config_pager {
2403         $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
2404         if (!defined $pager) {
2405                 $pager = 'less';
2406         } elsif (length $pager == 0 || $pager eq 'cat') {
2407                 $pager = undef;
2408         }
2409 }
2410
2411 sub run_pager {
2412         return unless -t *STDOUT;
2413         pipe my $rfd, my $wfd or return;
2414         defined(my $pid = fork) or ::fatal "Can't fork: $!\n";
2415         if (!$pid) {
2416                 open STDOUT, '>&', $wfd or
2417                                      ::fatal "Can't redirect to stdout: $!\n";
2418                 return;
2419         }
2420         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!\n";
2421         $ENV{LESS} ||= 'FRSX';
2422         exec $pager or ::fatal "Can't run pager: $! ($pager)\n";
2423 }
2424
2425 sub get_author_info {
2426         my ($dest, $author, $t, $tz) = @_;
2427         $author =~ s/(?:^\s*|\s*$)//g;
2428         $dest->{a_raw} = $author;
2429         my $au;
2430         if ($::_authors) {
2431                 $au = $rusers{$author} || undef;
2432         }
2433         if (!$au) {
2434                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
2435         }
2436         $dest->{t} = $t;
2437         $dest->{tz} = $tz;
2438         $dest->{a} = $au;
2439         # Date::Parse isn't in the standard Perl distro :(
2440         if ($tz =~ s/^\+//) {
2441                 $t += ::tz_to_s_offset($tz);
2442         } elsif ($tz =~ s/^\-//) {
2443                 $t -= ::tz_to_s_offset($tz);
2444         }
2445         $dest->{t_utc} = $t;
2446 }
2447
2448 sub process_commit {
2449         my ($c, $r_min, $r_max, $defer) = @_;
2450         if (defined $r_min && defined $r_max) {
2451                 if ($r_min == $c->{r} && $r_min == $r_max) {
2452                         show_commit($c);
2453                         return 0;
2454                 }
2455                 return 1 if $r_min == $r_max;
2456                 if ($r_min < $r_max) {
2457                         # we need to reverse the print order
2458                         return 0 if (defined $limit && --$limit < 0);
2459                         push @$defer, $c;
2460                         return 1;
2461                 }
2462                 if ($r_min != $r_max) {
2463                         return 1 if ($r_min < $c->{r});
2464                         return 1 if ($r_max > $c->{r});
2465                 }
2466         }
2467         return 0 if (defined $limit && --$limit < 0);
2468         show_commit($c);
2469         return 1;
2470 }
2471
2472 sub show_commit {
2473         my $c = shift;
2474         if ($oneline) {
2475                 my $x = "\n";
2476                 if (my $l = $c->{l}) {
2477                         while ($l->[0] =~ /^\s*$/) { shift @$l }
2478                         $x = $l->[0];
2479                 }
2480                 $l_fmt ||= 'A' . length($c->{r});
2481                 print 'r',pack($l_fmt, $c->{r}),' | ';
2482                 print "$c->{c} | " if $show_commit;
2483                 print $x;
2484         } else {
2485                 show_commit_normal($c);
2486         }
2487 }
2488
2489 sub show_commit_changed_paths {
2490         my ($c) = @_;
2491         return unless $c->{changed};
2492         print "Changed paths:\n", @{$c->{changed}};
2493 }
2494
2495 sub show_commit_normal {
2496         my ($c) = @_;
2497         print '-' x72, "\nr$c->{r} | ";
2498         print "$c->{c} | " if $show_commit;
2499         print "$c->{a} | ", strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)",
2500                                  localtime($c->{t_utc})), ' | ';
2501         my $nr_line = 0;
2502
2503         if (my $l = $c->{l}) {
2504                 while ($l->[$#$l] eq "\n" && $#$l > 0
2505                                           && $l->[($#$l - 1)] eq "\n") {
2506                         pop @$l;
2507                 }
2508                 $nr_line = scalar @$l;
2509                 if (!$nr_line) {
2510                         print "1 line\n\n\n";
2511                 } else {
2512                         if ($nr_line == 1) {
2513                                 $nr_line = '1 line';
2514                         } else {
2515                                 $nr_line .= ' lines';
2516                         }
2517                         print $nr_line, "\n";
2518                         show_commit_changed_paths($c);
2519                         print "\n";
2520                         print $_ foreach @$l;
2521                 }
2522         } else {
2523                 print "1 line\n";
2524                 show_commit_changed_paths($c);
2525                 print "\n";
2526
2527         }
2528         foreach my $x (qw/raw diff/) {
2529                 if ($c->{$x}) {
2530                         print "\n";
2531                         print $_ foreach @{$c->{$x}}
2532                 }
2533         }
2534 }
2535
2536 sub cmd_show_log {
2537         my (@args) = @_;
2538         my ($r_min, $r_max);
2539         my $r_last = -1; # prevent dupes
2540         if (defined $TZ) {
2541                 $ENV{TZ} = $TZ;
2542         } else {
2543                 delete $ENV{TZ};
2544         }
2545         if (defined $::_revision) {
2546                 if ($::_revision =~ /^(\d+):(\d+)$/) {
2547                         ($r_min, $r_max) = ($1, $2);
2548                 } elsif ($::_revision =~ /^\d+$/) {
2549                         $r_min = $r_max = $::_revision;
2550                 } else {
2551                         ::fatal "-r$::_revision is not supported, use ",
2552                                 "standard \'git log\' arguments instead\n";
2553                 }
2554         }
2555
2556         config_pager();
2557         @args = (git_svn_log_cmd($r_min, $r_max), @args);
2558         my $log = command_output_pipe(@args);
2559         run_pager();
2560         my (@k, $c, $d);
2561         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
2562         while (<$log>) {
2563                 if (/^${esc_color}commit ($::sha1_short)/o) {
2564                         my $cmt = $1;
2565                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
2566                                 $r_last = $c->{r};
2567                                 process_commit($c, $r_min, $r_max, \@k) or
2568                                                                 goto out;
2569                         }
2570                         $d = undef;
2571                         $c = { c => $cmt };
2572                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
2573                         get_author_info($c, $1, $2, $3);
2574                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
2575                         # ignore
2576                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
2577                         push @{$c->{raw}}, $_;
2578                 } elsif (/^${esc_color}[ACRMDT]\t/) {
2579                         # we could add $SVN->{svn_path} here, but that requires
2580                         # remote access at the moment (repo_path_split)...
2581                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
2582                         push @{$c->{changed}}, $_;
2583                 } elsif (/^${esc_color}diff /o) {
2584                         $d = 1;
2585                         push @{$c->{diff}}, $_;
2586                 } elsif ($d) {
2587                         push @{$c->{diff}}, $_;
2588                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
2589                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
2590                 } elsif (s/^${esc_color}    //o) {
2591                         push @{$c->{l}}, $_;
2592                 }
2593         }
2594         if ($c && defined $c->{r} && $c->{r} != $r_last) {
2595                 $r_last = $c->{r};
2596                 process_commit($c, $r_min, $r_max, \@k);
2597         }
2598         if (@k) {
2599                 my $swap = $r_max;
2600                 $r_max = $r_min;
2601                 $r_min = $swap;
2602                 process_commit($_, $r_min, $r_max) foreach reverse @k;
2603         }
2604 out:
2605         close $log;
2606         print '-' x72,"\n" unless $incremental || $oneline;
2607 }
2608
2609 package Git::SVN::Migration;
2610 # these version numbers do NOT correspond to actual version numbers
2611 # of git nor git-svn.  They are just relative.
2612 #
2613 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
2614 #
2615 # v1 layout: .git/$id/info/url, refs/remotes/$id
2616 #
2617 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
2618 #
2619 # v3 layout: .git/svn/$id, refs/remotes/$id
2620 #            - info/url may remain for backwards compatibility
2621 #            - this is what we migrate up to this layout automatically,
2622 #            - this will be used by git svn init on single branches
2623 #
2624 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
2625 #            - this is only created for newly multi-init-ed
2626 #              repositories.  Similar in spirit to the
2627 #              --use-separate-remotes option in git-clone (now default)
2628 #            - we do not automatically migrate to this (following
2629 #              the example set by core git)
2630 use strict;
2631 use warnings;
2632 use Carp qw/croak/;
2633 use File::Path qw/mkpath/;
2634 use File::Basename qw/dirname basename/;
2635 use vars qw/$_minimize/;
2636
2637 sub migrate_from_v0 {
2638         my $git_dir = $ENV{GIT_DIR};
2639         return undef unless -d $git_dir;
2640         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
2641         my $migrated = 0;
2642         while (<$fh>) {
2643                 chomp;
2644                 my ($id, $orig_ref) = ($_, $_);
2645                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
2646                 next unless -f "$git_dir/$id/info/url";
2647                 my $new_ref = "refs/remotes/$id";
2648                 if (::verify_ref("$new_ref^0")) {
2649                         print STDERR "W: $orig_ref is probably an old ",
2650                                      "branch used by an ancient version of ",
2651                                      "git-svn.\n",
2652                                      "However, $new_ref also exists.\n",
2653                                      "We will not be able ",
2654                                      "to use this branch until this ",
2655                                      "ambiguity is resolved.\n";
2656                         next;
2657                 }
2658                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
2659                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
2660                 command_noisy('update-ref', $new_ref, $orig_ref);
2661                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
2662                 $migrated++;
2663         }
2664         command_close_pipe($fh, $ctx);
2665         print STDERR "Done migrating from v0 layout...\n" if $migrated;
2666         $migrated;
2667 }
2668
2669 sub migrate_from_v1 {
2670         my $git_dir = $ENV{GIT_DIR};
2671         my $migrated = 0;
2672         return $migrated unless -d $git_dir;
2673         my $svn_dir = "$git_dir/svn";
2674
2675         # just in case somebody used 'svn' as their $id at some point...
2676         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
2677
2678         print STDERR "Migrating from a git-svn v1 layout...\n";
2679         mkpath([$svn_dir]);
2680         print STDERR "Data from a previous version of git-svn exists, but\n\t",
2681                      "$svn_dir\n\t(required for this version ",
2682                      "($::VERSION) of git-svn) does not. exist\n";
2683         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
2684         while (<$fh>) {
2685                 my $x = $_;
2686                 next unless $x =~ s#^refs/remotes/##;
2687                 chomp $x;
2688                 next unless -f "$git_dir/$x/info/url";
2689                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
2690                 next unless $u;
2691                 my $dn = dirname("$git_dir/svn/$x");
2692                 mkpath([$dn]) unless -d $dn;
2693                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
2694                         mkpath(["$git_dir/svn/svn"]);
2695                         print STDERR " - $git_dir/$x/info => ",
2696                                         "$git_dir/svn/$x/info\n";
2697                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
2698                                croak "$!: $x";
2699                         # don't worry too much about these, they probably
2700                         # don't exist with repos this old (save for index,
2701                         # and we can easily regenerate that)
2702                         foreach my $f (qw/unhandled.log index .rev_db/) {
2703                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
2704                         }
2705                 } else {
2706                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
2707                         rename "$git_dir/$x", "$git_dir/svn/$x" or
2708                                croak "$!: $x";
2709                 }
2710                 $migrated++;
2711         }
2712         command_close_pipe($fh, $ctx);
2713         print STDERR "Done migrating from a git-svn v1 layout\n";
2714         $migrated;
2715 }
2716
2717 sub read_old_urls {
2718         my ($l_map, $pfx, $path) = @_;
2719         my @dir;
2720         foreach (<$path/*>) {
2721                 if (-r "$_/info/url") {
2722                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
2723                         my $ref_id = $pfx . basename $_;
2724                         my $url = ::file_to_s("$_/info/url");
2725                         $l_map->{$ref_id} = $url;
2726                 } elsif (-d $_) {
2727                         push @dir, $_;
2728                 }
2729         }
2730         foreach (@dir) {
2731                 my $x = $_;
2732                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
2733                 read_old_urls($l_map, $x, $_);
2734         }
2735 }
2736
2737 sub migrate_from_v2 {
2738         my @cfg = command(qw/config -l/);
2739         return if grep /^svn-remote\..+\.url=/, @cfg;
2740         my %l_map;
2741         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
2742         my $migrated = 0;
2743
2744         foreach my $ref_id (sort keys %l_map) {
2745                 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
2746                 $migrated++;
2747         }
2748         $migrated;
2749 }
2750
2751 sub minimize_connections {
2752         my $r = Git::SVN::read_all_remotes();
2753         my $new_urls = {};
2754         my $root_repos = {};
2755         foreach my $repo_id (keys %$r) {
2756                 my $url = $r->{$repo_id}->{url} or next;
2757                 my $fetch = $r->{$repo_id}->{fetch} or next;
2758                 my $ra = Git::SVN::Ra->new($url);
2759
2760                 # skip existing cases where we already connect to the root
2761                 if (($ra->{url} eq $ra->{repos_root}) ||
2762                     (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
2763                      $repo_id)) {
2764                         $root_repos->{$ra->{url}} = $repo_id;
2765                         next;
2766                 }
2767
2768                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
2769                 my $root_path = $ra->{url};
2770                 $root_path =~ s#^\Q$ra->{repos_root}\E/*##;
2771                 foreach my $path (keys %$fetch) {
2772                         my $ref_id = $fetch->{$path};
2773                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
2774
2775                         # make sure we can read when connecting to
2776                         # a higher level of a repository
2777                         my ($last_rev, undef) = $gs->last_rev_commit;
2778                         if (!defined $last_rev) {
2779                                 $last_rev = eval {
2780                                         $root_ra->get_latest_revnum;
2781                                 };
2782                                 next if $@;
2783                         }
2784                         my $new = $root_path;
2785                         $new .= length $path ? "/$path" : '';
2786                         eval {
2787                                 $root_ra->get_log([$new], $last_rev, $last_rev,
2788                                                   0, 0, 1, sub { });
2789                         };
2790                         next if $@;
2791                         $new_urls->{$ra->{repos_root}}->{$new} =
2792                                 { ref_id => $ref_id,
2793                                   old_repo_id => $repo_id,
2794                                   old_path => $path };
2795                 }
2796         }
2797
2798         my @emptied;
2799         foreach my $url (keys %$new_urls) {
2800                 # see if we can re-use an existing [svn-remote "repo_id"]
2801                 # instead of creating a(n ugly) new section:
2802                 my $repo_id = $root_repos->{$url} ||
2803                               Git::SVN::sanitize_remote_name($url);
2804
2805                 my $fetch = $new_urls->{$url};
2806                 foreach my $path (keys %$fetch) {
2807                         my $x = $fetch->{$path};
2808                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
2809                         my $pfx = "svn-remote.$x->{old_repo_id}";
2810
2811                         my $old_fetch = quotemeta("$x->{old_path}:".
2812                                                   "refs/remotes/$x->{ref_id}");
2813                         command_noisy(qw/config --unset/,
2814                                       "$pfx.fetch", '^'. $old_fetch . '$');
2815                         delete $r->{$x->{old_repo_id}}->
2816                                {fetch}->{$x->{old_path}};
2817                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
2818                                 command_noisy(qw/config --unset/,
2819                                               "$pfx.url");
2820                                 push @emptied, $x->{old_repo_id}
2821                         }
2822                 }
2823         }
2824         if (@emptied) {
2825                 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
2826                            "$ENV{GIT_DIR}/config";
2827                 print STDERR <<EOF;
2828 The following [svn-remote] sections in your config file ($file) are empty
2829 and can be safely removed:
2830 EOF
2831                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
2832         }
2833 }
2834
2835 sub migration_check {
2836         migrate_from_v0();
2837         migrate_from_v1();
2838         migrate_from_v2();
2839         minimize_connections() if $_minimize;
2840 }
2841
2842 package Git::IndexInfo;
2843 use strict;
2844 use warnings;
2845 use Git qw/command_input_pipe command_close_pipe/;
2846
2847 sub new {
2848         my ($class) = @_;
2849         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
2850         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
2851 }
2852
2853 sub remove {
2854         my ($self, $path) = @_;
2855         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
2856                 return ++$self->{nr};
2857         }
2858         undef;
2859 }
2860
2861 sub update {
2862         my ($self, $mode, $hash, $path) = @_;
2863         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
2864                 return ++$self->{nr};
2865         }
2866         undef;
2867 }
2868
2869 sub DESTROY {
2870         my ($self) = @_;
2871         command_close_pipe($self->{gui}, $self->{ctx});
2872 }
2873
2874 __END__
2875
2876 Data structures:
2877
2878 $log_entry hashref as returned by libsvn_log_entry()
2879 {
2880         log => 'whitespace-formatted log entry
2881 ',                                              # trailing newline is preserved
2882         revision => '8',                        # integer
2883         date => '2004-02-24T17:01:44.108345Z',  # commit date
2884         author => 'committer name'
2885 };
2886
2887 @mods = array of diff-index line hashes, each element represents one line
2888         of diff-index output
2889
2890 diff-index line ($m hash)
2891 {
2892         mode_a => first column of diff-index output, no leading ':',
2893         mode_b => second column of diff-index output,
2894         sha1_b => sha1sum of the final blob,
2895         chg => change type [MCRADT],
2896         file_a => original file name of a file (iff chg is 'C' or 'R')
2897         file_b => new/current file name of a file (any chg)
2898 }
2899 ;
2900
2901 # retval of read_url_paths{,_all}();
2902 $l_map = {
2903         # repository root url
2904         'https://svn.musicpd.org' => {
2905                 # repository path               # GIT_SVN_ID
2906                 'mpd/trunk'             =>      'trunk',
2907                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
2908         },
2909 }
2910
2911 Notes:
2912         I don't trust the each() function on unless I created %hash myself
2913         because the internal iterator may not have started at base.