git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/aggregate.pm

   1 #!/usr/bin/perl
   2 # Blog aggregation plugin.
   3 package IkiWiki::Plugin::aggregate;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki;
   8 use HTML::Entities;
   9
  10 my %feeds;
  11 my %guids;
  12
  13 sub import { #{{{
  14         IkiWiki::hook(type => "getopt", id => "aggregate",
  15                 call => \&getopt);
  16         IkiWiki::hook(type => "checkconfig", id => "aggregate",
  17                 call => \&checkconfig);
  18         IkiWiki::hook(type => "filter", id => "aggregate",
  19                 call => \&filter);
  20         IkiWiki::hook(type => "preprocess", id => "aggregate",
  21                 call => \&preprocess);
  22         IkiWiki::hook(type => "delete", id => "aggregate",
  23                 call => \&delete);
  24         IkiWiki::hook(type => "savestate", id => "aggregate",
  25                 call => \&savestate);
  26 } # }}}
  27
  28 sub getopt () { #{{{
  29         eval q{use Getopt::Long};
  30         Getopt::Long::Configure('pass_through');
  31         GetOptions("aggregate" => \$IkiWiki::config{aggregate});
  32 } #}}}
  33
  34 sub checkconfig () { #{{{
  35         loadstate();
  36         if ($IkiWiki::config{aggregate}) {
  37                 IkiWiki::loadindex();
  38                 aggregate();
  39                 savestate();
  40         }
  41 } #}}}
  42
  43 sub filter (@) { #{{{
  44         my %params=@_;
  45         my $page=$params{page};
  46
  47         # Mark all feeds originating on this page as removable;
  48         # preprocess will unmark those that still exist.
  49         remove_feeds($page);
  50
  51         return $params{content};
  52 } # }}}
  53
  54 sub preprocess (@) { #{{{
  55         my %params=@_;
  56
  57         foreach my $required (qw{name url}) {
  58                 if (! exists $params{$required}) {
  59                         return "[[aggregate plugin missing $required parameter]]";
  60                 }
  61         }
  62
  63         my $feed={};
  64         my $name=$params{name};
  65         if (exists $feeds{$name}) {
  66                 $feed=$feeds{$name};
  67         }
  68         else {
  69                 $feeds{$name}=$feed;
  70         }
  71         $feed->{name}=$name;
  72         $feed->{sourcepage}=$params{page};
  73         $feed->{url}=$params{url};
  74         my $dir=exists $params{dir} ? $params{dir} : $params{page}."/".IkiWiki::titlepage($params{name});
  75         $dir=~s/^\/+//;
  76         ($dir)=$dir=~/$IkiWiki::config{wiki_file_regexp}/;
  77         $feed->{dir}=$dir;
  78         $feed->{feedurl}=defined $params{feedurl} ? $params{feedurl} : "";
  79         $feed->{updateinterval}=defined $params{updateinterval} ? $params{updateinterval} * 60 : 15 * 60;
  80         $feed->{expireage}=defined $params{expireage} ? $params{expireage} : 0;
  81         $feed->{expirecount}=defined $params{expirecount} ? $params{expirecount} : 0;
  82         delete $feed->{remove};
  83         $feed->{lastupdate}=0 unless defined $feed->{lastupdate};
  84         $feed->{numposts}=0 unless defined $feed->{numposts};
  85         $feed->{newposts}=0 unless defined $feed->{newposts};
  86         $feed->{message}="new feed" unless defined $feed->{message};
  87         $feed->{tags}=[];
  88         while (@_) {
  89                 my $key=shift;
  90                 my $value=shift;
  91                 if ($key eq 'tag') {
  92                         push @{$feed->{tags}}, $value;
  93                 }
  94         }
  95
  96         return "<a href=\"".$feed->{url}."\">".$feed->{name}."</a>: ".
  97                "<i>".$feed->{message}."</i> (".$feed->{numposts}.
  98                " stored posts; ".$feed->{newposts}." new)<br />";
  99 } # }}}
 100
 101 sub delete (@) { #{{{
 102         my @files=@_;
 103
 104         # Remove feed data for removed pages.
 105         foreach my $file (@files) {
 106                 my $page=IkiWiki::pagename($file);
 107                 remove_feeds($page);
 108         }
 109 } #}}}
 110
 111 sub loadstate () { #{{{
 112         if (-e "$IkiWiki::config{wikistatedir}/aggregate") {
 113                 open (IN, "$IkiWiki::config{wikistatedir}/aggregate" ||
 114                         die "$IkiWiki::config{wikistatedir}/aggregate: $!");
 115                 while (<IN>) {
 116                         $_=IkiWiki::possibly_foolish_untaint($_);
 117                         chomp;
 118                         my $data={};
 119                         foreach my $i (split(/ /, $_)) {
 120                                 my ($field, $val)=split(/=/, $i, 2);
 121                                 if ($field eq "name" || $field eq "feed" ||
 122                                     $field eq "guid" || $field eq "message") {
 123                                         $data->{$field}=decode_entities($val, " \t\n");
 124                                 }
 125                                 elsif ($field eq "tag") {
 126                                         push @{$data->{tags}}, $val;
 127                                 }
 128                                 else {
 129                                         $data->{$field}=$val;
 130                                 }
 131                         }
 132
 133                         if (exists $data->{name}) {
 134                                 $feeds{$data->{name}}=$data;
 135                         }
 136                         elsif (exists $data->{guid}) {
 137                                 $guids{$data->{guid}}=$data;
 138                         }
 139                 }
 140
 141                 close IN;
 142         }
 143 } #}}}
 144
 145 sub savestate () { #{{{
 146         eval q{use HTML::Entities};
 147         die $@ if $@;
 148         open (OUT, ">$IkiWiki::config{wikistatedir}/aggregate" ||
 149                 die "$IkiWiki::config{wikistatedir}/aggregate: $!");
 150         foreach my $data (values %feeds, values %guids) {
 151                 if ($data->{remove}) {
 152                         if ($data->{name}) {
 153                                 foreach my $guid (values %guids) {
 154                                         if ($guid->{feed} eq $data->{name}) {
 155                                                 $guid->{remove}=1;
 156                                         }
 157                                 }
 158                         }
 159                         else {
 160                                 unlink pagefile($data->{page});
 161                         }
 162                         next;
 163                 }
 164
 165                 my @line;
 166                 foreach my $field (keys %$data) {
 167                         if ($field eq "name" || $field eq "feed" ||
 168                             $field eq "guid" || $field eq "message") {
 169                                 push @line, "$field=".encode_entities($data->{$field}, " \t\n");
 170                         }
 171                         elsif ($field eq "tags") {
 172                                 push @line, "tag=$_" foreach @{$data->{tags}};
 173                         }
 174                         else {
 175                                 push @line, "$field=".$data->{$field};
 176                         }
 177                 }
 178                 print OUT join(" ", @line)."\n";
 179         }
 180         close OUT;
 181 } #}}}
 182
 183 sub aggregate () { #{{{
 184         eval q{use XML::Feed};
 185         die $@ if $@;
 186         eval q{use HTML::Entities};
 187         die $@ if $@;
 188
 189         foreach my $feed (values %feeds) {
 190                 next unless $IkiWiki::config{rebuild} ||
 191                         time - $feed->{lastupdate} >= $feed->{updateinterval};
 192                 $feed->{lastupdate}=time;
 193                 $feed->{newposts}=0;
 194                 $IkiWiki::forcerebuild{$feed->{sourcepage}}=1;
 195
 196                 IkiWiki::debug("checking feed ".$feed->{name}." ...");
 197
 198                 if (! length $feed->{feedurl}) {
 199                         my @urls=XML::Feed->find_feeds($feed->{url});
 200                         if (! @urls) {
 201                                 $feed->{message}="could not find feed at ".$feed->{feedurl};
 202                                 IkiWiki::debug($feed->{message});
 203                                 next;
 204                         }
 205                         $feed->{feedurl}=pop @urls;
 206                 }
 207                 my $f=eval{XML::Feed->parse(URI->new($feed->{feedurl}))};
 208                 if ($@) {
 209                         $feed->{message}="feed crashed XML::Feed! $@";
 210                         IkiWiki::debug($feed->{message});
 211                         next;
 212                 }
 213                 if (! $f) {
 214                         $feed->{message}=XML::Feed->errstr;
 215                         IkiWiki::debug($feed->{message});
 216                         next;
 217                 }
 218
 219                 foreach my $entry ($f->entries) {
 220                         add_page(
 221                                 feed => $feed,
 222                                 title => defined $entry->title ? decode_entities($entry->title) : "untitled",
 223                                 link => $entry->link,
 224                                 content => $entry->content->body,
 225                                 guid => defined $entry->id ? $entry->id : time."_".$feed->name,
 226                                 ctime => $entry->issued ? ($entry->issued->epoch || time) : time,
 227                         );
 228                 }
 229
 230                 $feed->{message}="processed ok";
 231         }
 232
 233         # TODO: expiry
 234 } #}}}
 235
 236 sub add_page (@) { #{{{
 237         my %params=@_;
 238
 239         my $feed=$params{feed};
 240         my $guid={};
 241         my $mtime;
 242         if (exists $guids{$params{guid}}) {
 243                 # updating an existing post
 244                 $guid=$guids{$params{guid}};
 245         }
 246         else {
 247                 # new post
 248                 $guid->{guid}=$params{guid};
 249                 $guids{$params{guid}}=$guid;
 250                 $mtime=$params{ctime};
 251                 $feed->{numposts}++;
 252                 $feed->{newposts}++;
 253
 254                 # assign it an unused page
 255                 my $page=IkiWiki::titlepage($params{title});
 256                 # escape slashes and periods in title so it doesn't specify
 257                 # directory name or trigger ".." disallowing code.
 258                 $page=~s!([/.])!"__".ord($1)."__"!eg;
 259                 $page=$feed->{dir}."/".$page;
 260                 $page=lc($page);
 261                 ($page)=$page=~/$IkiWiki::config{wiki_file_regexp}/;
 262                 if (! defined $page || ! length $page) {
 263                         $page=$feed->{dir}."/item";
 264                 }
 265                 my $c="";
 266                 while (exists $IkiWiki::pagesources{$page.$c} ||
 267                        -e pagefile($page.$c)) {
 268                         $c++
 269                 }
 270                 $guid->{page}=$page;
 271                 IkiWiki::debug("creating new page $page");
 272         }
 273         $guid->{feed}=$feed->{name};
 274
 275         # To write or not to write? Need to avoid writing unchanged pages
 276         # to avoid unneccessary rebuilding. The mtime from rss cannot be
 277         # trusted; let's use a digest.
 278         eval q{use Digest::MD5 'md5_hex'};
 279         require Encode;
 280         my $digest=md5_hex(Encode::encode_utf8($params{content}));
 281         return unless ! exists $guid->{md5} || $guid->{md5} ne $digest || $IkiWiki::config{rebuild};
 282         $guid->{md5}=$digest;
 283
 284         # Create the page.
 285         my $template=IkiWiki::template("aggregatepost.tmpl", blind_cache => 1);
 286         my $content=$params{content};
 287         $params{content}=~s/(?<!\\)\[\[/\\\[\[/g; # escape accidental wikilinks
 288                                                   # and preprocessor stuff
 289         $template->param(title => $params{title})
 290                 if defined $params{title} && length($params{title});
 291         $template->param(content => $params{content});
 292         $template->param(url => $feed->{url});
 293         $template->param(name => $feed->{name});
 294         $template->param(link => $params{link}) if defined $params{link};
 295         if (ref $feed->{tags}) {
 296                 $template->param(tags => [map { tag => $_ }, @{$feed->{tags}}]);
 297         }
 298         IkiWiki::writefile($guid->{page}.".html", $IkiWiki::config{srcdir},
 299                 $template->output);
 300
 301         # Set the mtime, this lets the build process get the right creation
 302         # time on record for the new page.
 303         utime $mtime, $mtime, pagefile($guid->{page}) if defined $mtime;
 304 } #}}}
 305
 306 sub remove_feeds () { #{{{
 307         my $page=shift;
 308
 309         my %removed;
 310         foreach my $id (keys %feeds) {
 311                 if ($feeds{$id}->{sourcepage} eq $page) {
 312                         $feeds{$id}->{remove}=1;
 313                         $removed{$id}=1;
 314                 }
 315         }
 316 } #}}}
 317
 318 sub pagefile ($) { #{{{
 319         my $page=shift;
 320
 321         return "$IkiWiki::config{srcdir}/$page.html";
 322 } #}}}
 323
 324 1