git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/autoindex.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::autoindex;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7 use Encode;
   8
   9 sub import {
  10         hook(type => "getsetup", id => "autoindex", call => \&getsetup);
  11         hook(type => "refresh", id => "autoindex", call => \&refresh);
  12 }
  13
  14 sub getsetup () {
  15         return
  16                 plugin => {
  17                         safe => 1,
  18                         rebuild => 0,
  19                         section => "special-purpose",
  20                 },
  21 }
  22
  23 sub genindex ($) {
  24         my $page=shift;
  25         my $file=newpagefile($page, $config{default_pageext});
  26         my $template=template("autoindex.tmpl");
  27         $template->param(page => $page);
  28         writefile($file, $config{srcdir}, $template->output);
  29         if ($config{rcs}) {
  30                 IkiWiki::rcs_add($file);
  31         }
  32 }
  33
  34 sub refresh () {
  35         eval q{use File::Find};
  36         error($@) if $@;
  37
  38         my (%pages, %dirs);
  39         foreach my $dir ($config{srcdir}, @{$config{underlaydirs}}, $config{underlaydir}) {
  40                 find({
  41                         no_chdir => 1,
  42                         wanted => sub {
  43                                 $_=decode_utf8($_);
  44                                 if (IkiWiki::file_pruned($_, $dir)) {
  45                                         $File::Find::prune=1;
  46                                 }
  47                                 elsif (! -l $_) {
  48                                         my ($f)=/$config{wiki_file_regexp}/; # untaint
  49                                         return unless defined $f;
  50                                         $f=~s/^\Q$dir\E\/?//;
  51                                         return unless length $f;
  52                                         return if $f =~ /\._([^.]+)$/; # skip internal page
  53                                         if (! -d _) {
  54                                                 $pages{pagename($f)}=1;
  55                                         }
  56                                         elsif ($dir eq $config{srcdir}) {
  57                                                 $dirs{$f}=1;
  58                                         }
  59                                 }
  60                         }
  61                 }, $dir);
  62         }
  63
  64         my %deleted;
  65         if (ref $pagestate{index}{autoindex}{deleted}) {
  66                %deleted=%{$pagestate{index}{autoindex}{deleted}};
  67                 foreach my $dir (keys %deleted) {
  68                         # remove deleted page state if the deleted page is re-added,
  69                         # or if all its subpages are deleted
  70                         if ($deleted{$dir} && (exists $pages{$dir} ||
  71                                                ! grep /^$dir\/.*/, keys %pages)) {
  72                                 delete $deleted{$dir};
  73                         }
  74                 }
  75                 $pagestate{index}{autoindex}{deleted}=\%deleted;
  76         }
  77
  78         my @needed;
  79         foreach my $dir (keys %dirs) {
  80                 if (! exists $pages{$dir} && ! $deleted{$dir} &&
  81                     grep /^$dir\/.*/, keys %pages) {
  82                         if (exists $IkiWiki::pagemtime{$dir}) {
  83                                 # This page must have just been deleted, so
  84                                 # don't re-add it. And remember it was
  85                                 # deleted.
  86                                 if (! ref $pagestate{index}{autoindex}{deleted}) {
  87                                         $pagestate{index}{autoindex}{deleted}={};
  88                                 }
  89                                 ${$pagestate{index}{autoindex}{deleted}}{$dir}=1;
  90                         }
  91                         else {
  92                                 push @needed, $dir;
  93                         }
  94                 }
  95         }
  96
  97         if (@needed) {
  98                 if ($config{rcs}) {
  99                         IkiWiki::disable_commit_hook();
 100                 }
 101                 foreach my $page (@needed) {
 102                         genindex($page);
 103                 }
 104                 if ($config{rcs}) {
 105                         IkiWiki::rcs_commit_staged(
 106                                 gettext("automatic index generation"),
 107                                 undef, undef);
 108                         IkiWiki::enable_commit_hook();
 109                 }
 110         }
 111 }
 112
 113 1