git.oblomov.eu Git - git/blob - git-add--interactive.perl

   1 #!/usr/bin/perl
   2
   3 use 5.008;
   4 use strict;
   5 use warnings;
   6 use Git qw(unquote_path);
   7 use Git::I18N;
   8
   9 binmode(STDOUT, ":raw");
  10
  11 my $repo = Git->repository();
  12
  13 my $menu_use_color = $repo->get_colorbool('color.interactive');
  14 my ($prompt_color, $header_color, $help_color) =
  15         $menu_use_color ? (
  16                 $repo->get_color('color.interactive.prompt', 'bold blue'),
  17                 $repo->get_color('color.interactive.header', 'bold'),
  18                 $repo->get_color('color.interactive.help', 'red bold'),
  19         ) : ();
  20 my $error_color = ();
  21 if ($menu_use_color) {
  22         my $help_color_spec = ($repo->config('color.interactive.help') or
  23                                 'red bold');
  24         $error_color = $repo->get_color('color.interactive.error',
  25                                         $help_color_spec);
  26 }
  27
  28 my $diff_use_color = $repo->get_colorbool('color.diff');
  29 my ($fraginfo_color) =
  30         $diff_use_color ? (
  31                 $repo->get_color('color.diff.frag', 'cyan'),
  32         ) : ();
  33 my ($diff_plain_color) =
  34         $diff_use_color ? (
  35                 $repo->get_color('color.diff.plain', ''),
  36         ) : ();
  37 my ($diff_old_color) =
  38         $diff_use_color ? (
  39                 $repo->get_color('color.diff.old', 'red'),
  40         ) : ();
  41 my ($diff_new_color) =
  42         $diff_use_color ? (
  43                 $repo->get_color('color.diff.new', 'green'),
  44         ) : ();
  45
  46 my $normal_color = $repo->get_color("", "reset");
  47
  48 my $diff_algorithm = $repo->config('diff.algorithm');
  49 my $diff_filter = $repo->config('interactive.difffilter');
  50
  51 my $use_readkey = 0;
  52 my $use_termcap = 0;
  53 my %term_escapes;
  54
  55 sub ReadMode;
  56 sub ReadKey;
  57 if ($repo->config_bool("interactive.singlekey")) {
  58         eval {
  59                 require Term::ReadKey;
  60                 Term::ReadKey->import;
  61                 $use_readkey = 1;
  62         };
  63         if (!$use_readkey) {
  64                 print STDERR "missing Term::ReadKey, disabling interactive.singlekey\n";
  65         }
  66         eval {
  67                 require Term::Cap;
  68                 my $termcap = Term::Cap->Tgetent;
  69                 foreach (values %$termcap) {
  70                         $term_escapes{$_} = 1 if /^\e/;
  71                 }
  72                 $use_termcap = 1;
  73         };
  74 }
  75
  76 sub colored {
  77         my $color = shift;
  78         my $string = join("", @_);
  79
  80         if (defined $color) {
  81                 # Put a color code at the beginning of each line, a reset at the end
  82                 # color after newlines that are not at the end of the string
  83                 $string =~ s/(\n+)(.)/$1$color$2/g;
  84                 # reset before newlines
  85                 $string =~ s/(\n+)/$normal_color$1/g;
  86                 # codes at beginning and end (if necessary):
  87                 $string =~ s/^/$color/;
  88                 $string =~ s/$/$normal_color/ unless $string =~ /\n$/;
  89         }
  90         return $string;
  91 }
  92
  93 # command line options
  94 my $patch_mode_only;
  95 my $patch_mode;
  96 my $patch_mode_revision;
  97
  98 sub apply_patch;
  99 sub apply_patch_for_checkout_commit;
 100 sub apply_patch_for_stash;
 101
 102 my %patch_modes = (
 103         'stage' => {
 104                 DIFF => 'diff-files -p',
 105                 APPLY => sub { apply_patch 'apply --cached', @_; },
 106                 APPLY_CHECK => 'apply --cached',
 107                 FILTER => 'file-only',
 108                 IS_REVERSE => 0,
 109         },
 110         'stash' => {
 111                 DIFF => 'diff-index -p HEAD',
 112                 APPLY => sub { apply_patch 'apply --cached', @_; },
 113                 APPLY_CHECK => 'apply --cached',
 114                 FILTER => undef,
 115                 IS_REVERSE => 0,
 116         },
 117         'reset_head' => {
 118                 DIFF => 'diff-index -p --cached',
 119                 APPLY => sub { apply_patch 'apply -R --cached', @_; },
 120                 APPLY_CHECK => 'apply -R --cached',
 121                 FILTER => 'index-only',
 122                 IS_REVERSE => 1,
 123         },
 124         'reset_nothead' => {
 125                 DIFF => 'diff-index -R -p --cached',
 126                 APPLY => sub { apply_patch 'apply --cached', @_; },
 127                 APPLY_CHECK => 'apply --cached',
 128                 FILTER => 'index-only',
 129                 IS_REVERSE => 0,
 130         },
 131         'checkout_index' => {
 132                 DIFF => 'diff-files -p',
 133                 APPLY => sub { apply_patch 'apply -R', @_; },
 134                 APPLY_CHECK => 'apply -R',
 135                 FILTER => 'file-only',
 136                 IS_REVERSE => 1,
 137         },
 138         'checkout_head' => {
 139                 DIFF => 'diff-index -p',
 140                 APPLY => sub { apply_patch_for_checkout_commit '-R', @_ },
 141                 APPLY_CHECK => 'apply -R',
 142                 FILTER => undef,
 143                 IS_REVERSE => 1,
 144         },
 145         'checkout_nothead' => {
 146                 DIFF => 'diff-index -R -p',
 147                 APPLY => sub { apply_patch_for_checkout_commit '', @_ },
 148                 APPLY_CHECK => 'apply',
 149                 FILTER => undef,
 150                 IS_REVERSE => 0,
 151         },
 152 );
 153
 154 $patch_mode = 'stage';
 155 my %patch_mode_flavour = %{$patch_modes{$patch_mode}};
 156
 157 sub run_cmd_pipe {
 158         if ($^O eq 'MSWin32') {
 159                 my @invalid = grep {m/[":*]/} @_;
 160                 die "$^O does not support: @invalid\n" if @invalid;
 161                 my @args = map { m/ /o ? "\"$_\"": $_ } @_;
 162                 return qx{@args};
 163         } else {
 164                 my $fh = undef;
 165                 open($fh, '-|', @_) or die;
 166                 return <$fh>;
 167         }
 168 }
 169
 170 my ($GIT_DIR) = run_cmd_pipe(qw(git rev-parse --git-dir));
 171
 172 if (!defined $GIT_DIR) {
 173         exit(1); # rev-parse would have already said "not a git repo"
 174 }
 175 chomp($GIT_DIR);
 176
 177 sub refresh {
 178         my $fh;
 179         open $fh, 'git update-index --refresh |'
 180             or die;
 181         while (<$fh>) {
 182                 ;# ignore 'needs update'
 183         }
 184         close $fh;
 185 }
 186
 187 sub list_untracked {
 188         map {
 189                 chomp $_;
 190                 unquote_path($_);
 191         }
 192         run_cmd_pipe(qw(git ls-files --others --exclude-standard --), @ARGV);
 193 }
 194
 195 # TRANSLATORS: you can adjust this to align "git add -i" status menu
 196 my $status_fmt = __('%12s %12s %s');
 197 my $status_head = sprintf($status_fmt, __('staged'), __('unstaged'), __('path'));
 198
 199 {
 200         my $initial;
 201         sub is_initial_commit {
 202                 $initial = system('git rev-parse HEAD -- >/dev/null 2>&1') != 0
 203                         unless defined $initial;
 204                 return $initial;
 205         }
 206 }
 207
 208 sub get_empty_tree {
 209         return '4b825dc642cb6eb9a060e54bf8d69288fbee4904';
 210 }
 211
 212 sub get_diff_reference {
 213         my $ref = shift;
 214         if (defined $ref and $ref ne 'HEAD') {
 215                 return $ref;
 216         } elsif (is_initial_commit()) {
 217                 return get_empty_tree();
 218         } else {
 219                 return 'HEAD';
 220         }
 221 }
 222
 223 # Returns list of hashes, contents of each of which are:
 224 # VALUE:        pathname
 225 # BINARY:       is a binary path
 226 # INDEX:        is index different from HEAD?
 227 # FILE:         is file different from index?
 228 # INDEX_ADDDEL: is it add/delete between HEAD and index?
 229 # FILE_ADDDEL:  is it add/delete between index and file?
 230 # UNMERGED:     is the path unmerged
 231
 232 sub list_modified {
 233         my ($only) = @_;
 234         my (%data, @return);
 235         my ($add, $del, $adddel, $file);
 236
 237         my $reference = get_diff_reference($patch_mode_revision);
 238         for (run_cmd_pipe(qw(git diff-index --cached
 239                              --numstat --summary), $reference,
 240                              '--', @ARGV)) {
 241                 if (($add, $del, $file) =
 242                     /^([-\d]+)  ([-\d]+)        (.*)/) {
 243                         my ($change, $bin);
 244                         $file = unquote_path($file);
 245                         if ($add eq '-' && $del eq '-') {
 246                                 $change = __('binary');
 247                                 $bin = 1;
 248                         }
 249                         else {
 250                                 $change = "+$add/-$del";
 251                         }
 252                         $data{$file} = {
 253                                 INDEX => $change,
 254                                 BINARY => $bin,
 255                                 FILE => __('nothing'),
 256                         }
 257                 }
 258                 elsif (($adddel, $file) =
 259                        /^ (create|delete) mode [0-7]+ (.*)$/) {
 260                         $file = unquote_path($file);
 261                         $data{$file}{INDEX_ADDDEL} = $adddel;
 262                 }
 263         }
 264
 265         for (run_cmd_pipe(qw(git diff-files --ignore-submodules=dirty --numstat --summary --raw --), @ARGV)) {
 266                 if (($add, $del, $file) =
 267                     /^([-\d]+)  ([-\d]+)        (.*)/) {
 268                         $file = unquote_path($file);
 269                         my ($change, $bin);
 270                         if ($add eq '-' && $del eq '-') {
 271                                 $change = __('binary');
 272                                 $bin = 1;
 273                         }
 274                         else {
 275                                 $change = "+$add/-$del";
 276                         }
 277                         $data{$file}{FILE} = $change;
 278                         if ($bin) {
 279                                 $data{$file}{BINARY} = 1;
 280                         }
 281                 }
 282                 elsif (($adddel, $file) =
 283                        /^ (create|delete) mode [0-7]+ (.*)$/) {
 284                         $file = unquote_path($file);
 285                         $data{$file}{FILE_ADDDEL} = $adddel;
 286                 }
 287                 elsif (/^:[0-7]+ [0-7]+ [0-9a-f]+ [0-9a-f]+ (.) (.*)$/) {
 288                         $file = unquote_path($2);
 289                         if (!exists $data{$file}) {
 290                                 $data{$file} = +{
 291                                         INDEX => __('unchanged'),
 292                                         BINARY => 0,
 293                                 };
 294                         }
 295                         if ($1 eq 'U') {
 296                                 $data{$file}{UNMERGED} = 1;
 297                         }
 298                 }
 299         }
 300
 301         for (sort keys %data) {
 302                 my $it = $data{$_};
 303
 304                 if ($only) {
 305                         if ($only eq 'index-only') {
 306                                 next if ($it->{INDEX} eq __('unchanged'));
 307                         }
 308                         if ($only eq 'file-only') {
 309                                 next if ($it->{FILE} eq __('nothing'));
 310                         }
 311                 }
 312                 push @return, +{
 313                         VALUE => $_,
 314                         %$it,
 315                 };
 316         }
 317         return @return;
 318 }
 319
 320 sub find_unique {
 321         my ($string, @stuff) = @_;
 322         my $found = undef;
 323         for (my $i = 0; $i < @stuff; $i++) {
 324                 my $it = $stuff[$i];
 325                 my $hit = undef;
 326                 if (ref $it) {
 327                         if ((ref $it) eq 'ARRAY') {
 328                                 $it = $it->[0];
 329                         }
 330                         else {
 331                                 $it = $it->{VALUE};
 332                         }
 333                 }
 334                 eval {
 335                         if ($it =~ /^$string/) {
 336                                 $hit = 1;
 337                         };
 338                 };
 339                 if (defined $hit && defined $found) {
 340                         return undef;
 341                 }
 342                 if ($hit) {
 343                         $found = $i + 1;
 344                 }
 345         }
 346         return $found;
 347 }
 348
 349 # inserts string into trie and updates count for each character
 350 sub update_trie {
 351         my ($trie, $string) = @_;
 352         foreach (split //, $string) {
 353                 $trie = $trie->{$_} ||= {COUNT => 0};
 354                 $trie->{COUNT}++;
 355         }
 356 }
 357
 358 # returns an array of tuples (prefix, remainder)
 359 sub find_unique_prefixes {
 360         my @stuff = @_;
 361         my @return = ();
 362
 363         # any single prefix exceeding the soft limit is omitted
 364         # if any prefix exceeds the hard limit all are omitted
 365         # 0 indicates no limit
 366         my $soft_limit = 0;
 367         my $hard_limit = 3;
 368
 369         # build a trie modelling all possible options
 370         my %trie;
 371         foreach my $print (@stuff) {
 372                 if ((ref $print) eq 'ARRAY') {
 373                         $print = $print->[0];
 374                 }
 375                 elsif ((ref $print) eq 'HASH') {
 376                         $print = $print->{VALUE};
 377                 }
 378                 update_trie(\%trie, $print);
 379                 push @return, $print;
 380         }
 381
 382         # use the trie to find the unique prefixes
 383         for (my $i = 0; $i < @return; $i++) {
 384                 my $ret = $return[$i];
 385                 my @letters = split //, $ret;
 386                 my %search = %trie;
 387                 my ($prefix, $remainder);
 388                 my $j;
 389                 for ($j = 0; $j < @letters; $j++) {
 390                         my $letter = $letters[$j];
 391                         if ($search{$letter}{COUNT} == 1) {
 392                                 $prefix = substr $ret, 0, $j + 1;
 393                                 $remainder = substr $ret, $j + 1;
 394                                 last;
 395                         }
 396                         else {
 397                                 my $prefix = substr $ret, 0, $j;
 398                                 return ()
 399                                     if ($hard_limit && $j + 1 > $hard_limit);
 400                         }
 401                         %search = %{$search{$letter}};
 402                 }
 403                 if (ord($letters[0]) > 127 ||
 404                     ($soft_limit && $j + 1 > $soft_limit)) {
 405                         $prefix = undef;
 406                         $remainder = $ret;
 407                 }
 408                 $return[$i] = [$prefix, $remainder];
 409         }
 410         return @return;
 411 }
 412
 413 # filters out prefixes which have special meaning to list_and_choose()
 414 sub is_valid_prefix {
 415         my $prefix = shift;
 416         return (defined $prefix) &&
 417             !($prefix =~ /[\s,]/) && # separators
 418             !($prefix =~ /^-/) &&    # deselection
 419             !($prefix =~ /^\d+/) &&  # selection
 420             ($prefix ne '*') &&      # "all" wildcard
 421             ($prefix ne '?');        # prompt help
 422 }
 423
 424 # given a prefix/remainder tuple return a string with the prefix highlighted
 425 # for now use square brackets; later might use ANSI colors (underline, bold)
 426 sub highlight_prefix {
 427         my $prefix = shift;
 428         my $remainder = shift;
 429
 430         if (!defined $prefix) {
 431                 return $remainder;
 432         }
 433
 434         if (!is_valid_prefix($prefix)) {
 435                 return "$prefix$remainder";
 436         }
 437
 438         if (!$menu_use_color) {
 439                 return "[$prefix]$remainder";
 440         }
 441
 442         return "$prompt_color$prefix$normal_color$remainder";
 443 }
 444
 445 sub error_msg {
 446         print STDERR colored $error_color, @_;
 447 }
 448
 449 sub list_and_choose {
 450         my ($opts, @stuff) = @_;
 451         my (@chosen, @return);
 452         if (!@stuff) {
 453             return @return;
 454         }
 455         my $i;
 456         my @prefixes = find_unique_prefixes(@stuff) unless $opts->{LIST_ONLY};
 457
 458       TOPLOOP:
 459         while (1) {
 460                 my $last_lf = 0;
 461
 462                 if ($opts->{HEADER}) {
 463                         if (!$opts->{LIST_FLAT}) {
 464                                 print "     ";
 465                         }
 466                         print colored $header_color, "$opts->{HEADER}\n";
 467                 }
 468                 for ($i = 0; $i < @stuff; $i++) {
 469                         my $chosen = $chosen[$i] ? '*' : ' ';
 470                         my $print = $stuff[$i];
 471                         my $ref = ref $print;
 472                         my $highlighted = highlight_prefix(@{$prefixes[$i]})
 473                             if @prefixes;
 474                         if ($ref eq 'ARRAY') {
 475                                 $print = $highlighted || $print->[0];
 476                         }
 477                         elsif ($ref eq 'HASH') {
 478                                 my $value = $highlighted || $print->{VALUE};
 479                                 $print = sprintf($status_fmt,
 480                                     $print->{INDEX},
 481                                     $print->{FILE},
 482                                     $value);
 483                         }
 484                         else {
 485                                 $print = $highlighted || $print;
 486                         }
 487                         printf("%s%2d: %s", $chosen, $i+1, $print);
 488                         if (($opts->{LIST_FLAT}) &&
 489                             (($i + 1) % ($opts->{LIST_FLAT}))) {
 490                                 print "\t";
 491                                 $last_lf = 0;
 492                         }
 493                         else {
 494                                 print "\n";
 495                                 $last_lf = 1;
 496                         }
 497                 }
 498                 if (!$last_lf) {
 499                         print "\n";
 500                 }
 501
 502                 return if ($opts->{LIST_ONLY});
 503
 504                 print colored $prompt_color, $opts->{PROMPT};
 505                 if ($opts->{SINGLETON}) {
 506                         print "> ";
 507                 }
 508                 else {
 509                         print ">> ";
 510                 }
 511                 my $line = <STDIN>;
 512                 if (!$line) {
 513                         print "\n";
 514                         $opts->{ON_EOF}->() if $opts->{ON_EOF};
 515                         last;
 516                 }
 517                 chomp $line;
 518                 last if $line eq '';
 519                 if ($line eq '?') {
 520                         $opts->{SINGLETON} ?
 521                             singleton_prompt_help_cmd() :
 522                             prompt_help_cmd();
 523                         next TOPLOOP;
 524                 }
 525                 for my $choice (split(/[\s,]+/, $line)) {
 526                         my $choose = 1;
 527                         my ($bottom, $top);
 528
 529                         # Input that begins with '-'; unchoose
 530                         if ($choice =~ s/^-//) {
 531                                 $choose = 0;
 532                         }
 533                         # A range can be specified like 5-7 or 5-.
 534                         if ($choice =~ /^(\d+)-(\d*)$/) {
 535                                 ($bottom, $top) = ($1, length($2) ? $2 : 1 + @stuff);
 536                         }
 537                         elsif ($choice =~ /^\d+$/) {
 538                                 $bottom = $top = $choice;
 539                         }
 540                         elsif ($choice eq '*') {
 541                                 $bottom = 1;
 542                                 $top = 1 + @stuff;
 543                         }
 544                         else {
 545                                 $bottom = $top = find_unique($choice, @stuff);
 546                                 if (!defined $bottom) {
 547                                         error_msg sprintf(__("Huh (%s)?\n"), $choice);
 548                                         next TOPLOOP;
 549                                 }
 550                         }
 551                         if ($opts->{SINGLETON} && $bottom != $top) {
 552                                 error_msg sprintf(__("Huh (%s)?\n"), $choice);
 553                                 next TOPLOOP;
 554                         }
 555                         for ($i = $bottom-1; $i <= $top-1; $i++) {
 556                                 next if (@stuff <= $i || $i < 0);
 557                                 $chosen[$i] = $choose;
 558                         }
 559                 }
 560                 last if ($opts->{IMMEDIATE} || $line eq '*');
 561         }
 562         for ($i = 0; $i < @stuff; $i++) {
 563                 if ($chosen[$i]) {
 564                         push @return, $stuff[$i];
 565                 }
 566         }
 567         return @return;
 568 }
 569
 570 sub singleton_prompt_help_cmd {
 571         print colored $help_color, __ <<'EOF' ;
 572 Prompt help:
 573 1          - select a numbered item
 574 foo        - select item based on unique prefix
 575            - (empty) select nothing
 576 EOF
 577 }
 578
 579 sub prompt_help_cmd {
 580         print colored $help_color, __ <<'EOF' ;
 581 Prompt help:
 582 1          - select a single item
 583 3-5        - select a range of items
 584 2-3,6-9    - select multiple ranges
 585 foo        - select item based on unique prefix
 586 -...       - unselect specified items
 587 *          - choose all items
 588            - (empty) finish selecting
 589 EOF
 590 }
 591
 592 sub status_cmd {
 593         list_and_choose({ LIST_ONLY => 1, HEADER => $status_head },
 594                         list_modified());
 595         print "\n";
 596 }
 597
 598 sub say_n_paths {
 599         my $did = shift @_;
 600         my $cnt = scalar @_;
 601         if ($did eq 'added') {
 602                 printf(__n("added %d path\n", "added %d paths\n",
 603                            $cnt), $cnt);
 604         } elsif ($did eq 'updated') {
 605                 printf(__n("updated %d path\n", "updated %d paths\n",
 606                            $cnt), $cnt);
 607         } elsif ($did eq 'reverted') {
 608                 printf(__n("reverted %d path\n", "reverted %d paths\n",
 609                            $cnt), $cnt);
 610         } else {
 611                 printf(__n("touched %d path\n", "touched %d paths\n",
 612                            $cnt), $cnt);
 613         }
 614 }
 615
 616 sub update_cmd {
 617         my @mods = list_modified('file-only');
 618         return if (!@mods);
 619
 620         my @update = list_and_choose({ PROMPT => __('Update'),
 621                                        HEADER => $status_head, },
 622                                      @mods);
 623         if (@update) {
 624                 system(qw(git update-index --add --remove --),
 625                        map { $_->{VALUE} } @update);
 626                 say_n_paths('updated', @update);
 627         }
 628         print "\n";
 629 }
 630
 631 sub revert_cmd {
 632         my @update = list_and_choose({ PROMPT => __('Revert'),
 633                                        HEADER => $status_head, },
 634                                      list_modified());
 635         if (@update) {
 636                 if (is_initial_commit()) {
 637                         system(qw(git rm --cached),
 638                                 map { $_->{VALUE} } @update);
 639                 }
 640                 else {
 641                         my @lines = run_cmd_pipe(qw(git ls-tree HEAD --),
 642                                                  map { $_->{VALUE} } @update);
 643                         my $fh;
 644                         open $fh, '| git update-index --index-info'
 645                             or die;
 646                         for (@lines) {
 647                                 print $fh $_;
 648                         }
 649                         close($fh);
 650                         for (@update) {
 651                                 if ($_->{INDEX_ADDDEL} &&
 652                                     $_->{INDEX_ADDDEL} eq 'create') {
 653                                         system(qw(git update-index --force-remove --),
 654                                                $_->{VALUE});
 655                                         printf(__("note: %s is untracked now.\n"), $_->{VALUE});
 656                                 }
 657                         }
 658                 }
 659                 refresh();
 660                 say_n_paths('reverted', @update);
 661         }
 662         print "\n";
 663 }
 664
 665 sub add_untracked_cmd {
 666         my @add = list_and_choose({ PROMPT => __('Add untracked') },
 667                                   list_untracked());
 668         if (@add) {
 669                 system(qw(git update-index --add --), @add);
 670                 say_n_paths('added', @add);
 671         } else {
 672                 print __("No untracked files.\n");
 673         }
 674         print "\n";
 675 }
 676
 677 sub run_git_apply {
 678         my $cmd = shift;
 679         my $fh;
 680         open $fh, '| git ' . $cmd . " --allow-overlap";
 681         print $fh @_;
 682         return close $fh;
 683 }
 684
 685 sub parse_diff {
 686         my ($path) = @_;
 687         my @diff_cmd = split(" ", $patch_mode_flavour{DIFF});
 688         if (defined $diff_algorithm) {
 689                 splice @diff_cmd, 1, 0, "--diff-algorithm=${diff_algorithm}";
 690         }
 691         if (defined $patch_mode_revision) {
 692                 push @diff_cmd, get_diff_reference($patch_mode_revision);
 693         }
 694         my @diff = run_cmd_pipe("git", @diff_cmd, "--", $path);
 695         my @colored = ();
 696         if ($diff_use_color) {
 697                 my @display_cmd = ("git", @diff_cmd, qw(--color --), $path);
 698                 if (defined $diff_filter) {
 699                         # quotemeta is overkill, but sufficient for shell-quoting
 700                         my $diff = join(' ', map { quotemeta } @display_cmd);
 701                         @display_cmd = ("$diff | $diff_filter");
 702                 }
 703
 704                 @colored = run_cmd_pipe(@display_cmd);
 705         }
 706         my (@hunk) = { TEXT => [], DISPLAY => [], TYPE => 'header' };
 707
 708         for (my $i = 0; $i < @diff; $i++) {
 709                 if ($diff[$i] =~ /^@@ /) {
 710                         push @hunk, { TEXT => [], DISPLAY => [],
 711                                 TYPE => 'hunk' };
 712                 }
 713                 push @{$hunk[-1]{TEXT}}, $diff[$i];
 714                 push @{$hunk[-1]{DISPLAY}},
 715                         (@colored ? $colored[$i] : $diff[$i]);
 716         }
 717         return @hunk;
 718 }
 719
 720 sub parse_diff_header {
 721         my $src = shift;
 722
 723         my $head = { TEXT => [], DISPLAY => [], TYPE => 'header' };
 724         my $mode = { TEXT => [], DISPLAY => [], TYPE => 'mode' };
 725         my $deletion = { TEXT => [], DISPLAY => [], TYPE => 'deletion' };
 726
 727         for (my $i = 0; $i < @{$src->{TEXT}}; $i++) {
 728                 my $dest =
 729                    $src->{TEXT}->[$i] =~ /^(old|new) mode (\d+)$/ ? $mode :
 730                    $src->{TEXT}->[$i] =~ /^deleted file/ ? $deletion :
 731                    $head;
 732                 push @{$dest->{TEXT}}, $src->{TEXT}->[$i];
 733                 push @{$dest->{DISPLAY}}, $src->{DISPLAY}->[$i];
 734         }
 735         return ($head, $mode, $deletion);
 736 }
 737
 738 sub hunk_splittable {
 739         my ($text) = @_;
 740
 741         my @s = split_hunk($text);
 742         return (1 < @s);
 743 }
 744
 745 sub parse_hunk_header {
 746         my ($line) = @_;
 747         my ($o_ofs, $o_cnt, $n_ofs, $n_cnt) =
 748             $line =~ /^@@ -(\d+)(?:,(\d+))? \+(\d+)(?:,(\d+))? @@/;
 749         $o_cnt = 1 unless defined $o_cnt;
 750         $n_cnt = 1 unless defined $n_cnt;
 751         return ($o_ofs, $o_cnt, $n_ofs, $n_cnt);
 752 }
 753
 754 sub format_hunk_header {
 755         my ($o_ofs, $o_cnt, $n_ofs, $n_cnt) = @_;
 756         return ("@@ -$o_ofs" .
 757                 (($o_cnt != 1) ? ",$o_cnt" : '') .
 758                 " +$n_ofs" .
 759                 (($n_cnt != 1) ? ",$n_cnt" : '') .
 760                 " @@\n");
 761 }
 762
 763 sub split_hunk {
 764         my ($text, $display) = @_;
 765         my @split = ();
 766         if (!defined $display) {
 767                 $display = $text;
 768         }
 769         # If there are context lines in the middle of a hunk,
 770         # it can be split, but we would need to take care of
 771         # overlaps later.
 772
 773         my ($o_ofs, undef, $n_ofs) = parse_hunk_header($text->[0]);
 774         my $hunk_start = 1;
 775
 776       OUTER:
 777         while (1) {
 778                 my $next_hunk_start = undef;
 779                 my $i = $hunk_start - 1;
 780                 my $this = +{
 781                         TEXT => [],
 782                         DISPLAY => [],
 783                         TYPE => 'hunk',
 784                         OLD => $o_ofs,
 785                         NEW => $n_ofs,
 786                         OCNT => 0,
 787                         NCNT => 0,
 788                         ADDDEL => 0,
 789                         POSTCTX => 0,
 790                         USE => undef,
 791                 };
 792
 793                 while (++$i < @$text) {
 794                         my $line = $text->[$i];
 795                         my $display = $display->[$i];
 796                         if ($line =~ /^\\/) {
 797                                 push @{$this->{TEXT}}, $line;
 798                                 push @{$this->{DISPLAY}}, $display;
 799                                 next;
 800                         }
 801                         if ($line =~ /^ /) {
 802                                 if ($this->{ADDDEL} &&
 803                                     !defined $next_hunk_start) {
 804                                         # We have seen leading context and
 805                                         # adds/dels and then here is another
 806                                         # context, which is trailing for this
 807                                         # split hunk and leading for the next
 808                                         # one.
 809                                         $next_hunk_start = $i;
 810                                 }
 811                                 push @{$this->{TEXT}}, $line;
 812                                 push @{$this->{DISPLAY}}, $display;
 813                                 $this->{OCNT}++;
 814                                 $this->{NCNT}++;
 815                                 if (defined $next_hunk_start) {
 816                                         $this->{POSTCTX}++;
 817                                 }
 818                                 next;
 819                         }
 820
 821                         # add/del
 822                         if (defined $next_hunk_start) {
 823                                 # We are done with the current hunk and
 824                                 # this is the first real change for the
 825                                 # next split one.
 826                                 $hunk_start = $next_hunk_start;
 827                                 $o_ofs = $this->{OLD} + $this->{OCNT};
 828                                 $n_ofs = $this->{NEW} + $this->{NCNT};
 829                                 $o_ofs -= $this->{POSTCTX};
 830                                 $n_ofs -= $this->{POSTCTX};
 831                                 push @split, $this;
 832                                 redo OUTER;
 833                         }
 834                         push @{$this->{TEXT}}, $line;
 835                         push @{$this->{DISPLAY}}, $display;
 836                         $this->{ADDDEL}++;
 837                         if ($line =~ /^-/) {
 838                                 $this->{OCNT}++;
 839                         }
 840                         else {
 841                                 $this->{NCNT}++;
 842                         }
 843                 }
 844
 845                 push @split, $this;
 846                 last;
 847         }
 848
 849         for my $hunk (@split) {
 850                 $o_ofs = $hunk->{OLD};
 851                 $n_ofs = $hunk->{NEW};
 852                 my $o_cnt = $hunk->{OCNT};
 853                 my $n_cnt = $hunk->{NCNT};
 854
 855                 my $head = format_hunk_header($o_ofs, $o_cnt, $n_ofs, $n_cnt);
 856                 my $display_head = $head;
 857                 unshift @{$hunk->{TEXT}}, $head;
 858                 if ($diff_use_color) {
 859                         $display_head = colored($fraginfo_color, $head);
 860                 }
 861                 unshift @{$hunk->{DISPLAY}}, $display_head;
 862         }
 863         return @split;
 864 }
 865
 866 sub find_last_o_ctx {
 867         my ($it) = @_;
 868         my $text = $it->{TEXT};
 869         my ($o_ofs, $o_cnt) = parse_hunk_header($text->[0]);
 870         my $i = @{$text};
 871         my $last_o_ctx = $o_ofs + $o_cnt;
 872         while (0 < --$i) {
 873                 my $line = $text->[$i];
 874                 if ($line =~ /^ /) {
 875                         $last_o_ctx--;
 876                         next;
 877                 }
 878                 last;
 879         }
 880         return $last_o_ctx;
 881 }
 882
 883 sub merge_hunk {
 884         my ($prev, $this) = @_;
 885         my ($o0_ofs, $o0_cnt, $n0_ofs, $n0_cnt) =
 886             parse_hunk_header($prev->{TEXT}[0]);
 887         my ($o1_ofs, $o1_cnt, $n1_ofs, $n1_cnt) =
 888             parse_hunk_header($this->{TEXT}[0]);
 889
 890         my (@line, $i, $ofs, $o_cnt, $n_cnt);
 891         $ofs = $o0_ofs;
 892         $o_cnt = $n_cnt = 0;
 893         for ($i = 1; $i < @{$prev->{TEXT}}; $i++) {
 894                 my $line = $prev->{TEXT}[$i];
 895                 if ($line =~ /^[+\\]/) {
 896                         $n_cnt++ if ($line =~ /^\+/);
 897                         push @line, $line;
 898                         next;
 899                 }
 900
 901                 last if ($o1_ofs <= $ofs);
 902
 903                 $o_cnt++;
 904                 $ofs++;
 905                 if ($line =~ /^ /) {
 906                         $n_cnt++;
 907                 }
 908                 push @line, $line;
 909         }
 910
 911         for ($i = 1; $i < @{$this->{TEXT}}; $i++) {
 912                 my $line = $this->{TEXT}[$i];
 913                 if ($line =~ /^[+\\]/) {
 914                         $n_cnt++ if ($line =~ /^\+/);
 915                         push @line, $line;
 916                         next;
 917                 }
 918                 $ofs++;
 919                 $o_cnt++;
 920                 if ($line =~ /^ /) {
 921                         $n_cnt++;
 922                 }
 923                 push @line, $line;
 924         }
 925         my $head = format_hunk_header($o0_ofs, $o_cnt, $n0_ofs, $n_cnt);
 926         @{$prev->{TEXT}} = ($head, @line);
 927 }
 928
 929 sub coalesce_overlapping_hunks {
 930         my (@in) = @_;
 931         my @out = ();
 932
 933         my ($last_o_ctx, $last_was_dirty);
 934         my $ofs_delta = 0;
 935
 936         for (@in) {
 937                 if ($_->{TYPE} ne 'hunk') {
 938                         push @out, $_;
 939                         next;
 940                 }
 941                 my $text = $_->{TEXT};
 942                 my ($o_ofs, $o_cnt, $n_ofs, $n_cnt) =
 943                                                 parse_hunk_header($text->[0]);
 944                 unless ($_->{USE}) {
 945                         $ofs_delta += $o_cnt - $n_cnt;
 946                         # If this hunk has been edited then subtract
 947                         # the delta that is due to the edit.
 948                         $_->{OFS_DELTA} and $ofs_delta -= $_->{OFS_DELTA};
 949                         next;
 950                 }
 951                 if ($ofs_delta) {
 952                         $n_ofs += $ofs_delta;
 953                         $_->{TEXT}->[0] = format_hunk_header($o_ofs, $o_cnt,
 954                                                              $n_ofs, $n_cnt);
 955                 }
 956                 # If this hunk was edited then adjust the offset delta
 957                 # to reflect the edit.
 958                 $_->{OFS_DELTA} and $ofs_delta += $_->{OFS_DELTA};
 959                 if (defined $last_o_ctx &&
 960                     $o_ofs <= $last_o_ctx &&
 961                     !$_->{DIRTY} &&
 962                     !$last_was_dirty) {
 963                         merge_hunk($out[-1], $_);
 964                 }
 965                 else {
 966                         push @out, $_;
 967                 }
 968                 $last_o_ctx = find_last_o_ctx($out[-1]);
 969                 $last_was_dirty = $_->{DIRTY};
 970         }
 971         return @out;
 972 }
 973
 974 sub reassemble_patch {
 975         my $head = shift;
 976         my @patch;
 977
 978         # Include everything in the header except the beginning of the diff.
 979         push @patch, (grep { !/^[-+]{3}/ } @$head);
 980
 981         # Then include any headers from the hunk lines, which must
 982         # come before any actual hunk.
 983         while (@_ && $_[0] !~ /^@/) {
 984                 push @patch, shift;
 985         }
 986
 987         # Then begin the diff.
 988         push @patch, grep { /^[-+]{3}/ } @$head;
 989
 990         # And then the actual hunks.
 991         push @patch, @_;
 992
 993         return @patch;
 994 }
 995
 996 sub color_diff {
 997         return map {
 998                 colored((/^@/  ? $fraginfo_color :
 999                          /^\+/ ? $diff_new_color :
1000                          /^-/  ? $diff_old_color :
1001                          $diff_plain_color),
1002                         $_);
1003         } @_;
1004 }
1005
1006 my %edit_hunk_manually_modes = (
1007         stage => N__(
1008 "If the patch applies cleanly, the edited hunk will immediately be
1009 marked for staging."),
1010         stash => N__(
1011 "If the patch applies cleanly, the edited hunk will immediately be
1012 marked for stashing."),
1013         reset_head => N__(
1014 "If the patch applies cleanly, the edited hunk will immediately be
1015 marked for unstaging."),
1016         reset_nothead => N__(
1017 "If the patch applies cleanly, the edited hunk will immediately be
1018 marked for applying."),
1019         checkout_index => N__(
1020 "If the patch applies cleanly, the edited hunk will immediately be
1021 marked for discarding."),
1022         checkout_head => N__(
1023 "If the patch applies cleanly, the edited hunk will immediately be
1024 marked for discarding."),
1025         checkout_nothead => N__(
1026 "If the patch applies cleanly, the edited hunk will immediately be
1027 marked for applying."),
1028 );
1029
1030 sub recount_edited_hunk {
1031         local $_;
1032         my ($oldtext, $newtext) = @_;
1033         my ($o_cnt, $n_cnt) = (0, 0);
1034         for (@{$newtext}[1..$#{$newtext}]) {
1035                 my $mode = substr($_, 0, 1);
1036                 if ($mode eq '-') {
1037                         $o_cnt++;
1038                 } elsif ($mode eq '+') {
1039                         $n_cnt++;
1040                 } elsif ($mode eq ' ') {
1041                         $o_cnt++;
1042                         $n_cnt++;
1043                 }
1044         }
1045         my ($o_ofs, undef, $n_ofs, undef) =
1046                                         parse_hunk_header($newtext->[0]);
1047         $newtext->[0] = format_hunk_header($o_ofs, $o_cnt, $n_ofs, $n_cnt);
1048         my (undef, $orig_o_cnt, undef, $orig_n_cnt) =
1049                                         parse_hunk_header($oldtext->[0]);
1050         # Return the change in the number of lines inserted by this hunk
1051         return $orig_o_cnt - $orig_n_cnt - $o_cnt + $n_cnt;
1052 }
1053
1054 sub edit_hunk_manually {
1055         my ($oldtext) = @_;
1056
1057         my $hunkfile = $repo->repo_path . "/addp-hunk-edit.diff";
1058         my $fh;
1059         open $fh, '>', $hunkfile
1060                 or die sprintf(__("failed to open hunk edit file for writing: %s"), $!);
1061         print $fh Git::comment_lines __("Manual hunk edit mode -- see bottom for a quick guide.\n");
1062         print $fh @$oldtext;
1063         my $is_reverse = $patch_mode_flavour{IS_REVERSE};
1064         my ($remove_plus, $remove_minus) = $is_reverse ? ('-', '+') : ('+', '-');
1065         my $comment_line_char = Git::get_comment_line_char;
1066         print $fh Git::comment_lines sprintf(__ <<EOF, $remove_minus, $remove_plus, $comment_line_char),
1067 ---
1068 To remove '%s' lines, make them ' ' lines (context).
1069 To remove '%s' lines, delete them.
1070 Lines starting with %s will be removed.
1071 EOF
1072 __($edit_hunk_manually_modes{$patch_mode}),
1073 # TRANSLATORS: 'it' refers to the patch mentioned in the previous messages.
1074 __ <<EOF2 ;
1075 If it does not apply cleanly, you will be given an opportunity to
1076 edit again.  If all lines of the hunk are removed, then the edit is
1077 aborted and the hunk is left unchanged.
1078 EOF2
1079         close $fh;
1080
1081         chomp(my $editor = run_cmd_pipe(qw(git var GIT_EDITOR)));
1082         system('sh', '-c', $editor.' "$@"', $editor, $hunkfile);
1083
1084         if ($? != 0) {
1085                 return undef;
1086         }
1087
1088         open $fh, '<', $hunkfile
1089                 or die sprintf(__("failed to open hunk edit file for reading: %s"), $!);
1090         my @newtext = grep { !/^\Q$comment_line_char\E/ } <$fh>;
1091         close $fh;
1092         unlink $hunkfile;
1093
1094         # Abort if nothing remains
1095         if (!grep { /\S/ } @newtext) {
1096                 return undef;
1097         }
1098
1099         # Reinsert the first hunk header if the user accidentally deleted it
1100         if ($newtext[0] !~ /^@/) {
1101                 unshift @newtext, $oldtext->[0];
1102         }
1103         return \@newtext;
1104 }
1105
1106 sub diff_applies {
1107         return run_git_apply($patch_mode_flavour{APPLY_CHECK} . ' --check',
1108                              map { @{$_->{TEXT}} } @_);
1109 }
1110
1111 sub _restore_terminal_and_die {
1112         ReadMode 'restore';
1113         print "\n";
1114         exit 1;
1115 }
1116
1117 sub prompt_single_character {
1118         if ($use_readkey) {
1119                 local $SIG{TERM} = \&_restore_terminal_and_die;
1120                 local $SIG{INT} = \&_restore_terminal_and_die;
1121                 ReadMode 'cbreak';
1122                 my $key = ReadKey 0;
1123                 ReadMode 'restore';
1124                 if ($use_termcap and $key eq "\e") {
1125                         while (!defined $term_escapes{$key}) {
1126                                 my $next = ReadKey 0.5;
1127                                 last if (!defined $next);
1128                                 $key .= $next;
1129                         }
1130                         $key =~ s/\e/^[/;
1131                 }
1132                 print "$key" if defined $key;
1133                 print "\n";
1134                 return $key;
1135         } else {
1136                 return <STDIN>;
1137         }
1138 }
1139
1140 sub prompt_yesno {
1141         my ($prompt) = @_;
1142         while (1) {
1143                 print colored $prompt_color, $prompt;
1144                 my $line = prompt_single_character;
1145                 return undef unless defined $line;
1146                 return 0 if $line =~ /^n/i;
1147                 return 1 if $line =~ /^y/i;
1148         }
1149 }
1150
1151 sub edit_hunk_loop {
1152         my ($head, $hunks, $ix) = @_;
1153         my $hunk = $hunks->[$ix];
1154         my $text = $hunk->{TEXT};
1155
1156         while (1) {
1157                 my $newtext = edit_hunk_manually($text);
1158                 if (!defined $newtext) {
1159                         return undef;
1160                 }
1161                 my $newhunk = {
1162                         TEXT => $newtext,
1163                         TYPE => $hunk->{TYPE},
1164                         USE => 1,
1165                         DIRTY => 1,
1166                 };
1167                 $newhunk->{OFS_DELTA} = recount_edited_hunk($text, $newtext);
1168                 # If this hunk has already been edited then add the
1169                 # offset delta of the previous edit to get the real
1170                 # delta from the original unedited hunk.
1171                 $hunk->{OFS_DELTA} and
1172                                 $newhunk->{OFS_DELTA} += $hunk->{OFS_DELTA};
1173                 if (diff_applies($head,
1174                                  @{$hunks}[0..$ix-1],
1175                                  $newhunk,
1176                                  @{$hunks}[$ix+1..$#{$hunks}])) {
1177                         $newhunk->{DISPLAY} = [color_diff(@{$newtext})];
1178                         return $newhunk;
1179                 }
1180                 else {
1181                         prompt_yesno(
1182                                 # TRANSLATORS: do not translate [y/n]
1183                                 # The program will only accept that input
1184                                 # at this point.
1185                                 # Consider translating (saying "no" discards!) as
1186                                 # (saying "n" for "no" discards!) if the translation
1187                                 # of the word "no" does not start with n.
1188                                 __('Your edited hunk does not apply. Edit again '
1189                                    . '(saying "no" discards!) [y/n]? ')
1190                                 ) or return undef;
1191                 }
1192         }
1193 }
1194
1195 my %help_patch_modes = (
1196         stage => N__(
1197 "y - stage this hunk
1198 n - do not stage this hunk
1199 q - quit; do not stage this hunk or any of the remaining ones
1200 a - stage this hunk and all later hunks in the file
1201 d - do not stage this hunk or any of the later hunks in the file"),
1202         stash => N__(
1203 "y - stash this hunk
1204 n - do not stash this hunk
1205 q - quit; do not stash this hunk or any of the remaining ones
1206 a - stash this hunk and all later hunks in the file
1207 d - do not stash this hunk or any of the later hunks in the file"),
1208         reset_head => N__(
1209 "y - unstage this hunk
1210 n - do not unstage this hunk
1211 q - quit; do not unstage this hunk or any of the remaining ones
1212 a - unstage this hunk and all later hunks in the file
1213 d - do not unstage this hunk or any of the later hunks in the file"),
1214         reset_nothead => N__(
1215 "y - apply this hunk to index
1216 n - do not apply this hunk to index
1217 q - quit; do not apply this hunk or any of the remaining ones
1218 a - apply this hunk and all later hunks in the file
1219 d - do not apply this hunk or any of the later hunks in the file"),
1220         checkout_index => N__(
1221 "y - discard this hunk from worktree
1222 n - do not discard this hunk from worktree
1223 q - quit; do not discard this hunk or any of the remaining ones
1224 a - discard this hunk and all later hunks in the file
1225 d - do not discard this hunk or any of the later hunks in the file"),
1226         checkout_head => N__(
1227 "y - discard this hunk from index and worktree
1228 n - do not discard this hunk from index and worktree
1229 q - quit; do not discard this hunk or any of the remaining ones
1230 a - discard this hunk and all later hunks in the file
1231 d - do not discard this hunk or any of the later hunks in the file"),
1232         checkout_nothead => N__(
1233 "y - apply this hunk to index and worktree
1234 n - do not apply this hunk to index and worktree
1235 q - quit; do not apply this hunk or any of the remaining ones
1236 a - apply this hunk and all later hunks in the file
1237 d - do not apply this hunk or any of the later hunks in the file"),
1238 );
1239
1240 sub help_patch_cmd {
1241         local $_;
1242         my $other = $_[0] . ",?";
1243         print colored $help_color, __($help_patch_modes{$patch_mode}), "\n",
1244                 map { "$_\n" } grep {
1245                         my $c = quotemeta(substr($_, 0, 1));
1246                         $other =~ /,$c/
1247                 } split "\n", __ <<EOF ;
1248 g - select a hunk to go to
1249 / - search for a hunk matching the given regex
1250 j - leave this hunk undecided, see next undecided hunk
1251 J - leave this hunk undecided, see next hunk
1252 k - leave this hunk undecided, see previous undecided hunk
1253 K - leave this hunk undecided, see previous hunk
1254 s - split the current hunk into smaller hunks
1255 e - manually edit the current hunk
1256 ? - print help
1257 EOF
1258 }
1259
1260 sub apply_patch {
1261         my $cmd = shift;
1262         my $ret = run_git_apply $cmd, @_;
1263         if (!$ret) {
1264                 print STDERR @_;
1265         }
1266         return $ret;
1267 }
1268
1269 sub apply_patch_for_checkout_commit {
1270         my $reverse = shift;
1271         my $applies_index = run_git_apply 'apply '.$reverse.' --cached --check', @_;
1272         my $applies_worktree = run_git_apply 'apply '.$reverse.' --check', @_;
1273
1274         if ($applies_worktree && $applies_index) {
1275                 run_git_apply 'apply '.$reverse.' --cached', @_;
1276                 run_git_apply 'apply '.$reverse, @_;
1277                 return 1;
1278         } elsif (!$applies_index) {
1279                 print colored $error_color, __("The selected hunks do not apply to the index!\n");
1280                 if (prompt_yesno __("Apply them to the worktree anyway? ")) {
1281                         return run_git_apply 'apply '.$reverse, @_;
1282                 } else {
1283                         print colored $error_color, __("Nothing was applied.\n");
1284                         return 0;
1285                 }
1286         } else {
1287                 print STDERR @_;
1288                 return 0;
1289         }
1290 }
1291
1292 sub patch_update_cmd {
1293         my @all_mods = list_modified($patch_mode_flavour{FILTER});
1294         error_msg sprintf(__("ignoring unmerged: %s\n"), $_->{VALUE})
1295                 for grep { $_->{UNMERGED} } @all_mods;
1296         @all_mods = grep { !$_->{UNMERGED} } @all_mods;
1297
1298         my @mods = grep { !($_->{BINARY}) } @all_mods;
1299         my @them;
1300
1301         if (!@mods) {
1302                 if (@all_mods) {
1303                         print STDERR __("Only binary files changed.\n");
1304                 } else {
1305                         print STDERR __("No changes.\n");
1306                 }
1307                 return 0;
1308         }
1309         if ($patch_mode_only) {
1310                 @them = @mods;
1311         }
1312         else {
1313                 @them = list_and_choose({ PROMPT => __('Patch update'),
1314                                           HEADER => $status_head, },
1315                                         @mods);
1316         }
1317         for (@them) {
1318                 return 0 if patch_update_file($_->{VALUE});
1319         }
1320 }
1321
1322 # Generate a one line summary of a hunk.
1323 sub summarize_hunk {
1324         my $rhunk = shift;
1325         my $summary = $rhunk->{TEXT}[0];
1326
1327         # Keep the line numbers, discard extra context.
1328         $summary =~ s/@@(.*?)@@.*/$1 /s;
1329         $summary .= " " x (20 - length $summary);
1330
1331         # Add some user context.
1332         for my $line (@{$rhunk->{TEXT}}) {
1333                 if ($line =~ m/^[+-].*\w/) {
1334                         $summary .= $line;
1335                         last;
1336                 }
1337         }
1338
1339         chomp $summary;
1340         return substr($summary, 0, 80) . "\n";
1341 }
1342
1343
1344 # Print a one-line summary of each hunk in the array ref in
1345 # the first argument, starting with the index in the 2nd.
1346 sub display_hunks {
1347         my ($hunks, $i) = @_;
1348         my $ctr = 0;
1349         $i ||= 0;
1350         for (; $i < @$hunks && $ctr < 20; $i++, $ctr++) {
1351                 my $status = " ";
1352                 if (defined $hunks->[$i]{USE}) {
1353                         $status = $hunks->[$i]{USE} ? "+" : "-";
1354                 }
1355                 printf "%s%2d: %s",
1356                         $status,
1357                         $i + 1,
1358                         summarize_hunk($hunks->[$i]);
1359         }
1360         return $i;
1361 }
1362
1363 my %patch_update_prompt_modes = (
1364         stage => {
1365                 mode => N__("Stage mode change [y,n,q,a,d%s,?]? "),
1366                 deletion => N__("Stage deletion [y,n,q,a,d%s,?]? "),
1367                 hunk => N__("Stage this hunk [y,n,q,a,d%s,?]? "),
1368         },
1369         stash => {
1370                 mode => N__("Stash mode change [y,n,q,a,d%s,?]? "),
1371                 deletion => N__("Stash deletion [y,n,q,a,d%s,?]? "),
1372                 hunk => N__("Stash this hunk [y,n,q,a,d%s,?]? "),
1373         },
1374         reset_head => {
1375                 mode => N__("Unstage mode change [y,n,q,a,d%s,?]? "),
1376                 deletion => N__("Unstage deletion [y,n,q,a,d%s,?]? "),
1377                 hunk => N__("Unstage this hunk [y,n,q,a,d%s,?]? "),
1378         },
1379         reset_nothead => {
1380                 mode => N__("Apply mode change to index [y,n,q,a,d%s,?]? "),
1381                 deletion => N__("Apply deletion to index [y,n,q,a,d%s,?]? "),
1382                 hunk => N__("Apply this hunk to index [y,n,q,a,d%s,?]? "),
1383         },
1384         checkout_index => {
1385                 mode => N__("Discard mode change from worktree [y,n,q,a,d%s,?]? "),
1386                 deletion => N__("Discard deletion from worktree [y,n,q,a,d%s,?]? "),
1387                 hunk => N__("Discard this hunk from worktree [y,n,q,a,d%s,?]? "),
1388         },
1389         checkout_head => {
1390                 mode => N__("Discard mode change from index and worktree [y,n,q,a,d%s,?]? "),
1391                 deletion => N__("Discard deletion from index and worktree [y,n,q,a,d%s,?]? "),
1392                 hunk => N__("Discard this hunk from index and worktree [y,n,q,a,d%s,?]? "),
1393         },
1394         checkout_nothead => {
1395                 mode => N__("Apply mode change to index and worktree [y,n,q,a,d%s,?]? "),
1396                 deletion => N__("Apply deletion to index and worktree [y,n,q,a,d%s,?]? "),
1397                 hunk => N__("Apply this hunk to index and worktree [y,n,q,a,d%s,?]? "),
1398         },
1399 );
1400
1401 sub patch_update_file {
1402         my $quit = 0;
1403         my ($ix, $num);
1404         my $path = shift;
1405         my ($head, @hunk) = parse_diff($path);
1406         ($head, my $mode, my $deletion) = parse_diff_header($head);
1407         for (@{$head->{DISPLAY}}) {
1408                 print;
1409         }
1410
1411         if (@{$mode->{TEXT}}) {
1412                 unshift @hunk, $mode;
1413         }
1414         if (@{$deletion->{TEXT}}) {
1415                 foreach my $hunk (@hunk) {
1416                         push @{$deletion->{TEXT}}, @{$hunk->{TEXT}};
1417                         push @{$deletion->{DISPLAY}}, @{$hunk->{DISPLAY}};
1418                 }
1419                 @hunk = ($deletion);
1420         }
1421
1422         $num = scalar @hunk;
1423         $ix = 0;
1424
1425         while (1) {
1426                 my ($prev, $next, $other, $undecided, $i);
1427                 $other = '';
1428
1429                 if ($num <= $ix) {
1430                         $ix = 0;
1431                 }
1432                 for ($i = 0; $i < $ix; $i++) {
1433                         if (!defined $hunk[$i]{USE}) {
1434                                 $prev = 1;
1435                                 $other .= ',k';
1436                                 last;
1437                         }
1438                 }
1439                 if ($ix) {
1440                         $other .= ',K';
1441                 }
1442                 for ($i = $ix + 1; $i < $num; $i++) {
1443                         if (!defined $hunk[$i]{USE}) {
1444                                 $next = 1;
1445                                 $other .= ',j';
1446                                 last;
1447                         }
1448                 }
1449                 if ($ix < $num - 1) {
1450                         $other .= ',J';
1451                 }
1452                 if ($num > 1) {
1453                         $other .= ',g,/';
1454                 }
1455                 for ($i = 0; $i < $num; $i++) {
1456                         if (!defined $hunk[$i]{USE}) {
1457                                 $undecided = 1;
1458                                 last;
1459                         }
1460                 }
1461                 last if (!$undecided);
1462
1463                 if ($hunk[$ix]{TYPE} eq 'hunk' &&
1464                     hunk_splittable($hunk[$ix]{TEXT})) {
1465                         $other .= ',s';
1466                 }
1467                 if ($hunk[$ix]{TYPE} eq 'hunk') {
1468                         $other .= ',e';
1469                 }
1470                 for (@{$hunk[$ix]{DISPLAY}}) {
1471                         print;
1472                 }
1473                 print colored $prompt_color,
1474                         sprintf(__($patch_update_prompt_modes{$patch_mode}{$hunk[$ix]{TYPE}}), $other);
1475
1476                 my $line = prompt_single_character;
1477                 last unless defined $line;
1478                 if ($line) {
1479                         if ($line =~ /^y/i) {
1480                                 $hunk[$ix]{USE} = 1;
1481                         }
1482                         elsif ($line =~ /^n/i) {
1483                                 $hunk[$ix]{USE} = 0;
1484                         }
1485                         elsif ($line =~ /^a/i) {
1486                                 while ($ix < $num) {
1487                                         if (!defined $hunk[$ix]{USE}) {
1488                                                 $hunk[$ix]{USE} = 1;
1489                                         }
1490                                         $ix++;
1491                                 }
1492                                 next;
1493                         }
1494                         elsif ($line =~ /^g(.*)/) {
1495                                 my $response = $1;
1496                                 unless ($other =~ /g/) {
1497                                         error_msg __("No other hunks to goto\n");
1498                                         next;
1499                                 }
1500                                 my $no = $ix > 10 ? $ix - 10 : 0;
1501                                 while ($response eq '') {
1502                                         $no = display_hunks(\@hunk, $no);
1503                                         if ($no < $num) {
1504                                                 print __("go to which hunk (<ret> to see more)? ");
1505                                         } else {
1506                                                 print __("go to which hunk? ");
1507                                         }
1508                                         $response = <STDIN>;
1509                                         if (!defined $response) {
1510                                                 $response = '';
1511                                         }
1512                                         chomp $response;
1513                                 }
1514                                 if ($response !~ /^\s*\d+\s*$/) {
1515                                         error_msg sprintf(__("Invalid number: '%s'\n"),
1516                                                              $response);
1517                                 } elsif (0 < $response && $response <= $num) {
1518                                         $ix = $response - 1;
1519                                 } else {
1520                                         error_msg sprintf(__n("Sorry, only %d hunk available.\n",
1521                                                               "Sorry, only %d hunks available.\n", $num), $num);
1522                                 }
1523                                 next;
1524                         }
1525                         elsif ($line =~ /^d/i) {
1526                                 while ($ix < $num) {
1527                                         if (!defined $hunk[$ix]{USE}) {
1528                                                 $hunk[$ix]{USE} = 0;
1529                                         }
1530                                         $ix++;
1531                                 }
1532                                 next;
1533                         }
1534                         elsif ($line =~ /^q/i) {
1535                                 for ($i = 0; $i < $num; $i++) {
1536                                         if (!defined $hunk[$i]{USE}) {
1537                                                 $hunk[$i]{USE} = 0;
1538                                         }
1539                                 }
1540                                 $quit = 1;
1541                                 last;
1542                         }
1543                         elsif ($line =~ m|^/(.*)|) {
1544                                 my $regex = $1;
1545                                 unless ($other =~ m|/|) {
1546                                         error_msg __("No other hunks to search\n");
1547                                         next;
1548                                 }
1549                                 if ($1 eq "") {
1550                                         print colored $prompt_color, __("search for regex? ");
1551                                         $regex = <STDIN>;
1552                                         if (defined $regex) {
1553                                                 chomp $regex;
1554                                         }
1555                                 }
1556                                 my $search_string;
1557                                 eval {
1558                                         $search_string = qr{$regex}m;
1559                                 };
1560                                 if ($@) {
1561                                         my ($err,$exp) = ($@, $1);
1562                                         $err =~ s/ at .*git-add--interactive line \d+, <STDIN> line \d+.*$//;
1563                                         error_msg sprintf(__("Malformed search regexp %s: %s\n"), $exp, $err);
1564                                         next;
1565                                 }
1566                                 my $iy = $ix;
1567                                 while (1) {
1568                                         my $text = join ("", @{$hunk[$iy]{TEXT}});
1569                                         last if ($text =~ $search_string);
1570                                         $iy++;
1571                                         $iy = 0 if ($iy >= $num);
1572                                         if ($ix == $iy) {
1573                                                 error_msg __("No hunk matches the given pattern\n");
1574                                                 last;
1575                                         }
1576                                 }
1577                                 $ix = $iy;
1578                                 next;
1579                         }
1580                         elsif ($line =~ /^K/) {
1581                                 if ($other =~ /K/) {
1582                                         $ix--;
1583                                 }
1584                                 else {
1585                                         error_msg __("No previous hunk\n");
1586                                 }
1587                                 next;
1588                         }
1589                         elsif ($line =~ /^J/) {
1590                                 if ($other =~ /J/) {
1591                                         $ix++;
1592                                 }
1593                                 else {
1594                                         error_msg __("No next hunk\n");
1595                                 }
1596                                 next;
1597                         }
1598                         elsif ($line =~ /^k/) {
1599                                 if ($other =~ /k/) {
1600                                         while (1) {
1601                                                 $ix--;
1602                                                 last if (!$ix ||
1603                                                          !defined $hunk[$ix]{USE});
1604                                         }
1605                                 }
1606                                 else {
1607                                         error_msg __("No previous hunk\n");
1608                                 }
1609                                 next;
1610                         }
1611                         elsif ($line =~ /^j/) {
1612                                 if ($other !~ /j/) {
1613                                         error_msg __("No next hunk\n");
1614                                         next;
1615                                 }
1616                         }
1617                         elsif ($line =~ /^s/) {
1618                                 unless ($other =~ /s/) {
1619                                         error_msg __("Sorry, cannot split this hunk\n");
1620                                         next;
1621                                 }
1622                                 my @split = split_hunk($hunk[$ix]{TEXT}, $hunk[$ix]{DISPLAY});
1623                                 if (1 < @split) {
1624                                         print colored $header_color, sprintf(
1625                                                 __n("Split into %d hunk.\n",
1626                                                     "Split into %d hunks.\n",
1627                                                     scalar(@split)), scalar(@split));
1628                                 }
1629                                 splice (@hunk, $ix, 1, @split);
1630                                 $num = scalar @hunk;
1631                                 next;
1632                         }
1633                         elsif ($line =~ /^e/) {
1634                                 unless ($other =~ /e/) {
1635                                         error_msg __("Sorry, cannot edit this hunk\n");
1636                                         next;
1637                                 }
1638                                 my $newhunk = edit_hunk_loop($head, \@hunk, $ix);
1639                                 if (defined $newhunk) {
1640                                         splice @hunk, $ix, 1, $newhunk;
1641                                 }
1642                         }
1643                         else {
1644                                 help_patch_cmd($other);
1645                                 next;
1646                         }
1647                         # soft increment
1648                         while (1) {
1649                                 $ix++;
1650                                 last if ($ix >= $num ||
1651                                          !defined $hunk[$ix]{USE});
1652                         }
1653                 }
1654         }
1655
1656         @hunk = coalesce_overlapping_hunks(@hunk);
1657
1658         my $n_lofs = 0;
1659         my @result = ();
1660         for (@hunk) {
1661                 if ($_->{USE}) {
1662                         push @result, @{$_->{TEXT}};
1663                 }
1664         }
1665
1666         if (@result) {
1667                 my @patch = reassemble_patch($head->{TEXT}, @result);
1668                 my $apply_routine = $patch_mode_flavour{APPLY};
1669                 &$apply_routine(@patch);
1670                 refresh();
1671         }
1672
1673         print "\n";
1674         return $quit;
1675 }
1676
1677 sub diff_cmd {
1678         my @mods = list_modified('index-only');
1679         @mods = grep { !($_->{BINARY}) } @mods;
1680         return if (!@mods);
1681         my (@them) = list_and_choose({ PROMPT => __('Review diff'),
1682                                      IMMEDIATE => 1,
1683                                      HEADER => $status_head, },
1684                                    @mods);
1685         return if (!@them);
1686         my $reference = (is_initial_commit()) ? get_empty_tree() : 'HEAD';
1687         system(qw(git diff -p --cached), $reference, '--',
1688                 map { $_->{VALUE} } @them);
1689 }
1690
1691 sub quit_cmd {
1692         print __("Bye.\n");
1693         exit(0);
1694 }
1695
1696 sub help_cmd {
1697 # TRANSLATORS: please do not translate the command names
1698 # 'status', 'update', 'revert', etc.
1699         print colored $help_color, __ <<'EOF' ;
1700 status        - show paths with changes
1701 update        - add working tree state to the staged set of changes
1702 revert        - revert staged set of changes back to the HEAD version
1703 patch         - pick hunks and update selectively
1704 diff          - view diff between HEAD and index
1705 add untracked - add contents of untracked files to the staged set of changes
1706 EOF
1707 }
1708
1709 sub process_args {
1710         return unless @ARGV;
1711         my $arg = shift @ARGV;
1712         if ($arg =~ /--patch(?:=(.*))?/) {
1713                 if (defined $1) {
1714                         if ($1 eq 'reset') {
1715                                 $patch_mode = 'reset_head';
1716                                 $patch_mode_revision = 'HEAD';
1717                                 $arg = shift @ARGV or die __("missing --");
1718                                 if ($arg ne '--') {
1719                                         $patch_mode_revision = $arg;
1720                                         $patch_mode = ($arg eq 'HEAD' ?
1721                                                        'reset_head' : 'reset_nothead');
1722                                         $arg = shift @ARGV or die __("missing --");
1723                                 }
1724                         } elsif ($1 eq 'checkout') {
1725                                 $arg = shift @ARGV or die __("missing --");
1726                                 if ($arg eq '--') {
1727                                         $patch_mode = 'checkout_index';
1728                                 } else {
1729                                         $patch_mode_revision = $arg;
1730                                         $patch_mode = ($arg eq 'HEAD' ?
1731                                                        'checkout_head' : 'checkout_nothead');
1732                                         $arg = shift @ARGV or die __("missing --");
1733                                 }
1734                         } elsif ($1 eq 'stage' or $1 eq 'stash') {
1735                                 $patch_mode = $1;
1736                                 $arg = shift @ARGV or die __("missing --");
1737                         } else {
1738                                 die sprintf(__("unknown --patch mode: %s"), $1);
1739                         }
1740                 } else {
1741                         $patch_mode = 'stage';
1742                         $arg = shift @ARGV or die __("missing --");
1743                 }
1744                 die sprintf(__("invalid argument %s, expecting --"),
1745                                $arg) unless $arg eq "--";
1746                 %patch_mode_flavour = %{$patch_modes{$patch_mode}};
1747                 $patch_mode_only = 1;
1748         }
1749         elsif ($arg ne "--") {
1750                 die sprintf(__("invalid argument %s, expecting --"), $arg);
1751         }
1752 }
1753
1754 sub main_loop {
1755         my @cmd = ([ 'status', \&status_cmd, ],
1756                    [ 'update', \&update_cmd, ],
1757                    [ 'revert', \&revert_cmd, ],
1758                    [ 'add untracked', \&add_untracked_cmd, ],
1759                    [ 'patch', \&patch_update_cmd, ],
1760                    [ 'diff', \&diff_cmd, ],
1761                    [ 'quit', \&quit_cmd, ],
1762                    [ 'help', \&help_cmd, ],
1763         );
1764         while (1) {
1765                 my ($it) = list_and_choose({ PROMPT => __('What now'),
1766                                              SINGLETON => 1,
1767                                              LIST_FLAT => 4,
1768                                              HEADER => __('*** Commands ***'),
1769                                              ON_EOF => \&quit_cmd,
1770                                              IMMEDIATE => 1 }, @cmd);
1771                 if ($it) {
1772                         eval {
1773                                 $it->[1]->();
1774                         };
1775                         if ($@) {
1776                                 print "$@";
1777                         }
1778                 }
1779         }
1780 }
1781
1782 process_args();
1783 refresh();
1784 if ($patch_mode_only) {
1785         patch_update_cmd();
1786 }
1787 else {
1788         status_cmd();
1789         main_loop();
1790 }