git.oblomov.eu Git - git/blob - perl/Git/SVN/Editor.pm

   1 package Git::SVN::Editor;
   2 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
   3 use strict;
   4 use warnings;
   5 use SVN::Core;
   6 use SVN::Delta;
   7 use Carp qw/croak/;
   8 use IO::File;
   9 use Git qw/command command_oneline command_noisy command_output_pipe
  10            command_input_pipe command_close_pipe
  11            command_bidi_pipe command_close_bidi_pipe/;
  12 BEGIN {
  13         @ISA = qw(SVN::Delta::Editor);
  14 }
  15
  16 sub new {
  17         my ($class, $opts) = @_;
  18         foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
  19                 die "$_ required!\n" unless (defined $opts->{$_});
  20         }
  21
  22         my $pool = SVN::Pool->new;
  23         my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
  24         my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
  25                                      $opts->{r}, $mods);
  26
  27         # $opts->{ra} functions should not be used after this:
  28         my @ce  = $opts->{ra}->get_commit_editor($opts->{log},
  29                                                 $opts->{editor_cb}, $pool);
  30         my $self = SVN::Delta::Editor->new(@ce, $pool);
  31         bless $self, $class;
  32         foreach (qw/svn_path r tree_a tree_b/) {
  33                 $self->{$_} = $opts->{$_};
  34         }
  35         $self->{url} = $opts->{ra}->{url};
  36         $self->{mods} = $mods;
  37         $self->{types} = $types;
  38         $self->{pool} = $pool;
  39         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
  40         $self->{rm} = { };
  41         $self->{path_prefix} = length $self->{svn_path} ?
  42                                "$self->{svn_path}/" : '';
  43         $self->{config} = $opts->{config};
  44         $self->{mergeinfo} = $opts->{mergeinfo};
  45         return $self;
  46 }
  47
  48 sub generate_diff {
  49         my ($tree_a, $tree_b) = @_;
  50         my @diff_tree = qw(diff-tree -z -r);
  51         if ($_cp_similarity) {
  52                 push @diff_tree, "-C$_cp_similarity";
  53         } else {
  54                 push @diff_tree, '-C';
  55         }
  56         push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
  57         push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
  58         push @diff_tree, $tree_a, $tree_b;
  59         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
  60         local $/ = "\0";
  61         my $state = 'meta';
  62         my @mods;
  63         while (<$diff_fh>) {
  64                 chomp $_; # this gets rid of the trailing "\0"
  65                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
  66                                         ($::sha1)\s($::sha1)\s
  67                                         ([MTCRAD])\d*$/xo) {
  68                         push @mods, {   mode_a => $1, mode_b => $2,
  69                                         sha1_a => $3, sha1_b => $4,
  70                                         chg => $5 };
  71                         if ($5 =~ /^(?:C|R)$/) {
  72                                 $state = 'file_a';
  73                         } else {
  74                                 $state = 'file_b';
  75                         }
  76                 } elsif ($state eq 'file_a') {
  77                         my $x = $mods[$#mods] or croak "Empty array\n";
  78                         if ($x->{chg} !~ /^(?:C|R)$/) {
  79                                 croak "Error parsing $_, $x->{chg}\n";
  80                         }
  81                         $x->{file_a} = $_;
  82                         $state = 'file_b';
  83                 } elsif ($state eq 'file_b') {
  84                         my $x = $mods[$#mods] or croak "Empty array\n";
  85                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
  86                                 croak "Error parsing $_, $x->{chg}\n";
  87                         }
  88                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
  89                                 croak "Error parsing $_, $x->{chg}\n";
  90                         }
  91                         $x->{file_b} = $_;
  92                         $state = 'meta';
  93                 } else {
  94                         croak "Error parsing $_\n";
  95                 }
  96         }
  97         command_close_pipe($diff_fh, $ctx);
  98         \@mods;
  99 }
 100
 101 sub check_diff_paths {
 102         my ($ra, $pfx, $rev, $mods) = @_;
 103         my %types;
 104         $pfx .= '/' if length $pfx;
 105
 106         sub type_diff_paths {
 107                 my ($ra, $types, $path, $rev) = @_;
 108                 my @p = split m#/+#, $path;
 109                 my $c = shift @p;
 110                 unless (defined $types->{$c}) {
 111                         $types->{$c} = $ra->check_path($c, $rev);
 112                 }
 113                 while (@p) {
 114                         $c .= '/' . shift @p;
 115                         next if defined $types->{$c};
 116                         $types->{$c} = $ra->check_path($c, $rev);
 117                 }
 118         }
 119
 120         foreach my $m (@$mods) {
 121                 foreach my $f (qw/file_a file_b/) {
 122                         next unless defined $m->{$f};
 123                         my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
 124                         if (length $pfx.$dir && ! defined $types{$dir}) {
 125                                 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
 126                         }
 127                 }
 128         }
 129         \%types;
 130 }
 131
 132 sub split_path {
 133         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
 134 }
 135
 136 sub repo_path {
 137         my ($self, $path) = @_;
 138         if (my $enc = $self->{pathnameencoding}) {
 139                 require Encode;
 140                 Encode::from_to($path, $enc, 'UTF-8');
 141         }
 142         $self->{path_prefix}.(defined $path ? $path : '');
 143 }
 144
 145 sub url_path {
 146         my ($self, $path) = @_;
 147         if ($self->{url} =~ m#^https?://#) {
 148                 # characters are taken from subversion/libsvn_subr/path.c
 149                 $path =~ s#([^~a-zA-Z0-9_./!$&'()*+,-])#sprintf("%%%02X",ord($1))#eg;
 150         }
 151         $self->{url} . '/' . $self->repo_path($path);
 152 }
 153
 154 sub rmdirs {
 155         my ($self) = @_;
 156         my $rm = $self->{rm};
 157         delete $rm->{''}; # we never delete the url we're tracking
 158         return unless %$rm;
 159
 160         foreach (keys %$rm) {
 161                 my @d = split m#/#, $_;
 162                 my $c = shift @d;
 163                 $rm->{$c} = 1;
 164                 while (@d) {
 165                         $c .= '/' . shift @d;
 166                         $rm->{$c} = 1;
 167                 }
 168         }
 169         delete $rm->{$self->{svn_path}};
 170         delete $rm->{''}; # we never delete the url we're tracking
 171         return unless %$rm;
 172
 173         my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
 174                                              $self->{tree_b});
 175         local $/ = "\0";
 176         while (<$fh>) {
 177                 chomp;
 178                 my @dn = split m#/#, $_;
 179                 while (pop @dn) {
 180                         delete $rm->{join '/', @dn};
 181                 }
 182                 unless (%$rm) {
 183                         close $fh;
 184                         return;
 185                 }
 186         }
 187         command_close_pipe($fh, $ctx);
 188
 189         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
 190         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
 191                 $self->close_directory($bat->{$d}, $p);
 192                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
 193                 print "\tD+\t$d/\n" unless $::_q;
 194                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
 195                 delete $bat->{$d};
 196         }
 197 }
 198
 199 sub open_or_add_dir {
 200         my ($self, $full_path, $baton, $deletions) = @_;
 201         my $t = $self->{types}->{$full_path};
 202         if (!defined $t) {
 203                 die "$full_path not known in r$self->{r} or we have a bug!\n";
 204         }
 205         {
 206                 no warnings 'once';
 207                 # SVN::Node::none and SVN::Node::file are used only once,
 208                 # so we're shutting up Perl's warnings about them.
 209                 if ($t == $SVN::Node::none || defined($deletions->{$full_path})) {
 210                         return $self->add_directory($full_path, $baton,
 211                             undef, -1, $self->{pool});
 212                 } elsif ($t == $SVN::Node::dir) {
 213                         return $self->open_directory($full_path, $baton,
 214                             $self->{r}, $self->{pool});
 215                 } # no warnings 'once'
 216                 print STDERR "$full_path already exists in repository at ",
 217                     "r$self->{r} and it is not a directory (",
 218                     ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
 219         } # no warnings 'once'
 220         exit 1;
 221 }
 222
 223 sub ensure_path {
 224         my ($self, $path, $deletions) = @_;
 225         my $bat = $self->{bat};
 226         my $repo_path = $self->repo_path($path);
 227         return $bat->{''} unless (length $repo_path);
 228
 229         my @p = split m#/+#, $repo_path;
 230         my $c = shift @p;
 231         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''}, $deletions);
 232         while (@p) {
 233                 my $c0 = $c;
 234                 $c .= '/' . shift @p;
 235                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0}, $deletions);
 236         }
 237         return $bat->{$c};
 238 }
 239
 240 # Subroutine to convert a globbing pattern to a regular expression.
 241 # From perl cookbook.
 242 sub glob2pat {
 243         my $globstr = shift;
 244         my %patmap = ('*' => '.*', '?' => '.', '[' => '[', ']' => ']');
 245         $globstr =~ s{(.)} { $patmap{$1} || "\Q$1" }ge;
 246         return '^' . $globstr . '$';
 247 }
 248
 249 sub check_autoprop {
 250         my ($self, $pattern, $properties, $file, $fbat) = @_;
 251         # Convert the globbing pattern to a regular expression.
 252         my $regex = glob2pat($pattern);
 253         # Check if the pattern matches the file name.
 254         if($file =~ m/($regex)/) {
 255                 # Parse the list of properties to set.
 256                 my @props = split(/;/, $properties);
 257                 foreach my $prop (@props) {
 258                         # Parse 'name=value' syntax and set the property.
 259                         if ($prop =~ /([^=]+)=(.*)/) {
 260                                 my ($n,$v) = ($1,$2);
 261                                 for ($n, $v) {
 262                                         s/^\s+//; s/\s+$//;
 263                                 }
 264                                 $self->change_file_prop($fbat, $n, $v);
 265                         }
 266                 }
 267         }
 268 }
 269
 270 sub apply_autoprops {
 271         my ($self, $file, $fbat) = @_;
 272         my $conf_t = ${$self->{config}}{'config'};
 273         no warnings 'once';
 274         # Check [miscellany]/enable-auto-props in svn configuration.
 275         if (SVN::_Core::svn_config_get_bool(
 276                 $conf_t,
 277                 $SVN::_Core::SVN_CONFIG_SECTION_MISCELLANY,
 278                 $SVN::_Core::SVN_CONFIG_OPTION_ENABLE_AUTO_PROPS,
 279                 0)) {
 280                 # Auto-props are enabled.  Enumerate them to look for matches.
 281                 my $callback = sub {
 282                         $self->check_autoprop($_[0], $_[1], $file, $fbat);
 283                 };
 284                 SVN::_Core::svn_config_enumerate(
 285                         $conf_t,
 286                         $SVN::_Core::SVN_CONFIG_SECTION_AUTO_PROPS,
 287                         $callback);
 288         }
 289 }
 290
 291 sub A {
 292         my ($self, $m, $deletions) = @_;
 293         my ($dir, $file) = split_path($m->{file_b});
 294         my $pbat = $self->ensure_path($dir, $deletions);
 295         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
 296                                         undef, -1);
 297         print "\tA\t$m->{file_b}\n" unless $::_q;
 298         $self->apply_autoprops($file, $fbat);
 299         $self->chg_file($fbat, $m);
 300         $self->close_file($fbat,undef,$self->{pool});
 301 }
 302
 303 sub C {
 304         my ($self, $m, $deletions) = @_;
 305         my ($dir, $file) = split_path($m->{file_b});
 306         my $pbat = $self->ensure_path($dir, $deletions);
 307         # workaround for a bug in svn serf backend (v1.8.5 and below):
 308         # store third argument to ->add_file() in a local variable, to make it
 309         # have the same lifetime as $fbat
 310         my $upa = $self->url_path($m->{file_a});
 311         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
 312                                 $upa, $self->{r});
 313         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
 314         $self->chg_file($fbat, $m);
 315         $self->close_file($fbat,undef,$self->{pool});
 316 }
 317
 318 sub delete_entry {
 319         my ($self, $path, $pbat) = @_;
 320         my $rpath = $self->repo_path($path);
 321         my ($dir, $file) = split_path($rpath);
 322         $self->{rm}->{$dir} = 1;
 323         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
 324 }
 325
 326 sub R {
 327         my ($self, $m, $deletions) = @_;
 328         my ($dir, $file) = split_path($m->{file_b});
 329         my $pbat = $self->ensure_path($dir, $deletions);
 330         # workaround for a bug in svn serf backend, see comment in C() above
 331         my $upa = $self->url_path($m->{file_a});
 332         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
 333                                 $upa, $self->{r});
 334         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
 335         $self->apply_autoprops($file, $fbat);
 336         $self->chg_file($fbat, $m);
 337         $self->close_file($fbat,undef,$self->{pool});
 338
 339         ($dir, $file) = split_path($m->{file_a});
 340         $pbat = $self->ensure_path($dir, $deletions);
 341         $self->delete_entry($m->{file_a}, $pbat);
 342 }
 343
 344 sub M {
 345         my ($self, $m, $deletions) = @_;
 346         my ($dir, $file) = split_path($m->{file_b});
 347         my $pbat = $self->ensure_path($dir, $deletions);
 348         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
 349                                 $pbat,$self->{r},$self->{pool});
 350         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
 351         $self->chg_file($fbat, $m);
 352         $self->close_file($fbat,undef,$self->{pool});
 353 }
 354
 355 sub T {
 356         my ($self, $m, $deletions) = @_;
 357
 358         # Work around subversion issue 4091: toggling the "is a
 359         # symlink" property requires removing and re-adding a
 360         # file or else "svn up" on affected clients trips an
 361         # assertion and aborts.
 362         if (($m->{mode_b} =~ /^120/ && $m->{mode_a} !~ /^120/) ||
 363             ($m->{mode_b} !~ /^120/ && $m->{mode_a} =~ /^120/)) {
 364                 $self->D({
 365                         mode_a => $m->{mode_a}, mode_b => '000000',
 366                         sha1_a => $m->{sha1_a}, sha1_b => '0' x 40,
 367                         chg => 'D', file_b => $m->{file_b}
 368                 }, $deletions);
 369                 $self->A({
 370                         mode_a => '000000', mode_b => $m->{mode_b},
 371                         sha1_a => '0' x 40, sha1_b => $m->{sha1_b},
 372                         chg => 'A', file_b => $m->{file_b}
 373                 }, $deletions);
 374                 return;
 375         }
 376
 377         $self->M($m, $deletions);
 378 }
 379
 380 sub change_file_prop {
 381         my ($self, $fbat, $pname, $pval) = @_;
 382         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
 383 }
 384
 385 sub change_dir_prop {
 386         my ($self, $pbat, $pname, $pval) = @_;
 387         $self->SUPER::change_dir_prop($pbat, $pname, $pval, $self->{pool});
 388 }
 389
 390 sub _chg_file_get_blob ($$$$) {
 391         my ($self, $fbat, $m, $which) = @_;
 392         my $fh = $::_repository->temp_acquire("git_blob_$which");
 393         if ($m->{"mode_$which"} =~ /^120/) {
 394                 print $fh 'link ' or croak $!;
 395                 $self->change_file_prop($fbat,'svn:special','*');
 396         } elsif ($m->{mode_a} =~ /^120/ && $m->{"mode_$which"} !~ /^120/) {
 397                 $self->change_file_prop($fbat,'svn:special',undef);
 398         }
 399         my $blob = $m->{"sha1_$which"};
 400         return ($fh,) if ($blob =~ /^0{40}$/);
 401         my $size = $::_repository->cat_blob($blob, $fh);
 402         croak "Failed to read object $blob" if ($size < 0);
 403         $fh->flush == 0 or croak $!;
 404         seek $fh, 0, 0 or croak $!;
 405
 406         my $exp = ::md5sum($fh);
 407         seek $fh, 0, 0 or croak $!;
 408         return ($fh, $exp);
 409 }
 410
 411 sub chg_file {
 412         my ($self, $fbat, $m) = @_;
 413         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
 414                 $self->change_file_prop($fbat,'svn:executable','*');
 415         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
 416                 $self->change_file_prop($fbat,'svn:executable',undef);
 417         }
 418         my ($fh_a, $exp_a) = _chg_file_get_blob $self, $fbat, $m, 'a';
 419         my ($fh_b, $exp_b) = _chg_file_get_blob $self, $fbat, $m, 'b';
 420         my $pool = SVN::Pool->new;
 421         my $atd = $self->apply_textdelta($fbat, $exp_a, $pool);
 422         if (-s $fh_a) {
 423                 my $txstream = SVN::TxDelta::new ($fh_a, $fh_b, $pool);
 424                 my $res = SVN::TxDelta::send_txstream($txstream, @$atd, $pool);
 425                 if (defined $res) {
 426                         die "Unexpected result from send_txstream: $res\n",
 427                             "(SVN::Core::VERSION: $SVN::Core::VERSION)\n";
 428                 }
 429         } else {
 430                 my $got = SVN::TxDelta::send_stream($fh_b, @$atd, $pool);
 431                 die "Checksum mismatch\nexpected: $exp_b\ngot: $got\n"
 432                     if ($got ne $exp_b);
 433         }
 434         Git::temp_release($fh_b, 1);
 435         Git::temp_release($fh_a, 1);
 436         $pool->clear;
 437 }
 438
 439 sub D {
 440         my ($self, $m, $deletions) = @_;
 441         my ($dir, $file) = split_path($m->{file_b});
 442         my $pbat = $self->ensure_path($dir, $deletions);
 443         print "\tD\t$m->{file_b}\n" unless $::_q;
 444         $self->delete_entry($m->{file_b}, $pbat);
 445 }
 446
 447 sub close_edit {
 448         my ($self) = @_;
 449         my ($p,$bat) = ($self->{pool}, $self->{bat});
 450         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
 451                 next if $_ eq '';
 452                 $self->close_directory($bat->{$_}, $p);
 453         }
 454         $self->close_directory($bat->{''}, $p);
 455         $self->SUPER::close_edit($p);
 456         $p->clear;
 457 }
 458
 459 sub abort_edit {
 460         my ($self) = @_;
 461         $self->SUPER::abort_edit($self->{pool});
 462 }
 463
 464 sub DESTROY {
 465         my $self = shift;
 466         $self->SUPER::DESTROY(@_);
 467         $self->{pool}->clear;
 468 }
 469
 470 # this drives the editor
 471 sub apply_diff {
 472         my ($self) = @_;
 473         my $mods = $self->{mods};
 474         my %o = ( D => 0, C => 1, R => 2, A => 3, M => 4, T => 5 );
 475         my %deletions;
 476
 477         foreach my $m (@$mods) {
 478                 if ($m->{chg} eq "D") {
 479                         $deletions{$m->{file_b}} = 1;
 480                 }
 481         }
 482
 483         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
 484                 my $f = $m->{chg};
 485                 if (defined $o{$f}) {
 486                         $self->$f($m, \%deletions);
 487                 } else {
 488                         fatal("Invalid change type: $f");
 489                 }
 490         }
 491
 492         if (defined($self->{mergeinfo})) {
 493                 $self->change_dir_prop($self->{bat}{''}, "svn:mergeinfo",
 494                                        $self->{mergeinfo});
 495         }
 496         $self->rmdirs if $_rmdir;
 497         if (@$mods == 0 && !defined($self->{mergeinfo})) {
 498                 $self->abort_edit;
 499         } else {
 500                 $self->close_edit;
 501         }
 502         return scalar @$mods;
 503 }
 504
 505 1;
 506 __END__
 507
 508 =head1 NAME
 509
 510 Git::SVN::Editor - commit driver for "git svn set-tree" and dcommit
 511
 512 =head1 SYNOPSIS
 513
 514         use Git::SVN::Editor;
 515         use Git::SVN::Ra;
 516
 517         my $ra = Git::SVN::Ra->new($url);
 518         my %opts = (
 519                 r => 19,
 520                 log => "log message",
 521                 ra => $ra,
 522                 config => SVN::Core::config_get_config($svn_config_dir),
 523                 tree_a => "$commit^",
 524                 tree_b => "$commit",
 525                 editor_cb => sub { print "Committed r$_[0]\n"; },
 526                 mergeinfo => "/branches/foo:1-10",
 527                 svn_path => "trunk"
 528         );
 529         Git::SVN::Editor->new(\%opts)->apply_diff or print "No changes\n";
 530
 531         my $re = Git::SVN::Editor::glob2pat("trunk/*");
 532         if ($branchname =~ /$re/) {
 533                 print "matched!\n";
 534         }
 535
 536 =head1 DESCRIPTION
 537
 538 This module is an implementation detail of the "git svn" command.
 539 Do not use it unless you are developing git-svn.
 540
 541 This module adapts the C<SVN::Delta::Editor> object returned by
 542 C<SVN::Delta::get_commit_editor> and drives it to convey the
 543 difference between two git tree objects to a remote Subversion
 544 repository.
 545
 546 The interface will change as git-svn evolves.
 547
 548 =head1 DEPENDENCIES
 549
 550 Subversion perl bindings,
 551 the core L<Carp> and L<IO::File> modules,
 552 and git's L<Git> helper module.
 553
 554 C<Git::SVN::Editor> has not been tested using callers other than
 555 B<git-svn> itself.
 556
 557 =head1 SEE ALSO
 558
 559 L<SVN::Delta>,
 560 L<Git::SVN::Fetcher>.
 561
 562 =head1 INCOMPATIBILITIES
 563
 564 None reported.
 565
 566 =head1 BUGS
 567
 568 None.