git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/openid.pm

   1 #!/usr/bin/perl
   2 # OpenID support.
   3 package IkiWiki::Plugin::openid;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki 3.00;
   8
   9 sub import {
  10         add_underlay("openid-selector");
  11         add_underlay("jquery");
  12         hook(type => "checkconfig", id => "openid", call => \&checkconfig);
  13         hook(type => "getsetup", id => "openid", call => \&getsetup);
  14         hook(type => "auth", id => "openid", call => \&auth);
  15         hook(type => "formbuilder_setup", id => "openid",
  16                 call => \&formbuilder_setup, last => 1);
  17 }
  18
  19 sub checkconfig () {
  20         if ($config{cgi}) {
  21                 # Intercept normal signin form, so the openid selector
  22                 # can be displayed.
  23                 #
  24                 # When other auth hooks are registered, give the selector
  25                 # a reference to the normal signin form.
  26                 require IkiWiki::CGI;
  27                 my $real_cgi_signin;
  28                 if (keys %{$IkiWiki::hooks{auth}} > 1) {
  29                         $real_cgi_signin=\&IkiWiki::cgi_signin;
  30                 }
  31                 inject(name => "IkiWiki::cgi_signin", call => sub ($$) {
  32                         openid_selector($real_cgi_signin, @_);
  33                 });
  34         }
  35 }
  36
  37 sub getsetup () {
  38         return
  39                 plugin => {
  40                         safe => 1,
  41                         rebuild => 0,
  42                         section => "auth",
  43                 },
  44                 openid_realm => {
  45                         type => "string",
  46                         description => "url pattern of openid realm (default is cgiurl)",
  47                         safe => 0,
  48                         rebuild => 0,
  49                 },
  50                 openid_cgiurl => {
  51                         type => "string",
  52                         description => "url to ikiwiki cgi to use for openid authentication (default is cgiurl)",
  53                         safe => 0,
  54                         rebuild => 0,
  55                 },
  56 }
  57
  58 sub openid_selector {
  59         my $real_cgi_signin=shift;
  60         my $q=shift;
  61         my $session=shift;
  62
  63         my $openid_url=$q->param('openid_identifier');
  64         my $openid_error;
  65
  66         if (! load_openid_module()) {
  67                 if ($real_cgi_signin) {
  68                         $real_cgi_signin->($q, $session);
  69                         exit;
  70                 }
  71                 error(sprintf(gettext("failed to load openid module: "), @_));
  72         }
  73         elsif (defined $q->param("action") && $q->param("action") eq "verify") {
  74                 validate($q, $session, $openid_url, sub {
  75                         $openid_error=shift;
  76                 });
  77         }
  78
  79         my $template=IkiWiki::template("openid-selector.tmpl");
  80         $template->param(
  81                 cgiurl => IkiWiki::cgiurl(),
  82                 (defined $openid_error ? (openid_error => $openid_error) : ()),
  83                 (defined $openid_url ? (openid_url => $openid_url) : ()),
  84                 ($real_cgi_signin ? (nonopenidform => $real_cgi_signin->($q, $session, 1)) : ()),
  85         );
  86
  87         IkiWiki::printheader($session);
  88         print IkiWiki::cgitemplate($q, "signin", $template->output);
  89         exit;
  90 }
  91
  92 sub formbuilder_setup (@) {
  93         my %params=@_;
  94
  95         my $form=$params{form};
  96         my $session=$params{session};
  97         my $cgi=$params{cgi};
  98
  99         if ($form->title eq "preferences" &&
 100                IkiWiki::openiduser($session->param("name"))) {
 101                 $form->field(name => "openid_identifier", disabled => 1,
 102                         label => htmllink("", "", "ikiwiki/OpenID", noimageinline => 1),
 103                         value => "",
 104                         size => 1, force => 1,
 105                         fieldset => "login",
 106                         comment => $session->param("name"));
 107                 $form->field(name => "email", type => "hidden");
 108         }
 109 }
 110
 111 sub validate ($$$;$) {
 112         my $q=shift;
 113         my $session=shift;
 114         my $openid_url=shift;
 115         my $errhandler=shift;
 116
 117         my $csr=getobj($q, $session);
 118
 119         my $claimed_identity = $csr->claimed_identity($openid_url);
 120         if (! $claimed_identity) {
 121                 if ($errhandler) {
 122                         $errhandler->($csr->err);
 123                         return 0;
 124                 }
 125                 else {
 126                         error($csr->err);
 127                 }
 128         }
 129
 130         # Ask for client to provide a name and email, if possible.
 131         # Try sreg and ax
 132         if ($claimed_identity->can("set_extension_args")) {
 133                 $claimed_identity->set_extension_args(
 134                         'http://openid.net/extensions/sreg/1.1',
 135                         {
 136                                 optional => 'email,fullname,nickname',
 137                         },
 138                 );
 139                 $claimed_identity->set_extension_args(
 140                         'http://openid.net/srv/ax/1.0',
 141                         {
 142                                 mode => 'fetch_request',
 143                                 'required' => 'email,fullname,nickname,firstname',
 144                                 'type.email' => "http://schema.openid.net/contact/email",
 145                                 'type.fullname' => "http://axschema.org/namePerson",
 146                                 'type.nickname' => "http://axschema.org/namePerson/friendly",
 147                                 'type.firstname' => "http://axschema.org/namePerson/first",
 148                         },
 149                 );
 150         }
 151
 152         my $cgiurl=$config{openid_cgiurl};
 153         $cgiurl=$q->url if ! defined $cgiurl;
 154
 155         my $trust_root=$config{openid_realm};
 156         $trust_root=$cgiurl if ! defined $trust_root;
 157
 158         my $check_url = $claimed_identity->check_url(
 159                 return_to => auto_upgrade_https($q, "$cgiurl?do=postsignin"),
 160                 trust_root => auto_upgrade_https($q, $trust_root),
 161                 delayed_return => 1,
 162         );
 163         # Redirect the user to the OpenID server, which will
 164         # eventually bounce them back to auth()
 165         IkiWiki::redirect($q, $check_url);
 166         exit 0;
 167 }
 168
 169 sub auth ($$) {
 170         my $q=shift;
 171         my $session=shift;
 172
 173         if (defined $q->param('openid.mode')) {
 174                 my $csr=getobj($q, $session);
 175
 176                 if (my $setup_url = $csr->user_setup_url) {
 177                         IkiWiki::redirect($q, $setup_url);
 178                 }
 179                 elsif ($csr->user_cancel) {
 180                         IkiWiki::redirect($q, IkiWiki::baseurl(undef));
 181                 }
 182                 elsif (my $vident = $csr->verified_identity) {
 183                         $session->param(name => $vident->url);
 184
 185                         my @extensions;
 186                         if ($vident->can("signed_extension_fields")) {
 187                                 @extensions=grep { defined } (
 188                                         $vident->signed_extension_fields('http://openid.net/extensions/sreg/1.1'),
 189                                         $vident->signed_extension_fields('http://openid.net/srv/ax/1.0'),
 190                                 );
 191                         }
 192                         my $nickname;
 193                         foreach my $ext (@extensions) {
 194                                 foreach my $field (qw{value.email email}) {
 195                                         if (exists $ext->{$field} &&
 196                                             defined $ext->{$field} &&
 197                                             length $ext->{$field}) {
 198                                                 $session->param(email => $ext->{$field});
 199                                                 if (! defined $nickname &&
 200                                                     $ext->{$field}=~/(.+)@.+/) {
 201                                                         $nickname = $1;
 202                                                 }
 203                                                 last;
 204                                         }
 205                                 }
 206                                 foreach my $field (qw{value.nickname nickname value.fullname fullname value.firstname}) {
 207                                         if (exists $ext->{$field} &&
 208                                             defined $ext->{$field} &&
 209                                             length $ext->{$field}) {
 210                                                 $nickname=$ext->{$field};
 211                                                 last;
 212                                         }
 213                                 }
 214                         }
 215                         if (defined $nickname) {
 216                                 $session->param(nickname =>
 217                                         Encode::decode_utf8($nickname));
 218                         }
 219                 }
 220                 else {
 221                         error("OpenID failure: ".$csr->err);
 222                 }
 223         }
 224         elsif (defined $q->param('openid_identifier')) {
 225                 # myopenid.com affiliate support
 226                 validate($q, $session, $q->param('openid_identifier'));
 227         }
 228 }
 229
 230 sub getobj ($$) {
 231         my $q=shift;
 232         my $session=shift;
 233
 234         eval q{use Net::INET6Glue::INET_is_INET6}; # may not be available
 235         eval q{use Net::OpenID::Consumer};
 236         error($@) if $@;
 237
 238         my $ua;
 239         eval q{use LWPx::ParanoidAgent};
 240         if (! $@) {
 241                 $ua=LWPx::ParanoidAgent->new(agent => $config{useragent});
 242         }
 243         else {
 244                 $ua=useragent();
 245         }
 246
 247         # Store the secret in the session.
 248         my $secret=$session->param("openid_secret");
 249         if (! defined $secret) {
 250                 $secret=rand;
 251                 $session->param(openid_secret => $secret);
 252         }
 253
 254         my $cgiurl=$config{openid_cgiurl};
 255         $cgiurl=$q->url if ! defined $cgiurl;
 256
 257         return Net::OpenID::Consumer->new(
 258                 ua => $ua,
 259                 args => $q,
 260                 consumer_secret => sub { return shift()+$secret },
 261                 required_root => auto_upgrade_https($q, $cgiurl),
 262         );
 263 }
 264
 265 sub auto_upgrade_https {
 266         my $q=shift;
 267         my $url=shift;
 268         if ($q->https()) {
 269                 $url=~s/^http:/https:/i;
 270         }
 271         return $url;
 272 }
 273
 274 sub load_openid_module {
 275         # Give up if module is unavailable to avoid needing to depend on it.
 276         eval q{use Net::OpenID::Consumer};
 277         if ($@) {
 278                 debug("unable to load Net::OpenID::Consumer, not enabling OpenID login ($@)");
 279                 return;
 280         }
 281         return 1;
 282 }
 283
 284 1