git.oblomov.eu Git - git/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 ## Definitions of private macros.
   5
   6 # GIT_CONF_SUBST(VAL, VAR)
   7 # ------------------------
   8 # Cause the line "VAR=VAL" to be eventually appended to ${config_file}.
   9 AC_DEFUN([GIT_CONF_SUBST],
  10 [AC_REQUIRE([GIT_CONF_SUBST_INIT])
  11 config_appended_defs="$config_appended_defs${newline}dnl
  12 $1=m4_if([$#],[1],[${$1}],[$2])"])
  13
  14 # GIT_CONF_SUBST_INIT
  15 # -------------------
  16 # Prepare shell variables and autoconf machine required by later calls
  17 # to GIT_CONF_SUBST.
  18 AC_DEFUN([GIT_CONF_SUBST_INIT],
  19     [config_appended_defs=; newline='
  20 '
  21     AC_CONFIG_COMMANDS([$config_file],
  22                        [echo "$config_appended_defs" >> "$config_file"],
  23                        [config_file=$config_file
  24                         config_appended_defs="$config_appended_defs"])])
  25
  26 # GIT_ARG_SET_PATH(PROGRAM)
  27 # -------------------------
  28 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  29 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  30 # --without-PROGRAM version used.
  31 AC_DEFUN([GIT_ARG_SET_PATH],
  32     [AC_ARG_WITH([$1],
  33         [AS_HELP_STRING([--with-$1=PATH],
  34                         [provide PATH to $1])],
  35         [GIT_CONF_APPEND_PATH([$1], [$2])],
  36         [])])
  37
  38 # GIT_CONF_APPEND_PATH(PROGRAM)
  39 # -----------------------------
  40 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  41 # Used by GIT_ARG_SET_PATH(PROGRAM)
  42 # Optional second argument allows setting NO_PROGRAM=YesPlease if
  43 # --without-PROGRAM is used.
  44 AC_DEFUN([GIT_CONF_APPEND_PATH],
  45     [m4_pushdef([GIT_UC_PROGRAM], m4_toupper([$1]))dnl
  46     if test "$withval" = "no"; then
  47         if test -n "$2"; then
  48                 GIT_UC_PROGRAM[]_PATH=$withval
  49                 AC_MSG_NOTICE([Disabling use of GIT_UC_PROGRAM])
  50                 GIT_CONF_SUBST([NO_]GIT_UC_PROGRAM, [YesPlease])
  51                 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [])
  52         else
  53                 AC_MSG_ERROR([You cannot use git without $1])
  54         fi
  55     else
  56         if test "$withval" = "yes"; then
  57                 AC_MSG_WARN([You should provide path for --with-$1=PATH])
  58         else
  59                 GIT_UC_PROGRAM[]_PATH=$withval
  60                 AC_MSG_NOTICE([Setting GIT_UC_PROGRAM[]_PATH to $withval])
  61                 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [$withval])
  62         fi
  63     fi
  64     m4_popdef([GIT_UC_PROGRAM])])
  65
  66 # GIT_PARSE_WITH(PACKAGE)
  67 # -----------------------
  68 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  69 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  70 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  71 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  72 AC_DEFUN([GIT_PARSE_WITH],
  73     [m4_pushdef([GIT_UC_PACKAGE], m4_toupper([$1]))dnl
  74     if test "$withval" = "no"; then
  75         NO_[]GIT_UC_PACKAGE=YesPlease
  76     elif test "$withval" = "yes"; then
  77         NO_[]GIT_UC_PACKAGE=
  78     else
  79         NO_[]GIT_UC_PACKAGE=
  80         GIT_UC_PACKAGE[]DIR=$withval
  81         AC_MSG_NOTICE([Setting GIT_UC_PACKAGE[]DIR to $withval])
  82         GIT_CONF_SUBST(GIT_UC_PACKAGE[DIR], [$withval])
  83     fi
  84     m4_popdef([GIT_UC_PACKAGE])])
  85
  86 # GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
  87 # -----------------------------------------------------
  88 # Set VAR to the value specied by --with-WITHNAME.
  89 # No verification of arguments is performed, but warnings are issued
  90 # if either 'yes' or 'no' is specified.
  91 # HELP_TEXT is presented when --help is called.
  92 # This is a direct way to allow setting variables in the Makefile.
  93 AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
  94 [AC_ARG_WITH([$1],
  95  [AS_HELP_STRING([--with-$1=VALUE], $3)],
  96  if test -n "$withval"; then
  97   if test "$withval" = "yes" -o "$withval" = "no"; then
  98     AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
  99                      [a value for $1 ($2).  Maybe you do...?])
 100   fi
 101   AC_MSG_NOTICE([Setting $2 to $withval])
 102   GIT_CONF_SUBST([$2], [$withval])
 103  fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
 104
 105 #
 106 # GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
 107 # -----------------------------------------
 108 # Similar to AC_CHECK_FUNC, but on systems that do not generate
 109 # warnings for missing prototypes (e.g. FreeBSD when compiling without
 110 # -Wall), it does not work.  By looking for function definition in
 111 # libraries, this problem can be worked around.
 112 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
 113   AC_SEARCH_LIBS([$1],,
 114   [$2],[$3])
 115 ],[$3])])
 116
 117 #
 118 # GIT_STASH_FLAGS(BASEPATH_VAR)
 119 # -----------------------------
 120 # Allow for easy stashing of LDFLAGS and CPPFLAGS before running
 121 # tests that may want to take user settings into account.
 122 AC_DEFUN([GIT_STASH_FLAGS],[
 123 if test -n "$1"; then
 124    old_CPPFLAGS="$CPPFLAGS"
 125    old_LDFLAGS="$LDFLAGS"
 126    CPPFLAGS="-I$1/include $CPPFLAGS"
 127    LDFLAGS="-L$1/$lib $LDFLAGS"
 128 fi
 129 ])
 130
 131 dnl
 132 dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 133 dnl -----------------------------
 134 dnl Restore the stashed *FLAGS values.
 135 AC_DEFUN([GIT_UNSTASH_FLAGS],[
 136 if test -n "$1"; then
 137    CPPFLAGS="$old_CPPFLAGS"
 138    LDFLAGS="$old_LDFLAGS"
 139 fi
 140 ])
 141
 142 ## Configure body starts here.
 143
 144 AC_PREREQ(2.59)
 145 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
 146
 147 AC_CONFIG_SRCDIR([git.c])
 148
 149 config_file=config.mak.autogen
 150 config_in=config.mak.in
 151
 152 GIT_CONF_SUBST([AUTOCONFIGURED], [YesPlease])
 153
 154 # Directories holding "saner" versions of common or POSIX binaries.
 155 AC_ARG_WITH([sane-tool-path],
 156   [AS_HELP_STRING(
 157     [--with-sane-tool-path=DIR-1[[:DIR-2...:DIR-n]]],
 158     [Directories to prepend to PATH in build system and generated scripts])],
 159   [if test "$withval" = "no"; then
 160     withval=''
 161   else
 162     AC_MSG_NOTICE([Setting SANE_TOOL_PATH to '$withval'])
 163   fi
 164   GIT_CONF_SUBST([SANE_TOOL_PATH], [$withval])],
 165   [# If the "--with-sane-tool-path" option was not given, don't touch
 166    # SANE_TOOL_PATH here, but let defaults in Makefile take care of it.
 167    # This should minimize spurious differences in the behaviour of the
 168    # Git build system when configure is used w.r.t. when it is not.
 169    :])
 170
 171 ## Site configuration related to programs (before tests)
 172 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 173 #
 174 # Set lib to alternative name of lib directory (e.g. lib64)
 175 AC_ARG_WITH([lib],
 176  [AS_HELP_STRING([--with-lib=ARG],
 177                  [ARG specifies alternative name for lib directory])],
 178  [if test "$withval" = "no" || test "$withval" = "yes"; then
 179         AC_MSG_WARN([You should provide name for --with-lib=ARG])
 180   else
 181         lib=$withval
 182         AC_MSG_NOTICE([Setting lib to '$lib'])
 183         GIT_CONF_SUBST([lib])
 184   fi])
 185
 186 if test -z "$lib"; then
 187    AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 188    lib=lib
 189 fi
 190
 191 AC_ARG_ENABLE([pthreads],
 192  [AS_HELP_STRING([--enable-pthreads=FLAGS],
 193   [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
 194   [The default if FLAGS is not specified is to try first -pthread]
 195   [and then -lpthread.]
 196   [--disable-pthreads will disable threading.])],
 197 [
 198 if test "x$enableval" = "xyes"; then
 199    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
 200 elif test "x$enableval" != "xno"; then
 201    PTHREAD_CFLAGS=$enableval
 202    AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
 203 else
 204    AC_MSG_NOTICE([POSIX Threads will be disabled.])
 205    NO_PTHREADS=YesPlease
 206    USER_NOPTHREAD=1
 207 fi],
 208 [
 209    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
 210 ])
 211
 212 # Define option to enable JavaScript minification
 213 AC_ARG_ENABLE([jsmin],
 214 [AS_HELP_STRING([--enable-jsmin=PATH],
 215   [PATH is the name of a JavaScript minifier or the absolute path to one.])],
 216 [
 217   JSMIN=$enableval;
 218   AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
 219   GIT_CONF_SUBST([JSMIN])
 220 ])
 221
 222 # Define option to enable CSS minification
 223 AC_ARG_ENABLE([cssmin],
 224 [AS_HELP_STRING([--enable-cssmin=PATH],
 225   [PATH is the name of a CSS minifier or the absolute path to one.])],
 226 [
 227   CSSMIN=$enableval;
 228   AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
 229   GIT_CONF_SUBST([CSSMIN])
 230 ])
 231
 232 ## Site configuration (override autodetection)
 233 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 234 AC_MSG_NOTICE([CHECKS for site configuration])
 235 #
 236 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 237 # tests.  These tests take up a significant amount of the total test time
 238 # but are not needed unless you plan to talk to SVN repos.
 239 #
 240 # Define PPC_SHA1 environment variable when running make to make use of
 241 # a bundled SHA1 routine optimized for PowerPC.
 242 #
 243 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 244 #
 245 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 246 # /foo/bar/include and /foo/bar/lib directories.
 247 AC_ARG_WITH(openssl,
 248 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 249 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),
 250 GIT_PARSE_WITH([openssl]))
 251
 252 # Define USE_LIBPCRE if you have and want to use libpcre. Various
 253 # commands such as log and grep offer runtime options to use
 254 # Perl-compatible regular expressions instead of standard or extended
 255 # POSIX regular expressions.
 256 #
 257 # USE_LIBPCRE is a synonym for USE_LIBPCRE2, define USE_LIBPCRE1
 258 # instead if you'd like to use the legacy version 1 of the PCRE
 259 # library. Support for version 1 will likely be removed in some future
 260 # release of Git, as upstream has all but abandoned it.
 261 #
 262 # Define LIBPCREDIR=/foo/bar if your PCRE header and library files are in
 263 # /foo/bar/include and /foo/bar/lib directories.
 264 #
 265 AC_ARG_WITH(libpcre,
 266 AS_HELP_STRING([--with-libpcre],[synonym for --with-libpcre2]),
 267     if test "$withval" = "no"; then
 268         USE_LIBPCRE2=
 269     elif test "$withval" = "yes"; then
 270         USE_LIBPCRE2=YesPlease
 271     else
 272         USE_LIBPCRE2=YesPlease
 273         LIBPCREDIR=$withval
 274         AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
 275         dnl USE_LIBPCRE2 can still be modified below, so don't substitute
 276         dnl it yet.
 277         GIT_CONF_SUBST([LIBPCREDIR])
 278     fi)
 279
 280 AC_ARG_WITH(libpcre1,
 281 AS_HELP_STRING([--with-libpcre1],[support Perl-compatible regexes via libpcre1 (default is NO)])
 282 AS_HELP_STRING([],           [ARG can be also prefix for libpcre library and headers]),
 283     if test "$withval" = "no"; then
 284         USE_LIBPCRE1=
 285     elif test "$withval" = "yes"; then
 286         USE_LIBPCRE1=YesPlease
 287     else
 288         USE_LIBPCRE1=YesPlease
 289         LIBPCREDIR=$withval
 290         AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
 291         dnl USE_LIBPCRE1 can still be modified below, so don't substitute
 292         dnl it yet.
 293         GIT_CONF_SUBST([LIBPCREDIR])
 294     fi)
 295
 296 AC_ARG_WITH(libpcre2,
 297 AS_HELP_STRING([--with-libpcre2],[support Perl-compatible regexes via libpcre2 (default is NO)])
 298 AS_HELP_STRING([],           [ARG can be also prefix for libpcre library and headers]),
 299     if test -n "$USE_LIBPCRE2"; then
 300         AC_MSG_ERROR([Only supply one of --with-libpcre or its synonym --with-libpcre2!])
 301     fi
 302
 303     if test -n "$USE_LIBPCRE1"; then
 304         AC_MSG_ERROR([Only supply one of --with-libpcre1 or --with-libpcre2!])
 305     fi
 306
 307     if test "$withval" = "no"; then
 308         USE_LIBPCRE2=
 309     elif test "$withval" = "yes"; then
 310         USE_LIBPCRE2=YesPlease
 311     else
 312         USE_LIBPCRE2=YesPlease
 313         LIBPCREDIR=$withval
 314         AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
 315         dnl USE_LIBPCRE2 can still be modified below, so don't substitute
 316         dnl it yet.
 317         GIT_CONF_SUBST([LIBPCREDIR])
 318     fi)
 319 #
 320 # Define HAVE_ALLOCA_H if you have working alloca(3) defined in that header.
 321 AC_FUNC_ALLOCA
 322 case $ac_cv_working_alloca_h in
 323     yes)    HAVE_ALLOCA_H=YesPlease;;
 324     *)      HAVE_ALLOCA_H='';;
 325 esac
 326 GIT_CONF_SUBST([HAVE_ALLOCA_H])
 327 #
 328 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 329 # git-http-push are not built, and you cannot use http:// and https://
 330 # transports.
 331 #
 332 # Define CURLDIR=/foo/bar if your curl header and library files are in
 333 # /foo/bar/include and /foo/bar/lib directories.
 334 AC_ARG_WITH(curl,
 335 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 336 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 337 GIT_PARSE_WITH(curl))
 338 #
 339 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 340 # not built, and you cannot push using http:// and https:// transports.
 341 #
 342 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 343 # /foo/bar/include and /foo/bar/lib directories.
 344 AC_ARG_WITH(expat,
 345 AS_HELP_STRING([--with-expat],
 346 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 347 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 348 GIT_PARSE_WITH(expat))
 349 #
 350 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 351 # installed in /sw, but don't want GIT to link against any libraries
 352 # installed there.  If defined you may specify your own (or Fink's)
 353 # include directories and library directories by defining CFLAGS
 354 # and LDFLAGS appropriately.
 355 #
 356 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 357 # have DarwinPorts installed in /opt/local, but don't want GIT to
 358 # link against any libraries installed there.  If defined you may
 359 # specify your own (or DarwinPort's) include directories and
 360 # library directories by defining CFLAGS and LDFLAGS appropriately.
 361 #
 362 # Define NO_MMAP if you want to avoid mmap.
 363 #
 364 # Define NO_ICONV if your libc does not properly support iconv.
 365 AC_ARG_WITH(iconv,
 366 AS_HELP_STRING([--without-iconv],
 367 [if your architecture doesn't properly support iconv])
 368 AS_HELP_STRING([--with-iconv=PATH],
 369 [PATH is prefix for libiconv library and headers])
 370 AS_HELP_STRING([],
 371 [used only if you need linking with libiconv]),
 372 GIT_PARSE_WITH(iconv))
 373
 374 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 375 #
 376 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 377 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 378 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 379 # randomly break unless your underlying filesystem supports those sub-second
 380 # times (my ext3 doesn't).
 381 #
 382 # Define USE_STDEV below if you want git to care about the underlying device
 383 # change being considered an inode change from the update-index perspective.
 384
 385 #
 386 # Allow user to set ETC_GITCONFIG variable
 387 GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
 388                         Use VALUE instead of /etc/gitconfig as the
 389                         global git configuration file.
 390                         If VALUE is not fully qualified it will be interpreted
 391                         as a path relative to the computed prefix at runtime.)
 392
 393 #
 394 # Allow user to set ETC_GITATTRIBUTES variable
 395 GIT_PARSE_WITH_SET_MAKE_VAR(gitattributes, ETC_GITATTRIBUTES,
 396                         Use VALUE instead of /etc/gitattributes as the
 397                         global git attributes file.
 398                         If VALUE is not fully qualified it will be interpreted
 399                         as a path relative to the computed prefix at runtime.)
 400
 401 #
 402 # Allow user to set the default pager
 403 GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
 404                         Use VALUE as the fall-back pager instead of 'less'.
 405                         This is used by things like 'git log' when the user
 406                         does not specify a pager to use through alternate
 407                         methods. eg: /usr/bin/pager)
 408 #
 409 # Allow user to set the default editor
 410 GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
 411                         Use VALUE as the fall-back editor instead of 'vi'.
 412                         This is used by things like 'git commit' when the user
 413                         does not specify a preferred editor through other
 414                         methods. eg: /usr/bin/editor)
 415
 416 #
 417 # Define SHELL_PATH to provide path to shell.
 418 GIT_ARG_SET_PATH(shell)
 419 #
 420 # Define PERL_PATH to provide path to Perl.
 421 GIT_ARG_SET_PATH(perl)
 422 #
 423 # Define PYTHON_PATH to provide path to Python.
 424 GIT_ARG_SET_PATH(python, allow-without)
 425 #
 426 # Define ZLIB_PATH to provide path to zlib.
 427 GIT_ARG_SET_PATH(zlib)
 428 #
 429 # Declare the with-tcltk/without-tcltk options.
 430 AC_ARG_WITH(tcltk,
 431 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 432 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 433 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 434 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),
 435 GIT_PARSE_WITH(tcltk))
 436 #
 437
 438
 439 ## Checks for programs.
 440 AC_MSG_NOTICE([CHECKS for programs])
 441 #
 442 AC_PROG_CC([cc gcc])
 443 AC_C_INLINE
 444 case $ac_cv_c_inline in
 445   inline | yes | no) INLINE='';;
 446   *)                 INLINE=$ac_cv_c_inline ;;
 447 esac
 448 GIT_CONF_SUBST([INLINE])
 449
 450 # which switch to pass runtime path to dynamic libraries to the linker
 451 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 452    SAVE_LDFLAGS="${LDFLAGS}"
 453    LDFLAGS="${SAVE_LDFLAGS} -R /"
 454    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 455    LDFLAGS="${SAVE_LDFLAGS}"
 456 ])
 457 if test "$git_cv_ld_dashr" = "yes"; then
 458    CC_LD_DYNPATH=-R
 459 else
 460    AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 461       SAVE_LDFLAGS="${LDFLAGS}"
 462       LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 463       AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 464       LDFLAGS="${SAVE_LDFLAGS}"
 465    ])
 466    if test "$git_cv_ld_wl_rpath" = "yes"; then
 467       CC_LD_DYNPATH=-Wl,-rpath,
 468    else
 469       AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 470          SAVE_LDFLAGS="${LDFLAGS}"
 471          LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 472          AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 473          LDFLAGS="${SAVE_LDFLAGS}"
 474       ])
 475       if test "$git_cv_ld_rpath" = "yes"; then
 476          CC_LD_DYNPATH=-rpath
 477       else
 478          CC_LD_DYNPATH=
 479          AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 480       fi
 481    fi
 482 fi
 483 GIT_CONF_SUBST([CC_LD_DYNPATH])
 484 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 485 AC_CHECK_TOOLS(AR, [gar ar], :)
 486 AC_CHECK_PROGS(TAR, [gtar tar])
 487 AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff])
 488 # TCLTK_PATH will be set to some value if we want Tcl/Tk
 489 # or will be empty otherwise.
 490 if test -n "$NO_TCLTK"; then
 491   TCLTK_PATH=
 492 else
 493   if test "$with_tcltk" = ""; then
 494   # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 495     TCLTK_PATH=wish
 496   elif test "$with_tcltk" = "yes"; then
 497   # Tcl/Tk check requested.
 498     AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 499   else
 500     AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 501     TCLTK_PATH="$with_tcltk"
 502   fi
 503 fi
 504 GIT_CONF_SUBST([TCLTK_PATH])
 505 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 506 if test -n "$ASCIIDOC"; then
 507         AC_MSG_CHECKING([for asciidoc version])
 508         asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 509         case "${asciidoc_version}" in
 510         asciidoc' '8*)
 511                 AC_MSG_RESULT([${asciidoc_version}])
 512                 ;;
 513         *)
 514                 AC_MSG_RESULT([${asciidoc_version} (unknown)])
 515                 ;;
 516         esac
 517 fi
 518
 519 if grep -a ascii configure.ac >/dev/null; then
 520   AC_MSG_RESULT([Using 'grep -a' for sane_grep])
 521   SANE_TEXT_GREP=-a
 522 else
 523   SANE_TEXT_GREP=
 524 fi
 525 GIT_CONF_SUBST([SANE_TEXT_GREP])
 526
 527 ## Checks for libraries.
 528 AC_MSG_NOTICE([CHECKS for libraries])
 529 #
 530 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 531 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 532
 533 GIT_STASH_FLAGS($OPENSSLDIR)
 534
 535 AC_CHECK_LIB([crypto], [SHA1_Init],
 536 [NEEDS_SSL_WITH_CRYPTO=],
 537 [AC_CHECK_LIB([ssl], [SHA1_Init],
 538  [NEEDS_SSL_WITH_CRYPTO=YesPlease NO_OPENSSL=],
 539  [NEEDS_SSL_WITH_CRYPTO=          NO_OPENSSL=YesPlease])])
 540
 541 GIT_UNSTASH_FLAGS($OPENSSLDIR)
 542
 543 GIT_CONF_SUBST([NEEDS_SSL_WITH_CRYPTO])
 544 GIT_CONF_SUBST([NO_OPENSSL])
 545
 546 #
 547 # Handle the USE_LIBPCRE1 and USE_LIBPCRE2 options potentially set
 548 # above.
 549 #
 550
 551 if test -n "$USE_LIBPCRE1"; then
 552
 553 GIT_STASH_FLAGS($LIBPCREDIR)
 554
 555 AC_CHECK_LIB([pcre], [pcre_version],
 556 [USE_LIBPCRE1=YesPlease],
 557 [USE_LIBPCRE1=])
 558
 559 GIT_UNSTASH_FLAGS($LIBPCREDIR)
 560
 561 GIT_CONF_SUBST([USE_LIBPCRE1])
 562
 563 fi
 564
 565
 566 if test -n "$USE_LIBPCRE2"; then
 567
 568 GIT_STASH_FLAGS($LIBPCREDIR)
 569
 570 AC_CHECK_LIB([pcre2-8], [pcre2_config_8],
 571 [USE_LIBPCRE2=YesPlease],
 572 [USE_LIBPCRE2=])
 573
 574 GIT_UNSTASH_FLAGS($LIBPCREDIR)
 575
 576 GIT_CONF_SUBST([USE_LIBPCRE2])
 577
 578 fi
 579
 580 #
 581 # Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 582 # git-http-push are not built, and you cannot use http:// and https://
 583 # transports.
 584
 585 GIT_STASH_FLAGS($CURLDIR)
 586
 587 AC_CHECK_LIB([curl], [curl_global_init],
 588 [NO_CURL=],
 589 [NO_CURL=YesPlease])
 590
 591 GIT_UNSTASH_FLAGS($CURLDIR)
 592
 593 GIT_CONF_SUBST([NO_CURL])
 594
 595 if test -z "$NO_CURL"; then
 596
 597 AC_CHECK_PROG([CURL_CONFIG], [curl-config],
 598 [curl-config],
 599 [no])
 600
 601 if test $CURL_CONFIG != no; then
 602     GIT_CONF_SUBST([CURL_CONFIG])
 603     if test -z "${NO_OPENSSL}"; then
 604       AC_MSG_CHECKING([if Curl supports SSL])
 605       if test $(curl-config --features|grep SSL) = SSL; then
 606          NEEDS_SSL_WITH_CURL=YesPlease
 607          AC_MSG_RESULT([yes])
 608       else
 609          NEEDS_SSL_WITH_CURL=
 610          AC_MSG_RESULT([no])
 611       fi
 612       GIT_CONF_SUBST([NEEDS_SSL_WITH_CURL])
 613     fi
 614 fi
 615
 616 fi
 617
 618
 619 #
 620 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 621 # not built, and you cannot push using http:// and https:// transports.
 622
 623 GIT_STASH_FLAGS($EXPATDIR)
 624
 625 AC_CHECK_LIB([expat], [XML_ParserCreate],
 626 [NO_EXPAT=],
 627 [NO_EXPAT=YesPlease])
 628
 629 GIT_UNSTASH_FLAGS($EXPATDIR)
 630
 631 GIT_CONF_SUBST([NO_EXPAT])
 632
 633 #
 634 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 635 # some Solaris installations).
 636 # Define NO_ICONV if neither libc nor libiconv support iconv.
 637
 638 if test -z "$NO_ICONV"; then
 639
 640 GIT_STASH_FLAGS($ICONVDIR)
 641
 642 AC_DEFUN([ICONVTEST_SRC],
 643 [AC_LANG_PROGRAM([#include <iconv.h>],
 644  [iconv_open("", "");])])
 645
 646 if test -n "$ICONVDIR"; then
 647    lib_order="-liconv -lc"
 648 else
 649    lib_order="-lc -liconv"
 650 fi
 651
 652 NO_ICONV=YesPlease
 653
 654 for l in $lib_order; do
 655     if test "$l" = "-liconv"; then
 656        NEEDS_LIBICONV=YesPlease
 657     else
 658        NEEDS_LIBICONV=
 659     fi
 660
 661     old_LIBS="$LIBS"
 662     LIBS="$LIBS $l"
 663     AC_MSG_CHECKING([for iconv in $l])
 664     AC_LINK_IFELSE([ICONVTEST_SRC],
 665         [AC_MSG_RESULT([yes])
 666         NO_ICONV=
 667         break],
 668         [AC_MSG_RESULT([no])])
 669     LIBS="$old_LIBS"
 670 done
 671
 672 #in case of break
 673 LIBS="$old_LIBS"
 674
 675 GIT_UNSTASH_FLAGS($ICONVDIR)
 676
 677 GIT_CONF_SUBST([NEEDS_LIBICONV])
 678 GIT_CONF_SUBST([NO_ICONV])
 679
 680 if test -n "$NO_ICONV"; then
 681     NEEDS_LIBICONV=
 682 fi
 683
 684 fi
 685
 686 #
 687 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 688
 689 GIT_STASH_FLAGS($ZLIB_PATH)
 690
 691 AC_DEFUN([ZLIBTEST_SRC], [
 692 AC_LANG_PROGRAM([#include <zlib.h>],
 693  [deflateBound(0, 0);])])
 694 AC_MSG_CHECKING([for deflateBound in -lz])
 695 old_LIBS="$LIBS"
 696 LIBS="$LIBS -lz"
 697 AC_LINK_IFELSE([ZLIBTEST_SRC],
 698         [AC_MSG_RESULT([yes])],
 699         [AC_MSG_RESULT([no])
 700         NO_DEFLATE_BOUND=yes])
 701 LIBS="$old_LIBS"
 702
 703 GIT_UNSTASH_FLAGS($ZLIB_PATH)
 704
 705 GIT_CONF_SUBST([NO_DEFLATE_BOUND])
 706
 707 #
 708 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 709 # Patrick Mauritz).
 710 AC_CHECK_LIB([c], [socket],
 711 [NEEDS_SOCKET=],
 712 [NEEDS_SOCKET=YesPlease])
 713 GIT_CONF_SUBST([NEEDS_SOCKET])
 714 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 715
 716 #
 717 # The next few tests will define NEEDS_RESOLV if linking with
 718 # libresolv provides some of the functions we would normally get
 719 # from libc.
 720 NEEDS_RESOLV=
 721 #
 722 # Define NO_INET_NTOP if linking with -lresolv is not enough.
 723 # Solaris 2.7 in particular hos inet_ntop in -lresolv.
 724 NO_INET_NTOP=
 725 AC_CHECK_FUNC([inet_ntop],
 726     [],
 727     [AC_CHECK_LIB([resolv], [inet_ntop],
 728         [NEEDS_RESOLV=YesPlease],
 729         [NO_INET_NTOP=YesPlease])
 730 ])
 731 GIT_CONF_SUBST([NO_INET_NTOP])
 732 #
 733 # Define NO_INET_PTON if linking with -lresolv is not enough.
 734 # Solaris 2.7 in particular hos inet_pton in -lresolv.
 735 NO_INET_PTON=
 736 AC_CHECK_FUNC([inet_pton],
 737     [],
 738     [AC_CHECK_LIB([resolv], [inet_pton],
 739         [NEEDS_RESOLV=YesPlease],
 740         [NO_INET_PTON=YesPlease])
 741 ])
 742 GIT_CONF_SUBST([NO_INET_PTON])
 743 #
 744 # Define NO_HSTRERROR if linking with -lresolv is not enough.
 745 # Solaris 2.6 in particular has no hstrerror, even in -lresolv.
 746 NO_HSTRERROR=
 747 AC_CHECK_FUNC([hstrerror],
 748     [],
 749     [AC_CHECK_LIB([resolv], [hstrerror],
 750         [NEEDS_RESOLV=YesPlease],
 751         [NO_HSTRERROR=YesPlease])
 752 ])
 753 GIT_CONF_SUBST([NO_HSTRERROR])
 754
 755 dnl This must go after all the possible places for its initialization,
 756 dnl in the AC_CHECK_FUNC invocations above.
 757 GIT_CONF_SUBST([NEEDS_RESOLV])
 758 #
 759 # If any of the above tests determined that -lresolv is needed at
 760 # build-time, also set it here for remaining configure-time checks.
 761 test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
 762
 763 AC_CHECK_LIB([c], [basename],
 764 [NEEDS_LIBGEN=],
 765 [NEEDS_LIBGEN=YesPlease])
 766 GIT_CONF_SUBST([NEEDS_LIBGEN])
 767 test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
 768
 769 AC_CHECK_LIB([c], [gettext],
 770 [LIBC_CONTAINS_LIBINTL=YesPlease],
 771 [LIBC_CONTAINS_LIBINTL=])
 772 GIT_CONF_SUBST([LIBC_CONTAINS_LIBINTL])
 773
 774 #
 775 # Define NO_GETTEXT if you don't want Git output to be translated.
 776 # A translated Git requires GNU libintl or another gettext implementation
 777 AC_CHECK_HEADER([libintl.h],
 778 [NO_GETTEXT=],
 779 [NO_GETTEXT=YesPlease])
 780 GIT_CONF_SUBST([NO_GETTEXT])
 781
 782 if test -z "$NO_GETTEXT"; then
 783     test -n "$LIBC_CONTAINS_LIBINTL" || LIBS="$LIBS -lintl"
 784 fi
 785
 786 ## Checks for header files.
 787 AC_MSG_NOTICE([CHECKS for header files])
 788 #
 789 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
 790 AC_CHECK_HEADER([sys/select.h],
 791 [NO_SYS_SELECT_H=],
 792 [NO_SYS_SELECT_H=UnfortunatelyYes])
 793 GIT_CONF_SUBST([NO_SYS_SELECT_H])
 794 #
 795 # Define NO_SYS_POLL_H if you don't have sys/poll.h
 796 AC_CHECK_HEADER([sys/poll.h],
 797 [NO_SYS_POLL_H=],
 798 [NO_SYS_POLL_H=UnfortunatelyYes])
 799 GIT_CONF_SUBST([NO_SYS_POLL_H])
 800 #
 801 # Define NO_INTTYPES_H if you don't have inttypes.h
 802 AC_CHECK_HEADER([inttypes.h],
 803 [NO_INTTYPES_H=],
 804 [NO_INTTYPES_H=UnfortunatelyYes])
 805 GIT_CONF_SUBST([NO_INTTYPES_H])
 806 #
 807 # Define OLD_ICONV if your library has an old iconv(), where the second
 808 # (input buffer pointer) parameter is declared with type (const char **).
 809 AC_DEFUN([OLDICONVTEST_SRC], [
 810 AC_LANG_PROGRAM([[
 811 #include <iconv.h>
 812
 813 extern size_t iconv(iconv_t cd,
 814                     char **inbuf, size_t *inbytesleft,
 815                     char **outbuf, size_t *outbytesleft);
 816 ]], [])])
 817
 818 GIT_STASH_FLAGS($ICONVDIR)
 819
 820 AC_MSG_CHECKING([for old iconv()])
 821 AC_COMPILE_IFELSE([OLDICONVTEST_SRC],
 822         [AC_MSG_RESULT([no])],
 823         [AC_MSG_RESULT([yes])
 824         OLD_ICONV=UnfortunatelyYes])
 825
 826 GIT_UNSTASH_FLAGS($ICONVDIR)
 827
 828 GIT_CONF_SUBST([OLD_ICONV])
 829
 830 ## Checks for typedefs, structures, and compiler characteristics.
 831 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 832 #
 833 TYPE_SOCKLEN_T
 834 case $ac_cv_type_socklen_t in
 835   yes)  SOCKLEN_T='';;
 836   *)    SOCKLEN_T=$git_cv_socklen_t_equiv;;
 837 esac
 838 GIT_CONF_SUBST([SOCKLEN_T])
 839
 840 #
 841 # Define NO_STRUCT_ITIMERVAL if you don't have struct itimerval.
 842 AC_CHECK_TYPES([struct itimerval],
 843 [NO_STRUCT_ITIMERVAL=],
 844 [NO_STRUCT_ITIMERVAL=UnfortunatelyYes],
 845 [#include <sys/time.h>])
 846 GIT_CONF_SUBST([NO_STRUCT_ITIMERVAL])
 847 #
 848 # Define USE_ST_TIMESPEC=YesPlease when stat.st_mtimespec.tv_nsec exists.
 849 # Define NO_NSEC=YesPlease when neither stat.st_mtim.tv_nsec nor
 850 # stat.st_mtimespec.tv_nsec exists.
 851 AC_CHECK_MEMBER([struct stat.st_mtimespec.tv_nsec])
 852 AC_CHECK_MEMBER([struct stat.st_mtim.tv_nsec])
 853 if test x$ac_cv_member_struct_stat_st_mtimespec_tv_nsec = xyes; then
 854         USE_ST_TIMESPEC=YesPlease
 855         GIT_CONF_SUBST([USE_ST_TIMESPEC])
 856 elif test x$ac_cv_member_struct_stat_st_mtim_tv_nsec != xyes; then
 857         NO_NSEC=YesPlease
 858         GIT_CONF_SUBST([NO_NSEC])
 859 fi
 860 #
 861 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 862 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 863 AC_CHECK_MEMBER(struct dirent.d_type,
 864 [NO_D_TYPE_IN_DIRENT=],
 865 [NO_D_TYPE_IN_DIRENT=YesPlease],
 866 [#include <dirent.h>])
 867 GIT_CONF_SUBST([NO_D_TYPE_IN_DIRENT])
 868 #
 869 # Define NO_GECOS_IN_PWENT if you don't have pw_gecos in struct passwd
 870 # in the C library.
 871 AC_CHECK_MEMBER(struct passwd.pw_gecos,
 872 [NO_GECOS_IN_PWENT=],
 873 [NO_GECOS_IN_PWENT=YesPlease],
 874 [#include <pwd.h>])
 875 GIT_CONF_SUBST([NO_GECOS_IN_PWENT])
 876 #
 877 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 878 # sockaddr_storage.
 879 AC_CHECK_TYPE(struct sockaddr_storage,
 880 [NO_SOCKADDR_STORAGE=],
 881 [NO_SOCKADDR_STORAGE=YesPlease],[
 882 #include <sys/types.h>
 883 #include <sys/socket.h>
 884 ])
 885 GIT_CONF_SUBST([NO_SOCKADDR_STORAGE])
 886 #
 887 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 888 AC_CHECK_TYPE([struct addrinfo],[
 889  GIT_CHECK_FUNC([getaddrinfo],
 890   [NO_IPV6=],
 891   [NO_IPV6=YesPlease])
 892 ],[NO_IPV6=YesPlease],[
 893 #include <sys/types.h>
 894 #include <sys/socket.h>
 895 #include <netdb.h>
 896 ])
 897 GIT_CONF_SUBST([NO_IPV6])
 898 #
 899 # Define NO_REGEX if your C library lacks regex support with REG_STARTEND
 900 # feature.
 901 AC_CACHE_CHECK([whether the platform regex supports REG_STARTEND],
 902  [ac_cv_c_regex_with_reg_startend], [
 903 AC_EGREP_CPP(yippeeyeswehaveit,
 904         AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 905 #include <regex.h>
 906 ],
 907 [#ifdef REG_STARTEND
 908 yippeeyeswehaveit
 909 #endif
 910 ]),
 911         [ac_cv_c_regex_with_reg_startend=yes],
 912         [ac_cv_c_regex_with_reg_startend=no])
 913 ])
 914 if test $ac_cv_c_regex_with_reg_startend = yes; then
 915         NO_REGEX=
 916 else
 917         NO_REGEX=YesPlease
 918 fi
 919 GIT_CONF_SUBST([NO_REGEX])
 920 #
 921 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 922 # when attempting to read from an fopen'ed directory.
 923 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 924  [ac_cv_fread_reads_directories],
 925 [
 926 AC_RUN_IFELSE(
 927         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 928                 [[
 929                 FILE *f = fopen(".", "r");
 930                 return f != NULL;]])],
 931         [ac_cv_fread_reads_directories=no],
 932         [ac_cv_fread_reads_directories=yes])
 933 ])
 934 if test $ac_cv_fread_reads_directories = yes; then
 935         FREAD_READS_DIRECTORIES=UnfortunatelyYes
 936 else
 937         FREAD_READS_DIRECTORIES=
 938 fi
 939 GIT_CONF_SUBST([FREAD_READS_DIRECTORIES])
 940 #
 941 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 942 # or vsnprintf() return -1 instead of number of characters which would
 943 # have been written to the final string if enough space had been available.
 944 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 945  [ac_cv_snprintf_returns_bogus],
 946 [
 947 AC_RUN_IFELSE(
 948         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 949                 #include "stdarg.h"
 950
 951                 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 952                 {
 953                   int ret;
 954                   va_list ap;
 955                   va_start(ap, format);
 956                   ret = vsnprintf(str, maxsize, format, ap);
 957                   va_end(ap);
 958                   return ret;
 959                 }],
 960                 [[char buf[6];
 961                   if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 962                       || strcmp(buf, "12")) return 1;
 963                   if (snprintf(buf, 3, "%s", "12345") != 5
 964                       || strcmp(buf, "12")) return 1]])],
 965         [ac_cv_snprintf_returns_bogus=no],
 966         [ac_cv_snprintf_returns_bogus=yes])
 967 ])
 968 if test $ac_cv_snprintf_returns_bogus = yes; then
 969         SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 970 else
 971         SNPRINTF_RETURNS_BOGUS=
 972 fi
 973 GIT_CONF_SUBST([SNPRINTF_RETURNS_BOGUS])
 974 #
 975 # Define NEEDS_MODE_TRANSLATION if your OS strays from the typical file type
 976 # bits in mode values.
 977 AC_CACHE_CHECK([whether the platform uses typical file type bits],
 978  [ac_cv_sane_mode_bits], [
 979 AC_EGREP_CPP(yippeeyeswehaveit,
 980         AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 981 [#if S_IFMT == 0170000 && \
 982         S_IFREG == 0100000 && S_IFDIR == 0040000 && S_IFLNK == 0120000 && \
 983         S_IFBLK == 0060000 && S_IFCHR == 0020000 && \
 984         S_IFIFO == 0010000 && S_IFSOCK == 0140000
 985 yippeeyeswehaveit
 986 #endif
 987 ]),
 988         [ac_cv_sane_mode_bits=yes],
 989         [ac_cv_sane_mode_bits=no])
 990 ])
 991 if test $ac_cv_sane_mode_bits = yes; then
 992         NEEDS_MODE_TRANSLATION=
 993 else
 994         NEEDS_MODE_TRANSLATION=UnfortunatelyYes
 995 fi
 996 GIT_CONF_SUBST([NEEDS_MODE_TRANSLATION])
 997
 998
 999 ## Checks for library functions.
1000 ## (in default C library and libraries checked by AC_CHECK_LIB)
1001 AC_MSG_NOTICE([CHECKS for library functions])
1002 #
1003 # Define NO_LIBGEN_H if you don't have libgen.h.
1004 AC_CHECK_HEADER([libgen.h],
1005 [NO_LIBGEN_H=],
1006 [NO_LIBGEN_H=YesPlease])
1007 GIT_CONF_SUBST([NO_LIBGEN_H])
1008 #
1009 # Define HAVE_PATHS_H if you have paths.h.
1010 AC_CHECK_HEADER([paths.h],
1011 [HAVE_PATHS_H=YesPlease],
1012 [HAVE_PATHS_H=])
1013 GIT_CONF_SUBST([HAVE_PATHS_H])
1014 #
1015 # Define HAVE_LIBCHARSET_H if have libcharset.h
1016 AC_CHECK_HEADER([libcharset.h],
1017 [HAVE_LIBCHARSET_H=YesPlease],
1018 [HAVE_LIBCHARSET_H=])
1019 GIT_CONF_SUBST([HAVE_LIBCHARSET_H])
1020 #
1021 # Define HAVE_STRINGS_H if you have strings.h
1022 AC_CHECK_HEADER([strings.h],
1023 [HAVE_STRINGS_H=YesPlease],
1024 [HAVE_STRINGS_H=])
1025 GIT_CONF_SUBST([HAVE_STRINGS_H])
1026 # Define CHARSET_LIB if libiconv does not export the locale_charset symbol
1027 # and libcharset does
1028 CHARSET_LIB=
1029 AC_CHECK_LIB([iconv], [locale_charset],
1030        [CHARSET_LIB=-liconv],
1031        [AC_CHECK_LIB([charset], [locale_charset],
1032                      [CHARSET_LIB=-lcharset])])
1033 GIT_CONF_SUBST([CHARSET_LIB])
1034 #
1035 # Define HAVE_CLOCK_GETTIME=YesPlease if clock_gettime is available.
1036 GIT_CHECK_FUNC(clock_gettime,
1037         [HAVE_CLOCK_GETTIME=YesPlease],
1038         [HAVE_CLOCK_GETTIME=])
1039 GIT_CONF_SUBST([HAVE_CLOCK_GETTIME])
1040
1041 AC_DEFUN([CLOCK_MONOTONIC_SRC], [
1042 AC_LANG_PROGRAM([[
1043 #include <time.h>
1044 clockid_t id = CLOCK_MONOTONIC;
1045 ]])])
1046
1047 #
1048 # Define HAVE_CLOCK_MONOTONIC=YesPlease if CLOCK_MONOTONIC is available.
1049 AC_MSG_CHECKING([for CLOCK_MONOTONIC])
1050 AC_COMPILE_IFELSE([CLOCK_MONOTONIC_SRC],
1051         [AC_MSG_RESULT([yes])
1052         HAVE_CLOCK_MONOTONIC=YesPlease],
1053         [AC_MSG_RESULT([no])
1054         HAVE_CLOCK_MONOTONIC=])
1055 GIT_CONF_SUBST([HAVE_CLOCK_MONOTONIC])
1056 #
1057 # Define NO_SETITIMER if you don't have setitimer.
1058 GIT_CHECK_FUNC(setitimer,
1059 [NO_SETITIMER=],
1060 [NO_SETITIMER=YesPlease])
1061 GIT_CONF_SUBST([NO_SETITIMER])
1062 #
1063 # Define NO_STRCASESTR if you don't have strcasestr.
1064 GIT_CHECK_FUNC(strcasestr,
1065 [NO_STRCASESTR=],
1066 [NO_STRCASESTR=YesPlease])
1067 GIT_CONF_SUBST([NO_STRCASESTR])
1068 #
1069 # Define NO_MEMMEM if you don't have memmem.
1070 GIT_CHECK_FUNC(memmem,
1071 [NO_MEMMEM=],
1072 [NO_MEMMEM=YesPlease])
1073 GIT_CONF_SUBST([NO_MEMMEM])
1074 #
1075 # Define NO_STRLCPY if you don't have strlcpy.
1076 GIT_CHECK_FUNC(strlcpy,
1077 [NO_STRLCPY=],
1078 [NO_STRLCPY=YesPlease])
1079 GIT_CONF_SUBST([NO_STRLCPY])
1080 #
1081 # Define NO_UINTMAX_T if your platform does not have uintmax_t
1082 AC_CHECK_TYPE(uintmax_t,
1083 [NO_UINTMAX_T=],
1084 [NO_UINTMAX_T=YesPlease],[
1085 #include <inttypes.h>
1086 ])
1087 GIT_CONF_SUBST([NO_UINTMAX_T])
1088 #
1089 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
1090 GIT_CHECK_FUNC(strtoumax,
1091 [NO_STRTOUMAX=],
1092 [NO_STRTOUMAX=YesPlease])
1093 GIT_CONF_SUBST([NO_STRTOUMAX])
1094 #
1095 # Define NO_SETENV if you don't have setenv in the C library.
1096 GIT_CHECK_FUNC(setenv,
1097 [NO_SETENV=],
1098 [NO_SETENV=YesPlease])
1099 GIT_CONF_SUBST([NO_SETENV])
1100 #
1101 # Define NO_UNSETENV if you don't have unsetenv in the C library.
1102 GIT_CHECK_FUNC(unsetenv,
1103 [NO_UNSETENV=],
1104 [NO_UNSETENV=YesPlease])
1105 GIT_CONF_SUBST([NO_UNSETENV])
1106 #
1107 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
1108 GIT_CHECK_FUNC(mkdtemp,
1109 [NO_MKDTEMP=],
1110 [NO_MKDTEMP=YesPlease])
1111 GIT_CONF_SUBST([NO_MKDTEMP])
1112 #
1113 # Define NO_INITGROUPS if you don't have initgroups in the C library.
1114 GIT_CHECK_FUNC(initgroups,
1115 [NO_INITGROUPS=],
1116 [NO_INITGROUPS=YesPlease])
1117 GIT_CONF_SUBST([NO_INITGROUPS])
1118 #
1119 # Define HAVE_GETDELIM if you have getdelim in the C library.
1120 GIT_CHECK_FUNC(getdelim,
1121 [HAVE_GETDELIM=YesPlease],
1122 [HAVE_GETDELIM=])
1123 GIT_CONF_SUBST([HAVE_GETDELIM])
1124 #
1125 #
1126 # Define NO_MMAP if you want to avoid mmap.
1127 #
1128 # Define NO_ICONV if your libc does not properly support iconv.
1129
1130 AC_DEFUN([BSD_SYSCTL_SRC], [
1131 AC_LANG_PROGRAM([[
1132 #include <stddef.h>
1133 #include <sys/types.h>
1134 #include <sys/sysctl.h>
1135 ]],[[
1136 int val, mib[2];
1137 size_t len;
1138 mib[0] = CTL_HW;
1139 mib[1] = 1;
1140 len = sizeof(val);
1141 return sysctl(mib, 2, &val, &len, NULL, 0) ? 1 : 0;
1142 ]])])
1143
1144 #
1145 # Define HAVE_BSD_SYSCTL=YesPlease if a BSD-compatible sysctl function is available.
1146 AC_MSG_CHECKING([for BSD sysctl])
1147 AC_COMPILE_IFELSE([BSD_SYSCTL_SRC],
1148         [AC_MSG_RESULT([yes])
1149         HAVE_BSD_SYSCTL=YesPlease],
1150         [AC_MSG_RESULT([no])
1151         HAVE_BSD_SYSCTL=])
1152 GIT_CONF_SUBST([HAVE_BSD_SYSCTL])
1153
1154 ## Other checks.
1155 # Define USE_PIC if you need the main git objects to be built with -fPIC
1156 # in order to build and link perl/Git.so.  x86-64 seems to need this.
1157 #
1158 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
1159 # Enable it on Windows.  By default, symrefs are still used.
1160 #
1161 # Define NO_PTHREADS if we do not have pthreads.
1162 #
1163 # Define PTHREAD_LIBS to the linker flag used for Pthread support.
1164 AC_DEFUN([PTHREADTEST_SRC], [
1165 AC_LANG_PROGRAM([[
1166 #include <pthread.h>
1167 static void *noop(void *ignore) { return ignore; }
1168 ]], [[
1169         pthread_mutex_t test_mutex;
1170         pthread_key_t test_key;
1171         pthread_t th;
1172         int retcode = 0;
1173         void *ret = (void *)0;
1174         retcode |= pthread_key_create(&test_key, (void *)0);
1175         retcode |= pthread_mutex_init(&test_mutex,(void *)0);
1176         retcode |= pthread_mutex_lock(&test_mutex);
1177         retcode |= pthread_mutex_unlock(&test_mutex);
1178         retcode |= pthread_create(&th, ret, noop, ret);
1179         retcode |= pthread_join(th, &ret);
1180         return retcode;
1181 ]])])
1182
1183 dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
1184 dnl   [[#include <pthread.h>]],
1185 dnl   [[pthread_mutex_t test_mutex;]]
1186 dnl )])
1187
1188 NO_PTHREADS=UnfortunatelyYes
1189 PTHREAD_LIBS=
1190
1191 if test -n "$USER_NOPTHREAD"; then
1192    AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
1193 # handle these separately since PTHREAD_CFLAGS could be '-lpthreads
1194 # -D_REENTRANT' or some such.
1195 elif test -z "$PTHREAD_CFLAGS"; then
1196   threads_found=no
1197   # Attempt to compile and link some code using pthreads to determine
1198   # required linker flags. The order is somewhat important here: We
1199   # first try it without any extra flags, to catch systems where
1200   # pthreads are part of the C library, then go on testing various other
1201   # flags. We do so to avoid false positives. For example, on Mac OS X
1202   # pthreads are part of the C library; moreover, the compiler allows us
1203   # to add "-mt" to the CFLAGS (although it will do nothing except
1204   # trigger a warning about an unused flag). Hence if we checked for
1205   # "-mt" before "" we would end up picking it. But unfortunately this
1206   # would then trigger compiler warnings on every single file we compile.
1207   for opt in "" -mt -pthread -lpthread; do
1208      old_CFLAGS="$CFLAGS"
1209      old_LIBS="$LIBS"
1210      case "$opt" in
1211         -l*)  LIBS="$opt $LIBS" ;;
1212         *)    CFLAGS="$opt $CFLAGS" ;;
1213      esac
1214
1215      AC_MSG_CHECKING([for POSIX Threads with '$opt'])
1216      AC_LINK_IFELSE([PTHREADTEST_SRC],
1217         [AC_MSG_RESULT([yes])
1218                 NO_PTHREADS=
1219                 PTHREAD_LIBS="$opt"
1220                 PTHREAD_CFLAGS="$opt"
1221                 threads_found=yes
1222                 break
1223         ],
1224         [AC_MSG_RESULT([no])])
1225       CFLAGS="$old_CFLAGS"
1226       LIBS="$old_LIBS"
1227   done
1228   if test $threads_found != yes; then
1229     AC_CHECK_LIB([pthread], [pthread_create],
1230         [PTHREAD_LIBS="-lpthread"],
1231         [NO_PTHREADS=UnfortunatelyYes])
1232   fi
1233 else
1234   old_CFLAGS="$CFLAGS"
1235   CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1236   AC_MSG_CHECKING([for POSIX Threads with '$PTHREAD_CFLAGS'])
1237   AC_LINK_IFELSE([PTHREADTEST_SRC],
1238         [AC_MSG_RESULT([yes])
1239                 NO_PTHREADS=
1240                 PTHREAD_LIBS="$PTHREAD_CFLAGS"
1241         ],
1242         [AC_MSG_RESULT([no])])
1243
1244   CFLAGS="$old_CFLAGS"
1245 fi
1246
1247 CFLAGS="$old_CFLAGS"
1248
1249 GIT_CONF_SUBST([PTHREAD_CFLAGS])
1250 GIT_CONF_SUBST([PTHREAD_LIBS])
1251 GIT_CONF_SUBST([NO_PTHREADS])
1252
1253 ## Output files
1254 AC_CONFIG_FILES(["${config_file}":"${config_in}"])
1255 AC_OUTPUT