git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Rcs/tla.pm

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5 use IkiWiki;
   6 use POSIX qw(setlocale LC_CTYPE);
   7
   8 package IkiWiki;
   9
  10 my $tla_webcommit=qr/^web commit (by (\w+)|from (\d+\.\d+\.\d+\.\d+)):?(.*)/;
  11
  12 sub quiet_system (@) {
  13         open (SAVEOUT, ">&STDOUT");
  14         close STDOUT;
  15         my $ret=system(@_);
  16         open (STDOUT, ">&SAVEOUT");
  17         close SAVEOUT;
  18         return $ret;
  19 }
  20
  21 sub rcs_update () { #{{{
  22         if (-d "$config{srcdir}/{arch}") {
  23                 if (quiet_system("tla", "replay", "-d", $config{srcdir}) != 0) {
  24                         warn("tla replay failed\n");
  25                 }
  26         }
  27 } #}}}
  28
  29 sub rcs_prepedit ($) { #{{{
  30         my $file=shift;
  31
  32         if (-d "$config{srcdir}/{arch}") {
  33                 # For Arch, return the tree-id of archive when
  34                 # editing begins.
  35                 my $rev=`tla tree-id $config{srcdir}`;
  36                 return defined $rev ? $rev : "";
  37         }
  38 } #}}}
  39
  40 sub rcs_commit ($$$) { #{{{
  41         my $file=shift;
  42         my $message=shift;
  43         my $rcstoken=shift;
  44
  45         if (-d "$config{srcdir}/{arch}") {
  46                 # Check to see if the page has been changed by someone
  47                 # else since rcs_prepedit was called.
  48                 my ($oldrev)=$rcstoken=~/^([A-Za-z0-9@\/._-]+)$/; # untaint
  49                 my $rev=`tla tree-id $config{srcdir}`;
  50                 if (defined $rev && defined $oldrev && $rev ne $oldrev) {
  51                         # Merge their changes into the file that we've
  52                         # changed.
  53                         if (system("tla", "update", "-d",
  54                                    "$config{srcdir}/$file") != 0) {
  55                                 warn("tla update failed\n");
  56                         }
  57                 }
  58
  59                 if (quiet_system("tla", "commit",
  60                            "-L".possibly_foolish_untaint($message),
  61                            '-d', $config{srcdir}) != 0) {
  62                         my $conflict=readfile("$config{srcdir}/$file");
  63                         if (system("tla", "undo", "--quiet", "-d", "$config{srcdir}") != 0) {
  64                                 warn("tla undo failed\n");
  65                         }
  66                         return $conflict;
  67                 }
  68         }
  69         return undef # success
  70 } #}}}
  71
  72 sub rcs_add ($) { #{{{
  73         my $file=shift;
  74
  75         if (-d "$config{srcdir}/{arch}") {
  76                 if (quiet_system("tla", "add", "$config{srcdir}/$file") != 0) {
  77                         warn("tla add failed\n");
  78                 }
  79         }
  80 } #}}}
  81
  82 sub rcs_recentchanges ($) {
  83         my $num=shift;
  84         my @ret;
  85
  86         return unless -d "$config{srcdir}/{arch}";
  87
  88         eval q{use Date::Parse};
  89         eval q{use Mail::Header};
  90
  91         my $logs = `tla logs -d $config{srcdir}`;
  92         my @changesets = reverse split(/\n/, $logs);
  93
  94         for (my $i=0; $i<$num && $i<$#changesets; $i++) {
  95                 my ($change)=$changesets[$i]=~/^([A-Za-z0-9@\/._-]+)$/; # untaint
  96
  97                 open(LOG, "tla cat-log -d $config{srcdir} $change|");
  98                 my $head = Mail::Header->new(\*LOG);
  99                 close(LOG);
 100
 101                 my $rev = $head->get("Revision");
 102                 my $summ = $head->get("Summary");
 103                 my $newfiles = $head->get("New-files");
 104                 my $modfiles = $head->get("Modified-files");
 105                 my $user = $head->get("Creator");
 106
 107                 my @paths = grep {!/^.*\/\.arch-ids\/.*\.id$/} split(/ /,
 108                         "$newfiles $modfiles");
 109
 110                 my $sdate = $head->get("Standard-date");
 111                 my $when = time - str2time($sdate, 'UTC');
 112
 113                 my $committype = "web";
 114                 if (defined $summ && $summ =~ /$tla_webcommit/) {
 115                         $user = defined $2 ? "$2" : "$3";
 116                         $summ = $4;
 117                 }
 118                 else {
 119                         $committype="tla";
 120                 }
 121
 122                 my @message;
 123                 push @message, { line => escapeHTML($summ) };
 124                 $user = escapeHTML($user);
 125
 126                 my @pages;
 127
 128                 foreach my $file (@paths) {
 129                         my $diffurl=$config{diffurl};
 130                         $diffurl=~s/\[\[file\]\]/$file/g;
 131                         $diffurl=~s/\[\[rev\]\]/$change/g;
 132                         push @pages, {
 133                                 page => pagename($file),
 134                                 diffurl => $diffurl,
 135                         } if length $file;
 136                 }
 137                 push @ret, { rev => $change,
 138                         user => $user,
 139                         committype => $committype,
 140                         when => $when,
 141                         message => [@message],
 142                         pages => [@pages],
 143                 } if @pages;
 144
 145                 last if $i == $num;
 146         }
 147
 148         return @ret;
 149 }
 150
 151 sub rcs_notify () { #{{{
 152         # FIXME: Not set
 153         if (! exists $ENV{REV}) {
 154                 error("REV is not set, not running from tla post-commit hook, cannot send notifications");
 155         }
 156         my $rev=int(possibly_foolish_untaint($ENV{REV}));
 157
 158         eval q{use Mail::Header};
 159         open(LOG, $ENV{"ARCH_LOG"});
 160         my $head = Mail::Header->new(\*LOG);
 161         close(LOG);
 162
 163         my $message = $head->get("Summary");
 164         my $user = $head->get("Creator");
 165
 166         my $newfiles = $head->get("New-files");
 167         my $modfiles = $head->get("Modified-files");
 168
 169         my @changed_pages = grep {!/^.*\/\.arch-ids\/.*\.id$/} split(/ /,
 170                 "$newfiles $modfiles");
 171
 172         if ($message =~ /$tla_webcommit/) {
 173                 $user=defined $2 ? "$2" : "$3";
 174                 $message=$4;
 175         }
 176
 177         require IkiWiki::UserInfo;
 178         my @email_recipients=commit_notify_list($user, @changed_pages);
 179         if (@email_recipients) {
 180                 # TODO: if a commit spans multiple pages, this will send
 181                 # subscribers a diff that might contain pages they did not
 182                 # sign up for. Should separate the diff per page and
 183                 # reassemble into one mail with just the pages subscribed to.
 184                 my $logs = `tla logs -d $config{srcdir}`;
 185                 my @changesets = reverse split(/\n/, $logs);
 186                 my $i;
 187
 188                 for($i=0;$i<$#changesets;$i++) {
 189                         last if $changesets[$i] eq $rev;
 190                 }
 191
 192                 my $revminusone = $changesets[$i+1];
 193                 my $diff=`tla diff -d $ENV{ARCH_TREE_ROOT} $revminusone`;
 194
 195                 my $subject="$config{wikiname} update of ";
 196                 if (@changed_pages > 2) {
 197                         $subject.="$changed_pages[0] $changed_pages[1] etc";
 198                 }
 199                 else {
 200                         $subject.=join(" ", @changed_pages);
 201                 }
 202                 $subject.=" by $user";
 203
 204                 my $template=template("notifymail.tmpl");
 205                 $template->param(
 206                         wikiname => $config{wikiname},
 207                         diff => $diff,
 208                         user => $user,
 209                         message => $message,
 210                 );
 211
 212                 eval q{use Mail::Sendmail};
 213                 foreach my $email (@email_recipients) {
 214                         sendmail(
 215                                 To => $email,
 216                                 From => "$config{wikiname} <$config{adminemail}>",
 217                                 Subject => $subject,
 218                                 Message => $template->output,
 219                         ) or error("Failed to send update notification mail");
 220                 }
 221         }
 222 } #}}}
 223
 224 sub rcs_getctime ($) { #{{{
 225         my $file=shift;
 226         eval q{use Date::Parse};
 227         eval q{use Mail::Header};
 228
 229         my $logs = `tla logs -d $config{srcdir}`;
 230         my @changesets = reverse split(/\n/, $logs);
 231         my $sdate;
 232
 233         for (my $i=0; $i<$#changesets; $i++) {
 234                 my $change = $changesets[$i];
 235
 236                 open(LOG, "tla cat-log -d $config{srcdir} $change|");
 237                 my $head = Mail::Header->new(\*LOG);
 238                 close(LOG);
 239
 240                 $sdate = $head->get("Standard-date");
 241                 my $newfiles = $head->get("New-files");
 242
 243                 my ($lastcreation) = grep {/^$file$/} split(/ /, "$newfiles");
 244                 last if defined($lastcreation);
 245         }
 246
 247         my $date=str2time($sdate, 'UTC');
 248         debug("found ctime ".localtime($date)." for $file");
 249         return $date;
 250 } #}}}
 251
 252 1