git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/inline.pm

   1 #!/usr/bin/perl
   2 # Page inlining and blogging.
   3 package IkiWiki::Plugin::inline;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use IkiWiki 3.00;
   9 use URI;
  10
  11 my %knownfeeds;
  12 my %page_numfeeds;
  13 my @inline;
  14 my $nested=0;
  15
  16 sub import {
  17         hook(type => "getopt", id => "inline", call => \&getopt);
  18         hook(type => "getsetup", id => "inline", call => \&getsetup);
  19         hook(type => "checkconfig", id => "inline", call => \&checkconfig);
  20         hook(type => "sessioncgi", id => "inline", call => \&sessioncgi);
  21         hook(type => "preprocess", id => "inline",
  22                 call => \&IkiWiki::preprocess_inline);
  23         hook(type => "pagetemplate", id => "inline",
  24                 call => \&IkiWiki::pagetemplate_inline);
  25         hook(type => "format", id => "inline", call => \&format, first => 1);
  26         # Hook to change to do pinging since it's called late.
  27         # This ensures each page only pings once and prevents slow
  28         # pings interrupting page builds.
  29         hook(type => "change", id => "inline", call => \&IkiWiki::pingurl);
  30 }
  31
  32 sub getopt () {
  33         eval q{use Getopt::Long};
  34         error($@) if $@;
  35         Getopt::Long::Configure('pass_through');
  36         GetOptions(
  37                 "rss!" => \$config{rss},
  38                 "atom!" => \$config{atom},
  39                 "allowrss!" => \$config{allowrss},
  40                 "allowatom!" => \$config{allowatom},
  41                 "pingurl=s" => sub {
  42                         push @{$config{pingurl}}, $_[1];
  43                 },
  44         );
  45 }
  46
  47 sub getsetup () {
  48         return
  49                 plugin => {
  50                         safe => 1,
  51                         rebuild => undef,
  52                 },
  53                 rss => {
  54                         type => "boolean",
  55                         example => 0,
  56                         description => "enable rss feeds by default?",
  57                         safe => 1,
  58                         rebuild => 1,
  59                 },
  60                 atom => {
  61                         type => "boolean",
  62                         example => 0,
  63                         description => "enable atom feeds by default?",
  64                         safe => 1,
  65                         rebuild => 1,
  66                 },
  67                 allowrss => {
  68                         type => "boolean",
  69                         example => 0,
  70                         description => "allow rss feeds to be used?",
  71                         safe => 1,
  72                         rebuild => 1,
  73                 },
  74                 allowatom => {
  75                         type => "boolean",
  76                         example => 0,
  77                         description => "allow atom feeds to be used?",
  78                         safe => 1,
  79                         rebuild => 1,
  80                 },
  81                 pingurl => {
  82                         type => "string",
  83                         example => "http://rpc.technorati.com/rpc/ping",
  84                         description => "urls to ping (using XML-RPC) on feed update",
  85                         safe => 1,
  86                         rebuild => 0,
  87                 },
  88 }
  89
  90 sub checkconfig () {
  91         if (($config{rss} || $config{atom}) && ! length $config{url}) {
  92                 error(gettext("Must specify url to wiki with --url when using --rss or --atom"));
  93         }
  94         if ($config{rss}) {
  95                 push @{$config{wiki_file_prune_regexps}}, qr/\.rss$/;
  96         }
  97         if ($config{atom}) {
  98                 push @{$config{wiki_file_prune_regexps}}, qr/\.atom$/;
  99         }
 100         if (! exists $config{pingurl}) {
 101                 $config{pingurl}=[];
 102         }
 103 }
 104
 105 sub format (@) {
 106         my %params=@_;
 107
 108         # Fill in the inline content generated earlier. This is actually an
 109         # optimisation.
 110         $params{content}=~s{<div class="inline" id="([^"]+)"></div>}{
 111                 delete @inline[$1,]
 112         }eg;
 113         return $params{content};
 114 }
 115
 116 sub sessioncgi ($$) {
 117         my $q=shift;
 118         my $session=shift;
 119
 120         if ($q->param('do') eq 'blog') {
 121                 my $page=titlepage(decode_utf8($q->param('title')));
 122                 $page=~s/(\/)/"__".ord($1)."__"/eg; # don't create subdirs
 123                 # if the page already exists, munge it to be unique
 124                 my $from=$q->param('from');
 125                 my $add="";
 126                 while (exists $IkiWiki::pagecase{lc($from."/".$page.$add)}) {
 127                         $add=1 unless length $add;
 128                         $add++;
 129                 }
 130                 $q->param('page', $page.$add);
 131                 # now go create the page
 132                 $q->param('do', 'create');
 133                 # make sure the editpage plugin in loaded
 134                 if (IkiWiki->can("cgi_editpage")) {
 135                         IkiWiki::cgi_editpage($q, $session);
 136                 }
 137                 else {
 138                         error(gettext("page editing not allowed"));
 139                 }
 140                 exit;
 141         }
 142 }
 143
 144 # Back to ikiwiki namespace for the rest, this code is very much
 145 # internal to ikiwiki even though it's separated into a plugin.
 146 package IkiWiki;
 147
 148 my %toping;
 149 my %feedlinks;
 150
 151 sub preprocess_inline (@) {
 152         my %params=@_;
 153
 154         if (! exists $params{pages} && ! exists $params{pagenames}) {
 155                 error gettext("missing pages parameter");
 156         }
 157         my $raw=yesno($params{raw});
 158         my $archive=yesno($params{archive});
 159         my $rss=(($config{rss} || $config{allowrss}) && exists $params{rss}) ? yesno($params{rss}) : $config{rss};
 160         my $atom=(($config{atom} || $config{allowatom}) && exists $params{atom}) ? yesno($params{atom}) : $config{atom};
 161         my $quick=exists $params{quick} ? yesno($params{quick}) : 0;
 162         my $feeds=exists $params{feeds} ? yesno($params{feeds}) : !$quick;
 163         my $emptyfeeds=exists $params{emptyfeeds} ? yesno($params{emptyfeeds}) : 1;
 164         my $feedonly=yesno($params{feedonly});
 165         if (! exists $params{show} && ! $archive) {
 166                 $params{show}=10;
 167         }
 168         if (! exists $params{feedshow} && exists $params{show}) {
 169                 $params{feedshow}=$params{show};
 170         }
 171         my $desc;
 172         if (exists $params{description}) {
 173                 $desc = $params{description}
 174         }
 175         else {
 176                 $desc = $config{wikiname};
 177         }
 178         my $actions=yesno($params{actions});
 179         if (exists $params{template}) {
 180                 $params{template}=~s/[^-_a-zA-Z0-9]+//g;
 181         }
 182         else {
 183                 $params{template} = $archive ? "archivepage" : "inlinepage";
 184         }
 185
 186         my @list;
 187
 188         if (exists $params{pagenames}) {
 189                 foreach my $p (qw(sort pages)) {
 190                         if (exists $params{$p}) {
 191                                 error sprintf(gettext("the %s and %s parameters cannot be used together"),
 192                                         "pagenames", $p);
 193                         }
 194                 }
 195
 196                 @list = map { bestlink($params{page}, $_) }
 197                         split ' ', $params{pagenames};
 198
 199                 if (yesno($params{reverse})) {
 200                         @list=reverse(@list);
 201                 }
 202
 203                 foreach my $p (@list) {
 204                         add_depends($params{page}, $p, deptype($quick ? "presence" : "content"));
 205                 }
 206         }
 207         else {
 208                 my $num=0;
 209                 if ($params{show}) {
 210                         $num=$params{show};
 211                 }
 212                 if ($params{feedshow} && $num < $params{feedshow}) {
 213                         $num=$params{feedshow};
 214                 }
 215                 if ($params{skip}) {
 216                         $num+=$params{skip};
 217                 }
 218
 219                 @list = pagespec_match_list($params{page}, $params{pages},
 220                         deptype => deptype($quick ? "presence" : "content"),
 221                         filter => sub { $_[0] eq $params{page} },
 222                         sort => exists $params{sort} ? $params{sort} : "age",
 223                         reverse => yesno($params{reverse}),
 224                         num => $num,
 225                 );
 226         }
 227
 228         if (exists $params{skip}) {
 229                 @list=@list[$params{skip} .. $#list];
 230         }
 231
 232         my @feedlist;
 233         if ($feeds) {
 234                 if (exists $params{feedshow} &&
 235                     $params{feedshow} && @list > $params{feedshow}) {
 236                         @feedlist=@list[0..$params{feedshow} - 1];
 237                 }
 238                 else {
 239                         @feedlist=@list;
 240                 }
 241         }
 242
 243         if ($params{show} && @list > $params{show}) {
 244                 @list=@list[0..$params{show} - 1];
 245         }
 246
 247         if ($feeds && exists $params{feedpages}) {
 248                 @feedlist = pagespec_match_list(
 249                         $params{page}, "($params{pages}) and ($params{feedpages})",
 250                         deptype => deptype($quick ? "presence" : "content"),
 251                         list => \@feedlist,
 252                 );
 253         }
 254
 255         my ($feedbase, $feednum);
 256         if ($feeds) {
 257                 # Ensure that multiple feeds on a page go to unique files.
 258
 259                 # Feedfile can lead to conflicts if usedirs is not enabled,
 260                 # so avoid supporting it in that case.
 261                 delete $params{feedfile} if ! $config{usedirs};
 262                 # Tight limits on legal feedfiles, to avoid security issues
 263                 # and conflicts.
 264                 if (defined $params{feedfile}) {
 265                         if ($params{feedfile} =~ /\// ||
 266                             $params{feedfile} !~ /$config{wiki_file_regexp}/) {
 267                                 error("illegal feedfile");
 268                         }
 269                         $params{feedfile}=possibly_foolish_untaint($params{feedfile});
 270                 }
 271                 $feedbase=targetpage($params{destpage}, "", $params{feedfile});
 272
 273                 my $feedid=join("\0", $feedbase, map { $_."\0".$params{$_} } sort keys %params);
 274                 if (exists $knownfeeds{$feedid}) {
 275                         $feednum=$knownfeeds{$feedid};
 276                 }
 277                 else {
 278                         if (exists $page_numfeeds{$params{destpage}}{$feedbase}) {
 279                                 if ($feeds) {
 280                                         $feednum=$knownfeeds{$feedid}=++$page_numfeeds{$params{destpage}}{$feedbase};
 281                                 }
 282                         }
 283                         else {
 284                                 $feednum=$knownfeeds{$feedid}="";
 285                                 if ($feeds) {
 286                                         $page_numfeeds{$params{destpage}}{$feedbase}=1;
 287                                 }
 288                         }
 289                 }
 290         }
 291
 292         my $rssurl=abs2rel($feedbase."rss".$feednum, dirname(htmlpage($params{destpage}))) if $feeds && $rss;
 293         my $atomurl=abs2rel($feedbase."atom".$feednum, dirname(htmlpage($params{destpage}))) if $feeds && $atom;
 294
 295         my $ret="";
 296
 297         if (length $config{cgiurl} && ! $params{preview} && (exists $params{rootpage} ||
 298             (exists $params{postform} && yesno($params{postform}))) &&
 299             IkiWiki->can("cgi_editpage")) {
 300                 # Add a blog post form, with feed buttons.
 301                 my $formtemplate=template("blogpost.tmpl", blind_cache => 1);
 302                 $formtemplate->param(cgiurl => $config{cgiurl});
 303                 $formtemplate->param(rootpage => rootpage(%params));
 304                 $formtemplate->param(rssurl => $rssurl) if $feeds && $rss;
 305                 $formtemplate->param(atomurl => $atomurl) if $feeds && $atom;
 306                 if (exists $params{postformtext}) {
 307                         $formtemplate->param(postformtext =>
 308                                 $params{postformtext});
 309                 }
 310                 else {
 311                         $formtemplate->param(postformtext =>
 312                                 gettext("Add a new post titled:"));
 313                 }
 314                 $ret.=$formtemplate->output;
 315
 316                 # The post form includes the feed buttons, so
 317                 # emptyfeeds cannot be hidden.
 318                 $emptyfeeds=1;
 319         }
 320         elsif ($feeds && !$params{preview} && ($emptyfeeds || @feedlist)) {
 321                 # Add feed buttons.
 322                 my $linktemplate=template("feedlink.tmpl", blind_cache => 1);
 323                 $linktemplate->param(rssurl => $rssurl) if $rss;
 324                 $linktemplate->param(atomurl => $atomurl) if $atom;
 325                 $ret.=$linktemplate->output;
 326         }
 327
 328         if (! $feedonly) {
 329                 require HTML::Template;
 330                 my @params=IkiWiki::template_params($params{template}.".tmpl", blind_cache => 1);
 331                 if (! @params) {
 332                         error sprintf(gettext("nonexistant template %s"), $params{template});
 333                 }
 334                 my $template=HTML::Template->new(@params) unless $raw;
 335
 336                 foreach my $page (@list) {
 337                         my $file = $pagesources{$page};
 338                         my $type = pagetype($file);
 339                         if (! $raw || ($raw && ! defined $type)) {
 340                                 unless ($archive && $quick) {
 341                                         # Get the content before populating the
 342                                         # template, since getting the content uses
 343                                         # the same template if inlines are nested.
 344                                         my $content=get_inline_content($page, $params{destpage});
 345                                         $template->param(content => $content);
 346                                 }
 347                                 $template->param(pageurl => urlto($page, $params{destpage}));
 348                                 $template->param(inlinepage => $page);
 349                                 $template->param(title => pagetitle(basename($page)));
 350                                 $template->param(ctime => displaytime($pagectime{$page}, $params{timeformat}));
 351                                 $template->param(mtime => displaytime($pagemtime{$page}, $params{timeformat}));
 352                                 $template->param(first => 1) if $page eq $list[0];
 353                                 $template->param(last => 1) if $page eq $list[$#list];
 354
 355                                 if ($actions) {
 356                                         my $file = $pagesources{$page};
 357                                         my $type = pagetype($file);
 358                                         if ($config{discussion}) {
 359                                                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/ &&
 360                                                     (length $config{cgiurl} ||
 361                                                      exists $links{$page."/".$config{discussionpage}})) {
 362                                                         $template->param(have_actions => 1);
 363                                                         $template->param(discussionlink =>
 364                                                                 htmllink($page,
 365                                                                         $params{destpage},
 366                                                                         $config{discussionpage},
 367                                                                         noimageinline => 1,
 368                                                                         forcesubpage => 1));
 369                                                 }
 370                                         }
 371                                         if (length $config{cgiurl} && defined $type) {
 372                                                 $template->param(have_actions => 1);
 373                                                 $template->param(editurl => cgiurl(do => "edit", page => $page));
 374                                         }
 375                                 }
 376
 377                                 run_hooks(pagetemplate => sub {
 378                                         shift->(page => $page, destpage => $params{destpage},
 379                                                 template => $template,);
 380                                 });
 381
 382                                 $ret.=$template->output;
 383                                 $template->clear_params;
 384                         }
 385                         else {
 386                                 if (defined $type) {
 387                                         $ret.="\n".
 388                                               linkify($page, $params{destpage},
 389                                               preprocess($page, $params{destpage},
 390                                               filter($page, $params{destpage},
 391                                               readfile(srcfile($file)))));
 392                                 }
 393                         }
 394                 }
 395         }
 396
 397         if ($feeds && ($emptyfeeds || @feedlist)) {
 398                 if ($rss) {
 399                         my $rssp=$feedbase."rss".$feednum;
 400                         will_render($params{destpage}, $rssp);
 401                         if (! $params{preview}) {
 402                                 writefile($rssp, $config{destdir},
 403                                         genfeed("rss",
 404                                                 $config{url}."/".$rssp, $desc, $params{guid}, $params{destpage}, @feedlist));
 405                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 406                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/rss+xml" title="$desc (RSS)" href="$rssurl" />};
 407                         }
 408                 }
 409                 if ($atom) {
 410                         my $atomp=$feedbase."atom".$feednum;
 411                         will_render($params{destpage}, $atomp);
 412                         if (! $params{preview}) {
 413                                 writefile($atomp, $config{destdir},
 414                                         genfeed("atom", $config{url}."/".$atomp, $desc, $params{guid}, $params{destpage}, @feedlist));
 415                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 416                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/atom+xml" title="$desc (Atom)" href="$atomurl" />};
 417                         }
 418                 }
 419         }
 420
 421         return $ret if $raw || $nested;
 422         push @inline, $ret;
 423         return "<div class=\"inline\" id=\"$#inline\"></div>\n\n";
 424 }
 425
 426 sub pagetemplate_inline (@) {
 427         my %params=@_;
 428         my $page=$params{page};
 429         my $template=$params{template};
 430
 431         $template->param(feedlinks => $feedlinks{$page})
 432                 if exists $feedlinks{$page} && $template->query(name => "feedlinks");
 433 }
 434
 435 sub get_inline_content ($$) {
 436         my $page=shift;
 437         my $destpage=shift;
 438
 439         my $file=$pagesources{$page};
 440         my $type=pagetype($file);
 441         if (defined $type) {
 442                 $nested++;
 443                 my $ret=htmlize($page, $destpage, $type,
 444                        linkify($page, $destpage,
 445                        preprocess($page, $destpage,
 446                        filter($page, $destpage,
 447                        readfile(srcfile($file))))));
 448                 $nested--;
 449                 return $ret;
 450         }
 451         else {
 452                 return "";
 453         }
 454 }
 455
 456 sub date_822 ($) {
 457         my $time=shift;
 458
 459         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 460         POSIX::setlocale(&POSIX::LC_TIME, "C");
 461         my $ret=POSIX::strftime("%a, %d %b %Y %H:%M:%S %z", localtime($time));
 462         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 463         return $ret;
 464 }
 465
 466 sub date_3339 ($) {
 467         my $time=shift;
 468
 469         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 470         POSIX::setlocale(&POSIX::LC_TIME, "C");
 471         my $ret=POSIX::strftime("%Y-%m-%dT%H:%M:%SZ", gmtime($time));
 472         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 473         return $ret;
 474 }
 475
 476 sub absolute_urls ($$) {
 477         # sucky sub because rss sucks
 478         my $content=shift;
 479         my $baseurl=shift;
 480
 481         my $url=$baseurl;
 482         $url=~s/[^\/]+$//;
 483
 484         # what is the non path part of the url?
 485         my $top_uri = URI->new($url);
 486         $top_uri->path_query(""); # reset the path
 487         my $urltop = $top_uri->as_string;
 488
 489         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(#[^"]+)"/$1 href="$baseurl$2"/mig;
 490         # relative to another wiki page
 491         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(?!\w+:)([^\/][^"]*)"/$1 href="$url$2"/mig;
 492         $content=~s/(<img(?:\s+(?:class|id|width|height)\s*="?\w+"?)*)\s+src=\s*"(?!\w+:)([^\/][^"]*)"/$1 src="$url$2"/mig;
 493         # relative to the top of the site
 494         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(?!\w+:)(\/[^"]*)"/$1 href="$urltop$2"/mig;
 495         $content=~s/(<img(?:\s+(?:class|id|width|height)\s*="?\w+"?)*)\s+src=\s*"(?!\w+:)(\/[^"]*)"/$1 src="$urltop$2"/mig;
 496         return $content;
 497 }
 498
 499 sub genfeed ($$$$$@) {
 500         my $feedtype=shift;
 501         my $feedurl=shift;
 502         my $feeddesc=shift;
 503         my $guid=shift;
 504         my $page=shift;
 505         my @pages=@_;
 506
 507         my $url=URI->new(encode_utf8(urlto($page,"",1)));
 508
 509         my $itemtemplate=template($feedtype."item.tmpl", blind_cache => 1);
 510         my $content="";
 511         my $lasttime = 0;
 512         foreach my $p (@pages) {
 513                 my $u=URI->new(encode_utf8(urlto($p, "", 1)));
 514                 my $pcontent = absolute_urls(get_inline_content($p, $page), $url);
 515
 516                 $itemtemplate->param(
 517                         title => pagetitle(basename($p)),
 518                         url => $u,
 519                         permalink => $u,
 520                         cdate_822 => date_822($pagectime{$p}),
 521                         mdate_822 => date_822($pagemtime{$p}),
 522                         cdate_3339 => date_3339($pagectime{$p}),
 523                         mdate_3339 => date_3339($pagemtime{$p}),
 524                 );
 525
 526                 if (exists $pagestate{$p}) {
 527                         if (exists $pagestate{$p}{meta}{guid}) {
 528                                 $itemtemplate->param(guid => $pagestate{$p}{meta}{guid});
 529                         }
 530
 531                         if (exists $pagestate{$p}{meta}{updated}) {
 532                                 $itemtemplate->param(mdate_822 => date_822($pagestate{$p}{meta}{updated}));
 533                                 $itemtemplate->param(mdate_3339 => date_3339($pagestate{$p}{meta}{updated}));
 534                         }
 535                 }
 536
 537                 if ($itemtemplate->query(name => "enclosure")) {
 538                         my $file=$pagesources{$p};
 539                         my $type=pagetype($file);
 540                         if (defined $type) {
 541                                 $itemtemplate->param(content => $pcontent);
 542                         }
 543                         else {
 544                                 my $size=(srcfile_stat($file))[8];
 545                                 my $mime="unknown";
 546                                 eval q{use File::MimeInfo};
 547                                 if (! $@) {
 548                                         $mime = mimetype($file);
 549                                 }
 550                                 $itemtemplate->param(
 551                                         enclosure => $u,
 552                                         type => $mime,
 553                                         length => $size,
 554                                 );
 555                         }
 556                 }
 557                 else {
 558                         $itemtemplate->param(content => $pcontent);
 559                 }
 560
 561                 run_hooks(pagetemplate => sub {
 562                         shift->(page => $p, destpage => $page,
 563                                 template => $itemtemplate);
 564                 });
 565
 566                 $content.=$itemtemplate->output;
 567                 $itemtemplate->clear_params;
 568
 569                 $lasttime = $pagemtime{$p} if $pagemtime{$p} > $lasttime;
 570         }
 571
 572         my $template=template($feedtype."page.tmpl", blind_cache => 1);
 573         $template->param(
 574                 title => $page ne "index" ? pagetitle($page) : $config{wikiname},
 575                 wikiname => $config{wikiname},
 576                 pageurl => $url,
 577                 content => $content,
 578                 feeddesc => $feeddesc,
 579                 guid => $guid,
 580                 feeddate => date_3339($lasttime),
 581                 feedurl => $feedurl,
 582                 version => $IkiWiki::version,
 583         );
 584         run_hooks(pagetemplate => sub {
 585                 shift->(page => $page, destpage => $page,
 586                         template => $template);
 587         });
 588
 589         return $template->output;
 590 }
 591
 592 sub pingurl (@) {
 593         return unless @{$config{pingurl}} && %toping;
 594
 595         eval q{require RPC::XML::Client};
 596         if ($@) {
 597                 debug(gettext("RPC::XML::Client not found, not pinging"));
 598                 return;
 599         }
 600
 601         # daemonize here so slow pings don't slow down wiki updates
 602         defined(my $pid = fork) or error("Can't fork: $!");
 603         return if $pid;
 604         chdir '/';
 605         POSIX::setsid() or error("Can't start a new session: $!");
 606         open STDIN, '/dev/null';
 607         open STDOUT, '>/dev/null';
 608         open STDERR, '>&STDOUT' or error("Can't dup stdout: $!");
 609
 610         # Don't need to keep a lock on the wiki as a daemon.
 611         IkiWiki::unlockwiki();
 612
 613         foreach my $page (keys %toping) {
 614                 my $title=pagetitle(basename($page), 0);
 615                 my $url=urlto($page, "", 1);
 616                 foreach my $pingurl (@{$config{pingurl}}) {
 617                         debug("Pinging $pingurl for $page");
 618                         eval {
 619                                 my $client = RPC::XML::Client->new($pingurl);
 620                                 my $req = RPC::XML::request->new('weblogUpdates.ping',
 621                                         $title, $url);
 622                                 my $res = $client->send_request($req);
 623                                 if (! ref $res) {
 624                                         error("Did not receive response to ping");
 625                                 }
 626                                 my $r=$res->value;
 627                                 if (! exists $r->{flerror} || $r->{flerror}) {
 628                                         error("Ping rejected: ".(exists $r->{message} ? $r->{message} : "[unknown reason]"));
 629                                 }
 630                         };
 631                         if ($@) {
 632                                 error "Ping failed: $@";
 633                         }
 634                 }
 635         }
 636
 637         exit 0; # daemon done
 638 }
 639
 640
 641 sub rootpage (@) {
 642         my %params=@_;
 643
 644         my $rootpage;
 645         if (exists $params{rootpage}) {
 646                 $rootpage=bestlink($params{page}, $params{rootpage});
 647                 if (!length $rootpage) {
 648                         $rootpage=$params{rootpage};
 649                 }
 650         }
 651         else {
 652                 $rootpage=$params{page};
 653         }
 654         return $rootpage;
 655 }
 656
 657 1