git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/rename.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::rename;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 2.00;
   7
   8 sub import { #{{{
   9         hook(type => "getsetup", id => "rename", call => \&getsetup);
  10         hook(type => "formbuilder_setup", id => "rename", call => \&formbuilder_setup);
  11         hook(type => "formbuilder", id => "rename", call => \&formbuilder);
  12         hook(type => "sessioncgi", id => "rename", call => \&sessioncgi);
  13
  14 } # }}}
  15
  16 sub getsetup () { #{{{
  17         return
  18                 plugin => {
  19                         safe => 1,
  20                         rebuild => 0,
  21                 },
  22 } #}}}
  23
  24 sub check_canrename ($$$$$$) { #{{{
  25         my $src=shift;
  26         my $srcfile=shift;
  27         my $dest=shift;
  28         my $destfile=shift;
  29         my $q=shift;
  30         my $session=shift;
  31
  32         my $attachment=! defined pagetype($pagesources{$src});
  33
  34         # Must be a known source file.
  35         if (! exists $pagesources{$src}) {
  36                 error(sprintf(gettext("%s does not exist"),
  37                         htmllink("", "", $src, noimageinline => 1)));
  38         }
  39
  40         # Must exist on disk, and be a regular file.
  41         if (! -e "$config{srcdir}/$srcfile") {
  42                 error(sprintf(gettext("%s is not in the srcdir, so it cannot be renamed"), $srcfile));
  43         }
  44         elsif (-l "$config{srcdir}/$srcfile" && ! -f _) {
  45                 error(sprintf(gettext("%s is not a file"), $srcfile));
  46         }
  47
  48         # Must be editable.
  49         IkiWiki::check_canedit($src, $q, $session);
  50         if ($attachment) {
  51                 if (IkiWiki::Plugin::attachment->can("check_canattach")) {
  52                         IkiWiki::Plugin::attachment::check_canattach($session, $src, $srcfile);
  53                 }
  54                 else {
  55                         error("renaming of attachments is not allowed");
  56                 }
  57         }
  58
  59         # Dest checks can be omitted by passing undef.
  60         if (defined $dest) {
  61                 if ($srcfile eq $destfile) {
  62                         error(gettext("no change to the file name was specified"));
  63                 }
  64
  65                 # Must be a legal filename, and not absolute.
  66                 if (IkiWiki::file_pruned($destfile, $config{srcdir}) ||
  67                     $destfile=~/^\//) {
  68                         error(sprintf(gettext("illegal name")));
  69                 }
  70
  71                 # Must not be a known source file.
  72                 if ($src ne $dest && exists $pagesources{$dest}) {
  73                         error(sprintf(gettext("%s already exists"),
  74                                 htmllink("", "", $dest, noimageinline => 1)));
  75                 }
  76
  77                 # Must not exist on disk already.
  78                 if (-l "$config{srcdir}/$destfile" || -e _) {
  79                         error(sprintf(gettext("%s already exists on disk"), $destfile));
  80                 }
  81
  82                 # Must be editable.
  83                 IkiWiki::check_canedit($dest, $q, $session);
  84                 if ($attachment) {
  85                         # Note that $srcfile is used here, not $destfile,
  86                         # because it wants the current file, to check it.
  87                         IkiWiki::Plugin::attachment::check_canattach($session, $dest, $srcfile);
  88                 }
  89         }
  90 } #}}}
  91
  92 sub rename_form ($$$) { #{{{
  93         my $q=shift;
  94         my $session=shift;
  95         my $page=shift;
  96
  97         eval q{use CGI::FormBuilder};
  98         error($@) if $@;
  99         my $f = CGI::FormBuilder->new(
 100                 name => "rename",
 101                 title => sprintf(gettext("rename %s"), pagetitle($page)),
 102                 header => 0,
 103                 charset => "utf-8",
 104                 method => 'POST',
 105                 javascript => 0,
 106                 params => $q,
 107                 action => $config{cgiurl},
 108                 stylesheet => IkiWiki::baseurl()."style.css",
 109                 fields => [qw{do page new_name attachment}],
 110         );
 111
 112         $f->field(name => "do", type => "hidden", value => "rename", force => 1);
 113         $f->field(name => "page", type => "hidden", value => $page, force => 1);
 114         $f->field(name => "new_name", value => pagetitle($page), size => 60);
 115         if (!$q->param("attachment")) {
 116                 # insert the standard extensions
 117                 my @page_types;
 118                 if (exists $IkiWiki::hooks{htmlize}) {
 119                         @page_types=grep { !/^_/ }
 120                                 keys %{$IkiWiki::hooks{htmlize}};
 121                 }
 122
 123                 # make sure the current extension is in the list
 124                 my ($ext) = $pagesources{$page}=~/\.([^.]+)$/;
 125                 if (! $IkiWiki::hooks{htmlize}{$ext}) {
 126                         unshift(@page_types, $ext);
 127                 }
 128
 129                 $f->field(name => "type", type => 'select',
 130                         options => \@page_types,
 131                         value => $ext, force => 1);
 132
 133                 foreach my $p (keys %pagesources) {
 134                         if ($pagesources{$p}=~m/^\Q$page\E\//) {
 135                                 $f->field(name => "subpages",
 136                                         label => "",
 137                                         type => "checkbox",
 138                                         options => [ [ 1 => gettext("Also rename SubPages and attachments") ] ],
 139                                         value => 1,
 140                                         force => 1);
 141                                 last;
 142                         }
 143                 }
 144         }
 145         $f->field(name => "attachment", type => "hidden");
 146
 147         return $f, ["Rename", "Cancel"];
 148 } #}}}
 149
 150 sub rename_start ($$$$) { #{{{
 151         my $q=shift;
 152         my $session=shift;
 153         my $attachment=shift;
 154         my $page=shift;
 155
 156         check_canrename($page, $pagesources{$page}, undef, undef,
 157                 $q, $session);
 158
 159         # Save current form state to allow returning to it later
 160         # without losing any edits.
 161         # (But don't save what button was submitted, to avoid
 162         # looping back to here.)
 163         # Note: "_submit" is CGI::FormBuilder internals.
 164         $q->param(-name => "_submit", -value => "");
 165         $session->param(postrename => scalar $q->Vars);
 166         IkiWiki::cgi_savesession($session);
 167
 168         if (defined $attachment) {
 169                 $q->param(-name => "attachment", -value => $attachment);
 170         }
 171         my ($f, $buttons)=rename_form($q, $session, $page);
 172         IkiWiki::showform($f, $buttons, $session, $q);
 173         exit 0;
 174 } #}}}
 175
 176 sub postrename ($;$$$) { #{{{
 177         my $session=shift;
 178         my $src=shift;
 179         my $dest=shift;
 180         my $attachment=shift;
 181
 182         # Load saved form state and return to edit page.
 183         my $postrename=CGI->new($session->param("postrename"));
 184         $session->clear("postrename");
 185         IkiWiki::cgi_savesession($session);
 186
 187         if (defined $dest) {
 188                 if (! $attachment) {
 189                         # They renamed the page they were editing. This requires
 190                         # fixups to the edit form state.
 191                         # Tweak the edit form to be editing the new page.
 192                         $postrename->param("page", $dest);
 193                 }
 194
 195                 # Update edit form content to fix any links present
 196                 # on it.
 197                 $postrename->param("editcontent",
 198                         renamepage_hook($dest, $src, $dest,
 199                                  $postrename->param("editcontent")));
 200
 201                 # Get a new edit token; old was likely invalidated.
 202                 $postrename->param("rcsinfo",
 203                         IkiWiki::rcs_prepedit($pagesources{$dest}));
 204         }
 205
 206         IkiWiki::cgi_editpage($postrename, $session);
 207 } #}}}
 208
 209 sub formbuilder (@) { #{{{
 210         my %params=@_;
 211         my $form=$params{form};
 212
 213         if (defined $form->field("do") && $form->field("do") eq "edit") {
 214                 my $q=$params{cgi};
 215                 my $session=$params{session};
 216
 217                 if ($form->submitted eq "Rename") {
 218                         rename_start($q, $session, 0, $form->field("page"));
 219                 }
 220                 elsif ($form->submitted eq "Rename Attachment") {
 221                         my @selected=$q->param("attachment_select");
 222                         if (@selected > 1) {
 223                                 error(gettext("Only one attachment can be renamed at a time."));
 224                         }
 225                         elsif (! @selected) {
 226                                 error(gettext("Please select the attachment to rename."))
 227                         }
 228                         rename_start($q, $session, 1, $selected[0]);
 229                 }
 230         }
 231 } #}}}
 232
 233 my $renamesummary;
 234
 235 sub formbuilder_setup (@) { #{{{
 236         my %params=@_;
 237         my $form=$params{form};
 238         my $q=$params{cgi};
 239
 240         if (defined $form->field("do") && $form->field("do") eq "edit") {
 241                 # Rename button for the page, and also for attachments.
 242                 push @{$params{buttons}}, "Rename";
 243                 $form->tmpl_param("field-rename" => '<input name="_submit" type="submit" value="Rename Attachment" />');
 244
 245                 if (defined $renamesummary) {
 246                         $form->tmpl_param(message => $renamesummary);
 247                 }
 248         }
 249 } #}}}
 250
 251 sub sessioncgi ($$) { #{{{
 252         my $q=shift;
 253
 254         if ($q->param("do") eq 'rename') {
 255                 my $session=shift;
 256                 my ($form, $buttons)=rename_form($q, $session, $q->param("page"));
 257                 IkiWiki::decode_form_utf8($form);
 258
 259                 if ($form->submitted eq 'Cancel') {
 260                         postrename($session);
 261                 }
 262                 elsif ($form->submitted eq 'Rename' && $form->validate) {
 263                         # Queue of rename actions to perfom.
 264                         my @torename;
 265
 266                         # These untaints are safe because of the checks
 267                         # performed in check_canrename later.
 268                         my $src=$q->param("page");
 269                         my $srcfile=IkiWiki::possibly_foolish_untaint($pagesources{$src});
 270                         my $dest=IkiWiki::possibly_foolish_untaint(titlepage($q->param("new_name")));
 271                         my $destfile=$dest;
 272                         if (! $q->param("attachment")) {
 273                                 my $type=$q->param('type');
 274                                 if (defined $type && length $type && $IkiWiki::hooks{htmlize}{$type}) {
 275                                         $type=IkiWiki::possibly_foolish_untaint($type);
 276                                 }
 277                                 else {
 278                                         my ($ext)=$srcfile=~/\.([^.]+)$/;
 279                                         $type=$ext;
 280                                 }
 281
 282                                 if (! $config{indexpages}) {
 283                                         $destfile.=".".$type;
 284                                 }
 285                                 else {
 286                                         $destfile.="/index.".$type;
 287                                 }
 288                         }
 289                         push @torename, {
 290                                 src => $src,
 291                                 srcfile => $srcfile,
 292                                 dest => $dest,
 293                                 destfile => $destfile,
 294                                 required => 1,
 295                         };
 296
 297                         # See if any subpages need to be renamed.
 298                         if ($q->param("subpages") && $src ne $dest) {
 299                                 foreach my $p (keys %pagesources) {
 300                                         if ($pagesources{$p}=~m/^\Q$src\E\//) {
 301                                                 my $d=$pagesources{$p};
 302                                                 $d=~s/^\Q$src\E\//$dest\//;
 303                                                 push @torename, {
 304                                                         src => $p,
 305                                                         srcfile => $pagesources{$p},
 306                                                         dest => pagename($d),
 307                                                         destfile => $d,
 308                                                         required => 0,
 309                                                 };
 310                                         }
 311                                 }
 312                         }
 313
 314                         require IkiWiki::Render;
 315                         IkiWiki::disable_commit_hook() if $config{rcs};
 316                         my %origpagesources=%pagesources;
 317
 318                         # First file renaming.
 319                         foreach my $rename (@torename) {
 320                                 if ($rename->{required}) {
 321                                         do_rename($rename, $q, $session);
 322                                 }
 323                                 else {
 324                                         eval {do_rename($rename, $q, $session)};
 325                                         if ($@) {
 326                                                 $rename->{error}=$@;
 327                                                 next;
 328                                         }
 329                                 }
 330
 331                                 # Temporarily tweak pagesources to point to
 332                                 # the renamed file, in case fixlinks needs
 333                                 # to edit it.
 334                                 $pagesources{$rename->{src}}=$rename->{destfile};
 335                         }
 336                         IkiWiki::rcs_commit_staged(
 337                                 sprintf(gettext("rename %s to %s"), $srcfile, $destfile),
 338                                 $session->param("name"), $ENV{REMOTE_ADDR}) if $config{rcs};
 339
 340                         # Then link fixups.
 341                         foreach my $rename (@torename) {
 342                                 next if $rename->{src} eq $rename->{dest};
 343                                 next if $rename->{error};
 344                                 foreach my $p (fixlinks($rename, $session)) {
 345                                         # map old page names to new
 346                                         foreach my $r (@torename) {
 347                                                 next if $rename->{error};
 348                                                 if ($r->{src} eq $p) {
 349                                                         $p=$r->{dest};
 350                                                         last;
 351                                                 }
 352                                         }
 353                                         push @{$rename->{fixedlinks}}, $p;
 354                                 }
 355                         }
 356
 357                         # Then refresh.
 358                         %pagesources=%origpagesources;
 359                         if ($config{rcs}) {
 360                                 IkiWiki::enable_commit_hook();
 361                                 IkiWiki::rcs_update();
 362                         }
 363                         IkiWiki::refresh();
 364                         IkiWiki::saveindex();
 365
 366                         # Find pages with remaining, broken links.
 367                         foreach my $rename (@torename) {
 368                                 next if $rename->{src} eq $rename->{dest};
 369
 370                                 foreach my $page (keys %links) {
 371                                         my $broken=0;
 372                                         foreach my $link (@{$links{$page}}) {
 373                                                 my $bestlink=bestlink($page, $link);
 374                                                 if ($bestlink eq $rename->{src}) {
 375                                                         push @{$rename->{brokenlinks}}, $page;
 376                                                         last;
 377                                                 }
 378                                         }
 379                                 }
 380                         }
 381
 382                         # Generate a summary, that will be shown at the top
 383                         # of the edit template.
 384                         $renamesummary="";
 385                         foreach my $rename (@torename) {
 386                                 my $template=template("renamesummary.tmpl");
 387                                 $template->param(src => $rename->{srcfile});
 388                                 $template->param(dest => $rename->{destfile});
 389                                 $template->param(error => $rename->{error});
 390                                 if ($rename->{src} ne $rename->{dest}) {
 391                                         $template->param(brokenlinks_checked => 1);
 392                                         $template->param(brokenlinks => [
 393                                                 map {
 394                                                         {
 395                                                                 page => htmllink($rename->{dest}, $rename->{dest}, $_,
 396                                                                                 noimageinline => 1)
 397                                                         }
 398                                                 } @{$rename->{brokenlinks}}
 399                                         ]);
 400                                         $template->param(fixedlinks => [
 401                                                 map {
 402                                                         {
 403                                                                 page => htmllink($rename->{dest}, $rename->{dest}, $_,
 404                                                                                 noimageinline => 1)
 405                                                         }
 406                                                 } @{$rename->{fixedlinks}}
 407                                         ]);
 408                                 }
 409                                 $renamesummary.=$template->output;
 410                         }
 411
 412                         postrename($session, $src, $dest, $q->param("attachment"));
 413                 }
 414                 else {
 415                         IkiWiki::showform($form, $buttons, $session, $q);
 416                 }
 417
 418                 exit 0;
 419         }
 420 } #}}}
 421
 422 sub renamepage_hook ($$$$) { #{{{
 423         my ($page, $src, $dest, $content)=@_;
 424
 425         IkiWiki::run_hooks(renamepage => sub {
 426                 $content=shift->(
 427                         page => $page,
 428                         oldpage => $src,
 429                         newpage => $dest,
 430                         content => $content,
 431                 );
 432         });
 433
 434         return $content;
 435 }# }}}
 436
 437 sub do_rename ($$$) { #{{{
 438         my $rename=shift;
 439         my $q=shift;
 440         my $session=shift;
 441
 442         # First, check if this rename is allowed.
 443         check_canrename($rename->{src},
 444                 $rename->{srcfile},
 445                 $rename->{dest},
 446                 $rename->{destfile},
 447                 $q, $session);
 448
 449         # Ensure that the dest directory exists and is ok.
 450         IkiWiki::prep_writefile($rename->{destfile}, $config{srcdir});
 451
 452         if ($config{rcs}) {
 453                 IkiWiki::rcs_rename($rename->{srcfile}, $rename->{destfile});
 454         }
 455         else {
 456                 if (! rename($config{srcdir}."/".$rename->{srcfile},
 457                              $config{srcdir}."/".$rename->{destfile})) {
 458                         error("rename: $!");
 459                 }
 460         }
 461
 462 } # }}}
 463
 464 sub fixlinks ($$$) { #{{{
 465         my $rename=shift;
 466         my $session=shift;
 467
 468         my @fixedlinks;
 469
 470         foreach my $page (keys %links) {
 471                 my $needfix=0;
 472                 foreach my $link (@{$links{$page}}) {
 473                         my $bestlink=bestlink($page, $link);
 474                         if ($bestlink eq $rename->{src}) {
 475                                 $needfix=1;
 476                                 last;
 477                         }
 478                 }
 479                 if ($needfix) {
 480                         my $file=$pagesources{$page};
 481                         my $oldcontent=readfile($config{srcdir}."/".$file);
 482                         my $content=renamepage_hook($page, $rename->{src}, $rename->{dest}, $oldcontent);
 483                         if ($oldcontent ne $content) {
 484                                 my $token=IkiWiki::rcs_prepedit($file);
 485                                 eval { writefile($file, $config{srcdir}, $content) };
 486                                 next if $@;
 487                                 my $conflict=IkiWiki::rcs_commit(
 488                                         $file,
 489                                         sprintf(gettext("update for rename of %s to %s"), $rename->{srcfile}, $rename->{destfile}),
 490                                         $token,
 491                                         $session->param("name"),
 492                                         $ENV{REMOTE_ADDR}
 493                                 );
 494                                 push @fixedlinks, $page if ! defined $conflict;
 495                         }
 496                 }
 497         }
 498
 499         return @fixedlinks;
 500 } #}}}
 501
 502 1