git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use POSIX qw/strftime/;
  23 use Term::ReadLine;
  24 use Getopt::Long;
  25 use Text::ParseWords;
  26 use Data::Dumper;
  27 use Term::ANSIColor;
  28 use File::Temp qw/ tempdir tempfile /;
  29 use File::Spec::Functions qw(catfile);
  30 use Error qw(:try);
  31 use Git;
  32
  33 Getopt::Long::Configure qw/ pass_through /;
  34
  35 package FakeTerm;
  36 sub new {
  37         my ($class, $reason) = @_;
  38         return bless \$reason, shift;
  39 }
  40 sub readline {
  41         my $self = shift;
  42         die "Cannot use readline on FakeTerm: $$self";
  43 }
  44 package main;
  45
  46
  47 sub usage {
  48         print <<EOT;
  49 git send-email [options] <file | directory | rev-list options >
  50
  51   Composing:
  52     --from                  <str>  * Email From:
  53     --[no-]to               <str>  * Email To:
  54     --[no-]cc               <str>  * Email Cc:
  55     --[no-]bcc              <str>  * Email Bcc:
  56     --subject               <str>  * Email "Subject:"
  57     --in-reply-to           <str>  * Email "In-Reply-To:"
  58     --[no-]xmailer                 * Add "X-Mailer:" header (default).
  59     --[no-]annotate                * Review each patch that will be sent in an editor.
  60     --compose                      * Open an editor for introduction.
  61     --compose-encoding      <str>  * Encoding to assume for introduction.
  62     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  63     --transfer-encoding     <str>  * Transfer encoding to use (quoted-printable, 8bit, base64)
  64
  65   Sending:
  66     --envelope-sender       <str>  * Email envelope sender.
  67     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  68                                      is optional. Default 'localhost'.
  69     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  70     --smtp-server-port      <int>  * Outgoing SMTP server port.
  71     --smtp-user             <str>  * Username for SMTP-AUTH.
  72     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  73     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  74     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  75     --smtp-ssl-cert-path    <str>  * Path to ca-certificates (either directory or file).
  76                                      Pass an empty string to disable certificate
  77                                      verification.
  78     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  79     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  80
  81   Automating:
  82     --identity              <str>  * Use the sendemail.<id> options.
  83     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  84     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  85     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  86     --[no-]cc-cover                * Email Cc: addresses in the cover letter.
  87     --[no-]to-cover                * Email To: addresses in the cover letter.
  88     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  89     --[no-]suppress-from           * Send to self. Default off.
  90     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  91     --[no-]thread                  * Use In-Reply-To: field. Default on.
  92
  93   Administering:
  94     --confirm               <str>  * Confirm recipients before sending;
  95                                      auto, cc, compose, always, or never.
  96     --quiet                        * Output one line of info per email.
  97     --dry-run                      * Don't actually send the emails.
  98     --[no-]validate                * Perform patch sanity checks. Default on.
  99     --[no-]format-patch            * understand any non optional arguments as
 100                                      `git format-patch` ones.
 101     --force                        * Send even if safety checks would prevent it.
 102
 103 EOT
 104         exit(1);
 105 }
 106
 107 # most mail servers generate the Date: header, but not all...
 108 sub format_2822_time {
 109         my ($time) = @_;
 110         my @localtm = localtime($time);
 111         my @gmttm = gmtime($time);
 112         my $localmin = $localtm[1] + $localtm[2] * 60;
 113         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 114         if ($localtm[0] != $gmttm[0]) {
 115                 die "local zone differs from GMT by a non-minute interval\n";
 116         }
 117         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 118                 $localmin += 1440;
 119         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 120                 $localmin -= 1440;
 121         } elsif ($gmttm[6] != $localtm[6]) {
 122                 die "local time offset greater than or equal to 24 hours\n";
 123         }
 124         my $offset = $localmin - $gmtmin;
 125         my $offhour = $offset / 60;
 126         my $offmin = abs($offset % 60);
 127         if (abs($offhour) >= 24) {
 128                 die ("local time offset greater than or equal to 24 hours\n");
 129         }
 130
 131         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 132                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 133                        $localtm[3],
 134                        qw(Jan Feb Mar Apr May Jun
 135                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 136                        $localtm[5]+1900,
 137                        $localtm[2],
 138                        $localtm[1],
 139                        $localtm[0],
 140                        ($offset >= 0) ? '+' : '-',
 141                        abs($offhour),
 142                        $offmin,
 143                        );
 144 }
 145
 146 my $have_email_valid = eval { require Email::Valid; 1 };
 147 my $have_mail_address = eval { require Mail::Address; 1 };
 148 my $smtp;
 149 my $auth;
 150
 151 # Regexes for RFC 2047 productions.
 152 my $re_token = qr/[^][()<>@,;:\\"\/?.= \000-\037\177-\377]+/;
 153 my $re_encoded_text = qr/[^? \000-\037\177-\377]+/;
 154 my $re_encoded_word = qr/=\?($re_token)\?($re_token)\?($re_encoded_text)\?=/;
 155
 156 # Variables we fill in automatically, or via prompting:
 157 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 158         $initial_reply_to,$initial_subject,@files,
 159         $author,$sender,$smtp_authpass,$annotate,$use_xmailer,$compose,$time);
 160
 161 my $envelope_sender;
 162
 163 # Example reply to:
 164 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 165
 166 my $repo = eval { Git->repository() };
 167 my @repo = $repo ? ($repo) : ();
 168 my $term = eval {
 169         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 170                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 171                 : new Term::ReadLine 'git-send-email';
 172 };
 173 if ($@) {
 174         $term = new FakeTerm "$@: going non-interactive";
 175 }
 176
 177 # Behavior modification variables
 178 my ($quiet, $dry_run) = (0, 0);
 179 my $format_patch;
 180 my $compose_filename;
 181 my $force = 0;
 182
 183 # Handle interactive edition of files.
 184 my $multiedit;
 185 my $editor;
 186
 187 sub do_edit {
 188         if (!defined($editor)) {
 189                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 190         }
 191         if (defined($multiedit) && !$multiedit) {
 192                 map {
 193                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 194                         if (($? & 127) || ($? >> 8)) {
 195                                 die("the editor exited uncleanly, aborting everything");
 196                         }
 197                 } @_;
 198         } else {
 199                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 200                 if (($? & 127) || ($? >> 8)) {
 201                         die("the editor exited uncleanly, aborting everything");
 202                 }
 203         }
 204 }
 205
 206 # Variables with corresponding config settings
 207 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 208 my ($cover_cc, $cover_to);
 209 my ($to_cmd, $cc_cmd);
 210 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 211 my ($smtp_authuser, $smtp_encryption, $smtp_ssl_cert_path);
 212 my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
 213 my ($validate, $confirm);
 214 my (@suppress_cc);
 215 my ($auto_8bit_encoding);
 216 my ($compose_encoding);
 217 my ($target_xfer_encoding);
 218
 219 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 220
 221 my %config_bool_settings = (
 222     "thread" => [\$thread, 1],
 223     "chainreplyto" => [\$chain_reply_to, 0],
 224     "suppressfrom" => [\$suppress_from, undef],
 225     "signedoffbycc" => [\$signed_off_by_cc, undef],
 226     "cccover" => [\$cover_cc, undef],
 227     "tocover" => [\$cover_to, undef],
 228     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 229     "validate" => [\$validate, 1],
 230     "multiedit" => [\$multiedit, undef],
 231     "annotate" => [\$annotate, undef],
 232     "xmailer" => [\$use_xmailer, 1]
 233 );
 234
 235 my %config_settings = (
 236     "smtpserver" => \$smtp_server,
 237     "smtpserverport" => \$smtp_server_port,
 238     "smtpserveroption" => \@smtp_server_options,
 239     "smtpuser" => \$smtp_authuser,
 240     "smtppass" => \$smtp_authpass,
 241     "smtpsslcertpath" => \$smtp_ssl_cert_path,
 242     "smtpdomain" => \$smtp_domain,
 243     "to" => \@initial_to,
 244     "tocmd" => \$to_cmd,
 245     "cc" => \@initial_cc,
 246     "cccmd" => \$cc_cmd,
 247     "aliasfiletype" => \$aliasfiletype,
 248     "bcc" => \@bcclist,
 249     "suppresscc" => \@suppress_cc,
 250     "envelopesender" => \$envelope_sender,
 251     "confirm"   => \$confirm,
 252     "from" => \$sender,
 253     "assume8bitencoding" => \$auto_8bit_encoding,
 254     "composeencoding" => \$compose_encoding,
 255     "transferencoding" => \$target_xfer_encoding,
 256 );
 257
 258 my %config_path_settings = (
 259     "aliasesfile" => \@alias_files,
 260 );
 261
 262 # Handle Uncouth Termination
 263 sub signal_handler {
 264
 265         # Make text normal
 266         print color("reset"), "\n";
 267
 268         # SMTP password masked
 269         system "stty echo";
 270
 271         # tmp files from --compose
 272         if (defined $compose_filename) {
 273                 if (-e $compose_filename) {
 274                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 275                 }
 276                 if (-e ($compose_filename . ".final")) {
 277                         print "'$compose_filename.final' contains the composed email.\n"
 278                 }
 279         }
 280
 281         exit;
 282 };
 283
 284 $SIG{TERM} = \&signal_handler;
 285 $SIG{INT}  = \&signal_handler;
 286
 287 # Begin by accumulating all the variables (defined above), that we will end up
 288 # needing, first, from the command line:
 289
 290 my $help;
 291 my $rc = GetOptions("h" => \$help,
 292                     "sender|from=s" => \$sender,
 293                     "in-reply-to=s" => \$initial_reply_to,
 294                     "subject=s" => \$initial_subject,
 295                     "to=s" => \@initial_to,
 296                     "to-cmd=s" => \$to_cmd,
 297                     "no-to" => \$no_to,
 298                     "cc=s" => \@initial_cc,
 299                     "no-cc" => \$no_cc,
 300                     "bcc=s" => \@bcclist,
 301                     "no-bcc" => \$no_bcc,
 302                     "chain-reply-to!" => \$chain_reply_to,
 303                     "no-chain-reply-to" => sub {$chain_reply_to = 0},
 304                     "smtp-server=s" => \$smtp_server,
 305                     "smtp-server-option=s" => \@smtp_server_options,
 306                     "smtp-server-port=s" => \$smtp_server_port,
 307                     "smtp-user=s" => \$smtp_authuser,
 308                     "smtp-pass:s" => \$smtp_authpass,
 309                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 310                     "smtp-encryption=s" => \$smtp_encryption,
 311                     "smtp-ssl-cert-path=s" => \$smtp_ssl_cert_path,
 312                     "smtp-debug:i" => \$debug_net_smtp,
 313                     "smtp-domain:s" => \$smtp_domain,
 314                     "identity=s" => \$identity,
 315                     "annotate!" => \$annotate,
 316                     "no-annotate" => sub {$annotate = 0},
 317                     "compose" => \$compose,
 318                     "quiet" => \$quiet,
 319                     "cc-cmd=s" => \$cc_cmd,
 320                     "suppress-from!" => \$suppress_from,
 321                     "no-suppress-from" => sub {$suppress_from = 0},
 322                     "suppress-cc=s" => \@suppress_cc,
 323                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 324                     "no-signed-off-cc|no-signed-off-by-cc" => sub {$signed_off_by_cc = 0},
 325                     "cc-cover|cc-cover!" => \$cover_cc,
 326                     "no-cc-cover" => sub {$cover_cc = 0},
 327                     "to-cover|to-cover!" => \$cover_to,
 328                     "no-to-cover" => sub {$cover_to = 0},
 329                     "confirm=s" => \$confirm,
 330                     "dry-run" => \$dry_run,
 331                     "envelope-sender=s" => \$envelope_sender,
 332                     "thread!" => \$thread,
 333                     "no-thread" => sub {$thread = 0},
 334                     "validate!" => \$validate,
 335                     "no-validate" => sub {$validate = 0},
 336                     "transfer-encoding=s" => \$target_xfer_encoding,
 337                     "format-patch!" => \$format_patch,
 338                     "no-format-patch" => sub {$format_patch = 0},
 339                     "8bit-encoding=s" => \$auto_8bit_encoding,
 340                     "compose-encoding=s" => \$compose_encoding,
 341                     "force" => \$force,
 342                     "xmailer!" => \$use_xmailer,
 343                     "no-xmailer" => sub {$use_xmailer = 0},
 344          );
 345
 346 usage() if $help;
 347 unless ($rc) {
 348     usage();
 349 }
 350
 351 die "Cannot run git format-patch from outside a repository\n"
 352         if $format_patch and not $repo;
 353
 354 # Now, let's fill any that aren't set in with defaults:
 355
 356 sub read_config {
 357         my ($prefix) = @_;
 358
 359         foreach my $setting (keys %config_bool_settings) {
 360                 my $target = $config_bool_settings{$setting}->[0];
 361                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 362         }
 363
 364         foreach my $setting (keys %config_path_settings) {
 365                 my $target = $config_path_settings{$setting};
 366                 if (ref($target) eq "ARRAY") {
 367                         unless (@$target) {
 368                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 369                                 @$target = @values if (@values && defined $values[0]);
 370                         }
 371                 }
 372                 else {
 373                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 374                 }
 375         }
 376
 377         foreach my $setting (keys %config_settings) {
 378                 my $target = $config_settings{$setting};
 379                 next if $setting eq "to" and defined $no_to;
 380                 next if $setting eq "cc" and defined $no_cc;
 381                 next if $setting eq "bcc" and defined $no_bcc;
 382                 if (ref($target) eq "ARRAY") {
 383                         unless (@$target) {
 384                                 my @values = Git::config(@repo, "$prefix.$setting");
 385                                 @$target = @values if (@values && defined $values[0]);
 386                         }
 387                 }
 388                 else {
 389                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 390                 }
 391         }
 392
 393         if (!defined $smtp_encryption) {
 394                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 395                 if (defined $enc) {
 396                         $smtp_encryption = $enc;
 397                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 398                         $smtp_encryption = 'ssl';
 399                 }
 400         }
 401 }
 402
 403 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 404 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 405 read_config("sendemail.$identity") if (defined $identity);
 406 read_config("sendemail");
 407
 408 # fall back on builtin bool defaults
 409 foreach my $setting (values %config_bool_settings) {
 410         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 411 }
 412
 413 # 'default' encryption is none -- this only prevents a warning
 414 $smtp_encryption = '' unless (defined $smtp_encryption);
 415
 416 # Set CC suppressions
 417 my(%suppress_cc);
 418 if (@suppress_cc) {
 419         foreach my $entry (@suppress_cc) {
 420                 die "Unknown --suppress-cc field: '$entry'\n"
 421                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 422                 $suppress_cc{$entry} = 1;
 423         }
 424 }
 425
 426 if ($suppress_cc{'all'}) {
 427         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 428                 $suppress_cc{$entry} = 1;
 429         }
 430         delete $suppress_cc{'all'};
 431 }
 432
 433 # If explicit old-style ones are specified, they trump --suppress-cc.
 434 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 435 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 436
 437 if ($suppress_cc{'body'}) {
 438         foreach my $entry (qw (sob bodycc)) {
 439                 $suppress_cc{$entry} = 1;
 440         }
 441         delete $suppress_cc{'body'};
 442 }
 443
 444 # Set confirm's default value
 445 my $confirm_unconfigured = !defined $confirm;
 446 if ($confirm_unconfigured) {
 447         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 448 };
 449 die "Unknown --confirm setting: '$confirm'\n"
 450         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 451
 452 # Debugging, print out the suppressions.
 453 if (0) {
 454         print "suppressions:\n";
 455         foreach my $entry (keys %suppress_cc) {
 456                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 457         }
 458 }
 459
 460 my ($repoauthor, $repocommitter);
 461 ($repoauthor) = Git::ident_person(@repo, 'author');
 462 ($repocommitter) = Git::ident_person(@repo, 'committer');
 463
 464 # Verify the user input
 465
 466 foreach my $entry (@initial_to) {
 467         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 468 }
 469
 470 foreach my $entry (@initial_cc) {
 471         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 472 }
 473
 474 foreach my $entry (@bcclist) {
 475         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 476 }
 477
 478 sub parse_address_line {
 479         if ($have_mail_address) {
 480                 return map { $_->format } Mail::Address->parse($_[0]);
 481         } else {
 482                 return split_addrs($_[0]);
 483         }
 484 }
 485
 486 sub split_addrs {
 487         return quotewords('\s*,\s*', 1, @_);
 488 }
 489
 490 my %aliases;
 491 my %parse_alias = (
 492         # multiline formats can be supported in the future
 493         mutt => sub { my $fh = shift; while (<$fh>) {
 494                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 495                         my ($alias, $addr) = ($1, $2);
 496                         $addr =~ s/#.*$//; # mutt allows # comments
 497                          # commas delimit multiple addresses
 498                         $aliases{$alias} = [ split_addrs($addr) ];
 499                 }}},
 500         mailrc => sub { my $fh = shift; while (<$fh>) {
 501                 if (/^alias\s+(\S+)\s+(.*)$/) {
 502                         # spaces delimit multiple addresses
 503                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 504                 }}},
 505         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 506                 for (my $x = ''; defined($x); $x = $_) {
 507                         chomp $x;
 508                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 509                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 510                         $aliases{$1} = [ split_addrs($2) ];
 511                 }},
 512         elm => sub  { my $fh = shift;
 513                       while (<$fh>) {
 514                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 515                               my ($alias, $addr) = ($1, $2);
 516                                $aliases{$alias} = [ split_addrs($addr) ];
 517                           }
 518                       } },
 519
 520         gnus => sub { my $fh = shift; while (<$fh>) {
 521                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 522                         $aliases{$1} = [ $2 ];
 523                 }}}
 524 );
 525
 526 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 527         foreach my $file (@alias_files) {
 528                 open my $fh, '<', $file or die "opening $file: $!\n";
 529                 $parse_alias{$aliasfiletype}->($fh);
 530                 close $fh;
 531         }
 532 }
 533
 534 ($sender) = expand_aliases($sender) if defined $sender;
 535
 536 # is_format_patch_arg($f) returns 0 if $f names a patch, or 1 if
 537 # $f is a revision list specification to be passed to format-patch.
 538 sub is_format_patch_arg {
 539         return unless $repo;
 540         my $f = shift;
 541         try {
 542                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 543                 if (defined($format_patch)) {
 544                         return $format_patch;
 545                 }
 546                 die(<<EOF);
 547 File '$f' exists but it could also be the range of commits
 548 to produce patches for.  Please disambiguate by...
 549
 550     * Saying "./$f" if you mean a file; or
 551     * Giving --format-patch option if you mean a range.
 552 EOF
 553         } catch Git::Error::Command with {
 554                 # Not a valid revision.  Treat it as a filename.
 555                 return 0;
 556         }
 557 }
 558
 559 # Now that all the defaults are set, process the rest of the command line
 560 # arguments and collect up the files that need to be processed.
 561 my @rev_list_opts;
 562 while (defined(my $f = shift @ARGV)) {
 563         if ($f eq "--") {
 564                 push @rev_list_opts, "--", @ARGV;
 565                 @ARGV = ();
 566         } elsif (-d $f and !is_format_patch_arg($f)) {
 567                 opendir my $dh, $f
 568                         or die "Failed to opendir $f: $!";
 569
 570                 push @files, grep { -f $_ } map { catfile($f, $_) }
 571                                 sort readdir $dh;
 572                 closedir $dh;
 573         } elsif ((-f $f or -p $f) and !is_format_patch_arg($f)) {
 574                 push @files, $f;
 575         } else {
 576                 push @rev_list_opts, $f;
 577         }
 578 }
 579
 580 if (@rev_list_opts) {
 581         die "Cannot run git format-patch from outside a repository\n"
 582                 unless $repo;
 583         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 584 }
 585
 586 if ($validate) {
 587         foreach my $f (@files) {
 588                 unless (-p $f) {
 589                         my $error = validate_patch($f);
 590                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 591                 }
 592         }
 593 }
 594
 595 if (@files) {
 596         unless ($quiet) {
 597                 print $_,"\n" for (@files);
 598         }
 599 } else {
 600         print STDERR "\nNo patch files specified!\n\n";
 601         usage();
 602 }
 603
 604 sub get_patch_subject {
 605         my $fn = shift;
 606         open (my $fh, '<', $fn);
 607         while (my $line = <$fh>) {
 608                 next unless ($line =~ /^Subject: (.*)$/);
 609                 close $fh;
 610                 return "GIT: $1\n";
 611         }
 612         close $fh;
 613         die "No subject line in $fn ?";
 614 }
 615
 616 if ($compose) {
 617         # Note that this does not need to be secure, but we will make a small
 618         # effort to have it be unique
 619         $compose_filename = ($repo ?
 620                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 621                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 622         open my $c, ">", $compose_filename
 623                 or die "Failed to open for writing $compose_filename: $!";
 624
 625
 626         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 627         my $tpl_subject = $initial_subject || '';
 628         my $tpl_reply_to = $initial_reply_to || '';
 629
 630         print $c <<EOT;
 631 From $tpl_sender # This line is ignored.
 632 GIT: Lines beginning in "GIT:" will be removed.
 633 GIT: Consider including an overall diffstat or table of contents
 634 GIT: for the patch you are writing.
 635 GIT:
 636 GIT: Clear the body content if you don't wish to send a summary.
 637 From: $tpl_sender
 638 Subject: $tpl_subject
 639 In-Reply-To: $tpl_reply_to
 640
 641 EOT
 642         for my $f (@files) {
 643                 print $c get_patch_subject($f);
 644         }
 645         close $c;
 646
 647         if ($annotate) {
 648                 do_edit($compose_filename, @files);
 649         } else {
 650                 do_edit($compose_filename);
 651         }
 652
 653         open my $c2, ">", $compose_filename . ".final"
 654                 or die "Failed to open $compose_filename.final : " . $!;
 655
 656         open $c, "<", $compose_filename
 657                 or die "Failed to open $compose_filename : " . $!;
 658
 659         my $need_8bit_cte = file_has_nonascii($compose_filename);
 660         my $in_body = 0;
 661         my $summary_empty = 1;
 662         if (!defined $compose_encoding) {
 663                 $compose_encoding = "UTF-8";
 664         }
 665         while(<$c>) {
 666                 next if m/^GIT:/;
 667                 if ($in_body) {
 668                         $summary_empty = 0 unless (/^\n$/);
 669                 } elsif (/^\n$/) {
 670                         $in_body = 1;
 671                         if ($need_8bit_cte) {
 672                                 print $c2 "MIME-Version: 1.0\n",
 673                                          "Content-Type: text/plain; ",
 674                                            "charset=$compose_encoding\n",
 675                                          "Content-Transfer-Encoding: 8bit\n";
 676                         }
 677                 } elsif (/^MIME-Version:/i) {
 678                         $need_8bit_cte = 0;
 679                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 680                         $initial_subject = $1;
 681                         my $subject = $initial_subject;
 682                         $_ = "Subject: " .
 683                                 quote_subject($subject, $compose_encoding) .
 684                                 "\n";
 685                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 686                         $initial_reply_to = $1;
 687                         next;
 688                 } elsif (/^From:\s*(.+)\s*$/i) {
 689                         $sender = $1;
 690                         next;
 691                 } elsif (/^(?:To|Cc|Bcc):/i) {
 692                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 693                         next;
 694                 }
 695                 print $c2 $_;
 696         }
 697         close $c;
 698         close $c2;
 699
 700         if ($summary_empty) {
 701                 print "Summary email is empty, skipping it\n";
 702                 $compose = -1;
 703         }
 704 } elsif ($annotate) {
 705         do_edit(@files);
 706 }
 707
 708 sub ask {
 709         my ($prompt, %arg) = @_;
 710         my $valid_re = $arg{valid_re};
 711         my $default = $arg{default};
 712         my $confirm_only = $arg{confirm_only};
 713         my $resp;
 714         my $i = 0;
 715         return defined $default ? $default : undef
 716                 unless defined $term->IN and defined fileno($term->IN) and
 717                        defined $term->OUT and defined fileno($term->OUT);
 718         while ($i++ < 10) {
 719                 $resp = $term->readline($prompt);
 720                 if (!defined $resp) { # EOF
 721                         print "\n";
 722                         return defined $default ? $default : undef;
 723                 }
 724                 if ($resp eq '' and defined $default) {
 725                         return $default;
 726                 }
 727                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 728                         return $resp;
 729                 }
 730                 if ($confirm_only) {
 731                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 732                         if (defined $yesno && $yesno =~ /y/i) {
 733                                 return $resp;
 734                         }
 735                 }
 736         }
 737         return;
 738 }
 739
 740 my %broken_encoding;
 741
 742 sub file_declares_8bit_cte {
 743         my $fn = shift;
 744         open (my $fh, '<', $fn);
 745         while (my $line = <$fh>) {
 746                 last if ($line =~ /^$/);
 747                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 748         }
 749         close $fh;
 750         return 0;
 751 }
 752
 753 foreach my $f (@files) {
 754         next unless (body_or_subject_has_nonascii($f)
 755                      && !file_declares_8bit_cte($f));
 756         $broken_encoding{$f} = 1;
 757 }
 758
 759 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 760         print "The following files are 8bit, but do not declare " .
 761                 "a Content-Transfer-Encoding.\n";
 762         foreach my $f (sort keys %broken_encoding) {
 763                 print "    $f\n";
 764         }
 765         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 766                                   valid_re => qr/.{4}/, confirm_only => 1,
 767                                   default => "UTF-8");
 768 }
 769
 770 if (!$force) {
 771         for my $f (@files) {
 772                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 773                         die "Refusing to send because the patch\n\t$f\n"
 774                                 . "has the template subject '*** SUBJECT HERE ***'. "
 775                                 . "Pass --force if you really want to send.\n";
 776                 }
 777         }
 778 }
 779
 780 if (!defined $sender) {
 781         $sender = $repoauthor || $repocommitter || '';
 782 }
 783
 784 # $sender could be an already sanitized address
 785 # (e.g. sendemail.from could be manually sanitized by user).
 786 # But it's a no-op to run sanitize_address on an already sanitized address.
 787 $sender = sanitize_address($sender);
 788
 789 my $prompting = 0;
 790 if (!@initial_to && !defined $to_cmd) {
 791         my $to = ask("Who should the emails be sent to (if any)? ",
 792                      default => "",
 793                      valid_re => qr/\@.*\./, confirm_only => 1);
 794         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 795         $prompting++;
 796 }
 797
 798 sub expand_aliases {
 799         return map { expand_one_alias($_) } @_;
 800 }
 801
 802 my %EXPANDED_ALIASES;
 803 sub expand_one_alias {
 804         my $alias = shift;
 805         if ($EXPANDED_ALIASES{$alias}) {
 806                 die "fatal: alias '$alias' expands to itself\n";
 807         }
 808         local $EXPANDED_ALIASES{$alias} = 1;
 809         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 810 }
 811
 812 @initial_to = expand_aliases(@initial_to);
 813 @initial_to = validate_address_list(sanitize_address_list(@initial_to));
 814 @initial_cc = expand_aliases(@initial_cc);
 815 @initial_cc = validate_address_list(sanitize_address_list(@initial_cc));
 816 @bcclist = expand_aliases(@bcclist);
 817 @bcclist = validate_address_list(sanitize_address_list(@bcclist));
 818
 819 if ($thread && !defined $initial_reply_to && $prompting) {
 820         $initial_reply_to = ask(
 821                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 822                 default => "",
 823                 valid_re => qr/\@.*\./, confirm_only => 1);
 824 }
 825 if (defined $initial_reply_to) {
 826         $initial_reply_to =~ s/^\s*<?//;
 827         $initial_reply_to =~ s/>?\s*$//;
 828         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 829 }
 830
 831 if (!defined $smtp_server) {
 832         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 833                 if (-x $_) {
 834                         $smtp_server = $_;
 835                         last;
 836                 }
 837         }
 838         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 839 }
 840
 841 if ($compose && $compose > 0) {
 842         @files = ($compose_filename . ".final", @files);
 843 }
 844
 845 # Variables we set as part of the loop over files
 846 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 847         $needs_confirm, $message_num, $ask_default);
 848
 849 sub extract_valid_address {
 850         my $address = shift;
 851         my $local_part_regexp = qr/[^<>"\s@]+/;
 852         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 853
 854         # check for a local address:
 855         return $address if ($address =~ /^($local_part_regexp)$/);
 856
 857         $address =~ s/^\s*<(.*)>\s*$/$1/;
 858         if ($have_email_valid) {
 859                 return scalar Email::Valid->address($address);
 860         }
 861
 862         # less robust/correct than the monster regexp in Email::Valid,
 863         # but still does a 99% job, and one less dependency
 864         return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
 865         return;
 866 }
 867
 868 sub extract_valid_address_or_die {
 869         my $address = shift;
 870         $address = extract_valid_address($address);
 871         die "error: unable to extract a valid address from: $address\n"
 872                 if !$address;
 873         return $address;
 874 }
 875
 876 sub validate_address {
 877         my $address = shift;
 878         while (!extract_valid_address($address)) {
 879                 print STDERR "error: unable to extract a valid address from: $address\n";
 880                 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
 881                         valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
 882                         default => 'q');
 883                 if (/^d/i) {
 884                         return undef;
 885                 } elsif (/^q/i) {
 886                         cleanup_compose_files();
 887                         exit(0);
 888                 }
 889                 $address = ask("Who should the email be sent to (if any)? ",
 890                         default => "",
 891                         valid_re => qr/\@.*\./, confirm_only => 1);
 892         }
 893         return $address;
 894 }
 895
 896 sub validate_address_list {
 897         return (grep { defined $_ }
 898                 map { validate_address($_) } @_);
 899 }
 900
 901 # Usually don't need to change anything below here.
 902
 903 # we make a "fake" message id by taking the current number
 904 # of seconds since the beginning of Unix time and tacking on
 905 # a random number to the end, in case we are called quicker than
 906 # 1 second since the last time we were called.
 907
 908 # We'll setup a template for the message id, using the "from" address:
 909
 910 my ($message_id_stamp, $message_id_serial);
 911 sub make_message_id {
 912         my $uniq;
 913         if (!defined $message_id_stamp) {
 914                 $message_id_stamp = strftime("%Y%m%d%H%M%S.$$", gmtime(time));
 915                 $message_id_serial = 0;
 916         }
 917         $message_id_serial++;
 918         $uniq = "$message_id_stamp-$message_id_serial";
 919
 920         my $du_part;
 921         for ($sender, $repocommitter, $repoauthor) {
 922                 $du_part = extract_valid_address(sanitize_address($_));
 923                 last if (defined $du_part and $du_part ne '');
 924         }
 925         if (not defined $du_part or $du_part eq '') {
 926                 require Sys::Hostname;
 927                 $du_part = 'user@' . Sys::Hostname::hostname();
 928         }
 929         my $message_id_template = "<%s-%s>";
 930         $message_id = sprintf($message_id_template, $uniq, $du_part);
 931         #print "new message id = $message_id\n"; # Was useful for debugging
 932 }
 933
 934
 935
 936 $time = time - scalar $#files;
 937
 938 sub unquote_rfc2047 {
 939         local ($_) = @_;
 940         my $charset;
 941         my $sep = qr/[ \t]+/;
 942         s{$re_encoded_word(?:$sep$re_encoded_word)*}{
 943                 my @words = split $sep, $&;
 944                 foreach (@words) {
 945                         m/$re_encoded_word/;
 946                         $charset = $1;
 947                         my $encoding = $2;
 948                         my $text = $3;
 949                         if ($encoding eq 'q' || $encoding eq 'Q') {
 950                                 $_ = $text;
 951                                 s/_/ /g;
 952                                 s/=([0-9A-F]{2})/chr(hex($1))/egi;
 953                         } else {
 954                                 # other encodings not supported yet
 955                         }
 956                 }
 957                 join '', @words;
 958         }eg;
 959         return wantarray ? ($_, $charset) : $_;
 960 }
 961
 962 sub quote_rfc2047 {
 963         local $_ = shift;
 964         my $encoding = shift || 'UTF-8';
 965         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 966         s/(.*)/=\?$encoding\?q\?$1\?=/;
 967         return $_;
 968 }
 969
 970 sub is_rfc2047_quoted {
 971         my $s = shift;
 972         length($s) <= 75 &&
 973         $s =~ m/^(?:"[[:ascii:]]*"|$re_encoded_word)$/o;
 974 }
 975
 976 sub subject_needs_rfc2047_quoting {
 977         my $s = shift;
 978
 979         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
 980 }
 981
 982 sub quote_subject {
 983         local $subject = shift;
 984         my $encoding = shift || 'UTF-8';
 985
 986         if (subject_needs_rfc2047_quoting($subject)) {
 987                 return quote_rfc2047($subject, $encoding);
 988         }
 989         return $subject;
 990 }
 991
 992 # use the simplest quoting being able to handle the recipient
 993 sub sanitize_address {
 994         my ($recipient) = @_;
 995
 996         # remove garbage after email address
 997         $recipient =~ s/(.*>).*$/$1/;
 998
 999         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
1000
1001         if (not $recipient_name) {
1002                 return $recipient;
1003         }
1004
1005         # if recipient_name is already quoted, do nothing
1006         if (is_rfc2047_quoted($recipient_name)) {
1007                 return $recipient;
1008         }
1009
1010         # rfc2047 is needed if a non-ascii char is included
1011         if ($recipient_name =~ /[^[:ascii:]]/) {
1012                 $recipient_name =~ s/^"(.*)"$/$1/;
1013                 $recipient_name = quote_rfc2047($recipient_name);
1014         }
1015
1016         # double quotes are needed if specials or CTLs are included
1017         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
1018                 $recipient_name =~ s/(["\\\r])/\\$1/g;
1019                 $recipient_name = qq["$recipient_name"];
1020         }
1021
1022         return "$recipient_name $recipient_addr";
1023
1024 }
1025
1026 sub sanitize_address_list {
1027         return (map { sanitize_address($_) } @_);
1028 }
1029
1030 # Returns the local Fully Qualified Domain Name (FQDN) if available.
1031 #
1032 # Tightly configured MTAa require that a caller sends a real DNS
1033 # domain name that corresponds the IP address in the HELO/EHLO
1034 # handshake. This is used to verify the connection and prevent
1035 # spammers from trying to hide their identity. If the DNS and IP don't
1036 # match, the receiveing MTA may deny the connection.
1037 #
1038 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
1039 #
1040 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
1041 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
1042 #
1043 # This maildomain*() code is based on ideas in Perl library Test::Reporter
1044 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1045
1046 sub valid_fqdn {
1047         my $domain = shift;
1048         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1049 }
1050
1051 sub maildomain_net {
1052         my $maildomain;
1053
1054         if (eval { require Net::Domain; 1 }) {
1055                 my $domain = Net::Domain::domainname();
1056                 $maildomain = $domain if valid_fqdn($domain);
1057         }
1058
1059         return $maildomain;
1060 }
1061
1062 sub maildomain_mta {
1063         my $maildomain;
1064
1065         if (eval { require Net::SMTP; 1 }) {
1066                 for my $host (qw(mailhost localhost)) {
1067                         my $smtp = Net::SMTP->new($host);
1068                         if (defined $smtp) {
1069                                 my $domain = $smtp->domain;
1070                                 $smtp->quit;
1071
1072                                 $maildomain = $domain if valid_fqdn($domain);
1073
1074                                 last if $maildomain;
1075                         }
1076                 }
1077         }
1078
1079         return $maildomain;
1080 }
1081
1082 sub maildomain {
1083         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1084 }
1085
1086 sub smtp_host_string {
1087         if (defined $smtp_server_port) {
1088                 return "$smtp_server:$smtp_server_port";
1089         } else {
1090                 return $smtp_server;
1091         }
1092 }
1093
1094 # Returns 1 if authentication succeeded or was not necessary
1095 # (smtp_user was not specified), and 0 otherwise.
1096
1097 sub smtp_auth_maybe {
1098         if (!defined $smtp_authuser || $auth) {
1099                 return 1;
1100         }
1101
1102         # Workaround AUTH PLAIN/LOGIN interaction defect
1103         # with Authen::SASL::Cyrus
1104         eval {
1105                 require Authen::SASL;
1106                 Authen::SASL->import(qw(Perl));
1107         };
1108
1109         # TODO: Authentication may fail not because credentials were
1110         # invalid but due to other reasons, in which we should not
1111         # reject credentials.
1112         $auth = Git::credential({
1113                 'protocol' => 'smtp',
1114                 'host' => smtp_host_string(),
1115                 'username' => $smtp_authuser,
1116                 # if there's no password, "git credential fill" will
1117                 # give us one, otherwise it'll just pass this one.
1118                 'password' => $smtp_authpass
1119         }, sub {
1120                 my $cred = shift;
1121                 return !!$smtp->auth($cred->{'username'}, $cred->{'password'});
1122         });
1123
1124         return $auth;
1125 }
1126
1127 sub ssl_verify_params {
1128         eval {
1129                 require IO::Socket::SSL;
1130                 IO::Socket::SSL->import(qw/SSL_VERIFY_PEER SSL_VERIFY_NONE/);
1131         };
1132         if ($@) {
1133                 print STDERR "Not using SSL_VERIFY_PEER due to out-of-date IO::Socket::SSL.\n";
1134                 return;
1135         }
1136
1137         if (!defined $smtp_ssl_cert_path) {
1138                 # use the OpenSSL defaults
1139                 return (SSL_verify_mode => SSL_VERIFY_PEER());
1140         }
1141
1142         if ($smtp_ssl_cert_path eq "") {
1143                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1144         } elsif (-d $smtp_ssl_cert_path) {
1145                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1146                         SSL_ca_path => $smtp_ssl_cert_path);
1147         } elsif (-f $smtp_ssl_cert_path) {
1148                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1149                         SSL_ca_file => $smtp_ssl_cert_path);
1150         } else {
1151                 print STDERR "Not using SSL_VERIFY_PEER because the CA path does not exist.\n";
1152                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1153         }
1154 }
1155
1156 sub file_name_is_absolute {
1157         my ($path) = @_;
1158
1159         # msys does not grok DOS drive-prefixes
1160         if ($^O eq 'msys') {
1161                 return ($path =~ m#^/# || $path =~ m#^[a-zA-Z]\:#)
1162         }
1163
1164         require File::Spec::Functions;
1165         return File::Spec::Functions::file_name_is_absolute($path);
1166 }
1167
1168 # Returns 1 if the message was sent, and 0 otherwise.
1169 # In actuality, the whole program dies when there
1170 # is an error sending a message.
1171
1172 sub send_message {
1173         my @recipients = unique_email_list(@to);
1174         @cc = (grep { my $cc = extract_valid_address_or_die($_);
1175                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1176                     }
1177                @cc);
1178         my $to = join (",\n\t", @recipients);
1179         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1180         @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1181         my $date = format_2822_time($time++);
1182         my $gitversion = '@@GIT_VERSION@@';
1183         if ($gitversion =~ m/..GIT_VERSION../) {
1184             $gitversion = Git::version();
1185         }
1186
1187         my $cc = join(",\n\t", unique_email_list(@cc));
1188         my $ccline = "";
1189         if ($cc ne '') {
1190                 $ccline = "\nCc: $cc";
1191         }
1192         make_message_id() unless defined($message_id);
1193
1194         my $header = "From: $sender
1195 To: $to${ccline}
1196 Subject: $subject
1197 Date: $date
1198 Message-Id: $message_id
1199 ";
1200         if ($use_xmailer) {
1201                 $header .= "X-Mailer: git-send-email $gitversion\n";
1202         }
1203         if ($reply_to) {
1204
1205                 $header .= "In-Reply-To: $reply_to\n";
1206                 $header .= "References: $references\n";
1207         }
1208         if (@xh) {
1209                 $header .= join("\n", @xh) . "\n";
1210         }
1211
1212         my @sendmail_parameters = ('-i', @recipients);
1213         my $raw_from = $sender;
1214         if (defined $envelope_sender && $envelope_sender ne "auto") {
1215                 $raw_from = $envelope_sender;
1216         }
1217         $raw_from = extract_valid_address($raw_from);
1218         unshift (@sendmail_parameters,
1219                         '-f', $raw_from) if(defined $envelope_sender);
1220
1221         if ($needs_confirm && !$dry_run) {
1222                 print "\n$header\n";
1223                 if ($needs_confirm eq "inform") {
1224                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1225                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1226                         print "    The Cc list above has been expanded by additional\n";
1227                         print "    addresses found in the patch commit message. By default\n";
1228                         print "    send-email prompts before sending whenever this occurs.\n";
1229                         print "    This behavior is controlled by the sendemail.confirm\n";
1230                         print "    configuration setting.\n";
1231                         print "\n";
1232                         print "    For additional information, run 'git send-email --help'.\n";
1233                         print "    To retain the current behavior, but squelch this message,\n";
1234                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1235                 }
1236                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1237                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1238                          default => $ask_default);
1239                 die "Send this email reply required" unless defined $_;
1240                 if (/^n/i) {
1241                         return 0;
1242                 } elsif (/^q/i) {
1243                         cleanup_compose_files();
1244                         exit(0);
1245                 } elsif (/^a/i) {
1246                         $confirm = 'never';
1247                 }
1248         }
1249
1250         unshift (@sendmail_parameters, @smtp_server_options);
1251
1252         if ($dry_run) {
1253                 # We don't want to send the email.
1254         } elsif (file_name_is_absolute($smtp_server)) {
1255                 my $pid = open my $sm, '|-';
1256                 defined $pid or die $!;
1257                 if (!$pid) {
1258                         exec($smtp_server, @sendmail_parameters) or die $!;
1259                 }
1260                 print $sm "$header\n$message";
1261                 close $sm or die $!;
1262         } else {
1263
1264                 if (!defined $smtp_server) {
1265                         die "The required SMTP server is not properly defined."
1266                 }
1267
1268                 if ($smtp_encryption eq 'ssl') {
1269                         $smtp_server_port ||= 465; # ssmtp
1270                         require Net::SMTP::SSL;
1271                         $smtp_domain ||= maildomain();
1272                         require IO::Socket::SSL;
1273                         # Net::SMTP::SSL->new() does not forward any SSL options
1274                         IO::Socket::SSL::set_client_defaults(
1275                                 ssl_verify_params());
1276                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1277                                                       Hello => $smtp_domain,
1278                                                       Port => $smtp_server_port,
1279                                                       Debug => $debug_net_smtp);
1280                 }
1281                 else {
1282                         require Net::SMTP;
1283                         $smtp_domain ||= maildomain();
1284                         $smtp_server_port ||= 25;
1285                         $smtp ||= Net::SMTP->new($smtp_server,
1286                                                  Hello => $smtp_domain,
1287                                                  Debug => $debug_net_smtp,
1288                                                  Port => $smtp_server_port);
1289                         if ($smtp_encryption eq 'tls' && $smtp) {
1290                                 require Net::SMTP::SSL;
1291                                 $smtp->command('STARTTLS');
1292                                 $smtp->response();
1293                                 if ($smtp->code == 220) {
1294                                         $smtp = Net::SMTP::SSL->start_SSL($smtp,
1295                                                                           ssl_verify_params())
1296                                                 or die "STARTTLS failed! ".IO::Socket::SSL::errstr();
1297                                         $smtp_encryption = '';
1298                                         # Send EHLO again to receive fresh
1299                                         # supported commands
1300                                         $smtp->hello($smtp_domain);
1301                                 } else {
1302                                         die "Server does not support STARTTLS! ".$smtp->message;
1303                                 }
1304                         }
1305                 }
1306
1307                 if (!$smtp) {
1308                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1309                             "VALUES: server=$smtp_server ",
1310                             "encryption=$smtp_encryption ",
1311                             "hello=$smtp_domain",
1312                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1313                 }
1314
1315                 smtp_auth_maybe or die $smtp->message;
1316
1317                 $smtp->mail( $raw_from ) or die $smtp->message;
1318                 $smtp->to( @recipients ) or die $smtp->message;
1319                 $smtp->data or die $smtp->message;
1320                 $smtp->datasend("$header\n$message") or die $smtp->message;
1321                 $smtp->dataend() or die $smtp->message;
1322                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1323         }
1324         if ($quiet) {
1325                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1326         } else {
1327                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1328                 if (!file_name_is_absolute($smtp_server)) {
1329                         print "Server: $smtp_server\n";
1330                         print "MAIL FROM:<$raw_from>\n";
1331                         foreach my $entry (@recipients) {
1332                             print "RCPT TO:<$entry>\n";
1333                         }
1334                 } else {
1335                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1336                 }
1337                 print $header, "\n";
1338                 if ($smtp) {
1339                         print "Result: ", $smtp->code, ' ',
1340                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1341                 } else {
1342                         print "Result: OK\n";
1343                 }
1344         }
1345
1346         return 1;
1347 }
1348
1349 $reply_to = $initial_reply_to;
1350 $references = $initial_reply_to || '';
1351 $subject = $initial_subject;
1352 $message_num = 0;
1353
1354 foreach my $t (@files) {
1355         open my $fh, "<", $t or die "can't open file $t";
1356
1357         my $author = undef;
1358         my $sauthor = undef;
1359         my $author_encoding;
1360         my $has_content_type;
1361         my $body_encoding;
1362         my $xfer_encoding;
1363         my $has_mime_version;
1364         @to = ();
1365         @cc = ();
1366         @xh = ();
1367         my $input_format = undef;
1368         my @header = ();
1369         $message = "";
1370         $message_num++;
1371         # First unfold multiline header fields
1372         while(<$fh>) {
1373                 last if /^\s*$/;
1374                 if (/^\s+\S/ and @header) {
1375                         chomp($header[$#header]);
1376                         s/^\s+/ /;
1377                         $header[$#header] .= $_;
1378             } else {
1379                         push(@header, $_);
1380                 }
1381         }
1382         # Now parse the header
1383         foreach(@header) {
1384                 if (/^From /) {
1385                         $input_format = 'mbox';
1386                         next;
1387                 }
1388                 chomp;
1389                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1390                         $input_format = 'mbox';
1391                 }
1392
1393                 if (defined $input_format && $input_format eq 'mbox') {
1394                         if (/^Subject:\s+(.*)$/i) {
1395                                 $subject = $1;
1396                         }
1397                         elsif (/^From:\s+(.*)$/i) {
1398                                 ($author, $author_encoding) = unquote_rfc2047($1);
1399                                 $sauthor = sanitize_address($author);
1400                                 next if $suppress_cc{'author'};
1401                                 next if $suppress_cc{'self'} and $sauthor eq $sender;
1402                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1403                                         $1, $_) unless $quiet;
1404                                 push @cc, $1;
1405                         }
1406                         elsif (/^To:\s+(.*)$/i) {
1407                                 foreach my $addr (parse_address_line($1)) {
1408                                         printf("(mbox) Adding to: %s from line '%s'\n",
1409                                                 $addr, $_) unless $quiet;
1410                                         push @to, $addr;
1411                                 }
1412                         }
1413                         elsif (/^Cc:\s+(.*)$/i) {
1414                                 foreach my $addr (parse_address_line($1)) {
1415                                         my $qaddr = unquote_rfc2047($addr);
1416                                         my $saddr = sanitize_address($qaddr);
1417                                         if ($saddr eq $sender) {
1418                                                 next if ($suppress_cc{'self'});
1419                                         } else {
1420                                                 next if ($suppress_cc{'cc'});
1421                                         }
1422                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1423                                                 $addr, $_) unless $quiet;
1424                                         push @cc, $addr;
1425                                 }
1426                         }
1427                         elsif (/^Content-type:/i) {
1428                                 $has_content_type = 1;
1429                                 if (/charset="?([^ "]+)/) {
1430                                         $body_encoding = $1;
1431                                 }
1432                                 push @xh, $_;
1433                         }
1434                         elsif (/^MIME-Version/i) {
1435                                 $has_mime_version = 1;
1436                                 push @xh, $_;
1437                         }
1438                         elsif (/^Message-Id: (.*)/i) {
1439                                 $message_id = $1;
1440                         }
1441                         elsif (/^Content-Transfer-Encoding: (.*)/i) {
1442                                 $xfer_encoding = $1 if not defined $xfer_encoding;
1443                         }
1444                         elsif (!/^Date:\s/i && /^[-A-Za-z]+:\s+\S/) {
1445                                 push @xh, $_;
1446                         }
1447
1448                 } else {
1449                         # In the traditional
1450                         # "send lots of email" format,
1451                         # line 1 = cc
1452                         # line 2 = subject
1453                         # So let's support that, too.
1454                         $input_format = 'lots';
1455                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1456                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1457                                         $_, $_) unless $quiet;
1458                                 push @cc, $_;
1459                         } elsif (!defined $subject) {
1460                                 $subject = $_;
1461                         }
1462                 }
1463         }
1464         # Now parse the message body
1465         while(<$fh>) {
1466                 $message .=  $_;
1467                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1468                         chomp;
1469                         my ($what, $c) = ($1, $2);
1470                         chomp $c;
1471                         my $sc = sanitize_address($c);
1472                         if ($sc eq $sender) {
1473                                 next if ($suppress_cc{'self'});
1474                         } else {
1475                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1476                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1477                         }
1478                         push @cc, $c;
1479                         printf("(body) Adding cc: %s from line '%s'\n",
1480                                 $c, $_) unless $quiet;
1481                 }
1482         }
1483         close $fh;
1484
1485         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1486                 if defined $to_cmd;
1487         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1488                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1489
1490         if ($broken_encoding{$t} && !$has_content_type) {
1491                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1492                 $has_content_type = 1;
1493                 push @xh, "Content-Type: text/plain; charset=$auto_8bit_encoding";
1494                 $body_encoding = $auto_8bit_encoding;
1495         }
1496
1497         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1498                 $subject = quote_subject($subject, $auto_8bit_encoding);
1499         }
1500
1501         if (defined $sauthor and $sauthor ne $sender) {
1502                 $message = "From: $author\n\n$message";
1503                 if (defined $author_encoding) {
1504                         if ($has_content_type) {
1505                                 if ($body_encoding eq $author_encoding) {
1506                                         # ok, we already have the right encoding
1507                                 }
1508                                 else {
1509                                         # uh oh, we should re-encode
1510                                 }
1511                         }
1512                         else {
1513                                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1514                                 $has_content_type = 1;
1515                                 push @xh,
1516                                   "Content-Type: text/plain; charset=$author_encoding";
1517                         }
1518                 }
1519         }
1520         if (defined $target_xfer_encoding) {
1521                 $xfer_encoding = '8bit' if not defined $xfer_encoding;
1522                 $message = apply_transfer_encoding(
1523                         $message, $xfer_encoding, $target_xfer_encoding);
1524                 $xfer_encoding = $target_xfer_encoding;
1525         }
1526         if (defined $xfer_encoding) {
1527                 push @xh, "Content-Transfer-Encoding: $xfer_encoding";
1528         }
1529         if (defined $xfer_encoding or $has_content_type) {
1530                 unshift @xh, 'MIME-Version: 1.0' unless $has_mime_version;
1531         }
1532
1533         $needs_confirm = (
1534                 $confirm eq "always" or
1535                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1536                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1537         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1538
1539         @to = validate_address_list(sanitize_address_list(@to));
1540         @cc = validate_address_list(sanitize_address_list(@cc));
1541
1542         @to = (@initial_to, @to);
1543         @cc = (@initial_cc, @cc);
1544
1545         if ($message_num == 1) {
1546                 if (defined $cover_cc and $cover_cc) {
1547                         @initial_cc = @cc;
1548                 }
1549                 if (defined $cover_to and $cover_to) {
1550                         @initial_to = @to;
1551                 }
1552         }
1553
1554         my $message_was_sent = send_message();
1555
1556         # set up for the next message
1557         if ($thread && $message_was_sent &&
1558                 ($chain_reply_to || !defined $reply_to || length($reply_to) == 0 ||
1559                 $message_num == 1)) {
1560                 $reply_to = $message_id;
1561                 if (length $references > 0) {
1562                         $references .= "\n $message_id";
1563                 } else {
1564                         $references = "$message_id";
1565                 }
1566         }
1567         $message_id = undef;
1568 }
1569
1570 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1571 # and return a results array
1572 sub recipients_cmd {
1573         my ($prefix, $what, $cmd, $file) = @_;
1574
1575         my @addresses = ();
1576         open my $fh, "-|", "$cmd \Q$file\E"
1577             or die "($prefix) Could not execute '$cmd'";
1578         while (my $address = <$fh>) {
1579                 $address =~ s/^\s*//g;
1580                 $address =~ s/\s*$//g;
1581                 $address = sanitize_address($address);
1582                 next if ($address eq $sender and $suppress_cc{'self'});
1583                 push @addresses, $address;
1584                 printf("($prefix) Adding %s: %s from: '%s'\n",
1585                        $what, $address, $cmd) unless $quiet;
1586                 }
1587         close $fh
1588             or die "($prefix) failed to close pipe to '$cmd'";
1589         return @addresses;
1590 }
1591
1592 cleanup_compose_files();
1593
1594 sub cleanup_compose_files {
1595         unlink($compose_filename, $compose_filename . ".final") if $compose;
1596 }
1597
1598 $smtp->quit if $smtp;
1599
1600 sub apply_transfer_encoding {
1601         my $message = shift;
1602         my $from = shift;
1603         my $to = shift;
1604
1605         return $message if ($from eq $to and $from ne '7bit');
1606
1607         require MIME::QuotedPrint;
1608         require MIME::Base64;
1609
1610         $message = MIME::QuotedPrint::decode($message)
1611                 if ($from eq 'quoted-printable');
1612         $message = MIME::Base64::decode($message)
1613                 if ($from eq 'base64');
1614
1615         die "cannot send message as 7bit"
1616                 if ($to eq '7bit' and $message =~ /[^[:ascii:]]/);
1617         return $message
1618                 if ($to eq '7bit' or $to eq '8bit');
1619         return MIME::QuotedPrint::encode($message, "\n", 0)
1620                 if ($to eq 'quoted-printable');
1621         return MIME::Base64::encode($message, "\n")
1622                 if ($to eq 'base64');
1623         die "invalid transfer encoding";
1624 }
1625
1626 sub unique_email_list {
1627         my %seen;
1628         my @emails;
1629
1630         foreach my $entry (@_) {
1631                 my $clean = extract_valid_address_or_die($entry);
1632                 $seen{$clean} ||= 0;
1633                 next if $seen{$clean}++;
1634                 push @emails, $entry;
1635         }
1636         return @emails;
1637 }
1638
1639 sub validate_patch {
1640         my $fn = shift;
1641         open(my $fh, '<', $fn)
1642                 or die "unable to open $fn: $!\n";
1643         while (my $line = <$fh>) {
1644                 if (length($line) > 998) {
1645                         return "$.: patch contains a line longer than 998 characters";
1646                 }
1647         }
1648         return;
1649 }
1650
1651 sub file_has_nonascii {
1652         my $fn = shift;
1653         open(my $fh, '<', $fn)
1654                 or die "unable to open $fn: $!\n";
1655         while (my $line = <$fh>) {
1656                 return 1 if $line =~ /[^[:ascii:]]/;
1657         }
1658         return 0;
1659 }
1660
1661 sub body_or_subject_has_nonascii {
1662         my $fn = shift;
1663         open(my $fh, '<', $fn)
1664                 or die "unable to open $fn: $!\n";
1665         while (my $line = <$fh>) {
1666                 last if $line =~ /^$/;
1667                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1668         }
1669         while (my $line = <$fh>) {
1670                 return 1 if $line =~ /[^[:ascii:]]/;
1671         }
1672         return 0;
1673 }