git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/blogspam.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::blogspam;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7 use Encode;
   8
   9 my $defaulturl='http://test.blogspam.net:8888/';
  10
  11 sub import {
  12         hook(type => "getsetup", id => "blogspam",  call => \&getsetup);
  13         hook(type => "checkconfig", id => "blogspam", call => \&checkconfig);
  14         hook(type => "checkcontent", id => "blogspam", call => \&checkcontent);
  15 }
  16
  17 sub getsetup () {
  18         return
  19                 plugin => {
  20                         safe => 1,
  21                         rebuild => 0,
  22                         section => "auth",
  23                 },
  24                 blogspam_pagespec => {
  25                         type => 'pagespec',
  26                         example => 'postcomment(*)',
  27                         description => 'PageSpec of pages to check for spam',
  28                         link => 'ikiwiki/PageSpec',
  29                         safe => 1,
  30                         rebuild => 0,
  31                 },
  32                 blogspam_options => {
  33                         type => "string",
  34                         example => "blacklist=1.2.3.4,blacklist=8.7.6.5,max-links=10",
  35                         description => "options to send to blogspam server",
  36                         link => "http://blogspam.net/api/testComment.html#options",
  37                         safe => 1,
  38                         rebuild => 0,
  39                 },
  40                 blogspam_server => {
  41                         type => "string",
  42                         default => $defaulturl,
  43                         description => "blogspam server XML-RPC url",
  44                         safe => 1,
  45                         rebuild => 0,
  46                 },
  47 }
  48
  49 sub checkconfig () {
  50         # This is done at checkconfig time because printing an error
  51         # if the module is missing when a spam is posted would not
  52         # let the admin know about the problem.
  53         eval q{
  54                 use RPC::XML;
  55                 use RPC::XML::Client;
  56         };
  57         error $@ if $@;
  58 }
  59
  60 sub checkcontent (@) {
  61         my %params=@_;
  62         my $session=$params{session};
  63
  64         my $spec='!admin()';
  65         if (exists $config{blogspam_pagespec} &&
  66             length $config{blogspam_pagespec}) {
  67                 $spec.=" and (".$config{blogspam_pagespec}.")";
  68         }
  69
  70         my $user=$session->param("name");
  71         return undef unless pagespec_match($params{page}, $spec,
  72                 (defined $user ? (user => $user) : ()),
  73                 (defined $session->remote_addr() ? (ip => $session->remote_addr()) : ()),
  74                 location => $params{page});
  75
  76         my $url=$defaulturl;
  77         $url = $config{blogspam_server} if exists $config{blogspam_server};
  78
  79         my $client = RPC::XML::Client->new($url);
  80
  81         my @options = split(",", $config{blogspam_options})
  82                 if exists $config{blogspam_options};
  83
  84         # Allow short comments and whitespace-only edits, unless the user
  85         # has overridden min-words themselves.
  86         push @options, "min-words=0"
  87                 unless grep /^min-words=/i, @options;
  88         # Wiki pages can have a lot of urls, unless the user specifically
  89         # wants to limit them.
  90         push @options, "exclude=lotsaurls"
  91                 unless grep /^max-links/i, @options;
  92         # Unless the user specified a size check, disable such checking.
  93         push @options, "exclude=size"
  94                 unless grep /^(?:max|min)-size/i, @options;
  95         # This test has absurd false positives on words like "alpha"
  96         # and "buy".
  97         push @options, "exclude=stopwords";
  98
  99         my %req=(
 100                 ip => $session->remote_addr(),
 101                 comment => encode_utf8(defined $params{diff} ? $params{diff} : $params{content}),
 102                 subject => encode_utf8(defined $params{subject} ? $params{subject} : ""),
 103                 name => encode_utf8(defined $params{author} ? $params{author} : ""),
 104                 link => encode_utf8(exists $params{url} ? $params{url} : ""),
 105                 options => join(",", @options),
 106                 site => encode_utf8($config{url}),
 107                 version => "ikiwiki ".$IkiWiki::version,
 108         );
 109         my $res = $client->send_request('testComment', \%req);
 110
 111         if (! ref $res || ! defined $res->value) {
 112                 debug("failed to get response from blogspam server ($url)");
 113                 return undef;
 114         }
 115         elsif ($res->value =~ /^SPAM:(.*)/) {
 116                 eval q{use Data::Dumper};
 117                 debug("blogspam server reports ".$res->value.": ".Dumper(\%req));
 118                 return gettext("Sorry, but that looks like spam to <a href=\"http://blogspam.net/\">blogspam</a>: ").$1;
 119         }
 120         elsif ($res->value ne 'OK') {
 121                 debug("blogspam server failure: ".$res->value);
 122                 return undef;
 123         }
 124         else {
 125                 return undef;
 126         }
 127 }
 128
 129 1