git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/mdwn.pm

   1 #!/usr/bin/perl
   2 # Markdown markup language
   3 package IkiWiki::Plugin::mdwn;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki 3.00;
   8
   9 sub import {
  10         hook(type => "getsetup", id => "mdwn", call => \&getsetup);
  11         hook(type => "htmlize", id => "mdwn", call => \&htmlize, longname => "Markdown");
  12 }
  13
  14 sub getsetup () {
  15         return
  16                 plugin => {
  17                         safe => 1,
  18                         rebuild => 1, # format plugin
  19                         section => "format",
  20                 },
  21                 multimarkdown => {
  22                         type => "boolean",
  23                         example => 0,
  24                         description => "enable multimarkdown features?",
  25                         safe => 1,
  26                         rebuild => 1,
  27                 },
  28 }
  29
  30 my $markdown_sub;
  31 sub htmlize (@) {
  32         my %params=@_;
  33         my $content = $params{content};
  34
  35         if (! defined $markdown_sub) {
  36                 # Markdown is forked and splintered upstream and can be
  37                 # available in a variety of forms. Support them all.
  38                 no warnings 'once';
  39                 $blosxom::version="is a proper perl module too much to ask?";
  40                 use warnings 'all';
  41
  42                 if (exists $config{multimarkdown} && $config{multimarkdown}) {
  43                         eval q{use Text::MultiMarkdown};
  44                         if ($@) {
  45                                 debug(gettext("multimarkdown is enabled, but Text::MultiMarkdown is not installed"));
  46                         }
  47                         else {
  48                                 $markdown_sub=sub {
  49                                         Text::MultiMarkdown::markdown(shift, {use_metadata => 0});
  50                                 }
  51                         }
  52                 }
  53                 if (! defined $markdown_sub) {
  54                         eval q{use Text::Markdown};
  55                         if (! $@) {
  56                                 if (Text::Markdown->can('markdown')) {
  57                                         $markdown_sub=\&Text::Markdown::markdown;
  58                                 }
  59                                 else {
  60                                         $markdown_sub=\&Text::Markdown::Markdown;
  61                                 }
  62                         }
  63                         else {
  64                                 eval q{use Markdown};
  65                                 if (! $@) {
  66                                         $markdown_sub=\&Markdown::Markdown;
  67                                 }
  68                                 else {
  69                                         do "/usr/bin/markdown" ||
  70                                                 error(sprintf(gettext("failed to load Markdown.pm perl module (%s) or /usr/bin/markdown (%s)"), $@, $!));
  71                                         $markdown_sub=\&Markdown::Markdown;
  72                                 }
  73                         }
  74                 }
  75
  76                 require Encode;
  77         }
  78
  79         # Workaround for perl bug (#376329)
  80         $content=Encode::encode_utf8($content);
  81         eval {$content=&$markdown_sub($content)};
  82         if ($@) {
  83                 eval {$content=&$markdown_sub($content)};
  84                 print STDERR $@ if $@;
  85         }
  86         $content=Encode::decode_utf8($content);
  87
  88         return $content;
  89 }
  90
  91 1