git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/img.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki enhanced image handling plugin
   3 # Christian Mock cm@tahina.priv.at 20061002
   4 package IkiWiki::Plugin::img;
   5
   6 use warnings;
   7 use strict;
   8 use IkiWiki 3.00;
   9
  10 my %imgdefaults;
  11
  12 sub import {
  13         hook(type => "getsetup", id => "img", call => \&getsetup);
  14         hook(type => "preprocess", id => "img", call => \&preprocess, scan => 1);
  15 }
  16
  17 sub getsetup () {
  18         return
  19                 plugin => {
  20                         safe => 1,
  21                         rebuild => undef,
  22                 },
  23 }
  24
  25 sub preprocess (@) {
  26         my ($image) = $_[0] =~ /$config{wiki_file_regexp}/; # untaint
  27         my %params=@_;
  28
  29         if (exists $imgdefaults{$params{page}}) {
  30                 foreach my $key (keys %{$imgdefaults{$params{page}}}) {
  31                         if (! exists $params{$key}) {
  32                                 $params{$key}=$imgdefaults{$params{page}}->{$key};
  33                         }
  34                 }
  35         }
  36
  37         if (! exists $params{size}) {
  38                 $params{size}='full';
  39         }
  40
  41         if ($image eq 'defaults') {
  42                 $imgdefaults{$params{page}} = \%params;
  43                 return '';
  44         }
  45
  46         add_link($params{page}, $image);
  47
  48         # optimisation: detect scan mode, and avoid generating the image
  49         if (! defined wantarray) {
  50                 return;
  51         }
  52
  53         my $file = bestlink($params{page}, $image);
  54         my $srcfile = srcfile($file, 1);
  55         if (! length $file || ! defined $srcfile) {
  56                 return htmllink($params{page}, $params{destpage}, $image);
  57         }
  58
  59         my $dir = $params{page};
  60         my $base = IkiWiki::basename($file);
  61
  62         eval q{use Image::Magick};
  63         error gettext("Image::Magick is not installed") if $@;
  64         my $im = Image::Magick->new;
  65         my $imglink;
  66         my $r;
  67
  68         if ($params{size} ne 'full') {
  69                 add_depends($params{page}, $image);
  70
  71                 my ($w, $h) = ($params{size} =~ /^(\d*)x(\d*)$/);
  72                 error sprintf(gettext('wrong size format "%s" (should be WxH)'), $params{size})
  73                         unless (defined $w && defined $h &&
  74                                 (length $w || length $h));
  75
  76                 my $outfile = "$config{destdir}/$dir/${w}x${h}-$base";
  77                 $imglink = "$dir/${w}x${h}-$base";
  78
  79                 will_render($params{page}, $imglink);
  80
  81                 if (-e $outfile && (-M $srcfile >= -M $outfile)) {
  82                         $r = $im->Read($outfile);
  83                         error sprintf(gettext("failed to read %s: %s"), $outfile, $r) if $r;
  84                 }
  85                 else {
  86                         $r = $im->Read($srcfile);
  87                         error sprintf(gettext("failed to read %s: %s"), $file, $r) if $r;
  88
  89                         $r = $im->Resize(geometry => "${w}x${h}");
  90                         error sprintf(gettext("failed to resize: %s"), $r) if $r;
  91
  92                         # don't actually write file in preview mode
  93                         if (! $params{preview}) {
  94                                 my @blob = $im->ImageToBlob();
  95                                 writefile($imglink, $config{destdir}, $blob[0], 1);
  96                         }
  97                         else {
  98                                 $imglink = $file;
  99                         }
 100                 }
 101         }
 102         else {
 103                 $r = $im->Read($srcfile);
 104                 error sprintf(gettext("failed to read %s: %s"), $file, $r) if $r;
 105                 $imglink = $file;
 106         }
 107
 108         my ($fileurl, $imgurl);
 109         if (! $params{preview}) {
 110                 $fileurl=urlto($file, $params{destpage});
 111                 $imgurl=urlto($imglink, $params{destpage});
 112         }
 113         else {
 114                 $fileurl="$config{url}/$file";
 115                 $imgurl="$config{url}/$imglink";
 116         }
 117
 118         if (! defined($im->Get("width")) || ! defined($im->Get("height"))) {
 119                 error sprintf(gettext("failed to determine size of image %s"), $file)
 120         }
 121
 122         my $imgtag='<img src="'.$imgurl.
 123                 '" width="'.$im->Get("width").
 124                 '" height="'.$im->Get("height").'"'.
 125                 (exists $params{alt} ? ' alt="'.$params{alt}.'"' : '').
 126                 (exists $params{title} ? ' title="'.$params{title}.'"' : '').
 127                 (exists $params{align} ? ' align="'.$params{align}.'"' : '').
 128                 (exists $params{class} ? ' class="'.$params{class}.'"' : '').
 129                 (exists $params{id} ? ' id="'.$params{id}.'"' : '').
 130                 ' />';
 131
 132         if (! defined $params{link} || lc($params{link}) eq 'yes') {
 133                 $imgtag='<a href="'.$fileurl.'">'.$imgtag.'</a>';
 134         }
 135         elsif ($params{link} =~ /^\w+:\/\//) {
 136                 $imgtag='<a href="'.$params{link}.'">'.$imgtag.'</a>';
 137         }
 138         elsif (length bestlink($params{page}, $params{link})) {
 139                 add_depends($params{page}, $params{link});
 140                 $imgtag=htmllink($params{page}, $params{destpage},
 141                         $params{link}, linktext => $imgtag,
 142                         noimageinline => 1);
 143         }
 144
 145         if (exists $params{caption}) {
 146                 return '<table class="img">'.
 147                         '<caption>'.$params{caption}.'</caption>'.
 148                         '<tr><td>'.$imgtag.'</td></tr>'.
 149                         '</table>';
 150         }
 151         else {
 152                 return $imgtag;
 153         }
 154 }
 155
 156 1