git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/inline.pm

   1 #!/usr/bin/perl
   2 # Page inlining and blogging.
   3 package IkiWiki::Plugin::inline;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use IkiWiki 3.00;
   9 use URI;
  10
  11 my %knownfeeds;
  12 my %page_numfeeds;
  13 my @inline;
  14 my $nested=0;
  15
  16 sub import {
  17         hook(type => "getopt", id => "inline", call => \&getopt);
  18         hook(type => "getsetup", id => "inline", call => \&getsetup);
  19         hook(type => "checkconfig", id => "inline", call => \&checkconfig);
  20         hook(type => "sessioncgi", id => "inline", call => \&sessioncgi);
  21         hook(type => "preprocess", id => "inline",
  22                 call => \&IkiWiki::preprocess_inline);
  23         hook(type => "pagetemplate", id => "inline",
  24                 call => \&IkiWiki::pagetemplate_inline);
  25         hook(type => "format", id => "inline", call => \&format, first => 1);
  26         # Hook to change to do pinging since it's called late.
  27         # This ensures each page only pings once and prevents slow
  28         # pings interrupting page builds.
  29         hook(type => "change", id => "inline", call => \&IkiWiki::pingurl);
  30 }
  31
  32 sub getopt () {
  33         eval q{use Getopt::Long};
  34         error($@) if $@;
  35         Getopt::Long::Configure('pass_through');
  36         GetOptions(
  37                 "rss!" => \$config{rss},
  38                 "atom!" => \$config{atom},
  39                 "allowrss!" => \$config{allowrss},
  40                 "allowatom!" => \$config{allowatom},
  41                 "pingurl=s" => sub {
  42                         push @{$config{pingurl}}, $_[1];
  43                 },
  44         );
  45 }
  46
  47 sub getsetup () {
  48         return
  49                 plugin => {
  50                         safe => 1,
  51                         rebuild => undef,
  52                 },
  53                 rss => {
  54                         type => "boolean",
  55                         example => 0,
  56                         description => "enable rss feeds by default?",
  57                         safe => 1,
  58                         rebuild => 1,
  59                 },
  60                 atom => {
  61                         type => "boolean",
  62                         example => 0,
  63                         description => "enable atom feeds by default?",
  64                         safe => 1,
  65                         rebuild => 1,
  66                 },
  67                 allowrss => {
  68                         type => "boolean",
  69                         example => 0,
  70                         description => "allow rss feeds to be used?",
  71                         safe => 1,
  72                         rebuild => 1,
  73                 },
  74                 allowatom => {
  75                         type => "boolean",
  76                         example => 0,
  77                         description => "allow atom feeds to be used?",
  78                         safe => 1,
  79                         rebuild => 1,
  80                 },
  81                 pingurl => {
  82                         type => "string",
  83                         example => "http://rpc.technorati.com/rpc/ping",
  84                         description => "urls to ping (using XML-RPC) on feed update",
  85                         safe => 1,
  86                         rebuild => 0,
  87                 },
  88 }
  89
  90 sub checkconfig () {
  91         if (($config{rss} || $config{atom}) && ! length $config{url}) {
  92                 error(gettext("Must specify url to wiki with --url when using --rss or --atom"));
  93         }
  94         if ($config{rss}) {
  95                 push @{$config{wiki_file_prune_regexps}}, qr/\.rss$/;
  96         }
  97         if ($config{atom}) {
  98                 push @{$config{wiki_file_prune_regexps}}, qr/\.atom$/;
  99         }
 100         if (! exists $config{pingurl}) {
 101                 $config{pingurl}=[];
 102         }
 103 }
 104
 105 sub format (@) {
 106         my %params=@_;
 107
 108         # Fill in the inline content generated earlier. This is actually an
 109         # optimisation.
 110         $params{content}=~s{<div class="inline" id="([^"]+)"></div>}{
 111                 delete @inline[$1,]
 112         }eg;
 113         return $params{content};
 114 }
 115
 116 sub sessioncgi ($$) {
 117         my $q=shift;
 118         my $session=shift;
 119
 120         if ($q->param('do') eq 'blog') {
 121                 my $page=titlepage(decode_utf8($q->param('title')));
 122                 $page=~s/(\/)/"__".ord($1)."__"/eg; # don't create subdirs
 123                 # if the page already exists, munge it to be unique
 124                 my $from=$q->param('from');
 125                 my $add="";
 126                 while (exists $IkiWiki::pagecase{lc($from."/".$page.$add)}) {
 127                         $add=1 unless length $add;
 128                         $add++;
 129                 }
 130                 $q->param('page', $page.$add);
 131                 # now go create the page
 132                 $q->param('do', 'create');
 133                 # make sure the editpage plugin in loaded
 134                 if (IkiWiki->can("cgi_editpage")) {
 135                         IkiWiki::cgi_editpage($q, $session);
 136                 }
 137                 else {
 138                         error(gettext("page editing not allowed"));
 139                 }
 140                 exit;
 141         }
 142 }
 143
 144 # Back to ikiwiki namespace for the rest, this code is very much
 145 # internal to ikiwiki even though it's separated into a plugin.
 146 package IkiWiki;
 147
 148 my %toping;
 149 my %feedlinks;
 150
 151 sub preprocess_inline (@) {
 152         my %params=@_;
 153
 154         if (! exists $params{pages} && ! exists $params{pagenames}) {
 155                 error gettext("missing pages parameter");
 156         }
 157         my $raw=yesno($params{raw});
 158         my $archive=yesno($params{archive});
 159         my $rss=(($config{rss} || $config{allowrss}) && exists $params{rss}) ? yesno($params{rss}) : $config{rss};
 160         my $atom=(($config{atom} || $config{allowatom}) && exists $params{atom}) ? yesno($params{atom}) : $config{atom};
 161         my $quick=exists $params{quick} ? yesno($params{quick}) : 0;
 162         my $feeds=exists $params{feeds} ? yesno($params{feeds}) : !$quick;
 163         my $emptyfeeds=exists $params{emptyfeeds} ? yesno($params{emptyfeeds}) : 1;
 164         my $feedonly=yesno($params{feedonly});
 165         if (! exists $params{show} && ! $archive) {
 166                 $params{show}=10;
 167         }
 168         if (! exists $params{feedshow} && exists $params{show}) {
 169                 $params{feedshow}=$params{show};
 170         }
 171         my $desc;
 172         if (exists $params{description}) {
 173                 $desc = $params{description}
 174         }
 175         else {
 176                 $desc = $config{wikiname};
 177         }
 178         my $actions=yesno($params{actions});
 179         if (exists $params{template}) {
 180                 $params{template}=~s/[^-_a-zA-Z0-9]+//g;
 181         }
 182         else {
 183                 $params{template} = $archive ? "archivepage" : "inlinepage";
 184         }
 185
 186         my @list;
 187
 188         if (exists $params{pagenames}) {
 189                 foreach my $p (qw(sort pages)) {
 190                         if (exists $params{$p}) {
 191                                 error sprintf(gettext("the %s and %s parameters cannot be used together"),
 192                                         "pagenames", $p);
 193                         }
 194                 }
 195
 196                 @list = map { bestlink($params{page}, $_) }
 197                         split ' ', $params{pagenames};
 198
 199                 $params{pages} = join(" or ", @list);
 200         }
 201         else {
 202                 @list = pagespec_match_list(
 203                         [ grep { $_ ne $params{page} } keys %pagesources ],
 204                         $params{pages}, location => $params{page});
 205
 206                 if (exists $params{sort} && $params{sort} eq 'title') {
 207                         @list=sort { pagetitle(basename($a)) cmp pagetitle(basename($b)) } @list;
 208                 }
 209                 elsif (exists $params{sort} && $params{sort} eq 'title_natural') {
 210                         eval q{use Sort::Naturally};
 211                         if ($@) {
 212                                 error(gettext("Sort::Naturally needed for title_natural sort"));
 213                         }
 214                         @list=sort { Sort::Naturally::ncmp(pagetitle(basename($a)), pagetitle(basename($b))) } @list;
 215                 }
 216                 elsif (exists $params{sort} && $params{sort} eq 'mtime') {
 217                         @list=sort { $pagemtime{$b} <=> $pagemtime{$a} } @list;
 218                 }
 219                 elsif (! exists $params{sort} || $params{sort} eq 'age') {
 220                         @list=sort { $pagectime{$b} <=> $pagectime{$a} } @list;
 221                 }
 222                 else {
 223                         error sprintf(gettext("unknown sort type %s"), $params{sort});
 224                 }
 225         }
 226
 227         if (yesno($params{reverse})) {
 228                 @list=reverse(@list);
 229         }
 230
 231         if (exists $params{skip}) {
 232                 @list=@list[$params{skip} .. scalar @list - 1];
 233         }
 234
 235         my @feedlist;
 236         if ($feeds) {
 237                 if (exists $params{feedshow} &&
 238                     $params{feedshow} && @list > $params{feedshow}) {
 239                         @feedlist=@list[0..$params{feedshow} - 1];
 240                 }
 241                 else {
 242                         @feedlist=@list;
 243                 }
 244         }
 245
 246         if ($params{show} && @list > $params{show}) {
 247                 @list=@list[0..$params{show} - 1];
 248         }
 249
 250         add_depends($params{page}, $params{pages});
 251         # Explicitly add all currently displayed pages as dependencies, so
 252         # that if they are removed or otherwise changed, the inline will be
 253         # sure to be updated.
 254         add_depends($params{page}, join(" or ", $#list >= $#feedlist ? @list : @feedlist));
 255
 256         if ($feeds && exists $params{feedpages}) {
 257                 @feedlist=grep { pagespec_match($_, $params{feedpages}, location => $params{page}) } @feedlist;
 258         }
 259
 260         my ($feedbase, $feednum);
 261         if ($feeds) {
 262                 # Ensure that multiple feeds on a page go to unique files.
 263
 264                 # Feedfile can lead to conflicts if usedirs is not enabled,
 265                 # so avoid supporting it in that case.
 266                 delete $params{feedfile} if ! $config{usedirs};
 267                 # Tight limits on legal feedfiles, to avoid security issues
 268                 # and conflicts.
 269                 if (defined $params{feedfile}) {
 270                         if ($params{feedfile} =~ /\// ||
 271                             $params{feedfile} !~ /$config{wiki_file_regexp}/) {
 272                                 error("illegal feedfile");
 273                         }
 274                         $params{feedfile}=possibly_foolish_untaint($params{feedfile});
 275                 }
 276                 $feedbase=targetpage($params{destpage}, "", $params{feedfile});
 277
 278                 my $feedid=join("\0", $feedbase, map { $_."\0".$params{$_} } sort keys %params);
 279                 if (exists $knownfeeds{$feedid}) {
 280                         $feednum=$knownfeeds{$feedid};
 281                 }
 282                 else {
 283                         if (exists $page_numfeeds{$params{destpage}}{$feedbase}) {
 284                                 if ($feeds) {
 285                                         $feednum=$knownfeeds{$feedid}=++$page_numfeeds{$params{destpage}}{$feedbase};
 286                                 }
 287                         }
 288                         else {
 289                                 $feednum=$knownfeeds{$feedid}="";
 290                                 if ($feeds) {
 291                                         $page_numfeeds{$params{destpage}}{$feedbase}=1;
 292                                 }
 293                         }
 294                 }
 295         }
 296
 297         my $rssurl=abs2rel($feedbase."rss".$feednum, dirname(htmlpage($params{destpage}))) if $feeds && $rss;
 298         my $atomurl=abs2rel($feedbase."atom".$feednum, dirname(htmlpage($params{destpage}))) if $feeds && $atom;
 299
 300         my $ret="";
 301
 302         if (length $config{cgiurl} && ! $params{preview} && (exists $params{rootpage} ||
 303             (exists $params{postform} && yesno($params{postform}))) &&
 304             IkiWiki->can("cgi_editpage")) {
 305                 # Add a blog post form, with feed buttons.
 306                 my $formtemplate=template("blogpost.tmpl", blind_cache => 1);
 307                 $formtemplate->param(cgiurl => $config{cgiurl});
 308                 my $rootpage;
 309                 if (exists $params{rootpage}) {
 310                         $rootpage=bestlink($params{page}, $params{rootpage});
 311                         if (!length $rootpage) {
 312                                 $rootpage=$params{rootpage};
 313                         }
 314                 }
 315                 else {
 316                         $rootpage=$params{page};
 317                 }
 318                 $formtemplate->param(rootpage => $rootpage);
 319                 $formtemplate->param(rssurl => $rssurl) if $feeds && $rss;
 320                 $formtemplate->param(atomurl => $atomurl) if $feeds && $atom;
 321                 if (exists $params{postformtext}) {
 322                         $formtemplate->param(postformtext =>
 323                                 $params{postformtext});
 324                 }
 325                 else {
 326                         $formtemplate->param(postformtext =>
 327                                 gettext("Add a new post titled:"));
 328                 }
 329                 $ret.=$formtemplate->output;
 330
 331                 # The post form includes the feed buttons, so
 332                 # emptyfeeds cannot be hidden.
 333                 $emptyfeeds=1;
 334         }
 335         elsif ($feeds && !$params{preview} && ($emptyfeeds || @feedlist)) {
 336                 # Add feed buttons.
 337                 my $linktemplate=template("feedlink.tmpl", blind_cache => 1);
 338                 $linktemplate->param(rssurl => $rssurl) if $rss;
 339                 $linktemplate->param(atomurl => $atomurl) if $atom;
 340                 $ret.=$linktemplate->output;
 341         }
 342
 343         if (! $feedonly) {
 344                 require HTML::Template;
 345                 my @params=IkiWiki::template_params($params{template}.".tmpl", blind_cache => 1);
 346                 if (! @params) {
 347                         error sprintf(gettext("nonexistant template %s"), $params{template});
 348                 }
 349                 my $template=HTML::Template->new(@params) unless $raw;
 350
 351                 foreach my $page (@list) {
 352                         my $file = $pagesources{$page};
 353                         my $type = pagetype($file);
 354                         if (! $raw || ($raw && ! defined $type)) {
 355                                 unless ($archive && $quick) {
 356                                         # Get the content before populating the
 357                                         # template, since getting the content uses
 358                                         # the same template if inlines are nested.
 359                                         my $content=get_inline_content($page, $params{destpage});
 360                                         $template->param(content => $content);
 361                                 }
 362                                 $template->param(pageurl => urlto($page, $params{destpage}));
 363                                 $template->param(inlinepage => $page);
 364                                 $template->param(title => pagetitle(basename($page)));
 365                                 $template->param(ctime => displaytime($pagectime{$page}, $params{timeformat}));
 366                                 $template->param(mtime => displaytime($pagemtime{$page}, $params{timeformat}));
 367                                 $template->param(first => 1) if $page eq $list[0];
 368                                 $template->param(last => 1) if $page eq $list[$#list];
 369
 370                                 if ($actions) {
 371                                         my $file = $pagesources{$page};
 372                                         my $type = pagetype($file);
 373                                         if ($config{discussion}) {
 374                                                 my $discussionlink=lc(gettext("Discussion"));
 375                                                 if ($page !~ /.*\/\Q$discussionlink\E$/ &&
 376                                                     (length $config{cgiurl} ||
 377                                                      exists $links{$page."/".$discussionlink})) {
 378                                                         $template->param(have_actions => 1);
 379                                                         $template->param(discussionlink =>
 380                                                                 htmllink($page,
 381                                                                         $params{destpage},
 382                                                                         gettext("Discussion"),
 383                                                                         noimageinline => 1,
 384                                                                         forcesubpage => 1));
 385                                                 }
 386                                         }
 387                                         if (length $config{cgiurl} && defined $type) {
 388                                                 $template->param(have_actions => 1);
 389                                                 $template->param(editurl => cgiurl(do => "edit", page => $page));
 390                                         }
 391                                 }
 392
 393                                 run_hooks(pagetemplate => sub {
 394                                         shift->(page => $page, destpage => $params{destpage},
 395                                                 template => $template,);
 396                                 });
 397
 398                                 $ret.=$template->output;
 399                                 $template->clear_params;
 400                         }
 401                         else {
 402                                 if (defined $type) {
 403                                         $ret.="\n".
 404                                               linkify($page, $params{destpage},
 405                                               preprocess($page, $params{destpage},
 406                                               filter($page, $params{destpage},
 407                                               readfile(srcfile($file)))));
 408                                 }
 409                         }
 410                 }
 411         }
 412
 413         if ($feeds && ($emptyfeeds || @feedlist)) {
 414                 if ($rss) {
 415                         my $rssp=$feedbase."rss".$feednum;
 416                         will_render($params{destpage}, $rssp);
 417                         if (! $params{preview}) {
 418                                 writefile($rssp, $config{destdir},
 419                                         genfeed("rss",
 420                                                 $config{url}."/".$rssp, $desc, $params{guid}, $params{destpage}, @feedlist));
 421                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 422                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/rss+xml" title="$desc (RSS)" href="$rssurl" />};
 423                         }
 424                 }
 425                 if ($atom) {
 426                         my $atomp=$feedbase."atom".$feednum;
 427                         will_render($params{destpage}, $atomp);
 428                         if (! $params{preview}) {
 429                                 writefile($atomp, $config{destdir},
 430                                         genfeed("atom", $config{url}."/".$atomp, $desc, $params{guid}, $params{destpage}, @feedlist));
 431                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 432                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/atom+xml" title="$desc (Atom)" href="$atomurl" />};
 433                         }
 434                 }
 435         }
 436
 437         return $ret if $raw || $nested;
 438         push @inline, $ret;
 439         return "<div class=\"inline\" id=\"$#inline\"></div>\n\n";
 440 }
 441
 442 sub pagetemplate_inline (@) {
 443         my %params=@_;
 444         my $page=$params{page};
 445         my $template=$params{template};
 446
 447         $template->param(feedlinks => $feedlinks{$page})
 448                 if exists $feedlinks{$page} && $template->query(name => "feedlinks");
 449 }
 450
 451 sub get_inline_content ($$) {
 452         my $page=shift;
 453         my $destpage=shift;
 454
 455         my $file=$pagesources{$page};
 456         my $type=pagetype($file);
 457         if (defined $type) {
 458                 $nested++;
 459                 my $ret=htmlize($page, $destpage, $type,
 460                        linkify($page, $destpage,
 461                        preprocess($page, $destpage,
 462                        filter($page, $destpage,
 463                        readfile(srcfile($file))))));
 464                 $nested--;
 465                 return $ret;
 466         }
 467         else {
 468                 return "";
 469         }
 470 }
 471
 472 sub date_822 ($) {
 473         my $time=shift;
 474
 475         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 476         POSIX::setlocale(&POSIX::LC_TIME, "C");
 477         my $ret=POSIX::strftime("%a, %d %b %Y %H:%M:%S %z", localtime($time));
 478         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 479         return $ret;
 480 }
 481
 482 sub date_3339 ($) {
 483         my $time=shift;
 484
 485         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 486         POSIX::setlocale(&POSIX::LC_TIME, "C");
 487         my $ret=POSIX::strftime("%Y-%m-%dT%H:%M:%SZ", gmtime($time));
 488         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 489         return $ret;
 490 }
 491
 492 sub absolute_urls ($$) {
 493         # sucky sub because rss sucks
 494         my $content=shift;
 495         my $baseurl=shift;
 496
 497         my $url=$baseurl;
 498         $url=~s/[^\/]+$//;
 499
 500         # what is the non path part of the url?
 501         my $top_uri = URI->new($url);
 502         $top_uri->path_query(""); # reset the path
 503         my $urltop = $top_uri->as_string;
 504
 505         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(#[^"]+)"/$1 href="$baseurl$2"/mig;
 506         # relative to another wiki page
 507         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(?!\w+:)([^\/][^"]*)"/$1 href="$url$2"/mig;
 508         $content=~s/(<img(?:\s+(?:class|id|width|height)\s*="?\w+"?)*)\s+src=\s*"(?!\w+:)([^\/][^"]*)"/$1 src="$url$2"/mig;
 509         # relative to the top of the site
 510         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(?!\w+:)(\/[^"]*)"/$1 href="$urltop$2"/mig;
 511         $content=~s/(<img(?:\s+(?:class|id|width|height)\s*="?\w+"?)*)\s+src=\s*"(?!\w+:)(\/[^"]*)"/$1 src="$urltop$2"/mig;
 512         return $content;
 513 }
 514
 515 sub genfeed ($$$$$@) {
 516         my $feedtype=shift;
 517         my $feedurl=shift;
 518         my $feeddesc=shift;
 519         my $guid=shift;
 520         my $page=shift;
 521         my @pages=@_;
 522
 523         my $url=URI->new(encode_utf8(urlto($page,"",1)));
 524
 525         my $itemtemplate=template($feedtype."item.tmpl", blind_cache => 1);
 526         my $content="";
 527         my $lasttime = 0;
 528         foreach my $p (@pages) {
 529                 my $u=URI->new(encode_utf8(urlto($p, "", 1)));
 530                 my $pcontent = absolute_urls(get_inline_content($p, $page), $url);
 531
 532                 $itemtemplate->param(
 533                         title => pagetitle(basename($p)),
 534                         url => $u,
 535                         permalink => $u,
 536                         cdate_822 => date_822($pagectime{$p}),
 537                         mdate_822 => date_822($pagemtime{$p}),
 538                         cdate_3339 => date_3339($pagectime{$p}),
 539                         mdate_3339 => date_3339($pagemtime{$p}),
 540                 );
 541
 542                 if (exists $pagestate{$p}) {
 543                         if (exists $pagestate{$p}{meta}{guid}) {
 544                                 $itemtemplate->param(guid => $pagestate{$p}{meta}{guid});
 545                         }
 546
 547                         if (exists $pagestate{$p}{meta}{updated}) {
 548                                 $itemtemplate->param(mdate_822 => date_822($pagestate{$p}{meta}{updated}));
 549                                 $itemtemplate->param(mdate_3339 => date_3339($pagestate{$p}{meta}{updated}));
 550                         }
 551                 }
 552
 553                 if ($itemtemplate->query(name => "enclosure")) {
 554                         my $file=$pagesources{$p};
 555                         my $type=pagetype($file);
 556                         if (defined $type) {
 557                                 $itemtemplate->param(content => $pcontent);
 558                         }
 559                         else {
 560                                 my $size=(srcfile_stat($file))[8];
 561                                 my $mime="unknown";
 562                                 eval q{use File::MimeInfo};
 563                                 if (! $@) {
 564                                         $mime = mimetype($file);
 565                                 }
 566                                 $itemtemplate->param(
 567                                         enclosure => $u,
 568                                         type => $mime,
 569                                         length => $size,
 570                                 );
 571                         }
 572                 }
 573                 else {
 574                         $itemtemplate->param(content => $pcontent);
 575                 }
 576
 577                 run_hooks(pagetemplate => sub {
 578                         shift->(page => $p, destpage => $page,
 579                                 template => $itemtemplate);
 580                 });
 581
 582                 $content.=$itemtemplate->output;
 583                 $itemtemplate->clear_params;
 584
 585                 $lasttime = $pagemtime{$p} if $pagemtime{$p} > $lasttime;
 586         }
 587
 588         my $template=template($feedtype."page.tmpl", blind_cache => 1);
 589         $template->param(
 590                 title => $page ne "index" ? pagetitle($page) : $config{wikiname},
 591                 wikiname => $config{wikiname},
 592                 pageurl => $url,
 593                 content => $content,
 594                 feeddesc => $feeddesc,
 595                 guid => $guid,
 596                 feeddate => date_3339($lasttime),
 597                 feedurl => $feedurl,
 598                 version => $IkiWiki::version,
 599         );
 600         run_hooks(pagetemplate => sub {
 601                 shift->(page => $page, destpage => $page,
 602                         template => $template);
 603         });
 604
 605         return $template->output;
 606 }
 607
 608 sub pingurl (@) {
 609         return unless @{$config{pingurl}} && %toping;
 610
 611         eval q{require RPC::XML::Client};
 612         if ($@) {
 613                 debug(gettext("RPC::XML::Client not found, not pinging"));
 614                 return;
 615         }
 616
 617         # daemonize here so slow pings don't slow down wiki updates
 618         defined(my $pid = fork) or error("Can't fork: $!");
 619         return if $pid;
 620         chdir '/';
 621         POSIX::setsid() or error("Can't start a new session: $!");
 622         open STDIN, '/dev/null';
 623         open STDOUT, '>/dev/null';
 624         open STDERR, '>&STDOUT' or error("Can't dup stdout: $!");
 625
 626         # Don't need to keep a lock on the wiki as a daemon.
 627         IkiWiki::unlockwiki();
 628
 629         foreach my $page (keys %toping) {
 630                 my $title=pagetitle(basename($page), 0);
 631                 my $url=urlto($page, "", 1);
 632                 foreach my $pingurl (@{$config{pingurl}}) {
 633                         debug("Pinging $pingurl for $page");
 634                         eval {
 635                                 my $client = RPC::XML::Client->new($pingurl);
 636                                 my $req = RPC::XML::request->new('weblogUpdates.ping',
 637                                         $title, $url);
 638                                 my $res = $client->send_request($req);
 639                                 if (! ref $res) {
 640                                         error("Did not receive response to ping");
 641                                 }
 642                                 my $r=$res->value;
 643                                 if (! exists $r->{flerror} || $r->{flerror}) {
 644                                         error("Ping rejected: ".(exists $r->{message} ? $r->{message} : "[unknown reason]"));
 645                                 }
 646                         };
 647                         if ($@) {
 648                                 error "Ping failed: $@";
 649                         }
 650                 }
 651         }
 652
 653         exit 0; # daemon done
 654 }
 655
 656 1