git.oblomov.eu Git - ikiwiki/blob - IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4 use warnings;
   5 use strict;
   6 use Encode;
   7 use HTML::Entities;
   8 use open qw{:utf8 :std};
   9
  10 use vars qw{%config %links %oldlinks %oldpagemtime %pagectime %pagecase
  11             %renderedfiles %oldrenderedfiles %pagesources %depends %hooks
  12             %forcerebuild};
  13
  14 use Exporter q{import};
  15 our @EXPORT = qw(hook debug error template htmlpage add_depends pagespec_match
  16                  bestlink htmllink readfile writefile pagetype srcfile pagename
  17                  displaytime will_render
  18                  %config %links %renderedfiles %pagesources);
  19 our $VERSION = 1.01; # plugin interface version
  20
  21 # Optimisation.
  22 use Memoize;
  23 memoize("abs2rel");
  24 memoize("pagespec_translate");
  25 memoize("file_pruned");
  26
  27 my $installdir=''; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  28 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  29
  30 sub defaultconfig () { #{{{
  31         wiki_file_prune_regexps => [qr/\.\./, qr/^\./, qr/\/\./, qr/\.x?html?$/,
  32                 qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//],
  33         wiki_link_regexp => qr/\[\[(?:([^\]\|]+)\|)?([^\s\]]+)\]\]/,
  34         wiki_file_regexp => qr/(^[-[:alnum:]_.:\/+]+$)/,
  35         web_commit_regexp => qr/^web commit (by (.*?(?=: |$))|from (\d+\.\d+\.\d+\.\d+)):?(.*)/,
  36         verbose => 0,
  37         syslog => 0,
  38         wikiname => "wiki",
  39         default_pageext => "mdwn",
  40         cgi => 0,
  41         rcs => '',
  42         notify => 0,
  43         url => '',
  44         cgiurl => '',
  45         historyurl => '',
  46         diffurl => '',
  47         anonok => 0,
  48         rss => 0,
  49         atom => 0,
  50         discussion => 1,
  51         rebuild => 0,
  52         refresh => 0,
  53         getctime => 0,
  54         w3mmode => 0,
  55         wrapper => undef,
  56         wrappermode => undef,
  57         svnrepo => undef,
  58         svnpath => "trunk",
  59         srcdir => undef,
  60         destdir => undef,
  61         pingurl => [],
  62         templatedir => "$installdir/share/ikiwiki/templates",
  63         underlaydir => "$installdir/share/ikiwiki/basewiki",
  64         setup => undef,
  65         adminuser => undef,
  66         adminemail => undef,
  67         plugin => [qw{mdwn inline htmlscrubber passwordauth}],
  68         timeformat => '%c',
  69         locale => undef,
  70         sslcookie => 0,
  71         httpauth => 0,
  72         userdir => "",
  73 } #}}}
  74
  75 sub checkconfig () { #{{{
  76         # locale stuff; avoid LC_ALL since it overrides everything
  77         if (defined $ENV{LC_ALL}) {
  78                 $ENV{LANG} = $ENV{LC_ALL};
  79                 delete $ENV{LC_ALL};
  80         }
  81         if (defined $config{locale}) {
  82                 eval q{use POSIX};
  83                 error($@) if $@;
  84                 $ENV{LANG} = $config{locale}
  85                         if POSIX::setlocale(&POSIX::LC_TIME, $config{locale});
  86         }
  87
  88         if ($config{w3mmode}) {
  89                 eval q{use Cwd q{abs_path}};
  90                 error($@) if $@;
  91                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
  92                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
  93                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
  94                         unless $config{cgiurl} =~ m!file:///!;
  95                 $config{url}="file://".$config{destdir};
  96         }
  97
  98         if ($config{cgi} && ! length $config{url}) {
  99                 error("Must specify url to wiki with --url when using --cgi\n");
 100         }
 101
 102         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 103                 unless exists $config{wikistatedir};
 104
 105         if ($config{rcs}) {
 106                 eval qq{require IkiWiki::Rcs::$config{rcs}};
 107                 if ($@) {
 108                         error("Failed to load RCS module IkiWiki::Rcs::$config{rcs}: $@");
 109                 }
 110         }
 111         else {
 112                 require IkiWiki::Rcs::Stub;
 113         }
 114
 115         run_hooks(checkconfig => sub { shift->() });
 116 } #}}}
 117
 118 sub loadplugins () { #{{{
 119         loadplugin($_) foreach @{$config{plugin}};
 120
 121         run_hooks(getopt => sub { shift->() });
 122         if (grep /^-/, @ARGV) {
 123                 print STDERR "Unknown option: $_\n"
 124                         foreach grep /^-/, @ARGV;
 125                 usage();
 126         }
 127 } #}}}
 128
 129 sub loadplugin ($) { #{{{
 130         my $plugin=shift;
 131
 132         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 133         eval qq{use $mod};
 134         if ($@) {
 135                 error("Failed to load plugin $mod: $@");
 136         }
 137 } #}}}
 138
 139 sub error ($) { #{{{
 140         if ($config{cgi}) {
 141                 print "Content-type: text/html\n\n";
 142                 print misctemplate("Error", "<p>Error: @_</p>");
 143         }
 144         log_message(error => @_);
 145         exit(1);
 146 } #}}}
 147
 148 sub debug ($) { #{{{
 149         return unless $config{verbose};
 150         log_message(debug => @_);
 151 } #}}}
 152
 153 my $log_open=0;
 154 sub log_message ($$) { #{{{
 155         my $type=shift;
 156
 157         if ($config{syslog}) {
 158                 require Sys::Syslog;
 159                 unless ($log_open) {
 160                         Sys::Syslog::setlogsock('unix');
 161                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 162                         $log_open=1;
 163                 }
 164                 eval {
 165                         Sys::Syslog::syslog($type, join(" ", @_));
 166                 }
 167         }
 168         elsif (! $config{cgi}) {
 169                 print "@_\n";
 170         }
 171         else {
 172                 print STDERR "@_\n";
 173         }
 174 } #}}}
 175
 176 sub possibly_foolish_untaint ($) { #{{{
 177         my $tainted=shift;
 178         my ($untainted)=$tainted=~/(.*)/;
 179         return $untainted;
 180 } #}}}
 181
 182 sub basename ($) { #{{{
 183         my $file=shift;
 184
 185         $file=~s!.*/+!!;
 186         return $file;
 187 } #}}}
 188
 189 sub dirname ($) { #{{{
 190         my $file=shift;
 191
 192         $file=~s!/*[^/]+$!!;
 193         return $file;
 194 } #}}}
 195
 196 sub pagetype ($) { #{{{
 197         my $page=shift;
 198
 199         if ($page =~ /\.([^.]+)$/) {
 200                 return $1 if exists $hooks{htmlize}{$1};
 201         }
 202         return undef;
 203 } #}}}
 204
 205 sub pagename ($) { #{{{
 206         my $file=shift;
 207
 208         my $type=pagetype($file);
 209         my $page=$file;
 210         $page=~s/\Q.$type\E*$// if defined $type;
 211         return $page;
 212 } #}}}
 213
 214 sub htmlpage ($) { #{{{
 215         my $page=shift;
 216
 217         return $page.".html";
 218 } #}}}
 219
 220 sub srcfile ($) { #{{{
 221         my $file=shift;
 222
 223         return "$config{srcdir}/$file" if -e "$config{srcdir}/$file";
 224         return "$config{underlaydir}/$file" if -e "$config{underlaydir}/$file";
 225         error("internal error: $file cannot be found");
 226 } #}}}
 227
 228 sub readfile ($;$) { #{{{
 229         my $file=shift;
 230         my $binary=shift;
 231
 232         if (-l $file) {
 233                 error("cannot read a symlink ($file)");
 234         }
 235
 236         local $/=undef;
 237         open (IN, $file) || error("failed to read $file: $!");
 238         binmode(IN) if ($binary);
 239         my $ret=<IN>;
 240         close IN;
 241         return $ret;
 242 } #}}}
 243
 244 sub writefile ($$$;$) { #{{{
 245         my $file=shift; # can include subdirs
 246         my $destdir=shift; # directory to put file in
 247         my $content=shift;
 248         my $binary=shift;
 249
 250         my $test=$file;
 251         while (length $test) {
 252                 if (-l "$destdir/$test") {
 253                         error("cannot write to a symlink ($test)");
 254                 }
 255                 $test=dirname($test);
 256         }
 257
 258         my $dir=dirname("$destdir/$file");
 259         if (! -d $dir) {
 260                 my $d="";
 261                 foreach my $s (split(m!/+!, $dir)) {
 262                         $d.="$s/";
 263                         if (! -d $d) {
 264                                 mkdir($d) || error("failed to create directory $d: $!");
 265                         }
 266                 }
 267         }
 268
 269         open (OUT, ">$destdir/$file") || error("failed to write $destdir/$file: $!");
 270         binmode(OUT) if ($binary);
 271         print OUT $content;
 272         close OUT;
 273 } #}}}
 274
 275 my %cleared;
 276 sub will_render ($$;$) { #{{{
 277         my $page=shift;
 278         my $dest=shift;
 279         my $clear=shift;
 280
 281         # Important security check.
 282         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
 283             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}})) {
 284                 error("$config{destdir}/$dest independently created, not overwriting with version from $page");
 285         }
 286
 287         if (! $clear || $cleared{$page}) {
 288                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
 289         }
 290         else {
 291                 $renderedfiles{$page}=[$dest];
 292                 $cleared{$page}=1;
 293         }
 294 } #}}}
 295
 296 sub bestlink ($$) { #{{{
 297         my $page=shift;
 298         my $link=shift;
 299
 300         my $cwd=$page;
 301         if ($link=~s/^\/+//) {
 302                 # absolute links
 303                 $cwd="";
 304         }
 305
 306         do {
 307                 my $l=$cwd;
 308                 $l.="/" if length $l;
 309                 $l.=$link;
 310
 311                 if (exists $links{$l}) {
 312                         return $l;
 313                 }
 314                 elsif (exists $pagecase{lc $l}) {
 315                         return $pagecase{lc $l};
 316                 }
 317         } while $cwd=~s!/?[^/]+$!!;
 318
 319         #print STDERR "warning: page $page, broken link: $link\n";
 320         return "";
 321 } #}}}
 322
 323 sub isinlinableimage ($) { #{{{
 324         my $file=shift;
 325
 326         $file=~/\.(png|gif|jpg|jpeg)$/i;
 327 } #}}}
 328
 329 sub pagetitle ($;$) { #{{{
 330         my $page=shift;
 331         my $unescaped=shift;
 332
 333         if ($unescaped) {
 334                 $page=~s/__(\d+)__/chr($1)/eg;
 335         }
 336         else {
 337                 $page=~s/__(\d+)__/&#$1;/g;
 338         }
 339         $page=~y/_/ /;
 340
 341         return $page;
 342 } #}}}
 343
 344 sub titlepage ($) { #{{{
 345         my $title=shift;
 346         $title=~y/ /_/;
 347         $title=~s/([^-[:alnum:]_:+\/.])/"__".ord($1)."__"/eg;
 348         return $title;
 349 } #}}}
 350
 351 sub cgiurl (@) { #{{{
 352         my %params=@_;
 353
 354         return $config{cgiurl}."?".join("&amp;", map "$_=$params{$_}", keys %params);
 355 } #}}}
 356
 357 sub baseurl (;$) { #{{{
 358         my $page=shift;
 359
 360         return "$config{url}/" if ! defined $page;
 361
 362         $page=~s/[^\/]+$//;
 363         $page=~s/[^\/]+\//..\//g;
 364         return $page;
 365 } #}}}
 366
 367 sub abs2rel ($$) { #{{{
 368         # Work around very innefficient behavior in File::Spec if abs2rel
 369         # is passed two relative paths. It's much faster if paths are
 370         # absolute! (Debian bug #376658; fixed in debian unstable now)
 371         my $path="/".shift;
 372         my $base="/".shift;
 373
 374         require File::Spec;
 375         my $ret=File::Spec->abs2rel($path, $base);
 376         $ret=~s/^// if defined $ret;
 377         return $ret;
 378 } #}}}
 379
 380 sub displaytime ($) { #{{{
 381         my $time=shift;
 382
 383         eval q{use POSIX};
 384         error($@) if $@;
 385         # strftime doesn't know about encodings, so make sure
 386         # its output is properly treated as utf8
 387         return decode_utf8(POSIX::strftime(
 388                         $config{timeformat}, localtime($time)));
 389 } #}}}
 390
 391 sub htmllink ($$$;$$$) { #{{{
 392         my $lpage=shift; # the page doing the linking
 393         my $page=shift; # the page that will contain the link (different for inline)
 394         my $link=shift;
 395         my $noimageinline=shift; # don't turn links into inline html images
 396         my $forcesubpage=shift; # force a link to a subpage
 397         my $linktext=shift; # set to force the link text to something
 398
 399         my $bestlink;
 400         if (! $forcesubpage) {
 401                 $bestlink=bestlink($lpage, $link);
 402         }
 403         else {
 404                 $bestlink="$lpage/".lc($link);
 405         }
 406
 407         $linktext=pagetitle(basename($link)) unless defined $linktext;
 408
 409         return "<span class=\"selflink\">$linktext</span>"
 410                 if length $bestlink && $page eq $bestlink;
 411
 412         if (! grep { $_ eq $bestlink } map { @{$_} } values %renderedfiles) {
 413                 $bestlink=htmlpage($bestlink);
 414         }
 415         if (! grep { $_ eq $bestlink } map { @{$_} } values %renderedfiles) {
 416                 return $linktext unless length $config{cgiurl};
 417                 return "<span><a href=\"".
 418                         cgiurl(do => "create", page => lc($link), from => $page).
 419                         "\">?</a>$linktext</span>"
 420         }
 421
 422         $bestlink=abs2rel($bestlink, dirname($page));
 423
 424         if (! $noimageinline && isinlinableimage($bestlink)) {
 425                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
 426         }
 427         return "<a href=\"$bestlink\">$linktext</a>";
 428 } #}}}
 429
 430 sub htmlize ($$$) { #{{{
 431         my $page=shift;
 432         my $type=shift;
 433         my $content=shift;
 434
 435         if (exists $hooks{htmlize}{$type}) {
 436                 $content=$hooks{htmlize}{$type}{call}->(
 437                         page => $page,
 438                         content => $content,
 439                 );
 440         }
 441         else {
 442                 error("htmlization of $type not supported");
 443         }
 444
 445         run_hooks(sanitize => sub {
 446                 $content=shift->(
 447                         page => $page,
 448                         content => $content,
 449                 );
 450         });
 451
 452         return $content;
 453 } #}}}
 454
 455 sub linkify ($$$) { #{{{
 456         my $lpage=shift; # the page containing the links
 457         my $page=shift; # the page the link will end up on (different for inline)
 458         my $content=shift;
 459
 460         $content =~ s{(\\?)$config{wiki_link_regexp}}{
 461                 $2 ? ( $1 ? "[[$2|$3]]" : htmllink($lpage, $page, titlepage($3), 0, 0, pagetitle($2)))
 462                    : ( $1 ? "[[$3]]" :    htmllink($lpage, $page, titlepage($3)))
 463         }eg;
 464
 465         return $content;
 466 } #}}}
 467
 468 my %preprocessing;
 469 sub preprocess ($$$;$) { #{{{
 470         my $page=shift; # the page the data comes from
 471         my $destpage=shift; # the page the data will appear in (different for inline)
 472         my $content=shift;
 473         my $scan=shift;
 474
 475         my $handle=sub {
 476                 my $escape=shift;
 477                 my $command=shift;
 478                 my $params=shift;
 479                 if (length $escape) {
 480                         return "[[$command $params]]";
 481                 }
 482                 elsif (exists $hooks{preprocess}{$command}) {
 483                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
 484                         # Note: preserve order of params, some plugins may
 485                         # consider it significant.
 486                         my @params;
 487                         while ($params =~ /(?:(\w+)=)?(?:"""(.*?)"""|"([^"]+)"|(\S+))(?:\s+|$)/sg) {
 488                                 my $key=$1;
 489                                 my $val;
 490                                 if (defined $2) {
 491                                         $val=$2;
 492                                         $val=~s/\r\n/\n/mg;
 493                                         $val=~s/^\n+//g;
 494                                         $val=~s/\n+$//g;
 495                                 }
 496                                 elsif (defined $3) {
 497                                         $val=$3;
 498                                 }
 499                                 elsif (defined $4) {
 500                                         $val=$4;
 501                                 }
 502
 503                                 if (defined $key) {
 504                                         push @params, $key, $val;
 505                                 }
 506                                 else {
 507                                         push @params, $val, '';
 508                                 }
 509                         }
 510                         if ($preprocessing{$page}++ > 3) {
 511                                 # Avoid loops of preprocessed pages preprocessing
 512                                 # other pages that preprocess them, etc.
 513                                 return "[[$command preprocessing loop detected on $page at depth $preprocessing{$page}]]";
 514                         }
 515                         my $ret=$hooks{preprocess}{$command}{call}->(
 516                                 @params,
 517                                 page => $page,
 518                                 destpage => $destpage,
 519                         );
 520                         $preprocessing{$page}--;
 521                         return $ret;
 522                 }
 523                 else {
 524                         return "[[$command $params]]";
 525                 }
 526         };
 527
 528         $content =~ s{(\\?)\[\[(\w+)\s+((?:(?:\w+=)?(?:""".*?"""|"[^"]+"|[^\s\]]+)\s*)*)\]\]}{$handle->($1, $2, $3)}seg;
 529         return $content;
 530 } #}}}
 531
 532 sub filter ($$) { #{{{
 533         my $page=shift;
 534         my $content=shift;
 535
 536         run_hooks(filter => sub {
 537                 $content=shift->(page => $page, content => $content);
 538         });
 539
 540         return $content;
 541 } #}}}
 542
 543 sub indexlink () { #{{{
 544         return "<a href=\"$config{url}\">$config{wikiname}</a>";
 545 } #}}}
 546
 547 sub lockwiki () { #{{{
 548         # Take an exclusive lock on the wiki to prevent multiple concurrent
 549         # run issues. The lock will be dropped on program exit.
 550         if (! -d $config{wikistatedir}) {
 551                 mkdir($config{wikistatedir});
 552         }
 553         open(WIKILOCK, ">$config{wikistatedir}/lockfile") ||
 554                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
 555         if (! flock(WIKILOCK, 2 | 4)) {
 556                 debug("wiki seems to be locked, waiting for lock");
 557                 my $wait=600; # arbitrary, but don't hang forever to
 558                               # prevent process pileup
 559                 for (1..600) {
 560                         return if flock(WIKILOCK, 2 | 4);
 561                         sleep 1;
 562                 }
 563                 error("wiki is locked; waited $wait seconds without lock being freed (possible stuck process or stale lock?)");
 564         }
 565 } #}}}
 566
 567 sub unlockwiki () { #{{{
 568         close WIKILOCK;
 569 } #}}}
 570
 571 sub loadindex () { #{{{
 572         open (IN, "$config{wikistatedir}/index") || return;
 573         while (<IN>) {
 574                 $_=possibly_foolish_untaint($_);
 575                 chomp;
 576                 my %items;
 577                 $items{link}=[];
 578                 $items{dest}=[];
 579                 foreach my $i (split(/ /, $_)) {
 580                         my ($item, $val)=split(/=/, $i, 2);
 581                         push @{$items{$item}}, decode_entities($val);
 582                 }
 583
 584                 next unless exists $items{src}; # skip bad lines for now
 585
 586                 my $page=pagename($items{src}[0]);
 587                 if (! $config{rebuild}) {
 588                         $pagesources{$page}=$items{src}[0];
 589                         $oldpagemtime{$page}=$items{mtime}[0];
 590                         $oldlinks{$page}=[@{$items{link}}];
 591                         $links{$page}=[@{$items{link}}];
 592                         $depends{$page}=$items{depends}[0] if exists $items{depends};
 593                         $renderedfiles{$page}=[@{$items{dest}}];
 594                         $oldrenderedfiles{$page}=[@{$items{dest}}];
 595                         $pagecase{lc $page}=$page;
 596                 }
 597                 $pagectime{$page}=$items{ctime}[0];
 598         }
 599         close IN;
 600 } #}}}
 601
 602 sub saveindex () { #{{{
 603         run_hooks(savestate => sub { shift->() });
 604
 605         if (! -d $config{wikistatedir}) {
 606                 mkdir($config{wikistatedir});
 607         }
 608         open (OUT, ">$config{wikistatedir}/index") ||
 609                 error("cannot write to $config{wikistatedir}/index: $!");
 610         foreach my $page (keys %oldpagemtime) {
 611                 next unless $oldpagemtime{$page};
 612                 my $line="mtime=$oldpagemtime{$page} ".
 613                         "ctime=$pagectime{$page} ".
 614                         "src=$pagesources{$page}";
 615                 $line.=" dest=$_" foreach @{$renderedfiles{$page}};
 616                 my %count;
 617                 $line.=" link=$_" foreach grep { ++$count{$_} == 1 } @{$links{$page}};
 618                 if (exists $depends{$page}) {
 619                         $line.=" depends=".encode_entities($depends{$page}, " \t\n");
 620                 }
 621                 print OUT $line."\n";
 622         }
 623         close OUT;
 624 } #}}}
 625
 626 sub template_params (@) { #{{{
 627         my $filename=shift;
 628
 629         require HTML::Template;
 630         return filter => sub {
 631                         my $text_ref = shift;
 632                         $$text_ref=&Encode::decode_utf8($$text_ref);
 633                 },
 634                 filename => "$config{templatedir}/$filename",
 635                 loop_context_vars => 1,
 636                 die_on_bad_params => 0,
 637                 @_;
 638 } #}}}
 639
 640 sub template ($;@) { #{{{
 641         HTML::Template->new(template_params(@_));
 642 } #}}}
 643
 644 sub misctemplate ($$;@) { #{{{
 645         my $title=shift;
 646         my $pagebody=shift;
 647
 648         my $template=template("misc.tmpl");
 649         $template->param(
 650                 title => $title,
 651                 indexlink => indexlink(),
 652                 wikiname => $config{wikiname},
 653                 pagebody => $pagebody,
 654                 baseurl => baseurl(),
 655                 @_,
 656         );
 657         run_hooks(pagetemplate => sub {
 658                 shift->(page => "", destpage => "", template => $template);
 659         });
 660         return $template->output;
 661 }#}}}
 662
 663 sub hook (@) { # {{{
 664         my %param=@_;
 665
 666         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
 667                 error "hook requires type, call, and id parameters";
 668         }
 669
 670         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
 671
 672         $hooks{$param{type}}{$param{id}}=\%param;
 673 } # }}}
 674
 675 sub run_hooks ($$) { # {{{
 676         # Calls the given sub for each hook of the given type,
 677         # passing it the hook function to call.
 678         my $type=shift;
 679         my $sub=shift;
 680
 681         if (exists $hooks{$type}) {
 682                 my @deferred;
 683                 foreach my $id (keys %{$hooks{$type}}) {
 684                         if ($hooks{$type}{$id}{last}) {
 685                                 push @deferred, $id;
 686                                 next;
 687                         }
 688                         $sub->($hooks{$type}{$id}{call});
 689                 }
 690                 foreach my $id (@deferred) {
 691                         $sub->($hooks{$type}{$id}{call});
 692                 }
 693         }
 694 } #}}}
 695
 696 sub globlist_to_pagespec ($) { #{{{
 697         my @globlist=split(' ', shift);
 698
 699         my (@spec, @skip);
 700         foreach my $glob (@globlist) {
 701                 if ($glob=~/^!(.*)/) {
 702                         push @skip, $glob;
 703                 }
 704                 else {
 705                         push @spec, $glob;
 706                 }
 707         }
 708
 709         my $spec=join(" or ", @spec);
 710         if (@skip) {
 711                 my $skip=join(" and ", @skip);
 712                 if (length $spec) {
 713                         $spec="$skip and ($spec)";
 714                 }
 715                 else {
 716                         $spec=$skip;
 717                 }
 718         }
 719         return $spec;
 720 } #}}}
 721
 722 sub is_globlist ($) { #{{{
 723         my $s=shift;
 724         $s=~/[^\s]+\s+([^\s]+)/ && $1 ne "and" && $1 ne "or";
 725 } #}}}
 726
 727 sub safequote ($) { #{{{
 728         my $s=shift;
 729         $s=~s/[{}]//g;
 730         return "q{$s}";
 731 } #}}}
 732
 733 sub pagespec_merge ($$) { #{{{
 734         my $a=shift;
 735         my $b=shift;
 736
 737         return $a if $a eq $b;
 738
 739         # Support for old-style GlobLists.
 740         if (is_globlist($a)) {
 741                 $a=globlist_to_pagespec($a);
 742         }
 743         if (is_globlist($b)) {
 744                 $b=globlist_to_pagespec($b);
 745         }
 746
 747         return "($a) or ($b)";
 748 } #}}}
 749
 750 sub pagespec_translate ($) { #{{{
 751         # This assumes that $page is in scope in the function
 752         # that evalulates the translated pagespec code.
 753         my $spec=shift;
 754
 755         # Support for old-style GlobLists.
 756         if (is_globlist($spec)) {
 757                 $spec=globlist_to_pagespec($spec);
 758         }
 759
 760         # Convert spec to perl code.
 761         my $code="";
 762         while ($spec=~m/\s*(\!|\(|\)|\w+\([^\)]+\)|[^\s()]+)\s*/ig) {
 763                 my $word=$1;
 764                 if (lc $word eq "and") {
 765                         $code.=" &&";
 766                 }
 767                 elsif (lc $word eq "or") {
 768                         $code.=" ||";
 769                 }
 770                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
 771                         $code.=" ".$word;
 772                 }
 773                 elsif ($word =~ /^(link|backlink|created_before|created_after|creation_month|creation_year|creation_day)\((.+)\)$/) {
 774                         $code.=" match_$1(\$page, ".safequote($2).")";
 775                 }
 776                 else {
 777                         $code.=" match_glob(\$page, ".safequote($word).")";
 778                 }
 779         }
 780
 781         return $code;
 782 } #}}}
 783
 784 sub add_depends ($$) { #{{{
 785         my $page=shift;
 786         my $pagespec=shift;
 787
 788         if (! exists $depends{$page}) {
 789                 $depends{$page}=$pagespec;
 790         }
 791         else {
 792                 $depends{$page}=pagespec_merge($depends{$page}, $pagespec);
 793         }
 794 } # }}}
 795
 796 sub file_pruned ($$) { #{{{
 797         require File::Spec;
 798         my $file=File::Spec->canonpath(shift);
 799         my $base=File::Spec->canonpath(shift);
 800         $file=~s#^\Q$base\E/*##;
 801
 802         my $regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
 803         $file =~ m/$regexp/;
 804 } #}}}
 805
 806 sub pagespec_match ($$) { #{{{
 807         my $page=shift;
 808         my $spec=shift;
 809
 810         return eval pagespec_translate($spec);
 811 } #}}}
 812
 813 sub match_glob ($$) { #{{{
 814         my $page=shift;
 815         my $glob=shift;
 816
 817         # turn glob into safe regexp
 818         $glob=quotemeta($glob);
 819         $glob=~s/\\\*/.*/g;
 820         $glob=~s/\\\?/./g;
 821
 822         return $page=~/^$glob$/i;
 823 } #}}}
 824
 825 sub match_link ($$) { #{{{
 826         my $page=shift;
 827         my $link=lc(shift);
 828
 829         my $links = $links{$page} or return undef;
 830         foreach my $p (@$links) {
 831                 return 1 if lc $p eq $link;
 832         }
 833         return 0;
 834 } #}}}
 835
 836 sub match_backlink ($$) { #{{{
 837         match_link(pop, pop);
 838 } #}}}
 839
 840 sub match_created_before ($$) { #{{{
 841         my $page=shift;
 842         my $testpage=shift;
 843
 844         if (exists $pagectime{$testpage}) {
 845                 return $pagectime{$page} < $pagectime{$testpage};
 846         }
 847         else {
 848                 return 0;
 849         }
 850 } #}}}
 851
 852 sub match_created_after ($$) { #{{{
 853         my $page=shift;
 854         my $testpage=shift;
 855
 856         if (exists $pagectime{$testpage}) {
 857                 return $pagectime{$page} > $pagectime{$testpage};
 858         }
 859         else {
 860                 return 0;
 861         }
 862 } #}}}
 863
 864 sub match_creation_day ($$) { #{{{
 865         return ((gmtime($pagectime{shift()}))[3] == shift);
 866 } #}}}
 867
 868 sub match_creation_month ($$) { #{{{
 869         return ((gmtime($pagectime{shift()}))[4] + 1 == shift);
 870 } #}}}
 871
 872 sub match_creation_year ($$) { #{{{
 873         return ((gmtime($pagectime{shift()}))[5] + 1900 == shift);
 874 } #}}}
 875
 876 1