git.oblomov.eu Git - git/blob - git-gui/lib/choose_repository.tcl

   1 # git-gui Git repository chooser
   2 # Copyright (C) 2007 Shawn Pearce
   3
   4 class choose_repository {
   5
   6 field top
   7 field w
   8 field w_body      ; # Widget holding the center content
   9 field w_next      ; # Next button
  10 field w_quit      ; # Quit button
  11 field o_cons      ; # Console object (if active)
  12 field w_types     ; # List of type buttons in clone
  13 field w_recentlist ; # Listbox containing recent repositories
  14 field w_localpath  ; # Entry widget bound to local_path
  15
  16 field done              0 ; # Finished picking the repository?
  17 field local_path       {} ; # Where this repository is locally
  18 field origin_url       {} ; # Where we are cloning from
  19 field origin_name  origin ; # What we shall call 'origin'
  20 field clone_type hardlink ; # Type of clone to construct
  21 field readtree_err        ; # Error output from read-tree (if any)
  22 field sorted_recent       ; # recent repositories (sorted)
  23
  24 constructor pick {} {
  25         global M1T M1B
  26
  27         make_toplevel top w
  28         wm title $top [mc "Git Gui"]
  29
  30         if {$top eq {.}} {
  31                 menu $w.mbar -tearoff 0
  32                 $top configure -menu $w.mbar
  33
  34                 set m_repo $w.mbar.repository
  35                 $w.mbar add cascade \
  36                         -label [mc Repository] \
  37                         -menu $m_repo
  38                 menu $m_repo
  39
  40                 if {[is_MacOSX]} {
  41                         $w.mbar add cascade -label Apple -menu .mbar.apple
  42                         menu $w.mbar.apple
  43                         $w.mbar.apple add command \
  44                                 -label [mc "About %s" [appname]] \
  45                                 -command do_about
  46                 } else {
  47                         $w.mbar add cascade -label [mc Help] -menu $w.mbar.help
  48                         menu $w.mbar.help
  49                         $w.mbar.help add command \
  50                                 -label [mc "About %s" [appname]] \
  51                                 -command do_about
  52                 }
  53
  54                 wm protocol $top WM_DELETE_WINDOW exit
  55                 bind $top <$M1B-q> exit
  56                 bind $top <$M1B-Q> exit
  57                 bind $top <Key-Escape> exit
  58         } else {
  59                 wm geometry $top "+[winfo rootx .]+[winfo rooty .]"
  60                 bind $top <Key-Escape> [list destroy $top]
  61                 set m_repo {}
  62         }
  63
  64         pack [git_logo $w.git_logo] -side left -fill y -padx 10 -pady 10
  65
  66         set w_body $w.body
  67         set opts $w_body.options
  68         frame $w_body
  69         text $opts \
  70                 -cursor $::cursor_ptr \
  71                 -relief flat \
  72                 -background [$w_body cget -background] \
  73                 -wrap none \
  74                 -spacing1 5 \
  75                 -width 50 \
  76                 -height 3
  77         pack $opts -anchor w -fill x
  78
  79         $opts tag conf link_new -foreground blue -underline 1
  80         $opts tag bind link_new <1> [cb _next new]
  81         $opts insert end [mc "Create New Repository"] link_new
  82         $opts insert end "\n"
  83         if {$m_repo ne {}} {
  84                 $m_repo add command \
  85                         -command [cb _next new] \
  86                         -accelerator $M1T-N \
  87                         -label [mc "New..."]
  88                 bind $top <$M1B-n> [cb _next new]
  89                 bind $top <$M1B-N> [cb _next new]
  90         }
  91
  92         $opts tag conf link_clone -foreground blue -underline 1
  93         $opts tag bind link_clone <1> [cb _next clone]
  94         $opts insert end [mc "Clone Existing Repository"] link_clone
  95         $opts insert end "\n"
  96         if {$m_repo ne {}} {
  97                 $m_repo add command \
  98                         -command [cb _next clone] \
  99                         -accelerator $M1T-C \
 100                         -label [mc "Clone..."]
 101                 bind $top <$M1B-c> [cb _next clone]
 102                 bind $top <$M1B-C> [cb _next clone]
 103         }
 104
 105         $opts tag conf link_open -foreground blue -underline 1
 106         $opts tag bind link_open <1> [cb _next open]
 107         $opts insert end [mc "Open Existing Repository"] link_open
 108         $opts insert end "\n"
 109         if {$m_repo ne {}} {
 110                 $m_repo add command \
 111                         -command [cb _next open] \
 112                         -accelerator $M1T-O \
 113                         -label [mc "Open..."]
 114                 bind $top <$M1B-o> [cb _next open]
 115                 bind $top <$M1B-O> [cb _next open]
 116         }
 117
 118         $opts conf -state disabled
 119
 120         set sorted_recent [_get_recentrepos]
 121         if {[llength $sorted_recent] > 0} {
 122                 if {$m_repo ne {}} {
 123                         $m_repo add separator
 124                         $m_repo add command \
 125                                 -state disabled \
 126                                 -label [mc "Recent Repositories"]
 127                 }
 128
 129                 label $w_body.space
 130                 label $w_body.recentlabel \
 131                         -anchor w \
 132                         -text [mc "Open Recent Repository:"]
 133                 set w_recentlist $w_body.recentlist
 134                 text $w_recentlist \
 135                         -cursor $::cursor_ptr \
 136                         -relief flat \
 137                         -background [$w_body.recentlabel cget -background] \
 138                         -wrap none \
 139                         -width 50 \
 140                         -height 10
 141                 $w_recentlist tag conf link \
 142                         -foreground blue \
 143                         -underline 1
 144                 set home $::env(HOME)
 145                 if {[is_Cygwin]} {
 146                         set home [exec cygpath --windows --absolute $home]
 147                 }
 148                 set home "[file normalize $home]/"
 149                 set hlen [string length $home]
 150                 foreach p $sorted_recent {
 151                         set path $p
 152                         if {[string equal -length $hlen $home $p]} {
 153                                 set p "~/[string range $p $hlen end]"
 154                         }
 155                         regsub -all "\n" $p "\\n" p
 156                         $w_recentlist insert end $p link
 157                         $w_recentlist insert end "\n"
 158
 159                         if {$m_repo ne {}} {
 160                                 $m_repo add command \
 161                                         -command [cb _open_recent_path $path] \
 162                                         -label "    $p"
 163                         }
 164                 }
 165                 $w_recentlist conf -state disabled
 166                 $w_recentlist tag bind link <1> [cb _open_recent %x,%y]
 167                 pack $w_body.space -anchor w -fill x
 168                 pack $w_body.recentlabel -anchor w -fill x
 169                 pack $w_recentlist -anchor w -fill x
 170         }
 171         pack $w_body -fill x -padx 10 -pady 10
 172
 173         frame $w.buttons
 174         set w_next $w.buttons.next
 175         set w_quit $w.buttons.quit
 176         button $w_quit \
 177                 -text [mc "Quit"] \
 178                 -command exit
 179         pack $w_quit -side right -padx 5
 180         pack $w.buttons -side bottom -fill x -padx 10 -pady 10
 181
 182         if {$m_repo ne {}} {
 183                 $m_repo add separator
 184                 $m_repo add command \
 185                         -label [mc Quit] \
 186                         -command exit \
 187                         -accelerator $M1T-Q
 188         }
 189
 190         bind $top <Return> [cb _invoke_next]
 191         bind $top <Visibility> "
 192                 [cb _center]
 193                 grab $top
 194                 focus $top
 195                 bind $top <Visibility> {}
 196         "
 197         wm deiconify $top
 198         tkwait variable @done
 199
 200         if {$top eq {.}} {
 201                 eval destroy [winfo children $top]
 202         }
 203 }
 204
 205 proc _home {} {
 206         if {[catch {set h $::env(HOME)}]
 207                 || ![file isdirectory $h]} {
 208                 set h .
 209         }
 210         return $h
 211 }
 212
 213 method _center {} {
 214         set nx [winfo reqwidth $top]
 215         set ny [winfo reqheight $top]
 216         set rx [expr {([winfo screenwidth  $top] - $nx) / 3}]
 217         set ry [expr {([winfo screenheight $top] - $ny) / 3}]
 218         wm geometry $top [format {+%d+%d} $rx $ry]
 219 }
 220
 221 method _invoke_next {} {
 222         if {[winfo exists $w_next]} {
 223                 uplevel #0 [$w_next cget -command]
 224         }
 225 }
 226
 227 proc _get_recentrepos {} {
 228         set recent [list]
 229         foreach p [get_config gui.recentrepo] {
 230                 if {[_is_git [file join $p .git]]} {
 231                         lappend recent $p
 232                 }
 233         }
 234         return [lsort $recent]
 235 }
 236
 237 proc _unset_recentrepo {p} {
 238         regsub -all -- {([()\[\]{}\.^$+*?\\])} $p {\\\1} p
 239         git config --global --unset gui.recentrepo "^$p\$"
 240 }
 241
 242 proc _append_recentrepos {path} {
 243         set path [file normalize $path]
 244         set recent [get_config gui.recentrepo]
 245
 246         if {[lindex $recent end] eq $path} {
 247                 return
 248         }
 249
 250         set i [lsearch $recent $path]
 251         if {$i >= 0} {
 252                 _unset_recentrepo $path
 253                 set recent [lreplace $recent $i $i]
 254         }
 255
 256         lappend recent $path
 257         git config --global --add gui.recentrepo $path
 258
 259         while {[llength $recent] > 10} {
 260                 _unset_recentrepo [lindex $recent 0]
 261                 set recent [lrange $recent 1 end]
 262         }
 263 }
 264
 265 method _open_recent {xy} {
 266         set id [lindex [split [$w_recentlist index @$xy] .] 0]
 267         set local_path [lindex $sorted_recent [expr {$id - 1}]]
 268         _do_open2 $this
 269 }
 270
 271 method _open_recent_path {p} {
 272         set local_path $p
 273         _do_open2 $this
 274 }
 275
 276 method _next {action} {
 277         destroy $w_body
 278         if {![winfo exists $w_next]} {
 279                 button $w_next -default active
 280                 pack $w_next -side right -padx 5 -before $w_quit
 281         }
 282         _do_$action $this
 283 }
 284
 285 method _write_local_path {args} {
 286         if {$local_path eq {}} {
 287                 $w_next conf -state disabled
 288         } else {
 289                 $w_next conf -state normal
 290         }
 291 }
 292
 293 method _git_init {} {
 294         if {[catch {file mkdir $local_path} err]} {
 295                 error_popup [strcat \
 296                         [mc "Failed to create repository %s:" $local_path] \
 297                         "\n\n$err"]
 298                 return 0
 299         }
 300
 301         if {[catch {cd $local_path} err]} {
 302                 error_popup [strcat \
 303                         [mc "Failed to create repository %s:" $local_path] \
 304                         "\n\n$err"]
 305                 return 0
 306         }
 307
 308         if {[catch {git init} err]} {
 309                 error_popup [strcat \
 310                         [mc "Failed to create repository %s:" $local_path] \
 311                         "\n\n$err"]
 312                 return 0
 313         }
 314
 315         _append_recentrepos [pwd]
 316         set ::_gitdir .git
 317         set ::_prefix {}
 318         return 1
 319 }
 320
 321 proc _is_git {path} {
 322         if {[file exists [file join $path HEAD]]
 323          && [file exists [file join $path objects]]
 324          && [file exists [file join $path config]]} {
 325                 return 1
 326         }
 327         if {[is_Cygwin]} {
 328                 if {[file exists [file join $path HEAD]]
 329                  && [file exists [file join $path objects.lnk]]
 330                  && [file exists [file join $path config.lnk]]} {
 331                         return 1
 332                 }
 333         }
 334         return 0
 335 }
 336
 337 proc _objdir {path} {
 338         set objdir [file join $path .git objects]
 339         if {[file isdirectory $objdir]} {
 340                 return $objdir
 341         }
 342
 343         set objdir [file join $path objects]
 344         if {[file isdirectory $objdir]} {
 345                 return $objdir
 346         }
 347
 348         if {[is_Cygwin]} {
 349                 set objdir [file join $path .git objects.lnk]
 350                 if {[file isfile $objdir]} {
 351                         return [win32_read_lnk $objdir]
 352                 }
 353
 354                 set objdir [file join $path objects.lnk]
 355                 if {[file isfile $objdir]} {
 356                         return [win32_read_lnk $objdir]
 357                 }
 358         }
 359
 360         return {}
 361 }
 362
 363 ######################################################################
 364 ##
 365 ## Create New Repository
 366
 367 method _do_new {} {
 368         $w_next conf \
 369                 -state disabled \
 370                 -command [cb _do_new2] \
 371                 -text [mc "Create"]
 372
 373         frame $w_body
 374         label $w_body.h \
 375                 -font font_uibold \
 376                 -text [mc "Create New Repository"]
 377         pack $w_body.h -side top -fill x -pady 10
 378         pack $w_body -fill x -padx 10
 379
 380         frame $w_body.where
 381         label $w_body.where.l -text [mc "Directory:"]
 382         entry $w_body.where.t \
 383                 -textvariable @local_path \
 384                 -font font_diff \
 385                 -width 50
 386         button $w_body.where.b \
 387                 -text [mc "Browse"] \
 388                 -command [cb _new_local_path]
 389         set w_localpath $w_body.where.t
 390
 391         pack $w_body.where.b -side right
 392         pack $w_body.where.l -side left
 393         pack $w_body.where.t -fill x
 394         pack $w_body.where -fill x
 395
 396         trace add variable @local_path write [cb _write_local_path]
 397         bind $w_body.h <Destroy> [list trace remove variable @local_path write [cb _write_local_path]]
 398         update
 399         focus $w_body.where.t
 400 }
 401
 402 method _new_local_path {} {
 403         if {$local_path ne {}} {
 404                 set p [file dirname $local_path]
 405         } else {
 406                 set p [_home]
 407         }
 408
 409         set p [tk_chooseDirectory \
 410                 -initialdir $p \
 411                 -parent $top \
 412                 -title [mc "Git Repository"] \
 413                 -mustexist false]
 414         if {$p eq {}} return
 415
 416         set p [file normalize $p]
 417         if {![_new_ok $p]} {
 418                 return
 419         }
 420         set local_path $p
 421         $w_localpath icursor end
 422 }
 423
 424 method _do_new2 {} {
 425         if {![_new_ok $local_path]} {
 426                 return
 427         }
 428         if {![_git_init $this]} {
 429                 return
 430         }
 431         set done 1
 432 }
 433
 434 proc _new_ok {p} {
 435         if {[file isdirectory $p]} {
 436                 if {[_is_git [file join $p .git]]} {
 437                         error_popup [mc "Directory %s already exists." $p]
 438                         return 0
 439                 }
 440         } elseif {[file exists $p]} {
 441                 error_popup [mc "File %s already exists." $p]
 442                 return 0
 443         }
 444         return 1
 445 }
 446
 447 ######################################################################
 448 ##
 449 ## Clone Existing Repository
 450
 451 method _do_clone {} {
 452         $w_next conf \
 453                 -state disabled \
 454                 -command [cb _do_clone2] \
 455                 -text [mc "Clone"]
 456
 457         frame $w_body
 458         label $w_body.h \
 459                 -font font_uibold \
 460                 -text [mc "Clone Existing Repository"]
 461         pack $w_body.h -side top -fill x -pady 10
 462         pack $w_body -fill x -padx 10
 463
 464         set args $w_body.args
 465         frame $w_body.args
 466         pack $args -fill both
 467
 468         label $args.origin_l -text [mc "URL:"]
 469         entry $args.origin_t \
 470                 -textvariable @origin_url \
 471                 -font font_diff \
 472                 -width 50
 473         button $args.origin_b \
 474                 -text [mc "Browse"] \
 475                 -command [cb _open_origin]
 476         grid $args.origin_l $args.origin_t $args.origin_b -sticky ew
 477
 478         label $args.where_l -text [mc "Directory:"]
 479         entry $args.where_t \
 480                 -textvariable @local_path \
 481                 -font font_diff \
 482                 -width 50
 483         button $args.where_b \
 484                 -text [mc "Browse"] \
 485                 -command [cb _new_local_path]
 486         grid $args.where_l $args.where_t $args.where_b -sticky ew
 487         set w_localpath $args.where_t
 488
 489         label $args.type_l -text [mc "Clone Type:"]
 490         frame $args.type_f
 491         set w_types [list]
 492         lappend w_types [radiobutton $args.type_f.hardlink \
 493                 -state disabled \
 494                 -anchor w \
 495                 -text [mc "Standard (Fast, Semi-Redundant, Hardlinks)"] \
 496                 -variable @clone_type \
 497                 -value hardlink]
 498         lappend w_types [radiobutton $args.type_f.full \
 499                 -state disabled \
 500                 -anchor w \
 501                 -text [mc "Full Copy (Slower, Redundant Backup)"] \
 502                 -variable @clone_type \
 503                 -value full]
 504         lappend w_types [radiobutton $args.type_f.shared \
 505                 -state disabled \
 506                 -anchor w \
 507                 -text [mc "Shared (Fastest, Not Recommended, No Backup)"] \
 508                 -variable @clone_type \
 509                 -value shared]
 510         foreach r $w_types {
 511                 pack $r -anchor w
 512         }
 513         grid $args.type_l $args.type_f -sticky new
 514
 515         grid columnconfigure $args 1 -weight 1
 516
 517         trace add variable @local_path write [cb _update_clone]
 518         trace add variable @origin_url write [cb _update_clone]
 519         bind $w_body.h <Destroy> "
 520                 [list trace remove variable @local_path write [cb _update_clone]]
 521                 [list trace remove variable @origin_url write [cb _update_clone]]
 522         "
 523         update
 524         focus $args.origin_t
 525 }
 526
 527 method _open_origin {} {
 528         if {$origin_url ne {} && [file isdirectory $origin_url]} {
 529                 set p $origin_url
 530         } else {
 531                 set p [_home]
 532         }
 533
 534         set p [tk_chooseDirectory \
 535                 -initialdir $p \
 536                 -parent $top \
 537                 -title [mc "Git Repository"] \
 538                 -mustexist true]
 539         if {$p eq {}} return
 540
 541         set p [file normalize $p]
 542         if {![_is_git [file join $p .git]] && ![_is_git $p]} {
 543                 error_popup [mc "Not a Git repository: %s" [file tail $p]]
 544                 return
 545         }
 546         set origin_url $p
 547 }
 548
 549 method _update_clone {args} {
 550         if {$local_path ne {} && $origin_url ne {}} {
 551                 $w_next conf -state normal
 552         } else {
 553                 $w_next conf -state disabled
 554         }
 555
 556         if {$origin_url ne {} &&
 557                 (  [_is_git [file join $origin_url .git]]
 558                 || [_is_git $origin_url])} {
 559                 set e normal
 560                 if {[[lindex $w_types 0] cget -state] eq {disabled}} {
 561                         set clone_type hardlink
 562                 }
 563         } else {
 564                 set e disabled
 565                 set clone_type full
 566         }
 567
 568         foreach r $w_types {
 569                 $r conf -state $e
 570         }
 571 }
 572
 573 method _do_clone2 {} {
 574         if {[file isdirectory $origin_url]} {
 575                 set origin_url [file normalize $origin_url]
 576         }
 577
 578         if {$clone_type eq {hardlink} && ![file isdirectory $origin_url]} {
 579                 error_popup [mc "Standard only available for local repository."]
 580                 return
 581         }
 582         if {$clone_type eq {shared} && ![file isdirectory $origin_url]} {
 583                 error_popup [mc "Shared only available for local repository."]
 584                 return
 585         }
 586
 587         if {$clone_type eq {hardlink} || $clone_type eq {shared}} {
 588                 set objdir [_objdir $origin_url]
 589                 if {$objdir eq {}} {
 590                         error_popup [mc "Not a Git repository: %s" [file tail $origin_url]]
 591                         return
 592                 }
 593         }
 594
 595         set giturl $origin_url
 596         if {[is_Cygwin] && [file isdirectory $giturl]} {
 597                 set giturl [exec cygpath --unix --absolute $giturl]
 598                 if {$clone_type eq {shared}} {
 599                         set objdir [exec cygpath --unix --absolute $objdir]
 600                 }
 601         }
 602
 603         if {[file exists $local_path]} {
 604                 error_popup [mc "Location %s already exists." $local_path]
 605                 return
 606         }
 607
 608         if {![_git_init $this]} return
 609         set local_path [pwd]
 610
 611         if {[catch {
 612                         git config remote.$origin_name.url $giturl
 613                         git config remote.$origin_name.fetch +refs/heads/*:refs/remotes/$origin_name/*
 614                 } err]} {
 615                 error_popup [strcat [mc "Failed to configure origin"] "\n\n$err"]
 616                 return
 617         }
 618
 619         destroy $w_body $w_next
 620
 621         switch -exact -- $clone_type {
 622         hardlink {
 623                 set o_cons [status_bar::two_line $w_body]
 624                 pack $w_body -fill x -padx 10 -pady 10
 625
 626                 $o_cons start \
 627                         [mc "Counting objects"] \
 628                         [mc "buckets"]
 629                 update
 630
 631                 if {[file exists [file join $objdir info alternates]]} {
 632                         set pwd [pwd]
 633                         if {[catch {
 634                                 file mkdir [gitdir objects info]
 635                                 set f_in [open [file join $objdir info alternates] r]
 636                                 set f_cp [open [gitdir objects info alternates] w]
 637                                 fconfigure $f_in -translation binary -encoding binary
 638                                 fconfigure $f_cp -translation binary -encoding binary
 639                                 cd $objdir
 640                                 while {[gets $f_in line] >= 0} {
 641                                         if {[is_Cygwin]} {
 642                                                 puts $f_cp [exec cygpath --unix --absolute $line]
 643                                         } else {
 644                                                 puts $f_cp [file normalize $line]
 645                                         }
 646                                 }
 647                                 close $f_in
 648                                 close $f_cp
 649                                 cd $pwd
 650                         } err]} {
 651                                 catch {cd $pwd}
 652                                 _clone_failed $this [mc "Unable to copy objects/info/alternates: %s" $err]
 653                                 return
 654                         }
 655                 }
 656
 657                 set tolink  [list]
 658                 set buckets [glob \
 659                         -tails \
 660                         -nocomplain \
 661                         -directory [file join $objdir] ??]
 662                 set bcnt [expr {[llength $buckets] + 2}]
 663                 set bcur 1
 664                 $o_cons update $bcur $bcnt
 665                 update
 666
 667                 file mkdir [file join .git objects pack]
 668                 foreach i [glob -tails -nocomplain \
 669                         -directory [file join $objdir pack] *] {
 670                         lappend tolink [file join pack $i]
 671                 }
 672                 $o_cons update [incr bcur] $bcnt
 673                 update
 674
 675                 foreach i $buckets {
 676                         file mkdir [file join .git objects $i]
 677                         foreach j [glob -tails -nocomplain \
 678                                 -directory [file join $objdir $i] *] {
 679                                 lappend tolink [file join $i $j]
 680                         }
 681                         $o_cons update [incr bcur] $bcnt
 682                         update
 683                 }
 684                 $o_cons stop
 685
 686                 if {$tolink eq {}} {
 687                         info_popup [strcat \
 688                                 [mc "Nothing to clone from %s." $origin_url] \
 689                                 "\n" \
 690                                 [mc "The 'master' branch has not been initialized."] \
 691                                 ]
 692                         destroy $w_body
 693                         set done 1
 694                         return
 695                 }
 696
 697                 set i [lindex $tolink 0]
 698                 if {[catch {
 699                                 file link -hard \
 700                                         [file join .git objects $i] \
 701                                         [file join $objdir $i]
 702                         } err]} {
 703                         info_popup [mc "Hardlinks are unavailable.  Falling back to copying."]
 704                         set i [_copy_files $this $objdir $tolink]
 705                 } else {
 706                         set i [_link_files $this $objdir [lrange $tolink 1 end]]
 707                 }
 708                 if {!$i} return
 709
 710                 destroy $w_body
 711         }
 712         full {
 713                 set o_cons [console::embed \
 714                         $w_body \
 715                         [mc "Cloning from %s" $origin_url]]
 716                 pack $w_body -fill both -expand 1 -padx 10
 717                 $o_cons exec \
 718                         [list git fetch --no-tags -k $origin_name] \
 719                         [cb _do_clone_tags]
 720         }
 721         shared {
 722                 set fd [open [gitdir objects info alternates] w]
 723                 fconfigure $fd -translation binary
 724                 puts $fd $objdir
 725                 close $fd
 726         }
 727         }
 728
 729         if {$clone_type eq {hardlink} || $clone_type eq {shared}} {
 730                 if {![_clone_refs $this]} return
 731                 set pwd [pwd]
 732                 if {[catch {
 733                                 cd $origin_url
 734                                 set HEAD [git rev-parse --verify HEAD^0]
 735                         } err]} {
 736                         _clone_failed $this [mc "Not a Git repository: %s" [file tail $origin_url]]
 737                         return 0
 738                 }
 739                 cd $pwd
 740                 _do_clone_checkout $this $HEAD
 741         }
 742 }
 743
 744 method _copy_files {objdir tocopy} {
 745         $o_cons start \
 746                 [mc "Copying objects"] \
 747                 [mc "KiB"]
 748         set tot 0
 749         set cmp 0
 750         foreach p $tocopy {
 751                 incr tot [file size [file join $objdir $p]]
 752         }
 753         foreach p $tocopy {
 754                 if {[catch {
 755                                 set f_in [open [file join $objdir $p] r]
 756                                 set f_cp [open [file join .git objects $p] w]
 757                                 fconfigure $f_in -translation binary -encoding binary
 758                                 fconfigure $f_cp -translation binary -encoding binary
 759
 760                                 while {![eof $f_in]} {
 761                                         incr cmp [fcopy $f_in $f_cp -size 16384]
 762                                         $o_cons update \
 763                                                 [expr {$cmp / 1024}] \
 764                                                 [expr {$tot / 1024}]
 765                                         update
 766                                 }
 767
 768                                 close $f_in
 769                                 close $f_cp
 770                         } err]} {
 771                         _clone_failed $this [mc "Unable to copy object: %s" $err]
 772                         return 0
 773                 }
 774         }
 775         return 1
 776 }
 777
 778 method _link_files {objdir tolink} {
 779         set total [llength $tolink]
 780         $o_cons start \
 781                 [mc "Linking objects"] \
 782                 [mc "objects"]
 783         for {set i 0} {$i < $total} {} {
 784                 set p [lindex $tolink $i]
 785                 if {[catch {
 786                                 file link -hard \
 787                                         [file join .git objects $p] \
 788                                         [file join $objdir $p]
 789                         } err]} {
 790                         _clone_failed $this [mc "Unable to hardlink object: %s" $err]
 791                         return 0
 792                 }
 793
 794                 incr i
 795                 if {$i % 5 == 0} {
 796                         $o_cons update $i $total
 797                         update
 798                 }
 799         }
 800         return 1
 801 }
 802
 803 method _clone_refs {} {
 804         set pwd [pwd]
 805         if {[catch {cd $origin_url} err]} {
 806                 error_popup [mc "Not a Git repository: %s" [file tail $origin_url]]
 807                 return 0
 808         }
 809         set fd_in [git_read for-each-ref \
 810                 --tcl \
 811                 {--format=list %(refname) %(objectname) %(*objectname)}]
 812         cd $pwd
 813
 814         set fd [open [gitdir packed-refs] w]
 815         fconfigure $fd -translation binary
 816         puts $fd "# pack-refs with: peeled"
 817         while {[gets $fd_in line] >= 0} {
 818                 set line [eval $line]
 819                 set refn [lindex $line 0]
 820                 set robj [lindex $line 1]
 821                 set tobj [lindex $line 2]
 822
 823                 if {[regsub ^refs/heads/ $refn \
 824                         "refs/remotes/$origin_name/" refn]} {
 825                         puts $fd "$robj $refn"
 826                 } elseif {[string match refs/tags/* $refn]} {
 827                         puts $fd "$robj $refn"
 828                         if {$tobj ne {}} {
 829                                 puts $fd "^$tobj"
 830                         }
 831                 }
 832         }
 833         close $fd_in
 834         close $fd
 835         return 1
 836 }
 837
 838 method _do_clone_tags {ok} {
 839         if {$ok} {
 840                 $o_cons exec \
 841                         [list git fetch --tags -k $origin_name] \
 842                         [cb _do_clone_HEAD]
 843         } else {
 844                 $o_cons done $ok
 845                 _clone_failed $this [mc "Cannot fetch branches and objects.  See console output for details."]
 846         }
 847 }
 848
 849 method _do_clone_HEAD {ok} {
 850         if {$ok} {
 851                 $o_cons exec \
 852                         [list git fetch $origin_name HEAD] \
 853                         [cb _do_clone_full_end]
 854         } else {
 855                 $o_cons done $ok
 856                 _clone_failed $this [mc "Cannot fetch tags.  See console output for details."]
 857         }
 858 }
 859
 860 method _do_clone_full_end {ok} {
 861         $o_cons done $ok
 862
 863         if {$ok} {
 864                 destroy $w_body
 865
 866                 set HEAD {}
 867                 if {[file exists [gitdir FETCH_HEAD]]} {
 868                         set fd [open [gitdir FETCH_HEAD] r]
 869                         while {[gets $fd line] >= 0} {
 870                                 if {[regexp "^(.{40})\t\t" $line line HEAD]} {
 871                                         break
 872                                 }
 873                         }
 874                         close $fd
 875                 }
 876
 877                 catch {git pack-refs}
 878                 _do_clone_checkout $this $HEAD
 879         } else {
 880                 _clone_failed $this [mc "Cannot determine HEAD.  See console output for details."]
 881         }
 882 }
 883
 884 method _clone_failed {{why {}}} {
 885         if {[catch {file delete -force $local_path} err]} {
 886                 set why [strcat \
 887                         $why \
 888                         "\n\n" \
 889                         [mc "Unable to cleanup %s" $local_path] \
 890                         "\n\n" \
 891                         $err]
 892         }
 893         if {$why ne {}} {
 894                 update
 895                 error_popup [strcat [mc "Clone failed."] "\n" $why]
 896         }
 897 }
 898
 899 method _do_clone_checkout {HEAD} {
 900         if {$HEAD eq {}} {
 901                 info_popup [strcat \
 902                         [mc "No default branch obtained."] \
 903                         "\n" \
 904                         [mc "The 'master' branch has not been initialized."] \
 905                         ]
 906                 set done 1
 907                 return
 908         }
 909         if {[catch {
 910                         git update-ref HEAD $HEAD^0
 911                 } err]} {
 912                 info_popup [strcat \
 913                         [mc "Cannot resolve %s as a commit." $HEAD^0] \
 914                         "\n  $err" \
 915                         "\n" \
 916                         [mc "The 'master' branch has not been initialized."] \
 917                         ]
 918                 set done 1
 919                 return
 920         }
 921
 922         set o_cons [status_bar::two_line $w_body]
 923         pack $w_body -fill x -padx 10 -pady 10
 924         $o_cons start \
 925                 [mc "Creating working directory"] \
 926                 [mc "files"]
 927
 928         set readtree_err {}
 929         set fd [git_read --stderr read-tree \
 930                 -m \
 931                 -u \
 932                 -v \
 933                 HEAD \
 934                 HEAD \
 935                 ]
 936         fconfigure $fd -blocking 0 -translation binary
 937         fileevent $fd readable [cb _readtree_wait $fd]
 938 }
 939
 940 method _readtree_wait {fd} {
 941         set buf [read $fd]
 942         $o_cons update_meter $buf
 943         append readtree_err $buf
 944
 945         fconfigure $fd -blocking 1
 946         if {![eof $fd]} {
 947                 fconfigure $fd -blocking 0
 948                 return
 949         }
 950
 951         if {[catch {close $fd}]} {
 952                 set err $readtree_err
 953                 regsub {^fatal: } $err {} err
 954                 error_popup [strcat \
 955                         [mc "Initial file checkout failed."] \
 956                         "\n\n$err"]
 957                 return
 958         }
 959
 960         set done 1
 961 }
 962
 963 ######################################################################
 964 ##
 965 ## Open Existing Repository
 966
 967 method _do_open {} {
 968         $w_next conf \
 969                 -state disabled \
 970                 -command [cb _do_open2] \
 971                 -text [mc "Open"]
 972
 973         frame $w_body
 974         label $w_body.h \
 975                 -font font_uibold \
 976                 -text [mc "Open Existing Repository"]
 977         pack $w_body.h -side top -fill x -pady 10
 978         pack $w_body -fill x -padx 10
 979
 980         frame $w_body.where
 981         label $w_body.where.l -text [mc "Repository:"]
 982         entry $w_body.where.t \
 983                 -textvariable @local_path \
 984                 -font font_diff \
 985                 -width 50
 986         button $w_body.where.b \
 987                 -text [mc "Browse"] \
 988                 -command [cb _open_local_path]
 989
 990         pack $w_body.where.b -side right
 991         pack $w_body.where.l -side left
 992         pack $w_body.where.t -fill x
 993         pack $w_body.where -fill x
 994
 995         trace add variable @local_path write [cb _write_local_path]
 996         bind $w_body.h <Destroy> [list trace remove variable @local_path write [cb _write_local_path]]
 997         update
 998         focus $w_body.where.t
 999 }
1000
1001 method _open_local_path {} {
1002         if {$local_path ne {}} {
1003                 set p $local_path
1004         } else {
1005                 set p [_home]
1006         }
1007
1008         set p [tk_chooseDirectory \
1009                 -initialdir $p \
1010                 -parent $top \
1011                 -title [mc "Git Repository"] \
1012                 -mustexist true]
1013         if {$p eq {}} return
1014
1015         set p [file normalize $p]
1016         if {![_is_git [file join $p .git]]} {
1017                 error_popup [mc "Not a Git repository: %s" [file tail $p]]
1018                 return
1019         }
1020         set local_path $p
1021 }
1022
1023 method _do_open2 {} {
1024         if {![_is_git [file join $local_path .git]]} {
1025                 error_popup [mc "Not a Git repository: %s" [file tail $local_path]]
1026                 return
1027         }
1028
1029         if {[catch {cd $local_path} err]} {
1030                 error_popup [strcat \
1031                         [mc "Failed to open repository %s:" $local_path] \
1032                         "\n\n$err"]
1033                 return
1034         }
1035
1036         _append_recentrepos [pwd]
1037         set ::_gitdir .git
1038         set ::_prefix {}
1039         set done 1
1040 }
1041
1042 }