git.oblomov.eu Git - ikiwiki/blob - IkiWiki/CGI.pm

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5 use IkiWiki;
   6 use IkiWiki::UserInfo;
   7 use open qw{:utf8 :std};
   8 use Encode;
   9
  10 package IkiWiki;
  11
  12 sub printheader ($) { #{{{
  13         my $session=shift;
  14
  15         if ($config{sslcookie}) {
  16                 print $session->header(-charset => 'utf-8',
  17                         -cookie => $session->cookie(-secure => 1));
  18         } else {
  19                 print $session->header(-charset => 'utf-8');
  20         }
  21
  22 } #}}}
  23
  24 sub showform ($$$$;@) { #{{{
  25         my $form=shift;
  26         my $buttons=shift;
  27         my $session=shift;
  28         my $cgi=shift;
  29
  30         if (exists $hooks{formbuilder}) {
  31                 run_hooks(formbuilder => sub {
  32                         shift->(form => $form, cgi => $cgi, session => $session,
  33                                 buttons => $buttons);
  34                 });
  35         }
  36
  37         printheader($session);
  38         print misctemplate($form->title, $form->render(submit => $buttons), @_);
  39 }
  40
  41 sub redirect ($$) { #{{{
  42         my $q=shift;
  43         my $url=shift;
  44         if (! $config{w3mmode}) {
  45                 print $q->redirect($url);
  46         }
  47         else {
  48                 print "Content-type: text/plain\n";
  49                 print "W3m-control: GOTO $url\n\n";
  50         }
  51 } #}}}
  52
  53 sub check_canedit ($$$;$) { #{{{
  54         my $page=shift;
  55         my $q=shift;
  56         my $session=shift;
  57         my $nonfatal=shift;
  58
  59         my $canedit;
  60         run_hooks(canedit => sub {
  61                 return if defined $canedit;
  62                 my $ret=shift->($page, $q, $session);
  63                 if (defined $ret) {
  64                         if ($ret eq "") {
  65                                 $canedit=1;
  66                         }
  67                         elsif (ref $ret eq 'CODE') {
  68                                 $ret->() unless $nonfatal;
  69                                 $canedit=0;
  70                         }
  71                         elsif (defined $ret) {
  72                                 error($ret) unless $nonfatal;
  73                                 $canedit=0;
  74                         }
  75                 }
  76         });
  77         return $canedit;
  78 } #}}}
  79
  80 sub decode_cgi_utf8 ($) { #{{{
  81         # decode_form_utf8 method is needed for 5.10
  82         if ($] < 5.01) {
  83                 my $cgi = shift;
  84                 foreach my $f ($cgi->param) {
  85                         $cgi->param($f, map { decode_utf8 $_ } $cgi->param($f));
  86                 }
  87         }
  88 } #}}}
  89
  90 sub decode_form_utf8 ($) { #{{{
  91         if ($] >= 5.01) {
  92                 my $form = shift;
  93                 foreach my $f ($form->field) {
  94                         $form->field(name  => $f,
  95                                      value => decode_utf8($form->field($f)),
  96                                      force => 1,
  97                         );
  98                 }
  99         }
 100 } #}}}
 101
 102 # Check if the user is signed in. If not, redirect to the signin form and
 103 # save their place to return to later.
 104 sub needsignin ($$) { #{{{
 105         my $q=shift;
 106         my $session=shift;
 107
 108         if (! defined $session->param("name") ||
 109             ! userinfo_get($session->param("name"), "regdate")) {
 110                 $session->param(postsignin => $ENV{QUERY_STRING});
 111                 cgi_signin($q, $session);
 112                 cgi_savesession($session);
 113                 exit;
 114         }
 115 } #}}}
 116
 117 sub cgi_signin ($$) { #{{{
 118         my $q=shift;
 119         my $session=shift;
 120
 121         decode_cgi_utf8($q);
 122         eval q{use CGI::FormBuilder};
 123         error($@) if $@;
 124         my $form = CGI::FormBuilder->new(
 125                 title => "signin",
 126                 name => "signin",
 127                 charset => "utf-8",
 128                 method => 'POST',
 129                 required => 'NONE',
 130                 javascript => 0,
 131                 params => $q,
 132                 action => $config{cgiurl},
 133                 header => 0,
 134                 template => {type => 'div'},
 135                 stylesheet => baseurl()."style.css",
 136         );
 137         my $buttons=["Login"];
 138
 139         if ($q->param("do") ne "signin" && !$form->submitted) {
 140                 $form->text(gettext("You need to log in first."));
 141         }
 142         $form->field(name => "do", type => "hidden", value => "signin",
 143                 force => 1);
 144
 145         decode_form_utf8($form);
 146         run_hooks(formbuilder_setup => sub {
 147                 shift->(form => $form, cgi => $q, session => $session,
 148                         buttons => $buttons);
 149         });
 150         decode_form_utf8($form);
 151
 152         if ($form->submitted) {
 153                 $form->validate;
 154         }
 155
 156         showform($form, $buttons, $session, $q);
 157 } #}}}
 158
 159 sub cgi_postsignin ($$) { #{{{
 160         my $q=shift;
 161         my $session=shift;
 162
 163         # Continue with whatever was being done before the signin process.
 164         if (defined $session->param("postsignin")) {
 165                 my $postsignin=CGI->new($session->param("postsignin"));
 166                 $session->clear("postsignin");
 167                 cgi($postsignin, $session);
 168                 cgi_savesession($session);
 169                 exit;
 170         }
 171         else {
 172                 error(gettext("login failed, perhaps you need to turn on cookies?"));
 173         }
 174 } #}}}
 175
 176 sub cgi_prefs ($$) { #{{{
 177         my $q=shift;
 178         my $session=shift;
 179
 180         needsignin($q, $session);
 181         decode_cgi_utf8($q);
 182
 183         # The session id is stored on the form and checked to
 184         # guard against CSRF.
 185         my $sid=$q->param('sid');
 186         if (! defined $sid) {
 187                 $q->delete_all;
 188         }
 189         elsif ($sid ne $session->id) {
 190                 error(gettext("Your login session has expired."));
 191         }
 192
 193         eval q{use CGI::FormBuilder};
 194         error($@) if $@;
 195         my $form = CGI::FormBuilder->new(
 196                 title => "preferences",
 197                 name => "preferences",
 198                 header => 0,
 199                 charset => "utf-8",
 200                 method => 'POST',
 201                 validate => {
 202                         email => 'EMAIL',
 203                 },
 204                 required => 'NONE',
 205                 javascript => 0,
 206                 params => $q,
 207                 action => $config{cgiurl},
 208                 template => {type => 'div'},
 209                 stylesheet => baseurl()."style.css",
 210                 fieldsets => [
 211                         [login => gettext("Login")],
 212                         [preferences => gettext("Preferences")],
 213                         [admin => gettext("Admin")]
 214                 ],
 215         );
 216         my $buttons=["Save Preferences", "Logout", "Cancel"];
 217
 218         decode_form_utf8($form);
 219         run_hooks(formbuilder_setup => sub {
 220                 shift->(form => $form, cgi => $q, session => $session,
 221                         buttons => $buttons);
 222         });
 223         decode_form_utf8($form);
 224
 225         $form->field(name => "do", type => "hidden", value => "prefs",
 226                 force => 1);
 227         $form->field(name => "sid", type => "hidden", value => $session->id,
 228                 force => 1);
 229         $form->field(name => "email", size => 50, fieldset => "preferences");
 230         $form->field(name => "banned_users", size => 50,
 231                 fieldset => "admin");
 232
 233         my $user_name=$session->param("name");
 234         if (! is_admin($user_name)) {
 235                 $form->field(name => "banned_users", type => "hidden");
 236         }
 237
 238         if (! $form->submitted) {
 239                 $form->field(name => "email", force => 1,
 240                         value => userinfo_get($user_name, "email"));
 241                 if (is_admin($user_name)) {
 242                         $form->field(name => "banned_users", force => 1,
 243                                 value => join(" ", get_banned_users()));
 244                 }
 245         }
 246
 247         if ($form->submitted eq 'Logout') {
 248                 $session->delete();
 249                 redirect($q, $config{url});
 250                 return;
 251         }
 252         elsif ($form->submitted eq 'Cancel') {
 253                 redirect($q, $config{url});
 254                 return;
 255         }
 256         elsif ($form->submitted eq 'Save Preferences' && $form->validate) {
 257                 if (defined $form->field('email')) {
 258                         userinfo_set($user_name, 'email', $form->field('email')) ||
 259                                 error("failed to set email");
 260                 }
 261                 if (is_admin($user_name)) {
 262                         set_banned_users(grep { ! is_admin($_) }
 263                                         split(' ',
 264                                                 $form->field("banned_users"))) ||
 265                                 error("failed saving changes");
 266                 }
 267                 $form->text(gettext("Preferences saved."));
 268         }
 269
 270         showform($form, $buttons, $session, $q);
 271 } #}}}
 272
 273 sub cgi_editpage ($$) { #{{{
 274         my $q=shift;
 275         my $session=shift;
 276
 277         decode_cgi_utf8($q);
 278
 279         my @fields=qw(do rcsinfo subpage from page type editcontent comments);
 280         my @buttons=("Save Page", "Preview", "Cancel");
 281         eval q{use CGI::FormBuilder};
 282         error($@) if $@;
 283         my $form = CGI::FormBuilder->new(
 284                 title => "editpage",
 285                 fields => \@fields,
 286                 charset => "utf-8",
 287                 method => 'POST',
 288                 required => [qw{editcontent}],
 289                 javascript => 0,
 290                 params => $q,
 291                 action => $config{cgiurl},
 292                 header => 0,
 293                 table => 0,
 294                 template => scalar template_params("editpage.tmpl"),
 295                 wikiname => $config{wikiname},
 296         );
 297
 298         decode_form_utf8($form);
 299         run_hooks(formbuilder_setup => sub {
 300                 shift->(form => $form, cgi => $q, session => $session,
 301                         buttons => \@buttons);
 302         });
 303         decode_form_utf8($form);
 304
 305         # This untaint is safe because titlepage removes any problematic
 306         # characters.
 307         my ($page)=$form->field('page');
 308         $page=titlepage(possibly_foolish_untaint($page));
 309         if (! defined $page || ! length $page ||
 310             file_pruned($page, $config{srcdir}) || $page=~/^\//) {
 311                 error("bad page name");
 312         }
 313
 314         my $baseurl=$config{url}."/".htmlpage($page);
 315
 316         my $from;
 317         if (defined $form->field('from')) {
 318                 ($from)=$form->field('from')=~/$config{wiki_file_regexp}/;
 319         }
 320
 321         my $file;
 322         my $type;
 323         if (exists $pagesources{$page} && $form->field("do") ne "create") {
 324                 $file=$pagesources{$page};
 325                 $type=pagetype($file);
 326                 if (! defined $type || $type=~/^_/) {
 327                         error(sprintf(gettext("%s is not an editable page"), $page));
 328                 }
 329                 if (! $form->submitted) {
 330                         $form->field(name => "rcsinfo",
 331                                 value => rcs_prepedit($file), force => 1);
 332                 }
 333                 $form->field(name => "editcontent", validate => '/.*/');
 334         }
 335         else {
 336                 $type=$form->param('type');
 337                 if (defined $type && length $type && $hooks{htmlize}{$type}) {
 338                         $type=possibly_foolish_untaint($type);
 339                 }
 340                 elsif (defined $from && exists $pagesources{$from}) {
 341                         # favor the type of linking page
 342                         $type=pagetype($pagesources{$from});
 343                 }
 344                 $type=$config{default_pageext} unless defined $type;
 345                 $file=$page.".".$type;
 346                 if (! $form->submitted) {
 347                         $form->field(name => "rcsinfo", value => "", force => 1);
 348                 }
 349                 $form->field(name => "editcontent", validate => '/.+/');
 350         }
 351
 352         $form->field(name => "do", type => 'hidden');
 353         $form->field(name => "sid", type => "hidden", value => $session->id,
 354                 force => 1);
 355         $form->field(name => "from", type => 'hidden');
 356         $form->field(name => "rcsinfo", type => 'hidden');
 357         $form->field(name => "subpage", type => 'hidden');
 358         $form->field(name => "page", value => pagetitle($page, 1), force => 1);
 359         $form->field(name => "type", value => $type, force => 1);
 360         $form->field(name => "comments", type => "text", size => 80);
 361         $form->field(name => "editcontent", type => "textarea", rows => 20,
 362                 cols => 80);
 363         $form->tmpl_param("can_commit", $config{rcs});
 364         $form->tmpl_param("indexlink", indexlink());
 365         $form->tmpl_param("helponformattinglink",
 366                 htmllink($page, $page, "ikiwiki/formatting",
 367                         noimageinline => 1,
 368                         linktext => "FormattingHelp"));
 369
 370         if ($form->submitted eq "Cancel") {
 371                 if ($form->field("do") eq "create" && defined $from) {
 372                         redirect($q, "$config{url}/".htmlpage($from));
 373                 }
 374                 elsif ($form->field("do") eq "create") {
 375                         redirect($q, $config{url});
 376                 }
 377                 else {
 378                         redirect($q, "$config{url}/".htmlpage($page));
 379                 }
 380                 return;
 381         }
 382         elsif ($form->submitted eq "Preview") {
 383                 my $new=not exists $pagesources{$page};
 384                 if ($new) {
 385                         # temporarily record its type
 386                         $pagesources{$page}=$page.".".$type;
 387                 }
 388
 389                 my $content=$form->field('editcontent');
 390
 391                 run_hooks(editcontent => sub {
 392                         $content=shift->(
 393                                 content => $content,
 394                                 page => $page,
 395                                 cgi => $q,
 396                                 session => $session,
 397                         );
 398                 });
 399                 $form->tmpl_param("page_preview",
 400                         htmlize($page, $type,
 401                         linkify($page, $page,
 402                         preprocess($page, $page,
 403                         filter($page, $page, $content), 0, 1))));
 404
 405                 if ($new) {
 406                         delete $pagesources{$page};
 407                 }
 408                 # previewing may have created files on disk
 409                 saveindex();
 410         }
 411         elsif ($form->submitted eq "Save Page") {
 412                 $form->tmpl_param("page_preview", "");
 413         }
 414         $form->tmpl_param("page_conflict", "");
 415
 416         if ($form->submitted ne "Save Page" || ! $form->validate) {
 417                 if ($form->field("do") eq "create") {
 418                         my @page_locs;
 419                         my $best_loc;
 420                         if (! defined $from || ! length $from ||
 421                             $from ne $form->field('from') ||
 422                             file_pruned($from, $config{srcdir}) ||
 423                             $from=~/^\// ||
 424                             $form->submitted eq "Preview") {
 425                                 @page_locs=$best_loc=$page;
 426                         }
 427                         else {
 428                                 my $dir=$from."/";
 429                                 $dir=~s![^/]+/+$!!;
 430
 431                                 if ((defined $form->field('subpage') && length $form->field('subpage')) ||
 432                                     $page eq gettext('discussion')) {
 433                                         $best_loc="$from/$page";
 434                                 }
 435                                 else {
 436                                         $best_loc=$dir.$page;
 437                                 }
 438
 439                                 push @page_locs, $dir.$page;
 440                                 push @page_locs, "$from/$page";
 441                                 while (length $dir) {
 442                                         $dir=~s![^/]+/+$!!;
 443                                         push @page_locs, $dir.$page;
 444                                 }
 445
 446                                 push @page_locs, "$config{userdir}/$page"
 447                                         if length $config{userdir};
 448                         }
 449
 450                         @page_locs = grep {
 451                                 ! exists $pagecase{lc $_}
 452                         } @page_locs;
 453                         if (! @page_locs) {
 454                                 # hmm, someone else made the page in the
 455                                 # meantime?
 456                                 if ($form->submitted eq "Preview") {
 457                                         # let them go ahead with the edit
 458                                         # and resolve the conflict at save
 459                                         # time
 460                                         @page_locs=$page;
 461                                 }
 462                                 else {
 463                                         redirect($q, "$config{url}/".htmlpage($page));
 464                                         return;
 465                                 }
 466                         }
 467
 468                         my @editable_locs = grep {
 469                                 check_canedit($_, $q, $session, 1)
 470                         } @page_locs;
 471                         if (! @editable_locs) {
 472                                 # let it throw an error this time
 473                                 map { check_canedit($_, $q, $session) } @page_locs;
 474                         }
 475
 476                         my @page_types;
 477                         if (exists $hooks{htmlize}) {
 478                                 @page_types=grep { !/^_/ }
 479                                         keys %{$hooks{htmlize}};
 480                         }
 481
 482                         $form->tmpl_param("page_select", 1);
 483                         $form->field(name => "page", type => 'select',
 484                                 options => [ map { pagetitle($_, 1) } @editable_locs ],
 485                                 value => pagetitle($best_loc, 1));
 486                         $form->field(name => "type", type => 'select',
 487                                 options => \@page_types);
 488                         $form->title(sprintf(gettext("creating %s"), pagetitle($page)));
 489
 490                 }
 491                 elsif ($form->field("do") eq "edit") {
 492                         check_canedit($page, $q, $session);
 493                         if (! defined $form->field('editcontent') ||
 494                             ! length $form->field('editcontent')) {
 495                                 my $content="";
 496                                 if (exists $pagesources{$page}) {
 497                                         $content=readfile(srcfile($pagesources{$page}));
 498                                         $content=~s/\n/\r\n/g;
 499                                 }
 500                                 $form->field(name => "editcontent", value => $content,
 501                                         force => 1);
 502                         }
 503                         $form->tmpl_param("page_select", 0);
 504                         $form->field(name => "page", type => 'hidden');
 505                         $form->field(name => "type", type => 'hidden');
 506                         $form->title(sprintf(gettext("editing %s"), pagetitle($page)));
 507                 }
 508
 509                 showform($form, \@buttons, $session, $q, forcebaseurl => $baseurl);
 510         }
 511         else {
 512                 # save page
 513                 check_canedit($page, $q, $session);
 514
 515                 # The session id is stored on the form and checked to
 516                 # guard against CSRF. But only if the user is logged in,
 517                 # as anonok can allow anonymous edits.
 518                 if (defined $session->param("name")) {
 519                         my $sid=$q->param('sid');
 520                         if (! defined $sid || $sid ne $session->id) {
 521                                 error(gettext("Your login session has expired."));
 522                         }
 523                 }
 524
 525                 my $exists=-e "$config{srcdir}/$file";
 526
 527                 if ($form->field("do") ne "create" && ! $exists &&
 528                     ! defined srcfile($file, 1)) {
 529                         $form->tmpl_param("page_gone", 1);
 530                         $form->field(name => "do", value => "create", force => 1);
 531                         $form->tmpl_param("page_select", 0);
 532                         $form->field(name => "page", type => 'hidden');
 533                         $form->field(name => "type", type => 'hidden');
 534                         $form->title(sprintf(gettext("editing %s"), $page));
 535                         showform($form, \@buttons, $session, $q, forcebaseurl => $baseurl);
 536                         return;
 537                 }
 538                 elsif ($form->field("do") eq "create" && $exists) {
 539                         $form->tmpl_param("creation_conflict", 1);
 540                         $form->field(name => "do", value => "edit", force => 1);
 541                         $form->tmpl_param("page_select", 0);
 542                         $form->field(name => "page", type => 'hidden');
 543                         $form->field(name => "type", type => 'hidden');
 544                         $form->title(sprintf(gettext("editing %s"), $page));
 545                         $form->field("editcontent",
 546                                 value => readfile("$config{srcdir}/$file").
 547                                          "\n\n\n".$form->field("editcontent"),
 548                                 force => 1);
 549                         showform($form, \@buttons, $session, $q, forcebaseurl => $baseurl);
 550                         return;
 551                 }
 552
 553                 my $content=$form->field('editcontent');
 554                 run_hooks(editcontent => sub {
 555                         $content=shift->(
 556                                 content => $content,
 557                                 page => $page,
 558                                 cgi => $q,
 559                                 session => $session,
 560                         );
 561                 });
 562                 $content=~s/\r\n/\n/g;
 563                 $content=~s/\r/\n/g;
 564                 $content.="\n" if $content !~ /\n$/;
 565
 566                 $config{cgi}=0; # avoid cgi error message
 567                 eval { writefile($file, $config{srcdir}, $content) };
 568                 $config{cgi}=1;
 569                 if ($@) {
 570                         $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 571                                 force => 1);
 572                         $form->tmpl_param("failed_save", 1);
 573                         $form->tmpl_param("error_message", $@);
 574                         $form->field("editcontent", value => $content, force => 1);
 575                         $form->tmpl_param("page_select", 0);
 576                         $form->field(name => "page", type => 'hidden');
 577                         $form->field(name => "type", type => 'hidden');
 578                         $form->title(sprintf(gettext("editing %s"), $page));
 579                         showform($form, \@buttons, $session, $q,
 580                                 forcebaseurl => $baseurl);
 581                         return;
 582                 }
 583
 584                 my $conflict;
 585                 if ($config{rcs}) {
 586                         my $message="";
 587                         if (defined $form->field('comments') &&
 588                             length $form->field('comments')) {
 589                                 $message=$form->field('comments');
 590                         }
 591
 592                         if (! $exists) {
 593                                 rcs_add($file);
 594                         }
 595
 596                         # Prevent deadlock with post-commit hook by
 597                         # signaling to it that it should not try to
 598                         # do anything.
 599                         disable_commit_hook();
 600                         $conflict=rcs_commit($file, $message,
 601                                 $form->field("rcsinfo"),
 602                                 $session->param("name"), $ENV{REMOTE_ADDR});
 603                         enable_commit_hook();
 604                         rcs_update();
 605                 }
 606
 607                 # Refresh even if there was a conflict, since other changes
 608                 # may have been committed while the post-commit hook was
 609                 # disabled.
 610                 require IkiWiki::Render;
 611                 refresh();
 612                 saveindex();
 613
 614                 if (defined $conflict) {
 615                         $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 616                                 force => 1);
 617                         $form->tmpl_param("page_conflict", 1);
 618                         $form->field("editcontent", value => $conflict, force => 1);
 619                         $form->field("do", "edit", force => 1);
 620                         $form->tmpl_param("page_select", 0);
 621                         $form->field(name => "page", type => 'hidden');
 622                         $form->field(name => "type", type => 'hidden');
 623                         $form->title(sprintf(gettext("editing %s"), $page));
 624                         showform($form, \@buttons, $session, $q,
 625                                 forcebaseurl => $baseurl);
 626                         return;
 627                 }
 628                 else {
 629                         # The trailing question mark tries to avoid broken
 630                         # caches and get the most recent version of the page.
 631                         redirect($q, "$config{url}/".htmlpage($page)."?updated");
 632                 }
 633         }
 634 } #}}}
 635
 636 sub cgi_getsession ($) { #{{{
 637         my $q=shift;
 638
 639         eval q{use CGI::Session};
 640         error($@) if $@;
 641         CGI::Session->name("ikiwiki_session_".encode_utf8($config{wikiname}));
 642
 643         my $oldmask=umask(077);
 644         my $session = CGI::Session->new("driver:DB_File", $q,
 645                 { FileName => "$config{wikistatedir}/sessions.db" });
 646         umask($oldmask);
 647
 648         return $session;
 649 } #}}}
 650
 651 sub cgi_savesession ($) { #{{{
 652         my $session=shift;
 653
 654         # Force session flush with safe umask.
 655         my $oldmask=umask(077);
 656         $session->flush;
 657         umask($oldmask);
 658 } #}}}
 659
 660 sub cgi (;$$) { #{{{
 661         my $q=shift;
 662         my $session=shift;
 663
 664         if (! $q) {
 665                 eval q{use CGI};
 666                 error($@) if $@;
 667
 668                 binmode(STDIN);
 669                 $q=CGI->new;
 670                 binmode(STDIN, ":utf8");
 671
 672                 run_hooks(cgi => sub { shift->($q) });
 673         }
 674
 675         my $do=$q->param('do');
 676         if (! defined $do || ! length $do) {
 677                 my $error = $q->cgi_error;
 678                 if ($error) {
 679                         error("Request not processed: $error");
 680                 }
 681                 else {
 682                         error("\"do\" parameter missing");
 683                 }
 684         }
 685
 686         # Need to lock the wiki before getting a session.
 687         lockwiki();
 688         loadindex();
 689
 690         if (! $session) {
 691                 $session=cgi_getsession($q);
 692         }
 693
 694         # Auth hooks can sign a user in.
 695         if ($do ne 'signin' && ! defined $session->param("name")) {
 696                 run_hooks(auth => sub {
 697                         shift->($q, $session)
 698                 });
 699                 if (defined $session->param("name")) {
 700                         # Make sure whatever user was authed is in the
 701                         # userinfo db.
 702                         if (! userinfo_get($session->param("name"), "regdate")) {
 703                                 userinfo_setall($session->param("name"), {
 704                                         email => "",
 705                                         password => "",
 706                                         regdate => time,
 707                                 }) || error("failed adding user");
 708                         }
 709                 }
 710         }
 711
 712         if (defined $session->param("name") &&
 713             userinfo_get($session->param("name"), "banned")) {
 714                 print $q->header(-status => "403 Forbidden");
 715                 $session->delete();
 716                 print gettext("You are banned.");
 717                 cgi_savesession($session);
 718         }
 719
 720         run_hooks(sessioncgi => sub { shift->($q, $session) });
 721
 722         if ($do eq 'signin') {
 723                 cgi_signin($q, $session);
 724                 cgi_savesession($session);
 725         }
 726         elsif ($do eq 'prefs') {
 727                 cgi_prefs($q, $session);
 728         }
 729         elsif ($do eq 'create' || $do eq 'edit') {
 730                 cgi_editpage($q, $session);
 731         }
 732         elsif (defined $session->param("postsignin") || $do eq 'postsignin') {
 733                 cgi_postsignin($q, $session);
 734         }
 735         else {
 736                 error("unknown do parameter");
 737         }
 738 } #}}}
 739
 740 1