git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Setup/Automator.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki setup automator.
   3
   4 package IkiWiki::Setup::Automator;
   5
   6 use warnings;
   7 use strict;
   8 use IkiWiki;
   9 use IkiWiki::UserInfo;
  10 use Term::ReadLine;
  11 use File::Path;
  12 use Encode;
  13
  14 sub ask ($$) {
  15         my ($question, $default)=@_;
  16
  17         my $r=Term::ReadLine->new("ikiwiki");
  18         $r->ornaments("md,me");
  19         $r->readline(encode_utf8($question)." ", $default);
  20 }
  21
  22 sub prettydir ($) {
  23         my $dir=shift;
  24         $dir=~s/^\Q$ENV{HOME}\E\//~\//;
  25         return $dir;
  26 }
  27
  28 sub sanitize_wikiname ($) {
  29         my $wikiname=shift;
  30
  31         # Sanitize this to avoid problimatic directory names.
  32         $wikiname=~s/[^-A-Za-z0-9_]//g;
  33         if (! length $wikiname) {
  34                 error gettext("you must enter a wikiname (that contains alphanumerics)");
  35         }
  36         return $wikiname;
  37 }
  38
  39 sub import (@) {
  40         my $this=shift;
  41         $config{setuptype}='Standard';
  42         IkiWiki::Setup::merge({@_});
  43
  44         if (! $config{force_overwrite}) {
  45                 # Avoid overwriting any existing files.
  46                 foreach my $key (qw{srcdir destdir repository dumpsetup}) {
  47                         next unless exists $config{$key};
  48                         my $add="";
  49                         my $dir=IkiWiki::dirname($config{$key})."/";
  50                         my $base=IkiWiki::basename($config{$key});
  51                         while (-e $dir.$add.$base) {
  52                                 $add=1 if ! $add;
  53                                 $add++;
  54                         }
  55                         $config{$key}=$dir.$add.$base;
  56                 }
  57         }
  58
  59         # Set up wrapper
  60         if ($config{rcs}) {
  61                 if ($config{rcs} eq 'git') {
  62                         $config{git_wrapper}=$config{repository}."/hooks/post-update";
  63                 }
  64                 elsif ($config{rcs} eq 'svn') {
  65                         $config{svn_wrapper}=$config{repository}."/hooks/post-commit";
  66                 }
  67                 elsif ($config{rcs} eq 'monotone') {
  68                         $config{mtn_wrapper}=$config{srcdir}."_MTN/ikiwiki-netsync-hook";
  69                 }
  70                 elsif ($config{rcs} eq 'darcs') {
  71                         $config{darcs_wrapper}=$config{repository}."/_darcs/ikiwiki-wrapper";
  72                 }
  73                 elsif ($config{rcs} eq 'bzr') {
  74                         # TODO
  75                         print STDERR "warning: do not know how to set up the bzr_wrapper hook!\n";
  76                 }
  77                 elsif ($config{rcs} eq 'mercurial') {
  78                         # TODO
  79                         print STDERR "warning: do not know how to set up the mercurial_wrapper hook!\n";
  80                 }
  81                 elsif ($config{rcs} eq 'cvs') {
  82                         $config{cvs_wrapper}=$config{repository}."/CVSROOT/post-commit";
  83                 }
  84                 else {
  85                         error sprintf(gettext("unsupported revision control system %s"),
  86                                 $config{rcs});
  87                 }
  88         }
  89
  90         IkiWiki::checkconfig();
  91
  92         print "\n\nSetting up $config{wikiname} ...\n";
  93
  94         # Set up the srcdir.
  95         mkpath($config{srcdir}) || die "mkdir $config{srcdir}: $!";
  96         # Copy in example wiki.
  97         if (exists $config{example}) {
  98                 # cp -R is POSIX
  99                 # Another reason not to use -a is so that pages such as blog
 100                 # posts will not have old creation dates on this new wiki.
 101                 system("cp -R $IkiWiki::installdir/share/ikiwiki/examples/$config{example}/* $config{srcdir}");
 102                 delete $config{example};
 103         }
 104
 105         # Set up the repository.
 106         delete $config{repository} if ! $config{rcs} || $config{rcs}=~/bzr|mercurial/;
 107         if ($config{rcs}) {
 108                 my @params=($config{rcs}, $config{srcdir});
 109                 push @params, $config{repository} if exists $config{repository};
 110                 if (system("ikiwiki-makerepo", @params) != 0) {
 111                         error gettext("failed to set up the repository with ikiwiki-makerepo");
 112                 }
 113         }
 114
 115         # Make sure that all the listed plugins can load
 116         # and checkconfig is ok. If a plugin fails to work,
 117         # remove it from the configuration and keep on truckin'.
 118         my %bakconfig=%config; # checkconfig can modify %config so back up
 119         if (! eval { IkiWiki::loadplugins(); IkiWiki::checkconfig() }) {
 120                 foreach my $plugin (@{$config{default_plugins}}, @{$bakconfig{add_plugins}}) {
 121                         eval {
 122                                 # delete all hooks so that only this plugins's
 123                                 # checkconfig will be run
 124                                 %IkiWiki::hooks=();
 125                                 IkiWiki::loadplugin($plugin);
 126                                 IkiWiki::run_hooks(checkconfig => sub { shift->() });
 127                         };
 128                         if ($@) {
 129                                 my $err=$@;
 130                                 print STDERR sprintf(gettext("** Disabling plugin %s, since it is failing with this message:"),
 131                                         $plugin)."\n";
 132                                 print STDERR "$err\n";
 133                                 push @{$bakconfig{disable_plugins}}, $plugin;
 134                         }
 135                 }
 136         }
 137         %config=%bakconfig;
 138
 139         # Generate setup file.
 140         require IkiWiki::Setup;
 141         IkiWiki::Setup::dump($config{dumpsetup});
 142
 143         # Build the wiki, but w/o wrappers, so it's not live yet.
 144         mkpath($config{destdir}) || die "mkdir $config{destdir}: $!";
 145         if (system("ikiwiki", "--refresh", "--setup", $config{dumpsetup}) != 0) {
 146                 die "ikiwiki --refresh --setup $config{dumpsetup} failed";
 147         }
 148
 149         # Create admin user(s).
 150         foreach my $admin (@{$config{adminuser}}) {
 151                 next if defined IkiWiki::openiduser($admin);
 152
 153                 # Prompt for password w/o echo.
 154                 my ($password, $password2);
 155                 system('stty -echo 2>/dev/null');
 156                 local $|=1;
 157                 print "\n\nCreating wiki admin $admin ...\n";
 158                 for (;;) {
 159                         print "Choose a password: ";
 160                         chomp($password=<STDIN>);
 161                         print "\n";
 162                         print "Confirm password: ";
 163                         chomp($password2=<STDIN>);
 164
 165                         last if $password2 eq $password;
 166
 167                         print "Password mismatch.\n\n";
 168                 }
 169                 print "\n\n\n";
 170                 system('stty sane 2>/dev/null');
 171
 172                 if (IkiWiki::userinfo_setall($admin, { regdate => time }) &&
 173                     IkiWiki::Plugin::passwordauth::setpassword($admin, $password)) {
 174                         IkiWiki::userinfo_set($admin, "email", $config{adminemail}) if defined $config{adminemail};
 175                 }
 176                 else {
 177                         error("problem setting up $admin user");
 178                 }
 179         }
 180
 181         # Add wrappers, make live.
 182         if (system("ikiwiki", "--wrappers", "--setup", $config{dumpsetup}) != 0) {
 183                 die "ikiwiki --wrappers --setup $config{dumpsetup} failed";
 184         }
 185
 186         # Add it to the wikilist.
 187         mkpath("$ENV{HOME}/.ikiwiki");
 188         open (WIKILIST, ">>$ENV{HOME}/.ikiwiki/wikilist") || die "$ENV{HOME}/.ikiwiki/wikilist: $!";
 189         print WIKILIST "$ENV{USER} $config{dumpsetup}\n";
 190         close WIKILIST;
 191         if (system("ikiwiki-update-wikilist") != 0) {
 192                 print STDERR "** Failed to add you to the system wikilist file.\n";
 193                 print STDERR "** (Probably ikiwiki-update-wikilist is not SUID root.)\n";
 194                 print STDERR "** Your wiki will not be automatically updated when ikiwiki is upgraded.\n";
 195         }
 196
 197         # Done!
 198         print "\n\nSuccessfully set up $config{wikiname}:\n";
 199         foreach my $key (qw{url srcdir destdir repository}) {
 200                 next unless exists $config{$key};
 201                 print "\t$key: ".(" " x (10 - length($key)))." ".
 202                         prettydir($config{$key})."\n";
 203         }
 204         print "To modify settings, edit ".prettydir($config{dumpsetup})." and then run:\n";
 205         print " ikiwiki -setup ".prettydir($config{dumpsetup})."\n";
 206         exit 0;
 207 }
 208
 209 1