git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/rename.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::rename;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 2.00;
   7
   8 sub import { #{{{
   9         hook(type => "getsetup", id => "rename", call => \&getsetup);
  10         hook(type => "formbuilder_setup", id => "rename", call => \&formbuilder_setup);
  11         hook(type => "formbuilder", id => "rename", call => \&formbuilder);
  12         hook(type => "sessioncgi", id => "rename", call => \&sessioncgi);
  13
  14 } # }}}
  15
  16 sub getsetup () { #{{{
  17         return
  18                 plugin => {
  19                         safe => 1,
  20                         rebuild => 0,
  21                 },
  22 } #}}}
  23
  24 sub check_canrename ($$$$$$) { #{{{
  25         my $src=shift;
  26         my $srcfile=shift;
  27         my $dest=shift;
  28         my $destfile=shift;
  29         my $q=shift;
  30         my $session=shift;
  31
  32         my $attachment=! defined IkiWiki::pagetype($pagesources{$src});
  33
  34         # Must be a known source file.
  35         if (! exists $pagesources{$src}) {
  36                 error(sprintf(gettext("%s does not exist"),
  37                         htmllink("", "", $src, noimageinline => 1)));
  38         }
  39
  40         # Must exist on disk, and be a regular file.
  41         if (! -e "$config{srcdir}/$srcfile") {
  42                 error(sprintf(gettext("%s is not in the srcdir, so it cannot be renamed"), $srcfile));
  43         }
  44         elsif (-l "$config{srcdir}/$srcfile" && ! -f _) {
  45                 error(sprintf(gettext("%s is not a file"), $srcfile));
  46         }
  47
  48         # Must be editable.
  49         IkiWiki::check_canedit($src, $q, $session);
  50         if ($attachment) {
  51                 if (IkiWiki::Plugin::attachment->can("check_canattach")) {
  52                         IkiWiki::Plugin::attachment::check_canattach($session, $src, $srcfile);
  53                 }
  54                 else {
  55                         error("renaming of attachments is not allowed");
  56                 }
  57         }
  58
  59         # Dest checks can be omitted by passing undef.
  60         if (defined $dest) {
  61                 if ($srcfile eq $destfile) {
  62                         error(gettext("no change to the file name was specified"));
  63                 }
  64
  65                 # Must be a legal filename, and not absolute.
  66                 if (IkiWiki::file_pruned($destfile, $config{srcdir}) ||
  67                     $destfile=~/^\//) {
  68                         error(sprintf(gettext("illegal name")));
  69                 }
  70
  71                 # Must not be a known source file.
  72                 if ($src ne $dest && exists $pagesources{$dest}) {
  73                         error(sprintf(gettext("%s already exists"),
  74                                 htmllink("", "", $dest, noimageinline => 1)));
  75                 }
  76
  77                 # Must not exist on disk already.
  78                 if (-l "$config{srcdir}/$destfile" || -e _) {
  79                         error(sprintf(gettext("%s already exists on disk"), $destfile));
  80                 }
  81
  82                 # Must be editable.
  83                 IkiWiki::check_canedit($dest, $q, $session);
  84                 if ($attachment) {
  85                         # Note that $srcfile is used here, not $destfile,
  86                         # because it wants the current file, to check it.
  87                         IkiWiki::Plugin::attachment::check_canattach($session, $dest, $srcfile);
  88                 }
  89         }
  90 } #}}}
  91
  92 sub rename_form ($$$) { #{{{
  93         my $q=shift;
  94         my $session=shift;
  95         my $page=shift;
  96
  97         eval q{use CGI::FormBuilder};
  98         error($@) if $@;
  99         my $f = CGI::FormBuilder->new(
 100                 name => "rename",
 101                 title => sprintf(gettext("rename %s"), IkiWiki::pagetitle($page)),
 102                 header => 0,
 103                 charset => "utf-8",
 104                 method => 'POST',
 105                 javascript => 0,
 106                 params => $q,
 107                 action => $config{cgiurl},
 108                 stylesheet => IkiWiki::baseurl()."style.css",
 109                 fields => [qw{do page new_name attachment}],
 110         );
 111
 112         $f->field(name => "do", type => "hidden", value => "rename", force => 1);
 113         $f->field(name => "page", type => "hidden", value => $page, force => 1);
 114         $f->field(name => "new_name", value => IkiWiki::pagetitle($page), size => 60);
 115         if (!$q->param("attachment")) {
 116                 # insert the standard extensions
 117                 my @page_types;
 118                 if (exists $IkiWiki::hooks{htmlize}) {
 119                         @page_types=grep { !/^_/ }
 120                                 keys %{$IkiWiki::hooks{htmlize}};
 121                 }
 122
 123                 # make sure the current extension is in the list
 124                 my ($ext) = $pagesources{$page}=~/\.([^.]+)$/;
 125                 if (! $IkiWiki::hooks{htmlize}{$ext}) {
 126                         unshift(@page_types, $ext);
 127                 }
 128
 129                 $f->field(name => "type", type => 'select',
 130                         options => \@page_types,
 131                         value => $ext, force => 1);
 132
 133                 foreach my $p (keys %pagesources) {
 134                         if ($pagesources{$p}=~m/^\Q$page\E\//) {
 135                                 $f->field(name => "subpages",
 136                                         label => "",
 137                                         type => "checkbox",
 138                                         options => [ [ 1 => gettext("Also rename SubPages and attachments") ] ],
 139                                         value => 1,
 140                                         force => 1);
 141                                 last;
 142                         }
 143                 }
 144         }
 145         $f->field(name => "attachment", type => "hidden");
 146
 147         return $f, ["Rename", "Cancel"];
 148 } #}}}
 149
 150 sub rename_start ($$$$) { #{{{
 151         my $q=shift;
 152         my $session=shift;
 153         my $attachment=shift;
 154         my $page=shift;
 155
 156         check_canrename($page, $pagesources{$page}, undef, undef,
 157                 $q, $session);
 158
 159         # Save current form state to allow returning to it later
 160         # without losing any edits.
 161         # (But don't save what button was submitted, to avoid
 162         # looping back to here.)
 163         # Note: "_submit" is CGI::FormBuilder internals.
 164         $q->param(-name => "_submit", -value => "");
 165         $session->param(postrename => scalar $q->Vars);
 166         IkiWiki::cgi_savesession($session);
 167
 168         my ($f, $buttons)=rename_form($q, $session, $page);
 169         if (defined $attachment) {
 170                 $f->field(name => "attachment", value => $attachment, force => 1);
 171         }
 172
 173         IkiWiki::showform($f, $buttons, $session, $q);
 174         exit 0;
 175 } #}}}
 176
 177 sub postrename ($;$$$) { #{{{
 178         my $session=shift;
 179         my $src=shift;
 180         my $dest=shift;
 181         my $attachment=shift;
 182
 183         # Load saved form state and return to edit page.
 184         my $postrename=CGI->new($session->param("postrename"));
 185         $session->clear("postrename");
 186         IkiWiki::cgi_savesession($session);
 187
 188         if (defined $dest) {
 189                 if (! $attachment) {
 190                         # They renamed the page they were editing. This requires
 191                         # fixups to the edit form state.
 192                         # Tweak the edit form to be editing the new page.
 193                         $postrename->param("page", $dest);
 194                 }
 195
 196                 # Update edit form content to fix any links present
 197                 # on it.
 198                 $postrename->param("editcontent",
 199                         renamepage_hook($dest, $src, $dest,
 200                                  $postrename->param("editcontent")));
 201
 202                 # Get a new edit token; old was likely invalidated.
 203                 $postrename->param("rcsinfo",
 204                         IkiWiki::rcs_prepedit($pagesources{$dest}));
 205         }
 206
 207         IkiWiki::cgi_editpage($postrename, $session);
 208 } #}}}
 209
 210 sub formbuilder (@) { #{{{
 211         my %params=@_;
 212         my $form=$params{form};
 213
 214         if (defined $form->field("do") && $form->field("do") eq "edit") {
 215                 my $q=$params{cgi};
 216                 my $session=$params{session};
 217
 218                 if ($form->submitted eq "Rename") {
 219                         rename_start($q, $session, 0, $form->field("page"));
 220                 }
 221                 elsif ($form->submitted eq "Rename Attachment") {
 222                         my @selected=$q->param("attachment_select");
 223                         if (@selected > 1) {
 224                                 error(gettext("Only one attachment can be renamed at a time."));
 225                         }
 226                         elsif (! @selected) {
 227                                 error(gettext("Please select the attachment to rename."))
 228                         }
 229                         rename_start($q, $session, 1, $selected[0]);
 230                 }
 231         }
 232 } #}}}
 233
 234 my $renamesummary;
 235
 236 sub formbuilder_setup (@) { #{{{
 237         my %params=@_;
 238         my $form=$params{form};
 239         my $q=$params{cgi};
 240
 241         if (defined $form->field("do") && $form->field("do") eq "edit") {
 242                 # Rename button for the page, and also for attachments.
 243                 push @{$params{buttons}}, "Rename";
 244                 $form->tmpl_param("field-rename" => '<input name="_submit" type="submit" value="Rename Attachment" />');
 245
 246                 if (defined $renamesummary) {
 247                         $form->tmpl_param(message => $renamesummary);
 248                 }
 249         }
 250 } #}}}
 251
 252 sub sessioncgi ($$) { #{{{
 253         my $q=shift;
 254
 255         if ($q->param("do") eq 'rename') {
 256                 my $session=shift;
 257                 my ($form, $buttons)=rename_form($q, $session, $q->param("page"));
 258                 IkiWiki::decode_form_utf8($form);
 259
 260                 if ($form->submitted eq 'Cancel') {
 261                         postrename($session);
 262                 }
 263                 elsif ($form->submitted eq 'Rename' && $form->validate) {
 264                         # Queue of rename actions to perfom.
 265                         my @torename;
 266
 267                         # These untaints are safe because of the checks
 268                         # performed in check_canrename later.
 269                         my $src=$q->param("page");
 270                         my $srcfile=IkiWiki::possibly_foolish_untaint($pagesources{$src});
 271                         my $dest=IkiWiki::possibly_foolish_untaint(IkiWiki::titlepage($q->param("new_name")));
 272                         my $destfile=$dest;
 273                         if (! $q->param("attachment")) {
 274                                 my $type=$q->param('type');
 275                                 if (defined $type && length $type && $IkiWiki::hooks{htmlize}{$type}) {
 276                                         $type=IkiWiki::possibly_foolish_untaint($type);
 277                                 }
 278                                 else {
 279                                         my ($ext)=$srcfile=~/\.([^.]+)$/;
 280                                         $type=$ext;
 281                                 }
 282
 283                                 $destfile.=".".$type;
 284                         }
 285                         push @torename, {
 286                                 src => $src,
 287                                 srcfile => $srcfile,
 288                                 dest => $dest,
 289                                 destfile => $destfile,
 290                                 required => 1,
 291                         };
 292
 293                         # See if any subpages need to be renamed.
 294                         if ($q->param("subpages") && $src ne $dest) {
 295                                 foreach my $p (keys %pagesources) {
 296                                         if ($pagesources{$p}=~m/^\Q$src\E\//) {
 297                                                 my $d=$pagesources{$p};
 298                                                 $d=~s/^\Q$src\E\//$dest\//;
 299                                                 push @torename, {
 300                                                         src => $p,
 301                                                         srcfile => $pagesources{$p},
 302                                                         dest => pagename($d),
 303                                                         destfile => $d,
 304                                                         required => 0,
 305                                                 };
 306                                         }
 307                                 }
 308                         }
 309
 310                         require IkiWiki::Render;
 311                         IkiWiki::disable_commit_hook() if $config{rcs};
 312                         my %origpagesources=%pagesources;
 313
 314                         # First file renaming.
 315                         foreach my $rename (@torename) {
 316                                 if ($rename->{required}) {
 317                                         do_rename($rename, $q, $session);
 318                                 }
 319                                 else {
 320                                         eval {do_rename($rename, $q, $session)};
 321                                         if ($@) {
 322                                                 $rename->{error}=$@;
 323                                                 next;
 324                                         }
 325                                 }
 326
 327                                 # Temporarily tweak pagesources to point to
 328                                 # the renamed file, in case fixlinks needs
 329                                 # to edit it.
 330                                 $pagesources{$rename->{src}}=$rename->{destfile};
 331                         }
 332                         IkiWiki::rcs_commit_staged(
 333                                 sprintf(gettext("rename %s to %s"), $srcfile, $destfile),
 334                                 $session->param("name"), $ENV{REMOTE_ADDR}) if $config{rcs};
 335
 336                         # Then link fixups.
 337                         foreach my $rename (@torename) {
 338                                 next if $rename->{src} eq $rename->{dest};
 339                                 next if $rename->{error};
 340                                 foreach my $p (fixlinks($rename, $session)) {
 341                                         # map old page names to new
 342                                         foreach my $r (@torename) {
 343                                                 next if $rename->{error};
 344                                                 if ($r->{src} eq $p) {
 345                                                         $p=$r->{dest};
 346                                                         last;
 347                                                 }
 348                                         }
 349                                         push @{$rename->{fixedlinks}}, $p;
 350                                 }
 351                         }
 352
 353                         # Then refresh.
 354                         %pagesources=%origpagesources;
 355                         if ($config{rcs}) {
 356                                 IkiWiki::enable_commit_hook();
 357                                 IkiWiki::rcs_update();
 358                         }
 359                         IkiWiki::refresh();
 360                         IkiWiki::saveindex();
 361
 362                         # Find pages with remaining, broken links.
 363                         foreach my $rename (@torename) {
 364                                 next if $rename->{src} eq $rename->{dest};
 365
 366                                 foreach my $page (keys %links) {
 367                                         my $broken=0;
 368                                         foreach my $link (@{$links{$page}}) {
 369                                                 my $bestlink=bestlink($page, $link);
 370                                                 if ($bestlink eq $rename->{src}) {
 371                                                         push @{$rename->{brokenlinks}}, $page;
 372                                                         last;
 373                                                 }
 374                                         }
 375                                 }
 376                         }
 377
 378                         # Generate a summary, that will be shown at the top
 379                         # of the edit template.
 380                         $renamesummary="";
 381                         foreach my $rename (@torename) {
 382                                 my $template=template("renamesummary.tmpl");
 383                                 $template->param(src => $rename->{srcfile});
 384                                 $template->param(dest => $rename->{destfile});
 385                                 $template->param(error => $rename->{error});
 386                                 if ($rename->{src} ne $rename->{dest}) {
 387                                         $template->param(brokenlinks_checked => 1);
 388                                         $template->param(brokenlinks => [
 389                                                 map {
 390                                                         {
 391                                                                 page => htmllink($rename->{dest}, $rename->{dest}, $_,
 392                                                                                 noimageinline => 1)
 393                                                         }
 394                                                 } @{$rename->{brokenlinks}}
 395                                         ]);
 396                                         $template->param(fixedlinks => [
 397                                                 map {
 398                                                         {
 399                                                                 page => htmllink($rename->{dest}, $rename->{dest}, $_,
 400                                                                                 noimageinline => 1)
 401                                                         }
 402                                                 } @{$rename->{fixedlinks}}
 403                                         ]);
 404                                 }
 405                                 $renamesummary.=$template->output;
 406                         }
 407
 408                         postrename($session, $src, $dest, $q->param("attachment"));
 409                 }
 410                 else {
 411                         IkiWiki::showform($form, $buttons, $session, $q);
 412                 }
 413
 414                 exit 0;
 415         }
 416 } #}}}
 417
 418 sub renamepage_hook ($$$$) { #{{{
 419         my ($page, $src, $dest, $content)=@_;
 420
 421         IkiWiki::run_hooks(renamepage => sub {
 422                 $content=shift->(
 423                         page => $page,
 424                         oldpage => $src,
 425                         newpage => $dest,
 426                         content => $content,
 427                 );
 428         });
 429
 430         return $content;
 431 }# }}}
 432
 433 sub do_rename ($$$) { #{{{
 434         my $rename=shift;
 435         my $q=shift;
 436         my $session=shift;
 437
 438         # First, check if this rename is allowed.
 439         check_canrename($rename->{src},
 440                 $rename->{srcfile},
 441                 $rename->{dest},
 442                 $rename->{destfile},
 443                 $q, $session);
 444
 445         # Ensure that the dest directory exists and is ok.
 446         IkiWiki::prep_writefile($rename->{destfile}, $config{srcdir});
 447
 448         if ($config{rcs}) {
 449                 IkiWiki::rcs_rename($rename->{srcfile}, $rename->{destfile});
 450         }
 451         else {
 452                 if (! rename($config{srcdir}."/".$rename->{srcfile},
 453                              $config{srcdir}."/".$rename->{destfile})) {
 454                         error("rename: $!");
 455                 }
 456         }
 457
 458 } # }}}
 459
 460 sub fixlinks ($$$) { #{{{
 461         my $rename=shift;
 462         my $session=shift;
 463
 464         my @fixedlinks;
 465
 466         foreach my $page (keys %links) {
 467                 my $needfix=0;
 468                 foreach my $link (@{$links{$page}}) {
 469                         my $bestlink=bestlink($page, $link);
 470                         if ($bestlink eq $rename->{src}) {
 471                                 $needfix=1;
 472                                 last;
 473                         }
 474                 }
 475                 if ($needfix) {
 476                         my $file=$pagesources{$page};
 477                         my $oldcontent=readfile($config{srcdir}."/".$file);
 478                         my $content=renamepage_hook($page, $rename->{src}, $rename->{dest}, $oldcontent);
 479                         if ($oldcontent ne $content) {
 480                                 my $token=IkiWiki::rcs_prepedit($file);
 481                                 eval { writefile($file, $config{srcdir}, $content) };
 482                                 next if $@;
 483                                 my $conflict=IkiWiki::rcs_commit(
 484                                         $file,
 485                                         sprintf(gettext("update for rename of %s to %s"), $rename->{srcfile}, $rename->{destfile}),
 486                                         $token,
 487                                         $session->param("name"),
 488                                         $ENV{REMOTE_ADDR}
 489                                 );
 490                                 push @fixedlinks, $page if ! defined $conflict;
 491                         }
 492                 }
 493         }
 494
 495         return @fixedlinks;
 496 } #}}}
 497
 498 1