git.oblomov.eu Git - git/blob - t/t7519/fsmonitor-watchman

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5 use IPC::Open2;
   6
   7 # An example hook script to integrate Watchman
   8 # (https://facebook.github.io/watchman/) with git to speed up detecting
   9 # new and modified files.
  10 #
  11 # The hook is passed a version (currently 1) and a time in nanoseconds
  12 # formatted as a string and outputs to stdout all files that have been
  13 # modified since the given time. Paths must be relative to the root of
  14 # the working tree and separated by a single NUL.
  15 #
  16 # To enable this hook, rename this file to "query-watchman" and set
  17 # 'git config core.fsmonitor .git/hooks/query-watchman'
  18 #
  19 my ($version, $time) = @ARGV;
  20 #print STDERR "$0 $version $time\n";
  21
  22 # Check the hook interface version
  23
  24 if ($version == 1) {
  25         # convert nanoseconds to seconds
  26         # subtract one second to make sure watchman will return all changes
  27         $time = int ($time / 1000000000) - 1;
  28 } else {
  29         exit 1;
  30 }
  31
  32 my $git_work_tree;
  33 if ($^O =~ 'msys' || $^O =~ 'cygwin') {
  34         $git_work_tree = Win32::GetCwd();
  35         $git_work_tree =~ tr/\\/\//;
  36 } else {
  37         require Cwd;
  38         $git_work_tree = Cwd::cwd();
  39 }
  40
  41 my $retry = 1;
  42
  43 launch_watchman();
  44
  45 sub launch_watchman {
  46
  47         my $pid = open2(\*CHLD_OUT, \*CHLD_IN, 'watchman -j')
  48             or die "open2() failed: $!\n" .
  49             "Falling back to scanning...\n";
  50
  51         # In the query expression below we're asking for names of files that
  52         # changed since $time but were not transient (ie created after
  53         # $time but no longer exist).
  54         #
  55         # To accomplish this, we're using the "since" generator to use the
  56         # recency index to select candidate nodes and "fields" to limit the
  57         # output to file names only.
  58
  59         my $query = <<" END";
  60                 ["query", "$git_work_tree", {
  61                         "since": $time,
  62                         "fields": ["name"]
  63                 }]
  64         END
  65
  66         open (my $fh, ">", ".git/watchman-query.json");
  67         print $fh $query;
  68         close $fh;
  69
  70         print CHLD_IN $query;
  71         close CHLD_IN;
  72         my $response = do {local $/; <CHLD_OUT>};
  73
  74         open ($fh, ">", ".git/watchman-response.json");
  75         print $fh $response;
  76         close $fh;
  77
  78         die "Watchman: command returned no output.\n" .
  79             "Falling back to scanning...\n" if $response eq "";
  80         die "Watchman: command returned invalid output: $response\n" .
  81             "Falling back to scanning...\n" unless $response =~ /^\{/;
  82
  83         my $json_pkg;
  84         eval {
  85                 require JSON::XS;
  86                 $json_pkg = "JSON::XS";
  87                 1;
  88         } or do {
  89                 require JSON::PP;
  90                 $json_pkg = "JSON::PP";
  91         };
  92
  93         my $o = $json_pkg->new->utf8->decode($response);
  94
  95         if ($retry > 0 and $o->{error} and $o->{error} =~ m/unable to resolve root .* directory (.*) is not watched/) {
  96                 print STDERR "Adding '$git_work_tree' to watchman's watch list.\n";
  97                 $retry--;
  98                 qx/watchman watch "$git_work_tree"/;
  99                 die "Failed to make watchman watch '$git_work_tree'.\n" .
 100                     "Falling back to scanning...\n" if $? != 0;
 101
 102                 # Watchman will always return all files on the first query so
 103                 # return the fast "everything is dirty" flag to git and do the
 104                 # Watchman query just to get it over with now so we won't pay
 105                 # the cost in git to look up each individual file.
 106
 107                 open ($fh, ">", ".git/watchman-output.out");
 108                 print "/\0";
 109                 close $fh;
 110
 111                 print "/\0";
 112                 eval { launch_watchman() };
 113                 exit 0;
 114         }
 115
 116         die "Watchman: $o->{error}.\n" .
 117             "Falling back to scanning...\n" if $o->{error};
 118
 119         open ($fh, ">", ".git/watchman-output.out");
 120         binmode $fh, ":utf8";
 121         print $fh @{$o->{files}};
 122         close $fh;
 123
 124         binmode STDOUT, ":utf8";
 125         local $, = "\0";
 126         print @{$o->{files}};
 127 }