git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Text::ParseWords;
  24 use Data::Dumper;
  25 use Term::ANSIColor;
  26 use File::Temp qw/ tempdir tempfile /;
  27 use File::Spec::Functions qw(catfile);
  28 use Error qw(:try);
  29 use Git;
  30
  31 Getopt::Long::Configure qw/ pass_through /;
  32
  33 package FakeTerm;
  34 sub new {
  35         my ($class, $reason) = @_;
  36         return bless \$reason, shift;
  37 }
  38 sub readline {
  39         my $self = shift;
  40         die "Cannot use readline on FakeTerm: $$self";
  41 }
  42 package main;
  43
  44
  45 sub usage {
  46         print <<EOT;
  47 git send-email [options] <file | directory | rev-list options >
  48
  49   Composing:
  50     --from                  <str>  * Email From:
  51     --[no-]to               <str>  * Email To:
  52     --[no-]cc               <str>  * Email Cc:
  53     --[no-]bcc              <str>  * Email Bcc:
  54     --subject               <str>  * Email "Subject:"
  55     --in-reply-to           <str>  * Email "In-Reply-To:"
  56     --annotate                     * Review each patch that will be sent in an editor.
  57     --compose                      * Open an editor for introduction.
  58     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  59
  60   Sending:
  61     --envelope-sender       <str>  * Email envelope sender.
  62     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  63                                      is optional. Default 'localhost'.
  64     --smtp-server-port      <int>  * Outgoing SMTP server port.
  65     --smtp-user             <str>  * Username for SMTP-AUTH.
  66     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  67     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  68     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  69     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  70     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  71
  72   Automating:
  73     --identity              <str>  * Use the sendemail.<id> options.
  74     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  75     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  76     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  77     --[no-]suppress-from           * Send to self. Default off.
  78     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  79     --[no-]thread                  * Use In-Reply-To: field. Default on.
  80
  81   Administering:
  82     --confirm               <str>  * Confirm recipients before sending;
  83                                      auto, cc, compose, always, or never.
  84     --quiet                        * Output one line of info per email.
  85     --dry-run                      * Don't actually send the emails.
  86     --[no-]validate                * Perform patch sanity checks. Default on.
  87     --[no-]format-patch            * understand any non optional arguments as
  88                                      `git format-patch` ones.
  89     --force                        * Send even if safety checks would prevent it.
  90
  91 EOT
  92         exit(1);
  93 }
  94
  95 # most mail servers generate the Date: header, but not all...
  96 sub format_2822_time {
  97         my ($time) = @_;
  98         my @localtm = localtime($time);
  99         my @gmttm = gmtime($time);
 100         my $localmin = $localtm[1] + $localtm[2] * 60;
 101         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 102         if ($localtm[0] != $gmttm[0]) {
 103                 die "local zone differs from GMT by a non-minute interval\n";
 104         }
 105         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 106                 $localmin += 1440;
 107         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 108                 $localmin -= 1440;
 109         } elsif ($gmttm[6] != $localtm[6]) {
 110                 die "local time offset greater than or equal to 24 hours\n";
 111         }
 112         my $offset = $localmin - $gmtmin;
 113         my $offhour = $offset / 60;
 114         my $offmin = abs($offset % 60);
 115         if (abs($offhour) >= 24) {
 116                 die ("local time offset greater than or equal to 24 hours\n");
 117         }
 118
 119         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 120                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 121                        $localtm[3],
 122                        qw(Jan Feb Mar Apr May Jun
 123                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 124                        $localtm[5]+1900,
 125                        $localtm[2],
 126                        $localtm[1],
 127                        $localtm[0],
 128                        ($offset >= 0) ? '+' : '-',
 129                        abs($offhour),
 130                        $offmin,
 131                        );
 132 }
 133
 134 my $have_email_valid = eval { require Email::Valid; 1 };
 135 my $have_mail_address = eval { require Mail::Address; 1 };
 136 my $smtp;
 137 my $auth;
 138
 139 # Variables we fill in automatically, or via prompting:
 140 my (@to,$no_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 141         $initial_reply_to,$initial_subject,@files,
 142         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 143
 144 my $envelope_sender;
 145
 146 # Example reply to:
 147 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 148
 149 my $repo = eval { Git->repository() };
 150 my @repo = $repo ? ($repo) : ();
 151 my $term = eval {
 152         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 153                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 154                 : new Term::ReadLine 'git-send-email';
 155 };
 156 if ($@) {
 157         $term = new FakeTerm "$@: going non-interactive";
 158 }
 159
 160 # Behavior modification variables
 161 my ($quiet, $dry_run) = (0, 0);
 162 my $format_patch;
 163 my $compose_filename;
 164 my $force = 0;
 165
 166 # Handle interactive edition of files.
 167 my $multiedit;
 168 my $editor;
 169
 170 sub do_edit {
 171         if (!defined($editor)) {
 172                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 173         }
 174         if (defined($multiedit) && !$multiedit) {
 175                 map {
 176                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 177                         if (($? & 127) || ($? >> 8)) {
 178                                 die("the editor exited uncleanly, aborting everything");
 179                         }
 180                 } @_;
 181         } else {
 182                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 183                 if (($? & 127) || ($? >> 8)) {
 184                         die("the editor exited uncleanly, aborting everything");
 185                 }
 186         }
 187 }
 188
 189 # Variables with corresponding config settings
 190 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 191 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 192 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts, $smtp_domain);
 193 my ($validate, $confirm);
 194 my (@suppress_cc);
 195 my ($auto_8bit_encoding);
 196
 197 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 198
 199 my $not_set_by_user = "true but not set by the user";
 200
 201 my %config_bool_settings = (
 202     "thread" => [\$thread, 1],
 203     "chainreplyto" => [\$chain_reply_to, $not_set_by_user],
 204     "suppressfrom" => [\$suppress_from, undef],
 205     "signedoffbycc" => [\$signed_off_by_cc, undef],
 206     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 207     "validate" => [\$validate, 1],
 208 );
 209
 210 my %config_settings = (
 211     "smtpserver" => \$smtp_server,
 212     "smtpserverport" => \$smtp_server_port,
 213     "smtpuser" => \$smtp_authuser,
 214     "smtppass" => \$smtp_authpass,
 215         "smtpdomain" => \$smtp_domain,
 216     "to" => \@to,
 217     "cc" => \@initial_cc,
 218     "cccmd" => \$cc_cmd,
 219     "aliasfiletype" => \$aliasfiletype,
 220     "bcc" => \@bcclist,
 221     "aliasesfile" => \@alias_files,
 222     "suppresscc" => \@suppress_cc,
 223     "envelopesender" => \$envelope_sender,
 224     "multiedit" => \$multiedit,
 225     "confirm"   => \$confirm,
 226     "from" => \$sender,
 227     "assume8bitencoding" => \$auto_8bit_encoding,
 228 );
 229
 230 # Help users prepare for 1.7.0
 231 sub chain_reply_to {
 232         if (defined $chain_reply_to &&
 233             $chain_reply_to eq $not_set_by_user) {
 234                 print STDERR
 235                     "In git 1.7.0, the default has changed to --no-chain-reply-to\n" .
 236                     "Set sendemail.chainreplyto configuration variable to true if\n" .
 237                     "you want to keep --chain-reply-to as your default.\n";
 238                 $chain_reply_to = 0;
 239         }
 240         return $chain_reply_to;
 241 }
 242
 243 # Handle Uncouth Termination
 244 sub signal_handler {
 245
 246         # Make text normal
 247         print color("reset"), "\n";
 248
 249         # SMTP password masked
 250         system "stty echo";
 251
 252         # tmp files from --compose
 253         if (defined $compose_filename) {
 254                 if (-e $compose_filename) {
 255                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 256                 }
 257                 if (-e ($compose_filename . ".final")) {
 258                         print "'$compose_filename.final' contains the composed email.\n"
 259                 }
 260         }
 261
 262         exit;
 263 };
 264
 265 $SIG{TERM} = \&signal_handler;
 266 $SIG{INT}  = \&signal_handler;
 267
 268 # Begin by accumulating all the variables (defined above), that we will end up
 269 # needing, first, from the command line:
 270
 271 my $rc = GetOptions("sender|from=s" => \$sender,
 272                     "in-reply-to=s" => \$initial_reply_to,
 273                     "subject=s" => \$initial_subject,
 274                     "to=s" => \@to,
 275                     "no-to" => \$no_to,
 276                     "cc=s" => \@initial_cc,
 277                     "no-cc" => \$no_cc,
 278                     "bcc=s" => \@bcclist,
 279                     "no-bcc" => \$no_bcc,
 280                     "chain-reply-to!" => \$chain_reply_to,
 281                     "smtp-server=s" => \$smtp_server,
 282                     "smtp-server-port=s" => \$smtp_server_port,
 283                     "smtp-user=s" => \$smtp_authuser,
 284                     "smtp-pass:s" => \$smtp_authpass,
 285                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 286                     "smtp-encryption=s" => \$smtp_encryption,
 287                     "smtp-debug:i" => \$debug_net_smtp,
 288                     "smtp-domain:s" => \$smtp_domain,
 289                     "identity=s" => \$identity,
 290                     "annotate" => \$annotate,
 291                     "compose" => \$compose,
 292                     "quiet" => \$quiet,
 293                     "cc-cmd=s" => \$cc_cmd,
 294                     "suppress-from!" => \$suppress_from,
 295                     "suppress-cc=s" => \@suppress_cc,
 296                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 297                     "confirm=s" => \$confirm,
 298                     "dry-run" => \$dry_run,
 299                     "envelope-sender=s" => \$envelope_sender,
 300                     "thread!" => \$thread,
 301                     "validate!" => \$validate,
 302                     "format-patch!" => \$format_patch,
 303                     "8bit-encoding=s" => \$auto_8bit_encoding,
 304                     "force" => \$force,
 305          );
 306
 307 unless ($rc) {
 308     usage();
 309 }
 310
 311 die "Cannot run git format-patch from outside a repository\n"
 312         if $format_patch and not $repo;
 313
 314 # Now, let's fill any that aren't set in with defaults:
 315
 316 sub read_config {
 317         my ($prefix) = @_;
 318
 319         foreach my $setting (keys %config_bool_settings) {
 320                 my $target = $config_bool_settings{$setting}->[0];
 321                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 322         }
 323
 324         foreach my $setting (keys %config_settings) {
 325                 my $target = $config_settings{$setting};
 326                 next if $setting eq "to" and defined $no_to;
 327                 next if $setting eq "cc" and defined $no_cc;
 328                 next if $setting eq "bcc" and defined $no_bcc;
 329                 if (ref($target) eq "ARRAY") {
 330                         unless (@$target) {
 331                                 my @values = Git::config(@repo, "$prefix.$setting");
 332                                 @$target = @values if (@values && defined $values[0]);
 333                         }
 334                 }
 335                 else {
 336                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 337                 }
 338         }
 339
 340         if (!defined $smtp_encryption) {
 341                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 342                 if (defined $enc) {
 343                         $smtp_encryption = $enc;
 344                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 345                         $smtp_encryption = 'ssl';
 346                 }
 347         }
 348 }
 349
 350 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 351 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 352 read_config("sendemail.$identity") if (defined $identity);
 353 read_config("sendemail");
 354
 355 # fall back on builtin bool defaults
 356 foreach my $setting (values %config_bool_settings) {
 357         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 358 }
 359
 360 # 'default' encryption is none -- this only prevents a warning
 361 $smtp_encryption = '' unless (defined $smtp_encryption);
 362
 363 # Set CC suppressions
 364 my(%suppress_cc);
 365 if (@suppress_cc) {
 366         foreach my $entry (@suppress_cc) {
 367                 die "Unknown --suppress-cc field: '$entry'\n"
 368                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 369                 $suppress_cc{$entry} = 1;
 370         }
 371 }
 372
 373 if ($suppress_cc{'all'}) {
 374         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 375                 $suppress_cc{$entry} = 1;
 376         }
 377         delete $suppress_cc{'all'};
 378 }
 379
 380 # If explicit old-style ones are specified, they trump --suppress-cc.
 381 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 382 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 383
 384 if ($suppress_cc{'body'}) {
 385         foreach my $entry (qw (sob bodycc)) {
 386                 $suppress_cc{$entry} = 1;
 387         }
 388         delete $suppress_cc{'body'};
 389 }
 390
 391 # Set confirm's default value
 392 my $confirm_unconfigured = !defined $confirm;
 393 if ($confirm_unconfigured) {
 394         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 395 };
 396 die "Unknown --confirm setting: '$confirm'\n"
 397         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 398
 399 # Debugging, print out the suppressions.
 400 if (0) {
 401         print "suppressions:\n";
 402         foreach my $entry (keys %suppress_cc) {
 403                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 404         }
 405 }
 406
 407 my ($repoauthor, $repocommitter);
 408 ($repoauthor) = Git::ident_person(@repo, 'author');
 409 ($repocommitter) = Git::ident_person(@repo, 'committer');
 410
 411 # Verify the user input
 412
 413 foreach my $entry (@to) {
 414         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 415 }
 416
 417 foreach my $entry (@initial_cc) {
 418         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 419 }
 420
 421 foreach my $entry (@bcclist) {
 422         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 423 }
 424
 425 sub parse_address_line {
 426         if ($have_mail_address) {
 427                 return map { $_->format } Mail::Address->parse($_[0]);
 428         } else {
 429                 return split_addrs($_[0]);
 430         }
 431 }
 432
 433 sub split_addrs {
 434         return quotewords('\s*,\s*', 1, @_);
 435 }
 436
 437 my %aliases;
 438 my %parse_alias = (
 439         # multiline formats can be supported in the future
 440         mutt => sub { my $fh = shift; while (<$fh>) {
 441                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 442                         my ($alias, $addr) = ($1, $2);
 443                         $addr =~ s/#.*$//; # mutt allows # comments
 444                          # commas delimit multiple addresses
 445                         $aliases{$alias} = [ split_addrs($addr) ];
 446                 }}},
 447         mailrc => sub { my $fh = shift; while (<$fh>) {
 448                 if (/^alias\s+(\S+)\s+(.*)$/) {
 449                         # spaces delimit multiple addresses
 450                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 451                 }}},
 452         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 453                 for (my $x = ''; defined($x); $x = $_) {
 454                         chomp $x;
 455                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 456                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 457                         $aliases{$1} = [ split_addrs($2) ];
 458                 }},
 459         elm => sub  { my $fh = shift;
 460                       while (<$fh>) {
 461                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 462                               my ($alias, $addr) = ($1, $2);
 463                                $aliases{$alias} = [ split_addrs($addr) ];
 464                           }
 465                       } },
 466
 467         gnus => sub { my $fh = shift; while (<$fh>) {
 468                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 469                         $aliases{$1} = [ $2 ];
 470                 }}}
 471 );
 472
 473 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 474         foreach my $file (@alias_files) {
 475                 open my $fh, '<', $file or die "opening $file: $!\n";
 476                 $parse_alias{$aliasfiletype}->($fh);
 477                 close $fh;
 478         }
 479 }
 480
 481 ($sender) = expand_aliases($sender) if defined $sender;
 482
 483 # returns 1 if the conflict must be solved using it as a format-patch argument
 484 sub check_file_rev_conflict($) {
 485         return unless $repo;
 486         my $f = shift;
 487         try {
 488                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 489                 if (defined($format_patch)) {
 490                         return $format_patch;
 491                 }
 492                 die(<<EOF);
 493 File '$f' exists but it could also be the range of commits
 494 to produce patches for.  Please disambiguate by...
 495
 496     * Saying "./$f" if you mean a file; or
 497     * Giving --format-patch option if you mean a range.
 498 EOF
 499         } catch Git::Error::Command with {
 500                 return 0;
 501         }
 502 }
 503
 504 # Now that all the defaults are set, process the rest of the command line
 505 # arguments and collect up the files that need to be processed.
 506 my @rev_list_opts;
 507 while (defined(my $f = shift @ARGV)) {
 508         if ($f eq "--") {
 509                 push @rev_list_opts, "--", @ARGV;
 510                 @ARGV = ();
 511         } elsif (-d $f and !check_file_rev_conflict($f)) {
 512                 opendir my $dh, $f
 513                         or die "Failed to opendir $f: $!";
 514
 515                 push @files, grep { -f $_ } map { catfile($f, $_) }
 516                                 sort readdir $dh;
 517                 closedir $dh;
 518         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 519                 push @files, $f;
 520         } else {
 521                 push @rev_list_opts, $f;
 522         }
 523 }
 524
 525 if (@rev_list_opts) {
 526         die "Cannot run git format-patch from outside a repository\n"
 527                 unless $repo;
 528         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 529 }
 530
 531 if ($validate) {
 532         foreach my $f (@files) {
 533                 unless (-p $f) {
 534                         my $error = validate_patch($f);
 535                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 536                 }
 537         }
 538 }
 539
 540 if (@files) {
 541         unless ($quiet) {
 542                 print $_,"\n" for (@files);
 543         }
 544 } else {
 545         print STDERR "\nNo patch files specified!\n\n";
 546         usage();
 547 }
 548
 549 sub get_patch_subject {
 550         my $fn = shift;
 551         open (my $fh, '<', $fn);
 552         while (my $line = <$fh>) {
 553                 next unless ($line =~ /^Subject: (.*)$/);
 554                 close $fh;
 555                 return "GIT: $1\n";
 556         }
 557         close $fh;
 558         die "No subject line in $fn ?";
 559 }
 560
 561 if ($compose) {
 562         # Note that this does not need to be secure, but we will make a small
 563         # effort to have it be unique
 564         $compose_filename = ($repo ?
 565                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 566                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 567         open my $c, ">", $compose_filename
 568                 or die "Failed to open for writing $compose_filename: $!";
 569
 570
 571         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 572         my $tpl_subject = $initial_subject || '';
 573         my $tpl_reply_to = $initial_reply_to || '';
 574
 575         print $c <<EOT;
 576 From $tpl_sender # This line is ignored.
 577 GIT: Lines beginning in "GIT:" will be removed.
 578 GIT: Consider including an overall diffstat or table of contents
 579 GIT: for the patch you are writing.
 580 GIT:
 581 GIT: Clear the body content if you don't wish to send a summary.
 582 From: $tpl_sender
 583 Subject: $tpl_subject
 584 In-Reply-To: $tpl_reply_to
 585
 586 EOT
 587         for my $f (@files) {
 588                 print $c get_patch_subject($f);
 589         }
 590         close $c;
 591
 592         if ($annotate) {
 593                 do_edit($compose_filename, @files);
 594         } else {
 595                 do_edit($compose_filename);
 596         }
 597
 598         open my $c2, ">", $compose_filename . ".final"
 599                 or die "Failed to open $compose_filename.final : " . $!;
 600
 601         open $c, "<", $compose_filename
 602                 or die "Failed to open $compose_filename : " . $!;
 603
 604         my $need_8bit_cte = file_has_nonascii($compose_filename);
 605         my $in_body = 0;
 606         my $summary_empty = 1;
 607         while(<$c>) {
 608                 next if m/^GIT:/;
 609                 if ($in_body) {
 610                         $summary_empty = 0 unless (/^\n$/);
 611                 } elsif (/^\n$/) {
 612                         $in_body = 1;
 613                         if ($need_8bit_cte) {
 614                                 print $c2 "MIME-Version: 1.0\n",
 615                                          "Content-Type: text/plain; ",
 616                                            "charset=UTF-8\n",
 617                                          "Content-Transfer-Encoding: 8bit\n";
 618                         }
 619                 } elsif (/^MIME-Version:/i) {
 620                         $need_8bit_cte = 0;
 621                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 622                         $initial_subject = $1;
 623                         my $subject = $initial_subject;
 624                         $_ = "Subject: " .
 625                                 ($subject =~ /[^[:ascii:]]/ ?
 626                                  quote_rfc2047($subject) :
 627                                  $subject) .
 628                                 "\n";
 629                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 630                         $initial_reply_to = $1;
 631                         next;
 632                 } elsif (/^From:\s*(.+)\s*$/i) {
 633                         $sender = $1;
 634                         next;
 635                 } elsif (/^(?:To|Cc|Bcc):/i) {
 636                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 637                         next;
 638                 }
 639                 print $c2 $_;
 640         }
 641         close $c;
 642         close $c2;
 643
 644         if ($summary_empty) {
 645                 print "Summary email is empty, skipping it\n";
 646                 $compose = -1;
 647         }
 648 } elsif ($annotate) {
 649         do_edit(@files);
 650 }
 651
 652 sub ask {
 653         my ($prompt, %arg) = @_;
 654         my $valid_re = $arg{valid_re};
 655         my $default = $arg{default};
 656         my $resp;
 657         my $i = 0;
 658         return defined $default ? $default : undef
 659                 unless defined $term->IN and defined fileno($term->IN) and
 660                        defined $term->OUT and defined fileno($term->OUT);
 661         while ($i++ < 10) {
 662                 $resp = $term->readline($prompt);
 663                 if (!defined $resp) { # EOF
 664                         print "\n";
 665                         return defined $default ? $default : undef;
 666                 }
 667                 if ($resp eq '' and defined $default) {
 668                         return $default;
 669                 }
 670                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 671                         return $resp;
 672                 }
 673         }
 674         return undef;
 675 }
 676
 677 my %broken_encoding;
 678
 679 sub file_declares_8bit_cte {
 680         my $fn = shift;
 681         open (my $fh, '<', $fn);
 682         while (my $line = <$fh>) {
 683                 last if ($line =~ /^$/);
 684                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 685         }
 686         close $fh;
 687         return 0;
 688 }
 689
 690 foreach my $f (@files) {
 691         next unless (body_or_subject_has_nonascii($f)
 692                      && !file_declares_8bit_cte($f));
 693         $broken_encoding{$f} = 1;
 694 }
 695
 696 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 697         print "The following files are 8bit, but do not declare " .
 698                 "a Content-Transfer-Encoding.\n";
 699         foreach my $f (sort keys %broken_encoding) {
 700                 print "    $f\n";
 701         }
 702         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 703                                   default => "UTF-8");
 704 }
 705
 706 if (!$force) {
 707         for my $f (@files) {
 708                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 709                         die "Refusing to send because the patch\n\t$f\n"
 710                                 . "has the template subject '*** SUBJECT HERE ***'. "
 711                                 . "Pass --force if you really want to send.\n";
 712                 }
 713         }
 714 }
 715
 716 my $prompting = 0;
 717 if (!defined $sender) {
 718         $sender = $repoauthor || $repocommitter || '';
 719         $sender = ask("Who should the emails appear to be from? [$sender] ",
 720                       default => $sender);
 721         print "Emails will be sent from: ", $sender, "\n";
 722         $prompting++;
 723 }
 724
 725 if (!@to) {
 726         my $to = ask("Who should the emails be sent to? ");
 727         push @to, parse_address_line($to) if defined $to; # sanitized/validated later
 728         $prompting++;
 729 }
 730
 731 sub expand_aliases {
 732         return map { expand_one_alias($_) } @_;
 733 }
 734
 735 my %EXPANDED_ALIASES;
 736 sub expand_one_alias {
 737         my $alias = shift;
 738         if ($EXPANDED_ALIASES{$alias}) {
 739                 die "fatal: alias '$alias' expands to itself\n";
 740         }
 741         local $EXPANDED_ALIASES{$alias} = 1;
 742         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 743 }
 744
 745 @to = expand_aliases(@to);
 746 @to = (map { sanitize_address($_) } @to);
 747 @initial_cc = expand_aliases(@initial_cc);
 748 @bcclist = expand_aliases(@bcclist);
 749
 750 if ($thread && !defined $initial_reply_to && $prompting) {
 751         $initial_reply_to = ask(
 752                 "Message-ID to be used as In-Reply-To for the first email? ");
 753 }
 754 if (defined $initial_reply_to) {
 755         $initial_reply_to =~ s/^\s*<?//;
 756         $initial_reply_to =~ s/>?\s*$//;
 757         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 758 }
 759
 760 if (!defined $smtp_server) {
 761         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 762                 if (-x $_) {
 763                         $smtp_server = $_;
 764                         last;
 765                 }
 766         }
 767         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 768 }
 769
 770 if ($compose && $compose > 0) {
 771         @files = ($compose_filename . ".final", @files);
 772 }
 773
 774 # Variables we set as part of the loop over files
 775 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 776         $needs_confirm, $message_num, $ask_default);
 777
 778 sub extract_valid_address {
 779         my $address = shift;
 780         my $local_part_regexp = '[^<>"\s@]+';
 781         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 782
 783         # check for a local address:
 784         return $address if ($address =~ /^($local_part_regexp)$/);
 785
 786         $address =~ s/^\s*<(.*)>\s*$/$1/;
 787         if ($have_email_valid) {
 788                 return scalar Email::Valid->address($address);
 789         } else {
 790                 # less robust/correct than the monster regexp in Email::Valid,
 791                 # but still does a 99% job, and one less dependency
 792                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 793                 return $1;
 794         }
 795 }
 796
 797 # Usually don't need to change anything below here.
 798
 799 # we make a "fake" message id by taking the current number
 800 # of seconds since the beginning of Unix time and tacking on
 801 # a random number to the end, in case we are called quicker than
 802 # 1 second since the last time we were called.
 803
 804 # We'll setup a template for the message id, using the "from" address:
 805
 806 my ($message_id_stamp, $message_id_serial);
 807 sub make_message_id {
 808         my $uniq;
 809         if (!defined $message_id_stamp) {
 810                 $message_id_stamp = sprintf("%s-%s", time, $$);
 811                 $message_id_serial = 0;
 812         }
 813         $message_id_serial++;
 814         $uniq = "$message_id_stamp-$message_id_serial";
 815
 816         my $du_part;
 817         for ($sender, $repocommitter, $repoauthor) {
 818                 $du_part = extract_valid_address(sanitize_address($_));
 819                 last if (defined $du_part and $du_part ne '');
 820         }
 821         if (not defined $du_part or $du_part eq '') {
 822                 use Sys::Hostname qw();
 823                 $du_part = 'user@' . Sys::Hostname::hostname();
 824         }
 825         my $message_id_template = "<%s-git-send-email-%s>";
 826         $message_id = sprintf($message_id_template, $uniq, $du_part);
 827         #print "new message id = $message_id\n"; # Was useful for debugging
 828 }
 829
 830
 831
 832 $time = time - scalar $#files;
 833
 834 sub unquote_rfc2047 {
 835         local ($_) = @_;
 836         my $encoding;
 837         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 838                 $encoding = $1;
 839                 s/_/ /g;
 840                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 841         }
 842         return wantarray ? ($_, $encoding) : $_;
 843 }
 844
 845 sub quote_rfc2047 {
 846         local $_ = shift;
 847         my $encoding = shift || 'UTF-8';
 848         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 849         s/(.*)/=\?$encoding\?q\?$1\?=/;
 850         return $_;
 851 }
 852
 853 sub is_rfc2047_quoted {
 854         my $s = shift;
 855         my $token = '[^][()<>@,;:"\/?.= \000-\037\177-\377]+';
 856         my $encoded_text = '[!->@-~]+';
 857         length($s) <= 75 &&
 858         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 859 }
 860
 861 # use the simplest quoting being able to handle the recipient
 862 sub sanitize_address {
 863         my ($recipient) = @_;
 864         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 865
 866         if (not $recipient_name) {
 867                 return $recipient;
 868         }
 869
 870         # if recipient_name is already quoted, do nothing
 871         if (is_rfc2047_quoted($recipient_name)) {
 872                 return $recipient;
 873         }
 874
 875         # rfc2047 is needed if a non-ascii char is included
 876         if ($recipient_name =~ /[^[:ascii:]]/) {
 877                 $recipient_name =~ s/^"(.*)"$/$1/;
 878                 $recipient_name = quote_rfc2047($recipient_name);
 879         }
 880
 881         # double quotes are needed if specials or CTLs are included
 882         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 883                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 884                 $recipient_name = qq["$recipient_name"];
 885         }
 886
 887         return "$recipient_name $recipient_addr";
 888
 889 }
 890
 891 # Returns the local Fully Qualified Domain Name (FQDN) if available.
 892 #
 893 # Tightly configured MTAa require that a caller sends a real DNS
 894 # domain name that corresponds the IP address in the HELO/EHLO
 895 # handshake. This is used to verify the connection and prevent
 896 # spammers from trying to hide their identity. If the DNS and IP don't
 897 # match, the receiveing MTA may deny the connection.
 898 #
 899 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
 900 #
 901 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
 902 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
 903 #
 904 # This maildomain*() code is based on ideas in Perl library Test::Reporter
 905 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
 906
 907 sub valid_fqdn {
 908         my $domain = shift;
 909         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
 910 }
 911
 912 sub maildomain_net {
 913         my $maildomain;
 914
 915         if (eval { require Net::Domain; 1 }) {
 916                 my $domain = Net::Domain::domainname();
 917                 $maildomain = $domain if valid_fqdn($domain);
 918         }
 919
 920         return $maildomain;
 921 }
 922
 923 sub maildomain_mta {
 924         my $maildomain;
 925
 926         if (eval { require Net::SMTP; 1 }) {
 927                 for my $host (qw(mailhost localhost)) {
 928                         my $smtp = Net::SMTP->new($host);
 929                         if (defined $smtp) {
 930                                 my $domain = $smtp->domain;
 931                                 $smtp->quit;
 932
 933                                 $maildomain = $domain if valid_fqdn($domain);
 934
 935                                 last if $maildomain;
 936                         }
 937                 }
 938         }
 939
 940         return $maildomain;
 941 }
 942
 943 sub maildomain {
 944         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
 945 }
 946
 947 # Returns 1 if the message was sent, and 0 otherwise.
 948 # In actuality, the whole program dies when there
 949 # is an error sending a message.
 950
 951 sub send_message {
 952         my @recipients = unique_email_list(@to);
 953         @cc = (grep { my $cc = extract_valid_address($_);
 954                       not grep { $cc eq $_ } @recipients
 955                     }
 956                map { sanitize_address($_) }
 957                @cc);
 958         my $to = join (",\n\t", @recipients);
 959         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 960         @recipients = (map { extract_valid_address($_) } @recipients);
 961         my $date = format_2822_time($time++);
 962         my $gitversion = '@@GIT_VERSION@@';
 963         if ($gitversion =~ m/..GIT_VERSION../) {
 964             $gitversion = Git::version();
 965         }
 966
 967         my $cc = join(",\n\t", unique_email_list(@cc));
 968         my $ccline = "";
 969         if ($cc ne '') {
 970                 $ccline = "\nCc: $cc";
 971         }
 972         my $sanitized_sender = sanitize_address($sender);
 973         make_message_id() unless defined($message_id);
 974
 975         my $header = "From: $sanitized_sender
 976 To: $to${ccline}
 977 Subject: $subject
 978 Date: $date
 979 Message-Id: $message_id
 980 X-Mailer: git-send-email $gitversion
 981 ";
 982         if ($reply_to) {
 983
 984                 $header .= "In-Reply-To: $reply_to\n";
 985                 $header .= "References: $references\n";
 986         }
 987         if (@xh) {
 988                 $header .= join("\n", @xh) . "\n";
 989         }
 990
 991         my @sendmail_parameters = ('-i', @recipients);
 992         my $raw_from = $sanitized_sender;
 993         if (defined $envelope_sender && $envelope_sender ne "auto") {
 994                 $raw_from = $envelope_sender;
 995         }
 996         $raw_from = extract_valid_address($raw_from);
 997         unshift (@sendmail_parameters,
 998                         '-f', $raw_from) if(defined $envelope_sender);
 999
1000         if ($needs_confirm && !$dry_run) {
1001                 print "\n$header\n";
1002                 if ($needs_confirm eq "inform") {
1003                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1004                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1005                         print "    The Cc list above has been expanded by additional\n";
1006                         print "    addresses found in the patch commit message. By default\n";
1007                         print "    send-email prompts before sending whenever this occurs.\n";
1008                         print "    This behavior is controlled by the sendemail.confirm\n";
1009                         print "    configuration setting.\n";
1010                         print "\n";
1011                         print "    For additional information, run 'git send-email --help'.\n";
1012                         print "    To retain the current behavior, but squelch this message,\n";
1013                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1014                 }
1015                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1016                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1017                          default => $ask_default);
1018                 die "Send this email reply required" unless defined $_;
1019                 if (/^n/i) {
1020                         return 0;
1021                 } elsif (/^q/i) {
1022                         cleanup_compose_files();
1023                         exit(0);
1024                 } elsif (/^a/i) {
1025                         $confirm = 'never';
1026                 }
1027         }
1028
1029         if ($dry_run) {
1030                 # We don't want to send the email.
1031         } elsif ($smtp_server =~ m#^/#) {
1032                 my $pid = open my $sm, '|-';
1033                 defined $pid or die $!;
1034                 if (!$pid) {
1035                         exec($smtp_server, @sendmail_parameters) or die $!;
1036                 }
1037                 print $sm "$header\n$message";
1038                 close $sm or die $?;
1039         } else {
1040
1041                 if (!defined $smtp_server) {
1042                         die "The required SMTP server is not properly defined."
1043                 }
1044
1045                 if ($smtp_encryption eq 'ssl') {
1046                         $smtp_server_port ||= 465; # ssmtp
1047                         require Net::SMTP::SSL;
1048                         $smtp_domain ||= maildomain();
1049                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1050                                                       Hello => $smtp_domain,
1051                                                       Port => $smtp_server_port);
1052                 }
1053                 else {
1054                         require Net::SMTP;
1055                         $smtp_domain ||= maildomain();
1056                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
1057                                                  ? "$smtp_server:$smtp_server_port"
1058                                                  : $smtp_server,
1059                                                  Hello => $smtp_domain,
1060                                                  Debug => $debug_net_smtp);
1061                         if ($smtp_encryption eq 'tls' && $smtp) {
1062                                 require Net::SMTP::SSL;
1063                                 $smtp->command('STARTTLS');
1064                                 $smtp->response();
1065                                 if ($smtp->code == 220) {
1066                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
1067                                                 or die "STARTTLS failed! ".$smtp->message;
1068                                         $smtp_encryption = '';
1069                                         # Send EHLO again to receive fresh
1070                                         # supported commands
1071                                         $smtp->hello();
1072                                 } else {
1073                                         die "Server does not support STARTTLS! ".$smtp->message;
1074                                 }
1075                         }
1076                 }
1077
1078                 if (!$smtp) {
1079                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1080                             "VALUES: server=$smtp_server ",
1081                             "encryption=$smtp_encryption ",
1082                             "hello=$smtp_domain",
1083                             defined $smtp_server_port ? "port=$smtp_server_port" : "";
1084                 }
1085
1086                 if (defined $smtp_authuser) {
1087
1088                         if (!defined $smtp_authpass) {
1089
1090                                 system "stty -echo";
1091
1092                                 do {
1093                                         print "Password: ";
1094                                         $_ = <STDIN>;
1095                                         print "\n";
1096                                 } while (!defined $_);
1097
1098                                 chomp($smtp_authpass = $_);
1099
1100                                 system "stty echo";
1101                         }
1102
1103                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
1104                 }
1105
1106                 $smtp->mail( $raw_from ) or die $smtp->message;
1107                 $smtp->to( @recipients ) or die $smtp->message;
1108                 $smtp->data or die $smtp->message;
1109                 $smtp->datasend("$header\n$message") or die $smtp->message;
1110                 $smtp->dataend() or die $smtp->message;
1111                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1112         }
1113         if ($quiet) {
1114                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1115         } else {
1116                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1117                 if ($smtp_server !~ m#^/#) {
1118                         print "Server: $smtp_server\n";
1119                         print "MAIL FROM:<$raw_from>\n";
1120                         foreach my $entry (@recipients) {
1121                             print "RCPT TO:<$entry>\n";
1122                         }
1123                 } else {
1124                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1125                 }
1126                 print $header, "\n";
1127                 if ($smtp) {
1128                         print "Result: ", $smtp->code, ' ',
1129                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1130                 } else {
1131                         print "Result: OK\n";
1132                 }
1133         }
1134
1135         return 1;
1136 }
1137
1138 $reply_to = $initial_reply_to;
1139 $references = $initial_reply_to || '';
1140 $subject = $initial_subject;
1141 $message_num = 0;
1142
1143 foreach my $t (@files) {
1144         open my $fh, "<", $t or die "can't open file $t";
1145
1146         my $author = undef;
1147         my $author_encoding;
1148         my $has_content_type;
1149         my $body_encoding;
1150         @cc = ();
1151         @xh = ();
1152         my $input_format = undef;
1153         my @header = ();
1154         $message = "";
1155         $message_num++;
1156         # First unfold multiline header fields
1157         while(<$fh>) {
1158                 last if /^\s*$/;
1159                 if (/^\s+\S/ and @header) {
1160                         chomp($header[$#header]);
1161                         s/^\s+/ /;
1162                         $header[$#header] .= $_;
1163             } else {
1164                         push(@header, $_);
1165                 }
1166         }
1167         # Now parse the header
1168         foreach(@header) {
1169                 if (/^From /) {
1170                         $input_format = 'mbox';
1171                         next;
1172                 }
1173                 chomp;
1174                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1175                         $input_format = 'mbox';
1176                 }
1177
1178                 if (defined $input_format && $input_format eq 'mbox') {
1179                         if (/^Subject:\s+(.*)$/) {
1180                                 $subject = $1;
1181                         }
1182                         elsif (/^From:\s+(.*)$/) {
1183                                 ($author, $author_encoding) = unquote_rfc2047($1);
1184                                 next if $suppress_cc{'author'};
1185                                 next if $suppress_cc{'self'} and $author eq $sender;
1186                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1187                                         $1, $_) unless $quiet;
1188                                 push @cc, $1;
1189                         }
1190                         elsif (/^Cc:\s+(.*)$/) {
1191                                 foreach my $addr (parse_address_line($1)) {
1192                                         if (unquote_rfc2047($addr) eq $sender) {
1193                                                 next if ($suppress_cc{'self'});
1194                                         } else {
1195                                                 next if ($suppress_cc{'cc'});
1196                                         }
1197                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1198                                                 $addr, $_) unless $quiet;
1199                                         push @cc, $addr;
1200                                 }
1201                         }
1202                         elsif (/^Content-type:/i) {
1203                                 $has_content_type = 1;
1204                                 if (/charset="?([^ "]+)/) {
1205                                         $body_encoding = $1;
1206                                 }
1207                                 push @xh, $_;
1208                         }
1209                         elsif (/^Message-Id: (.*)/i) {
1210                                 $message_id = $1;
1211                         }
1212                         elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1213                                 push @xh, $_;
1214                         }
1215
1216                 } else {
1217                         # In the traditional
1218                         # "send lots of email" format,
1219                         # line 1 = cc
1220                         # line 2 = subject
1221                         # So let's support that, too.
1222                         $input_format = 'lots';
1223                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1224                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1225                                         $_, $_) unless $quiet;
1226                                 push @cc, $_;
1227                         } elsif (!defined $subject) {
1228                                 $subject = $_;
1229                         }
1230                 }
1231         }
1232         # Now parse the message body
1233         while(<$fh>) {
1234                 $message .=  $_;
1235                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1236                         chomp;
1237                         my ($what, $c) = ($1, $2);
1238                         chomp $c;
1239                         if ($c eq $sender) {
1240                                 next if ($suppress_cc{'self'});
1241                         } else {
1242                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1243                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1244                         }
1245                         push @cc, $c;
1246                         printf("(body) Adding cc: %s from line '%s'\n",
1247                                 $c, $_) unless $quiet;
1248                 }
1249         }
1250         close $fh;
1251
1252         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1253                 open my $fh, "$cc_cmd \Q$t\E |"
1254                         or die "(cc-cmd) Could not execute '$cc_cmd'";
1255                 while(<$fh>) {
1256                         my $c = $_;
1257                         $c =~ s/^\s*//g;
1258                         $c =~ s/\n$//g;
1259                         next if ($c eq $sender and $suppress_from);
1260                         push @cc, $c;
1261                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1262                                 $c, $cc_cmd) unless $quiet;
1263                 }
1264                 close $fh
1265                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1266         }
1267
1268         if ($broken_encoding{$t} && !$has_content_type) {
1269                 $has_content_type = 1;
1270                 push @xh, "MIME-Version: 1.0",
1271                         "Content-Type: text/plain; charset=$auto_8bit_encoding",
1272                         "Content-Transfer-Encoding: 8bit";
1273                 $body_encoding = $auto_8bit_encoding;
1274         }
1275
1276         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1277                 $subject = quote_rfc2047($subject, $auto_8bit_encoding);
1278         }
1279
1280         if (defined $author and $author ne $sender) {
1281                 $message = "From: $author\n\n$message";
1282                 if (defined $author_encoding) {
1283                         if ($has_content_type) {
1284                                 if ($body_encoding eq $author_encoding) {
1285                                         # ok, we already have the right encoding
1286                                 }
1287                                 else {
1288                                         # uh oh, we should re-encode
1289                                 }
1290                         }
1291                         else {
1292                                 $has_content_type = 1;
1293                                 push @xh,
1294                                   'MIME-Version: 1.0',
1295                                   "Content-Type: text/plain; charset=$author_encoding",
1296                                   'Content-Transfer-Encoding: 8bit';
1297                         }
1298                 }
1299         }
1300
1301         $needs_confirm = (
1302                 $confirm eq "always" or
1303                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1304                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1305         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1306
1307         @cc = (@initial_cc, @cc);
1308
1309         my $message_was_sent = send_message();
1310
1311         # set up for the next message
1312         if ($thread && $message_was_sent &&
1313                 (chain_reply_to() || !defined $reply_to || length($reply_to) == 0)) {
1314                 $reply_to = $message_id;
1315                 if (length $references > 0) {
1316                         $references .= "\n $message_id";
1317                 } else {
1318                         $references = "$message_id";
1319                 }
1320         }
1321         $message_id = undef;
1322 }
1323
1324 cleanup_compose_files();
1325
1326 sub cleanup_compose_files {
1327         unlink($compose_filename, $compose_filename . ".final") if $compose;
1328 }
1329
1330 $smtp->quit if $smtp;
1331
1332 sub unique_email_list {
1333         my %seen;
1334         my @emails;
1335
1336         foreach my $entry (@_) {
1337                 if (my $clean = extract_valid_address($entry)) {
1338                         $seen{$clean} ||= 0;
1339                         next if $seen{$clean}++;
1340                         push @emails, $entry;
1341                 } else {
1342                         print STDERR "W: unable to extract a valid address",
1343                                         " from: $entry\n";
1344                 }
1345         }
1346         return @emails;
1347 }
1348
1349 sub validate_patch {
1350         my $fn = shift;
1351         open(my $fh, '<', $fn)
1352                 or die "unable to open $fn: $!\n";
1353         while (my $line = <$fh>) {
1354                 if (length($line) > 998) {
1355                         return "$.: patch contains a line longer than 998 characters";
1356                 }
1357         }
1358         return undef;
1359 }
1360
1361 sub file_has_nonascii {
1362         my $fn = shift;
1363         open(my $fh, '<', $fn)
1364                 or die "unable to open $fn: $!\n";
1365         while (my $line = <$fh>) {
1366                 return 1 if $line =~ /[^[:ascii:]]/;
1367         }
1368         return 0;
1369 }
1370
1371 sub body_or_subject_has_nonascii {
1372         my $fn = shift;
1373         open(my $fh, '<', $fn)
1374                 or die "unable to open $fn: $!\n";
1375         while (my $line = <$fh>) {
1376                 last if $line =~ /^$/;
1377                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1378         }
1379         while (my $line = <$fh>) {
1380                 return 1 if $line =~ /[^[:ascii:]]/;
1381         }
1382         return 0;
1383 }