git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Term::ANSIColor;
  26 use File::Temp qw/ tempdir tempfile /;
  27 use File::Spec::Functions qw(catfile);
  28 use Error qw(:try);
  29 use Git;
  30
  31 Getopt::Long::Configure qw/ pass_through /;
  32
  33 package FakeTerm;
  34 sub new {
  35         my ($class, $reason) = @_;
  36         return bless \$reason, shift;
  37 }
  38 sub readline {
  39         my $self = shift;
  40         die "Cannot use readline on FakeTerm: $$self";
  41 }
  42 package main;
  43
  44
  45 sub usage {
  46         print <<EOT;
  47 git send-email [options] <file | directory | rev-list options >
  48
  49   Composing:
  50     --from                  <str>  * Email From:
  51     --[no-]to               <str>  * Email To:
  52     --[no-]cc               <str>  * Email Cc:
  53     --[no-]bcc              <str>  * Email Bcc:
  54     --subject               <str>  * Email "Subject:"
  55     --in-reply-to           <str>  * Email "In-Reply-To:"
  56     --[no-]xmailer                 * Add "X-Mailer:" header (default).
  57     --[no-]annotate                * Review each patch that will be sent in an editor.
  58     --compose                      * Open an editor for introduction.
  59     --compose-encoding      <str>  * Encoding to assume for introduction.
  60     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  61     --transfer-encoding     <str>  * Transfer encoding to use (quoted-printable, 8bit, base64)
  62
  63   Sending:
  64     --envelope-sender       <str>  * Email envelope sender.
  65     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  66                                      is optional. Default 'localhost'.
  67     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  68     --smtp-server-port      <int>  * Outgoing SMTP server port.
  69     --smtp-user             <str>  * Username for SMTP-AUTH.
  70     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  71     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  72     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  73     --smtp-ssl-cert-path    <str>  * Path to ca-certificates (either directory or file).
  74                                      Pass an empty string to disable certificate
  75                                      verification.
  76     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  77     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  78
  79   Automating:
  80     --identity              <str>  * Use the sendemail.<id> options.
  81     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  82     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  83     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  84     --[no-]cc-cover                * Email Cc: addresses in the cover letter.
  85     --[no-]to-cover                * Email To: addresses in the cover letter.
  86     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  87     --[no-]suppress-from           * Send to self. Default off.
  88     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  89     --[no-]thread                  * Use In-Reply-To: field. Default on.
  90
  91   Administering:
  92     --confirm               <str>  * Confirm recipients before sending;
  93                                      auto, cc, compose, always, or never.
  94     --quiet                        * Output one line of info per email.
  95     --dry-run                      * Don't actually send the emails.
  96     --[no-]validate                * Perform patch sanity checks. Default on.
  97     --[no-]format-patch            * understand any non optional arguments as
  98                                      `git format-patch` ones.
  99     --force                        * Send even if safety checks would prevent it.
 100
 101 EOT
 102         exit(1);
 103 }
 104
 105 # most mail servers generate the Date: header, but not all...
 106 sub format_2822_time {
 107         my ($time) = @_;
 108         my @localtm = localtime($time);
 109         my @gmttm = gmtime($time);
 110         my $localmin = $localtm[1] + $localtm[2] * 60;
 111         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 112         if ($localtm[0] != $gmttm[0]) {
 113                 die "local zone differs from GMT by a non-minute interval\n";
 114         }
 115         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 116                 $localmin += 1440;
 117         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 118                 $localmin -= 1440;
 119         } elsif ($gmttm[6] != $localtm[6]) {
 120                 die "local time offset greater than or equal to 24 hours\n";
 121         }
 122         my $offset = $localmin - $gmtmin;
 123         my $offhour = $offset / 60;
 124         my $offmin = abs($offset % 60);
 125         if (abs($offhour) >= 24) {
 126                 die ("local time offset greater than or equal to 24 hours\n");
 127         }
 128
 129         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 130                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 131                        $localtm[3],
 132                        qw(Jan Feb Mar Apr May Jun
 133                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 134                        $localtm[5]+1900,
 135                        $localtm[2],
 136                        $localtm[1],
 137                        $localtm[0],
 138                        ($offset >= 0) ? '+' : '-',
 139                        abs($offhour),
 140                        $offmin,
 141                        );
 142 }
 143
 144 my $have_email_valid = eval { require Email::Valid; 1 };
 145 my $have_mail_address = eval { require Mail::Address; 1 };
 146 my $smtp;
 147 my $auth;
 148
 149 # Regexes for RFC 2047 productions.
 150 my $re_token = qr/[^][()<>@,;:\\"\/?.= \000-\037\177-\377]+/;
 151 my $re_encoded_text = qr/[^? \000-\037\177-\377]+/;
 152 my $re_encoded_word = qr/=\?($re_token)\?($re_token)\?($re_encoded_text)\?=/;
 153
 154 # Variables we fill in automatically, or via prompting:
 155 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 156         $initial_reply_to,$initial_subject,@files,
 157         $author,$sender,$smtp_authpass,$annotate,$use_xmailer,$compose,$time);
 158
 159 my $envelope_sender;
 160
 161 # Example reply to:
 162 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 163
 164 my $repo = eval { Git->repository() };
 165 my @repo = $repo ? ($repo) : ();
 166 my $term = eval {
 167         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 168                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 169                 : new Term::ReadLine 'git-send-email';
 170 };
 171 if ($@) {
 172         $term = new FakeTerm "$@: going non-interactive";
 173 }
 174
 175 # Behavior modification variables
 176 my ($quiet, $dry_run) = (0, 0);
 177 my $format_patch;
 178 my $compose_filename;
 179 my $force = 0;
 180
 181 # Handle interactive edition of files.
 182 my $multiedit;
 183 my $editor;
 184
 185 sub do_edit {
 186         if (!defined($editor)) {
 187                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 188         }
 189         if (defined($multiedit) && !$multiedit) {
 190                 map {
 191                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 192                         if (($? & 127) || ($? >> 8)) {
 193                                 die("the editor exited uncleanly, aborting everything");
 194                         }
 195                 } @_;
 196         } else {
 197                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 198                 if (($? & 127) || ($? >> 8)) {
 199                         die("the editor exited uncleanly, aborting everything");
 200                 }
 201         }
 202 }
 203
 204 # Variables with corresponding config settings
 205 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 206 my ($cover_cc, $cover_to);
 207 my ($to_cmd, $cc_cmd);
 208 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 209 my ($smtp_authuser, $smtp_encryption, $smtp_ssl_cert_path);
 210 my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
 211 my ($validate, $confirm);
 212 my (@suppress_cc);
 213 my ($auto_8bit_encoding);
 214 my ($compose_encoding);
 215 my ($target_xfer_encoding);
 216
 217 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 218
 219 my %config_bool_settings = (
 220     "thread" => [\$thread, 1],
 221     "chainreplyto" => [\$chain_reply_to, 0],
 222     "suppressfrom" => [\$suppress_from, undef],
 223     "signedoffbycc" => [\$signed_off_by_cc, undef],
 224     "cccover" => [\$cover_cc, undef],
 225     "tocover" => [\$cover_to, undef],
 226     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 227     "validate" => [\$validate, 1],
 228     "multiedit" => [\$multiedit, undef],
 229     "annotate" => [\$annotate, undef],
 230     "xmailer" => [\$use_xmailer, 1]
 231 );
 232
 233 my %config_settings = (
 234     "smtpserver" => \$smtp_server,
 235     "smtpserverport" => \$smtp_server_port,
 236     "smtpserveroption" => \@smtp_server_options,
 237     "smtpuser" => \$smtp_authuser,
 238     "smtppass" => \$smtp_authpass,
 239     "smtpsslcertpath" => \$smtp_ssl_cert_path,
 240     "smtpdomain" => \$smtp_domain,
 241     "to" => \@initial_to,
 242     "tocmd" => \$to_cmd,
 243     "cc" => \@initial_cc,
 244     "cccmd" => \$cc_cmd,
 245     "aliasfiletype" => \$aliasfiletype,
 246     "bcc" => \@bcclist,
 247     "suppresscc" => \@suppress_cc,
 248     "envelopesender" => \$envelope_sender,
 249     "confirm"   => \$confirm,
 250     "from" => \$sender,
 251     "assume8bitencoding" => \$auto_8bit_encoding,
 252     "composeencoding" => \$compose_encoding,
 253     "transferencoding" => \$target_xfer_encoding,
 254 );
 255
 256 my %config_path_settings = (
 257     "aliasesfile" => \@alias_files,
 258 );
 259
 260 # Handle Uncouth Termination
 261 sub signal_handler {
 262
 263         # Make text normal
 264         print color("reset"), "\n";
 265
 266         # SMTP password masked
 267         system "stty echo";
 268
 269         # tmp files from --compose
 270         if (defined $compose_filename) {
 271                 if (-e $compose_filename) {
 272                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 273                 }
 274                 if (-e ($compose_filename . ".final")) {
 275                         print "'$compose_filename.final' contains the composed email.\n"
 276                 }
 277         }
 278
 279         exit;
 280 };
 281
 282 $SIG{TERM} = \&signal_handler;
 283 $SIG{INT}  = \&signal_handler;
 284
 285 # Begin by accumulating all the variables (defined above), that we will end up
 286 # needing, first, from the command line:
 287
 288 my $help;
 289 my $rc = GetOptions("h" => \$help,
 290                     "sender|from=s" => \$sender,
 291                     "in-reply-to=s" => \$initial_reply_to,
 292                     "subject=s" => \$initial_subject,
 293                     "to=s" => \@initial_to,
 294                     "to-cmd=s" => \$to_cmd,
 295                     "no-to" => \$no_to,
 296                     "cc=s" => \@initial_cc,
 297                     "no-cc" => \$no_cc,
 298                     "bcc=s" => \@bcclist,
 299                     "no-bcc" => \$no_bcc,
 300                     "chain-reply-to!" => \$chain_reply_to,
 301                     "no-chain-reply-to" => sub {$chain_reply_to = 0},
 302                     "smtp-server=s" => \$smtp_server,
 303                     "smtp-server-option=s" => \@smtp_server_options,
 304                     "smtp-server-port=s" => \$smtp_server_port,
 305                     "smtp-user=s" => \$smtp_authuser,
 306                     "smtp-pass:s" => \$smtp_authpass,
 307                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 308                     "smtp-encryption=s" => \$smtp_encryption,
 309                     "smtp-ssl-cert-path=s" => \$smtp_ssl_cert_path,
 310                     "smtp-debug:i" => \$debug_net_smtp,
 311                     "smtp-domain:s" => \$smtp_domain,
 312                     "identity=s" => \$identity,
 313                     "annotate!" => \$annotate,
 314                     "no-annotate" => sub {$annotate = 0},
 315                     "compose" => \$compose,
 316                     "quiet" => \$quiet,
 317                     "cc-cmd=s" => \$cc_cmd,
 318                     "suppress-from!" => \$suppress_from,
 319                     "no-suppress-from" => sub {$suppress_from = 0},
 320                     "suppress-cc=s" => \@suppress_cc,
 321                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 322                     "no-signed-off-cc|no-signed-off-by-cc" => sub {$signed_off_by_cc = 0},
 323                     "cc-cover|cc-cover!" => \$cover_cc,
 324                     "no-cc-cover" => sub {$cover_cc = 0},
 325                     "to-cover|to-cover!" => \$cover_to,
 326                     "no-to-cover" => sub {$cover_to = 0},
 327                     "confirm=s" => \$confirm,
 328                     "dry-run" => \$dry_run,
 329                     "envelope-sender=s" => \$envelope_sender,
 330                     "thread!" => \$thread,
 331                     "no-thread" => sub {$thread = 0},
 332                     "validate!" => \$validate,
 333                     "no-validate" => sub {$validate = 0},
 334                     "transfer-encoding=s" => \$target_xfer_encoding,
 335                     "format-patch!" => \$format_patch,
 336                     "no-format-patch" => sub {$format_patch = 0},
 337                     "8bit-encoding=s" => \$auto_8bit_encoding,
 338                     "compose-encoding=s" => \$compose_encoding,
 339                     "force" => \$force,
 340                     "xmailer!" => \$use_xmailer,
 341                     "no-xmailer" => sub {$use_xmailer = 0},
 342          );
 343
 344 usage() if $help;
 345 unless ($rc) {
 346     usage();
 347 }
 348
 349 die "Cannot run git format-patch from outside a repository\n"
 350         if $format_patch and not $repo;
 351
 352 # Now, let's fill any that aren't set in with defaults:
 353
 354 sub read_config {
 355         my ($prefix) = @_;
 356
 357         foreach my $setting (keys %config_bool_settings) {
 358                 my $target = $config_bool_settings{$setting}->[0];
 359                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 360         }
 361
 362         foreach my $setting (keys %config_path_settings) {
 363                 my $target = $config_path_settings{$setting};
 364                 if (ref($target) eq "ARRAY") {
 365                         unless (@$target) {
 366                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 367                                 @$target = @values if (@values && defined $values[0]);
 368                         }
 369                 }
 370                 else {
 371                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 372                 }
 373         }
 374
 375         foreach my $setting (keys %config_settings) {
 376                 my $target = $config_settings{$setting};
 377                 next if $setting eq "to" and defined $no_to;
 378                 next if $setting eq "cc" and defined $no_cc;
 379                 next if $setting eq "bcc" and defined $no_bcc;
 380                 if (ref($target) eq "ARRAY") {
 381                         unless (@$target) {
 382                                 my @values = Git::config(@repo, "$prefix.$setting");
 383                                 @$target = @values if (@values && defined $values[0]);
 384                         }
 385                 }
 386                 else {
 387                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 388                 }
 389         }
 390
 391         if (!defined $smtp_encryption) {
 392                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 393                 if (defined $enc) {
 394                         $smtp_encryption = $enc;
 395                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 396                         $smtp_encryption = 'ssl';
 397                 }
 398         }
 399 }
 400
 401 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 402 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 403 read_config("sendemail.$identity") if (defined $identity);
 404 read_config("sendemail");
 405
 406 # fall back on builtin bool defaults
 407 foreach my $setting (values %config_bool_settings) {
 408         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 409 }
 410
 411 # 'default' encryption is none -- this only prevents a warning
 412 $smtp_encryption = '' unless (defined $smtp_encryption);
 413
 414 # Set CC suppressions
 415 my(%suppress_cc);
 416 if (@suppress_cc) {
 417         foreach my $entry (@suppress_cc) {
 418                 die "Unknown --suppress-cc field: '$entry'\n"
 419                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 420                 $suppress_cc{$entry} = 1;
 421         }
 422 }
 423
 424 if ($suppress_cc{'all'}) {
 425         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 426                 $suppress_cc{$entry} = 1;
 427         }
 428         delete $suppress_cc{'all'};
 429 }
 430
 431 # If explicit old-style ones are specified, they trump --suppress-cc.
 432 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 433 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 434
 435 if ($suppress_cc{'body'}) {
 436         foreach my $entry (qw (sob bodycc)) {
 437                 $suppress_cc{$entry} = 1;
 438         }
 439         delete $suppress_cc{'body'};
 440 }
 441
 442 # Set confirm's default value
 443 my $confirm_unconfigured = !defined $confirm;
 444 if ($confirm_unconfigured) {
 445         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 446 };
 447 die "Unknown --confirm setting: '$confirm'\n"
 448         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 449
 450 # Debugging, print out the suppressions.
 451 if (0) {
 452         print "suppressions:\n";
 453         foreach my $entry (keys %suppress_cc) {
 454                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 455         }
 456 }
 457
 458 my ($repoauthor, $repocommitter);
 459 ($repoauthor) = Git::ident_person(@repo, 'author');
 460 ($repocommitter) = Git::ident_person(@repo, 'committer');
 461
 462 # Verify the user input
 463
 464 foreach my $entry (@initial_to) {
 465         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 466 }
 467
 468 foreach my $entry (@initial_cc) {
 469         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 470 }
 471
 472 foreach my $entry (@bcclist) {
 473         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 474 }
 475
 476 sub parse_address_line {
 477         if ($have_mail_address) {
 478                 return map { $_->format } Mail::Address->parse($_[0]);
 479         } else {
 480                 return split_addrs($_[0]);
 481         }
 482 }
 483
 484 sub split_addrs {
 485         return quotewords('\s*,\s*', 1, @_);
 486 }
 487
 488 my %aliases;
 489 my %parse_alias = (
 490         # multiline formats can be supported in the future
 491         mutt => sub { my $fh = shift; while (<$fh>) {
 492                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 493                         my ($alias, $addr) = ($1, $2);
 494                         $addr =~ s/#.*$//; # mutt allows # comments
 495                          # commas delimit multiple addresses
 496                         $aliases{$alias} = [ split_addrs($addr) ];
 497                 }}},
 498         mailrc => sub { my $fh = shift; while (<$fh>) {
 499                 if (/^alias\s+(\S+)\s+(.*)$/) {
 500                         # spaces delimit multiple addresses
 501                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 502                 }}},
 503         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 504                 for (my $x = ''; defined($x); $x = $_) {
 505                         chomp $x;
 506                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 507                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 508                         $aliases{$1} = [ split_addrs($2) ];
 509                 }},
 510         elm => sub  { my $fh = shift;
 511                       while (<$fh>) {
 512                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 513                               my ($alias, $addr) = ($1, $2);
 514                                $aliases{$alias} = [ split_addrs($addr) ];
 515                           }
 516                       } },
 517
 518         gnus => sub { my $fh = shift; while (<$fh>) {
 519                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 520                         $aliases{$1} = [ $2 ];
 521                 }}}
 522 );
 523
 524 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 525         foreach my $file (@alias_files) {
 526                 open my $fh, '<', $file or die "opening $file: $!\n";
 527                 $parse_alias{$aliasfiletype}->($fh);
 528                 close $fh;
 529         }
 530 }
 531
 532 ($sender) = expand_aliases($sender) if defined $sender;
 533
 534 # is_format_patch_arg($f) returns 0 if $f names a patch, or 1 if
 535 # $f is a revision list specification to be passed to format-patch.
 536 sub is_format_patch_arg {
 537         return unless $repo;
 538         my $f = shift;
 539         try {
 540                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 541                 if (defined($format_patch)) {
 542                         return $format_patch;
 543                 }
 544                 die(<<EOF);
 545 File '$f' exists but it could also be the range of commits
 546 to produce patches for.  Please disambiguate by...
 547
 548     * Saying "./$f" if you mean a file; or
 549     * Giving --format-patch option if you mean a range.
 550 EOF
 551         } catch Git::Error::Command with {
 552                 # Not a valid revision.  Treat it as a filename.
 553                 return 0;
 554         }
 555 }
 556
 557 # Now that all the defaults are set, process the rest of the command line
 558 # arguments and collect up the files that need to be processed.
 559 my @rev_list_opts;
 560 while (defined(my $f = shift @ARGV)) {
 561         if ($f eq "--") {
 562                 push @rev_list_opts, "--", @ARGV;
 563                 @ARGV = ();
 564         } elsif (-d $f and !is_format_patch_arg($f)) {
 565                 opendir my $dh, $f
 566                         or die "Failed to opendir $f: $!";
 567
 568                 push @files, grep { -f $_ } map { catfile($f, $_) }
 569                                 sort readdir $dh;
 570                 closedir $dh;
 571         } elsif ((-f $f or -p $f) and !is_format_patch_arg($f)) {
 572                 push @files, $f;
 573         } else {
 574                 push @rev_list_opts, $f;
 575         }
 576 }
 577
 578 if (@rev_list_opts) {
 579         die "Cannot run git format-patch from outside a repository\n"
 580                 unless $repo;
 581         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 582 }
 583
 584 if ($validate) {
 585         foreach my $f (@files) {
 586                 unless (-p $f) {
 587                         my $error = validate_patch($f);
 588                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 589                 }
 590         }
 591 }
 592
 593 if (@files) {
 594         unless ($quiet) {
 595                 print $_,"\n" for (@files);
 596         }
 597 } else {
 598         print STDERR "\nNo patch files specified!\n\n";
 599         usage();
 600 }
 601
 602 sub get_patch_subject {
 603         my $fn = shift;
 604         open (my $fh, '<', $fn);
 605         while (my $line = <$fh>) {
 606                 next unless ($line =~ /^Subject: (.*)$/);
 607                 close $fh;
 608                 return "GIT: $1\n";
 609         }
 610         close $fh;
 611         die "No subject line in $fn ?";
 612 }
 613
 614 if ($compose) {
 615         # Note that this does not need to be secure, but we will make a small
 616         # effort to have it be unique
 617         $compose_filename = ($repo ?
 618                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 619                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 620         open my $c, ">", $compose_filename
 621                 or die "Failed to open for writing $compose_filename: $!";
 622
 623
 624         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 625         my $tpl_subject = $initial_subject || '';
 626         my $tpl_reply_to = $initial_reply_to || '';
 627
 628         print $c <<EOT;
 629 From $tpl_sender # This line is ignored.
 630 GIT: Lines beginning in "GIT:" will be removed.
 631 GIT: Consider including an overall diffstat or table of contents
 632 GIT: for the patch you are writing.
 633 GIT:
 634 GIT: Clear the body content if you don't wish to send a summary.
 635 From: $tpl_sender
 636 Subject: $tpl_subject
 637 In-Reply-To: $tpl_reply_to
 638
 639 EOT
 640         for my $f (@files) {
 641                 print $c get_patch_subject($f);
 642         }
 643         close $c;
 644
 645         if ($annotate) {
 646                 do_edit($compose_filename, @files);
 647         } else {
 648                 do_edit($compose_filename);
 649         }
 650
 651         open my $c2, ">", $compose_filename . ".final"
 652                 or die "Failed to open $compose_filename.final : " . $!;
 653
 654         open $c, "<", $compose_filename
 655                 or die "Failed to open $compose_filename : " . $!;
 656
 657         my $need_8bit_cte = file_has_nonascii($compose_filename);
 658         my $in_body = 0;
 659         my $summary_empty = 1;
 660         if (!defined $compose_encoding) {
 661                 $compose_encoding = "UTF-8";
 662         }
 663         while(<$c>) {
 664                 next if m/^GIT:/;
 665                 if ($in_body) {
 666                         $summary_empty = 0 unless (/^\n$/);
 667                 } elsif (/^\n$/) {
 668                         $in_body = 1;
 669                         if ($need_8bit_cte) {
 670                                 print $c2 "MIME-Version: 1.0\n",
 671                                          "Content-Type: text/plain; ",
 672                                            "charset=$compose_encoding\n",
 673                                          "Content-Transfer-Encoding: 8bit\n";
 674                         }
 675                 } elsif (/^MIME-Version:/i) {
 676                         $need_8bit_cte = 0;
 677                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 678                         $initial_subject = $1;
 679                         my $subject = $initial_subject;
 680                         $_ = "Subject: " .
 681                                 quote_subject($subject, $compose_encoding) .
 682                                 "\n";
 683                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 684                         $initial_reply_to = $1;
 685                         next;
 686                 } elsif (/^From:\s*(.+)\s*$/i) {
 687                         $sender = $1;
 688                         next;
 689                 } elsif (/^(?:To|Cc|Bcc):/i) {
 690                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 691                         next;
 692                 }
 693                 print $c2 $_;
 694         }
 695         close $c;
 696         close $c2;
 697
 698         if ($summary_empty) {
 699                 print "Summary email is empty, skipping it\n";
 700                 $compose = -1;
 701         }
 702 } elsif ($annotate) {
 703         do_edit(@files);
 704 }
 705
 706 sub ask {
 707         my ($prompt, %arg) = @_;
 708         my $valid_re = $arg{valid_re};
 709         my $default = $arg{default};
 710         my $confirm_only = $arg{confirm_only};
 711         my $resp;
 712         my $i = 0;
 713         return defined $default ? $default : undef
 714                 unless defined $term->IN and defined fileno($term->IN) and
 715                        defined $term->OUT and defined fileno($term->OUT);
 716         while ($i++ < 10) {
 717                 $resp = $term->readline($prompt);
 718                 if (!defined $resp) { # EOF
 719                         print "\n";
 720                         return defined $default ? $default : undef;
 721                 }
 722                 if ($resp eq '' and defined $default) {
 723                         return $default;
 724                 }
 725                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 726                         return $resp;
 727                 }
 728                 if ($confirm_only) {
 729                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 730                         if (defined $yesno && $yesno =~ /y/i) {
 731                                 return $resp;
 732                         }
 733                 }
 734         }
 735         return;
 736 }
 737
 738 my %broken_encoding;
 739
 740 sub file_declares_8bit_cte {
 741         my $fn = shift;
 742         open (my $fh, '<', $fn);
 743         while (my $line = <$fh>) {
 744                 last if ($line =~ /^$/);
 745                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 746         }
 747         close $fh;
 748         return 0;
 749 }
 750
 751 foreach my $f (@files) {
 752         next unless (body_or_subject_has_nonascii($f)
 753                      && !file_declares_8bit_cte($f));
 754         $broken_encoding{$f} = 1;
 755 }
 756
 757 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 758         print "The following files are 8bit, but do not declare " .
 759                 "a Content-Transfer-Encoding.\n";
 760         foreach my $f (sort keys %broken_encoding) {
 761                 print "    $f\n";
 762         }
 763         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 764                                   valid_re => qr/.{4}/, confirm_only => 1,
 765                                   default => "UTF-8");
 766 }
 767
 768 if (!$force) {
 769         for my $f (@files) {
 770                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 771                         die "Refusing to send because the patch\n\t$f\n"
 772                                 . "has the template subject '*** SUBJECT HERE ***'. "
 773                                 . "Pass --force if you really want to send.\n";
 774                 }
 775         }
 776 }
 777
 778 if (!defined $sender) {
 779         $sender = $repoauthor || $repocommitter || '';
 780 }
 781
 782 # $sender could be an already sanitized address
 783 # (e.g. sendemail.from could be manually sanitized by user).
 784 # But it's a no-op to run sanitize_address on an already sanitized address.
 785 $sender = sanitize_address($sender);
 786
 787 my $prompting = 0;
 788 if (!@initial_to && !defined $to_cmd) {
 789         my $to = ask("Who should the emails be sent to (if any)? ",
 790                      default => "",
 791                      valid_re => qr/\@.*\./, confirm_only => 1);
 792         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 793         $prompting++;
 794 }
 795
 796 sub expand_aliases {
 797         return map { expand_one_alias($_) } @_;
 798 }
 799
 800 my %EXPANDED_ALIASES;
 801 sub expand_one_alias {
 802         my $alias = shift;
 803         if ($EXPANDED_ALIASES{$alias}) {
 804                 die "fatal: alias '$alias' expands to itself\n";
 805         }
 806         local $EXPANDED_ALIASES{$alias} = 1;
 807         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 808 }
 809
 810 @initial_to = expand_aliases(@initial_to);
 811 @initial_to = validate_address_list(sanitize_address_list(@initial_to));
 812 @initial_cc = expand_aliases(@initial_cc);
 813 @initial_cc = validate_address_list(sanitize_address_list(@initial_cc));
 814 @bcclist = expand_aliases(@bcclist);
 815 @bcclist = validate_address_list(sanitize_address_list(@bcclist));
 816
 817 if ($thread && !defined $initial_reply_to && $prompting) {
 818         $initial_reply_to = ask(
 819                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 820                 default => "",
 821                 valid_re => qr/\@.*\./, confirm_only => 1);
 822 }
 823 if (defined $initial_reply_to) {
 824         $initial_reply_to =~ s/^\s*<?//;
 825         $initial_reply_to =~ s/>?\s*$//;
 826         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 827 }
 828
 829 if (!defined $smtp_server) {
 830         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 831                 if (-x $_) {
 832                         $smtp_server = $_;
 833                         last;
 834                 }
 835         }
 836         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 837 }
 838
 839 if ($compose && $compose > 0) {
 840         @files = ($compose_filename . ".final", @files);
 841 }
 842
 843 # Variables we set as part of the loop over files
 844 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 845         $needs_confirm, $message_num, $ask_default);
 846
 847 sub extract_valid_address {
 848         my $address = shift;
 849         my $local_part_regexp = qr/[^<>"\s@]+/;
 850         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 851
 852         # check for a local address:
 853         return $address if ($address =~ /^($local_part_regexp)$/);
 854
 855         $address =~ s/^\s*<(.*)>\s*$/$1/;
 856         if ($have_email_valid) {
 857                 return scalar Email::Valid->address($address);
 858         }
 859
 860         # less robust/correct than the monster regexp in Email::Valid,
 861         # but still does a 99% job, and one less dependency
 862         return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
 863         return;
 864 }
 865
 866 sub extract_valid_address_or_die {
 867         my $address = shift;
 868         $address = extract_valid_address($address);
 869         die "error: unable to extract a valid address from: $address\n"
 870                 if !$address;
 871         return $address;
 872 }
 873
 874 sub validate_address {
 875         my $address = shift;
 876         while (!extract_valid_address($address)) {
 877                 print STDERR "error: unable to extract a valid address from: $address\n";
 878                 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
 879                         valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
 880                         default => 'q');
 881                 if (/^d/i) {
 882                         return undef;
 883                 } elsif (/^q/i) {
 884                         cleanup_compose_files();
 885                         exit(0);
 886                 }
 887                 $address = ask("Who should the email be sent to (if any)? ",
 888                         default => "",
 889                         valid_re => qr/\@.*\./, confirm_only => 1);
 890         }
 891         return $address;
 892 }
 893
 894 sub validate_address_list {
 895         return (grep { defined $_ }
 896                 map { validate_address($_) } @_);
 897 }
 898
 899 # Usually don't need to change anything below here.
 900
 901 # we make a "fake" message id by taking the current number
 902 # of seconds since the beginning of Unix time and tacking on
 903 # a random number to the end, in case we are called quicker than
 904 # 1 second since the last time we were called.
 905
 906 # We'll setup a template for the message id, using the "from" address:
 907
 908 my ($message_id_stamp, $message_id_serial);
 909 sub make_message_id {
 910         my $uniq;
 911         if (!defined $message_id_stamp) {
 912                 $message_id_stamp = sprintf("%s-%s", time, $$);
 913                 $message_id_serial = 0;
 914         }
 915         $message_id_serial++;
 916         $uniq = "$message_id_stamp-$message_id_serial";
 917
 918         my $du_part;
 919         for ($sender, $repocommitter, $repoauthor) {
 920                 $du_part = extract_valid_address(sanitize_address($_));
 921                 last if (defined $du_part and $du_part ne '');
 922         }
 923         if (not defined $du_part or $du_part eq '') {
 924                 require Sys::Hostname;
 925                 $du_part = 'user@' . Sys::Hostname::hostname();
 926         }
 927         my $message_id_template = "<%s-git-send-email-%s>";
 928         $message_id = sprintf($message_id_template, $uniq, $du_part);
 929         #print "new message id = $message_id\n"; # Was useful for debugging
 930 }
 931
 932
 933
 934 $time = time - scalar $#files;
 935
 936 sub unquote_rfc2047 {
 937         local ($_) = @_;
 938         my $charset;
 939         my $sep = qr/[ \t]+/;
 940         s{$re_encoded_word(?:$sep$re_encoded_word)*}{
 941                 my @words = split $sep, $&;
 942                 foreach (@words) {
 943                         m/$re_encoded_word/;
 944                         $charset = $1;
 945                         my $encoding = $2;
 946                         my $text = $3;
 947                         if ($encoding eq 'q' || $encoding eq 'Q') {
 948                                 $_ = $text;
 949                                 s/_/ /g;
 950                                 s/=([0-9A-F]{2})/chr(hex($1))/egi;
 951                         } else {
 952                                 # other encodings not supported yet
 953                         }
 954                 }
 955                 join '', @words;
 956         }eg;
 957         return wantarray ? ($_, $charset) : $_;
 958 }
 959
 960 sub quote_rfc2047 {
 961         local $_ = shift;
 962         my $encoding = shift || 'UTF-8';
 963         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 964         s/(.*)/=\?$encoding\?q\?$1\?=/;
 965         return $_;
 966 }
 967
 968 sub is_rfc2047_quoted {
 969         my $s = shift;
 970         length($s) <= 75 &&
 971         $s =~ m/^(?:"[[:ascii:]]*"|$re_encoded_word)$/o;
 972 }
 973
 974 sub subject_needs_rfc2047_quoting {
 975         my $s = shift;
 976
 977         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
 978 }
 979
 980 sub quote_subject {
 981         local $subject = shift;
 982         my $encoding = shift || 'UTF-8';
 983
 984         if (subject_needs_rfc2047_quoting($subject)) {
 985                 return quote_rfc2047($subject, $encoding);
 986         }
 987         return $subject;
 988 }
 989
 990 # use the simplest quoting being able to handle the recipient
 991 sub sanitize_address {
 992         my ($recipient) = @_;
 993
 994         # remove garbage after email address
 995         $recipient =~ s/(.*>).*$/$1/;
 996
 997         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 998
 999         if (not $recipient_name) {
1000                 return $recipient;
1001         }
1002
1003         # if recipient_name is already quoted, do nothing
1004         if (is_rfc2047_quoted($recipient_name)) {
1005                 return $recipient;
1006         }
1007
1008         # rfc2047 is needed if a non-ascii char is included
1009         if ($recipient_name =~ /[^[:ascii:]]/) {
1010                 $recipient_name =~ s/^"(.*)"$/$1/;
1011                 $recipient_name = quote_rfc2047($recipient_name);
1012         }
1013
1014         # double quotes are needed if specials or CTLs are included
1015         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
1016                 $recipient_name =~ s/(["\\\r])/\\$1/g;
1017                 $recipient_name = qq["$recipient_name"];
1018         }
1019
1020         return "$recipient_name $recipient_addr";
1021
1022 }
1023
1024 sub sanitize_address_list {
1025         return (map { sanitize_address($_) } @_);
1026 }
1027
1028 # Returns the local Fully Qualified Domain Name (FQDN) if available.
1029 #
1030 # Tightly configured MTAa require that a caller sends a real DNS
1031 # domain name that corresponds the IP address in the HELO/EHLO
1032 # handshake. This is used to verify the connection and prevent
1033 # spammers from trying to hide their identity. If the DNS and IP don't
1034 # match, the receiveing MTA may deny the connection.
1035 #
1036 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
1037 #
1038 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
1039 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
1040 #
1041 # This maildomain*() code is based on ideas in Perl library Test::Reporter
1042 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1043
1044 sub valid_fqdn {
1045         my $domain = shift;
1046         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1047 }
1048
1049 sub maildomain_net {
1050         my $maildomain;
1051
1052         if (eval { require Net::Domain; 1 }) {
1053                 my $domain = Net::Domain::domainname();
1054                 $maildomain = $domain if valid_fqdn($domain);
1055         }
1056
1057         return $maildomain;
1058 }
1059
1060 sub maildomain_mta {
1061         my $maildomain;
1062
1063         if (eval { require Net::SMTP; 1 }) {
1064                 for my $host (qw(mailhost localhost)) {
1065                         my $smtp = Net::SMTP->new($host);
1066                         if (defined $smtp) {
1067                                 my $domain = $smtp->domain;
1068                                 $smtp->quit;
1069
1070                                 $maildomain = $domain if valid_fqdn($domain);
1071
1072                                 last if $maildomain;
1073                         }
1074                 }
1075         }
1076
1077         return $maildomain;
1078 }
1079
1080 sub maildomain {
1081         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1082 }
1083
1084 sub smtp_host_string {
1085         if (defined $smtp_server_port) {
1086                 return "$smtp_server:$smtp_server_port";
1087         } else {
1088                 return $smtp_server;
1089         }
1090 }
1091
1092 # Returns 1 if authentication succeeded or was not necessary
1093 # (smtp_user was not specified), and 0 otherwise.
1094
1095 sub smtp_auth_maybe {
1096         if (!defined $smtp_authuser || $auth) {
1097                 return 1;
1098         }
1099
1100         # Workaround AUTH PLAIN/LOGIN interaction defect
1101         # with Authen::SASL::Cyrus
1102         eval {
1103                 require Authen::SASL;
1104                 Authen::SASL->import(qw(Perl));
1105         };
1106
1107         # TODO: Authentication may fail not because credentials were
1108         # invalid but due to other reasons, in which we should not
1109         # reject credentials.
1110         $auth = Git::credential({
1111                 'protocol' => 'smtp',
1112                 'host' => smtp_host_string(),
1113                 'username' => $smtp_authuser,
1114                 # if there's no password, "git credential fill" will
1115                 # give us one, otherwise it'll just pass this one.
1116                 'password' => $smtp_authpass
1117         }, sub {
1118                 my $cred = shift;
1119                 return !!$smtp->auth($cred->{'username'}, $cred->{'password'});
1120         });
1121
1122         return $auth;
1123 }
1124
1125 sub ssl_verify_params {
1126         eval {
1127                 require IO::Socket::SSL;
1128                 IO::Socket::SSL->import(qw/SSL_VERIFY_PEER SSL_VERIFY_NONE/);
1129         };
1130         if ($@) {
1131                 print STDERR "Not using SSL_VERIFY_PEER due to out-of-date IO::Socket::SSL.\n";
1132                 return;
1133         }
1134
1135         if (!defined $smtp_ssl_cert_path) {
1136                 # use the OpenSSL defaults
1137                 return (SSL_verify_mode => SSL_VERIFY_PEER());
1138         }
1139
1140         if ($smtp_ssl_cert_path eq "") {
1141                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1142         } elsif (-d $smtp_ssl_cert_path) {
1143                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1144                         SSL_ca_path => $smtp_ssl_cert_path);
1145         } elsif (-f $smtp_ssl_cert_path) {
1146                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1147                         SSL_ca_file => $smtp_ssl_cert_path);
1148         } else {
1149                 print STDERR "Not using SSL_VERIFY_PEER because the CA path does not exist.\n";
1150                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1151         }
1152 }
1153
1154 sub file_name_is_absolute {
1155         my ($path) = @_;
1156
1157         # msys does not grok DOS drive-prefixes
1158         if ($^O eq 'msys') {
1159                 return ($path =~ m#^/# || $path =~ m#^[a-zA-Z]\:#)
1160         }
1161
1162         require File::Spec::Functions;
1163         return File::Spec::Functions::file_name_is_absolute($path);
1164 }
1165
1166 # Returns 1 if the message was sent, and 0 otherwise.
1167 # In actuality, the whole program dies when there
1168 # is an error sending a message.
1169
1170 sub send_message {
1171         my @recipients = unique_email_list(@to);
1172         @cc = (grep { my $cc = extract_valid_address_or_die($_);
1173                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1174                     }
1175                @cc);
1176         my $to = join (",\n\t", @recipients);
1177         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1178         @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1179         my $date = format_2822_time($time++);
1180         my $gitversion = '@@GIT_VERSION@@';
1181         if ($gitversion =~ m/..GIT_VERSION../) {
1182             $gitversion = Git::version();
1183         }
1184
1185         my $cc = join(",\n\t", unique_email_list(@cc));
1186         my $ccline = "";
1187         if ($cc ne '') {
1188                 $ccline = "\nCc: $cc";
1189         }
1190         make_message_id() unless defined($message_id);
1191
1192         my $header = "From: $sender
1193 To: $to${ccline}
1194 Subject: $subject
1195 Date: $date
1196 Message-Id: $message_id
1197 ";
1198         if ($use_xmailer) {
1199                 $header .= "X-Mailer: git-send-email $gitversion\n";
1200         }
1201         if ($reply_to) {
1202
1203                 $header .= "In-Reply-To: $reply_to\n";
1204                 $header .= "References: $references\n";
1205         }
1206         if (@xh) {
1207                 $header .= join("\n", @xh) . "\n";
1208         }
1209
1210         my @sendmail_parameters = ('-i', @recipients);
1211         my $raw_from = $sender;
1212         if (defined $envelope_sender && $envelope_sender ne "auto") {
1213                 $raw_from = $envelope_sender;
1214         }
1215         $raw_from = extract_valid_address($raw_from);
1216         unshift (@sendmail_parameters,
1217                         '-f', $raw_from) if(defined $envelope_sender);
1218
1219         if ($needs_confirm && !$dry_run) {
1220                 print "\n$header\n";
1221                 if ($needs_confirm eq "inform") {
1222                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1223                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1224                         print "    The Cc list above has been expanded by additional\n";
1225                         print "    addresses found in the patch commit message. By default\n";
1226                         print "    send-email prompts before sending whenever this occurs.\n";
1227                         print "    This behavior is controlled by the sendemail.confirm\n";
1228                         print "    configuration setting.\n";
1229                         print "\n";
1230                         print "    For additional information, run 'git send-email --help'.\n";
1231                         print "    To retain the current behavior, but squelch this message,\n";
1232                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1233                 }
1234                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1235                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1236                          default => $ask_default);
1237                 die "Send this email reply required" unless defined $_;
1238                 if (/^n/i) {
1239                         return 0;
1240                 } elsif (/^q/i) {
1241                         cleanup_compose_files();
1242                         exit(0);
1243                 } elsif (/^a/i) {
1244                         $confirm = 'never';
1245                 }
1246         }
1247
1248         unshift (@sendmail_parameters, @smtp_server_options);
1249
1250         if ($dry_run) {
1251                 # We don't want to send the email.
1252         } elsif (file_name_is_absolute($smtp_server)) {
1253                 my $pid = open my $sm, '|-';
1254                 defined $pid or die $!;
1255                 if (!$pid) {
1256                         exec($smtp_server, @sendmail_parameters) or die $!;
1257                 }
1258                 print $sm "$header\n$message";
1259                 close $sm or die $!;
1260         } else {
1261
1262                 if (!defined $smtp_server) {
1263                         die "The required SMTP server is not properly defined."
1264                 }
1265
1266                 if ($smtp_encryption eq 'ssl') {
1267                         $smtp_server_port ||= 465; # ssmtp
1268                         require Net::SMTP::SSL;
1269                         $smtp_domain ||= maildomain();
1270                         require IO::Socket::SSL;
1271                         # Net::SMTP::SSL->new() does not forward any SSL options
1272                         IO::Socket::SSL::set_client_defaults(
1273                                 ssl_verify_params());
1274                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1275                                                       Hello => $smtp_domain,
1276                                                       Port => $smtp_server_port,
1277                                                       Debug => $debug_net_smtp);
1278                 }
1279                 else {
1280                         require Net::SMTP;
1281                         $smtp_domain ||= maildomain();
1282                         $smtp_server_port ||= 25;
1283                         $smtp ||= Net::SMTP->new($smtp_server,
1284                                                  Hello => $smtp_domain,
1285                                                  Debug => $debug_net_smtp,
1286                                                  Port => $smtp_server_port);
1287                         if ($smtp_encryption eq 'tls' && $smtp) {
1288                                 require Net::SMTP::SSL;
1289                                 $smtp->command('STARTTLS');
1290                                 $smtp->response();
1291                                 if ($smtp->code == 220) {
1292                                         $smtp = Net::SMTP::SSL->start_SSL($smtp,
1293                                                                           ssl_verify_params())
1294                                                 or die "STARTTLS failed! ".IO::Socket::SSL::errstr();
1295                                         $smtp_encryption = '';
1296                                         # Send EHLO again to receive fresh
1297                                         # supported commands
1298                                         $smtp->hello($smtp_domain);
1299                                 } else {
1300                                         die "Server does not support STARTTLS! ".$smtp->message;
1301                                 }
1302                         }
1303                 }
1304
1305                 if (!$smtp) {
1306                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1307                             "VALUES: server=$smtp_server ",
1308                             "encryption=$smtp_encryption ",
1309                             "hello=$smtp_domain",
1310                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1311                 }
1312
1313                 smtp_auth_maybe or die $smtp->message;
1314
1315                 $smtp->mail( $raw_from ) or die $smtp->message;
1316                 $smtp->to( @recipients ) or die $smtp->message;
1317                 $smtp->data or die $smtp->message;
1318                 $smtp->datasend("$header\n$message") or die $smtp->message;
1319                 $smtp->dataend() or die $smtp->message;
1320                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1321         }
1322         if ($quiet) {
1323                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1324         } else {
1325                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1326                 if (!file_name_is_absolute($smtp_server)) {
1327                         print "Server: $smtp_server\n";
1328                         print "MAIL FROM:<$raw_from>\n";
1329                         foreach my $entry (@recipients) {
1330                             print "RCPT TO:<$entry>\n";
1331                         }
1332                 } else {
1333                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1334                 }
1335                 print $header, "\n";
1336                 if ($smtp) {
1337                         print "Result: ", $smtp->code, ' ',
1338                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1339                 } else {
1340                         print "Result: OK\n";
1341                 }
1342         }
1343
1344         return 1;
1345 }
1346
1347 $reply_to = $initial_reply_to;
1348 $references = $initial_reply_to || '';
1349 $subject = $initial_subject;
1350 $message_num = 0;
1351
1352 foreach my $t (@files) {
1353         open my $fh, "<", $t or die "can't open file $t";
1354
1355         my $author = undef;
1356         my $sauthor = undef;
1357         my $author_encoding;
1358         my $has_content_type;
1359         my $body_encoding;
1360         my $xfer_encoding;
1361         my $has_mime_version;
1362         @to = ();
1363         @cc = ();
1364         @xh = ();
1365         my $input_format = undef;
1366         my @header = ();
1367         $message = "";
1368         $message_num++;
1369         # First unfold multiline header fields
1370         while(<$fh>) {
1371                 last if /^\s*$/;
1372                 if (/^\s+\S/ and @header) {
1373                         chomp($header[$#header]);
1374                         s/^\s+/ /;
1375                         $header[$#header] .= $_;
1376             } else {
1377                         push(@header, $_);
1378                 }
1379         }
1380         # Now parse the header
1381         foreach(@header) {
1382                 if (/^From /) {
1383                         $input_format = 'mbox';
1384                         next;
1385                 }
1386                 chomp;
1387                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1388                         $input_format = 'mbox';
1389                 }
1390
1391                 if (defined $input_format && $input_format eq 'mbox') {
1392                         if (/^Subject:\s+(.*)$/i) {
1393                                 $subject = $1;
1394                         }
1395                         elsif (/^From:\s+(.*)$/i) {
1396                                 ($author, $author_encoding) = unquote_rfc2047($1);
1397                                 $sauthor = sanitize_address($author);
1398                                 next if $suppress_cc{'author'};
1399                                 next if $suppress_cc{'self'} and $sauthor eq $sender;
1400                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1401                                         $1, $_) unless $quiet;
1402                                 push @cc, $1;
1403                         }
1404                         elsif (/^To:\s+(.*)$/i) {
1405                                 foreach my $addr (parse_address_line($1)) {
1406                                         printf("(mbox) Adding to: %s from line '%s'\n",
1407                                                 $addr, $_) unless $quiet;
1408                                         push @to, $addr;
1409                                 }
1410                         }
1411                         elsif (/^Cc:\s+(.*)$/i) {
1412                                 foreach my $addr (parse_address_line($1)) {
1413                                         my $qaddr = unquote_rfc2047($addr);
1414                                         my $saddr = sanitize_address($qaddr);
1415                                         if ($saddr eq $sender) {
1416                                                 next if ($suppress_cc{'self'});
1417                                         } else {
1418                                                 next if ($suppress_cc{'cc'});
1419                                         }
1420                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1421                                                 $addr, $_) unless $quiet;
1422                                         push @cc, $addr;
1423                                 }
1424                         }
1425                         elsif (/^Content-type:/i) {
1426                                 $has_content_type = 1;
1427                                 if (/charset="?([^ "]+)/) {
1428                                         $body_encoding = $1;
1429                                 }
1430                                 push @xh, $_;
1431                         }
1432                         elsif (/^MIME-Version/i) {
1433                                 $has_mime_version = 1;
1434                                 push @xh, $_;
1435                         }
1436                         elsif (/^Message-Id: (.*)/i) {
1437                                 $message_id = $1;
1438                         }
1439                         elsif (/^Content-Transfer-Encoding: (.*)/i) {
1440                                 $xfer_encoding = $1 if not defined $xfer_encoding;
1441                         }
1442                         elsif (!/^Date:\s/i && /^[-A-Za-z]+:\s+\S/) {
1443                                 push @xh, $_;
1444                         }
1445
1446                 } else {
1447                         # In the traditional
1448                         # "send lots of email" format,
1449                         # line 1 = cc
1450                         # line 2 = subject
1451                         # So let's support that, too.
1452                         $input_format = 'lots';
1453                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1454                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1455                                         $_, $_) unless $quiet;
1456                                 push @cc, $_;
1457                         } elsif (!defined $subject) {
1458                                 $subject = $_;
1459                         }
1460                 }
1461         }
1462         # Now parse the message body
1463         while(<$fh>) {
1464                 $message .=  $_;
1465                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1466                         chomp;
1467                         my ($what, $c) = ($1, $2);
1468                         chomp $c;
1469                         my $sc = sanitize_address($c);
1470                         if ($sc eq $sender) {
1471                                 next if ($suppress_cc{'self'});
1472                         } else {
1473                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1474                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1475                         }
1476                         push @cc, $c;
1477                         printf("(body) Adding cc: %s from line '%s'\n",
1478                                 $c, $_) unless $quiet;
1479                 }
1480         }
1481         close $fh;
1482
1483         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1484                 if defined $to_cmd;
1485         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1486                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1487
1488         if ($broken_encoding{$t} && !$has_content_type) {
1489                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1490                 $has_content_type = 1;
1491                 push @xh, "Content-Type: text/plain; charset=$auto_8bit_encoding";
1492                 $body_encoding = $auto_8bit_encoding;
1493         }
1494
1495         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1496                 $subject = quote_subject($subject, $auto_8bit_encoding);
1497         }
1498
1499         if (defined $sauthor and $sauthor ne $sender) {
1500                 $message = "From: $author\n\n$message";
1501                 if (defined $author_encoding) {
1502                         if ($has_content_type) {
1503                                 if ($body_encoding eq $author_encoding) {
1504                                         # ok, we already have the right encoding
1505                                 }
1506                                 else {
1507                                         # uh oh, we should re-encode
1508                                 }
1509                         }
1510                         else {
1511                                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1512                                 $has_content_type = 1;
1513                                 push @xh,
1514                                   "Content-Type: text/plain; charset=$author_encoding";
1515                         }
1516                 }
1517         }
1518         if (defined $target_xfer_encoding) {
1519                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1520                 $message = apply_transfer_encoding(
1521                         $message, $xfer_encoding, $target_xfer_encoding);
1522                 $xfer_encoding = $target_xfer_encoding;
1523         }
1524         if (defined $xfer_encoding) {
1525                 push @xh, "Content-Transfer-Encoding: $xfer_encoding";
1526         }
1527         if (defined $xfer_encoding or $has_content_type) {
1528                 unshift @xh, 'MIME-Version: 1.0' unless $has_mime_version;
1529         }
1530
1531         $needs_confirm = (
1532                 $confirm eq "always" or
1533                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1534                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1535         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1536
1537         @to = validate_address_list(sanitize_address_list(@to));
1538         @cc = validate_address_list(sanitize_address_list(@cc));
1539
1540         @to = (@initial_to, @to);
1541         @cc = (@initial_cc, @cc);
1542
1543         if ($message_num == 1) {
1544                 if (defined $cover_cc and $cover_cc) {
1545                         @initial_cc = @cc;
1546                 }
1547                 if (defined $cover_to and $cover_to) {
1548                         @initial_to = @to;
1549                 }
1550         }
1551
1552         my $message_was_sent = send_message();
1553
1554         # set up for the next message
1555         if ($thread && $message_was_sent &&
1556                 ($chain_reply_to || !defined $reply_to || length($reply_to) == 0 ||
1557                 $message_num == 1)) {
1558                 $reply_to = $message_id;
1559                 if (length $references > 0) {
1560                         $references .= "\n $message_id";
1561                 } else {
1562                         $references = "$message_id";
1563                 }
1564         }
1565         $message_id = undef;
1566 }
1567
1568 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1569 # and return a results array
1570 sub recipients_cmd {
1571         my ($prefix, $what, $cmd, $file) = @_;
1572
1573         my @addresses = ();
1574         open my $fh, "-|", "$cmd \Q$file\E"
1575             or die "($prefix) Could not execute '$cmd'";
1576         while (my $address = <$fh>) {
1577                 $address =~ s/^\s*//g;
1578                 $address =~ s/\s*$//g;
1579                 $address = sanitize_address($address);
1580                 next if ($address eq $sender and $suppress_cc{'self'});
1581                 push @addresses, $address;
1582                 printf("($prefix) Adding %s: %s from: '%s'\n",
1583                        $what, $address, $cmd) unless $quiet;
1584                 }
1585         close $fh
1586             or die "($prefix) failed to close pipe to '$cmd'";
1587         return @addresses;
1588 }
1589
1590 cleanup_compose_files();
1591
1592 sub cleanup_compose_files {
1593         unlink($compose_filename, $compose_filename . ".final") if $compose;
1594 }
1595
1596 $smtp->quit if $smtp;
1597
1598 sub apply_transfer_encoding {
1599         my $message = shift;
1600         my $from = shift;
1601         my $to = shift;
1602
1603         return $message if ($from eq $to and $from ne '7bit');
1604
1605         require MIME::QuotedPrint;
1606         require MIME::Base64;
1607
1608         $message = MIME::QuotedPrint::decode($message)
1609                 if ($from eq 'quoted-printable');
1610         $message = MIME::Base64::decode($message)
1611                 if ($from eq 'base64');
1612
1613         die "cannot send message as 7bit"
1614                 if ($to eq '7bit' and $message =~ /[^[:ascii:]]/);
1615         return $message
1616                 if ($to eq '7bit' or $to eq '8bit');
1617         return MIME::QuotedPrint::encode($message, "\n", 0)
1618                 if ($to eq 'quoted-printable');
1619         return MIME::Base64::encode($message, "\n")
1620                 if ($to eq 'base64');
1621         die "invalid transfer encoding";
1622 }
1623
1624 sub unique_email_list {
1625         my %seen;
1626         my @emails;
1627
1628         foreach my $entry (@_) {
1629                 my $clean = extract_valid_address_or_die($entry);
1630                 $seen{$clean} ||= 0;
1631                 next if $seen{$clean}++;
1632                 push @emails, $entry;
1633         }
1634         return @emails;
1635 }
1636
1637 sub validate_patch {
1638         my $fn = shift;
1639         open(my $fh, '<', $fn)
1640                 or die "unable to open $fn: $!\n";
1641         while (my $line = <$fh>) {
1642                 if (length($line) > 998) {
1643                         return "$.: patch contains a line longer than 998 characters";
1644                 }
1645         }
1646         return;
1647 }
1648
1649 sub file_has_nonascii {
1650         my $fn = shift;
1651         open(my $fh, '<', $fn)
1652                 or die "unable to open $fn: $!\n";
1653         while (my $line = <$fh>) {
1654                 return 1 if $line =~ /[^[:ascii:]]/;
1655         }
1656         return 0;
1657 }
1658
1659 sub body_or_subject_has_nonascii {
1660         my $fn = shift;
1661         open(my $fh, '<', $fn)
1662                 or die "unable to open $fn: $!\n";
1663         while (my $line = <$fh>) {
1664                 last if $line =~ /^$/;
1665                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1666         }
1667         while (my $line = <$fh>) {
1668                 return 1 if $line =~ /[^[:ascii:]]/;
1669         }
1670         return 0;
1671 }