git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/meta.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki metadata plugin.
   3 package IkiWiki::Plugin::meta;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki 2.00;
   8
   9 my %metaheaders;
  10
  11 sub import { #{{{
  12         hook(type => "needsbuild", id => "meta", call => \&needsbuild);
  13         hook(type => "preprocess", id => "meta", call => \&preprocess, scan => 1);
  14         hook(type => "pagetemplate", id => "meta", call => \&pagetemplate);
  15 } # }}}
  16
  17 sub needsbuild (@) { #{{{
  18         my $needsbuild=shift;
  19         foreach my $page (keys %pagestate) {
  20                 if (exists $pagestate{$page}{meta}) {
  21                         if (grep { $_ eq $pagesources{$page} } @$needsbuild) {
  22                                 # remove state, it will be re-added
  23                                 # if the preprocessor directive is still
  24                                 # there during the rebuild
  25                                 delete $pagestate{$page}{meta};
  26                         }
  27                 }
  28         }
  29 }
  30
  31 sub scrub ($) { #{{{
  32         if (IkiWiki::Plugin::htmlscrubber->can("sanitize")) {
  33                 return IkiWiki::Plugin::htmlscrubber::sanitize(content => shift);
  34         }
  35         else {
  36                 return shift;
  37         }
  38 } #}}}
  39
  40 sub htmlize ($$$) { #{{{
  41         my $page = shift;
  42         my $destpage = shift;
  43
  44         return IkiWiki::htmlize($page, pagetype($pagesources{$page}),
  45                 IkiWiki::linkify($page, $destpage,
  46                 IkiWiki::preprocess($page, $destpage, shift)));
  47 }
  48
  49 sub preprocess (@) { #{{{
  50         return "" unless @_;
  51         my %params=@_;
  52         my $key=shift;
  53         my $value=$params{$key};
  54         delete $params{$key};
  55         my $page=$params{page};
  56         delete $params{page};
  57         my $destpage=$params{destpage};
  58         delete $params{destpage};
  59         delete $params{preview};
  60
  61         eval q{use HTML::Entities};
  62         # Always decode, even if encoding later, since it might not be
  63         # fully encoded.
  64         $value=decode_entities($value);
  65
  66         # Metadata collection that needs to happen during the scan pass.
  67         if ($key eq 'title') {
  68                 $pagestate{$page}{meta}{title}=HTML::Entities::encode_numeric($value);
  69         }
  70         elsif ($key eq 'license') {
  71                 push @{$metaheaders{$page}}, '<link rel="license" href="#page_license" />';
  72                 $pagestate{$page}{meta}{license}=$value;
  73                 return "";
  74         }
  75         elsif ($key eq 'copyright') {
  76                 push @{$metaheaders{$page}}, '<link rel="copyright" href="#page_copyright" />';
  77                 $pagestate{$page}{meta}{copyright}=$value;
  78                 return "";
  79         }
  80         elsif ($key eq 'link' && ! %params) {
  81                 # hidden WikiLink
  82                 push @{$links{$page}}, $value;
  83                 return "";
  84         }
  85         elsif ($key eq 'author') {
  86                 $pagestate{$page}{meta}{author}=$value;
  87                 # fallthorough
  88         }
  89         elsif ($key eq 'authorurl') {
  90                 $pagestate{$page}{meta}{authorurl}=$value;
  91                 # fallthrough
  92         }
  93
  94         if (! defined wantarray) {
  95                 # avoid collecting duplicate data during scan pass
  96                 return;
  97         }
  98
  99         # Metadata collection that happens only during preprocessing pass.
 100         if ($key eq 'date') {
 101                 eval q{use Date::Parse};
 102                 if (! $@) {
 103                         my $time = str2time($value);
 104                         $IkiWiki::pagectime{$page}=$time if defined $time;
 105                 }
 106         }
 107         elsif ($key eq 'permalink') {
 108                 $pagestate{$page}{meta}{permalink}=$value;
 109                 push @{$metaheaders{$page}}, scrub('<link rel="bookmark" href="'.encode_entities($value).'" />');
 110         }
 111         elsif ($key eq 'stylesheet') {
 112                 my $rel=exists $params{rel} ? $params{rel} : "alternate stylesheet";
 113                 my $title=exists $params{title} ? $params{title} : $value;
 114                 # adding .css to the value prevents using any old web
 115                 # editable page as a stylesheet
 116                 my $stylesheet=bestlink($page, $value.".css");
 117                 if (! length $stylesheet) {
 118                         return "[[meta ".gettext("stylesheet not found")."]]";
 119                 }
 120                 push @{$metaheaders{$page}}, '<link href="'.urlto($stylesheet, $page).
 121                         '" rel="'.encode_entities($rel).
 122                         '" title="'.encode_entities($title).
 123                         "\" type=\"text/css\" />";
 124         }
 125         elsif ($key eq 'openid') {
 126                 if (exists $params{server}) {
 127                         push @{$metaheaders{$page}}, '<link href="'.encode_entities($params{server}).
 128                                 '" rel="openid.server" />';
 129                 }
 130                 push @{$metaheaders{$page}}, '<link href="'.encode_entities($value).
 131                         '" rel="openid.delegate" />';
 132         }
 133         elsif ($key eq 'redir') {
 134                 return "" if $page ne $destpage;
 135                 my $safe=0;
 136                 if ($value !~ /^\w+:\/\//) {
 137                         my ($redir_page, $redir_anchor) = split /\#/, $value;
 138
 139                         add_depends($page, $redir_page);
 140                         my $link=bestlink($page, $redir_page);
 141                         if (! length $link) {
 142                                 return "[[meta ".gettext("redir page not found")."]]";
 143                         }
 144
 145                         $value=urlto($link, $page);
 146                         $value.='#'.$redir_anchor if defined $redir_anchor;
 147                         $safe=1;
 148
 149                         # redir cycle detection
 150                         $pagestate{$page}{meta}{redir}=$link;
 151                         my $at=$page;
 152                         my %seen;
 153                         while (exists $pagestate{$at}{meta}{redir}) {
 154                                 if ($seen{$at}) {
 155                                         return "[[meta ".gettext("redir cycle is not allowed")."]]";
 156                                 }
 157                                 $seen{$at}=1;
 158                                 $at=$pagestate{$at}{meta}{redir};
 159                         }
 160                 }
 161                 else {
 162                         $value=encode_entities($value);
 163                 }
 164                 my $delay=int(exists $params{delay} ? $params{delay} : 0);
 165                 my $redir="<meta http-equiv=\"refresh\" content=\"$delay; URL=$value\">";
 166                 if (! $safe) {
 167                         $redir=scrub($redir);
 168                 }
 169                 push @{$metaheaders{$page}}, $redir;
 170         }
 171         elsif ($key eq 'link') {
 172                 if (%params) {
 173                         push @{$metaheaders{$page}}, scrub("<link href=\"".encode_entities($value)."\" ".
 174                                 join(" ", map {
 175                                         encode_entities($_)."=\"".encode_entities(decode_entities($params{$_}))."\""
 176                                 } keys %params).
 177                                 " />\n");
 178                 }
 179         }
 180         else {
 181                 push @{$metaheaders{$page}}, scrub('<meta name="'.encode_entities($key).
 182                         '" content="'.encode_entities($value).'" />');
 183         }
 184
 185         return "";
 186 } # }}}
 187
 188 sub pagetemplate (@) { #{{{
 189         my %params=@_;
 190         my $page=$params{page};
 191         my $destpage=$params{destpage};
 192         my $template=$params{template};
 193
 194         if (exists $metaheaders{$page} && $template->query(name => "meta")) {
 195                 # avoid duplicate meta lines
 196                 my %seen;
 197                 $template->param(meta => join("\n", grep { (! $seen{$_}) && ($seen{$_}=1) } @{$metaheaders{$page}}));
 198         }
 199         if (exists $pagestate{$page}{meta}{title} && $template->query(name => "title")) {
 200                 $template->param(title => $pagestate{$page}{meta}{title});
 201                 $template->param(title_overridden => 1);
 202         }
 203
 204         foreach my $field (qw{author authorurl permalink}) {
 205                 $template->param($field => $pagestate{$page}{meta}{$field})
 206                         if exists $pagestate{$page}{meta}{$field} && $template->query(name => $field);
 207         }
 208
 209         foreach my $field (qw{license copyright}) {
 210                 if (exists $pagestate{$page}{meta}{$field} && $template->query(name => $field) &&
 211                     ($page eq $destpage || ! exists $pagestate{$destpage}{meta}{$field} ||
 212                      $pagestate{$page}{meta}{$field} ne $pagestate{$destpage}{meta}{$field})) {
 213                         $template->param($field => htmlize($page, $destpage, $pagestate{$page}{meta}{$field}));
 214                 }
 215         }
 216 } # }}}
 217
 218 sub match { #{{{
 219         my $field=shift;
 220         my $page=shift;
 221
 222         # turn glob into a safe regexp
 223         my $re=quotemeta(shift);
 224         $re=~s/\\\*/.*/g;
 225         $re=~s/\\\?/./g;
 226
 227         my $val;
 228         if (exists $pagestate{$page}{meta}{$field}) {
 229                 $val=$pagestate{$page}{meta}{$field};
 230         }
 231         elsif ($field eq 'title') {
 232                 $val=pagetitle($page);
 233         }
 234
 235         if (defined $val) {
 236                 if ($val=~/^$re$/i) {
 237                         return IkiWiki::SuccessReason->new("$re matches $field of $page");
 238                 }
 239                 else {
 240                         return IkiWiki::FailReason->new("$re does not match $field of $page");
 241                 }
 242         }
 243         else {
 244                 return IkiWiki::FailReason->new("$page does not have a $field");
 245         }
 246 } #}}}
 247
 248 package IkiWiki::PageSpec;
 249
 250 sub match_title ($$;@) { #{{{
 251         IkiWiki::Plugin::meta::match("title", @_);
 252 } #}}}
 253
 254 sub match_author ($$;@) { #{{{
 255         IkiWiki::Plugin::meta::match("author", @_);
 256 } #}}}
 257
 258 sub match_authorurl ($$;@) { #{{{
 259         IkiWiki::Plugin::meta::match("authorurl", @_);
 260 } #}}}
 261
 262 sub match_license ($$;@) { #{{{
 263         IkiWiki::Plugin::meta::match("license", @_);
 264 } #}}}
 265
 266 sub match_copyright ($$;@) { #{{{
 267         IkiWiki::Plugin::meta::match("copyright", @_);
 268 } #}}}
 269
 270 1