git.oblomov.eu Git - ikiwiki/blob - IkiWiki/CGI.pm

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5 use IkiWiki;
   6 use IkiWiki::UserInfo;
   7 use open qw{:utf8 :std};
   8 use Encode;
   9
  10 package IkiWiki;
  11
  12 sub printheader ($) { #{{{
  13         my $session=shift;
  14
  15         if ($config{sslcookie}) {
  16                 print $session->header(-charset => 'utf-8',
  17                         -cookie => $session->cookie(-secure => 1));
  18         } else {
  19                 print $session->header(-charset => 'utf-8');
  20         }
  21
  22 } #}}}
  23
  24 sub redirect ($$) { #{{{
  25         my $q=shift;
  26         my $url=shift;
  27         if (! $config{w3mmode}) {
  28                 print $q->redirect($url);
  29         }
  30         else {
  31                 print "Content-type: text/plain\n";
  32                 print "W3m-control: GOTO $url\n\n";
  33         }
  34 } #}}}
  35
  36 sub check_canedit ($$$;$) { #{{{
  37         my $page=shift;
  38         my $q=shift;
  39         my $session=shift;
  40         my $nonfatal=shift;
  41
  42         my $canedit;
  43         run_hooks(canedit => sub {
  44                 return if defined $canedit;
  45                 my $ret=shift->($page, $q, $session);
  46                 if (defined $ret && $ret eq "") {
  47                         $canedit=1;
  48                 }
  49                 elsif (defined $ret) {
  50                         $canedit=0;
  51                         error($ret) unless $nonfatal;
  52                 }
  53         });
  54         return $canedit;
  55 } #}}}
  56
  57 sub decode_form_utf8 ($) { #{{{
  58         my $form = shift;
  59         foreach my $f ($form->field) {
  60                 next if Encode::is_utf8(scalar $form->field($f));
  61                 $form->field(name  => $f,
  62                              value => decode_utf8($form->field($f)),
  63                              force => 1,
  64                             );
  65         }
  66 } #}}}
  67
  68 sub cgi_recentchanges ($) { #{{{
  69         my $q=shift;
  70
  71         # Optimisation: building recentchanges means calculating lots of
  72         # links. Memoizing htmllink speeds it up a lot (can't be memoized
  73         # during page builds as the return values may change, but they
  74         # won't here.)
  75         eval q{use Memoize};
  76         error($@) if $@;
  77         memoize("htmllink");
  78
  79         eval q{use Time::Duration};
  80         error($@) if $@;
  81
  82         my $changelog=[rcs_recentchanges(100)];
  83         foreach my $change (@$changelog) {
  84                 $change->{when} = concise(ago($change->{when}));
  85
  86                 $change->{user} = userlink($change->{user});
  87
  88                 my $is_excess = exists $change->{pages}[10]; # limit pages to first 10
  89                 delete @{$change->{pages}}[10 .. @{$change->{pages}}] if $is_excess;
  90                 $change->{pages} = [
  91                         map {
  92                                 $_->{link} = htmllink("", "", $_->{page},
  93                                         noimageinline => 1,
  94                                         linktext => pagetitle($_->{page}));
  95                                 $_;
  96                         } @{$change->{pages}}
  97                 ];
  98                 push @{$change->{pages}}, { link => '...' } if $is_excess;
  99         }
 100
 101         my $template=template("recentchanges.tmpl");
 102         $template->param(
 103                 title => "RecentChanges",
 104                 indexlink => indexlink(),
 105                 wikiname => $config{wikiname},
 106                 changelog => $changelog,
 107                 baseurl => baseurl(),
 108         );
 109         run_hooks(pagetemplate => sub {
 110                 shift->(page => "", destpage => "", template => $template);
 111         });
 112         print $q->header(-charset => 'utf-8'), $template->output;
 113 } #}}}
 114
 115 # Check if the user is signed in. If not, redirect to the signin form and
 116 # save their place to return to later.
 117 sub needsignin ($$) { #{{{
 118         my $q=shift;
 119         my $session=shift;
 120
 121         if (! defined $session->param("name") ||
 122             ! userinfo_get($session->param("name"), "regdate")) {
 123                 if (! defined $session->param("postsignin")) {
 124                         $session->param(postsignin => $ENV{QUERY_STRING});
 125                 }
 126                 cgi_signin($q, $session);
 127                 cgi_savesession($session);
 128                 exit;
 129         }
 130 } #}}}
 131
 132 sub cgi_signin ($$) { #{{{
 133         my $q=shift;
 134         my $session=shift;
 135
 136         eval q{use CGI::FormBuilder};
 137         error($@) if $@;
 138         my $form = CGI::FormBuilder->new(
 139                 title => "signin",
 140                 header => 1,
 141                 charset => "utf-8",
 142                 method => 'POST',
 143                 required => 'NONE',
 144                 javascript => 0,
 145                 params => $q,
 146                 action => $config{cgiurl},
 147                 header => 0,
 148                 template => scalar template_params("signin.tmpl"),
 149                 stylesheet => baseurl()."style.css",
 150         );
 151         my $buttons=["Login"];
 152
 153         if ($q->param("do") ne "signin" && !$form->submitted) {
 154                 $form->text(gettext("You need to log in first."));
 155         }
 156         $form->field(name => "do", type => "hidden", value => "signin",
 157                 force => 1);
 158
 159         run_hooks(formbuilder_setup => sub {
 160                 shift->(form => $form, cgi => $q, session => $session);
 161         });
 162
 163         decode_form_utf8($form);
 164
 165         if (exists $hooks{formbuilder}) {
 166                 run_hooks(formbuilder => sub {
 167                         shift->(form => $form, cgi => $q, session => $session,
 168                                 buttons => $buttons);
 169                 });
 170         }
 171         else {
 172                 if ($form->submitted) {
 173                         $form->validate;
 174                 }
 175                 printheader($session);
 176                 print misctemplate($form->title, $form->render(submit => $buttons));
 177         }
 178 } #}}}
 179
 180 sub cgi_postsignin ($$) { #{{{
 181         my $q=shift;
 182         my $session=shift;
 183
 184         # Continue with whatever was being done before the signin process.
 185         if (defined $session->param("postsignin")) {
 186                 my $postsignin=CGI->new($session->param("postsignin"));
 187                 $session->clear("postsignin");
 188                 cgi($postsignin, $session);
 189                 cgi_savesession($session);
 190                 exit;
 191         }
 192         else {
 193                 # This can occur, for example, if a user went to the signin
 194                 # url via a bookmark.
 195                 redirect($q, $config{url});
 196         }
 197 } #}}}
 198
 199 sub cgi_prefs ($$) { #{{{
 200         my $q=shift;
 201         my $session=shift;
 202
 203         needsignin($q, $session);
 204
 205         eval q{use CGI::FormBuilder};
 206         error($@) if $@;
 207         my $form = CGI::FormBuilder->new(
 208                 title => "preferences",
 209                 header => 0,
 210                 charset => "utf-8",
 211                 method => 'POST',
 212                 validate => {
 213                         email => 'EMAIL',
 214                 },
 215                 required => 'NONE',
 216                 javascript => 0,
 217                 params => $q,
 218                 action => $config{cgiurl},
 219                 template => scalar template_params("prefs.tmpl"),
 220                 stylesheet => baseurl()."style.css",
 221         );
 222         my $buttons=["Save Preferences", "Logout", "Cancel"];
 223
 224         run_hooks(formbuilder_setup => sub {
 225                 shift->(form => $form, cgi => $q, session => $session);
 226         });
 227
 228         $form->field(name => "do", type => "hidden");
 229         $form->field(name => "email", size => 50);
 230         $form->field(name => "subscriptions", size => 50,
 231                 comment => "(".htmllink("", "", "PageSpec", noimageinline => 1).")");
 232         $form->field(name => "banned_users", size => 50);
 233
 234         my $user_name=$session->param("name");
 235         if (! is_admin($user_name)) {
 236                 $form->field(name => "banned_users", type => "hidden");
 237         }
 238
 239         if (! $form->submitted) {
 240                 $form->field(name => "email", force => 1,
 241                         value => userinfo_get($user_name, "email"));
 242                 $form->field(name => "subscriptions", force => 1,
 243                         value => userinfo_get($user_name, "subscriptions"));
 244                 if (is_admin($user_name)) {
 245                         $form->field(name => "banned_users", force => 1,
 246                                 value => join(" ", get_banned_users()));
 247                 }
 248         }
 249
 250         decode_form_utf8($form);
 251
 252         if ($form->submitted eq 'Logout') {
 253                 $session->delete();
 254                 redirect($q, $config{url});
 255                 return;
 256         }
 257         elsif ($form->submitted eq 'Cancel') {
 258                 redirect($q, $config{url});
 259                 return;
 260         }
 261         elsif ($form->submitted eq 'Save Preferences' && $form->validate) {
 262                 foreach my $field (qw(email subscriptions)) {
 263                         if (defined $form->field($field) && length $form->field($field)) {
 264                                 userinfo_set($user_name, $field, $form->field($field)) ||
 265                                         error("failed to set $field");
 266                         }
 267                 }
 268                 if (is_admin($user_name)) {
 269                         set_banned_users(grep { ! is_admin($_) }
 270                                         split(' ',
 271                                                 $form->field("banned_users"))) ||
 272                                 error("failed saving changes");
 273                 }
 274                 $form->text(gettext("Preferences saved."));
 275         }
 276
 277         if (exists $hooks{formbuilder}) {
 278                 run_hooks(formbuilder => sub {
 279                         shift->(form => $form, cgi => $q, session => $session,
 280                                 buttons => $buttons);
 281                 });
 282         }
 283         else {
 284                 printheader($session);
 285                 print misctemplate($form->title, $form->render(submit => $buttons));
 286         }
 287 } #}}}
 288
 289 sub cgi_editpage ($$) { #{{{
 290         my $q=shift;
 291         my $session=shift;
 292
 293         my @fields=qw(do rcsinfo subpage from page type editcontent comments);
 294         my @buttons=("Save Page", "Preview", "Cancel");
 295
 296         eval q{use CGI::FormBuilder};
 297         error($@) if $@;
 298         my $form = CGI::FormBuilder->new(
 299                 fields => \@fields,
 300                 header => 1,
 301                 charset => "utf-8",
 302                 method => 'POST',
 303                 validate => {
 304                         editcontent => '/.+/',
 305                 },
 306                 required => [qw{editcontent}],
 307                 javascript => 0,
 308                 params => $q,
 309                 action => $config{cgiurl},
 310                 table => 0,
 311                 template => scalar template_params("editpage.tmpl"),
 312         );
 313
 314         run_hooks(formbuilder_setup => sub {
 315                 shift->(form => $form, cgi => $q, session => $session);
 316         });
 317
 318         decode_form_utf8($form);
 319
 320         # This untaint is safe because titlepage removes any problematic
 321         # characters.
 322         my ($page)=$form->field('page');
 323         $page=titlepage(possibly_foolish_untaint($page));
 324         if (! defined $page || ! length $page || file_pruned($page, $config{srcdir}) || $page=~/^\//) {
 325                 error("bad page name");
 326         }
 327
 328         my $from;
 329         if (defined $form->field('from')) {
 330                 ($from)=$form->field('from')=~/$config{wiki_file_regexp}/;
 331         }
 332
 333         my $file;
 334         my $type;
 335         if (exists $pagesources{$page}) {
 336                 $file=$pagesources{$page};
 337                 $type=pagetype($file);
 338                 if (! defined $type) {
 339                         error(sprintf(gettext("%s is not an editable page"), $page));
 340                 }
 341         }
 342         else {
 343                 $type=$form->param('type');
 344                 if (defined $type && length $type && $hooks{htmlize}{$type}) {
 345                         $type=possibly_foolish_untaint($type);
 346                 }
 347                 elsif (defined $from) {
 348                         # favor the type of linking page
 349                         $type=pagetype($pagesources{$from});
 350                 }
 351                 $type=$config{default_pageext} unless defined $type;
 352                 $file=$page.".".$type;
 353         }
 354
 355         my $newfile=0;
 356         if (! -e "$config{srcdir}/$file") {
 357                 $newfile=1;
 358         }
 359
 360         $form->field(name => "do", type => 'hidden');
 361         $form->field(name => "from", type => 'hidden');
 362         $form->field(name => "rcsinfo", type => 'hidden');
 363         $form->field(name => "subpage", type => 'hidden');
 364         $form->field(name => "page", value => $page, force => 1);
 365         $form->field(name => "type", value => $type, force => 1);
 366         $form->field(name => "comments", type => "text", size => 80);
 367         $form->field(name => "editcontent", type => "textarea", rows => 20,
 368                 cols => 80);
 369         $form->tmpl_param("can_commit", $config{rcs});
 370         $form->tmpl_param("indexlink", indexlink());
 371         $form->tmpl_param("helponformattinglink",
 372                 htmllink("", "", "HelpOnFormatting", noimageinline => 1));
 373         $form->tmpl_param("baseurl", baseurl());
 374         if (! $form->submitted) {
 375                 $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 376                         force => 1);
 377         }
 378
 379         if ($form->submitted eq "Cancel") {
 380                 if ($newfile && defined $from) {
 381                         redirect($q, "$config{url}/".htmlpage($from));
 382                 }
 383                 elsif ($newfile) {
 384                         redirect($q, $config{url});
 385                 }
 386                 else {
 387                         redirect($q, "$config{url}/".htmlpage($page));
 388                 }
 389                 return;
 390         }
 391         elsif ($form->submitted eq "Preview") {
 392                 my $content=$form->field('editcontent');
 393                 my $comments=$form->field('comments');
 394                 $form->field(name => "editcontent",
 395                                 value => $content, force => 1);
 396                 $form->field(name => "comments",
 397                                 value => $comments, force => 1);
 398                 $config{rss}=$config{atom}=0; # avoid preview writing a feed!
 399                 $form->tmpl_param("page_preview",
 400                         htmlize($page, $type,
 401                         linkify($page, "",
 402                         preprocess($page, $page,
 403                         filter($page, $content)))));
 404         }
 405         else {
 406                 $form->tmpl_param("page_preview", "");
 407         }
 408         $form->tmpl_param("page_conflict", "");
 409
 410         if (! $form->submitted || $form->submitted eq "Preview" ||
 411             ! $form->validate) {
 412                 if ($form->field("do") eq "create") {
 413                         my @page_locs;
 414                         my $best_loc;
 415                         if (! defined $from || ! length $from ||
 416                             $from ne $form->field('from') ||
 417                             file_pruned($from, $config{srcdir}) ||
 418                             $from=~/^\// ||
 419                             $form->submitted eq "Preview") {
 420                                 @page_locs=$best_loc=$page;
 421                         }
 422                         else {
 423                                 my $dir=$from."/";
 424                                 $dir=~s![^/]+/+$!!;
 425
 426                                 if ((defined $form->field('subpage') && length $form->field('subpage')) ||
 427                                     $page eq gettext('discussion')) {
 428                                         $best_loc="$from/$page";
 429                                 }
 430                                 else {
 431                                         $best_loc=$dir.$page;
 432                                 }
 433
 434                                 push @page_locs, $dir.$page;
 435                                 push @page_locs, "$from/$page";
 436                                 while (length $dir) {
 437                                         $dir=~s![^/]+/+$!!;
 438                                         push @page_locs, $dir.$page;
 439                                 }
 440                         }
 441                         push @page_locs, "$config{userdir}/$page"
 442                                 if length $config{userdir};
 443
 444                         @page_locs = grep {
 445                                 ! exists $pagecase{lc $_}
 446                         } @page_locs;
 447                         if (! @page_locs) {
 448                                 # hmm, someone else made the page in the
 449                                 # meantime?
 450                                 redirect($q, "$config{url}/".htmlpage($page));
 451                                 return;
 452                         }
 453
 454                         my @editable_locs = grep {
 455                                 check_canedit($_, $q, $session, 1)
 456                         } @page_locs;
 457                         if (! @editable_locs) {
 458                                 # let it throw an error this time
 459                                 map { check_canedit($_, $q, $session) } @page_locs;
 460                         }
 461
 462                         my @page_types;
 463                         if (exists $hooks{htmlize}) {
 464                                 @page_types=keys %{$hooks{htmlize}};
 465                         }
 466
 467                         $form->tmpl_param("page_select", 1);
 468                         $form->field(name => "page", type => 'select',
 469                                 options => { map { $_ => pagetitle($_, 1) } @editable_locs },
 470                                 value => $best_loc);
 471                         $form->field(name => "type", type => 'select',
 472                                 options => \@page_types);
 473                         $form->title(sprintf(gettext("creating %s"), pagetitle($page)));
 474                 }
 475                 elsif ($form->field("do") eq "edit") {
 476                         check_canedit($page, $q, $session);
 477                         if (! defined $form->field('editcontent') ||
 478                             ! length $form->field('editcontent')) {
 479                                 my $content="";
 480                                 if (exists $pagesources{$page}) {
 481                                         $content=readfile(srcfile($pagesources{$page}));
 482                                         $content=~s/\n/\r\n/g;
 483                                 }
 484                                 $form->field(name => "editcontent", value => $content,
 485                                         force => 1);
 486                         }
 487                         $form->tmpl_param("page_select", 0);
 488                         $form->field(name => "page", type => 'hidden');
 489                         $form->field(name => "type", type => 'hidden');
 490                         $form->title(sprintf(gettext("editing %s"), pagetitle($page)));
 491                 }
 492
 493                 print $form->render(submit => \@buttons);
 494         }
 495         else {
 496                 # save page
 497                 check_canedit($page, $q, $session);
 498
 499                 my $content=$form->field('editcontent');
 500
 501                 $content=~s/\r\n/\n/g;
 502                 $content=~s/\r/\n/g;
 503
 504                 $config{cgi}=0; # avoid cgi error message
 505                 eval { writefile($file, $config{srcdir}, $content) };
 506                 $config{cgi}=1;
 507                 if ($@) {
 508                         $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 509                                 force => 1);
 510                         $form->tmpl_param("failed_save", 1);
 511                         $form->tmpl_param("error_message", $@);
 512                         $form->field("editcontent", value => $content, force => 1);
 513                         $form->field(name => "comments", value => $form->field('comments'), force => 1);
 514                         $form->field("do", "edit)");
 515                         $form->tmpl_param("page_select", 0);
 516                         $form->field(name => "page", type => 'hidden');
 517                         $form->field(name => "type", type => 'hidden');
 518                         $form->title(sprintf(gettext("editing %s"), $page));
 519                         print $form->render(submit => \@buttons);
 520                         return;
 521                 }
 522
 523                 my $conflict;
 524                 if ($config{rcs}) {
 525                         my $message="";
 526                         if (defined $form->field('comments') &&
 527                             length $form->field('comments')) {
 528                                 $message=$form->field('comments');
 529                         }
 530
 531                         if ($newfile) {
 532                                 rcs_add($file);
 533                         }
 534
 535                         # Prevent deadlock with post-commit hook by
 536                         # signaling to it that it should not try to
 537                         # do anything (except send commit mails).
 538                         disable_commit_hook();
 539                         $conflict=rcs_commit($file, $message,
 540                                 $form->field("rcsinfo"),
 541                                 $session->param("name"), $ENV{REMOTE_ADDR});
 542                         enable_commit_hook();
 543                         rcs_update();
 544                 }
 545
 546                 # Refresh even if there was a conflict, since other changes
 547                 # may have been committed while the post-commit hook was
 548                 # disabled.
 549                 require IkiWiki::Render;
 550                 refresh();
 551                 saveindex();
 552
 553                 if (defined $conflict) {
 554                         $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 555                                 force => 1);
 556                         $form->tmpl_param("page_conflict", 1);
 557                         $form->field("editcontent", value => $conflict, force => 1);
 558                         $form->field(name => "comments", value => $form->field('comments'), force => 1);
 559                         $form->field("do", "edit)");
 560                         $form->tmpl_param("page_select", 0);
 561                         $form->field(name => "page", type => 'hidden');
 562                         $form->field(name => "type", type => 'hidden');
 563                         $form->title(sprintf(gettext("editing %s"), $page));
 564                         print $form->render(submit => \@buttons);
 565                         return;
 566                 }
 567                 else {
 568                         # The trailing question mark tries to avoid broken
 569                         # caches and get the most recent version of the page.
 570                         redirect($q, "$config{url}/".htmlpage($page)."?updated");
 571                 }
 572         }
 573 } #}}}
 574
 575 sub cgi_getsession ($) { #{{{
 576         my $q=shift;
 577
 578         eval q{use CGI::Session};
 579         CGI::Session->name("ikiwiki_session_".encode_utf8($config{wikiname}));
 580
 581         my $oldmask=umask(077);
 582         my $session = CGI::Session->new("driver:DB_File", $q,
 583                 { FileName => "$config{wikistatedir}/sessions.db" });
 584         umask($oldmask);
 585
 586         return $session;
 587 } #}}}
 588
 589 sub cgi_savesession ($) { #{{{
 590         my $session=shift;
 591
 592         # Force session flush with safe umask.
 593         my $oldmask=umask(077);
 594         $session->flush;
 595         umask($oldmask);
 596 } #}}}
 597
 598 sub cgi (;$$) { #{{{
 599         my $q=shift;
 600         my $session=shift;
 601
 602         if (! $q) {
 603                 eval q{use CGI};
 604                 error($@) if $@;
 605
 606                 $q=CGI->new;
 607
 608                 run_hooks(cgi => sub { shift->($q) });
 609         }
 610
 611         my $do=$q->param('do');
 612         if (! defined $do || ! length $do) {
 613                 my $error = $q->cgi_error;
 614                 if ($error) {
 615                         error("Request not processed: $error");
 616                 }
 617                 else {
 618                         error("\"do\" parameter missing");
 619                 }
 620         }
 621
 622         # Things that do not need a session.
 623         if ($do eq 'recentchanges') {
 624                 cgi_recentchanges($q);
 625                 return;
 626         }
 627         elsif ($do eq 'hyperestraier') {
 628                 cgi_hyperestraier();
 629         }
 630
 631         # Need to lock the wiki before getting a session.
 632         lockwiki();
 633
 634         if (! $session) {
 635                 $session=cgi_getsession($q);
 636         }
 637
 638         # Auth hooks can sign a user in.
 639         if ($do ne 'signin' && ! defined $session->param("name")) {
 640                 run_hooks(auth => sub {
 641                         shift->($q, $session)
 642                 });
 643                 if (defined $session->param("name")) {
 644                         # Make sure whatever user was authed is in the
 645                         # userinfo db.
 646                         if (! userinfo_get($session->param("name"), "regdate")) {
 647                                 userinfo_setall($session->param("name"), {
 648                                         email => "",
 649                                         password => "",
 650                                         regdate => time,
 651                                 }) || error("failed adding user");
 652                         }
 653                 }
 654         }
 655
 656         if (defined $session->param("name") &&
 657             userinfo_get($session->param("name"), "banned")) {
 658                 print $q->header(-status => "403 Forbidden");
 659                 $session->delete();
 660                 print gettext("You are banned.");
 661                 cgi_savesession($session);
 662         }
 663         elsif ($do eq 'signin') {
 664                 cgi_signin($q, $session);
 665                 cgi_savesession($session);
 666         }
 667         elsif (defined $session->param("postsignin")) {
 668                 cgi_postsignin($q, $session);
 669         }
 670         elsif ($do eq 'prefs') {
 671                 cgi_prefs($q, $session);
 672         }
 673         elsif ($do eq 'create' || $do eq 'edit') {
 674                 cgi_editpage($q, $session);
 675         }
 676         elsif ($do eq 'blog') {
 677                 my $page=titlepage(decode_utf8($q->param('title')));
 678                 $page=~s/(\/)/"__".ord($1)."__"/eg; # escape slashes too
 679                 # if the page already exists, munge it to be unique
 680                 my $from=$q->param('from');
 681                 my $add="";
 682                 while (exists $pagecase{lc "$from/$page$add"}) {
 683                         $add=1 unless length $add;
 684                         $add++;
 685                 }
 686                 $q->param('page', $page.$add);
 687                 # now run same as create
 688                 $q->param('do', 'create');
 689                 cgi_editpage($q, $session);
 690         }
 691         elsif ($do eq 'postsignin') {
 692                 error(gettext("login failed, perhaps you need to turn on cookies?"));
 693         }
 694         else {
 695                 error("unknown do parameter");
 696         }
 697 } #}}}
 698
 699 sub userlink ($) { #{{{
 700         my $user=shift;
 701
 702         eval q{use CGI 'escapeHTML'};
 703         error($@) if $@;
 704         if ($user =~ m!^https?://! &&
 705             eval q{use Net::OpenID::VerifiedIdentity; 1} && !$@) {
 706                 # Munge user-urls, as used by eg, OpenID.
 707                 my $oid=Net::OpenID::VerifiedIdentity->new(identity => $user);
 708                 my $display=$oid->display;
 709                 # Convert "user.somehost.com" to "user [somehost.com]".
 710                 if ($display !~ /\[/) {
 711                         $display=~s/^(.*?)\.([^.]+\.[a-z]+)$/$1 [$2]/;
 712                 }
 713                 # Convert "http://somehost.com/user" to "user [somehost.com]".
 714                 if ($display !~ /\[/) {
 715                         $display=~s/^https?:\/\/(.+)\/([^\/]+)$/$2 [$1]/;
 716                 }
 717                 $display=~s!^https?://!!; # make sure this is removed
 718                 return "<a href=\"$user\">".escapeHTML($display)."</a>";
 719         }
 720         else {
 721                 return htmllink("", "", escapeHTML(
 722                         length $config{userdir} ? $config{userdir}."/".$user : $user
 723                 ), noimageinline => 1);
 724         }
 725 } #}}}
 726
 727 1