git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/remove.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::remove;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7
   8 sub import {
   9         hook(type => "getsetup", id => "remove", call => \&getsetup);
  10         hook(type => "formbuilder_setup", id => "remove", call => \&formbuilder_setup);
  11         hook(type => "formbuilder", id => "remove", call => \&formbuilder);
  12         hook(type => "sessioncgi", id => "remove", call => \&sessioncgi);
  13
  14 }
  15
  16 sub getsetup () {
  17         return
  18                 plugin => {
  19                         safe => 1,
  20                         rebuild => 0,
  21                 },
  22 }
  23
  24 sub check_canremove ($$$) {
  25         my $page=shift;
  26         my $q=shift;
  27         my $session=shift;
  28
  29         # Must be a known source file.
  30         if (! exists $pagesources{$page}) {
  31                 error(sprintf(gettext("%s does not exist"),
  32                         htmllink("", "", $page, noimageinline => 1)));
  33         }
  34
  35         # Must exist on disk, and be a regular file.
  36         my $file=$pagesources{$page};
  37         if (! -e "$config{srcdir}/$file") {
  38                 error(sprintf(gettext("%s is not in the srcdir, so it cannot be deleted"), $file));
  39         }
  40         elsif (-l "$config{srcdir}/$file" && ! -f _) {
  41                 error(sprintf(gettext("%s is not a file"), $file));
  42         }
  43
  44         # Must be editable.
  45         IkiWiki::check_canedit($page, $q, $session);
  46
  47         # If a user can't upload an attachment, don't let them delete it.
  48         # This is sorta overkill, but better safe than sorry.
  49         if (! defined pagetype($pagesources{$page})) {
  50                 if (IkiWiki::Plugin::attachment->can("check_canattach")) {
  51                         IkiWiki::Plugin::attachment::check_canattach($session, $page, $file);
  52                 }
  53                 else {
  54                         error("renaming of attachments is not allowed");
  55                 }
  56         }
  57 }
  58
  59 sub formbuilder_setup (@) {
  60         my %params=@_;
  61         my $form=$params{form};
  62         my $q=$params{cgi};
  63
  64         if (defined $form->field("do") && ($form->field("do") eq "edit" ||
  65             $form->field("do") eq "create")) {
  66                 # Removal button for the page, and also for attachments.
  67                 push @{$params{buttons}}, "Remove" if $form->field("do") eq "edit";
  68                 $form->tmpl_param("field-remove" => '<input name="_submit" type="submit" value="Remove Attachments" />');
  69         }
  70 }
  71
  72 sub confirmation_form ($$) {
  73         my $q=shift;
  74         my $session=shift;
  75
  76         eval q{use CGI::FormBuilder};
  77         error($@) if $@;
  78         my $f = CGI::FormBuilder->new(
  79                 name => "remove",
  80                 header => 0,
  81                 charset => "utf-8",
  82                 method => 'POST',
  83                 javascript => 0,
  84                 params => $q,
  85                 action => $config{cgiurl},
  86                 stylesheet => IkiWiki::baseurl()."style.css",
  87                 fields => [qw{do page}],
  88         );
  89
  90         $f->field(name => "do", type => "hidden", value => "remove", force => 1);
  91
  92         return $f, ["Remove", "Cancel"];
  93 }
  94
  95 sub removal_confirm ($$@) {
  96         my $q=shift;
  97         my $session=shift;
  98         my $attachment=shift;
  99         my @pages=@_;
 100
 101         foreach my $page (@pages) {
 102                 check_canremove($page, $q, $session);
 103         }
 104
 105         # Save current form state to allow returning to it later
 106         # without losing any edits.
 107         # (But don't save what button was submitted, to avoid
 108         # looping back to here.)
 109         # Note: "_submit" is CGI::FormBuilder internals.
 110         $q->param(-name => "_submit", -value => "");
 111         $session->param(postremove => scalar $q->Vars);
 112         IkiWiki::cgi_savesession($session);
 113
 114         my ($f, $buttons)=confirmation_form($q, $session);
 115         $f->title(sprintf(gettext("confirm removal of %s"),
 116                 join(", ", map { pagetitle($_) } @pages)));
 117         $f->field(name => "page", type => "hidden", value => \@pages, force => 1);
 118         if (defined $attachment) {
 119                 $f->field(name => "attachment", type => "hidden",
 120                         value => $attachment, force => 1);
 121         }
 122
 123         IkiWiki::showform($f, $buttons, $session, $q);
 124         exit 0;
 125 }
 126
 127 sub postremove ($) {
 128         my $session=shift;
 129
 130         # Load saved form state and return to edit form.
 131         my $postremove=CGI->new($session->param("postremove"));
 132         $session->clear("postremove");
 133         IkiWiki::cgi_savesession($session);
 134         IkiWiki::cgi($postremove, $session);
 135 }
 136
 137 sub formbuilder (@) {
 138         my %params=@_;
 139         my $form=$params{form};
 140
 141         if (defined $form->field("do") && ($form->field("do") eq "edit" ||
 142             $form->field("do") eq "create")) {
 143                 my $q=$params{cgi};
 144                 my $session=$params{session};
 145
 146                 if ($form->submitted eq "Remove" && $form->field("do") eq "edit") {
 147                         removal_confirm($q, $session, 0, $form->field("page"));
 148                 }
 149                 elsif ($form->submitted eq "Remove Attachments") {
 150                         my @selected=$q->param("attachment_select");
 151                         if (! @selected) {
 152                                 error(gettext("Please select the attachments to remove."));
 153                         }
 154                         removal_confirm($q, $session, 1, @selected);
 155                 }
 156         }
 157 }
 158
 159 sub sessioncgi ($$) {
 160         my $q=shift;
 161
 162         if ($q->param("do") eq 'remove') {
 163                 my $session=shift;
 164                 my ($form, $buttons)=confirmation_form($q, $session);
 165                 IkiWiki::decode_form_utf8($form);
 166
 167                 if ($form->submitted eq 'Cancel') {
 168                         postremove($session);
 169                 }
 170                 elsif ($form->submitted eq 'Remove' && $form->validate) {
 171                         my @pages=$q->param("page");
 172
 173                         # Validate removal by checking that the page exists,
 174                         # and that the user is allowed to edit(/remove) it.
 175                         my @files;
 176                         foreach my $page (@pages) {
 177                                 check_canremove($page, $q, $session);
 178
 179                                 # This untaint is safe because of the
 180                                 # checks performed above, which verify the
 181                                 # page is a normal file, etc.
 182                                 push @files, IkiWiki::possibly_foolish_untaint($pagesources{$page});
 183                         }
 184
 185                         # Do removal, and update the wiki.
 186                         require IkiWiki::Render;
 187                         if ($config{rcs}) {
 188                                 IkiWiki::disable_commit_hook();
 189                                 foreach my $file (@files) {
 190                                         IkiWiki::rcs_remove($file);
 191                                 }
 192                                 IkiWiki::rcs_commit_staged(gettext("removed"),
 193                                         $session->param("name"), $ENV{REMOTE_ADDR});
 194                                 IkiWiki::enable_commit_hook();
 195                                 IkiWiki::rcs_update();
 196                         }
 197                         else {
 198                                 foreach my $file (@files) {
 199                                         IkiWiki::prune("$config{srcdir}/$file");
 200                                 }
 201                         }
 202                         IkiWiki::refresh();
 203                         IkiWiki::saveindex();
 204
 205                         if ($q->param("attachment")) {
 206                                 # Attachments were deleted, so redirect
 207                                 # back to the edit form.
 208                                 postremove($session);
 209                         }
 210                         else {
 211                                 # The page is gone, so redirect to parent
 212                                 # of the page.
 213                                 my $parent=IkiWiki::dirname($pages[0]);
 214                                 if (! exists $pagesources{$parent}) {
 215                                         $parent="index";
 216                                 }
 217                                 IkiWiki::redirect($q, urlto($parent, '/', 1));
 218                         }
 219                 }
 220                 else {
 221                         removal_confirm($q, $session, 0, $q->param("page"));
 222                 }
 223
 224                 exit 0;
 225         }
 226 }
 227
 228 1