git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/aggregate.pm

   1 #!/usr/bin/perl
   2 # Feed aggregation plugin.
   3 package IkiWiki::Plugin::aggregate;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki 2.00;
   8 use HTML::Parser;
   9 use HTML::Tagset;
  10 use HTML::Entities;
  11 use URI;
  12 use open qw{:utf8 :std};
  13
  14 my %feeds;
  15 my %guids;
  16
  17 sub import { #{{{
  18         hook(type => "getopt", id => "aggregate", call => \&getopt);
  19         hook(type => "checkconfig", id => "aggregate", call => \&checkconfig);
  20         hook(type => "needsbuild", id => "aggregate", call => \&needsbuild);
  21         hook(type => "preprocess", id => "aggregate", call => \&preprocess);
  22         hook(type => "delete", id => "aggregate", call => \&delete);
  23         hook(type => "savestate", id => "aggregate", call => \&savestate);
  24         hook(type => "htmlize", id => "_aggregated", call => \&htmlize);
  25         if (exists $config{aggregate_webtrigger} && $config{aggregate_webtrigger}) {
  26                 hook(type => "cgi", id => "aggregate", call => \&cgi);
  27         }
  28 } # }}}
  29
  30 sub getopt () { #{{{
  31         eval q{use Getopt::Long};
  32         error($@) if $@;
  33         Getopt::Long::Configure('pass_through');
  34         GetOptions(
  35                 "aggregate" => \$config{aggregate},
  36                 "aggregateinternal!" => \$config{aggregateinternal},
  37         );
  38 } #}}}
  39
  40 sub checkconfig () { #{{{
  41         if ($config{aggregate} && ! ($config{post_commit} &&
  42                                      IkiWiki::commit_hook_enabled())) {
  43                 launchaggregation();
  44         }
  45 } #}}}
  46
  47 sub cgi ($) { #{{{
  48         my $cgi=shift;
  49
  50         if (defined $cgi->param('do') &&
  51             $cgi->param("do") eq "aggregate_webtrigger") {
  52                 $|=1;
  53                 print "Content-Type: text/plain\n\n";
  54                 $config{cgi}=0;
  55                 $config{verbose}=1;
  56                 $config{syslog}=0;
  57                 print gettext("Aggregation triggered via web.")."\n\n";
  58                 if (launchaggregation()) {
  59                         IkiWiki::lockwiki();
  60                         IkiWiki::loadindex();
  61                         require IkiWiki::Render;
  62                         IkiWiki::refresh();
  63                         IkiWiki::saveindex();
  64                 }
  65                 else {
  66                         print gettext("Nothing to do right now, all feeds are up-to-date!")."\n";
  67                 }
  68                 exit 0;
  69         }
  70 } #}}}
  71
  72 sub launchaggregation () { #{{{
  73         # See if any feeds need aggregation.
  74         loadstate();
  75         my @feeds=needsaggregate();
  76         return unless @feeds;
  77         if (! lockaggregate()) {
  78                 debug("an aggregation process is already running");
  79                 return;
  80         }
  81         # force a later rebuild of source pages
  82         $IkiWiki::forcerebuild{$_->{sourcepage}}=1
  83                 foreach @feeds;
  84
  85         # Fork a child process to handle the aggregation.
  86         # The parent process will then handle building the
  87         # result. This avoids messy code to clear state
  88         # accumulated while aggregating.
  89         defined(my $pid = fork) or error("Can't fork: $!");
  90         if (! $pid) {
  91                 IkiWiki::loadindex();
  92                 # Aggregation happens without the main wiki lock
  93                 # being held. This allows editing pages etc while
  94                 # aggregation is running.
  95                 aggregate(@feeds);
  96
  97                 IkiWiki::lockwiki;
  98                 # Merge changes, since aggregation state may have
  99                 # changed on disk while the aggregation was happening.
 100                 mergestate();
 101                 expire();
 102                 savestate();
 103                 IkiWiki::unlockwiki;
 104                 exit 0;
 105         }
 106         waitpid($pid,0);
 107         if ($?) {
 108                 error "aggregation failed with code $?";
 109         }
 110
 111         clearstate();
 112         unlockaggregate();
 113
 114         return 1;
 115 } #}}}
 116
 117 #  Pages with extension _aggregated have plain html markup, pass through.
 118 sub htmlize (@) { #{{{
 119         my %params=@_;
 120         return $params{content};
 121 } #}}}
 122
 123 # Used by ikiwiki-transition aggregateinternal.
 124 sub migrate_to_internal { #{{{
 125         if (! lockaggregate()) {
 126                 error("an aggregation process is currently running");
 127         }
 128
 129         IkiWiki::lockwiki();
 130         loadstate();
 131         $config{verbose}=1;
 132
 133         foreach my $data (values %guids) {
 134                 next unless $data->{page};
 135                 next if $data->{expired};
 136
 137                 $config{aggregateinternal} = 0;
 138                 my $oldname = pagefile($data->{page});
 139                 my $oldoutput = $config{destdir}."/".IkiWiki::htmlpage($data->{page});
 140
 141                 $config{aggregateinternal} = 1;
 142                 my $newname = pagefile($data->{page});
 143
 144                 debug "moving $oldname -> $newname";
 145                 if (-e $newname) {
 146                         if (-e $oldname) {
 147                                 error("$newname already exists");
 148                         }
 149                         else {
 150                                 debug("already renamed to $newname?");
 151                         }
 152                 }
 153                 elsif (-e $oldname) {
 154                         rename($oldname, $newname) || error("$!");
 155                 }
 156                 else {
 157                         debug("$oldname not found");
 158                 }
 159                 if (-e $oldoutput) {
 160                         debug("removing output file $oldoutput");
 161                         unlink($oldoutput) || error ("$!");
 162                 }
 163         }
 164
 165         savestate();
 166         IkiWiki::unlockwiki;
 167
 168         unlockaggregate();
 169 } #}}}
 170
 171 sub needsbuild (@) { #{{{
 172         my $needsbuild=shift;
 173
 174         loadstate();
 175
 176         foreach my $feed (values %feeds) {
 177                 if (exists $pagesources{$feed->{sourcepage}} &&
 178                     grep { $_ eq $pagesources{$feed->{sourcepage}} } @$needsbuild) {
 179                         # Mark all feeds originating on this page as
 180                         # not yet seen; preprocess will unmark those that
 181                         # still exist.
 182                         markunseen($feed->{sourcepage});
 183                 }
 184         }
 185 } # }}}
 186
 187 sub preprocess (@) { #{{{
 188         my %params=@_;
 189
 190         foreach my $required (qw{name url}) {
 191                 if (! exists $params{$required}) {
 192                         error sprintf(gettext("missing %s parameter"), $required)
 193                 }
 194         }
 195
 196         my $feed={};
 197         my $name=$params{name};
 198         if (exists $feeds{$name}) {
 199                 $feed=$feeds{$name};
 200         }
 201         else {
 202                 $feeds{$name}=$feed;
 203         }
 204         $feed->{name}=$name;
 205         $feed->{sourcepage}=$params{page};
 206         $feed->{url}=$params{url};
 207         my $dir=exists $params{dir} ? $params{dir} : $params{page}."/".IkiWiki::titlepage($params{name});
 208         $dir=~s/^\/+//;
 209         ($dir)=$dir=~/$config{wiki_file_regexp}/;
 210         $feed->{dir}=$dir;
 211         $feed->{feedurl}=defined $params{feedurl} ? $params{feedurl} : "";
 212         $feed->{updateinterval}=defined $params{updateinterval} ? $params{updateinterval} * 60 : 15 * 60;
 213         $feed->{expireage}=defined $params{expireage} ? $params{expireage} : 0;
 214         $feed->{expirecount}=defined $params{expirecount} ? $params{expirecount} : 0;
 215         if (exists $params{template}) {
 216                 $params{template}=~s/[^-_a-zA-Z0-9]+//g;
 217         }
 218         else {
 219                 $params{template} = "aggregatepost"
 220         }
 221         $feed->{template}=$params{template} . ".tmpl";
 222         delete $feed->{unseen};
 223         $feed->{lastupdate}=0 unless defined $feed->{lastupdate};
 224         $feed->{numposts}=0 unless defined $feed->{numposts};
 225         $feed->{newposts}=0 unless defined $feed->{newposts};
 226         $feed->{message}=gettext("new feed") unless defined $feed->{message};
 227         $feed->{error}=0 unless defined $feed->{error};
 228         $feed->{tags}=[];
 229         while (@_) {
 230                 my $key=shift;
 231                 my $value=shift;
 232                 if ($key eq 'tag') {
 233                         push @{$feed->{tags}}, $value;
 234                 }
 235         }
 236
 237         return "<a href=\"".$feed->{url}."\">".$feed->{name}."</a>: ".
 238                ($feed->{error} ? "<em>" : "").$feed->{message}.
 239                ($feed->{error} ? "</em>" : "").
 240                " (".$feed->{numposts}." ".gettext("posts").
 241                ($feed->{newposts} ? "; ".$feed->{newposts}.
 242                                     " ".gettext("new") : "").
 243                ")";
 244 } # }}}
 245
 246 sub delete (@) { #{{{
 247         my @files=@_;
 248
 249         # Remove feed data for removed pages.
 250         foreach my $file (@files) {
 251                 my $page=pagename($file);
 252                 markunseen($page);
 253         }
 254 } #}}}
 255
 256 sub markunseen ($) { #{{{
 257         my $page=shift;
 258
 259         foreach my $id (keys %feeds) {
 260                 if ($feeds{$id}->{sourcepage} eq $page) {
 261                         $feeds{$id}->{unseen}=1;
 262                 }
 263         }
 264 } #}}}
 265
 266 my $state_loaded=0;
 267
 268 sub loadstate () { #{{{
 269         return if $state_loaded;
 270         $state_loaded=1;
 271         if (-e "$config{wikistatedir}/aggregate") {
 272                 open(IN, "$config{wikistatedir}/aggregate") ||
 273                         die "$config{wikistatedir}/aggregate: $!";
 274                 while (<IN>) {
 275                         $_=IkiWiki::possibly_foolish_untaint($_);
 276                         chomp;
 277                         my $data={};
 278                         foreach my $i (split(/ /, $_)) {
 279                                 my ($field, $val)=split(/=/, $i, 2);
 280                                 if ($field eq "name" || $field eq "feed" ||
 281                                     $field eq "guid" || $field eq "message") {
 282                                         $data->{$field}=decode_entities($val, " \t\n");
 283                                 }
 284                                 elsif ($field eq "tag") {
 285                                         push @{$data->{tags}}, $val;
 286                                 }
 287                                 else {
 288                                         $data->{$field}=$val;
 289                                 }
 290                         }
 291
 292                         if (exists $data->{name}) {
 293                                 $feeds{$data->{name}}=$data;
 294                         }
 295                         elsif (exists $data->{guid}) {
 296                                 $guids{$data->{guid}}=$data;
 297                         }
 298                 }
 299
 300                 close IN;
 301         }
 302 } #}}}
 303
 304 sub savestate () { #{{{
 305         return unless $state_loaded;
 306         garbage_collect();
 307         my $newfile="$config{wikistatedir}/aggregate.new";
 308         my $cleanup = sub { unlink($newfile) };
 309         open (OUT, ">$newfile") || error("open $newfile: $!", $cleanup);
 310         foreach my $data (values %feeds, values %guids) {
 311                 my @line;
 312                 foreach my $field (keys %$data) {
 313                         if ($field eq "name" || $field eq "feed" ||
 314                             $field eq "guid" || $field eq "message") {
 315                                 push @line, "$field=".encode_entities($data->{$field}, " \t\n");
 316                         }
 317                         elsif ($field eq "tags") {
 318                                 push @line, "tag=$_" foreach @{$data->{tags}};
 319                         }
 320                         else {
 321                                 push @line, "$field=".$data->{$field};
 322                         }
 323                 }
 324                 print OUT join(" ", @line)."\n" || error("write $newfile: $!", $cleanup);
 325         }
 326         close OUT || error("save $newfile: $!", $cleanup);
 327         rename($newfile, "$config{wikistatedir}/aggregate") ||
 328                 error("rename $newfile: $!", $cleanup);
 329 } #}}}
 330
 331 sub garbage_collect () { #{{{
 332         foreach my $name (keys %feeds) {
 333                 # remove any feeds that were not seen while building the pages
 334                 # that used to contain them
 335                 if ($feeds{$name}->{unseen}) {
 336                         delete $feeds{$name};
 337                 }
 338         }
 339
 340         foreach my $guid (values %guids) {
 341                 # any guid whose feed is gone should be removed
 342                 if (! exists $feeds{$guid->{feed}}) {
 343                         unlink pagefile($guid->{page})
 344                                 if exists $guid->{page};
 345                         delete $guids{$guid->{guid}};
 346                 }
 347                 # handle expired guids
 348                 elsif ($guid->{expired} && exists $guid->{page}) {
 349                         unlink pagefile($guid->{page});
 350                         delete $guid->{page};
 351                         delete $guid->{md5};
 352                 }
 353         }
 354 } #}}}
 355
 356 sub mergestate () { #{{{
 357         # Load the current state in from disk, and merge into it
 358         # values from the state in memory that might have changed
 359         # during aggregation.
 360         my %myfeeds=%feeds;
 361         my %myguids=%guids;
 362         clearstate();
 363         loadstate();
 364
 365         # All that can change in feed state during aggregation is a few
 366         # fields.
 367         foreach my $name (keys %myfeeds) {
 368                 if (exists $feeds{$name}) {
 369                         foreach my $field (qw{message lastupdate numposts
 370                                               newposts error}) {
 371                                 $feeds{$name}->{$field}=$myfeeds{$name}->{$field};
 372                         }
 373                 }
 374         }
 375
 376         # New guids can be created during aggregation.
 377         # It's also possible that guids were removed from the on-disk state
 378         # while the aggregation was in process. That would only happen if
 379         # their feed was also removed, so any removed guids added back here
 380         # will be garbage collected later.
 381         foreach my $guid (keys %myguids) {
 382                 if (! exists $guids{$guid}) {
 383                         $guids{$guid}=$myguids{$guid};
 384                 }
 385         }
 386 } #}}}
 387
 388 sub clearstate () { #{{{
 389         %feeds=();
 390         %guids=();
 391         $state_loaded=0;
 392 } #}}}
 393
 394 sub expire () { #{{{
 395         foreach my $feed (values %feeds) {
 396                 next unless $feed->{expireage} || $feed->{expirecount};
 397                 my $count=0;
 398                 my %seen;
 399                 foreach my $item (sort { $IkiWiki::pagectime{$b->{page}} <=> $IkiWiki::pagectime{$a->{page}} }
 400                                   grep { exists $_->{page} && $_->{feed} eq $feed->{name} && $IkiWiki::pagectime{$_->{page}} }
 401                                   values %guids) {
 402                         if ($feed->{expireage}) {
 403                                 my $days_old = (time - $IkiWiki::pagectime{$item->{page}}) / 60 / 60 / 24;
 404                                 if ($days_old > $feed->{expireage}) {
 405                                         debug(sprintf(gettext("expiring %s (%s days old)"),
 406                                                 $item->{page}, int($days_old)));
 407                                         $item->{expired}=1;
 408                                 }
 409                         }
 410                         elsif ($feed->{expirecount} &&
 411                                $count >= $feed->{expirecount}) {
 412                                 debug(sprintf(gettext("expiring %s"), $item->{page}));
 413                                 $item->{expired}=1;
 414                         }
 415                         else {
 416                                 if (! $seen{$item->{page}}) {
 417                                         $seen{$item->{page}}=1;
 418                                         $count++;
 419                                 }
 420                         }
 421                 }
 422         }
 423 } #}}}
 424
 425 sub needsaggregate () { #{{{
 426         return values %feeds if $config{rebuild};
 427         return grep { time - $_->{lastupdate} >= $_->{updateinterval} } values %feeds;
 428 } #}}}
 429
 430 sub aggregate (@) { #{{{
 431         eval q{use XML::Feed};
 432         error($@) if $@;
 433         eval q{use URI::Fetch};
 434         error($@) if $@;
 435
 436         foreach my $feed (@_) {
 437                 $feed->{lastupdate}=time;
 438                 $feed->{newposts}=0;
 439                 $feed->{message}=sprintf(gettext("processed ok at %s"),
 440                         displaytime($feed->{lastupdate}));
 441                 $feed->{error}=0;
 442
 443                 debug(sprintf(gettext("checking feed %s ..."), $feed->{name}));
 444
 445                 if (! length $feed->{feedurl}) {
 446                         my @urls=XML::Feed->find_feeds($feed->{url});
 447                         if (! @urls) {
 448                                 $feed->{message}=sprintf(gettext("could not find feed at %s"), $feed->{url});
 449                                 $feed->{error}=1;
 450                                 debug($feed->{message});
 451                                 next;
 452                         }
 453                         $feed->{feedurl}=pop @urls;
 454                 }
 455                 my $res=URI::Fetch->fetch($feed->{feedurl});
 456                 if (! $res) {
 457                         $feed->{message}=URI::Fetch->errstr;
 458                         $feed->{error}=1;
 459                         debug($feed->{message});
 460                         next;
 461                 }
 462                 if ($res->status == URI::Fetch::URI_GONE()) {
 463                         $feed->{message}=gettext("feed not found");
 464                         $feed->{error}=1;
 465                         debug($feed->{message});
 466                         next;
 467                 }
 468                 my $content=$res->content;
 469                 my $f=eval{XML::Feed->parse(\$content)};
 470                 if ($@) {
 471                         # One common cause of XML::Feed crashing is a feed
 472                         # that contains invalid UTF-8 sequences. Convert
 473                         # feed to ascii to try to work around.
 474                         $feed->{message}.=" ".sprintf(gettext("(invalid UTF-8 stripped from feed)"));
 475                         $content=Encode::decode_utf8($content, 0);
 476                         $f=eval{XML::Feed->parse(\$content)};
 477                 }
 478                 if ($@) {
 479                         # Another possibility is badly escaped entities.
 480                         $feed->{message}.=" ".sprintf(gettext("(feed entities escaped)"));
 481                         $content=~s/\&(?!amp)(\w+);/&amp;$1;/g;
 482                         $content=Encode::decode_utf8($content, 0);
 483                         $f=eval{XML::Feed->parse(\$content)};
 484                 }
 485                 if ($@) {
 486                         $feed->{message}=gettext("feed crashed XML::Feed!")." ($@)";
 487                         $feed->{error}=1;
 488                         debug($feed->{message});
 489                         next;
 490                 }
 491                 if (! $f) {
 492                         $feed->{message}=XML::Feed->errstr;
 493                         $feed->{error}=1;
 494                         debug($feed->{message});
 495                         next;
 496                 }
 497
 498                 foreach my $entry ($f->entries) {
 499                         add_page(
 500                                 feed => $feed,
 501                                 copyright => $f->copyright,
 502                                 title => defined $entry->title ? decode_entities($entry->title) : "untitled",
 503                                 link => $entry->link,
 504                                 content => defined $entry->content->body ? $entry->content->body : "",
 505                                 guid => defined $entry->id ? $entry->id : time."_".$feed->{name},
 506                                 ctime => $entry->issued ? ($entry->issued->epoch || time) : time,
 507                         );
 508                 }
 509         }
 510 } #}}}
 511
 512 sub add_page (@) { #{{{
 513         my %params=@_;
 514
 515         my $feed=$params{feed};
 516         my $guid={};
 517         my $mtime;
 518         if (exists $guids{$params{guid}}) {
 519                 # updating an existing post
 520                 $guid=$guids{$params{guid}};
 521                 return if $guid->{expired};
 522         }
 523         else {
 524                 # new post
 525                 $guid->{guid}=$params{guid};
 526                 $guids{$params{guid}}=$guid;
 527                 $mtime=$params{ctime};
 528                 $feed->{numposts}++;
 529                 $feed->{newposts}++;
 530
 531                 # assign it an unused page
 532                 my $page=IkiWiki::titlepage($params{title});
 533                 # escape slashes and periods in title so it doesn't specify
 534                 # directory name or trigger ".." disallowing code.
 535                 $page=~s!([/.])!"__".ord($1)."__"!eg;
 536                 $page=$feed->{dir}."/".$page;
 537                 ($page)=$page=~/$config{wiki_file_regexp}/;
 538                 if (! defined $page || ! length $page) {
 539                         $page=$feed->{dir}."/item";
 540                 }
 541                 my $c="";
 542                 while (exists $IkiWiki::pagecase{lc $page.$c} ||
 543                        -e pagefile($page.$c)) {
 544                         $c++
 545                 }
 546
 547                 # Make sure that the file name isn't too long.
 548                 # NB: This doesn't check for path length limits.
 549                 my $max=POSIX::pathconf($config{srcdir}, &POSIX::_PC_NAME_MAX);
 550                 if (defined $max && length(htmlfn($page)) >= $max) {
 551                         $c="";
 552                         $page=$feed->{dir}."/item";
 553                         while (exists $IkiWiki::pagecase{lc $page.$c} ||
 554                                -e pagefile($page.$c)) {
 555                                 $c++
 556                         }
 557                 }
 558
 559                 $guid->{page}=$page;
 560                 debug(sprintf(gettext("creating new page %s"), $page));
 561         }
 562         $guid->{feed}=$feed->{name};
 563
 564         # To write or not to write? Need to avoid writing unchanged pages
 565         # to avoid unneccessary rebuilding. The mtime from rss cannot be
 566         # trusted; let's use a digest.
 567         eval q{use Digest::MD5 'md5_hex'};
 568         error($@) if $@;
 569         require Encode;
 570         my $digest=md5_hex(Encode::encode_utf8($params{content}));
 571         return unless ! exists $guid->{md5} || $guid->{md5} ne $digest || $config{rebuild};
 572         $guid->{md5}=$digest;
 573
 574         # Create the page.
 575         my $template=template($feed->{template}, blind_cache => 1);
 576         $template->param(title => $params{title})
 577                 if defined $params{title} && length($params{title});
 578         $template->param(content => htmlescape(htmlabs($params{content}, $feed->{feedurl})));
 579         $template->param(name => $feed->{name});
 580         $template->param(url => $feed->{url});
 581         $template->param(copyright => $params{copyright})
 582                 if defined $params{copyright} && length $params{copyright};
 583         $template->param(permalink => urlabs($params{link}, $feed->{feedurl}))
 584                 if defined $params{link};
 585         if (ref $feed->{tags}) {
 586                 $template->param(tags => [map { tag => $_ }, @{$feed->{tags}}]);
 587         }
 588         writefile(htmlfn($guid->{page}), $config{srcdir},
 589                 $template->output);
 590
 591         # Set the mtime, this lets the build process get the right creation
 592         # time on record for the new page.
 593         utime $mtime, $mtime, pagefile($guid->{page})
 594                 if defined $mtime && $mtime <= time;
 595 } #}}}
 596
 597 sub htmlescape ($) { #{{{
 598         # escape accidental wikilinks and preprocessor stuff
 599         my $html=shift;
 600         $html=~s/(?<!\\)\[\[/\\\[\[/g;
 601         return $html;
 602 } #}}}
 603
 604 sub urlabs ($$) { #{{{
 605         my $url=shift;
 606         my $urlbase=shift;
 607
 608         URI->new_abs($url, $urlbase)->as_string;
 609 } #}}}
 610
 611 sub htmlabs ($$) { #{{{
 612         # Convert links in html from relative to absolute.
 613         # Note that this is a heuristic, which is not specified by the rss
 614         # spec and may not be right for all feeds. Also, see Debian
 615         # bug #381359.
 616         my $html=shift;
 617         my $urlbase=shift;
 618
 619         my $ret="";
 620         my $p = HTML::Parser->new(api_version => 3);
 621         $p->handler(default => sub { $ret.=join("", @_) }, "text");
 622         $p->handler(start => sub {
 623                 my ($tagname, $pos, $text) = @_;
 624                 if (ref $HTML::Tagset::linkElements{$tagname}) {
 625                         while (4 <= @$pos) {
 626                                 # use attribute sets from right to left
 627                                 # to avoid invalidating the offsets
 628                                 # when replacing the values
 629                                 my($k_offset, $k_len, $v_offset, $v_len) =
 630                                         splice(@$pos, -4);
 631                                 my $attrname = lc(substr($text, $k_offset, $k_len));
 632                                 next unless grep { $_ eq $attrname } @{$HTML::Tagset::linkElements{$tagname}};
 633                                 next unless $v_offset; # 0 v_offset means no value
 634                                 my $v = substr($text, $v_offset, $v_len);
 635                                 $v =~ s/^([\'\"])(.*)\1$/$2/;
 636                                 my $new_v=urlabs($v, $urlbase);
 637                                 $new_v =~ s/\"/&quot;/g; # since we quote with ""
 638                                 substr($text, $v_offset, $v_len) = qq("$new_v");
 639                         }
 640                 }
 641                 $ret.=$text;
 642         }, "tagname, tokenpos, text");
 643         $p->parse($html);
 644         $p->eof;
 645
 646         return $ret;
 647 } #}}}
 648
 649 sub pagefile ($) { #{{{
 650         my $page=shift;
 651
 652         return "$config{srcdir}/".htmlfn($page);
 653 } #}}}
 654
 655 sub htmlfn ($) { #{{{
 656         return shift().".".($config{aggregateinternal} ? "_aggregated" : $config{htmlext});
 657 } #}}}
 658
 659 my $aggregatelock;
 660
 661 sub lockaggregate () { #{{{
 662         # Take an exclusive lock to prevent multiple concurrent aggregators.
 663         # Returns true if the lock was aquired.
 664         if (! -d $config{wikistatedir}) {
 665                 mkdir($config{wikistatedir});
 666         }
 667         open($aggregatelock, '>', "$config{wikistatedir}/aggregatelock") ||
 668                 error ("cannot open to $config{wikistatedir}/aggregatelock: $!");
 669         if (! flock($aggregatelock, 2 | 4)) { # LOCK_EX | LOCK_NB
 670                 close($aggregatelock) || error("failed closing aggregatelock: $!");
 671                 return 0;
 672         }
 673         return 1;
 674 } #}}}
 675
 676 sub unlockaggregate () { #{{{
 677         return close($aggregatelock) if $aggregatelock;
 678         return;
 679 } #}}}
 680
 681 1