git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Setup/Standard.pm

   1 #!/usr/bin/perl
   2 # Standard ikiwiki setup module.
   3 # Parameters to import should be all the standard ikiwiki config stuff,
   4 # plus an array of wrappers to set up.
   5
   6 package IkiWiki::Setup::Standard;
   7
   8 use warnings;
   9 use strict;
  10 use IkiWiki;
  11
  12 sub import { #{{{
  13         $IkiWiki::Setup::raw_setup=$_[1];
  14 } #}}}
  15
  16 sub dumpline ($$$$) { #{{{
  17         my $key=shift;
  18         my $value=shift;
  19         my $type=shift;
  20         my $prefix=shift;
  21
  22         eval q{use Data::Dumper};
  23         error($@) if $@;
  24         local $Data::Dumper::Terse=1;
  25         local $Data::Dumper::Indent=1;
  26         local $Data::Dumper::Pad="\t";
  27         local $Data::Dumper::Sortkeys=1;
  28         local $Data::Dumper::Quotekeys=0;
  29
  30         my $dumpedvalue;
  31         if ($type eq 'boolean' || $type eq 'integer') {
  32                 # avoid quotes
  33                 $dumpedvalue=$value;
  34         }
  35         elsif ($type eq 'string' && ref $value eq 'ARRAY' && @$value &&
  36             ! grep { /[^-A-Za-z0-9_]/ } @$value) {
  37                 # dump simple array as qw{}
  38                 $dumpedvalue="[qw{ ".join(" ", @$value)." }]";
  39         }
  40         else {
  41                 $dumpedvalue=Dumper($value);
  42                 chomp $dumpedvalue;
  43                 $dumpedvalue=~s/^\t//;
  44         }
  45
  46         return "\t$prefix$key => $dumpedvalue,";
  47 } #}}}
  48
  49 sub dumpvalues ($@) { #{{{
  50         my $setup=shift;
  51         my @ret;
  52         while (@_) {
  53                 my $key=shift;
  54                 my %info=%{shift()};
  55
  56                 next if $info{type} eq "internal";
  57
  58                 push @ret, "\t# ".$info{description} if exists $info{description};
  59
  60                 if (exists $setup->{$key} && defined $setup->{$key}) {
  61                         push @ret, dumpline($key, $setup->{$key}, $info{type}, "");
  62                         delete $setup->{$key};
  63                 }
  64                 elsif (exists $info{default} && defined $info{default}) {
  65                         push @ret, dumpline($key, $info{default}, $info{type}, "#");
  66                 }
  67                 elsif (exists $info{example}) {
  68                         push @ret, dumpline($key, $info{example}, $info{type}, "#");
  69                 }
  70         }
  71         return @ret;
  72 } #}}}
  73
  74 sub gendump ($) { #{{{
  75         my $description=shift;
  76         my %setup=(%config);
  77         my @ret;
  78
  79         push @ret, "\t# basic setup";
  80         push @ret, dumpvalues(\%setup, IkiWiki::getsetup());
  81
  82         # Load all plugins, so that all setup options are available.
  83         my @plugins=sort(IkiWiki::listplugins());
  84         foreach my $plugin (@plugins) {
  85                 eval { IkiWiki::loadplugin($plugin) };
  86                 if (exists $IkiWiki::hooks{checkconfig}{$plugin}{call}) {
  87                         my @s=eval { $IkiWiki::hooks{checkconfig}{$plugin}{call}->() };
  88                 }
  89         }
  90         unshift @plugins, $config{rcs} if $config{rcs};
  91
  92         foreach my $id (@plugins) {
  93                 my $title="\t# $id".($id ne $config{rcs} ? " plugin" : "");
  94                 if (exists $IkiWiki::hooks{getsetup}{$id}{call}) {
  95                         # use an array rather than a hash, to preserve order
  96                         my @s=eval { $IkiWiki::hooks{getsetup}{$id}{call}->() };
  97                         next unless @s;
  98                         push @ret, "", $title;
  99                         push @ret, dumpvalues(\%setup, @s);
 100                 }
 101         }
 102
 103         unshift @ret,
 104                 "#!/usr/bin/perl",
 105                 "# $description",
 106                 "#",
 107                 "# Passing this to ikiwiki --setup will make ikiwiki generate",
 108                 "# wrappers and build the wiki.",
 109                 "#",
 110                 "# Remember to re-run ikiwiki --setup any time you edit this file.",
 111                 "use IkiWiki::Setup::Standard {";
 112         push @ret, "}";
 113
 114         return @ret;
 115 } #}}}
 116
 117 1