git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/tag.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki tag plugin.
   3 package IkiWiki::Plugin::tag;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki 3.00;
   8
   9 sub import {
  10         hook(type => "checkconfig", id => "tag", call => \&checkconfig);
  11         hook(type => "getopt", id => "tag", call => \&getopt);
  12         hook(type => "getsetup", id => "tag", call => \&getsetup);
  13         hook(type => "preprocess", id => "tag", call => \&preprocess_tag, scan => 1);
  14         hook(type => "preprocess", id => "taglink", call => \&preprocess_taglink, scan => 1);
  15         hook(type => "pagetemplate", id => "tag", call => \&pagetemplate);
  16
  17         IkiWiki::loadplugin("transient");
  18 }
  19
  20 sub getopt () {
  21         eval q{use Getopt::Long};
  22         error($@) if $@;
  23         Getopt::Long::Configure('pass_through');
  24         GetOptions("tagbase=s" => \$config{tagbase});
  25 }
  26
  27 sub getsetup () {
  28         return
  29                 plugin => {
  30                         safe => 1,
  31                         rebuild => undef,
  32                 },
  33                 tagbase => {
  34                         type => "string",
  35                         example => "tag",
  36                         description => "parent page tags are located under",
  37                         safe => 1,
  38                         rebuild => 1,
  39                 },
  40                 tag_autocreate => {
  41                         type => "boolean",
  42                         example => 1,
  43                         description => "autocreate new tag pages?",
  44                         safe => 1,
  45                         rebuild => undef,
  46                 },
  47                 tag_autocreate_commit => {
  48                         type => "boolean",
  49                         example => 1,
  50                         default => 1,
  51                         description => "commit autocreated tag pages",
  52                         safe => 1,
  53                         rebuild => 0,
  54                 },
  55 }
  56
  57 sub checkconfig () {
  58         if (! defined $config{tag_autocreate_commit}) {
  59                 $config{tag_autocreate_commit} = 1;
  60         }
  61 }
  62
  63 sub taglink ($) {
  64         my $tag=shift;
  65
  66         if ($tag !~ m{^/} &&
  67             defined $config{tagbase}) {
  68                 $tag="/".$config{tagbase}."/".$tag;
  69                 $tag=~y#/#/#s; # squash dups
  70         }
  71
  72         return $tag;
  73 }
  74
  75 # Returns a tag name from a tag link
  76 sub tagname ($) {
  77         my $tag=shift;
  78         if (defined $config{tagbase}) {
  79                 $tag =~ s!^/\Q$config{tagbase}\E/!!;
  80         } else {
  81                 $tag =~ s!^\.?/!!;
  82         }
  83         return pagetitle($tag, 1);
  84 }
  85
  86 sub htmllink_tag ($$$;@) {
  87         my $page=shift;
  88         my $destpage=shift;
  89         my $tag=shift;
  90         my %opts=@_;
  91
  92         return htmllink($page, $destpage, taglink($tag), %opts);
  93 }
  94
  95 sub gentag ($) {
  96         my $tag=shift;
  97
  98         if ($config{tag_autocreate} ||
  99             ($config{tagbase} && ! defined $config{tag_autocreate})) {
 100                 my $tagpage=taglink($tag);
 101                 if ($tagpage=~/^\.\/(.*)/) {
 102                         $tagpage=$1;
 103                 }
 104                 else {
 105                         $tagpage=~s/^\///;
 106                 }
 107                 if (exists $IkiWiki::pagecase{lc $tagpage}) {
 108                         $tagpage=$IkiWiki::pagecase{lc $tagpage}
 109                 }
 110
 111                 my $tagfile = newpagefile($tagpage, $config{default_pageext});
 112
 113                 add_autofile($tagfile, "tag", sub {
 114                         my $message=sprintf(gettext("creating tag page %s"), $tagpage);
 115                         debug($message);
 116
 117                         my $template=template("autotag.tmpl");
 118                         $template->param(tagname => tagname($tag));
 119                         $template->param(tag => $tag);
 120
 121                         my $dir = $config{srcdir};
 122                         if (! $config{tag_autocreate_commit}) {
 123                                 $dir = $IkiWiki::Plugin::transient::transientdir;
 124                         }
 125
 126                         writefile($tagfile, $dir, $template->output);
 127                         if ($config{rcs} && $config{tag_autocreate_commit}) {
 128                                 IkiWiki::disable_commit_hook();
 129                                 IkiWiki::rcs_add($tagfile);
 130                                 IkiWiki::rcs_commit_staged(message => $message);
 131                                 IkiWiki::enable_commit_hook();
 132                         }
 133                 });
 134         }
 135 }
 136
 137 sub preprocess_tag (@) {
 138         if (! @_) {
 139                 return "";
 140         }
 141         my %params=@_;
 142         my $page = $params{page};
 143         delete $params{page};
 144         delete $params{destpage};
 145         delete $params{preview};
 146
 147         foreach my $tag (keys %params) {
 148                 $tag=linkpage($tag);
 149
 150                 # hidden WikiLink
 151                 add_link($page, taglink($tag), 'tag');
 152
 153                 gentag($tag);
 154         }
 155
 156         return "";
 157 }
 158
 159 sub preprocess_taglink (@) {
 160         if (! @_) {
 161                 return "";
 162         }
 163         my %params=@_;
 164         return join(" ", map {
 165                 if (/(.*)\|(.*)/) {
 166                         my $tag=linkpage($2);
 167                         add_link($params{page}, taglink($tag), 'tag');
 168                         gentag($tag);
 169                         return htmllink_tag($params{page}, $params{destpage}, $tag,
 170                                 linktext => pagetitle($1));
 171                 }
 172                 else {
 173                         my $tag=linkpage($_);
 174                         add_link($params{page}, taglink($tag), 'tag');
 175                         gentag($tag);
 176                         return htmllink_tag($params{page}, $params{destpage}, $tag);
 177                 }
 178         }
 179         grep {
 180                 $_ ne 'page' && $_ ne 'destpage' && $_ ne 'preview'
 181         } keys %params);
 182 }
 183
 184 sub pagetemplate (@) {
 185         my %params=@_;
 186         my $page=$params{page};
 187         my $destpage=$params{destpage};
 188         my $template=$params{template};
 189
 190         my $tags = $typedlinks{$page}{tag};
 191
 192         $template->param(tags => [
 193                 map {
 194                         link => htmllink_tag($page, $destpage, $_,
 195                                         rel => "tag", linktext => tagname($_))
 196                 }, sort keys %$tags
 197         ]) if defined $tags && %$tags && $template->query(name => "tags");
 198
 199         if ($template->query(name => "categories")) {
 200                 # It's an rss/atom template. Add any categories.
 201                 if (defined $tags && %$tags) {
 202                         $template->param(categories => [map { category => tagname($_) },
 203                                 sort keys %$tags]);
 204                 }
 205         }
 206 }
 207
 208 package IkiWiki::PageSpec;
 209
 210 sub match_tagged ($$;@) {
 211         my $page=shift;
 212         my $glob=IkiWiki::Plugin::tag::taglink(shift);
 213         return match_link($page, $glob, linktype => 'tag', @_);
 214 }
 215
 216 1