git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/remove.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::remove;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7
   8 sub import {
   9         hook(type => "getsetup", id => "remove", call => \&getsetup);
  10         hook(type => "formbuilder_setup", id => "remove", call => \&formbuilder_setup);
  11         hook(type => "formbuilder", id => "remove", call => \&formbuilder);
  12         hook(type => "sessioncgi", id => "remove", call => \&sessioncgi);
  13
  14 }
  15
  16 sub getsetup () {
  17         return
  18                 plugin => {
  19                         safe => 1,
  20                         rebuild => 0,
  21                         section => "web",
  22                 },
  23 }
  24
  25 sub check_canremove ($$$) {
  26         my $page=shift;
  27         my $q=shift;
  28         my $session=shift;
  29
  30         # Must be a known source file.
  31         if (! exists $pagesources{$page}) {
  32                 error(sprintf(gettext("%s does not exist"),
  33                         htmllink("", "", $page, noimageinline => 1)));
  34         }
  35
  36         # Must exist on disk, and be a regular file.
  37         my $file=$pagesources{$page};
  38         if (! -e "$config{srcdir}/$file") {
  39                 error(sprintf(gettext("%s is not in the srcdir, so it cannot be deleted"), $file));
  40         }
  41         elsif (-l "$config{srcdir}/$file" && ! -f _) {
  42                 error(sprintf(gettext("%s is not a file"), $file));
  43         }
  44
  45         # Must be editable.
  46         IkiWiki::check_canedit($page, $q, $session);
  47
  48         # If a user can't upload an attachment, don't let them delete it.
  49         # This is sorta overkill, but better safe than sorry.
  50         if (! defined pagetype($pagesources{$page})) {
  51                 if (IkiWiki::Plugin::attachment->can("check_canattach")) {
  52                         IkiWiki::Plugin::attachment::check_canattach($session, $page, "$config{srcdir}/$file");
  53                 }
  54                 else {
  55                         error("removal of attachments is not allowed");
  56                 }
  57         }
  58
  59         my $canremove;
  60         IkiWiki::run_hooks(canremove => sub {
  61                 return if defined $canremove;
  62                 my $ret=shift->(page => $page, cgi => $q, session => $session);
  63                 if (defined $ret) {
  64                         if ($ret eq "") {
  65                                 $canremove=1;
  66                         }
  67                         elsif (ref $ret eq 'CODE') {
  68                                 $ret->();
  69                                 $canremove=0;
  70                         }
  71                         elsif (defined $ret) {
  72                                 error($ret);
  73                                 $canremove=0;
  74                         }
  75                 }
  76         });
  77 }
  78
  79 sub formbuilder_setup (@) {
  80         my %params=@_;
  81         my $form=$params{form};
  82         my $q=$params{cgi};
  83
  84         if (defined $form->field("do") && ($form->field("do") eq "edit" ||
  85             $form->field("do") eq "create")) {
  86                 # Removal button for the page, and also for attachments.
  87                 push @{$params{buttons}}, "Remove" if $form->field("do") eq "edit";
  88                 $form->tmpl_param("field-remove" => '<input name="_submit" type="submit" value="Remove Attachments" />');
  89         }
  90 }
  91
  92 sub confirmation_form ($$) {
  93         my $q=shift;
  94         my $session=shift;
  95
  96         eval q{use CGI::FormBuilder};
  97         error($@) if $@;
  98         my $f = CGI::FormBuilder->new(
  99                 name => "remove",
 100                 header => 0,
 101                 charset => "utf-8",
 102                 method => 'POST',
 103                 javascript => 0,
 104                 params => $q,
 105                 action => $config{cgiurl},
 106                 stylesheet => IkiWiki::baseurl()."style.css",
 107                 fields => [qw{do page}],
 108         );
 109
 110         $f->field(name => "do", type => "hidden", value => "remove", force => 1);
 111
 112         return $f, ["Remove", "Cancel"];
 113 }
 114
 115 sub removal_confirm ($$@) {
 116         my $q=shift;
 117         my $session=shift;
 118         my $attachment=shift;
 119         my @pages=@_;
 120
 121         foreach my $page (@pages) {
 122                 check_canremove($page, $q, $session);
 123         }
 124
 125         # Save current form state to allow returning to it later
 126         # without losing any edits.
 127         # (But don't save what button was submitted, to avoid
 128         # looping back to here.)
 129         # Note: "_submit" is CGI::FormBuilder internals.
 130         $q->param(-name => "_submit", -value => "");
 131         $session->param(postremove => scalar $q->Vars);
 132         IkiWiki::cgi_savesession($session);
 133
 134         my ($f, $buttons)=confirmation_form($q, $session);
 135         $f->title(sprintf(gettext("confirm removal of %s"),
 136                 join(", ", map { pagetitle($_) } @pages)));
 137         $f->field(name => "page", type => "hidden", value => \@pages, force => 1);
 138         if (defined $attachment) {
 139                 $f->field(name => "attachment", type => "hidden",
 140                         value => $attachment, force => 1);
 141         }
 142
 143         IkiWiki::showform($f, $buttons, $session, $q);
 144         exit 0;
 145 }
 146
 147 sub postremove ($) {
 148         my $session=shift;
 149
 150         # Load saved form state and return to edit form.
 151         my $postremove=CGI->new($session->param("postremove"));
 152         $session->clear("postremove");
 153         IkiWiki::cgi_savesession($session);
 154         IkiWiki::cgi($postremove, $session);
 155 }
 156
 157 sub formbuilder (@) {
 158         my %params=@_;
 159         my $form=$params{form};
 160
 161         if (defined $form->field("do") && ($form->field("do") eq "edit" ||
 162             $form->field("do") eq "create")) {
 163                 my $q=$params{cgi};
 164                 my $session=$params{session};
 165
 166                 if ($form->submitted eq "Remove" && $form->field("do") eq "edit") {
 167                         removal_confirm($q, $session, 0, $form->field("page"));
 168                 }
 169                 elsif ($form->submitted eq "Remove Attachments") {
 170                         my @selected=map { Encode::decode_utf8($_) } $q->param("attachment_select");
 171                         if (! @selected) {
 172                                 error(gettext("Please select the attachments to remove."));
 173                         }
 174                         removal_confirm($q, $session, 1, @selected);
 175                 }
 176         }
 177 }
 178
 179 sub sessioncgi ($$) {
 180         my $q=shift;
 181
 182         if ($q->param("do") eq 'remove') {
 183                 my $session=shift;
 184                 my ($form, $buttons)=confirmation_form($q, $session);
 185                 IkiWiki::decode_form_utf8($form);
 186
 187                 if ($form->submitted eq 'Cancel') {
 188                         postremove($session);
 189                 }
 190                 elsif ($form->submitted eq 'Remove' && $form->validate) {
 191                         my @pages=$form->field("page");
 192
 193                         # Validate removal by checking that the page exists,
 194                         # and that the user is allowed to edit(/remove) it.
 195                         my @files;
 196                         foreach my $page (@pages) {
 197                                 check_canremove($page, $q, $session);
 198
 199                                 # This untaint is safe because of the
 200                                 # checks performed above, which verify the
 201                                 # page is a normal file, etc.
 202                                 push @files, IkiWiki::possibly_foolish_untaint($pagesources{$page});
 203                         }
 204
 205                         # Do removal, and update the wiki.
 206                         require IkiWiki::Render;
 207                         if ($config{rcs}) {
 208                                 IkiWiki::disable_commit_hook();
 209                                 foreach my $file (@files) {
 210                                         IkiWiki::rcs_remove($file);
 211                                 }
 212                                 IkiWiki::rcs_commit_staged(gettext("removed"),
 213                                         $session->param("name"), $ENV{REMOTE_ADDR});
 214                                 IkiWiki::enable_commit_hook();
 215                                 IkiWiki::rcs_update();
 216                         }
 217                         else {
 218                                 foreach my $file (@files) {
 219                                         IkiWiki::prune("$config{srcdir}/$file");
 220                                 }
 221                         }
 222                         IkiWiki::refresh();
 223                         IkiWiki::saveindex();
 224
 225                         if ($q->param("attachment")) {
 226                                 # Attachments were deleted, so redirect
 227                                 # back to the edit form.
 228                                 postremove($session);
 229                         }
 230                         else {
 231                                 # The page is gone, so redirect to parent
 232                                 # of the page.
 233                                 my $parent=IkiWiki::dirname($pages[0]);
 234                                 if (! exists $pagesources{$parent}) {
 235                                         $parent="index";
 236                                 }
 237                                 IkiWiki::redirect($q, urlto($parent, '/', 1));
 238                         }
 239                 }
 240                 else {
 241                         removal_confirm($q, $session, 0, $form->field("page"));
 242                 }
 243
 244                 exit 0;
 245         }
 246 }
 247
 248 1