git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/color.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki text colouring plugin
   3 # Paweł‚ Tęcza <ptecza@net.icm.edu.pl>
   4 package IkiWiki::Plugin::color;
   5
   6 use warnings;
   7 use strict;
   8 use IkiWiki 3.00;
   9
  10 sub import {
  11         hook(type => "preprocess", id => "color", call => \&preprocess);
  12         hook(type => "format",     id => "color", call => \&format);
  13         hook(type => "getsetup",   id => "color", call => \&getsetup);
  14 }
  15
  16 sub getsetup () {
  17         return
  18                 plugin => {
  19                         safe => 1,
  20                         rebuild => undef,
  21                         section => "widget",
  22                 },
  23 }
  24
  25 sub preserve_style ($$$) {
  26         my $foreground = shift;
  27         my $background = shift;
  28         my $text       = shift;
  29
  30         $foreground = defined $foreground ? lc($foreground) : '';
  31         $background = defined $background ? lc($background) : '';
  32         $text       = '' unless (defined $text);
  33
  34         # Validate colors. Only color name or color code are valid.
  35         $foreground = '' unless ($foreground &&
  36                                 ($foreground =~ /^[a-z]+$/ || $foreground =~ /^#[0-9a-f]{3,6}$/));
  37         $background = '' unless ($background &&
  38                                 ($background =~ /^[a-z]+$/ || $background =~ /^#[0-9a-f]{3,6}$/));
  39
  40         my $preserved = '';
  41         $preserved .= '<span class="color">';
  42         $preserved .= 'color: '.$foreground if ($foreground);
  43         $preserved .= '; ' if ($foreground && $background);
  44         $preserved .= 'background-color: '.$background if ($background);
  45         $preserved .= '</span>';
  46         $preserved .= '<span class="colorend">'.$text.'</span>';
  47
  48         return $preserved;
  49
  50 }
  51
  52 sub replace_preserved_style ($) {
  53         my $content = shift;
  54
  55         $content =~ s!<span class="color">((color: ([a-z]+|\#[0-9a-f]{3,6})?)?((; )?(background-color: ([a-z]+|\#[0-9a-f]{3,6})?)?)?)</span>!<span class="color" style="$1">!g;
  56         $content =~ s!<span class="colorend">!!g;
  57
  58         return $content;
  59 }
  60
  61 sub preprocess (@) {
  62         my %params = @_;
  63
  64         # Preprocess the text to expand any preprocessor directives
  65         # embedded inside it.
  66         $params{text} = IkiWiki::preprocess($params{page}, $params{destpage},
  67                                 IkiWiki::filter($params{page}, $params{destpage}, $params{text}));
  68
  69         return preserve_style($params{foreground}, $params{background}, $params{text});
  70 }
  71
  72 sub format (@) {
  73         my %params = @_;
  74
  75         $params{content} = replace_preserved_style($params{content});
  76         return $params{content};
  77 }
  78
  79 1