git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/attachment.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::attachment;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7
   8 sub import {
   9         add_underlay("javascript");
  10         hook(type => "getsetup", id => "attachment", call => \&getsetup);
  11         hook(type => "checkconfig", id => "attachment", call => \&checkconfig);
  12         hook(type => "formbuilder_setup", id => "attachment", call => \&formbuilder_setup);
  13         hook(type => "formbuilder", id => "attachment", call => \&formbuilder);
  14         IkiWiki::loadplugin("filecheck");
  15 }
  16
  17 sub getsetup () {
  18         return
  19                 plugin => {
  20                         safe => 1,
  21                         rebuild => 0,
  22                         section => "web",
  23                 },
  24                 allowed_attachments => {
  25                         type => "pagespec",
  26                         example => "virusfree() and mimetype(image/*) and maxsize(50kb)",
  27                         description => "enhanced PageSpec specifying what attachments are allowed",
  28                         link => "ikiwiki/PageSpec/attachment",
  29                         safe => 1,
  30                         rebuild => 0,
  31                 },
  32                 virus_checker => {
  33                         type => "string",
  34                         example => "clamdscan -",
  35                         description => "virus checker program (reads STDIN, returns nonzero if virus found)",
  36                         safe => 0, # executed
  37                         rebuild => 0,
  38                 },
  39 }
  40
  41 sub check_canattach ($$;$) {
  42         my $session=shift;
  43         my $dest=shift; # where it's going to be put, under the srcdir
  44         my $file=shift; # the path to the attachment currently
  45
  46         # Don't allow an attachment to be uploaded with the same name as an
  47         # existing page.
  48         if (exists $IkiWiki::pagesources{$dest} &&
  49             $IkiWiki::pagesources{$dest} ne $dest) {
  50                 error(sprintf(gettext("there is already a page named %s"), $dest));
  51         }
  52
  53         # Use a special pagespec to test that the attachment is valid.
  54         my $allowed=1;
  55         if (defined $config{allowed_attachments} &&
  56             length $config{allowed_attachments}) {
  57                 $allowed=pagespec_match($dest,
  58                         $config{allowed_attachments},
  59                         file => $file,
  60                         user => $session->param("name"),
  61                         ip => $session->remote_addr(),
  62                 );
  63         }
  64
  65         if (! $allowed) {
  66                 error(gettext("prohibited by allowed_attachments")." ($allowed)");
  67         }
  68         else {
  69                 return 1;
  70         }
  71 }
  72
  73 sub checkconfig () {
  74         $config{cgi_disable_uploads}=0;
  75 }
  76
  77 sub formbuilder_setup (@) {
  78         my %params=@_;
  79         my $form=$params{form};
  80         my $q=$params{cgi};
  81
  82         if (defined $form->field("do") && ($form->field("do") eq "edit" ||
  83             $form->field("do") eq "create")) {
  84                 # Add attachment field, set type to multipart.
  85                 $form->enctype(&CGI::MULTIPART);
  86                 $form->field(name => 'attachment', type => 'file');
  87                 # These buttons are not put in the usual place, so
  88                 # are not added to the normal formbuilder button list.
  89                 $form->tmpl_param("field-upload" => '<input name="_submit" type="submit" value="Upload Attachment" />');
  90                 $form->tmpl_param("field-link" => '<input name="_submit" type="submit" value="Insert Links" />');
  91
  92                 # Add the toggle javascript; the attachments interface uses
  93                 # it to toggle visibility.
  94                 require IkiWiki::Plugin::toggle;
  95                 $form->tmpl_param("javascript" => IkiWiki::Plugin::toggle::include_javascript($params{page}));
  96                 # Start with the attachments interface toggled invisible,
  97                 # but if it was used, keep it open.
  98                 if ($form->submitted ne "Upload Attachment" &&
  99                     (! defined $q->param("attachment_select") ||
 100                     ! length $q->param("attachment_select"))) {
 101                         $form->tmpl_param("attachments-class" => "toggleable");
 102                 }
 103                 else {
 104                         $form->tmpl_param("attachments-class" => "toggleable-open");
 105                 }
 106         }
 107 }
 108
 109 sub formbuilder (@) {
 110         my %params=@_;
 111         my $form=$params{form};
 112         my $q=$params{cgi};
 113
 114         return if ! defined $form->field("do") || ($form->field("do") ne "edit" && $form->field("do") ne "create") ;
 115
 116         my $filename=Encode::decode_utf8($q->param('attachment'));
 117         if (defined $filename && length $filename &&
 118             ($form->submitted eq "Upload Attachment" || $form->submitted eq "Save Page")) {
 119                 attachment_store($filename, $form, $q, $params{session});
 120         }
 121         if ($form->submitted eq "Save Page") {
 122                 attachments_save($form, $params{session});
 123         }
 124
 125         if ($form->submitted eq "Insert Links") {
 126                 my $page=quotemeta(Encode::decode_utf8($q->param("page")));
 127                 my $add="";
 128                 foreach my $f ($q->param("attachment_select")) {
 129                         $f=Encode::decode_utf8($f);
 130                         $f=~s/^$page\///;
 131                         if (IkiWiki::isinlinableimage($f) &&
 132                             UNIVERSAL::can("IkiWiki::Plugin::img", "import")) {
 133                                 $add.='[[!img '.$f.' align="right" size="" alt=""]]';
 134                         }
 135                         else {
 136                                 $add.="[[$f]]";
 137                         }
 138                         $add.="\n";
 139                 }
 140                 $form->field(name => 'editcontent',
 141                         value => $form->field('editcontent')."\n\n".$add,
 142                         force => 1) if length $add;
 143         }
 144
 145         # Generate the attachment list only after having added any new
 146         # attachments.
 147         $form->tmpl_param("attachment_list" => [attachment_list($form->field('page'))]);
 148 }
 149
 150 sub attachment_holding_dir {
 151         my $page=shift;
 152
 153         return $config{wikistatedir}."/attachments/$page";
 154 }
 155
 156 # Stores the attachment in a holding area, not yet in the wiki proper.
 157 sub attachment_store {
 158         my $filename=shift;
 159         my $form=shift;
 160         my $q=shift;
 161         my $session=shift;
 162
 163         # This is an (apparently undocumented) way to get the name
 164         # of the temp file that CGI writes the upload to.
 165         my $tempfile=$q->tmpFileName($filename);
 166         if (! defined $tempfile || ! length $tempfile) {
 167                 # perl 5.8 needs an alternative, awful method
 168                 if ($q =~ /HASH/ && exists $q->{'.tmpfiles'}) {
 169                         foreach my $key (keys(%{$q->{'.tmpfiles'}})) {
 170                                 $tempfile=$q->tmpFileName(\$key);
 171                                 last if defined $tempfile && length $tempfile;
 172                         }
 173                 }
 174                 if (! defined $tempfile || ! length $tempfile) {
 175                         error("CGI::tmpFileName failed to return the uploaded file name");
 176                 }
 177         }
 178
 179         $filename=IkiWiki::basename($filename);
 180         $filename=~s/.*\\+(.+)/$1/; # hello, windows
 181         $filename=IkiWiki::possibly_foolish_untaint(linkpage($filename));
 182
 183         # Check that the user is allowed to edit the attachment.
 184         my $final_filename=
 185                 linkpage(IkiWiki::possibly_foolish_untaint(
 186                         attachment_location($form->field('page')))).
 187                 $filename;
 188         if (IkiWiki::file_pruned($final_filename)) {
 189                 error(gettext("bad attachment filename"));
 190         }
 191         IkiWiki::check_canedit($final_filename, $q, $session);
 192         # And that the attachment itself is acceptable.
 193         check_canattach($session, $final_filename, $tempfile);
 194
 195         # Move the attachment into holding directory.
 196         # Try to use a fast rename; fall back to copying.
 197         my $dest=attachment_holding_dir($form->field('page'));
 198         IkiWiki::prep_writefile($filename, $dest);
 199         unlink($dest."/".$filename);
 200         if (rename($tempfile, $dest."/".$filename)) {
 201                 # The temp file has tight permissions; loosen up.
 202                 chmod(0666 & ~umask, $dest."/".$filename);
 203         }
 204         else {
 205                 my $fh=$q->upload('attachment');
 206                 if (! defined $fh || ! ref $fh) {
 207                         # needed by old CGI versions
 208                         $fh=$q->param('attachment');
 209                         if (! defined $fh || ! ref $fh) {
 210                                 # even that doesn't always work,
 211                                 # fall back to opening the tempfile
 212                                 $fh=undef;
 213                                 open($fh, "<", $tempfile) || error("failed to open \"$tempfile\": $!");
 214                         }
 215                 }
 216                 binmode($fh);
 217                 # Needed for fast_file_copy.
 218                 require IkiWiki::Render;
 219                 writefile($filename, $dest, undef, 1, sub {
 220                         IkiWiki::fast_file_copy($tempfile, $filename, $fh, @_);
 221                 });
 222         }
 223 }
 224
 225 # Save all stored attachments for a page.
 226 sub attachments_save {
 227         my $form=shift;
 228         my $session=shift;
 229
 230         # Move attachments out of holding directory.
 231         my @attachments;
 232         my $dir=attachment_holding_dir($form->field('page'));
 233         foreach my $filename (glob("$dir/*")) {
 234                 next unless -f $filename;
 235                 my $dest=$config{srcdir}."/".
 236                         linkpage(IkiWiki::possibly_foolish_untaint(
 237                                 attachment_location($form->field('page')))).
 238                         $filename;
 239                 unlink($dest);
 240                 rename($filename, $dest);
 241                 push @attachments, $dest;
 242         }
 243         return unless @attachments;
 244         rmdir($dir);
 245
 246         # Check the attachments in and trigger a wiki refresh.
 247         if ($config{rcs}) {
 248                 IkiWiki::rcs_add($_) foreach @attachments;
 249                 IkiWiki::disable_commit_hook();
 250                 IkiWiki::rcs_commit_staged(
 251                         message => gettext("attachment upload"),
 252                         session => $session,
 253                 );
 254                 IkiWiki::enable_commit_hook();
 255                 IkiWiki::rcs_update();
 256         }
 257         IkiWiki::refresh();
 258         IkiWiki::saveindex();
 259 }
 260
 261 sub attachment_location ($) {
 262         my $page=shift;
 263
 264         # Put the attachment in a subdir of the page it's attached
 265         # to, unless that page is an "index" page.
 266         $page=~s/(^|\/)index//;
 267         $page.="/" if length $page;
 268
 269         return $page;
 270 }
 271
 272 sub attachment_list ($) {
 273         my $page=shift;
 274         my $loc=attachment_location($page);
 275
 276         my @ret;
 277         foreach my $f (values %pagesources) {
 278                 if (! defined pagetype($f) &&
 279                     $f=~m/^\Q$loc\E[^\/]+$/) {
 280                         push @ret, {
 281                                 "field-select" => '<input type="checkbox" name="attachment_select" value="'.$f.'" />',
 282                                 link => htmllink($page, $page, $f, noimageinline => 1),
 283                                 size => IkiWiki::Plugin::filecheck::humansize((stat($f))[7]),
 284                                 mtime => displaytime($IkiWiki::pagemtime{$f}),
 285                                 mtime_raw => $IkiWiki::pagemtime{$f},
 286                         };
 287                 }
 288         }
 289
 290         # Sort newer attachments to the top of the list, so a newly-added
 291         # attachment appears just before the form used to add it.
 292         return sort { $b->{mtime_raw} <=> $a->{mtime_raw} || $a->{link} cmp $b->{link} } @ret;
 293 }
 294
 295 1