git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/pagestats.pm

   1 #!/usr/bin/perl
   2 #
   3 # Produce page statistics in various forms.
   4 #
   5 # Currently supported:
   6 #   cloud: produces statistics in the form of a del.icio.us-style tag cloud
   7 #          (default)
   8 #   table: produces a table with the number of backlinks for each page
   9 #
  10 # By Enrico Zini.
  11 package IkiWiki::Plugin::pagestats;
  12
  13 use warnings;
  14 use strict;
  15 use IkiWiki;
  16
  17 # Names of the HTML classes to use for the tag cloud
  18 our @classes = ('smallestPC', 'smallPC', 'normalPC', 'bigPC', 'biggestPC' );
  19
  20 sub import { #{{{
  21         IkiWiki::hook(type => "preprocess", id => "pagestats",
  22                 call => \&preprocess);
  23 } # }}}
  24
  25 sub preprocess (@) { #{{{
  26         my %params=@_;
  27         $params{pages}="*" unless defined $params{pages};
  28         my $style = ($params{style} or 'cloud');
  29
  30         # Needs to update whenever a page is added or removed, so
  31         # register a dependency.
  32         IkiWiki::add_depends($params{page}, $params{pages});
  33
  34         my %counts;
  35         my $max = 0;
  36         foreach my $page (%IkiWiki::links) {
  37                 if (IkiWiki::globlist_match($page, $params{pages})) {
  38                         my @bl = IkiWiki::backlinks($page);
  39                         $counts{$page} = scalar(@bl);
  40                         $max = $counts{$page} if $counts{$page} > $max;
  41                 }
  42         }
  43
  44         if ($style eq 'table') {
  45                 return "<table class='pageStats'>\n".join("\n", map { "<tr><td>$_</td><td>".$counts{$_}."</td></tr>" }
  46                       sort { $counts{$b} <=> $counts{$a} } keys %counts)."\n</table>\n" ;
  47         } else {
  48                 # In case of misspelling, default to a page cloud
  49
  50                 my $res = "<div class='pagecloud'>\n";
  51                 foreach my $page (sort keys %counts) {
  52                         my $class = $classes[$counts{$page} * scalar(@classes) / ($max + 1)];
  53                         $res .= "<span class=\"$class\">".
  54                                 IkiWiki::htmllink($params{page}, $params{destpage}, $page).
  55                                 "</span>\n";
  56                 }
  57                 $res .= "</div>\n";
  58
  59                 return $res;
  60         }
  61 } # }}}
  62
  63 1