git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/websetup.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::websetup;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 2.00;
   7
   8 sub import { #{{{
   9         hook(type => "getsetup", id => "websetup", call => \&getsetup);
  10         hook(type => "checkconfig", id => "websetup", call => \&checkconfig);
  11         hook(type => "sessioncgi", id => "websetup", call => \&sessioncgi);
  12         hook(type => "formbuilder_setup", id => "websetup",
  13              call => \&formbuilder_setup);
  14 } # }}}
  15
  16 sub getsetup () { #{{{
  17         return
  18                 plugin => {
  19                         safe => 1,
  20                         rebuild => 0,
  21                 },
  22                 websetup_force_plugins => {
  23                         type => "string",
  24                         example => [],
  25                         description => "list of plugins that cannot be enabled/disabled via the web interface",
  26                         safe => 0,
  27                         rebuild => 0,
  28                 },
  29                 websetup_show_unsafe => {
  30                         type => "boolean",
  31                         example => 1,
  32                         description => "show unsafe settings, read-only, in web interface?",
  33                         safe => 0,
  34                         rebuild => 0,
  35                 },
  36 } #}}}
  37
  38 sub checkconfig () { #{{{
  39         if (! exists $config{websetup_show_unsafe}) {
  40                 $config{websetup_show_unsafe}=1;
  41         }
  42 } #}}}
  43
  44 sub formatexample ($$) { #{{{
  45         my $example=shift;
  46         my $value=shift;
  47
  48         if (defined $value && length $value) {
  49                 return "";
  50         }
  51         elsif (defined $example && ! ref $example && length $example) {
  52                 return "<br/ ><small>Example: <tt>$example</tt></small>";
  53         }
  54         else {
  55                 return "";
  56         }
  57 } #}}}
  58
  59 sub showfields ($$$@) { #{{{
  60         my $form=shift;
  61         my $plugin=shift;
  62         my $enabled=shift;
  63
  64         my @show;
  65         my %plugininfo;
  66         while (@_) {
  67                 my $key=shift;
  68                 my %info=%{shift()};
  69
  70                 # skip internal settings
  71                 next if defined $info{type} && $info{type} eq "internal";
  72                 # XXX hashes not handled yet
  73                 next if ref $config{$key} && ref $config{$key} eq 'HASH' || ref $info{example} eq 'HASH';
  74                 # maybe skip unsafe settings
  75                 next if ! $info{safe} && ! ($config{websetup_show_unsafe} && $config{websetup_advanced});
  76                 # maybe skip advanced settings
  77                 next if $info{advanced} && ! $config{websetup_advanced};
  78                 # these are handled specially, so don't show
  79                 next if $key eq 'add_plugins' || $key eq 'disable_plugins';
  80
  81                 if ($key eq 'plugin') {
  82                         %plugininfo=%info;
  83                         next;
  84                 }
  85
  86                 push @show, $key, \%info;
  87         }
  88
  89         my $section=defined $plugin ? $plugin." ".gettext("plugin") : "main";
  90         my %enabledfields;
  91         my $shownfields=0;
  92
  93         my $plugin_forced=defined $plugin && (! $plugininfo{safe} ||
  94                 (exists $config{websetup_force_plugins} && grep { $_ eq $plugin } @{$config{websetup_force_plugins}}));
  95         if ($plugin_forced && ! $enabled) {
  96                 # plugin is forced disabled, so skip its settings
  97                 @show=();
  98         }
  99
 100         # show plugin toggle
 101         if (defined $plugin && (! $plugin_forced || $config{websetup_advanced})) {
 102                 my $name="enable.$plugin";
 103                 $form->field(
 104                         name => $name,
 105                         label => "",
 106                         type => "checkbox",
 107                         fieldset => $section,
 108                         options => [ [ 1 => sprintf(gettext("enable %s?"), $plugin) ]]
 109                 );
 110                 if (! $form->submitted) {
 111                         $form->field(name => $name, value => $enabled);
 112                 }
 113                 if ($plugin_forced) {
 114                         $form->field(name => $name, disabled => 1);
 115                 }
 116                 else {
 117                         $enabledfields{$name}=[$name, \%plugininfo];
 118                 }
 119         }
 120
 121         # show plugin settings
 122         while (@show) {
 123                 my $key=shift @show;
 124                 my %info=%{shift @show};
 125
 126                 my $description=$info{description};
 127                 if (exists $info{link} && length $info{link}) {
 128                         if ($info{link} =~ /^\w+:\/\//) {
 129                                 $description="<a href=\"$info{link}\">$description</a>";
 130                         }
 131                         else {
 132                                 $description=htmllink("", "", $info{link}, noimageinline => 1, linktext => $description);
 133                         }
 134                 }
 135
 136                 # multiple plugins can have the same field
 137                 my $name=defined $plugin ? $plugin.".".$key : $key;
 138
 139                 my $value=$config{$key};
 140
 141                 if ($info{safe} && (ref $config{$key} eq 'ARRAY' || ref $info{example} eq 'ARRAY')) {
 142                         push @{$value}, "", ""; # blank items for expansion
 143                 }
 144
 145                 if ($info{type} eq "string") {
 146                         $form->field(
 147                                 name => $name,
 148                                 label => $description,
 149                                 comment => formatexample($info{example}, $value),
 150                                 type => "text",
 151                                 value => $value,
 152                                 size => 60,
 153                                 fieldset => $section,
 154                         );
 155                 }
 156                 elsif ($info{type} eq "pagespec") {
 157                         $form->field(
 158                                 name => $name,
 159                                 label => $description,
 160                                 comment => formatexample($info{example}, $value),
 161                                 type => "text",
 162                                 value => $value,
 163                                 size => 60,
 164                                 validate => \&IkiWiki::pagespec_valid,
 165                                 fieldset => $section,
 166                         );
 167                 }
 168                 elsif ($info{type} eq "integer") {
 169                         $form->field(
 170                                 name => $name,
 171                                 label => $description,
 172                                 comment => formatexample($info{example}, $value),
 173                                 type => "text",
 174                                 value => $value,
 175                                 size => 5,
 176                                 validate => '/^[0-9]+$/',
 177                                 fieldset => $section,
 178                         );
 179                 }
 180                 elsif ($info{type} eq "boolean") {
 181                         $form->field(
 182                                 name => $name,
 183                                 label => "",
 184                                 type => "checkbox",
 185                                 options => [ [ 1 => $description ] ],
 186                                 fieldset => $section,
 187                         );
 188                         if (! $form->submitted) {
 189                                 $form->field(name => $name, value => $value);
 190                         }
 191                 }
 192
 193                 if (! $info{safe}) {
 194                         $form->field(name => $name, disabled => 1);
 195                 }
 196                 else {
 197                         $enabledfields{$name}=[$key, \%info];
 198                 }
 199                 $shownfields++;
 200         }
 201
 202         # if no fields were shown for the plugin, drop it into the
 203         # plugins fieldset
 204         if (defined $plugin && (! $plugin_forced || $config{websetup_advanced}) &&
 205             ! $shownfields) {
 206                 $form->field(name => "enable.$plugin", fieldset => "plugins");
 207         }
 208
 209         return %enabledfields;
 210 } #}}}
 211
 212 sub showform ($$) { #{{{
 213         my $cgi=shift;
 214         my $session=shift;
 215
 216         if (! defined $session->param("name") ||
 217             ! IkiWiki::is_admin($session->param("name"))) {
 218                 error(gettext("you are not logged in as an admin"));
 219         }
 220
 221         eval q{use CGI::FormBuilder};
 222         error($@) if $@;
 223
 224         my $form = CGI::FormBuilder->new(
 225                 title => "setup",
 226                 name => "setup",
 227                 header => 0,
 228                 charset => "utf-8",
 229                 method => 'POST',
 230                 javascript => 0,
 231                 reset => 1,
 232                 params => $cgi,
 233                 fieldsets => [
 234                         [main => gettext("main")],
 235                         [plugins => gettext("plugins")]
 236                 ],
 237                 action => $config{cgiurl},
 238                 template => {type => 'div'},
 239                 stylesheet => IkiWiki::baseurl()."style.css",
 240         );
 241
 242         $form->field(name => "do", type => "hidden", value => "setup",
 243                 force => 1);
 244
 245         if ($form->submitted eq 'Basic Mode') {
 246                 $form->field(name => "showadvanced", type => "hidden",
 247                         value => 0, force => 1);
 248         }
 249         elsif ($form->submitted eq 'Advanced Mode') {
 250                 $form->field(name => "showadvanced", type => "hidden",
 251                         value => 1, force => 1);
 252         }
 253         my $advancedtoggle;
 254         if ($form->field("showadvanced")) {
 255                 $config{websetup_advanced}=1;
 256                 $advancedtoggle="Basic Mode";
 257         }
 258         else {
 259                 $config{websetup_advanced}=0;
 260                 $advancedtoggle="Advanced Mode";
 261         }
 262
 263         my $buttons=["Save Setup", $advancedtoggle, "Cancel"];
 264
 265         IkiWiki::decode_form_utf8($form);
 266         IkiWiki::run_hooks(formbuilder_setup => sub {
 267                 shift->(form => $form, cgi => $cgi, session => $session,
 268                         buttons => $buttons);
 269         });
 270         IkiWiki::decode_form_utf8($form);
 271
 272         my %fields=showfields($form, undef, undef, IkiWiki::getsetup());
 273
 274         # record all currently enabled plugins before all are loaded
 275         my %enabled_plugins=%IkiWiki::loaded_plugins;
 276
 277         # per-plugin setup
 278         require IkiWiki::Setup;
 279         foreach my $pair (IkiWiki::Setup::getsetup()) {
 280                 my $plugin=$pair->[0];
 281                 my $setup=$pair->[1];
 282
 283                 my %shown=showfields($form, $plugin, $enabled_plugins{$plugin}, @{$setup});
 284                 if (%shown) {
 285                         $fields{$_}=$shown{$_} foreach keys %shown;
 286                 }
 287         }
 288
 289         if ($form->submitted eq "Cancel") {
 290                 IkiWiki::redirect($cgi, $config{url});
 291                 return;
 292         }
 293         elsif (($form->submitted eq 'Save Setup' || $form->submitted eq 'Rebuild Wiki') && $form->validate) {
 294                 # Push values from form into %config, avoiding unnecessary
 295                 # changes, and keeping track of which changes need a
 296                 # rebuild.
 297                 my %rebuild;
 298                 foreach my $field (keys %fields) {
 299                         my %info=%{$fields{$field}->[1]};
 300                         my $key=$fields{$field}->[0];
 301                         my @value=$form->field($field);
 302                         if (! @value) {
 303                                 @value=0;
 304                         }
 305
 306                         if (! $info{safe}) {
 307                                 error("unsafe field $key"); # should never happen
 308                         }
 309
 310                         if (exists $info{rebuild} &&
 311                             ($info{rebuild} || ! defined $info{rebuild})) {
 312                                 $rebuild{$field}=$info{rebuild};
 313                         }
 314
 315                         if ($field=~/^enable\.(.*)/) {
 316                                 my $plugin=$1;
 317                                 if ($value[0] != exists $enabled_plugins{$plugin}) {
 318                                         # TODO plugin enable/disable
 319                                 }
 320                                 else {
 321                                         delete $rebuild{$field};
 322                                 }
 323                                 next;
 324                         }
 325
 326                         if (ref $config{$key} eq "ARRAY" || ref $info{example} eq "ARRAY") {
 327                                 @value=sort grep { length $_ } @value;
 328                                 my @oldvalue=sort grep { length $_ }
 329                                         (defined $config{$key} ? @{$config{$key}} : ());
 330                                 if ((@oldvalue) == (@value)) {
 331                                         delete $rebuild{$field};
 332                                 }
 333                                 else {
 334                                         $config{$key}=\@value;
 335                                 }
 336                         }
 337                         elsif (ref $config{$key} || ref $info{example}) {
 338                                 error("complex field $key"); # should never happen
 339                         }
 340                         else {
 341                                 if (defined $config{$key} && $config{$key} eq $value[0]) {
 342                                         delete $rebuild{$field};
 343                                 }
 344                                 elsif (! defined $config{$key} && ! length $value[0]) {
 345                                         delete $rebuild{$field};
 346                                 }
 347                                 elsif (! defined $config{$key} && ! $value[0] &&
 348                                        $info{type} eq "boolean") {
 349                                         delete $rebuild{$field};
 350                                 }
 351                                 else {
 352                                         $config{$key}=$value[0];
 353                                 }
 354                         }
 355                 }
 356
 357                 if (%rebuild && ! $form->field("rebuild_asked")) {
 358                         my $required=0;
 359                         foreach my $field ($form->field) {
 360                                 $required=1 if $rebuild{$field};
 361                                 next if exists $rebuild{$field};
 362                                 $form->field(name => $field, type => "hidden",
 363                                         force => 1);
 364                         }
 365                         if ($required) {
 366                                 $form->text(gettext("The configuration changes shown below require a wiki rebuild to take effect."));
 367                                 $buttons=["Rebuild Wiki", "Cancel"];
 368                         }
 369                         else {
 370                                 $form->text(gettext("For the configuration changes shown below to fully take effect, you may need to rebuild the wiki."));
 371                                 $buttons=["Rebuild Wiki", "Save Setup", "Cancel"];
 372                         }
 373                         $form->field(name => "rebuild_asked", type => "hidden",
 374                                 value => 1, force => 1);
 375                         $form->reset(0); # doesn't really make sense here
 376                 }
 377                 else {
 378                         $form->field(name => "rebuild_asked", type => "hidden",
 379                                 value => 0, force => 1);
 380                         # TODO save to real path
 381                         IkiWiki::Setup::dump("/tmp/s");
 382                         $form->text(gettext("Setup saved."));
 383
 384                         if ($form->submitted eq 'Rebuild Wiki') {
 385                                 # TODO rebuild
 386                         }
 387                 }
 388         }
 389
 390         IkiWiki::showform($form, $buttons, $session, $cgi);
 391 } #}}}
 392
 393 sub sessioncgi ($$) { #{{{
 394         my $cgi=shift;
 395         my $session=shift;
 396
 397         if ($cgi->param("do") eq "setup") {
 398                 showform($cgi, $session);
 399                 exit;
 400         }
 401 } #}}}
 402
 403 sub formbuilder_setup (@) { #{{{
 404         my %params=@_;
 405
 406         my $form=$params{form};
 407         if ($form->title eq "preferences") {
 408                 push @{$params{buttons}}, "Wiki Setup";
 409                 if ($form->submitted && $form->submitted eq "Wiki Setup") {
 410                         showform($params{cgi}, $params{session});
 411                         exit;
 412                 }
 413         }
 414 } #}}}
 415
 416 1