git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Data::Dumper;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49
  50   Composing:
  51     --from                  <str>  * Email From:
  52     --[no-]to               <str>  * Email To:
  53     --[no-]cc               <str>  * Email Cc:
  54     --[no-]bcc              <str>  * Email Bcc:
  55     --subject               <str>  * Email "Subject:"
  56     --in-reply-to           <str>  * Email "In-Reply-To:"
  57     --[no-]annotate                * Review each patch that will be sent in an editor.
  58     --compose                      * Open an editor for introduction.
  59     --compose-encoding      <str>  * Encoding to assume for introduction.
  60     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  61
  62   Sending:
  63     --envelope-sender       <str>  * Email envelope sender.
  64     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  65                                      is optional. Default 'localhost'.
  66     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  67     --smtp-server-port      <int>  * Outgoing SMTP server port.
  68     --smtp-user             <str>  * Username for SMTP-AUTH.
  69     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  70     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  71     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  72     --smtp-ssl-cert-path    <str>  * Path to ca-certificates (either directory or file).
  73                                      Pass an empty string to disable certificate
  74                                      verification.
  75     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  76     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  77
  78   Automating:
  79     --identity              <str>  * Use the sendemail.<id> options.
  80     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  81     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  82     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  83     --[no-]cc-cover                * Email Cc: addresses in the cover letter.
  84     --[no-]to-cover                * Email To: addresses in the cover letter.
  85     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  86     --[no-]suppress-from           * Send to self. Default off.
  87     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  88     --[no-]thread                  * Use In-Reply-To: field. Default on.
  89
  90   Administering:
  91     --confirm               <str>  * Confirm recipients before sending;
  92                                      auto, cc, compose, always, or never.
  93     --quiet                        * Output one line of info per email.
  94     --dry-run                      * Don't actually send the emails.
  95     --[no-]validate                * Perform patch sanity checks. Default on.
  96     --[no-]format-patch            * understand any non optional arguments as
  97                                      `git format-patch` ones.
  98     --force                        * Send even if safety checks would prevent it.
  99
 100 EOT
 101         exit(1);
 102 }
 103
 104 # most mail servers generate the Date: header, but not all...
 105 sub format_2822_time {
 106         my ($time) = @_;
 107         my @localtm = localtime($time);
 108         my @gmttm = gmtime($time);
 109         my $localmin = $localtm[1] + $localtm[2] * 60;
 110         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 111         if ($localtm[0] != $gmttm[0]) {
 112                 die "local zone differs from GMT by a non-minute interval\n";
 113         }
 114         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 115                 $localmin += 1440;
 116         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 117                 $localmin -= 1440;
 118         } elsif ($gmttm[6] != $localtm[6]) {
 119                 die "local time offset greater than or equal to 24 hours\n";
 120         }
 121         my $offset = $localmin - $gmtmin;
 122         my $offhour = $offset / 60;
 123         my $offmin = abs($offset % 60);
 124         if (abs($offhour) >= 24) {
 125                 die ("local time offset greater than or equal to 24 hours\n");
 126         }
 127
 128         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 129                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 130                        $localtm[3],
 131                        qw(Jan Feb Mar Apr May Jun
 132                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 133                        $localtm[5]+1900,
 134                        $localtm[2],
 135                        $localtm[1],
 136                        $localtm[0],
 137                        ($offset >= 0) ? '+' : '-',
 138                        abs($offhour),
 139                        $offmin,
 140                        );
 141 }
 142
 143 my $have_email_valid = eval { require Email::Valid; 1 };
 144 my $have_mail_address = eval { require Mail::Address; 1 };
 145 my $smtp;
 146 my $auth;
 147
 148 # Variables we fill in automatically, or via prompting:
 149 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 150         $initial_reply_to,$initial_subject,@files,
 151         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 152
 153 my $envelope_sender;
 154
 155 # Example reply to:
 156 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 157
 158 my $repo = eval { Git->repository() };
 159 my @repo = $repo ? ($repo) : ();
 160 my $term = eval {
 161         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 162                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 163                 : new Term::ReadLine 'git-send-email';
 164 };
 165 if ($@) {
 166         $term = new FakeTerm "$@: going non-interactive";
 167 }
 168
 169 # Behavior modification variables
 170 my ($quiet, $dry_run) = (0, 0);
 171 my $format_patch;
 172 my $compose_filename;
 173 my $force = 0;
 174
 175 # Handle interactive edition of files.
 176 my $multiedit;
 177 my $editor;
 178
 179 sub do_edit {
 180         if (!defined($editor)) {
 181                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 182         }
 183         if (defined($multiedit) && !$multiedit) {
 184                 map {
 185                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 186                         if (($? & 127) || ($? >> 8)) {
 187                                 die("the editor exited uncleanly, aborting everything");
 188                         }
 189                 } @_;
 190         } else {
 191                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 192                 if (($? & 127) || ($? >> 8)) {
 193                         die("the editor exited uncleanly, aborting everything");
 194                 }
 195         }
 196 }
 197
 198 # Variables with corresponding config settings
 199 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 200 my ($cover_cc, $cover_to);
 201 my ($to_cmd, $cc_cmd);
 202 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 203 my ($smtp_authuser, $smtp_encryption, $smtp_ssl_cert_path);
 204 my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
 205 my ($validate, $confirm);
 206 my (@suppress_cc);
 207 my ($auto_8bit_encoding);
 208 my ($compose_encoding);
 209
 210 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 211
 212 my %config_bool_settings = (
 213     "thread" => [\$thread, 1],
 214     "chainreplyto" => [\$chain_reply_to, 0],
 215     "suppressfrom" => [\$suppress_from, undef],
 216     "signedoffbycc" => [\$signed_off_by_cc, undef],
 217     "cccover" => [\$cover_cc, undef],
 218     "tocover" => [\$cover_to, undef],
 219     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 220     "validate" => [\$validate, 1],
 221     "multiedit" => [\$multiedit, undef],
 222     "annotate" => [\$annotate, undef]
 223 );
 224
 225 my %config_settings = (
 226     "smtpserver" => \$smtp_server,
 227     "smtpserverport" => \$smtp_server_port,
 228     "smtpserveroption" => \@smtp_server_options,
 229     "smtpuser" => \$smtp_authuser,
 230     "smtppass" => \$smtp_authpass,
 231     "smtpsslcertpath" => \$smtp_ssl_cert_path,
 232     "smtpdomain" => \$smtp_domain,
 233     "to" => \@initial_to,
 234     "tocmd" => \$to_cmd,
 235     "cc" => \@initial_cc,
 236     "cccmd" => \$cc_cmd,
 237     "aliasfiletype" => \$aliasfiletype,
 238     "bcc" => \@bcclist,
 239     "suppresscc" => \@suppress_cc,
 240     "envelopesender" => \$envelope_sender,
 241     "confirm"   => \$confirm,
 242     "from" => \$sender,
 243     "assume8bitencoding" => \$auto_8bit_encoding,
 244     "composeencoding" => \$compose_encoding,
 245 );
 246
 247 my %config_path_settings = (
 248     "aliasesfile" => \@alias_files,
 249 );
 250
 251 # Handle Uncouth Termination
 252 sub signal_handler {
 253
 254         # Make text normal
 255         print color("reset"), "\n";
 256
 257         # SMTP password masked
 258         system "stty echo";
 259
 260         # tmp files from --compose
 261         if (defined $compose_filename) {
 262                 if (-e $compose_filename) {
 263                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 264                 }
 265                 if (-e ($compose_filename . ".final")) {
 266                         print "'$compose_filename.final' contains the composed email.\n"
 267                 }
 268         }
 269
 270         exit;
 271 };
 272
 273 $SIG{TERM} = \&signal_handler;
 274 $SIG{INT}  = \&signal_handler;
 275
 276 # Begin by accumulating all the variables (defined above), that we will end up
 277 # needing, first, from the command line:
 278
 279 my $help;
 280 my $rc = GetOptions("h" => \$help,
 281                     "sender|from=s" => \$sender,
 282                     "in-reply-to=s" => \$initial_reply_to,
 283                     "subject=s" => \$initial_subject,
 284                     "to=s" => \@initial_to,
 285                     "to-cmd=s" => \$to_cmd,
 286                     "no-to" => \$no_to,
 287                     "cc=s" => \@initial_cc,
 288                     "no-cc" => \$no_cc,
 289                     "bcc=s" => \@bcclist,
 290                     "no-bcc" => \$no_bcc,
 291                     "chain-reply-to!" => \$chain_reply_to,
 292                     "smtp-server=s" => \$smtp_server,
 293                     "smtp-server-option=s" => \@smtp_server_options,
 294                     "smtp-server-port=s" => \$smtp_server_port,
 295                     "smtp-user=s" => \$smtp_authuser,
 296                     "smtp-pass:s" => \$smtp_authpass,
 297                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 298                     "smtp-encryption=s" => \$smtp_encryption,
 299                     "smtp-ssl-cert-path=s" => \$smtp_ssl_cert_path,
 300                     "smtp-debug:i" => \$debug_net_smtp,
 301                     "smtp-domain:s" => \$smtp_domain,
 302                     "identity=s" => \$identity,
 303                     "annotate!" => \$annotate,
 304                     "compose" => \$compose,
 305                     "quiet" => \$quiet,
 306                     "cc-cmd=s" => \$cc_cmd,
 307                     "suppress-from!" => \$suppress_from,
 308                     "suppress-cc=s" => \@suppress_cc,
 309                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 310                     "cc-cover|cc-cover!" => \$cover_cc,
 311                     "to-cover|to-cover!" => \$cover_to,
 312                     "confirm=s" => \$confirm,
 313                     "dry-run" => \$dry_run,
 314                     "envelope-sender=s" => \$envelope_sender,
 315                     "thread!" => \$thread,
 316                     "validate!" => \$validate,
 317                     "format-patch!" => \$format_patch,
 318                     "8bit-encoding=s" => \$auto_8bit_encoding,
 319                     "compose-encoding=s" => \$compose_encoding,
 320                     "force" => \$force,
 321          );
 322
 323 usage() if $help;
 324 unless ($rc) {
 325     usage();
 326 }
 327
 328 die "Cannot run git format-patch from outside a repository\n"
 329         if $format_patch and not $repo;
 330
 331 # Now, let's fill any that aren't set in with defaults:
 332
 333 sub read_config {
 334         my ($prefix) = @_;
 335
 336         foreach my $setting (keys %config_bool_settings) {
 337                 my $target = $config_bool_settings{$setting}->[0];
 338                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 339         }
 340
 341         foreach my $setting (keys %config_path_settings) {
 342                 my $target = $config_path_settings{$setting};
 343                 if (ref($target) eq "ARRAY") {
 344                         unless (@$target) {
 345                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 346                                 @$target = @values if (@values && defined $values[0]);
 347                         }
 348                 }
 349                 else {
 350                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 351                 }
 352         }
 353
 354         foreach my $setting (keys %config_settings) {
 355                 my $target = $config_settings{$setting};
 356                 next if $setting eq "to" and defined $no_to;
 357                 next if $setting eq "cc" and defined $no_cc;
 358                 next if $setting eq "bcc" and defined $no_bcc;
 359                 if (ref($target) eq "ARRAY") {
 360                         unless (@$target) {
 361                                 my @values = Git::config(@repo, "$prefix.$setting");
 362                                 @$target = @values if (@values && defined $values[0]);
 363                         }
 364                 }
 365                 else {
 366                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 367                 }
 368         }
 369
 370         if (!defined $smtp_encryption) {
 371                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 372                 if (defined $enc) {
 373                         $smtp_encryption = $enc;
 374                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 375                         $smtp_encryption = 'ssl';
 376                 }
 377         }
 378 }
 379
 380 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 381 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 382 read_config("sendemail.$identity") if (defined $identity);
 383 read_config("sendemail");
 384
 385 # fall back on builtin bool defaults
 386 foreach my $setting (values %config_bool_settings) {
 387         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 388 }
 389
 390 # 'default' encryption is none -- this only prevents a warning
 391 $smtp_encryption = '' unless (defined $smtp_encryption);
 392
 393 # Set CC suppressions
 394 my(%suppress_cc);
 395 if (@suppress_cc) {
 396         foreach my $entry (@suppress_cc) {
 397                 die "Unknown --suppress-cc field: '$entry'\n"
 398                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 399                 $suppress_cc{$entry} = 1;
 400         }
 401 }
 402
 403 if ($suppress_cc{'all'}) {
 404         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 405                 $suppress_cc{$entry} = 1;
 406         }
 407         delete $suppress_cc{'all'};
 408 }
 409
 410 # If explicit old-style ones are specified, they trump --suppress-cc.
 411 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 412 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 413
 414 if ($suppress_cc{'body'}) {
 415         foreach my $entry (qw (sob bodycc)) {
 416                 $suppress_cc{$entry} = 1;
 417         }
 418         delete $suppress_cc{'body'};
 419 }
 420
 421 # Set confirm's default value
 422 my $confirm_unconfigured = !defined $confirm;
 423 if ($confirm_unconfigured) {
 424         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 425 };
 426 die "Unknown --confirm setting: '$confirm'\n"
 427         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 428
 429 # Debugging, print out the suppressions.
 430 if (0) {
 431         print "suppressions:\n";
 432         foreach my $entry (keys %suppress_cc) {
 433                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 434         }
 435 }
 436
 437 my ($repoauthor, $repocommitter);
 438 ($repoauthor) = Git::ident_person(@repo, 'author');
 439 ($repocommitter) = Git::ident_person(@repo, 'committer');
 440
 441 # Verify the user input
 442
 443 foreach my $entry (@initial_to) {
 444         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 445 }
 446
 447 foreach my $entry (@initial_cc) {
 448         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 449 }
 450
 451 foreach my $entry (@bcclist) {
 452         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 453 }
 454
 455 sub parse_address_line {
 456         if ($have_mail_address) {
 457                 return map { $_->format } Mail::Address->parse($_[0]);
 458         } else {
 459                 return split_addrs($_[0]);
 460         }
 461 }
 462
 463 sub split_addrs {
 464         return quotewords('\s*,\s*', 1, @_);
 465 }
 466
 467 my %aliases;
 468 my %parse_alias = (
 469         # multiline formats can be supported in the future
 470         mutt => sub { my $fh = shift; while (<$fh>) {
 471                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 472                         my ($alias, $addr) = ($1, $2);
 473                         $addr =~ s/#.*$//; # mutt allows # comments
 474                          # commas delimit multiple addresses
 475                         $aliases{$alias} = [ split_addrs($addr) ];
 476                 }}},
 477         mailrc => sub { my $fh = shift; while (<$fh>) {
 478                 if (/^alias\s+(\S+)\s+(.*)$/) {
 479                         # spaces delimit multiple addresses
 480                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 481                 }}},
 482         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 483                 for (my $x = ''; defined($x); $x = $_) {
 484                         chomp $x;
 485                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 486                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 487                         $aliases{$1} = [ split_addrs($2) ];
 488                 }},
 489         elm => sub  { my $fh = shift;
 490                       while (<$fh>) {
 491                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 492                               my ($alias, $addr) = ($1, $2);
 493                                $aliases{$alias} = [ split_addrs($addr) ];
 494                           }
 495                       } },
 496
 497         gnus => sub { my $fh = shift; while (<$fh>) {
 498                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 499                         $aliases{$1} = [ $2 ];
 500                 }}}
 501 );
 502
 503 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 504         foreach my $file (@alias_files) {
 505                 open my $fh, '<', $file or die "opening $file: $!\n";
 506                 $parse_alias{$aliasfiletype}->($fh);
 507                 close $fh;
 508         }
 509 }
 510
 511 ($sender) = expand_aliases($sender) if defined $sender;
 512
 513 # is_format_patch_arg($f) returns 0 if $f names a patch, or 1 if
 514 # $f is a revision list specification to be passed to format-patch.
 515 sub is_format_patch_arg {
 516         return unless $repo;
 517         my $f = shift;
 518         try {
 519                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 520                 if (defined($format_patch)) {
 521                         return $format_patch;
 522                 }
 523                 die(<<EOF);
 524 File '$f' exists but it could also be the range of commits
 525 to produce patches for.  Please disambiguate by...
 526
 527     * Saying "./$f" if you mean a file; or
 528     * Giving --format-patch option if you mean a range.
 529 EOF
 530         } catch Git::Error::Command with {
 531                 # Not a valid revision.  Treat it as a filename.
 532                 return 0;
 533         }
 534 }
 535
 536 # Now that all the defaults are set, process the rest of the command line
 537 # arguments and collect up the files that need to be processed.
 538 my @rev_list_opts;
 539 while (defined(my $f = shift @ARGV)) {
 540         if ($f eq "--") {
 541                 push @rev_list_opts, "--", @ARGV;
 542                 @ARGV = ();
 543         } elsif (-d $f and !is_format_patch_arg($f)) {
 544                 opendir my $dh, $f
 545                         or die "Failed to opendir $f: $!";
 546
 547                 push @files, grep { -f $_ } map { catfile($f, $_) }
 548                                 sort readdir $dh;
 549                 closedir $dh;
 550         } elsif ((-f $f or -p $f) and !is_format_patch_arg($f)) {
 551                 push @files, $f;
 552         } else {
 553                 push @rev_list_opts, $f;
 554         }
 555 }
 556
 557 if (@rev_list_opts) {
 558         die "Cannot run git format-patch from outside a repository\n"
 559                 unless $repo;
 560         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 561 }
 562
 563 if ($validate) {
 564         foreach my $f (@files) {
 565                 unless (-p $f) {
 566                         my $error = validate_patch($f);
 567                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 568                 }
 569         }
 570 }
 571
 572 if (@files) {
 573         unless ($quiet) {
 574                 print $_,"\n" for (@files);
 575         }
 576 } else {
 577         print STDERR "\nNo patch files specified!\n\n";
 578         usage();
 579 }
 580
 581 sub get_patch_subject {
 582         my $fn = shift;
 583         open (my $fh, '<', $fn);
 584         while (my $line = <$fh>) {
 585                 next unless ($line =~ /^Subject: (.*)$/);
 586                 close $fh;
 587                 return "GIT: $1\n";
 588         }
 589         close $fh;
 590         die "No subject line in $fn ?";
 591 }
 592
 593 if ($compose) {
 594         # Note that this does not need to be secure, but we will make a small
 595         # effort to have it be unique
 596         $compose_filename = ($repo ?
 597                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 598                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 599         open my $c, ">", $compose_filename
 600                 or die "Failed to open for writing $compose_filename: $!";
 601
 602
 603         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 604         my $tpl_subject = $initial_subject || '';
 605         my $tpl_reply_to = $initial_reply_to || '';
 606
 607         print $c <<EOT;
 608 From $tpl_sender # This line is ignored.
 609 GIT: Lines beginning in "GIT:" will be removed.
 610 GIT: Consider including an overall diffstat or table of contents
 611 GIT: for the patch you are writing.
 612 GIT:
 613 GIT: Clear the body content if you don't wish to send a summary.
 614 From: $tpl_sender
 615 Subject: $tpl_subject
 616 In-Reply-To: $tpl_reply_to
 617
 618 EOT
 619         for my $f (@files) {
 620                 print $c get_patch_subject($f);
 621         }
 622         close $c;
 623
 624         if ($annotate) {
 625                 do_edit($compose_filename, @files);
 626         } else {
 627                 do_edit($compose_filename);
 628         }
 629
 630         open my $c2, ">", $compose_filename . ".final"
 631                 or die "Failed to open $compose_filename.final : " . $!;
 632
 633         open $c, "<", $compose_filename
 634                 or die "Failed to open $compose_filename : " . $!;
 635
 636         my $need_8bit_cte = file_has_nonascii($compose_filename);
 637         my $in_body = 0;
 638         my $summary_empty = 1;
 639         if (!defined $compose_encoding) {
 640                 $compose_encoding = "UTF-8";
 641         }
 642         while(<$c>) {
 643                 next if m/^GIT:/;
 644                 if ($in_body) {
 645                         $summary_empty = 0 unless (/^\n$/);
 646                 } elsif (/^\n$/) {
 647                         $in_body = 1;
 648                         if ($need_8bit_cte) {
 649                                 print $c2 "MIME-Version: 1.0\n",
 650                                          "Content-Type: text/plain; ",
 651                                            "charset=$compose_encoding\n",
 652                                          "Content-Transfer-Encoding: 8bit\n";
 653                         }
 654                 } elsif (/^MIME-Version:/i) {
 655                         $need_8bit_cte = 0;
 656                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 657                         $initial_subject = $1;
 658                         my $subject = $initial_subject;
 659                         $_ = "Subject: " .
 660                                 quote_subject($subject, $compose_encoding) .
 661                                 "\n";
 662                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 663                         $initial_reply_to = $1;
 664                         next;
 665                 } elsif (/^From:\s*(.+)\s*$/i) {
 666                         $sender = $1;
 667                         next;
 668                 } elsif (/^(?:To|Cc|Bcc):/i) {
 669                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 670                         next;
 671                 }
 672                 print $c2 $_;
 673         }
 674         close $c;
 675         close $c2;
 676
 677         if ($summary_empty) {
 678                 print "Summary email is empty, skipping it\n";
 679                 $compose = -1;
 680         }
 681 } elsif ($annotate) {
 682         do_edit(@files);
 683 }
 684
 685 sub ask {
 686         my ($prompt, %arg) = @_;
 687         my $valid_re = $arg{valid_re};
 688         my $default = $arg{default};
 689         my $confirm_only = $arg{confirm_only};
 690         my $resp;
 691         my $i = 0;
 692         return defined $default ? $default : undef
 693                 unless defined $term->IN and defined fileno($term->IN) and
 694                        defined $term->OUT and defined fileno($term->OUT);
 695         while ($i++ < 10) {
 696                 $resp = $term->readline($prompt);
 697                 if (!defined $resp) { # EOF
 698                         print "\n";
 699                         return defined $default ? $default : undef;
 700                 }
 701                 if ($resp eq '' and defined $default) {
 702                         return $default;
 703                 }
 704                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 705                         return $resp;
 706                 }
 707                 if ($confirm_only) {
 708                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 709                         if (defined $yesno && $yesno =~ /y/i) {
 710                                 return $resp;
 711                         }
 712                 }
 713         }
 714         return;
 715 }
 716
 717 my %broken_encoding;
 718
 719 sub file_declares_8bit_cte {
 720         my $fn = shift;
 721         open (my $fh, '<', $fn);
 722         while (my $line = <$fh>) {
 723                 last if ($line =~ /^$/);
 724                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 725         }
 726         close $fh;
 727         return 0;
 728 }
 729
 730 foreach my $f (@files) {
 731         next unless (body_or_subject_has_nonascii($f)
 732                      && !file_declares_8bit_cte($f));
 733         $broken_encoding{$f} = 1;
 734 }
 735
 736 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 737         print "The following files are 8bit, but do not declare " .
 738                 "a Content-Transfer-Encoding.\n";
 739         foreach my $f (sort keys %broken_encoding) {
 740                 print "    $f\n";
 741         }
 742         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 743                                   default => "UTF-8");
 744 }
 745
 746 if (!$force) {
 747         for my $f (@files) {
 748                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 749                         die "Refusing to send because the patch\n\t$f\n"
 750                                 . "has the template subject '*** SUBJECT HERE ***'. "
 751                                 . "Pass --force if you really want to send.\n";
 752                 }
 753         }
 754 }
 755
 756 if (!defined $sender) {
 757         $sender = $repoauthor || $repocommitter || '';
 758 }
 759
 760 # $sender could be an already sanitized address
 761 # (e.g. sendemail.from could be manually sanitized by user).
 762 # But it's a no-op to run sanitize_address on an already sanitized address.
 763 $sender = sanitize_address($sender);
 764
 765 my $prompting = 0;
 766 if (!@initial_to && !defined $to_cmd) {
 767         my $to = ask("Who should the emails be sent to (if any)? ",
 768                      default => "",
 769                      valid_re => qr/\@.*\./, confirm_only => 1);
 770         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 771         $prompting++;
 772 }
 773
 774 sub expand_aliases {
 775         return map { expand_one_alias($_) } @_;
 776 }
 777
 778 my %EXPANDED_ALIASES;
 779 sub expand_one_alias {
 780         my $alias = shift;
 781         if ($EXPANDED_ALIASES{$alias}) {
 782                 die "fatal: alias '$alias' expands to itself\n";
 783         }
 784         local $EXPANDED_ALIASES{$alias} = 1;
 785         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 786 }
 787
 788 @initial_to = expand_aliases(@initial_to);
 789 @initial_to = validate_address_list(sanitize_address_list(@initial_to));
 790 @initial_cc = expand_aliases(@initial_cc);
 791 @initial_cc = validate_address_list(sanitize_address_list(@initial_cc));
 792 @bcclist = expand_aliases(@bcclist);
 793 @bcclist = validate_address_list(sanitize_address_list(@bcclist));
 794
 795 if ($thread && !defined $initial_reply_to && $prompting) {
 796         $initial_reply_to = ask(
 797                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 798                 default => "",
 799                 valid_re => qr/\@.*\./, confirm_only => 1);
 800 }
 801 if (defined $initial_reply_to) {
 802         $initial_reply_to =~ s/^\s*<?//;
 803         $initial_reply_to =~ s/>?\s*$//;
 804         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 805 }
 806
 807 if (!defined $smtp_server) {
 808         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 809                 if (-x $_) {
 810                         $smtp_server = $_;
 811                         last;
 812                 }
 813         }
 814         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 815 }
 816
 817 if ($compose && $compose > 0) {
 818         @files = ($compose_filename . ".final", @files);
 819 }
 820
 821 # Variables we set as part of the loop over files
 822 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 823         $needs_confirm, $message_num, $ask_default);
 824
 825 sub extract_valid_address {
 826         my $address = shift;
 827         my $local_part_regexp = qr/[^<>"\s@]+/;
 828         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 829
 830         # check for a local address:
 831         return $address if ($address =~ /^($local_part_regexp)$/);
 832
 833         $address =~ s/^\s*<(.*)>\s*$/$1/;
 834         if ($have_email_valid) {
 835                 return scalar Email::Valid->address($address);
 836         }
 837
 838         # less robust/correct than the monster regexp in Email::Valid,
 839         # but still does a 99% job, and one less dependency
 840         return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
 841         return;
 842 }
 843
 844 sub extract_valid_address_or_die {
 845         my $address = shift;
 846         $address = extract_valid_address($address);
 847         die "error: unable to extract a valid address from: $address\n"
 848                 if !$address;
 849         return $address;
 850 }
 851
 852 sub validate_address {
 853         my $address = shift;
 854         while (!extract_valid_address($address)) {
 855                 print STDERR "error: unable to extract a valid address from: $address\n";
 856                 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
 857                         valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
 858                         default => 'q');
 859                 if (/^d/i) {
 860                         return undef;
 861                 } elsif (/^q/i) {
 862                         cleanup_compose_files();
 863                         exit(0);
 864                 }
 865                 $address = ask("Who should the email be sent to (if any)? ",
 866                         default => "",
 867                         valid_re => qr/\@.*\./, confirm_only => 1);
 868         }
 869         return $address;
 870 }
 871
 872 sub validate_address_list {
 873         return (grep { defined $_ }
 874                 map { validate_address($_) } @_);
 875 }
 876
 877 # Usually don't need to change anything below here.
 878
 879 # we make a "fake" message id by taking the current number
 880 # of seconds since the beginning of Unix time and tacking on
 881 # a random number to the end, in case we are called quicker than
 882 # 1 second since the last time we were called.
 883
 884 # We'll setup a template for the message id, using the "from" address:
 885
 886 my ($message_id_stamp, $message_id_serial);
 887 sub make_message_id {
 888         my $uniq;
 889         if (!defined $message_id_stamp) {
 890                 $message_id_stamp = sprintf("%s-%s", time, $$);
 891                 $message_id_serial = 0;
 892         }
 893         $message_id_serial++;
 894         $uniq = "$message_id_stamp-$message_id_serial";
 895
 896         my $du_part;
 897         for ($sender, $repocommitter, $repoauthor) {
 898                 $du_part = extract_valid_address(sanitize_address($_));
 899                 last if (defined $du_part and $du_part ne '');
 900         }
 901         if (not defined $du_part or $du_part eq '') {
 902                 require Sys::Hostname;
 903                 $du_part = 'user@' . Sys::Hostname::hostname();
 904         }
 905         my $message_id_template = "<%s-git-send-email-%s>";
 906         $message_id = sprintf($message_id_template, $uniq, $du_part);
 907         #print "new message id = $message_id\n"; # Was useful for debugging
 908 }
 909
 910
 911
 912 $time = time - scalar $#files;
 913
 914 sub unquote_rfc2047 {
 915         local ($_) = @_;
 916         my $encoding;
 917         s{=\?([^?]+)\?q\?(.*?)\?=}{
 918                 $encoding = $1;
 919                 my $e = $2;
 920                 $e =~ s/_/ /g;
 921                 $e =~ s/=([0-9A-F]{2})/chr(hex($1))/eg;
 922                 $e;
 923         }eg;
 924         return wantarray ? ($_, $encoding) : $_;
 925 }
 926
 927 sub quote_rfc2047 {
 928         local $_ = shift;
 929         my $encoding = shift || 'UTF-8';
 930         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 931         s/(.*)/=\?$encoding\?q\?$1\?=/;
 932         return $_;
 933 }
 934
 935 sub is_rfc2047_quoted {
 936         my $s = shift;
 937         my $token = qr/[^][()<>@,;:"\/?.= \000-\037\177-\377]+/;
 938         my $encoded_text = qr/[!->@-~]+/;
 939         length($s) <= 75 &&
 940         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 941 }
 942
 943 sub subject_needs_rfc2047_quoting {
 944         my $s = shift;
 945
 946         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
 947 }
 948
 949 sub quote_subject {
 950         local $subject = shift;
 951         my $encoding = shift || 'UTF-8';
 952
 953         if (subject_needs_rfc2047_quoting($subject)) {
 954                 return quote_rfc2047($subject, $encoding);
 955         }
 956         return $subject;
 957 }
 958
 959 # use the simplest quoting being able to handle the recipient
 960 sub sanitize_address {
 961         my ($recipient) = @_;
 962
 963         # remove garbage after email address
 964         $recipient =~ s/(.*>).*$/$1/;
 965
 966         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 967
 968         if (not $recipient_name) {
 969                 return $recipient;
 970         }
 971
 972         # if recipient_name is already quoted, do nothing
 973         if (is_rfc2047_quoted($recipient_name)) {
 974                 return $recipient;
 975         }
 976
 977         # rfc2047 is needed if a non-ascii char is included
 978         if ($recipient_name =~ /[^[:ascii:]]/) {
 979                 $recipient_name =~ s/^"(.*)"$/$1/;
 980                 $recipient_name = quote_rfc2047($recipient_name);
 981         }
 982
 983         # double quotes are needed if specials or CTLs are included
 984         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 985                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 986                 $recipient_name = qq["$recipient_name"];
 987         }
 988
 989         return "$recipient_name $recipient_addr";
 990
 991 }
 992
 993 sub sanitize_address_list {
 994         return (map { sanitize_address($_) } @_);
 995 }
 996
 997 # Returns the local Fully Qualified Domain Name (FQDN) if available.
 998 #
 999 # Tightly configured MTAa require that a caller sends a real DNS
1000 # domain name that corresponds the IP address in the HELO/EHLO
1001 # handshake. This is used to verify the connection and prevent
1002 # spammers from trying to hide their identity. If the DNS and IP don't
1003 # match, the receiveing MTA may deny the connection.
1004 #
1005 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
1006 #
1007 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
1008 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
1009 #
1010 # This maildomain*() code is based on ideas in Perl library Test::Reporter
1011 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1012
1013 sub valid_fqdn {
1014         my $domain = shift;
1015         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1016 }
1017
1018 sub maildomain_net {
1019         my $maildomain;
1020
1021         if (eval { require Net::Domain; 1 }) {
1022                 my $domain = Net::Domain::domainname();
1023                 $maildomain = $domain if valid_fqdn($domain);
1024         }
1025
1026         return $maildomain;
1027 }
1028
1029 sub maildomain_mta {
1030         my $maildomain;
1031
1032         if (eval { require Net::SMTP; 1 }) {
1033                 for my $host (qw(mailhost localhost)) {
1034                         my $smtp = Net::SMTP->new($host);
1035                         if (defined $smtp) {
1036                                 my $domain = $smtp->domain;
1037                                 $smtp->quit;
1038
1039                                 $maildomain = $domain if valid_fqdn($domain);
1040
1041                                 last if $maildomain;
1042                         }
1043                 }
1044         }
1045
1046         return $maildomain;
1047 }
1048
1049 sub maildomain {
1050         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1051 }
1052
1053 sub smtp_host_string {
1054         if (defined $smtp_server_port) {
1055                 return "$smtp_server:$smtp_server_port";
1056         } else {
1057                 return $smtp_server;
1058         }
1059 }
1060
1061 # Returns 1 if authentication succeeded or was not necessary
1062 # (smtp_user was not specified), and 0 otherwise.
1063
1064 sub smtp_auth_maybe {
1065         if (!defined $smtp_authuser || $auth) {
1066                 return 1;
1067         }
1068
1069         # Workaround AUTH PLAIN/LOGIN interaction defect
1070         # with Authen::SASL::Cyrus
1071         eval {
1072                 require Authen::SASL;
1073                 Authen::SASL->import(qw(Perl));
1074         };
1075
1076         # TODO: Authentication may fail not because credentials were
1077         # invalid but due to other reasons, in which we should not
1078         # reject credentials.
1079         $auth = Git::credential({
1080                 'protocol' => 'smtp',
1081                 'host' => smtp_host_string(),
1082                 'username' => $smtp_authuser,
1083                 # if there's no password, "git credential fill" will
1084                 # give us one, otherwise it'll just pass this one.
1085                 'password' => $smtp_authpass
1086         }, sub {
1087                 my $cred = shift;
1088                 return !!$smtp->auth($cred->{'username'}, $cred->{'password'});
1089         });
1090
1091         return $auth;
1092 }
1093
1094 sub ssl_verify_params {
1095         eval {
1096                 require IO::Socket::SSL;
1097                 IO::Socket::SSL->import(qw/SSL_VERIFY_PEER SSL_VERIFY_NONE/);
1098         };
1099         if ($@) {
1100                 print STDERR "Not using SSL_VERIFY_PEER due to out-of-date IO::Socket::SSL.\n";
1101                 return;
1102         }
1103
1104         if (!defined $smtp_ssl_cert_path) {
1105                 # use the OpenSSL defaults
1106                 return (SSL_verify_mode => SSL_VERIFY_PEER());
1107         }
1108
1109         if ($smtp_ssl_cert_path eq "") {
1110                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1111         } elsif (-d $smtp_ssl_cert_path) {
1112                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1113                         SSL_ca_path => $smtp_ssl_cert_path);
1114         } elsif (-f $smtp_ssl_cert_path) {
1115                 return (SSL_verify_mode => SSL_VERIFY_PEER(),
1116                         SSL_ca_file => $smtp_ssl_cert_path);
1117         } else {
1118                 print STDERR "Not using SSL_VERIFY_PEER because the CA path does not exist.\n";
1119                 return (SSL_verify_mode => SSL_VERIFY_NONE());
1120         }
1121 }
1122
1123 sub file_name_is_absolute {
1124         my ($path) = @_;
1125
1126         # msys does not grok DOS drive-prefixes
1127         if ($^O eq 'msys') {
1128                 return ($path =~ m#^/# || $path =~ m#^[a-zA-Z]\:#)
1129         }
1130
1131         require File::Spec::Functions;
1132         return File::Spec::Functions::file_name_is_absolute($path);
1133 }
1134
1135 # Returns 1 if the message was sent, and 0 otherwise.
1136 # In actuality, the whole program dies when there
1137 # is an error sending a message.
1138
1139 sub send_message {
1140         my @recipients = unique_email_list(@to);
1141         @cc = (grep { my $cc = extract_valid_address_or_die($_);
1142                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1143                     }
1144                @cc);
1145         my $to = join (",\n\t", @recipients);
1146         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1147         @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1148         my $date = format_2822_time($time++);
1149         my $gitversion = '@@GIT_VERSION@@';
1150         if ($gitversion =~ m/..GIT_VERSION../) {
1151             $gitversion = Git::version();
1152         }
1153
1154         my $cc = join(",\n\t", unique_email_list(@cc));
1155         my $ccline = "";
1156         if ($cc ne '') {
1157                 $ccline = "\nCc: $cc";
1158         }
1159         make_message_id() unless defined($message_id);
1160
1161         my $header = "From: $sender
1162 To: $to${ccline}
1163 Subject: $subject
1164 Date: $date
1165 Message-Id: $message_id
1166 X-Mailer: git-send-email $gitversion
1167 ";
1168         if ($reply_to) {
1169
1170                 $header .= "In-Reply-To: $reply_to\n";
1171                 $header .= "References: $references\n";
1172         }
1173         if (@xh) {
1174                 $header .= join("\n", @xh) . "\n";
1175         }
1176
1177         my @sendmail_parameters = ('-i', @recipients);
1178         my $raw_from = $sender;
1179         if (defined $envelope_sender && $envelope_sender ne "auto") {
1180                 $raw_from = $envelope_sender;
1181         }
1182         $raw_from = extract_valid_address($raw_from);
1183         unshift (@sendmail_parameters,
1184                         '-f', $raw_from) if(defined $envelope_sender);
1185
1186         if ($needs_confirm && !$dry_run) {
1187                 print "\n$header\n";
1188                 if ($needs_confirm eq "inform") {
1189                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1190                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1191                         print "    The Cc list above has been expanded by additional\n";
1192                         print "    addresses found in the patch commit message. By default\n";
1193                         print "    send-email prompts before sending whenever this occurs.\n";
1194                         print "    This behavior is controlled by the sendemail.confirm\n";
1195                         print "    configuration setting.\n";
1196                         print "\n";
1197                         print "    For additional information, run 'git send-email --help'.\n";
1198                         print "    To retain the current behavior, but squelch this message,\n";
1199                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1200                 }
1201                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1202                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1203                          default => $ask_default);
1204                 die "Send this email reply required" unless defined $_;
1205                 if (/^n/i) {
1206                         return 0;
1207                 } elsif (/^q/i) {
1208                         cleanup_compose_files();
1209                         exit(0);
1210                 } elsif (/^a/i) {
1211                         $confirm = 'never';
1212                 }
1213         }
1214
1215         unshift (@sendmail_parameters, @smtp_server_options);
1216
1217         if ($dry_run) {
1218                 # We don't want to send the email.
1219         } elsif (file_name_is_absolute($smtp_server)) {
1220                 my $pid = open my $sm, '|-';
1221                 defined $pid or die $!;
1222                 if (!$pid) {
1223                         exec($smtp_server, @sendmail_parameters) or die $!;
1224                 }
1225                 print $sm "$header\n$message";
1226                 close $sm or die $!;
1227         } else {
1228
1229                 if (!defined $smtp_server) {
1230                         die "The required SMTP server is not properly defined."
1231                 }
1232
1233                 if ($smtp_encryption eq 'ssl') {
1234                         $smtp_server_port ||= 465; # ssmtp
1235                         require Net::SMTP::SSL;
1236                         $smtp_domain ||= maildomain();
1237                         require IO::Socket::SSL;
1238                         # Net::SMTP::SSL->new() does not forward any SSL options
1239                         IO::Socket::SSL::set_client_defaults(
1240                                 ssl_verify_params());
1241                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1242                                                       Hello => $smtp_domain,
1243                                                       Port => $smtp_server_port,
1244                                                       Debug => $debug_net_smtp);
1245                 }
1246                 else {
1247                         require Net::SMTP;
1248                         $smtp_domain ||= maildomain();
1249                         $smtp_server_port ||= 25;
1250                         $smtp ||= Net::SMTP->new($smtp_server,
1251                                                  Hello => $smtp_domain,
1252                                                  Debug => $debug_net_smtp,
1253                                                  Port => $smtp_server_port);
1254                         if ($smtp_encryption eq 'tls' && $smtp) {
1255                                 require Net::SMTP::SSL;
1256                                 $smtp->command('STARTTLS');
1257                                 $smtp->response();
1258                                 if ($smtp->code == 220) {
1259                                         $smtp = Net::SMTP::SSL->start_SSL($smtp,
1260                                                                           ssl_verify_params())
1261                                                 or die "STARTTLS failed! ".IO::Socket::SSL::errstr();
1262                                         $smtp_encryption = '';
1263                                         # Send EHLO again to receive fresh
1264                                         # supported commands
1265                                         $smtp->hello($smtp_domain);
1266                                 } else {
1267                                         die "Server does not support STARTTLS! ".$smtp->message;
1268                                 }
1269                         }
1270                 }
1271
1272                 if (!$smtp) {
1273                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1274                             "VALUES: server=$smtp_server ",
1275                             "encryption=$smtp_encryption ",
1276                             "hello=$smtp_domain",
1277                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1278                 }
1279
1280                 smtp_auth_maybe or die $smtp->message;
1281
1282                 $smtp->mail( $raw_from ) or die $smtp->message;
1283                 $smtp->to( @recipients ) or die $smtp->message;
1284                 $smtp->data or die $smtp->message;
1285                 $smtp->datasend("$header\n$message") or die $smtp->message;
1286                 $smtp->dataend() or die $smtp->message;
1287                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1288         }
1289         if ($quiet) {
1290                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1291         } else {
1292                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1293                 if (!file_name_is_absolute($smtp_server)) {
1294                         print "Server: $smtp_server\n";
1295                         print "MAIL FROM:<$raw_from>\n";
1296                         foreach my $entry (@recipients) {
1297                             print "RCPT TO:<$entry>\n";
1298                         }
1299                 } else {
1300                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1301                 }
1302                 print $header, "\n";
1303                 if ($smtp) {
1304                         print "Result: ", $smtp->code, ' ',
1305                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1306                 } else {
1307                         print "Result: OK\n";
1308                 }
1309         }
1310
1311         return 1;
1312 }
1313
1314 $reply_to = $initial_reply_to;
1315 $references = $initial_reply_to || '';
1316 $subject = $initial_subject;
1317 $message_num = 0;
1318
1319 foreach my $t (@files) {
1320         open my $fh, "<", $t or die "can't open file $t";
1321
1322         my $author = undef;
1323         my $sauthor = undef;
1324         my $author_encoding;
1325         my $has_content_type;
1326         my $body_encoding;
1327         @to = ();
1328         @cc = ();
1329         @xh = ();
1330         my $input_format = undef;
1331         my @header = ();
1332         $message = "";
1333         $message_num++;
1334         # First unfold multiline header fields
1335         while(<$fh>) {
1336                 last if /^\s*$/;
1337                 if (/^\s+\S/ and @header) {
1338                         chomp($header[$#header]);
1339                         s/^\s+/ /;
1340                         $header[$#header] .= $_;
1341             } else {
1342                         push(@header, $_);
1343                 }
1344         }
1345         # Now parse the header
1346         foreach(@header) {
1347                 if (/^From /) {
1348                         $input_format = 'mbox';
1349                         next;
1350                 }
1351                 chomp;
1352                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1353                         $input_format = 'mbox';
1354                 }
1355
1356                 if (defined $input_format && $input_format eq 'mbox') {
1357                         if (/^Subject:\s+(.*)$/i) {
1358                                 $subject = $1;
1359                         }
1360                         elsif (/^From:\s+(.*)$/i) {
1361                                 ($author, $author_encoding) = unquote_rfc2047($1);
1362                                 $sauthor = sanitize_address($author);
1363                                 next if $suppress_cc{'author'};
1364                                 next if $suppress_cc{'self'} and $sauthor eq $sender;
1365                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1366                                         $1, $_) unless $quiet;
1367                                 push @cc, $1;
1368                         }
1369                         elsif (/^To:\s+(.*)$/i) {
1370                                 foreach my $addr (parse_address_line($1)) {
1371                                         printf("(mbox) Adding to: %s from line '%s'\n",
1372                                                 $addr, $_) unless $quiet;
1373                                         push @to, $addr;
1374                                 }
1375                         }
1376                         elsif (/^Cc:\s+(.*)$/i) {
1377                                 foreach my $addr (parse_address_line($1)) {
1378                                         my $qaddr = unquote_rfc2047($addr);
1379                                         my $saddr = sanitize_address($qaddr);
1380                                         if ($saddr eq $sender) {
1381                                                 next if ($suppress_cc{'self'});
1382                                         } else {
1383                                                 next if ($suppress_cc{'cc'});
1384                                         }
1385                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1386                                                 $addr, $_) unless $quiet;
1387                                         push @cc, $addr;
1388                                 }
1389                         }
1390                         elsif (/^Content-type:/i) {
1391                                 $has_content_type = 1;
1392                                 if (/charset="?([^ "]+)/) {
1393                                         $body_encoding = $1;
1394                                 }
1395                                 push @xh, $_;
1396                         }
1397                         elsif (/^Message-Id: (.*)/i) {
1398                                 $message_id = $1;
1399                         }
1400                         elsif (!/^Date:\s/i && /^[-A-Za-z]+:\s+\S/) {
1401                                 push @xh, $_;
1402                         }
1403
1404                 } else {
1405                         # In the traditional
1406                         # "send lots of email" format,
1407                         # line 1 = cc
1408                         # line 2 = subject
1409                         # So let's support that, too.
1410                         $input_format = 'lots';
1411                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1412                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1413                                         $_, $_) unless $quiet;
1414                                 push @cc, $_;
1415                         } elsif (!defined $subject) {
1416                                 $subject = $_;
1417                         }
1418                 }
1419         }
1420         # Now parse the message body
1421         while(<$fh>) {
1422                 $message .=  $_;
1423                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1424                         chomp;
1425                         my ($what, $c) = ($1, $2);
1426                         chomp $c;
1427                         my $sc = sanitize_address($c);
1428                         if ($sc eq $sender) {
1429                                 next if ($suppress_cc{'self'});
1430                         } else {
1431                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1432                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1433                         }
1434                         push @cc, $c;
1435                         printf("(body) Adding cc: %s from line '%s'\n",
1436                                 $c, $_) unless $quiet;
1437                 }
1438         }
1439         close $fh;
1440
1441         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1442                 if defined $to_cmd;
1443         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1444                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1445
1446         if ($broken_encoding{$t} && !$has_content_type) {
1447                 $has_content_type = 1;
1448                 push @xh, "MIME-Version: 1.0",
1449                         "Content-Type: text/plain; charset=$auto_8bit_encoding",
1450                         "Content-Transfer-Encoding: 8bit";
1451                 $body_encoding = $auto_8bit_encoding;
1452         }
1453
1454         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1455                 $subject = quote_subject($subject, $auto_8bit_encoding);
1456         }
1457
1458         if (defined $sauthor and $sauthor ne $sender) {
1459                 $message = "From: $author\n\n$message";
1460                 if (defined $author_encoding) {
1461                         if ($has_content_type) {
1462                                 if ($body_encoding eq $author_encoding) {
1463                                         # ok, we already have the right encoding
1464                                 }
1465                                 else {
1466                                         # uh oh, we should re-encode
1467                                 }
1468                         }
1469                         else {
1470                                 $has_content_type = 1;
1471                                 push @xh,
1472                                   'MIME-Version: 1.0',
1473                                   "Content-Type: text/plain; charset=$author_encoding",
1474                                   'Content-Transfer-Encoding: 8bit';
1475                         }
1476                 }
1477         }
1478
1479         $needs_confirm = (
1480                 $confirm eq "always" or
1481                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1482                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1483         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1484
1485         @to = validate_address_list(sanitize_address_list(@to));
1486         @cc = validate_address_list(sanitize_address_list(@cc));
1487
1488         @to = (@initial_to, @to);
1489         @cc = (@initial_cc, @cc);
1490
1491         if ($message_num == 1) {
1492                 if (defined $cover_cc and $cover_cc) {
1493                         @initial_cc = @cc;
1494                 }
1495                 if (defined $cover_to and $cover_to) {
1496                         @initial_to = @to;
1497                 }
1498         }
1499
1500         my $message_was_sent = send_message();
1501
1502         # set up for the next message
1503         if ($thread && $message_was_sent &&
1504                 ($chain_reply_to || !defined $reply_to || length($reply_to) == 0 ||
1505                 $message_num == 1)) {
1506                 $reply_to = $message_id;
1507                 if (length $references > 0) {
1508                         $references .= "\n $message_id";
1509                 } else {
1510                         $references = "$message_id";
1511                 }
1512         }
1513         $message_id = undef;
1514 }
1515
1516 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1517 # and return a results array
1518 sub recipients_cmd {
1519         my ($prefix, $what, $cmd, $file) = @_;
1520
1521         my @addresses = ();
1522         open my $fh, "-|", "$cmd \Q$file\E"
1523             or die "($prefix) Could not execute '$cmd'";
1524         while (my $address = <$fh>) {
1525                 $address =~ s/^\s*//g;
1526                 $address =~ s/\s*$//g;
1527                 $address = sanitize_address($address);
1528                 next if ($address eq $sender and $suppress_cc{'self'});
1529                 push @addresses, $address;
1530                 printf("($prefix) Adding %s: %s from: '%s'\n",
1531                        $what, $address, $cmd) unless $quiet;
1532                 }
1533         close $fh
1534             or die "($prefix) failed to close pipe to '$cmd'";
1535         return @addresses;
1536 }
1537
1538 cleanup_compose_files();
1539
1540 sub cleanup_compose_files {
1541         unlink($compose_filename, $compose_filename . ".final") if $compose;
1542 }
1543
1544 $smtp->quit if $smtp;
1545
1546 sub unique_email_list {
1547         my %seen;
1548         my @emails;
1549
1550         foreach my $entry (@_) {
1551                 my $clean = extract_valid_address_or_die($entry);
1552                 $seen{$clean} ||= 0;
1553                 next if $seen{$clean}++;
1554                 push @emails, $entry;
1555         }
1556         return @emails;
1557 }
1558
1559 sub validate_patch {
1560         my $fn = shift;
1561         open(my $fh, '<', $fn)
1562                 or die "unable to open $fn: $!\n";
1563         while (my $line = <$fh>) {
1564                 if (length($line) > 998) {
1565                         return "$.: patch contains a line longer than 998 characters";
1566                 }
1567         }
1568         return;
1569 }
1570
1571 sub file_has_nonascii {
1572         my $fn = shift;
1573         open(my $fh, '<', $fn)
1574                 or die "unable to open $fn: $!\n";
1575         while (my $line = <$fh>) {
1576                 return 1 if $line =~ /[^[:ascii:]]/;
1577         }
1578         return 0;
1579 }
1580
1581 sub body_or_subject_has_nonascii {
1582         my $fn = shift;
1583         open(my $fh, '<', $fn)
1584                 or die "unable to open $fn: $!\n";
1585         while (my $line = <$fh>) {
1586                 last if $line =~ /^$/;
1587                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1588         }
1589         while (my $line = <$fh>) {
1590                 return 1 if $line =~ /[^[:ascii:]]/;
1591         }
1592         return 0;
1593 }