git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/editpage.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::editpage;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki;
   7 use open qw{:utf8 :std};
   8
   9 sub import {
  10         hook(type => "getsetup", id => "editpage", call => \&getsetup);
  11         hook(type => "refresh", id => "editpage", call => \&refresh);
  12         hook(type => "sessioncgi", id => "editpage", call => \&IkiWiki::cgi_editpage);
  13 }
  14
  15 sub getsetup () {
  16         return
  17                 plugin => {
  18                         safe => 1,
  19                         rebuild => 1,
  20                 },
  21 }
  22
  23 sub refresh () {
  24         if (exists $wikistate{editpage} && exists $wikistate{editpage}{previews}) {
  25                 # Expire old preview files after one hour.
  26                 my $expire=time - (60 * 60);
  27
  28                 my @previews;
  29                 foreach my $file (@{$wikistate{editpage}{previews}}) {
  30                         my $mtime=(stat("$config{destdir}/$file"))[9];
  31                         if (defined $mtime && $mtime <= $expire) {
  32                                 # Avoid deleting a preview that was later saved.
  33                                 my $delete=1;
  34                                 foreach my $page (keys %renderedfiles) {
  35                                         if (grep { $_ eq $file } @{$renderedfiles{$page}}) {
  36                                                 $delete=0;
  37                                         }
  38                                 }
  39                                 if ($delete) {
  40                                         debug(sprintf(gettext("removing old preview %s"), $file));
  41                                         IkiWiki::prune("$config{destdir}/$file");
  42                                 }
  43                         }
  44                         elsif (defined $mtime) {
  45                                 push @previews, $file;
  46                         }
  47                 }
  48                 $wikistate{editpage}{previews}=\@previews;
  49         }
  50 }
  51
  52 # Back to ikiwiki namespace for the rest, this code is very much
  53 # internal to ikiwiki even though it's separated into a plugin,
  54 # and other plugins use the functions below.
  55 package IkiWiki;
  56
  57 sub check_canedit ($$$;$) {
  58         my $page=shift;
  59         my $q=shift;
  60         my $session=shift;
  61         my $nonfatal=shift;
  62
  63         my $canedit;
  64         run_hooks(canedit => sub {
  65                 return if defined $canedit;
  66                 my $ret=shift->($page, $q, $session);
  67                 if (defined $ret) {
  68                         if ($ret eq "") {
  69                                 $canedit=1;
  70                         }
  71                         elsif (ref $ret eq 'CODE') {
  72                                 $ret->() unless $nonfatal;
  73                                 $canedit=0;
  74                         }
  75                         elsif (defined $ret) {
  76                                 error($ret) unless $nonfatal;
  77                                 $canedit=0;
  78                         }
  79                 }
  80         });
  81         return defined $canedit ? $canedit : 1;
  82 }
  83
  84 sub check_content (@) {
  85         my %params=@_;
  86
  87         return 1 if ! exists $hooks{checkcontent}; # optimisation
  88
  89         if (exists $pagesources{$params{page}}) {
  90                 my @diff;
  91                 my %old=map { $_ => 1 }
  92                         split("\n", readfile(srcfile($pagesources{$params{page}})));
  93                 foreach my $line (split("\n", $params{content})) {
  94                         push @diff, $line if ! exists $old{$_};
  95                 }
  96                 $params{content}=join("\n", @diff);
  97         }
  98
  99         my $ok;
 100         run_hooks(checkcontent => sub {
 101                 return if defined $ok;
 102                 my $ret=shift->(%params);
 103                 if (defined $ret) {
 104                         if ($ret eq "") {
 105                                 $ok=1;
 106                         }
 107                         elsif (ref $ret eq 'CODE') {
 108                                 $ret->();
 109                                 $ok=0;
 110                         }
 111                         elsif (defined $ret) {
 112                                 error($ret);
 113                         }
 114                 }
 115
 116         });
 117         return defined $ok ? $ok : 1;
 118 }
 119
 120 sub check_cansave ($$$$) {
 121         my $page=shift;
 122         my $content=shift;
 123         my $q=shift;
 124         my $session=shift;
 125
 126         my $cansave;
 127         run_hooks(cansave => sub {
 128                 return if defined $cansave;
 129                 my $ret=shift->($page, $content, $q, $session);
 130                 if (defined $ret) {
 131                         if ($ret eq "") {
 132                                 $cansave=1;
 133                         }
 134                         elsif (ref $ret eq 'CODE') {
 135                                 $ret->();
 136                                 $cansave=0;
 137                         }
 138                         else {
 139                                 error($ret);
 140                                 $cansave=0;
 141                         }
 142                 }
 143         });
 144         return $cansave;
 145 }
 146
 147 sub cgi_editpage ($$) {
 148         my $q=shift;
 149         my $session=shift;
 150
 151         my $do=$q->param('do');
 152         return unless $do eq 'create' || $do eq 'edit';
 153
 154         decode_cgi_utf8($q);
 155
 156         my @fields=qw(do rcsinfo subpage from page type editcontent comments);
 157         my @buttons=("Save Page", "Preview", "Cancel");
 158         eval q{use CGI::FormBuilder};
 159         error($@) if $@;
 160         my $form = CGI::FormBuilder->new(
 161                 fields => \@fields,
 162                 charset => "utf-8",
 163                 method => 'POST',
 164                 required => [qw{editcontent}],
 165                 javascript => 0,
 166                 params => $q,
 167                 action => $config{cgiurl},
 168                 header => 0,
 169                 table => 0,
 170                 template => scalar template_params("editpage.tmpl"),
 171         );
 172
 173         decode_form_utf8($form);
 174         run_hooks(formbuilder_setup => sub {
 175                 shift->(form => $form, cgi => $q, session => $session,
 176                         buttons => \@buttons);
 177         });
 178         decode_form_utf8($form);
 179
 180         # This untaint is safe because we check file_pruned and
 181         # wiki_file_regexp.
 182         my ($page)=$form->field('page')=~/$config{wiki_file_regexp}/;
 183         $page=possibly_foolish_untaint($page);
 184         my $absolute=($page =~ s#^/+##);
 185         if (! defined $page || ! length $page ||
 186             file_pruned($page, $config{srcdir})) {
 187                 error(gettext("bad page name"));
 188         }
 189
 190         my $baseurl = urlto($page, undef, 1);
 191
 192         my $from;
 193         if (defined $form->field('from')) {
 194                 ($from)=$form->field('from')=~/$config{wiki_file_regexp}/;
 195         }
 196
 197         my $file;
 198         my $type;
 199         if (exists $pagesources{$page} && $form->field("do") ne "create") {
 200                 $file=$pagesources{$page};
 201                 $type=pagetype($file);
 202                 if (! defined $type || $type=~/^_/) {
 203                         error(sprintf(gettext("%s is not an editable page"), $page));
 204                 }
 205                 if (! $form->submitted) {
 206                         $form->field(name => "rcsinfo",
 207                                 value => rcs_prepedit($file), force => 1);
 208                 }
 209                 $form->field(name => "editcontent", validate => '/.*/');
 210         }
 211         else {
 212                 $type=$form->param('type');
 213                 if (defined $type && length $type && $hooks{htmlize}{$type}) {
 214                         $type=possibly_foolish_untaint($type);
 215                 }
 216                 elsif (defined $from && exists $pagesources{$from}) {
 217                         # favor the type of linking page
 218                         $type=pagetype($pagesources{$from});
 219                 }
 220                 $type=$config{default_pageext} unless defined $type;
 221                 $file=newpagefile($page, $type);
 222                 if (! $form->submitted) {
 223                         $form->field(name => "rcsinfo", value => "", force => 1);
 224                 }
 225                 $form->field(name => "editcontent", validate => '/.+/');
 226         }
 227
 228         $form->field(name => "do", type => 'hidden');
 229         $form->field(name => "sid", type => "hidden", value => $session->id,
 230                 force => 1);
 231         $form->field(name => "from", type => 'hidden');
 232         $form->field(name => "rcsinfo", type => 'hidden');
 233         $form->field(name => "subpage", type => 'hidden');
 234         $form->field(name => "page", value => $page, force => 1);
 235         $form->field(name => "type", value => $type, force => 1);
 236         $form->field(name => "comments", type => "text", size => 80);
 237         $form->field(name => "editcontent", type => "textarea", rows => 20,
 238                 cols => 80);
 239         $form->tmpl_param("can_commit", $config{rcs});
 240         $form->tmpl_param("indexlink", indexlink());
 241         $form->tmpl_param("helponformattinglink",
 242                 htmllink($page, $page, "ikiwiki/formatting",
 243                         noimageinline => 1,
 244                         linktext => "FormattingHelp"));
 245
 246         if ($form->submitted eq "Cancel") {
 247                 if ($form->field("do") eq "create" && defined $from) {
 248                         redirect($q, urlto($from, undef, 1));
 249                 }
 250                 elsif ($form->field("do") eq "create") {
 251                         redirect($q, $config{url});
 252                 }
 253                 else {
 254                         redirect($q, urlto($page, undef, 1));
 255                 }
 256                 exit;
 257         }
 258         elsif ($form->submitted eq "Preview") {
 259                 my $new=not exists $pagesources{$page};
 260                 if ($new) {
 261                         # temporarily record its type
 262                         $pagesources{$page}=$page.".".$type;
 263                 }
 264                 my %wasrendered=map { $_ => 1 } @{$renderedfiles{$page}};
 265
 266                 my $content=$form->field('editcontent');
 267
 268                 run_hooks(editcontent => sub {
 269                         $content=shift->(
 270                                 content => $content,
 271                                 page => $page,
 272                                 cgi => $q,
 273                                 session => $session,
 274                         );
 275                 });
 276                 my $preview=htmlize($page, $page, $type,
 277                         linkify($page, $page,
 278                         preprocess($page, $page,
 279                         filter($page, $page, $content), 0, 1)));
 280                 run_hooks(format => sub {
 281                         $preview=shift->(
 282                                 page => $page,
 283                                 content => $preview,
 284                         );
 285                 });
 286                 $form->tmpl_param("page_preview", $preview);
 287
 288                 if ($new) {
 289                         delete $pagesources{$page};
 290                 }
 291
 292                 # Previewing may have created files on disk.
 293                 # Keep a list of these to be deleted later.
 294                 my %previews = map { $_ => 1 } @{$wikistate{editpage}{previews}};
 295                 foreach my $f (@{$renderedfiles{$page}}) {
 296                         $previews{$f}=1 unless $wasrendered{$f};
 297                 }
 298                 @{$wikistate{editpage}{previews}} = keys %previews;
 299                 $renderedfiles{$page}=[keys %wasrendered];
 300                 saveindex();
 301         }
 302         elsif ($form->submitted eq "Save Page") {
 303                 $form->tmpl_param("page_preview", "");
 304         }
 305
 306         if ($form->submitted ne "Save Page" || ! $form->validate) {
 307                 if ($form->field("do") eq "create") {
 308                         my @page_locs;
 309                         my $best_loc;
 310                         if (! defined $from || ! length $from ||
 311                             $from ne $form->field('from') ||
 312                             file_pruned($from, $config{srcdir}) ||
 313                             $from=~/^\// ||
 314                             $absolute ||
 315                             $form->submitted) {
 316                                 @page_locs=$best_loc=$page;
 317                         }
 318                         else {
 319                                 my $dir=$from."/";
 320                                 $dir=~s![^/]+/+$!!;
 321
 322                                 if ((defined $form->field('subpage') && length $form->field('subpage')) ||
 323                                     $page eq gettext('discussion')) {
 324                                         $best_loc="$from/$page";
 325                                 }
 326                                 else {
 327                                         $best_loc=$dir.$page;
 328                                 }
 329
 330                                 push @page_locs, $dir.$page;
 331                                 push @page_locs, "$from/$page";
 332                                 while (length $dir) {
 333                                         $dir=~s![^/]+/+$!!;
 334                                         push @page_locs, $dir.$page;
 335                                 }
 336
 337                                 push @page_locs, "$config{userdir}/$page"
 338                                         if length $config{userdir};
 339                         }
 340
 341                         @page_locs = grep {
 342                                 ! exists $pagecase{lc $_}
 343                         } @page_locs;
 344                         if (! @page_locs) {
 345                                 # hmm, someone else made the page in the
 346                                 # meantime?
 347                                 if ($form->submitted eq "Preview") {
 348                                         # let them go ahead with the edit
 349                                         # and resolve the conflict at save
 350                                         # time
 351                                         @page_locs=$page;
 352                                 }
 353                                 else {
 354                                         redirect($q, urlto($page, undef, 1));
 355                                         exit;
 356                                 }
 357                         }
 358
 359                         my @editable_locs = grep {
 360                                 check_canedit($_, $q, $session, 1)
 361                         } @page_locs;
 362                         if (! @editable_locs) {
 363                                 # let it throw an error this time
 364                                 map { check_canedit($_, $q, $session) } @page_locs;
 365                         }
 366
 367                         my @page_types;
 368                         if (exists $hooks{htmlize}) {
 369                                 @page_types=grep { !/^_/ }
 370                                         keys %{$hooks{htmlize}};
 371                         }
 372
 373                         $form->tmpl_param("page_select", 1);
 374                         $form->field(name => "page", type => 'select',
 375                                 options => [ map { [ $_, pagetitle($_, 1) ] } @editable_locs ],
 376                                 value => $best_loc);
 377                         $form->field(name => "type", type => 'select',
 378                                 options => \@page_types);
 379                         $form->title(sprintf(gettext("creating %s"), pagetitle($page)));
 380
 381                 }
 382                 elsif ($form->field("do") eq "edit") {
 383                         check_canedit($page, $q, $session);
 384                         if (! defined $form->field('editcontent') ||
 385                             ! length $form->field('editcontent')) {
 386                                 my $content="";
 387                                 if (exists $pagesources{$page}) {
 388                                         $content=readfile(srcfile($pagesources{$page}));
 389                                         $content=~s/\n/\r\n/g;
 390                                 }
 391                                 $form->field(name => "editcontent", value => $content,
 392                                         force => 1);
 393                         }
 394                         $form->tmpl_param("page_select", 0);
 395                         $form->field(name => "page", type => 'hidden');
 396                         $form->field(name => "type", type => 'hidden');
 397                         $form->title(sprintf(gettext("editing %s"), pagetitle($page)));
 398                 }
 399
 400                 showform($form, \@buttons, $session, $q, forcebaseurl => $baseurl);
 401         }
 402         else {
 403                 # save page
 404                 check_canedit($page, $q, $session);
 405                 checksessionexpiry($q, $session, $q->param('sid'));
 406
 407                 my $exists=-e "$config{srcdir}/$file";
 408
 409                 if ($form->field("do") ne "create" && ! $exists &&
 410                     ! defined srcfile($file, 1)) {
 411                         $form->tmpl_param("message", template("editpagegone.tmpl")->output);
 412                         $form->field(name => "do", value => "create", force => 1);
 413                         $form->tmpl_param("page_select", 0);
 414                         $form->field(name => "page", type => 'hidden');
 415                         $form->field(name => "type", type => 'hidden');
 416                         $form->title(sprintf(gettext("editing %s"), $page));
 417                         showform($form, \@buttons, $session, $q, forcebaseurl => $baseurl);
 418                         exit;
 419                 }
 420                 elsif ($form->field("do") eq "create" && $exists) {
 421                         $form->tmpl_param("message", template("editcreationconflict.tmpl")->output);
 422                         $form->field(name => "do", value => "edit", force => 1);
 423                         $form->tmpl_param("page_select", 0);
 424                         $form->field(name => "page", type => 'hidden');
 425                         $form->field(name => "type", type => 'hidden');
 426                         $form->title(sprintf(gettext("editing %s"), $page));
 427                         $form->field("editcontent",
 428                                 value => readfile("$config{srcdir}/$file").
 429                                          "\n\n\n".$form->field("editcontent"),
 430                                 force => 1);
 431                         showform($form, \@buttons, $session, $q, forcebaseurl => $baseurl);
 432                         exit;
 433                 }
 434
 435                 my $message="";
 436                 if (defined $form->field('comments') &&
 437                     length $form->field('comments')) {
 438                         $message=$form->field('comments');
 439                 }
 440
 441                 my $content=$form->field('editcontent');
 442                 check_cansave($page, $content, $q, $session);
 443                 check_content(content => $content, page => $page,
 444                         cgi => $q, session => $session,
 445                         subject => $message);
 446                 run_hooks(editcontent => sub {
 447                         $content=shift->(
 448                                 content => $content,
 449                                 page => $page,
 450                                 cgi => $q,
 451                                 session => $session,
 452                         );
 453                 });
 454                 $content=~s/\r\n/\n/g;
 455                 $content=~s/\r/\n/g;
 456                 $content.="\n" if $content !~ /\n$/;
 457
 458                 $config{cgi}=0; # avoid cgi error message
 459                 eval { writefile($file, $config{srcdir}, $content) };
 460                 $config{cgi}=1;
 461                 if ($@) {
 462                         $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 463                                 force => 1);
 464                         my $mtemplate=template("editfailedsave.tmpl");
 465                         $mtemplate->param(error_message => $@);
 466                         $form->tmpl_param("message", $mtemplate->output);
 467                         $form->field("editcontent", value => $content, force => 1);
 468                         $form->tmpl_param("page_select", 0);
 469                         $form->field(name => "page", type => 'hidden');
 470                         $form->field(name => "type", type => 'hidden');
 471                         $form->title(sprintf(gettext("editing %s"), $page));
 472                         showform($form, \@buttons, $session, $q,
 473                                 forcebaseurl => $baseurl);
 474                         exit;
 475                 }
 476
 477                 my $conflict;
 478                 if ($config{rcs}) {
 479                         if (! $exists) {
 480                                 rcs_add($file);
 481                         }
 482
 483                         # Prevent deadlock with post-commit hook by
 484                         # signaling to it that it should not try to
 485                         # do anything.
 486                         disable_commit_hook();
 487                         $conflict=rcs_commit($file, $message,
 488                                 $form->field("rcsinfo"),
 489                                 $session->param("name"), $ENV{REMOTE_ADDR});
 490                         enable_commit_hook();
 491                         rcs_update();
 492                 }
 493
 494                 # Refresh even if there was a conflict, since other changes
 495                 # may have been committed while the post-commit hook was
 496                 # disabled.
 497                 require IkiWiki::Render;
 498                 refresh();
 499                 saveindex();
 500
 501                 if (defined $conflict) {
 502                         $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 503                                 force => 1);
 504                         $form->tmpl_param("message", template("editconflict.tmpl")->output);
 505                         $form->field("editcontent", value => $conflict, force => 1);
 506                         $form->field("do", "edit", force => 1);
 507                         $form->tmpl_param("page_select", 0);
 508                         $form->field(name => "page", type => 'hidden');
 509                         $form->field(name => "type", type => 'hidden');
 510                         $form->title(sprintf(gettext("editing %s"), $page));
 511                         showform($form, \@buttons, $session, $q,
 512                                 forcebaseurl => $baseurl);
 513                 }
 514                 else {
 515                         # The trailing question mark tries to avoid broken
 516                         # caches and get the most recent version of the page.
 517                         redirect($q, urlto($page, undef, 1)."?updated");
 518                 }
 519         }
 520
 521         exit;
 522 }
 523
 524 1