git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/po.pm

   1 #!/usr/bin/perl
   2 # .po as a wiki page type
   3 # Licensed under GPL v2 or greater
   4 # Copyright (C) 2008-2009 intrigeri <intrigeri@boum.org>
   5 # inspired by the GPL'd po4a-translate,
   6 # which is Copyright 2002, 2003, 2004 by Martin Quinson (mquinson#debian.org)
   7 package IkiWiki::Plugin::po;
   8
   9 use warnings;
  10 use strict;
  11 use IkiWiki 3.00;
  12 use Encode;
  13 use Locale::Po4a::Chooser;
  14 use Locale::Po4a::Po;
  15 use File::Basename;
  16 use File::Copy;
  17 use File::Spec;
  18 use File::Temp;
  19 use Memoize;
  20 use UNIVERSAL;
  21
  22 my %translations;
  23 my @origneedsbuild;
  24 my %origsubs;
  25
  26 memoize("istranslatable");
  27 memoize("_istranslation");
  28 memoize("percenttranslated");
  29
  30 sub import {
  31         hook(type => "getsetup", id => "po", call => \&getsetup);
  32         hook(type => "checkconfig", id => "po", call => \&checkconfig);
  33         hook(type => "needsbuild", id => "po", call => \&needsbuild);
  34         hook(type => "scan", id => "po", call => \&scan, last =>1);
  35         hook(type => "filter", id => "po", call => \&filter);
  36         hook(type => "htmlize", id => "po", call => \&htmlize);
  37         hook(type => "pagetemplate", id => "po", call => \&pagetemplate, last => 1);
  38         hook(type => "postscan", id => "po", call => \&postscan);
  39         hook(type => "rename", id => "po", call => \&renamepages, first => 1);
  40         hook(type => "delete", id => "po", call => \&mydelete);
  41         hook(type => "change", id => "po", call => \&change);
  42         hook(type => "cansave", id => "po", call => \&cansave);
  43         hook(type => "canremove", id => "po", call => \&canremove);
  44         hook(type => "canrename", id => "po", call => \&canrename);
  45         hook(type => "editcontent", id => "po", call => \&editcontent);
  46         hook(type => "formbuilder_setup", id => "po", call => \&formbuilder_setup, last => 1);
  47         hook(type => "formbuilder", id => "po", call => \&formbuilder);
  48
  49         $origsubs{'bestlink'}=\&IkiWiki::bestlink;
  50         inject(name => "IkiWiki::bestlink", call => \&mybestlink);
  51         $origsubs{'beautify_urlpath'}=\&IkiWiki::beautify_urlpath;
  52         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
  53         $origsubs{'targetpage'}=\&IkiWiki::targetpage;
  54         inject(name => "IkiWiki::targetpage", call => \&mytargetpage);
  55         $origsubs{'urlto'}=\&IkiWiki::urlto;
  56         inject(name => "IkiWiki::urlto", call => \&myurlto);
  57         $origsubs{'nicepagetitle'}=\&IkiWiki::nicepagetitle;
  58         inject(name => "IkiWiki::nicepagetitle", call => \&mynicepagetitle);
  59 }
  60
  61
  62 # ,----
  63 # | Table of contents
  64 # `----
  65
  66 # 1. Hooks
  67 # 2. Injected functions
  68 # 3. Blackboxes for private data
  69 # 4. Helper functions
  70 # 5. PageSpec's
  71
  72
  73 # ,----
  74 # | Hooks
  75 # `----
  76
  77 sub getsetup () {
  78         return
  79                 plugin => {
  80                         safe => 0,
  81                         rebuild => 1,
  82                 },
  83                 po_master_language => {
  84                         type => "string",
  85                         example => {
  86                                 'code' => 'en',
  87                                 'name' => 'English'
  88                         },
  89                         description => "master language (non-PO files)",
  90                         safe => 1,
  91                         rebuild => 1,
  92                 },
  93                 po_slave_languages => {
  94                         type => "string",
  95                         example => {
  96                                 'fr' => 'Français',
  97                                 'es' => 'Castellano',
  98                                 'de' => 'Deutsch'
  99                         },
 100                         description => "slave languages (PO files)",
 101                         safe => 1,
 102                         rebuild => 1,
 103                 },
 104                 po_translatable_pages => {
 105                         type => "pagespec",
 106                         example => "!*/Discussion",
 107                         description => "PageSpec controlling which pages are translatable",
 108                         link => "ikiwiki/PageSpec",
 109                         safe => 1,
 110                         rebuild => 1,
 111                 },
 112                 po_link_to => {
 113                         type => "string",
 114                         example => "current",
 115                         description => "internal linking behavior (default/current/negotiated)",
 116                         safe => 1,
 117                         rebuild => 1,
 118                 },
 119                 po_translation_status_in_links => {
 120                         type => "boolean",
 121                         example => 1,
 122                         description => "display translation status in links to translations",
 123                         safe => 1,
 124                         rebuild => 1,
 125                 },
 126 }
 127
 128 sub checkconfig () {
 129         foreach my $field (qw{po_master_language po_slave_languages}) {
 130                 if (! exists $config{$field} || ! defined $config{$field}) {
 131                         error(sprintf(gettext("Must specify %s when using the %s plugin"),
 132                                       $field, 'po'));
 133                 }
 134         }
 135         if (! (keys %{$config{po_slave_languages}})) {
 136                 error(gettext("At least one slave language must be defined ".
 137                               "in po_slave_languages when using the po plugin"));
 138         }
 139         map {
 140                 islanguagecode($_)
 141                         or error(sprintf(gettext("%s is not a valid language code"), $_));
 142         } ($config{po_master_language}{code}, keys %{$config{po_slave_languages}});
 143         if (! exists $config{po_translatable_pages} ||
 144             ! defined $config{po_translatable_pages}) {
 145                 $config{po_translatable_pages}="";
 146         }
 147         if (! exists $config{po_link_to} ||
 148             ! defined $config{po_link_to}) {
 149                 $config{po_link_to}='default';
 150         }
 151         elsif (! grep {
 152                         $config{po_link_to} eq $_
 153                 } ('default', 'current', 'negotiated')) {
 154                 warn(sprintf(gettext('%s is not a valid value for po_link_to, falling back to po_link_to=default'),
 155                              $config{po_link_to}));
 156                 $config{po_link_to}='default';
 157         }
 158         elsif ($config{po_link_to} eq "negotiated" && ! $config{usedirs}) {
 159                 warn(gettext('po_link_to=negotiated requires usedirs to be enabled, falling back to po_link_to=default'));
 160                 $config{po_link_to}='default';
 161         }
 162         if (! exists $config{po_translation_status_in_links} ||
 163             ! defined $config{po_translation_status_in_links}) {
 164                 $config{po_translation_status_in_links}=1;
 165         }
 166         push @{$config{wiki_file_prune_regexps}}, qr/\.pot$/;
 167 }
 168
 169 sub needsbuild () {
 170         my $needsbuild=shift;
 171
 172         # backup @needsbuild content so that change() can know whether
 173         # a given master page was rendered because its source file was changed
 174         @origneedsbuild=(@$needsbuild);
 175
 176         flushmemoizecache();
 177         buildtranslationscache();
 178
 179         # make existing translations depend on the corresponding master page
 180         foreach my $master (keys %translations) {
 181                 map add_depends($_, $master), values %{otherlanguages($master)};
 182         }
 183 }
 184
 185 # Massage the recorded state of internal links so that:
 186 # - it matches the actually generated links, rather than the links as written
 187 #   in the pages' source
 188 # - backlinks are consistent in all cases
 189 sub scan (@) {
 190         my %params=@_;
 191         my $page=$params{page};
 192         my $content=$params{content};
 193
 194         return unless UNIVERSAL::can("IkiWiki::Plugin::link", "import");
 195
 196         if (istranslation($page)) {
 197                 foreach my $destpage (@{$links{$page}}) {
 198                         if (istranslatable($destpage)) {
 199                                 # replace one occurence of $destpage in $links{$page}
 200                                 # (we only want to replace the one that was added by
 201                                 # IkiWiki::Plugin::link::scan, other occurences may be
 202                                 # there for other reasons)
 203                                 for (my $i=0; $i<@{$links{$page}}; $i++) {
 204                                         if (@{$links{$page}}[$i] eq $destpage) {
 205                                                 @{$links{$page}}[$i] = $destpage . '.' . lang($page);
 206                                                 last;
 207                                         }
 208                                 }
 209                         }
 210                 }
 211         }
 212         elsif (! istranslatable($page) && ! istranslation($page)) {
 213                 foreach my $destpage (@{$links{$page}}) {
 214                         if (istranslatable($destpage)) {
 215                                 # make sure any destpage's translations has
 216                                 # $page in its backlinks
 217                                 push @{$links{$page}},
 218                                         values %{otherlanguages($destpage)};
 219                         }
 220                 }
 221         }
 222 }
 223
 224 # We use filter to convert PO to the master page's format,
 225 # since the rest of ikiwiki should not work on PO files.
 226 sub filter (@) {
 227         my %params = @_;
 228
 229         my $page = $params{page};
 230         my $destpage = $params{destpage};
 231         my $content = $params{content};
 232         if (istranslation($page) && ! alreadyfiltered($page, $destpage)) {
 233                 $content = po_to_markup($page, $content);
 234                 setalreadyfiltered($page, $destpage);
 235         }
 236         return $content;
 237 }
 238
 239 sub htmlize (@) {
 240         my %params=@_;
 241
 242         my $page = $params{page};
 243         my $content = $params{content};
 244
 245         # ignore PO files this plugin did not create
 246         return $content unless istranslation($page);
 247
 248         # force content to be htmlize'd as if it was the same type as the master page
 249         return IkiWiki::htmlize($page, $page,
 250                                 pagetype(srcfile($pagesources{masterpage($page)})),
 251                                 $content);
 252 }
 253
 254 sub pagetemplate (@) {
 255         my %params=@_;
 256         my $page=$params{page};
 257         my $destpage=$params{destpage};
 258         my $template=$params{template};
 259
 260         my ($masterpage, $lang) = istranslation($page);
 261
 262         if (istranslation($page) && $template->query(name => "percenttranslated")) {
 263                 $template->param(percenttranslated => percenttranslated($page));
 264         }
 265         if ($template->query(name => "istranslation")) {
 266                 $template->param(istranslation => scalar istranslation($page));
 267         }
 268         if ($template->query(name => "istranslatable")) {
 269                 $template->param(istranslatable => istranslatable($page));
 270         }
 271         if ($template->query(name => "HOMEPAGEURL")) {
 272                 $template->param(homepageurl => homepageurl($page));
 273         }
 274         if ($template->query(name => "otherlanguages")) {
 275                 $template->param(otherlanguages => [otherlanguagesloop($page)]);
 276                 map add_depends($page, $_), (values %{otherlanguages($page)});
 277         }
 278         # Rely on IkiWiki::Render's genpage() to decide wether
 279         # a discussion link should appear on $page; this is not
 280         # totally accurate, though: some broken links may be generated
 281         # when cgiurl is disabled.
 282         # This compromise avoids some code duplication, and will probably
 283         # prevent future breakage when ikiwiki internals change.
 284         # Known limitations are preferred to future random bugs.
 285         if ($template->param('discussionlink') && istranslation($page)) {
 286                 $template->param('discussionlink' => htmllink(
 287                                                         $page,
 288                                                         $destpage,
 289                                                         $masterpage . '/' . gettext("Discussion"),
 290                                                         noimageinline => 1,
 291                                                         forcesubpage => 0,
 292                                                         linktext => gettext("Discussion"),
 293                                                         ));
 294         }
 295         # Remove broken parentlink to ./index.html on home page's translations.
 296         # It works because this hook has the "last" parameter set, to ensure it
 297         # runs after parentlinks' own pagetemplate hook.
 298         if ($template->param('parentlinks')
 299             && istranslation($page)
 300             && $masterpage eq "index") {
 301                 $template->param('parentlinks' => []);
 302         }
 303 } # }}}
 304
 305 sub postscan (@) {
 306         my %params = @_;
 307         my $page = $params{page};
 308
 309         # backlinks involve back-dependencies, so that nicepagetitle effects,
 310         # such as translation status displayed in links, are updated
 311         use IkiWiki::Render;
 312         map add_depends($page, $_), keys %{$IkiWiki::backlinks{$page}};
 313 }
 314
 315 # Add the renamed page translations to the list of to-be-renamed pages.
 316 sub renamepages($$$) {
 317         my ($torename, $cgi, $session) = (shift, shift, shift);
 318
 319         # copy the initial array, so that we can iterate on it AND
 320         # modify it at the same time, without iterating on the items we
 321         # pushed on it ourselves
 322         my @torename=@{$torename};
 323
 324         # Save the page(s) the user asked to rename, so that our
 325         # canrename hook can tell the difference between:
 326         #  - a translation being renamed as a consequence of its master page
 327         #    being renamed
 328         #  - a user trying to directly rename a translation
 329         # This is why this hook has to be run first, before @torename is modified
 330         # by other plugins.
 331         $session->param(po_orig_torename => [ @torename ]);
 332         IkiWiki::cgi_savesession($session);
 333
 334         foreach my $rename (@torename) {
 335                 next unless istranslatable($rename->{src});
 336                 my %otherpages=%{otherlanguages($rename->{src})};
 337                 while (my ($lang, $otherpage) = each %otherpages) {
 338                         push @{$torename}, {
 339                                 src => $otherpage,
 340                                 srcfile => $pagesources{$otherpage},
 341                                 dest => otherlanguage($rename->{dest}, $lang),
 342                                 destfile => $rename->{dest}.".".$lang.".po",
 343                                 required => 0,
 344                         };
 345                 }
 346         }
 347 }
 348
 349 sub mydelete(@) {
 350         my @deleted=@_;
 351
 352         map { deletetranslations($_) } grep istranslatablefile($_), @deleted;
 353 }
 354
 355 sub change(@) {
 356         my @rendered=@_;
 357
 358         my $updated_po_files=0;
 359
 360         # Refresh/create POT and PO files as needed.
 361         foreach my $file (grep {istranslatablefile($_)} @rendered) {
 362                 my $page=pagename($file);
 363                 my $masterfile=srcfile($file);
 364                 my $updated_pot_file=0;
 365                 # Only refresh Pot file if it does not exist, or if
 366                 # $pagesources{$page} was changed: don't if only the HTML was
 367                 # refreshed, e.g. because of a dependency.
 368                 if ((grep { $_ eq $pagesources{$page} } @origneedsbuild)
 369                     || ! -e potfile($masterfile)) {
 370                         refreshpot($masterfile);
 371                         $updated_pot_file=1;
 372                 }
 373                 my @pofiles;
 374                 map {
 375                         push @pofiles, $_ if ($updated_pot_file || ! -e $_);
 376                 } (pofiles($masterfile));
 377                 if (@pofiles) {
 378                         refreshpofiles($masterfile, @pofiles);
 379                         map { IkiWiki::rcs_add($_) } @pofiles if $config{rcs};
 380                         $updated_po_files=1;
 381                 }
 382         }
 383
 384         if ($updated_po_files) {
 385                 commit_and_refresh(
 386                         gettext("updated PO files"),
 387                         "IkiWiki::Plugin::po::change");
 388         }
 389 }
 390
 391 sub cansave ($$$$) {
 392         my ($page, $content, $cgi, $session) = (shift, shift, shift, shift);
 393
 394         if (istranslation($page)) {
 395                 my $res = isvalidpo($content);
 396                 if ($res) {
 397                         return undef;
 398                 }
 399                 else {
 400                         return "$res";
 401                 }
 402         }
 403         return undef;
 404 }
 405
 406 sub canremove ($$$) {
 407         my ($page, $cgi, $session) = (shift, shift, shift);
 408
 409         if (istranslation($page)) {
 410                 return gettext("Can not remove a translation. Removing the master page, ".
 411                                "though, removes its translations as well.");
 412         }
 413         return undef;
 414 }
 415
 416 sub canrename ($$@) {
 417         my ($cgi, $session) = (shift, shift);
 418         my %params = @_;
 419
 420         if (istranslation($params{src})) {
 421                 my $masterpage = masterpage($params{src});
 422                 # Tell the difference between:
 423                 #  - a translation being renamed as a consequence of its master page
 424                 #    being renamed, which is allowed
 425                 #  - a user trying to directly rename a translation, which is forbidden
 426                 # by looking for the master page in the list of to-be-renamed pages we
 427                 # saved early in the renaming process.
 428                 my $orig_torename = $session->param("po_orig_torename");
 429                 unless (scalar grep { $_->{src} eq $masterpage } @{$orig_torename}) {
 430                         return gettext("Can not rename a translation. Renaming the master page, ".
 431                                        "though, renames its translations as well.");
 432                 }
 433         }
 434         return undef;
 435 }
 436
 437 # As we're previewing or saving a page, the content may have
 438 # changed, so tell the next filter() invocation it must not be lazy.
 439 sub editcontent () {
 440         my %params=@_;
 441
 442         unsetalreadyfiltered($params{page}, $params{page});
 443         return $params{content};
 444 }
 445
 446 sub formbuilder_setup (@) {
 447         my %params=@_;
 448         my $form=$params{form};
 449         my $q=$params{cgi};
 450
 451         return unless defined $form->field("do");
 452
 453         if ($form->field("do") eq "create") {
 454                 # Warn the user: new pages must be written in master language.
 455                 my $template=template("pocreatepage.tmpl");
 456                 $template->param(LANG => $config{po_master_language}{name});
 457                 $form->tmpl_param(message => $template->output);
 458         }
 459         elsif ($form->field("do") eq "edit") {
 460                 # Remove the rename/remove buttons on slave pages.
 461                 # This has to be done after the rename/remove plugins have added
 462                 # their buttons, which is why this hook must be run last.
 463                 # The canrename/canremove hooks already ensure this is forbidden
 464                 # at the backend level, so this is only UI sugar.
 465                 if (istranslation($form->field("page"))) {
 466                         map {
 467                                 for (my $i = 0; $i < @{$params{buttons}}; $i++) {
 468                                         if (@{$params{buttons}}[$i] eq $_) {
 469                                                 delete  @{$params{buttons}}[$i];
 470                                                 last;
 471                                         }
 472                                 }
 473                         } qw(Rename Remove);
 474                 }
 475         }
 476 }
 477
 478 sub formbuilder (@) {
 479         my %params=@_;
 480         my $form=$params{form};
 481         my $q=$params{cgi};
 482
 483         return unless defined $form->field("do");
 484
 485         # Do not allow to create pages of type po: they are automatically created.
 486         # The main reason to do so is to bypass the "favor the type of linking page
 487         # on page creation" logic, which is unsuitable when a broken link is clicked
 488         # on a slave (PO) page.
 489         # This cannot be done in the formbuilder_setup hook as the list of types is
 490         # computed later.
 491         if ($form->field("do") eq "create") {
 492                 for my $field ($form->field) {
 493                         next unless "$field" eq "type";
 494                         if ($field->type eq 'select') {
 495                                 # remove po from the list of types
 496                                 my @types = grep { $_ ne 'po' } $field->options;
 497                                 $field->options(\@types) if scalar @types;
 498                         }
 499                         else {
 500                                 # make sure the default value is not po;
 501                                 # does this case actually happen?
 502                                 debug "po(formbuilder) ".gettext("type field is not select - not implemented yet");
 503                         }
 504                 }
 505         }
 506 }
 507
 508 # ,----
 509 # | Injected functions
 510 # `----
 511
 512 # Implement po_link_to 'current' and 'negotiated' settings.
 513 sub mybestlink ($$) {
 514         my $page=shift;
 515         my $link=shift;
 516
 517         my $res=$origsubs{'bestlink'}->(masterpage($page), $link);
 518         if (length $res
 519             && ($config{po_link_to} eq "current" || $config{po_link_to} eq "negotiated")
 520             && istranslatable($res)
 521             && istranslation($page)) {
 522                 return $res . "." . lang($page);
 523         }
 524         return $res;
 525 }
 526
 527 sub mybeautify_urlpath ($) {
 528         my $url=shift;
 529
 530         my $res=$origsubs{'beautify_urlpath'}->($url);
 531         if ($config{po_link_to} eq "negotiated") {
 532                 $res =~ s!/\Qindex.$config{po_master_language}{code}.$config{htmlext}\E$!/!;
 533                 $res =~ s!/\Qindex.$config{htmlext}\E$!/!;
 534                 map {
 535                         $res =~ s!/\Qindex.$_.$config{htmlext}\E$!/!;
 536                 } (keys %{$config{po_slave_languages}});
 537         }
 538         return $res;
 539 }
 540
 541 sub mytargetpage ($$) {
 542         my $page=shift;
 543         my $ext=shift;
 544
 545         if (istranslation($page) || istranslatable($page)) {
 546                 my ($masterpage, $lang) = (masterpage($page), lang($page));
 547                 if (! $config{usedirs} || $masterpage eq 'index') {
 548                         return $masterpage . "." . $lang . "." . $ext;
 549                 }
 550                 else {
 551                         return $masterpage . "/index." . $lang . "." . $ext;
 552                 }
 553         }
 554         return $origsubs{'targetpage'}->($page, $ext);
 555 }
 556
 557 sub myurlto ($$;$) {
 558         my $to=shift;
 559         my $from=shift;
 560         my $absolute=shift;
 561
 562         # workaround hard-coded /index.$config{htmlext} in IkiWiki::urlto()
 563         if (! length $to
 564             && $config{po_link_to} eq "current"
 565             && istranslatable('index')) {
 566                 return IkiWiki::beautify_urlpath(IkiWiki::baseurl($from) . "index." . lang($from) . ".$config{htmlext}");
 567         }
 568         # avoid using our injected beautify_urlpath if run by cgi_editpage,
 569         # so that one is redirected to the just-edited page rather than to the
 570         # negociated translation; to prevent unnecessary fiddling with caller/inject,
 571         # we only do so when our beautify_urlpath would actually do what we want to
 572         # avoid, i.e. when po_link_to = negotiated
 573         if ($config{po_link_to} eq "negotiated") {
 574                 my @caller = caller(1);
 575                 my $run_by_editpage = 0;
 576                 $run_by_editpage = 1 if (exists $caller[3] && defined $caller[3]
 577                                          && $caller[3] eq "IkiWiki::cgi_editpage");
 578                 inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'})
 579                         if $run_by_editpage;
 580                 my $res = $origsubs{'urlto'}->($to,$from,$absolute);
 581                 inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath)
 582                         if $run_by_editpage;
 583                 return $res;
 584         }
 585         else {
 586                 return $origsubs{'urlto'}->($to,$from,$absolute)
 587         }
 588 }
 589
 590 sub mynicepagetitle ($;$) {
 591         my ($page, $unescaped) = (shift, shift);
 592
 593         my $res = $origsubs{'nicepagetitle'}->($page, $unescaped);
 594         return $res unless istranslation($page);
 595         return $res unless $config{po_translation_status_in_links};
 596         my @caller = caller(1);
 597         return $res if (exists $caller[3] && defined $caller[3]
 598                         && $caller[3] eq "IkiWiki::Plugin::parentlinks::parentlinks");
 599         return $res.' ('.percenttranslated($page).'&nbsp;%)';
 600 }
 601
 602 # ,----
 603 # | Blackboxes for private data
 604 # `----
 605
 606 {
 607         my %filtered;
 608
 609         sub alreadyfiltered($$) {
 610                 my $page=shift;
 611                 my $destpage=shift;
 612
 613                 return ( exists $filtered{$page}{$destpage}
 614                          && $filtered{$page}{$destpage} eq 1 );
 615         }
 616
 617         sub setalreadyfiltered($$) {
 618                 my $page=shift;
 619                 my $destpage=shift;
 620
 621                 $filtered{$page}{$destpage}=1;
 622         }
 623
 624         sub unsetalreadyfiltered($$) {
 625                 my $page=shift;
 626                 my $destpage=shift;
 627
 628                 if (exists $filtered{$page}{$destpage}) {
 629                         delete $filtered{$page}{$destpage};
 630                 }
 631         }
 632
 633         sub resetalreadyfiltered() {
 634                 undef %filtered;
 635         }
 636 }
 637
 638 # ,----
 639 # | Helper functions
 640 # `----
 641
 642 sub maybe_add_leading_slash ($;$) {
 643         my $str=shift;
 644         my $add=shift;
 645         $add=1 unless defined $add;
 646         return '/' . $str if $add;
 647         return $str;
 648 }
 649
 650 sub istranslatablefile ($) {
 651         my $file=shift;
 652
 653         return 0 unless defined $file;
 654         return 0 if (defined pagetype($file) && pagetype($file) eq 'po');
 655         return 0 if $file =~ /\.pot$/;
 656         return 1 if pagespec_match(pagename($file), $config{po_translatable_pages});
 657         return;
 658 }
 659
 660 sub istranslatable ($) {
 661         my $page=shift;
 662
 663         $page=~s#^/##;
 664         return 1 if istranslatablefile($pagesources{$page});
 665         return;
 666 }
 667
 668 sub _istranslation ($) {
 669         my $page=shift;
 670
 671         my $hasleadingslash = ($page=~s#^/##);
 672         my $file=$pagesources{$page};
 673         return 0 unless (defined $file
 674                          && defined pagetype($file)
 675                          && pagetype($file) eq 'po');
 676         return 0 if $file =~ /\.pot$/;
 677
 678         my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
 679         return 0 unless (defined $masterpage && defined $lang
 680                          && length $masterpage && length $lang
 681                          && defined $pagesources{$masterpage}
 682                          && defined $config{po_slave_languages}{$lang});
 683
 684         return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang)
 685                 if istranslatable($masterpage);
 686 }
 687
 688 sub istranslation ($) {
 689         my $page=shift;
 690
 691         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 692                 my $hasleadingslash = ($masterpage=~s#^/##);
 693                 $translations{$masterpage}{$lang}=$page unless exists $translations{$masterpage}{$lang};
 694                 return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang);
 695         }
 696         return;
 697 }
 698
 699 sub masterpage ($) {
 700         my $page=shift;
 701
 702         if ( 1 < (my ($masterpage, $lang) = _istranslation($page))) {
 703                 return $masterpage;
 704         }
 705         return $page;
 706 }
 707
 708 sub lang ($) {
 709         my $page=shift;
 710
 711         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 712                 return $lang;
 713         }
 714         return $config{po_master_language}{code};
 715 }
 716
 717 sub islanguagecode ($) {
 718         my $code=shift;
 719
 720         return ($code =~ /^[a-z]{2}$/);
 721 }
 722
 723 sub otherlanguage ($$) {
 724         my $page=shift;
 725         my $code=shift;
 726
 727         return masterpage($page) if $code eq $config{po_master_language}{code};
 728         return masterpage($page) . '.' . $code;
 729 }
 730
 731 sub otherlanguages ($) {
 732         my $page=shift;
 733
 734         my %ret;
 735         return \%ret unless (istranslation($page) || istranslatable($page));
 736         my $curlang=lang($page);
 737         foreach my $lang
 738                 ($config{po_master_language}{code}, keys %{$config{po_slave_languages}}) {
 739                 next if $lang eq $curlang;
 740                 $ret{$lang}=otherlanguage($page, $lang);
 741         }
 742         return \%ret;
 743 }
 744
 745 sub potfile ($) {
 746         my $masterfile=shift;
 747
 748         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 749         $dir='' if $dir eq './';
 750         return File::Spec->catpath('', $dir, $name . ".pot");
 751 }
 752
 753 sub pofile ($$) {
 754         my $masterfile=shift;
 755         my $lang=shift;
 756
 757         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 758         $dir='' if $dir eq './';
 759         return File::Spec->catpath('', $dir, $name . "." . $lang . ".po");
 760 }
 761
 762 sub pofiles ($) {
 763         my $masterfile=shift;
 764
 765         return map pofile($masterfile, $_), (keys %{$config{po_slave_languages}});
 766 }
 767
 768 sub refreshpot ($) {
 769         my $masterfile=shift;
 770
 771         my $potfile=potfile($masterfile);
 772         my %options = ("markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0);
 773         my $doc=Locale::Po4a::Chooser::new('text',%options);
 774         $doc->{TT}{utf_mode} = 1;
 775         $doc->{TT}{file_in_charset} = 'utf-8';
 776         $doc->{TT}{file_out_charset} = 'utf-8';
 777         $doc->read($masterfile);
 778         # let's cheat a bit to force porefs option to be passed to Locale::Po4a::Po;
 779         # this is undocument use of internal Locale::Po4a::TransTractor's data,
 780         # compulsory since this module prevents us from using the porefs option.
 781         $doc->{TT}{po_out}=Locale::Po4a::Po->new({ 'porefs' => 'none' });
 782         $doc->{TT}{po_out}->set_charset('utf-8');
 783         # do the actual work
 784         $doc->parse;
 785         IkiWiki::prep_writefile(basename($potfile),dirname($potfile));
 786         $doc->writepo($potfile);
 787 }
 788
 789 sub refreshpofiles ($@) {
 790         my $masterfile=shift;
 791         my @pofiles=@_;
 792
 793         my $potfile=potfile($masterfile);
 794         (-e $potfile)
 795                 or error("po(refreshpofiles) ".sprintf(gettext("POT file (%s) does not exist"),
 796                                                        $potfile));
 797
 798         foreach my $pofile (@pofiles) {
 799                 IkiWiki::prep_writefile(basename($pofile),dirname($pofile));
 800                 if (-e $pofile) {
 801                         system("msgmerge", "-U", "--backup=none", $pofile, $potfile) == 0
 802                                 or error("po(refreshpofiles) ".
 803                                          sprintf(gettext("failed to update %s"),
 804                                                  $pofile));
 805                 }
 806                 else {
 807                         File::Copy::syscopy($potfile,$pofile)
 808                                 or error("po(refreshpofiles) ".
 809                                          sprintf(gettext("failed to copy the POT file to %s"),
 810                                                  $pofile));
 811                 }
 812         }
 813 }
 814
 815 sub buildtranslationscache() {
 816         # use istranslation's side-effect
 817         map istranslation($_), (keys %pagesources);
 818 }
 819
 820 sub resettranslationscache() {
 821         undef %translations;
 822 }
 823
 824 sub flushmemoizecache() {
 825         Memoize::flush_cache("istranslatable");
 826         Memoize::flush_cache("_istranslation");
 827         Memoize::flush_cache("percenttranslated");
 828 }
 829
 830 sub urlto_with_orig_beautiful_urlpath($$) {
 831         my $to=shift;
 832         my $from=shift;
 833
 834         inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'});
 835         my $res=urlto($to, $from);
 836         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
 837
 838         return $res;
 839 }
 840
 841 sub percenttranslated ($) {
 842         my $page=shift;
 843
 844         $page=~s/^\///;
 845         return gettext("N/A") unless istranslation($page);
 846         my $file=srcfile($pagesources{$page});
 847         my $masterfile = srcfile($pagesources{masterpage($page)});
 848         my %options = (
 849                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
 850         );
 851         my $doc=Locale::Po4a::Chooser::new('text',%options);
 852         $doc->process(
 853                 'po_in_name'    => [ $file ],
 854                 'file_in_name'  => [ $masterfile ],
 855                 'file_in_charset'  => 'utf-8',
 856                 'file_out_charset' => 'utf-8',
 857         ) or error("po(percenttranslated) ".
 858                    sprintf(gettext("failed to translate %s"), $page));
 859         my ($percent,$hit,$queries) = $doc->stats();
 860         $percent =~ s/\.[0-9]+$//;
 861         return $percent;
 862 }
 863
 864 sub languagename ($) {
 865         my $code=shift;
 866
 867         return $config{po_master_language}{name}
 868                 if $code eq $config{po_master_language}{code};
 869         return $config{po_slave_languages}{$code}
 870                 if defined $config{po_slave_languages}{$code};
 871         return;
 872 }
 873
 874 sub otherlanguagesloop ($) {
 875         my $page=shift;
 876
 877         my @ret;
 878         my %otherpages=%{otherlanguages($page)};
 879         while (my ($lang, $otherpage) = each %otherpages) {
 880                 if (istranslation($page) && masterpage($page) eq $otherpage) {
 881                         push @ret, {
 882                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 883                                 code => $lang,
 884                                 language => languagename($lang),
 885                                 master => 1,
 886                         };
 887                 }
 888                 else {
 889                         push @ret, {
 890                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 891                                 code => $lang,
 892                                 language => languagename($lang),
 893                                 percent => percenttranslated($otherpage),
 894                         }
 895                 }
 896         }
 897         return sort {
 898                         return -1 if $a->{code} eq $config{po_master_language}{code};
 899                         return 1 if $b->{code} eq $config{po_master_language}{code};
 900                         return $a->{language} cmp $b->{language};
 901                 } @ret;
 902 }
 903
 904 sub homepageurl (;$) {
 905         my $page=shift;
 906
 907         return urlto('', $page);
 908 }
 909
 910 sub deletetranslations ($) {
 911         my $deletedmasterfile=shift;
 912
 913         my $deletedmasterpage=pagename($deletedmasterfile);
 914         my @todelete;
 915         map {
 916                 my $file = newpagefile($deletedmasterpage.'.'.$_, 'po');
 917                 my $absfile = "$config{srcdir}/$file";
 918                 if (-e $absfile && ! -l $absfile && ! -d $absfile) {
 919                         push @todelete, $file;
 920                 }
 921         } keys %{$config{po_slave_languages}};
 922
 923         map {
 924                 if ($config{rcs}) {
 925                         IkiWiki::rcs_remove($_);
 926                 }
 927                 else {
 928                         IkiWiki::prune("$config{srcdir}/$_");
 929                 }
 930         } @todelete;
 931
 932         if (scalar @todelete) {
 933                 commit_and_refresh(
 934                         gettext("removed obsolete PO files"),
 935                         "IkiWiki::Plugin::po::deletetranslations");
 936         }
 937 }
 938
 939 sub commit_and_refresh ($$) {
 940         my ($msg, $author) = (shift, shift);
 941
 942         if ($config{rcs}) {
 943                 IkiWiki::disable_commit_hook();
 944                 IkiWiki::rcs_commit_staged($msg, $author, "127.0.0.1");
 945                 IkiWiki::enable_commit_hook();
 946                 IkiWiki::rcs_update();
 947         }
 948         # Reinitialize module's private variables.
 949         resetalreadyfiltered();
 950         resettranslationscache();
 951         flushmemoizecache();
 952         # Trigger a wiki refresh.
 953         require IkiWiki::Render;
 954         # without preliminary saveindex/loadindex, refresh()
 955         # complains about a lot of uninitialized variables
 956         IkiWiki::saveindex();
 957         IkiWiki::loadindex();
 958         IkiWiki::refresh();
 959         IkiWiki::saveindex();
 960 }
 961
 962 # on success, returns the filtered content.
 963 # on error, if $nonfatal, warn and return undef; else, error out.
 964 sub po_to_markup ($$;$) {
 965         my ($page, $content) = (shift, shift);
 966         my $nonfatal = shift;
 967
 968         $content = '' unless defined $content;
 969         $content = decode_utf8(encode_utf8($content));
 970         # CRLF line terminators make poor Locale::Po4a feel bad
 971         $content=~s/\r\n/\n/g;
 972
 973         # There are incompatibilities between some File::Temp versions
 974         # (including 0.18, bundled with Lenny's perl-modules package)
 975         # and others (e.g. 0.20, previously present in the archive as
 976         # a standalone package): under certain circumstances, some
 977         # return a relative filename, whereas others return an absolute one;
 978         # we here use this module in a way that is at least compatible
 979         # with 0.18 and 0.20. Beware, hit'n'run refactorers!
 980         my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-in.XXXXXXXXXX",
 981                                     DIR => File::Spec->tmpdir,
 982                                     UNLINK => 1)->filename;
 983         my $outfile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-out.XXXXXXXXXX",
 984                                      DIR => File::Spec->tmpdir,
 985                                      UNLINK => 1)->filename;
 986
 987         my $fail = sub ($) {
 988                 my $msg = "po(po_to_markup) - $page : " . shift;
 989                 if ($nonfatal) {
 990                         warn $msg;
 991                         return undef;
 992                 }
 993                 error($msg, sub { unlink $infile, $outfile});
 994         };
 995
 996         writefile(basename($infile), File::Spec->tmpdir, $content)
 997                 or return $fail->(sprintf(gettext("failed to write %s"), $infile));
 998
 999         my $masterfile = srcfile($pagesources{masterpage($page)});
1000         my %options = (
1001                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
1002         );
1003         my $doc=Locale::Po4a::Chooser::new('text',%options);
1004         $doc->process(
1005                 'po_in_name'    => [ $infile ],
1006                 'file_in_name'  => [ $masterfile ],
1007                 'file_in_charset'  => 'utf-8',
1008                 'file_out_charset' => 'utf-8',
1009         ) or return $fail->(gettext("failed to translate"));
1010         $doc->write($outfile)
1011                 or return $fail->(sprintf(gettext("failed to write %s"), $outfile));
1012
1013         $content = readfile($outfile)
1014                 or return $fail->(sprintf(gettext("failed to read %s"), $outfile));
1015
1016         # Unlinking should happen automatically, thanks to File::Temp,
1017         # but it does not work here, probably because of the way writefile()
1018         # and Locale::Po4a::write() work.
1019         unlink $infile, $outfile;
1020
1021         return $content;
1022 }
1023
1024 # returns a SuccessReason or FailReason object
1025 sub isvalidpo ($) {
1026         my $content = shift;
1027
1028         # NB: we don't use po_to_markup here, since Po4a parser does
1029         # not mind invalid PO content
1030         $content = '' unless defined $content;
1031         $content = decode_utf8(encode_utf8($content));
1032
1033         # There are incompatibilities between some File::Temp versions
1034         # (including 0.18, bundled with Lenny's perl-modules package)
1035         # and others (e.g. 0.20, previously present in the archive as
1036         # a standalone package): under certain circumstances, some
1037         # return a relative filename, whereas others return an absolute one;
1038         # we here use this module in a way that is at least compatible
1039         # with 0.18 and 0.20. Beware, hit'n'run refactorers!
1040         my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-isvalidpo.XXXXXXXXXX",
1041                                     DIR => File::Spec->tmpdir,
1042                                     UNLINK => 1)->filename;
1043
1044         my $fail = sub ($) {
1045                 my $msg = '[po/isvalidpo] ' . shift;
1046                 unlink $infile;
1047                 return IkiWiki::FailReason->new("$msg");
1048         };
1049
1050         writefile(basename($infile), File::Spec->tmpdir, $content)
1051                 or return $fail->(sprintf(gettext("failed to write %s"), $infile));
1052
1053         my $res = (system("msgfmt", "--check", $infile, "-o", "/dev/null") == 0);
1054
1055         # Unlinking should happen automatically, thanks to File::Temp,
1056         # but it does not work here, probably because of the way writefile()
1057         # and Locale::Po4a::write() work.
1058         unlink $infile;
1059
1060         if ($res) {
1061             return IkiWiki::SuccessReason->new("valid gettext data");
1062         }
1063         return IkiWiki::FailReason->new("invalid gettext data, go back ".
1064                                         "to previous page to go on with edit");
1065 }
1066
1067 # ,----
1068 # | PageSpec's
1069 # `----
1070
1071 package IkiWiki::PageSpec;
1072 use warnings;
1073 use strict;
1074 use IkiWiki 2.00;
1075
1076 sub match_istranslation ($;@) {
1077         my $page=shift;
1078
1079         if (IkiWiki::Plugin::po::istranslation($page)) {
1080                 return IkiWiki::SuccessReason->new("is a translation page");
1081         }
1082         else {
1083                 return IkiWiki::FailReason->new("is not a translation page");
1084         }
1085 }
1086
1087 sub match_istranslatable ($;@) {
1088         my $page=shift;
1089
1090         if (IkiWiki::Plugin::po::istranslatable($page)) {
1091                 return IkiWiki::SuccessReason->new("is set as translatable in po_translatable_pages");
1092         }
1093         else {
1094                 return IkiWiki::FailReason->new("is not set as translatable in po_translatable_pages");
1095         }
1096 }
1097
1098 sub match_lang ($$;@) {
1099         my $page=shift;
1100         my $wanted=shift;
1101
1102         my $regexp=IkiWiki::glob2re($wanted);
1103         my $lang=IkiWiki::Plugin::po::lang($page);
1104         if ($lang!~/^$regexp$/i) {
1105                 return IkiWiki::FailReason->new("file language is $lang, not $wanted");
1106         }
1107         else {
1108                 return IkiWiki::SuccessReason->new("file language is $wanted");
1109         }
1110 }
1111
1112 sub match_currentlang ($$;@) {
1113         my $page=shift;
1114         shift;
1115         my %params=@_;
1116
1117         return IkiWiki::FailReason->new("no location provided") unless exists $params{location};
1118
1119         my $currentlang=IkiWiki::Plugin::po::lang($params{location});
1120         my $lang=IkiWiki::Plugin::po::lang($page);
1121
1122         if ($lang eq $currentlang) {
1123                 return IkiWiki::SuccessReason->new("file language is the same as current one, i.e. $currentlang");
1124         }
1125         else {
1126                 return IkiWiki::FailReason->new("file language is $lang, whereas current language is $currentlang");
1127         }
1128 }
1129
1130 1