git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Wrapper.pm

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5 use Cwd q{abs_path};
   6 use Data::Dumper ;
   7 use IkiWiki;
   8
   9 package IkiWiki;
  10
  11 sub gen_wrapper () { #{{{
  12         $config{srcdir}=abs_path($config{srcdir});
  13         $config{destdir}=abs_path($config{destdir});
  14         my $this=abs_path($0);
  15         if (! -x $this) {
  16                 error(sprintf(gettext("%s doesn't seem to be executable"), $this));
  17         }
  18
  19         if ($config{setup}) {
  20                 error(gettext("cannot create a wrapper that uses a setup file"));
  21         }
  22         my $wrapper=possibly_foolish_untaint($config{wrapper});
  23         if (! defined $wrapper || ! length $wrapper) {
  24                 error(gettext("wrapper filename not specified"));
  25         }
  26         delete $config{wrapper};
  27
  28         my @envsave;
  29         push @envsave, qw{REMOTE_ADDR QUERY_STRING REQUEST_METHOD REQUEST_URI
  30                        CONTENT_TYPE CONTENT_LENGTH GATEWAY_INTERFACE
  31                        HTTP_COOKIE REMOTE_USER} if $config{cgi};
  32         my $envsave="";
  33         foreach my $var (@envsave) {
  34                 $envsave.=<<"EOF"
  35         if ((s=getenv("$var")))
  36                 addenv("$var", s);
  37 EOF
  38         }
  39
  40         $Data::Dumper::Indent=0; # no newlines
  41         my $configstring=Data::Dumper->Dump([\%config], ['*config']);
  42         $configstring=~s/\\/\\\\/g;
  43         $configstring=~s/"/\\"/g;
  44         $configstring=~s/\n/\\n/g;
  45
  46         #translators: The first parameter is a filename, and the second is
  47         #translators: a (probably not translated) error message.
  48         open(OUT, ">$wrapper.c") || error(sprintf(gettext("failed to write %s: %s"), "$wrapper.c", $!));;
  49         print OUT <<"EOF";
  50 /* A wrapper for ikiwiki, can be safely made suid. */
  51 #include <stdio.h>
  52 #include <sys/types.h>
  53 #include <unistd.h>
  54 #include <stdlib.h>
  55 #include <string.h>
  56
  57 extern char **environ;
  58 char *newenviron[$#envsave+5];
  59 int i=0;
  60
  61 addenv(char *var, char *val) {
  62         char *s=malloc(strlen(var)+1+strlen(val)+1);
  63         if (!s)
  64                 perror("malloc");
  65         sprintf(s, "%s=%s", var, val);
  66         newenviron[i++]=s;
  67 }
  68
  69 int main (int argc, char **argv) {
  70         /* Sanitize environment. */
  71         char *s;
  72 $envsave
  73         newenviron[i++]="HOME=$ENV{HOME}";
  74         newenviron[i++]="WRAPPED_OPTIONS=$configstring";
  75         newenviron[i]=NULL;
  76         environ=newenviron;
  77
  78         if (setregid(getegid(), -1) != 0 &&
  79             setregid(getegid(), -1) != 0) {
  80                 perror("failed to drop real gid");
  81                 exit(1);
  82         }
  83         if (setreuid(geteuid(), -1) != 0 &&
  84             setreuid(geteuid(), -1) != 0) {
  85                 perror("failed to drop real uid");
  86                 exit(1);
  87         }
  88
  89         execl("$this", "$this", NULL);
  90         perror("exec $this");
  91         exit(1);
  92 }
  93 EOF
  94         close OUT;
  95
  96         my $cc=exists $ENV{CC} ? possibly_foolish_untaint($ENV{CC}) : 'cc';
  97         if (system($cc, "$wrapper.c", "-o", "$wrapper.new") != 0) {
  98                 #translators: The parameter is a C filename.
  99                 error(sprintf(gettext("failed to compile %s"), "$wrapper.c"));
 100         }
 101         unlink("$wrapper.c");
 102         if (defined $config{wrappergroup}) {
 103                 my $gid=(getgrnam($config{wrappergroup}))[2];
 104                 if (! defined $gid) {
 105                         error(sprintf("bad wrappergroup"));
 106                 }
 107                 if (! chown(-1, $gid, "$wrapper.new")) {
 108                         error("chown $wrapper.new: $!");
 109                 }
 110         }
 111         if (defined $config{wrappermode} &&
 112             ! chmod(oct($config{wrappermode}), "$wrapper.new")) {
 113                 error("chmod $wrapper.new: $!");
 114         }
 115         if (! rename("$wrapper.new", $wrapper)) {
 116                 error("rename $wrapper.new $wrapper: $!");
 117         }
 118         #translators: The parameter is a filename.
 119         printf(gettext("successfully generated %s"), $wrapper);
 120         print "\n";
 121 } #}}}
 122
 123 1