git.oblomov.eu Git - ikiwiki/blob - IkiWiki/Plugin/inline.pm

   1 #!/usr/bin/perl
   2 # Page inlining and blogging.
   3 package IkiWiki::Plugin::inline;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use IkiWiki 3.00;
   9 use URI;
  10
  11 my %knownfeeds;
  12 my %page_numfeeds;
  13 my @inline;
  14 my $nested=0;
  15
  16 sub import {
  17         hook(type => "getopt", id => "inline", call => \&getopt);
  18         hook(type => "getsetup", id => "inline", call => \&getsetup);
  19         hook(type => "checkconfig", id => "inline", call => \&checkconfig);
  20         hook(type => "sessioncgi", id => "inline", call => \&sessioncgi);
  21         hook(type => "preprocess", id => "inline",
  22                 call => \&IkiWiki::preprocess_inline, scan => 1);
  23         hook(type => "pagetemplate", id => "inline",
  24                 call => \&IkiWiki::pagetemplate_inline);
  25         hook(type => "format", id => "inline", call => \&format, first => 1);
  26         # Hook to change to do pinging since it's called late.
  27         # This ensures each page only pings once and prevents slow
  28         # pings interrupting page builds.
  29         hook(type => "change", id => "inline", call => \&IkiWiki::pingurl);
  30 }
  31
  32 sub getopt () {
  33         eval q{use Getopt::Long};
  34         error($@) if $@;
  35         Getopt::Long::Configure('pass_through');
  36         GetOptions(
  37                 "rss!" => \$config{rss},
  38                 "atom!" => \$config{atom},
  39                 "allowrss!" => \$config{allowrss},
  40                 "allowatom!" => \$config{allowatom},
  41                 "pingurl=s" => sub {
  42                         push @{$config{pingurl}}, $_[1];
  43                 },
  44         );
  45 }
  46
  47 sub getsetup () {
  48         return
  49                 plugin => {
  50                         safe => 1,
  51                         rebuild => undef,
  52                         section => "core",
  53                 },
  54                 rss => {
  55                         type => "boolean",
  56                         example => 0,
  57                         description => "enable rss feeds by default?",
  58                         safe => 1,
  59                         rebuild => 1,
  60                 },
  61                 atom => {
  62                         type => "boolean",
  63                         example => 0,
  64                         description => "enable atom feeds by default?",
  65                         safe => 1,
  66                         rebuild => 1,
  67                 },
  68                 allowrss => {
  69                         type => "boolean",
  70                         example => 0,
  71                         description => "allow rss feeds to be used?",
  72                         safe => 1,
  73                         rebuild => 1,
  74                 },
  75                 allowatom => {
  76                         type => "boolean",
  77                         example => 0,
  78                         description => "allow atom feeds to be used?",
  79                         safe => 1,
  80                         rebuild => 1,
  81                 },
  82                 pingurl => {
  83                         type => "string",
  84                         example => "http://rpc.technorati.com/rpc/ping",
  85                         description => "urls to ping (using XML-RPC) on feed update",
  86                         safe => 1,
  87                         rebuild => 0,
  88                 },
  89 }
  90
  91 sub checkconfig () {
  92         if (($config{rss} || $config{atom}) && ! length $config{url}) {
  93                 error(gettext("Must specify url to wiki with --url when using --rss or --atom"));
  94         }
  95         if ($config{rss}) {
  96                 push @{$config{wiki_file_prune_regexps}}, qr/\.rss$/;
  97         }
  98         if ($config{atom}) {
  99                 push @{$config{wiki_file_prune_regexps}}, qr/\.atom$/;
 100         }
 101         if (! exists $config{pingurl}) {
 102                 $config{pingurl}=[];
 103         }
 104 }
 105
 106 sub format (@) {
 107         my %params=@_;
 108
 109         # Fill in the inline content generated earlier. This is actually an
 110         # optimisation.
 111         $params{content}=~s{<div class="inline" id="([^"]+)"></div>}{
 112                 delete @inline[$1,]
 113         }eg;
 114         return $params{content};
 115 }
 116
 117 sub sessioncgi ($$) {
 118         my $q=shift;
 119         my $session=shift;
 120
 121         if ($q->param('do') eq 'blog') {
 122                 my $page=titlepage(decode_utf8($q->param('title')));
 123                 $page=~s/(\/)/"__".ord($1)."__"/eg; # don't create subdirs
 124                 # if the page already exists, munge it to be unique
 125                 my $from=$q->param('from');
 126                 my $add="";
 127                 while (exists $IkiWiki::pagecase{lc($from."/".$page.$add)}) {
 128                         $add=1 unless length $add;
 129                         $add++;
 130                 }
 131                 $q->param('page', "/$from/$page$add");
 132                 # now go create the page
 133                 $q->param('do', 'create');
 134                 # make sure the editpage plugin is loaded
 135                 if (IkiWiki->can("cgi_editpage")) {
 136                         IkiWiki::cgi_editpage($q, $session);
 137                 }
 138                 else {
 139                         error(gettext("page editing not allowed"));
 140                 }
 141                 exit;
 142         }
 143 }
 144
 145 # Back to ikiwiki namespace for the rest, this code is very much
 146 # internal to ikiwiki even though it's separated into a plugin.
 147 package IkiWiki;
 148
 149 my %toping;
 150 my %feedlinks;
 151
 152 sub preprocess_inline (@) {
 153         my %params=@_;
 154
 155         if (! exists $params{pages} && ! exists $params{pagenames}) {
 156                 error gettext("missing pages parameter");
 157         }
 158
 159         if (! defined wantarray) {
 160                 # Running in scan mode: only do the essentials
 161
 162                 if (yesno($params{trail}) && IkiWiki::Plugin::trail->can("preprocess_trailitems")) {
 163                         # default to sorting age, the same as inline itself,
 164                         # but let the params override that
 165                         IkiWiki::Plugin::trail::preprocess_trailitems(sort => 'age', %params);
 166                 }
 167
 168                 return;
 169         }
 170
 171         if (yesno($params{trail}) && IkiWiki::Plugin::trail->can("preprocess_trailitems")) {
 172                 scalar IkiWiki::Plugin::trail::preprocess_trailitems(sort => 'age', %params);
 173         }
 174
 175         my $raw=yesno($params{raw});
 176         my $archive=yesno($params{archive});
 177         my $rss=(($config{rss} || $config{allowrss}) && exists $params{rss}) ? yesno($params{rss}) : $config{rss};
 178         my $atom=(($config{atom} || $config{allowatom}) && exists $params{atom}) ? yesno($params{atom}) : $config{atom};
 179         my $quick=exists $params{quick} ? yesno($params{quick}) : 0;
 180         my $feeds=exists $params{feeds} ? yesno($params{feeds}) : !$quick && ! $raw;
 181         my $emptyfeeds=exists $params{emptyfeeds} ? yesno($params{emptyfeeds}) : 1;
 182         my $feedonly=yesno($params{feedonly});
 183         if (! exists $params{show} && ! $archive) {
 184                 $params{show}=10;
 185         }
 186         if (! exists $params{feedshow} && exists $params{show}) {
 187                 $params{feedshow}=$params{show};
 188         }
 189         my $desc;
 190         if (exists $params{description}) {
 191                 $desc = $params{description}
 192         }
 193         else {
 194                 $desc = $config{wikiname};
 195         }
 196         my $actions=yesno($params{actions});
 197         if (exists $params{template}) {
 198                 $params{template}=~s/[^-_a-zA-Z0-9]+//g;
 199         }
 200         else {
 201                 $params{template} = $archive ? "archivepage" : "inlinepage";
 202         }
 203
 204         my @list;
 205
 206         if (exists $params{pagenames}) {
 207                 foreach my $p (qw(sort pages)) {
 208                         if (exists $params{$p}) {
 209                                 error sprintf(gettext("the %s and %s parameters cannot be used together"),
 210                                         "pagenames", $p);
 211                         }
 212                 }
 213
 214                 @list = map { bestlink($params{page}, $_) }
 215                         split ' ', $params{pagenames};
 216
 217                 if (yesno($params{reverse})) {
 218                         @list=reverse(@list);
 219                 }
 220
 221                 foreach my $p (@list) {
 222                         add_depends($params{page}, $p, deptype($quick ? "presence" : "content"));
 223                 }
 224         }
 225         else {
 226                 my $num=0;
 227                 if ($params{show}) {
 228                         $num=$params{show};
 229                 }
 230                 if ($params{feedshow} && $num < $params{feedshow} && $num > 0) {
 231                         $num=$params{feedshow};
 232                 }
 233                 if ($params{skip} && $num) {
 234                         $num+=$params{skip};
 235                 }
 236
 237                 @list = pagespec_match_list($params{page}, $params{pages},
 238                         deptype => deptype($quick ? "presence" : "content"),
 239                         filter => sub { $_[0] eq $params{page} },
 240                         sort => exists $params{sort} ? $params{sort} : "age",
 241                         reverse => yesno($params{reverse}),
 242                         ($num ? (num => $num) : ()),
 243                 );
 244         }
 245
 246         if (exists $params{skip}) {
 247                 @list=@list[$params{skip} .. $#list];
 248         }
 249
 250         my @feedlist;
 251         if ($feeds) {
 252                 if (exists $params{feedshow} &&
 253                     $params{feedshow} && @list > $params{feedshow}) {
 254                         @feedlist=@list[0..$params{feedshow} - 1];
 255                 }
 256                 else {
 257                         @feedlist=@list;
 258                 }
 259         }
 260
 261         if ($params{show} && @list > $params{show}) {
 262                 @list=@list[0..$params{show} - 1];
 263         }
 264
 265         if ($feeds && exists $params{feedpages}) {
 266                 @feedlist = pagespec_match_list(
 267                         $params{page}, "($params{pages}) and ($params{feedpages})",
 268                         deptype => deptype($quick ? "presence" : "content"),
 269                         list => \@feedlist,
 270                 );
 271         }
 272
 273         my ($feedbase, $feednum);
 274         if ($feeds) {
 275                 # Ensure that multiple feeds on a page go to unique files.
 276
 277                 # Feedfile can lead to conflicts if usedirs is not enabled,
 278                 # so avoid supporting it in that case.
 279                 delete $params{feedfile} if ! $config{usedirs};
 280                 # Tight limits on legal feedfiles, to avoid security issues
 281                 # and conflicts.
 282                 if (defined $params{feedfile}) {
 283                         if ($params{feedfile} =~ /\// ||
 284                             $params{feedfile} !~ /$config{wiki_file_regexp}/) {
 285                                 error("illegal feedfile");
 286                         }
 287                         $params{feedfile}=possibly_foolish_untaint($params{feedfile});
 288                 }
 289                 $feedbase=targetpage($params{page}, "", $params{feedfile});
 290
 291                 my $feedid=join("\0", $feedbase, map { $_."\0".$params{$_} } sort keys %params);
 292                 if (exists $knownfeeds{$feedid}) {
 293                         $feednum=$knownfeeds{$feedid};
 294                 }
 295                 else {
 296                         if (exists $page_numfeeds{$params{destpage}}{$feedbase}) {
 297                                 if ($feeds) {
 298                                         $feednum=$knownfeeds{$feedid}=++$page_numfeeds{$params{destpage}}{$feedbase};
 299                                 }
 300                         }
 301                         else {
 302                                 $feednum=$knownfeeds{$feedid}="";
 303                                 if ($feeds) {
 304                                         $page_numfeeds{$params{destpage}}{$feedbase}=1;
 305                                 }
 306                         }
 307                 }
 308         }
 309
 310         my ($rssurl, $atomurl, $rssdesc, $atomdesc);
 311         if ($feeds) {
 312                 if ($rss) {
 313                         $rssurl=abs2rel($feedbase."rss".$feednum, dirname(htmlpage($params{destpage})));
 314                         $rssdesc = sprintf(gettext("%s (RSS feed)"), $desc);
 315                 }
 316                 if ($atom) {
 317                         $atomurl=abs2rel($feedbase."atom".$feednum, dirname(htmlpage($params{destpage})));
 318                         $atomdesc = sprintf(gettext("%s (Atom feed)"), $desc);
 319                 }
 320         }
 321
 322         my $ret="";
 323
 324         if (length $config{cgiurl} && ! $params{preview} && (exists $params{rootpage} ||
 325             (exists $params{postform} && yesno($params{postform}))) &&
 326             IkiWiki->can("cgi_editpage")) {
 327                 # Add a blog post form, with feed buttons.
 328                 my $formtemplate=template_depends("blogpost.tmpl", $params{page}, blind_cache => 1);
 329                 $formtemplate->param(cgiurl => IkiWiki::cgiurl());
 330                 $formtemplate->param(rootpage => rootpage(%params));
 331                 if ($feeds) {
 332                         if ($rss) {
 333                                 $formtemplate->param(rssurl => $rssurl);
 334                                 $formtemplate->param(rssdesc => $rssdesc);
 335                         }
 336                         if ($atom) {
 337                                 $formtemplate->param(atomurl => $atomurl);
 338                                 $formtemplate->param(atomdesc => $atomdesc);
 339                         }
 340                 }
 341                 if (exists $params{postformtext}) {
 342                         $formtemplate->param(postformtext =>
 343                                 $params{postformtext});
 344                 }
 345                 else {
 346                         $formtemplate->param(postformtext =>
 347                                 gettext("Add a new post titled:"));
 348                 }
 349                 if (exists $params{id}) {
 350                         $formtemplate->param(postformid =>
 351                                 $params{id});
 352                 }
 353                 $ret.=$formtemplate->output;
 354
 355                 # The post form includes the feed buttons, so
 356                 # emptyfeeds cannot be hidden.
 357                 $emptyfeeds=1;
 358         }
 359         elsif ($feeds && !$params{preview} && ($emptyfeeds || @feedlist)) {
 360                 # Add feed buttons.
 361                 my $linktemplate=template_depends("feedlink.tmpl", $params{page}, blind_cache => 1);
 362                 if ($rss) {
 363                         $linktemplate->param(rssurl => $rssurl);
 364                         $linktemplate->param(rssdesc => $rssdesc);
 365                 }
 366                 if ($atom) {
 367                         $linktemplate->param(atomurl => $atomurl);
 368                         $linktemplate->param(atomdesc => $atomdesc);
 369                 }
 370                 if (exists $params{id}) {
 371                         $linktemplate->param(id => $params{id});
 372                 }
 373                 $ret.=$linktemplate->output;
 374         }
 375
 376         if (! $feedonly) {
 377                 my $template;
 378                 if (! $raw) {
 379                         # cannot use wiki pages as templates; template not sanitized due to
 380                         # format hook hack
 381                         eval {
 382                                 $template=template_depends($params{template}.".tmpl", $params{page},
 383                                         blind_cache => 1);
 384                         };
 385                         if ($@) {
 386                                 error sprintf(gettext("failed to process template %s"), $params{template}.".tmpl").": $@";
 387                         }
 388                 }
 389                 my $needcontent=$raw || (!($archive && $quick) && $template->query(name => 'content'));
 390
 391                 foreach my $page (@list) {
 392                         my $file = $pagesources{$page};
 393                         my $type = pagetype($file);
 394                         if (! $raw) {
 395                                 if ($needcontent) {
 396                                         # Get the content before populating the
 397                                         # template, since getting the content uses
 398                                         # the same template if inlines are nested.
 399                                         my $content=get_inline_content($page, $params{destpage});
 400                                         $template->param(content => $content);
 401                                 }
 402                                 $template->param(pageurl => urlto($page, $params{destpage}));
 403                                 $template->param(inlinepage => $page);
 404                                 $template->param(title => pagetitle(basename($page)));
 405                                 $template->param(ctime => displaytime($pagectime{$page}, $params{timeformat}, 1));
 406                                 $template->param(mtime => displaytime($pagemtime{$page}, $params{timeformat}));
 407                                 $template->param(first => 1) if $page eq $list[0];
 408                                 $template->param(last => 1) if $page eq $list[$#list];
 409                                 $template->param(html5 => $config{html5});
 410
 411                                 if ($actions) {
 412                                         my $file = $pagesources{$page};
 413                                         my $type = pagetype($file);
 414                                         if ($config{discussion}) {
 415                                                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/i &&
 416                                                     (length $config{cgiurl} ||
 417                                                      exists $pagesources{$page."/".lc($config{discussionpage})})) {
 418                                                         $template->param(have_actions => 1);
 419                                                         $template->param(discussionlink =>
 420                                                                 htmllink($page,
 421                                                                         $params{destpage},
 422                                                                         $config{discussionpage},
 423                                                                         noimageinline => 1,
 424                                                                         forcesubpage => 1));
 425                                                 }
 426                                         }
 427                                         if (length $config{cgiurl} &&
 428                                             defined $type &&
 429                                             IkiWiki->can("cgi_editpage")) {
 430                                                 $template->param(have_actions => 1);
 431                                                 $template->param(editurl => cgiurl(do => "edit", page => $page));
 432
 433                                         }
 434                                 }
 435
 436                                 run_hooks(pagetemplate => sub {
 437                                         shift->(page => $page, destpage => $params{destpage},
 438                                                 template => $template,);
 439                                 });
 440
 441                                 $ret.=$template->output;
 442                                 $template->clear_params;
 443                         }
 444                         else {
 445                                 if (defined $type) {
 446                                         $ret.="\n".
 447                                               linkify($page, $params{destpage},
 448                                               preprocess($page, $params{destpage},
 449                                               filter($page, $params{destpage},
 450                                               readfile(srcfile($file)))));
 451                                 }
 452                                 else {
 453                                         $ret.="\n".
 454                                               readfile(srcfile($file));
 455                                 }
 456                         }
 457                 }
 458         }
 459
 460         if ($feeds && ($emptyfeeds || @feedlist)) {
 461                 if ($rss) {
 462                         my $rssp=$feedbase."rss".$feednum;
 463                         will_render($params{destpage}, $rssp);
 464                         if (! $params{preview}) {
 465                                 writefile($rssp, $config{destdir},
 466                                         genfeed("rss",
 467                                                 $config{url}."/".$rssp, $desc, $params{guid}, $params{page}, @feedlist));
 468                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 469                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/rss+xml" title="$rssdesc" href="$rssurl" />};
 470                         }
 471                 }
 472                 if ($atom) {
 473                         my $atomp=$feedbase."atom".$feednum;
 474                         will_render($params{destpage}, $atomp);
 475                         if (! $params{preview}) {
 476                                 writefile($atomp, $config{destdir},
 477                                         genfeed("atom", $config{url}."/".$atomp, $desc, $params{guid}, $params{page}, @feedlist));
 478                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 479                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/atom+xml" title="$atomdesc" href="$atomurl" />};
 480                         }
 481                 }
 482         }
 483
 484         clear_inline_content_cache();
 485
 486         return $ret if $raw || $nested;
 487         push @inline, $ret;
 488         return "<div class=\"inline\" id=\"$#inline\"></div>\n\n";
 489 }
 490
 491 sub pagetemplate_inline (@) {
 492         my %params=@_;
 493         my $page=$params{page};
 494         my $template=$params{template};
 495
 496         $template->param(feedlinks => $feedlinks{$page})
 497                 if exists $feedlinks{$page} && $template->query(name => "feedlinks");
 498 }
 499
 500 {
 501 my %inline_content;
 502 my $cached_destpage="";
 503
 504 sub get_inline_content ($$) {
 505         my $page=shift;
 506         my $destpage=shift;
 507
 508         if (exists $inline_content{$page} && $cached_destpage eq $destpage) {
 509                 return $inline_content{$page};
 510         }
 511
 512         my $file=$pagesources{$page};
 513         my $type=pagetype($file);
 514         my $ret="";
 515         if (defined $type) {
 516                 $nested++;
 517                 $ret=htmlize($page, $destpage, $type,
 518                        linkify($page, $destpage,
 519                        preprocess($page, $destpage,
 520                        filter($page, $destpage,
 521                        readfile(srcfile($file))))));
 522                 $nested--;
 523                 if (isinternal($page)) {
 524                         # make inlined text of internal pages searchable
 525                         run_hooks(indexhtml => sub {
 526                                 shift->(page => $page, destpage => $destpage,
 527                                         content => $ret);
 528                         });
 529                 }
 530         }
 531
 532         if ($cached_destpage ne $destpage) {
 533                 clear_inline_content_cache();
 534                 $cached_destpage=$destpage;
 535         }
 536         return $inline_content{$page}=$ret;
 537 }
 538
 539 sub clear_inline_content_cache () {
 540         %inline_content=();
 541 }
 542
 543 }
 544
 545 sub date_822 ($) {
 546         my $time=shift;
 547
 548         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 549         POSIX::setlocale(&POSIX::LC_TIME, "C");
 550         my $ret=POSIX::strftime("%a, %d %b %Y %H:%M:%S %z", localtime($time));
 551         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 552         return $ret;
 553 }
 554
 555 sub absolute_urls ($$) {
 556         # needed because rss sucks
 557         my $html=shift;
 558         my $baseurl=shift;
 559
 560         my $url=$baseurl;
 561         $url=~s/[^\/]+$//;
 562         my $urltop; # calculated if needed
 563
 564         my $ret="";
 565
 566         eval q{use HTML::Parser; use HTML::Tagset};
 567         die $@ if $@;
 568         my $p = HTML::Parser->new(api_version => 3);
 569         $p->handler(default => sub { $ret.=join("", @_) }, "text");
 570         $p->handler(start => sub {
 571                 my ($tagname, $pos, $text) = @_;
 572                 if (ref $HTML::Tagset::linkElements{$tagname}) {
 573                         while (4 <= @$pos) {
 574                                 # use attribute sets from right to left
 575                                 # to avoid invalidating the offsets
 576                                 # when replacing the values
 577                                 my ($k_offset, $k_len, $v_offset, $v_len) =
 578                                         splice(@$pos, -4);
 579                                 my $attrname = lc(substr($text, $k_offset, $k_len));
 580                                 next unless grep { $_ eq $attrname } @{$HTML::Tagset::linkElements{$tagname}};
 581                                 next unless $v_offset; # 0 v_offset means no value
 582                                 my $v = substr($text, $v_offset, $v_len);
 583                                 $v =~ s/^([\'\"])(.*)\1$/$2/;
 584                                 eval q{use HTML::Entities};
 585                                 my $dv = decode_entities($v);
 586                                 if ($dv=~/^#/) {
 587                                         $v=$baseurl.$v; # anchor
 588                                 }
 589                                 elsif ($dv=~/^(?!\w+:)[^\/]/) {
 590                                         $v=$url.$v; # relative url
 591                                 }
 592                                 elsif ($dv=~/^\//) {
 593                                         if (! defined $urltop) {
 594                                                 # what is the non path part of the url?
 595                                                 my $top_uri = URI->new($url);
 596                                                 $top_uri->path_query(""); # reset the path
 597                                                 $urltop = $top_uri->as_string;
 598                                         }
 599                                         $v=$urltop.$v; # url relative to top of site
 600                                 }
 601                                 $v =~ s/\"/&quot;/g; # since we quote with ""
 602                                 substr($text, $v_offset, $v_len) = qq("$v");
 603                         }
 604                 }
 605                 $ret.=$text;
 606         }, "tagname, tokenpos, text");
 607         $p->parse($html);
 608         $p->eof;
 609
 610         return $ret;
 611 }
 612
 613 sub genfeed ($$$$$@) {
 614         my $feedtype=shift;
 615         my $feedurl=shift;
 616         my $feeddesc=shift;
 617         my $guid=shift;
 618         my $page=shift;
 619         my @pages=@_;
 620
 621         my $url=URI->new(encode_utf8(urlto($page,"",1)));
 622
 623         my $itemtemplate=template_depends($feedtype."item.tmpl", $page, blind_cache => 1);
 624         my $content="";
 625         my $lasttime = 0;
 626         foreach my $p (@pages) {
 627                 my $u=URI->new(encode_utf8(urlto($p, "", 1)));
 628                 my $pcontent = absolute_urls(get_inline_content($p, $page), $url);
 629
 630                 $itemtemplate->param(
 631                         title => pagetitle(basename($p)),
 632                         url => $u,
 633                         permalink => $u,
 634                         cdate_822 => date_822($pagectime{$p}),
 635                         mdate_822 => date_822($pagemtime{$p}),
 636                         cdate_3339 => date_3339($pagectime{$p}),
 637                         mdate_3339 => date_3339($pagemtime{$p}),
 638                 );
 639
 640                 if (exists $pagestate{$p}) {
 641                         if (exists $pagestate{$p}{meta}{guid}) {
 642                                 eval q{use HTML::Entities};
 643                                 $itemtemplate->param(guid => HTML::Entities::encode_numeric($pagestate{$p}{meta}{guid}));
 644                         }
 645
 646                         if (exists $pagestate{$p}{meta}{updated}) {
 647                                 $itemtemplate->param(mdate_822 => date_822($pagestate{$p}{meta}{updated}));
 648                                 $itemtemplate->param(mdate_3339 => date_3339($pagestate{$p}{meta}{updated}));
 649                         }
 650                 }
 651
 652                 if ($itemtemplate->query(name => "enclosure")) {
 653                         my $file=$pagesources{$p};
 654                         my $type=pagetype($file);
 655                         if (defined $type) {
 656                                 $itemtemplate->param(content => $pcontent);
 657                         }
 658                         else {
 659                                 my $size=(srcfile_stat($file))[8];
 660                                 my $mime="unknown";
 661                                 eval q{use File::MimeInfo};
 662                                 if (! $@) {
 663                                         $mime = mimetype($file);
 664                                 }
 665                                 $itemtemplate->param(
 666                                         enclosure => $u,
 667                                         type => $mime,
 668                                         length => $size,
 669                                 );
 670                         }
 671                 }
 672                 else {
 673                         $itemtemplate->param(content => $pcontent);
 674                 }
 675
 676                 run_hooks(pagetemplate => sub {
 677                         shift->(page => $p, destpage => $page,
 678                                 template => $itemtemplate);
 679                 });
 680
 681                 $content.=$itemtemplate->output;
 682                 $itemtemplate->clear_params;
 683
 684                 $lasttime = $pagemtime{$p} if $pagemtime{$p} > $lasttime;
 685         }
 686
 687         my $template=template_depends($feedtype."page.tmpl", $page, blind_cache => 1);
 688         $template->param(
 689                 title => $page ne "index" ? pagetitle($page) : $config{wikiname},
 690                 wikiname => $config{wikiname},
 691                 pageurl => $url,
 692                 content => $content,
 693                 feeddesc => $feeddesc,
 694                 guid => $guid,
 695                 feeddate => date_3339($lasttime),
 696                 feedurl => $feedurl,
 697         );
 698         run_hooks(pagetemplate => sub {
 699                 shift->(page => $page, destpage => $page,
 700                         template => $template);
 701         });
 702
 703         return $template->output;
 704 }
 705
 706 sub pingurl (@) {
 707         return unless @{$config{pingurl}} && %toping;
 708
 709         eval q{require RPC::XML::Client};
 710         if ($@) {
 711                 debug(gettext("RPC::XML::Client not found, not pinging"));
 712                 return;
 713         }
 714
 715         # daemonize here so slow pings don't slow down wiki updates
 716         defined(my $pid = fork) or error("Can't fork: $!");
 717         return if $pid;
 718         chdir '/';
 719         POSIX::setsid() or error("Can't start a new session: $!");
 720         open STDIN, '/dev/null';
 721         open STDOUT, '>/dev/null';
 722         open STDERR, '>&STDOUT' or error("Can't dup stdout: $!");
 723
 724         # Don't need to keep a lock on the wiki as a daemon.
 725         IkiWiki::unlockwiki();
 726
 727         foreach my $page (keys %toping) {
 728                 my $title=pagetitle(basename($page), 0);
 729                 my $url=urlto($page, "", 1);
 730                 foreach my $pingurl (@{$config{pingurl}}) {
 731                         debug("Pinging $pingurl for $page");
 732                         eval {
 733                                 my $client = RPC::XML::Client->new($pingurl);
 734                                 my $req = RPC::XML::request->new('weblogUpdates.ping',
 735                                         $title, $url);
 736                                 my $res = $client->send_request($req);
 737                                 if (! ref $res) {
 738                                         error("Did not receive response to ping");
 739                                 }
 740                                 my $r=$res->value;
 741                                 if (! exists $r->{flerror} || $r->{flerror}) {
 742                                         error("Ping rejected: ".(exists $r->{message} ? $r->{message} : "[unknown reason]"));
 743                                 }
 744                         };
 745                         if ($@) {
 746                                 error "Ping failed: $@";
 747                         }
 748                 }
 749         }
 750
 751         exit 0; # daemon done
 752 }
 753
 754
 755 sub rootpage (@) {
 756         my %params=@_;
 757
 758         my $rootpage;
 759         if (exists $params{rootpage}) {
 760                 $rootpage=bestlink($params{page}, $params{rootpage});
 761                 if (!length $rootpage) {
 762                         $rootpage=$params{rootpage};
 763                 }
 764         }
 765         else {
 766                 $rootpage=$params{page};
 767         }
 768         return $rootpage;
 769 }
 770
 771 1