git.oblomov.eu Git - git/blob - git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Text::ParseWords;
  24 use Data::Dumper;
  25 use Term::ANSIColor;
  26 use File::Temp qw/ tempdir tempfile /;
  27 use Error qw(:try);
  28 use Git;
  29
  30 Getopt::Long::Configure qw/ pass_through /;
  31
  32 package FakeTerm;
  33 sub new {
  34         my ($class, $reason) = @_;
  35         return bless \$reason, shift;
  36 }
  37 sub readline {
  38         my $self = shift;
  39         die "Cannot use readline on FakeTerm: $$self";
  40 }
  41 package main;
  42
  43
  44 sub usage {
  45         print <<EOT;
  46 git send-email [options] <file | directory | rev-list options >
  47
  48   Composing:
  49     --from                  <str>  * Email From:
  50     --to                    <str>  * Email To:
  51     --cc                    <str>  * Email Cc:
  52     --bcc                   <str>  * Email Bcc:
  53     --subject               <str>  * Email "Subject:"
  54     --in-reply-to           <str>  * Email "In-Reply-To:"
  55     --annotate                     * Review each patch that will be sent in an editor.
  56     --compose                      * Open an editor for introduction.
  57
  58   Sending:
  59     --envelope-sender       <str>  * Email envelope sender.
  60     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  61                                      is optional. Default 'localhost'.
  62     --smtp-server-port      <int>  * Outgoing SMTP server port.
  63     --smtp-user             <str>  * Username for SMTP-AUTH.
  64     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  65     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  66     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  67
  68   Automating:
  69     --identity              <str>  * Use the sendemail.<id> options.
  70     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  71     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  72     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  73     --[no-]suppress-from           * Send to self. Default off.
  74     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  75     --[no-]thread                  * Use In-Reply-To: field. Default on.
  76
  77   Administering:
  78     --confirm               <str>  * Confirm recipients before sending;
  79                                      auto, cc, compose, always, or never.
  80     --quiet                        * Output one line of info per email.
  81     --dry-run                      * Don't actually send the emails.
  82     --[no-]validate                * Perform patch sanity checks. Default on.
  83     --[no-]format-patch            * understand any non optional arguments as
  84                                      `git format-patch` ones.
  85
  86 EOT
  87         exit(1);
  88 }
  89
  90 # most mail servers generate the Date: header, but not all...
  91 sub format_2822_time {
  92         my ($time) = @_;
  93         my @localtm = localtime($time);
  94         my @gmttm = gmtime($time);
  95         my $localmin = $localtm[1] + $localtm[2] * 60;
  96         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
  97         if ($localtm[0] != $gmttm[0]) {
  98                 die "local zone differs from GMT by a non-minute interval\n";
  99         }
 100         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 101                 $localmin += 1440;
 102         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 103                 $localmin -= 1440;
 104         } elsif ($gmttm[6] != $localtm[6]) {
 105                 die "local time offset greater than or equal to 24 hours\n";
 106         }
 107         my $offset = $localmin - $gmtmin;
 108         my $offhour = $offset / 60;
 109         my $offmin = abs($offset % 60);
 110         if (abs($offhour) >= 24) {
 111                 die ("local time offset greater than or equal to 24 hours\n");
 112         }
 113
 114         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 115                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 116                        $localtm[3],
 117                        qw(Jan Feb Mar Apr May Jun
 118                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 119                        $localtm[5]+1900,
 120                        $localtm[2],
 121                        $localtm[1],
 122                        $localtm[0],
 123                        ($offset >= 0) ? '+' : '-',
 124                        abs($offhour),
 125                        $offmin,
 126                        );
 127 }
 128
 129 my $have_email_valid = eval { require Email::Valid; 1 };
 130 my $have_mail_address = eval { require Mail::Address; 1 };
 131 my $smtp;
 132 my $auth;
 133
 134 sub unique_email_list(@);
 135 sub cleanup_compose_files();
 136
 137 # Variables we fill in automatically, or via prompting:
 138 my (@to,@cc,@initial_cc,@bcclist,@xh,
 139         $initial_reply_to,$initial_subject,@files,
 140         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 141
 142 my $envelope_sender;
 143
 144 # Example reply to:
 145 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 146
 147 my $repo = eval { Git->repository() };
 148 my @repo = $repo ? ($repo) : ();
 149 my $term = eval {
 150         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 151                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 152                 : new Term::ReadLine 'git-send-email';
 153 };
 154 if ($@) {
 155         $term = new FakeTerm "$@: going non-interactive";
 156 }
 157
 158 # Behavior modification variables
 159 my ($quiet, $dry_run) = (0, 0);
 160 my $format_patch;
 161 my $compose_filename;
 162
 163 # Handle interactive edition of files.
 164 my $multiedit;
 165 my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 166 sub do_edit {
 167         if (defined($multiedit) && !$multiedit) {
 168                 map {
 169                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 170                         if (($? & 127) || ($? >> 8)) {
 171                                 die("the editor exited uncleanly, aborting everything");
 172                         }
 173                 } @_;
 174         } else {
 175                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 176                 if (($? & 127) || ($? >> 8)) {
 177                         die("the editor exited uncleanly, aborting everything");
 178                 }
 179         }
 180 }
 181
 182 # Variables with corresponding config settings
 183 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 184 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 185 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 186 my ($validate, $confirm);
 187 my (@suppress_cc);
 188
 189 my %config_bool_settings = (
 190     "thread" => [\$thread, 1],
 191     "chainreplyto" => [\$chain_reply_to, undef],
 192     "suppressfrom" => [\$suppress_from, undef],
 193     "signedoffbycc" => [\$signed_off_by_cc, undef],
 194     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 195     "validate" => [\$validate, 1],
 196 );
 197
 198 my %config_settings = (
 199     "smtpserver" => \$smtp_server,
 200     "smtpserverport" => \$smtp_server_port,
 201     "smtpuser" => \$smtp_authuser,
 202     "smtppass" => \$smtp_authpass,
 203     "to" => \@to,
 204     "cc" => \@initial_cc,
 205     "cccmd" => \$cc_cmd,
 206     "aliasfiletype" => \$aliasfiletype,
 207     "bcc" => \@bcclist,
 208     "aliasesfile" => \@alias_files,
 209     "suppresscc" => \@suppress_cc,
 210     "envelopesender" => \$envelope_sender,
 211     "multiedit" => \$multiedit,
 212     "confirm"   => \$confirm,
 213     "from" => \$sender,
 214 );
 215
 216 # Handle Uncouth Termination
 217 sub signal_handler {
 218
 219         # Make text normal
 220         print color("reset"), "\n";
 221
 222         # SMTP password masked
 223         system "stty echo";
 224
 225         # tmp files from --compose
 226         if (defined $compose_filename) {
 227                 if (-e $compose_filename) {
 228                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 229                 }
 230                 if (-e ($compose_filename . ".final")) {
 231                         print "'$compose_filename.final' contains the composed email.\n"
 232                 }
 233         }
 234
 235         exit;
 236 };
 237
 238 $SIG{TERM} = \&signal_handler;
 239 $SIG{INT}  = \&signal_handler;
 240
 241 # Begin by accumulating all the variables (defined above), that we will end up
 242 # needing, first, from the command line:
 243
 244 my $rc = GetOptions("sender|from=s" => \$sender,
 245                     "in-reply-to=s" => \$initial_reply_to,
 246                     "subject=s" => \$initial_subject,
 247                     "to=s" => \@to,
 248                     "cc=s" => \@initial_cc,
 249                     "bcc=s" => \@bcclist,
 250                     "chain-reply-to!" => \$chain_reply_to,
 251                     "smtp-server=s" => \$smtp_server,
 252                     "smtp-server-port=s" => \$smtp_server_port,
 253                     "smtp-user=s" => \$smtp_authuser,
 254                     "smtp-pass:s" => \$smtp_authpass,
 255                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 256                     "smtp-encryption=s" => \$smtp_encryption,
 257                     "identity=s" => \$identity,
 258                     "annotate" => \$annotate,
 259                     "compose" => \$compose,
 260                     "quiet" => \$quiet,
 261                     "cc-cmd=s" => \$cc_cmd,
 262                     "suppress-from!" => \$suppress_from,
 263                     "suppress-cc=s" => \@suppress_cc,
 264                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 265                     "confirm=s" => \$confirm,
 266                     "dry-run" => \$dry_run,
 267                     "envelope-sender=s" => \$envelope_sender,
 268                     "thread!" => \$thread,
 269                     "validate!" => \$validate,
 270                     "format-patch!" => \$format_patch,
 271          );
 272
 273 unless ($rc) {
 274     usage();
 275 }
 276
 277 die "Cannot run git format-patch from outside a repository\n"
 278         if $format_patch and not $repo;
 279
 280 # Now, let's fill any that aren't set in with defaults:
 281
 282 sub read_config {
 283         my ($prefix) = @_;
 284
 285         foreach my $setting (keys %config_bool_settings) {
 286                 my $target = $config_bool_settings{$setting}->[0];
 287                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 288         }
 289
 290         foreach my $setting (keys %config_settings) {
 291                 my $target = $config_settings{$setting};
 292                 if (ref($target) eq "ARRAY") {
 293                         unless (@$target) {
 294                                 my @values = Git::config(@repo, "$prefix.$setting");
 295                                 @$target = @values if (@values && defined $values[0]);
 296                         }
 297                 }
 298                 else {
 299                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 300                 }
 301         }
 302
 303         if (!defined $smtp_encryption) {
 304                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 305                 if (defined $enc) {
 306                         $smtp_encryption = $enc;
 307                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 308                         $smtp_encryption = 'ssl';
 309                 }
 310         }
 311 }
 312
 313 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 314 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 315 read_config("sendemail.$identity") if (defined $identity);
 316 read_config("sendemail");
 317
 318 # fall back on builtin bool defaults
 319 foreach my $setting (values %config_bool_settings) {
 320         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 321 }
 322
 323 # 'default' encryption is none -- this only prevents a warning
 324 $smtp_encryption = '' unless (defined $smtp_encryption);
 325
 326 # Set CC suppressions
 327 my(%suppress_cc);
 328 if (@suppress_cc) {
 329         foreach my $entry (@suppress_cc) {
 330                 die "Unknown --suppress-cc field: '$entry'\n"
 331                         unless $entry =~ /^(all|cccmd|cc|author|self|sob|body|bodycc)$/;
 332                 $suppress_cc{$entry} = 1;
 333         }
 334 }
 335
 336 if ($suppress_cc{'all'}) {
 337         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 338                 $suppress_cc{$entry} = 1;
 339         }
 340         delete $suppress_cc{'all'};
 341 }
 342
 343 # If explicit old-style ones are specified, they trump --suppress-cc.
 344 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 345 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 346
 347 if ($suppress_cc{'body'}) {
 348         foreach my $entry (qw (sob bodycc)) {
 349                 $suppress_cc{$entry} = 1;
 350         }
 351         delete $suppress_cc{'body'};
 352 }
 353
 354 # Set confirm's default value
 355 my $confirm_unconfigured = !defined $confirm;
 356 if ($confirm_unconfigured) {
 357         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 358 };
 359 die "Unknown --confirm setting: '$confirm'\n"
 360         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 361
 362 # Debugging, print out the suppressions.
 363 if (0) {
 364         print "suppressions:\n";
 365         foreach my $entry (keys %suppress_cc) {
 366                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 367         }
 368 }
 369
 370 my ($repoauthor, $repocommitter);
 371 ($repoauthor) = Git::ident_person(@repo, 'author');
 372 ($repocommitter) = Git::ident_person(@repo, 'committer');
 373
 374 # Verify the user input
 375
 376 foreach my $entry (@to) {
 377         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 378 }
 379
 380 foreach my $entry (@initial_cc) {
 381         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 382 }
 383
 384 foreach my $entry (@bcclist) {
 385         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 386 }
 387
 388 sub parse_address_line {
 389         if ($have_mail_address) {
 390                 return map { $_->format } Mail::Address->parse($_[0]);
 391         } else {
 392                 return split_addrs($_[0]);
 393         }
 394 }
 395
 396 sub split_addrs {
 397         return quotewords('\s*,\s*', 1, @_);
 398 }
 399
 400 my %aliases;
 401 my %parse_alias = (
 402         # multiline formats can be supported in the future
 403         mutt => sub { my $fh = shift; while (<$fh>) {
 404                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 405                         my ($alias, $addr) = ($1, $2);
 406                         $addr =~ s/#.*$//; # mutt allows # comments
 407                          # commas delimit multiple addresses
 408                         $aliases{$alias} = [ split_addrs($addr) ];
 409                 }}},
 410         mailrc => sub { my $fh = shift; while (<$fh>) {
 411                 if (/^alias\s+(\S+)\s+(.*)$/) {
 412                         # spaces delimit multiple addresses
 413                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 414                 }}},
 415         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 416                 for (my $x = ''; defined($x); $x = $_) {
 417                         chomp $x;
 418                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 419                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 420                         $aliases{$1} = [ split_addrs($2) ];
 421                 }},
 422         elm => sub  { my $fh = shift;
 423                       while (<$fh>) {
 424                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 425                               my ($alias, $addr) = ($1, $2);
 426                                $aliases{$alias} = [ split_addrs($addr) ];
 427                           }
 428                       } },
 429
 430         gnus => sub { my $fh = shift; while (<$fh>) {
 431                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 432                         $aliases{$1} = [ $2 ];
 433                 }}}
 434 );
 435
 436 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 437         foreach my $file (@alias_files) {
 438                 open my $fh, '<', $file or die "opening $file: $!\n";
 439                 $parse_alias{$aliasfiletype}->($fh);
 440                 close $fh;
 441         }
 442 }
 443
 444 ($sender) = expand_aliases($sender) if defined $sender;
 445
 446 # returns 1 if the conflict must be solved using it as a format-patch argument
 447 sub check_file_rev_conflict($) {
 448         return unless $repo;
 449         my $f = shift;
 450         try {
 451                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 452                 if (defined($format_patch)) {
 453                         return $format_patch;
 454                 }
 455                 die(<<EOF);
 456 File '$f' exists but it could also be the range of commits
 457 to produce patches for.  Please disambiguate by...
 458
 459     * Saying "./$f" if you mean a file; or
 460     * Giving --format-patch option if you mean a range.
 461 EOF
 462         } catch Git::Error::Command with {
 463                 return 0;
 464         }
 465 }
 466
 467 # Now that all the defaults are set, process the rest of the command line
 468 # arguments and collect up the files that need to be processed.
 469 my @rev_list_opts;
 470 while (defined(my $f = shift @ARGV)) {
 471         if ($f eq "--") {
 472                 push @rev_list_opts, "--", @ARGV;
 473                 @ARGV = ();
 474         } elsif (-d $f and !check_file_rev_conflict($f)) {
 475                 opendir(DH,$f)
 476                         or die "Failed to opendir $f: $!";
 477
 478                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 479                                 sort readdir(DH);
 480                 closedir(DH);
 481         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 482                 push @files, $f;
 483         } else {
 484                 push @rev_list_opts, $f;
 485         }
 486 }
 487
 488 if (@rev_list_opts) {
 489         die "Cannot run git format-patch from outside a repository\n"
 490                 unless $repo;
 491         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 492 }
 493
 494 if ($validate) {
 495         foreach my $f (@files) {
 496                 unless (-p $f) {
 497                         my $error = validate_patch($f);
 498                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 499                 }
 500         }
 501 }
 502
 503 if (@files) {
 504         unless ($quiet) {
 505                 print $_,"\n" for (@files);
 506         }
 507 } else {
 508         print STDERR "\nNo patch files specified!\n\n";
 509         usage();
 510 }
 511
 512 sub get_patch_subject($) {
 513         my $fn = shift;
 514         open (my $fh, '<', $fn);
 515         while (my $line = <$fh>) {
 516                 next unless ($line =~ /^Subject: (.*)$/);
 517                 close $fh;
 518                 return "GIT: $1\n";
 519         }
 520         close $fh;
 521         die "No subject line in $fn ?";
 522 }
 523
 524 if ($compose) {
 525         # Note that this does not need to be secure, but we will make a small
 526         # effort to have it be unique
 527         $compose_filename = ($repo ?
 528                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 529                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 530         open(C,">",$compose_filename)
 531                 or die "Failed to open for writing $compose_filename: $!";
 532
 533
 534         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 535         my $tpl_subject = $initial_subject || '';
 536         my $tpl_reply_to = $initial_reply_to || '';
 537
 538         print C <<EOT;
 539 From $tpl_sender # This line is ignored.
 540 GIT: Lines beginning in "GIT:" will be removed.
 541 GIT: Consider including an overall diffstat or table of contents
 542 GIT: for the patch you are writing.
 543 GIT:
 544 GIT: Clear the body content if you don't wish to send a summary.
 545 From: $tpl_sender
 546 Subject: $tpl_subject
 547 In-Reply-To: $tpl_reply_to
 548
 549 EOT
 550         for my $f (@files) {
 551                 print C get_patch_subject($f);
 552         }
 553         close(C);
 554
 555         my $re_edit = 0;
 556         do {
 557                 if ($annotate) {
 558                         do_edit($compose_filename, @files);
 559                 } else {
 560                         do_edit($compose_filename);
 561                 }
 562
 563                 open(C, "<", $compose_filename) ||
 564                         die "Failed to open $compose_filename: $!";
 565                 if (grep(/^Subject:\s*$/i, <C>)) {
 566                         my $r = ask("No Subject, send anyway? ".
 567                                     "([y]es|[n]o|[e]dit again): ",
 568                                     valid_re => qr/^[yne]/i,
 569                                     default => "n");
 570                         $re_edit = lc(substr($r, 0, 1)) eq "e";
 571                         exit(0) if lc(substr($r, 0, 1)) eq "n";
 572                 }
 573                 close C;
 574         } while ($re_edit);
 575
 576         open(C2,">",$compose_filename . ".final")
 577                 or die "Failed to open $compose_filename.final : " . $!;
 578
 579         open(C,"<",$compose_filename)
 580                 or die "Failed to open $compose_filename : " . $!;
 581
 582         my $need_8bit_cte = file_has_nonascii($compose_filename);
 583         my $in_body = 0;
 584         my $summary_empty = 1;
 585         while(<C>) {
 586                 next if m/^GIT:/;
 587                 if ($in_body) {
 588                         $summary_empty = 0 unless (/^\n$/);
 589                 } elsif (/^\n$/) {
 590                         $in_body = 1;
 591                         if ($need_8bit_cte) {
 592                                 print C2 "MIME-Version: 1.0\n",
 593                                          "Content-Type: text/plain; ",
 594                                            "charset=UTF-8\n",
 595                                          "Content-Transfer-Encoding: 8bit\n";
 596                         }
 597                 } elsif (/^MIME-Version:/i) {
 598                         $need_8bit_cte = 0;
 599                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 600                         $initial_subject = $1;
 601                         my $subject = $initial_subject;
 602                         $_ = "Subject: " .
 603                                 ($subject =~ /[^[:ascii:]]/ ?
 604                                  quote_rfc2047($subject) :
 605                                  $subject) .
 606                                 "\n";
 607                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 608                         $initial_reply_to = $1;
 609                         next;
 610                 } elsif (/^From:\s*(.+)\s*$/i) {
 611                         $sender = $1;
 612                         next;
 613                 } elsif (/^(?:To|Cc|Bcc):/i) {
 614                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 615                         next;
 616                 }
 617                 print C2 $_;
 618         }
 619         close(C);
 620         close(C2);
 621
 622         if ($summary_empty) {
 623                 print "Summary email is empty, skipping it\n";
 624                 $compose = -1;
 625         }
 626 } elsif ($annotate) {
 627         do_edit(@files);
 628 }
 629
 630 sub ask {
 631         my ($prompt, %arg) = @_;
 632         my $valid_re = $arg{valid_re};
 633         my $default = $arg{default};
 634         my $resp;
 635         my $i = 0;
 636         return defined $default ? $default : undef
 637                 unless defined $term->IN and defined fileno($term->IN) and
 638                        defined $term->OUT and defined fileno($term->OUT);
 639         while ($i++ < 10) {
 640                 $resp = $term->readline($prompt);
 641                 if (!defined $resp) { # EOF
 642                         print "\n";
 643                         return defined $default ? $default : undef;
 644                 }
 645                 if ($resp eq '' and defined $default) {
 646                         return $default;
 647                 }
 648                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 649                         return $resp;
 650                 }
 651         }
 652         return undef;
 653 }
 654
 655 my $prompting = 0;
 656 if (!defined $sender) {
 657         $sender = $repoauthor || $repocommitter || '';
 658         $sender = ask("Who should the emails appear to be from? [$sender] ",
 659                       default => $sender);
 660         print "Emails will be sent from: ", $sender, "\n";
 661         $prompting++;
 662 }
 663
 664 if (!@to) {
 665         my $to = ask("Who should the emails be sent to? ");
 666         push @to, parse_address_line($to) if defined $to; # sanitized/validated later
 667         $prompting++;
 668 }
 669
 670 sub expand_aliases {
 671         return map { expand_one_alias($_) } @_;
 672 }
 673
 674 my %EXPANDED_ALIASES;
 675 sub expand_one_alias {
 676         my $alias = shift;
 677         if ($EXPANDED_ALIASES{$alias}) {
 678                 die "fatal: alias '$alias' expands to itself\n";
 679         }
 680         local $EXPANDED_ALIASES{$alias} = 1;
 681         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 682 }
 683
 684 @to = expand_aliases(@to);
 685 @to = (map { sanitize_address($_) } @to);
 686 @initial_cc = expand_aliases(@initial_cc);
 687 @bcclist = expand_aliases(@bcclist);
 688
 689 if ($thread && !defined $initial_reply_to && $prompting) {
 690         $initial_reply_to = ask(
 691                 "Message-ID to be used as In-Reply-To for the first email? ");
 692 }
 693 if (defined $initial_reply_to) {
 694         $initial_reply_to =~ s/^\s*<?//;
 695         $initial_reply_to =~ s/>?\s*$//;
 696         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 697 }
 698
 699 if (!defined $smtp_server) {
 700         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 701                 if (-x $_) {
 702                         $smtp_server = $_;
 703                         last;
 704                 }
 705         }
 706         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 707 }
 708
 709 if ($compose && $compose > 0) {
 710         @files = ($compose_filename . ".final", @files);
 711 }
 712
 713 # Variables we set as part of the loop over files
 714 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 715         $needs_confirm, $message_num, $ask_default);
 716
 717 sub extract_valid_address {
 718         my $address = shift;
 719         my $local_part_regexp = '[^<>"\s@]+';
 720         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 721
 722         # check for a local address:
 723         return $address if ($address =~ /^($local_part_regexp)$/);
 724
 725         $address =~ s/^\s*<(.*)>\s*$/$1/;
 726         if ($have_email_valid) {
 727                 return scalar Email::Valid->address($address);
 728         } else {
 729                 # less robust/correct than the monster regexp in Email::Valid,
 730                 # but still does a 99% job, and one less dependency
 731                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 732                 return $1;
 733         }
 734 }
 735
 736 # Usually don't need to change anything below here.
 737
 738 # we make a "fake" message id by taking the current number
 739 # of seconds since the beginning of Unix time and tacking on
 740 # a random number to the end, in case we are called quicker than
 741 # 1 second since the last time we were called.
 742
 743 # We'll setup a template for the message id, using the "from" address:
 744
 745 my ($message_id_stamp, $message_id_serial);
 746 sub make_message_id
 747 {
 748         my $uniq;
 749         if (!defined $message_id_stamp) {
 750                 $message_id_stamp = sprintf("%s-%s", time, $$);
 751                 $message_id_serial = 0;
 752         }
 753         $message_id_serial++;
 754         $uniq = "$message_id_stamp-$message_id_serial";
 755
 756         my $du_part;
 757         for ($sender, $repocommitter, $repoauthor) {
 758                 $du_part = extract_valid_address(sanitize_address($_));
 759                 last if (defined $du_part and $du_part ne '');
 760         }
 761         if (not defined $du_part or $du_part eq '') {
 762                 use Sys::Hostname qw();
 763                 $du_part = 'user@' . Sys::Hostname::hostname();
 764         }
 765         my $message_id_template = "<%s-git-send-email-%s>";
 766         $message_id = sprintf($message_id_template, $uniq, $du_part);
 767         #print "new message id = $message_id\n"; # Was useful for debugging
 768 }
 769
 770
 771
 772 $time = time - scalar $#files;
 773
 774 sub unquote_rfc2047 {
 775         local ($_) = @_;
 776         my $encoding;
 777         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 778                 $encoding = $1;
 779                 s/_/ /g;
 780                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 781         }
 782         return wantarray ? ($_, $encoding) : $_;
 783 }
 784
 785 sub quote_rfc2047 {
 786         local $_ = shift;
 787         my $encoding = shift || 'UTF-8';
 788         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 789         s/(.*)/=\?$encoding\?q\?$1\?=/;
 790         return $_;
 791 }
 792
 793 sub is_rfc2047_quoted {
 794         my $s = shift;
 795         my $token = '[^][()<>@,;:"\/?.= \000-\037\177-\377]+';
 796         my $encoded_text = '[!->@-~]+';
 797         length($s) <= 75 &&
 798         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 799 }
 800
 801 # use the simplest quoting being able to handle the recipient
 802 sub sanitize_address
 803 {
 804         my ($recipient) = @_;
 805         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 806
 807         if (not $recipient_name) {
 808                 return "$recipient";
 809         }
 810
 811         # if recipient_name is already quoted, do nothing
 812         if (is_rfc2047_quoted($recipient_name)) {
 813                 return $recipient;
 814         }
 815
 816         # rfc2047 is needed if a non-ascii char is included
 817         if ($recipient_name =~ /[^[:ascii:]]/) {
 818                 $recipient_name =~ s/^"(.*)"$/$1/;
 819                 $recipient_name = quote_rfc2047($recipient_name);
 820         }
 821
 822         # double quotes are needed if specials or CTLs are included
 823         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 824                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 825                 $recipient_name = "\"$recipient_name\"";
 826         }
 827
 828         return "$recipient_name $recipient_addr";
 829
 830 }
 831
 832 # Returns 1 if the message was sent, and 0 otherwise.
 833 # In actuality, the whole program dies when there
 834 # is an error sending a message.
 835
 836 sub send_message
 837 {
 838         my @recipients = unique_email_list(@to);
 839         @cc = (grep { my $cc = extract_valid_address($_);
 840                       not grep { $cc eq $_ } @recipients
 841                     }
 842                map { sanitize_address($_) }
 843                @cc);
 844         my $to = join (",\n\t", @recipients);
 845         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 846         @recipients = (map { extract_valid_address($_) } @recipients);
 847         my $date = format_2822_time($time++);
 848         my $gitversion = '@@GIT_VERSION@@';
 849         if ($gitversion =~ m/..GIT_VERSION../) {
 850             $gitversion = Git::version();
 851         }
 852
 853         my $cc = join(", ", unique_email_list(@cc));
 854         my $ccline = "";
 855         if ($cc ne '') {
 856                 $ccline = "\nCc: $cc";
 857         }
 858         my $sanitized_sender = sanitize_address($sender);
 859         make_message_id() unless defined($message_id);
 860
 861         my $header = "From: $sanitized_sender
 862 To: $to${ccline}
 863 Subject: $subject
 864 Date: $date
 865 Message-Id: $message_id
 866 X-Mailer: git-send-email $gitversion
 867 ";
 868         if ($reply_to) {
 869
 870                 $header .= "In-Reply-To: $reply_to\n";
 871                 $header .= "References: $references\n";
 872         }
 873         if (@xh) {
 874                 $header .= join("\n", @xh) . "\n";
 875         }
 876
 877         my @sendmail_parameters = ('-i', @recipients);
 878         my $raw_from = $sanitized_sender;
 879         $raw_from = $envelope_sender if (defined $envelope_sender);
 880         $raw_from = extract_valid_address($raw_from);
 881         unshift (@sendmail_parameters,
 882                         '-f', $raw_from) if(defined $envelope_sender);
 883
 884         if ($needs_confirm && !$dry_run) {
 885                 print "\n$header\n";
 886                 if ($needs_confirm eq "inform") {
 887                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
 888                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
 889                         print "    The Cc list above has been expanded by additional\n";
 890                         print "    addresses found in the patch commit message. By default\n";
 891                         print "    send-email prompts before sending whenever this occurs.\n";
 892                         print "    This behavior is controlled by the sendemail.confirm\n";
 893                         print "    configuration setting.\n";
 894                         print "\n";
 895                         print "    For additional information, run 'git send-email --help'.\n";
 896                         print "    To retain the current behavior, but squelch this message,\n";
 897                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
 898                 }
 899                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
 900                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 901                          default => $ask_default);
 902                 die "Send this email reply required" unless defined $_;
 903                 if (/^n/i) {
 904                         return 0;
 905                 } elsif (/^q/i) {
 906                         cleanup_compose_files();
 907                         exit(0);
 908                 } elsif (/^a/i) {
 909                         $confirm = 'never';
 910                 }
 911         }
 912
 913         if ($dry_run) {
 914                 # We don't want to send the email.
 915         } elsif ($smtp_server =~ m#^/#) {
 916                 my $pid = open my $sm, '|-';
 917                 defined $pid or die $!;
 918                 if (!$pid) {
 919                         exec($smtp_server, @sendmail_parameters) or die $!;
 920                 }
 921                 print $sm "$header\n$message";
 922                 close $sm or die $?;
 923         } else {
 924
 925                 if (!defined $smtp_server) {
 926                         die "The required SMTP server is not properly defined."
 927                 }
 928
 929                 if ($smtp_encryption eq 'ssl') {
 930                         $smtp_server_port ||= 465; # ssmtp
 931                         require Net::SMTP::SSL;
 932                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 933                 }
 934                 else {
 935                         require Net::SMTP;
 936                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 937                                                  ? "$smtp_server:$smtp_server_port"
 938                                                  : $smtp_server);
 939                         if ($smtp_encryption eq 'tls' && $smtp) {
 940                                 require Net::SMTP::SSL;
 941                                 $smtp->command('STARTTLS');
 942                                 $smtp->response();
 943                                 if ($smtp->code == 220) {
 944                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
 945                                                 or die "STARTTLS failed! ".$smtp->message;
 946                                         $smtp_encryption = '';
 947                                         # Send EHLO again to receive fresh
 948                                         # supported commands
 949                                         $smtp->hello();
 950                                 } else {
 951                                         die "Server does not support STARTTLS! ".$smtp->message;
 952                                 }
 953                         }
 954                 }
 955
 956                 if (!$smtp) {
 957                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 958                 }
 959
 960                 if (defined $smtp_authuser) {
 961
 962                         if (!defined $smtp_authpass) {
 963
 964                                 system "stty -echo";
 965
 966                                 do {
 967                                         print "Password: ";
 968                                         $_ = <STDIN>;
 969                                         print "\n";
 970                                 } while (!defined $_);
 971
 972                                 chomp($smtp_authpass = $_);
 973
 974                                 system "stty echo";
 975                         }
 976
 977                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 978                 }
 979
 980                 $smtp->mail( $raw_from ) or die $smtp->message;
 981                 $smtp->to( @recipients ) or die $smtp->message;
 982                 $smtp->data or die $smtp->message;
 983                 $smtp->datasend("$header\n$message") or die $smtp->message;
 984                 $smtp->dataend() or die $smtp->message;
 985                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
 986         }
 987         if ($quiet) {
 988                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 989         } else {
 990                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 991                 if ($smtp_server !~ m#^/#) {
 992                         print "Server: $smtp_server\n";
 993                         print "MAIL FROM:<$raw_from>\n";
 994                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 995                 } else {
 996                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 997                 }
 998                 print $header, "\n";
 999                 if ($smtp) {
1000                         print "Result: ", $smtp->code, ' ',
1001                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1002                 } else {
1003                         print "Result: OK\n";
1004                 }
1005         }
1006
1007         return 1;
1008 }
1009
1010 $reply_to = $initial_reply_to;
1011 $references = $initial_reply_to || '';
1012 $subject = $initial_subject;
1013 $message_num = 0;
1014
1015 foreach my $t (@files) {
1016         open(F,"<",$t) or die "can't open file $t";
1017
1018         my $author = undef;
1019         my $author_encoding;
1020         my $has_content_type;
1021         my $body_encoding;
1022         @cc = ();
1023         @xh = ();
1024         my $input_format = undef;
1025         my @header = ();
1026         $message = "";
1027         $message_num++;
1028         # First unfold multiline header fields
1029         while(<F>) {
1030                 last if /^\s*$/;
1031                 if (/^\s+\S/ and @header) {
1032                         chomp($header[$#header]);
1033                         s/^\s+/ /;
1034                         $header[$#header] .= $_;
1035             } else {
1036                         push(@header, $_);
1037                 }
1038         }
1039         # Now parse the header
1040         foreach(@header) {
1041                 if (/^From /) {
1042                         $input_format = 'mbox';
1043                         next;
1044                 }
1045                 chomp;
1046                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1047                         $input_format = 'mbox';
1048                 }
1049
1050                 if (defined $input_format && $input_format eq 'mbox') {
1051                         if (/^Subject:\s+(.*)$/) {
1052                                 $subject = $1;
1053                         }
1054                         elsif (/^From:\s+(.*)$/) {
1055                                 ($author, $author_encoding) = unquote_rfc2047($1);
1056                                 next if $suppress_cc{'author'};
1057                                 next if $suppress_cc{'self'} and $author eq $sender;
1058                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1059                                         $1, $_) unless $quiet;
1060                                 push @cc, $1;
1061                         }
1062                         elsif (/^Cc:\s+(.*)$/) {
1063                                 foreach my $addr (parse_address_line($1)) {
1064                                         if (unquote_rfc2047($addr) eq $sender) {
1065                                                 next if ($suppress_cc{'self'});
1066                                         } else {
1067                                                 next if ($suppress_cc{'cc'});
1068                                         }
1069                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1070                                                 $addr, $_) unless $quiet;
1071                                         push @cc, $addr;
1072                                 }
1073                         }
1074                         elsif (/^Content-type:/i) {
1075                                 $has_content_type = 1;
1076                                 if (/charset="?([^ "]+)/) {
1077                                         $body_encoding = $1;
1078                                 }
1079                                 push @xh, $_;
1080                         }
1081                         elsif (/^Message-Id: (.*)/i) {
1082                                 $message_id = $1;
1083                         }
1084                         elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1085                                 push @xh, $_;
1086                         }
1087
1088                 } else {
1089                         # In the traditional
1090                         # "send lots of email" format,
1091                         # line 1 = cc
1092                         # line 2 = subject
1093                         # So let's support that, too.
1094                         $input_format = 'lots';
1095                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1096                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1097                                         $_, $_) unless $quiet;
1098                                 push @cc, $_;
1099                         } elsif (!defined $subject) {
1100                                 $subject = $_;
1101                         }
1102                 }
1103         }
1104         # Now parse the message body
1105         while(<F>) {
1106                 $message .=  $_;
1107                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1108                         chomp;
1109                         my ($what, $c) = ($1, $2);
1110                         chomp $c;
1111                         if ($c eq $sender) {
1112                                 next if ($suppress_cc{'self'});
1113                         } else {
1114                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1115                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1116                         }
1117                         push @cc, $c;
1118                         printf("(body) Adding cc: %s from line '%s'\n",
1119                                 $c, $_) unless $quiet;
1120                 }
1121         }
1122         close F;
1123
1124         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1125                 open(F, "$cc_cmd \Q$t\E |")
1126                         or die "(cc-cmd) Could not execute '$cc_cmd'";
1127                 while(<F>) {
1128                         my $c = $_;
1129                         $c =~ s/^\s*//g;
1130                         $c =~ s/\n$//g;
1131                         next if ($c eq $sender and $suppress_from);
1132                         push @cc, $c;
1133                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1134                                 $c, $cc_cmd) unless $quiet;
1135                 }
1136                 close F
1137                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1138         }
1139
1140         if (defined $author and $author ne $sender) {
1141                 $message = "From: $author\n\n$message";
1142                 if (defined $author_encoding) {
1143                         if ($has_content_type) {
1144                                 if ($body_encoding eq $author_encoding) {
1145                                         # ok, we already have the right encoding
1146                                 }
1147                                 else {
1148                                         # uh oh, we should re-encode
1149                                 }
1150                         }
1151                         else {
1152                                 push @xh,
1153                                   'MIME-Version: 1.0',
1154                                   "Content-Type: text/plain; charset=$author_encoding",
1155                                   'Content-Transfer-Encoding: 8bit';
1156                         }
1157                 }
1158         }
1159
1160         $needs_confirm = (
1161                 $confirm eq "always" or
1162                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1163                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1164         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1165
1166         @cc = (@initial_cc, @cc);
1167
1168         my $message_was_sent = send_message();
1169
1170         # set up for the next message
1171         if ($thread && $message_was_sent &&
1172                 ($chain_reply_to || !defined $reply_to || length($reply_to) == 0)) {
1173                 $reply_to = $message_id;
1174                 if (length $references > 0) {
1175                         $references .= "\n $message_id";
1176                 } else {
1177                         $references = "$message_id";
1178                 }
1179         }
1180         $message_id = undef;
1181 }
1182
1183 cleanup_compose_files();
1184
1185 sub cleanup_compose_files() {
1186         unlink($compose_filename, $compose_filename . ".final") if $compose;
1187 }
1188
1189 $smtp->quit if $smtp;
1190
1191 sub unique_email_list(@) {
1192         my %seen;
1193         my @emails;
1194
1195         foreach my $entry (@_) {
1196                 if (my $clean = extract_valid_address($entry)) {
1197                         $seen{$clean} ||= 0;
1198                         next if $seen{$clean}++;
1199                         push @emails, $entry;
1200                 } else {
1201                         print STDERR "W: unable to extract a valid address",
1202                                         " from: $entry\n";
1203                 }
1204         }
1205         return @emails;
1206 }
1207
1208 sub validate_patch {
1209         my $fn = shift;
1210         open(my $fh, '<', $fn)
1211                 or die "unable to open $fn: $!\n";
1212         while (my $line = <$fh>) {
1213                 if (length($line) > 998) {
1214                         return "$.: patch contains a line longer than 998 characters";
1215                 }
1216         }
1217         return undef;
1218 }
1219
1220 sub file_has_nonascii {
1221         my $fn = shift;
1222         open(my $fh, '<', $fn)
1223                 or die "unable to open $fn: $!\n";
1224         while (my $line = <$fh>) {
1225                 return 1 if $line =~ /[^[:ascii:]]/;
1226         }
1227         return 0;
1228 }