git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/edittemplate.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::edittemplate;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7 use HTML::Template;
   8 use Encode;
   9
  10 sub import {
  11         hook(type => "getsetup", id => "edittemplate",
  12                 call => \&getsetup);
  13         hook(type => "needsbuild", id => "edittemplate",
  14                 call => \&needsbuild);
  15         hook(type => "preprocess", id => "edittemplate",
  16                 call => \&preprocess);
  17         hook(type => "formbuilder", id => "edittemplate",
  18                 call => \&formbuilder);
  19 }
  20
  21 sub getsetup () {
  22         return
  23                 plugin => {
  24                         safe => 1,
  25                         rebuild => undef,
  26                         section => "web",
  27                 },
  28 }
  29
  30 sub needsbuild (@) {
  31         my $needsbuild=shift;
  32
  33         foreach my $page (keys %pagestate) {
  34                 if (exists $pagestate{$page}{edittemplate}) {
  35                         if (exists $pagesources{$page} &&
  36                             grep { $_ eq $pagesources{$page} } @$needsbuild) {
  37                                 # remove state, it will be re-added
  38                                 # if the preprocessor directive is still
  39                                 # there during the rebuild
  40                                 delete $pagestate{$page}{edittemplate};
  41                         }
  42                 }
  43         }
  44 }
  45
  46 sub preprocess (@) {
  47         my %params=@_;
  48
  49         return "" if $params{page} ne $params{destpage};
  50
  51         if (! exists $params{template} || ! length($params{template})) {
  52                 error gettext("template not specified")
  53         }
  54         if (! exists $params{match} || ! length($params{match})) {
  55                 error gettext("match not specified")
  56         }
  57
  58         my $link=linkpage($params{template});
  59         my $bestlink=bestlink($params{page}, $link);
  60         $pagestate{$params{page}}{edittemplate}{$params{match}}=$bestlink;
  61
  62         return "" if ($params{silent} && IkiWiki::yesno($params{silent}));
  63         add_depends($params{page}, $link, deptype("presence"));
  64         return sprintf(gettext("edittemplate %s registered for %s"),
  65                 htmllink($params{page}, $params{destpage}, $link),
  66                 $params{match});
  67 }
  68
  69 sub formbuilder (@) {
  70         my %params=@_;
  71         my $form=$params{form};
  72
  73         return if $form->field("do") ne "create" ||
  74                 (defined $form->field("editcontent") && length $form->field("editcontent"));
  75
  76         my $page=$form->field("page");
  77
  78         # The tricky bit here is that $page is probably just the base
  79         # page name, without any subdir, but the pagespec for a template
  80         # probably does include the subdir (ie, "bugs/*"). We don't know
  81         # what subdir the user will pick to put the page in. So, try them
  82         # all, starting with the one that was made default.
  83         my @page_locs=$page;
  84         foreach my $field ($form->field) {
  85                 if ($field eq 'page') {
  86                         @page_locs=$field->def_value;
  87
  88                         # FormBuilder is on the bad crack. See #551499
  89                         my @options=map { ref $_ ? @$_ : $_ } $field->options;
  90
  91                         push @page_locs, @options;
  92                 }
  93         }
  94         foreach my $p (@page_locs) {
  95                 foreach my $registering_page (keys %pagestate) {
  96                         if (exists $pagestate{$registering_page}{edittemplate}) {
  97                                 foreach my $pagespec (sort keys %{$pagestate{$registering_page}{edittemplate}}) {
  98                                         if (pagespec_match($p, $pagespec, location => $registering_page)) {
  99                                                 my $template=$pagestate{$registering_page}{edittemplate}{$pagespec};
 100                                                 $form->field(name => "editcontent",
 101                                                          value =>  filltemplate($template, $page));
 102                                                 $form->field(name => "type",
 103                                                          value => pagetype($pagesources{$template}))
 104                                                                 if $pagesources{$template};
 105                                                 return;
 106                                         }
 107                                 }
 108                         }
 109                 }
 110         }
 111 }
 112
 113 sub filltemplate ($$) {
 114         my $template_page=shift;
 115         my $page=shift;
 116
 117         my $template_file=$pagesources{$template_page};
 118         if (! defined $template_file) {
 119                 return;
 120         }
 121
 122         my $template;
 123         eval {
 124                 $template=HTML::Template->new(
 125                         filter => sub {
 126                                 my $text_ref = shift;
 127                                 $$text_ref=&Encode::decode_utf8($$text_ref);
 128                                 chomp $$text_ref;
 129                         },
 130                         filename => srcfile($template_file),
 131                         die_on_bad_params => 0,
 132                         no_includes => 1,
 133                 );
 134         };
 135         if ($@) {
 136                 # Indicate that the earlier preprocessor directive set
 137                 # up a template that doesn't work.
 138                 return "[[!pagetemplate ".gettext("failed to process")." $@]]";
 139         }
 140
 141         $template->param(name => $page);
 142
 143         return $template->output;
 144 }
 145
 146 1