git.oblomov.eu Git - ikiwiki/blob - IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use Fcntl q{:flock};
   9 use URI::Escape q{uri_escape_utf8};
  10 use POSIX ();
  11 use Storable;
  12 use open qw{:utf8 :std};
  13
  14 use vars qw{%config %links %oldlinks %pagemtime %pagectime %pagecase
  15         %pagestate %wikistate %renderedfiles %oldrenderedfiles
  16         %pagesources %delpagesources %destsources %depends %depends_simple
  17         @mass_depends %hooks %forcerebuild %loaded_plugins %typedlinks
  18         %oldtypedlinks %autofiles @underlayfiles $lastrev $phase};
  19
  20 use Exporter q{import};
  21 our @EXPORT = qw(hook debug error htmlpage template template_depends
  22         deptype add_depends pagespec_match pagespec_match_list bestlink
  23         htmllink readfile writefile pagetype srcfile pagename
  24         displaytime strftime_utf8 will_render gettext ngettext urlto targetpage
  25         add_underlay pagetitle titlepage linkpage newpagefile
  26         inject add_link add_autofile useragent
  27         %config %links %pagestate %wikistate %renderedfiles
  28         %pagesources %destsources %typedlinks);
  29 our $VERSION = 3.00; # plugin interface version, next is ikiwiki version
  30 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  31 our $installdir='/usr'; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  32
  33 # Page dependency types.
  34 our $DEPEND_CONTENT=1;
  35 our $DEPEND_PRESENCE=2;
  36 our $DEPEND_LINKS=4;
  37
  38 # Phases of processing.
  39 sub PHASE_SCAN () { 0 }
  40 sub PHASE_RENDER () { 1 }
  41 $phase = PHASE_SCAN;
  42
  43 # Optimisation.
  44 use Memoize;
  45 memoize("abs2rel");
  46 memoize("sortspec_translate");
  47 memoize("pagespec_translate");
  48 memoize("template_file");
  49
  50 sub getsetup () {
  51         wikiname => {
  52                 type => "string",
  53                 default => "wiki",
  54                 description => "name of the wiki",
  55                 safe => 1,
  56                 rebuild => 1,
  57         },
  58         adminemail => {
  59                 type => "string",
  60                 default => undef,
  61                 example => 'me@example.com',
  62                 description => "contact email for wiki",
  63                 safe => 1,
  64                 rebuild => 0,
  65         },
  66         adminuser => {
  67                 type => "string",
  68                 default => [],
  69                 description => "users who are wiki admins",
  70                 safe => 1,
  71                 rebuild => 0,
  72         },
  73         banned_users => {
  74                 type => "string",
  75                 default => [],
  76                 description => "users who are banned from the wiki",
  77                 safe => 1,
  78                 rebuild => 0,
  79         },
  80         srcdir => {
  81                 type => "string",
  82                 default => undef,
  83                 example => "$ENV{HOME}/wiki",
  84                 description => "where the source of the wiki is located",
  85                 safe => 0, # path
  86                 rebuild => 1,
  87         },
  88         destdir => {
  89                 type => "string",
  90                 default => undef,
  91                 example => "/var/www/wiki",
  92                 description => "where to build the wiki",
  93                 safe => 0, # path
  94                 rebuild => 1,
  95         },
  96         url => {
  97                 type => "string",
  98                 default => '',
  99                 example => "http://example.com/wiki",
 100                 description => "base url to the wiki",
 101                 safe => 1,
 102                 rebuild => 1,
 103         },
 104         cgiurl => {
 105                 type => "string",
 106                 default => '',
 107                 example => "http://example.com/wiki/ikiwiki.cgi",
 108                 description => "url to the ikiwiki.cgi",
 109                 safe => 1,
 110                 rebuild => 1,
 111         },
 112         reverse_proxy => {
 113                 type => "boolean",
 114                 default => 0,
 115                 description => "do not adjust cgiurl if CGI is accessed via different URL",
 116                 advanced => 0,
 117                 safe => 1,
 118                 rebuild => 0, # only affects CGI requests
 119         },
 120         cgi_wrapper => {
 121                 type => "string",
 122                 default => '',
 123                 example => "/var/www/wiki/ikiwiki.cgi",
 124                 description => "filename of cgi wrapper to generate",
 125                 safe => 0, # file
 126                 rebuild => 0,
 127         },
 128         cgi_wrappermode => {
 129                 type => "string",
 130                 default => '06755',
 131                 description => "mode for cgi_wrapper (can safely be made suid)",
 132                 safe => 0,
 133                 rebuild => 0,
 134         },
 135         cgi_overload_delay => {
 136                 type => "string",
 137                 default => '',
 138                 example => "10",
 139                 description => "number of seconds to delay CGI requests when overloaded",
 140                 safe => 1,
 141                 rebuild => 0,
 142         },
 143         cgi_overload_message => {
 144                 type => "string",
 145                 default => '',
 146                 example => "Please wait",
 147                 description => "message to display when overloaded (may contain html)",
 148                 safe => 1,
 149                 rebuild => 0,
 150         },
 151         only_committed_changes => {
 152                 type => "boolean",
 153                 default => 0,
 154                 description => "enable optimization of only refreshing committed changes?",
 155                 safe => 1,
 156                 rebuild => 0,
 157         },
 158         rcs => {
 159                 type => "string",
 160                 default => '',
 161                 description => "rcs backend to use",
 162                 safe => 0, # don't allow overriding
 163                 rebuild => 0,
 164         },
 165         default_plugins => {
 166                 type => "internal",
 167                 default => [qw{mdwn link inline meta htmlscrubber passwordauth
 168                                 openid emailauth signinedit lockedit conditional
 169                                 recentchanges parentlinks editpage
 170                                 templatebody}],
 171                 description => "plugins to enable by default",
 172                 safe => 0,
 173                 rebuild => 1,
 174         },
 175         add_plugins => {
 176                 type => "string",
 177                 default => [],
 178                 description => "plugins to add to the default configuration",
 179                 safe => 1,
 180                 rebuild => 1,
 181         },
 182         disable_plugins => {
 183                 type => "string",
 184                 default => [],
 185                 description => "plugins to disable",
 186                 safe => 1,
 187                 rebuild => 1,
 188         },
 189         templatedir => {
 190                 type => "string",
 191                 default => "$installdir/share/ikiwiki/templates",
 192                 description => "additional directory to search for template files",
 193                 advanced => 1,
 194                 safe => 0, # path
 195                 rebuild => 1,
 196         },
 197         underlaydir => {
 198                 type => "string",
 199                 default => "$installdir/share/ikiwiki/basewiki",
 200                 description => "base wiki source location",
 201                 advanced => 1,
 202                 safe => 0, # path
 203                 rebuild => 0,
 204         },
 205         underlaydirbase => {
 206                 type => "internal",
 207                 default => "$installdir/share/ikiwiki",
 208                 description => "parent directory containing additional underlays",
 209                 safe => 0,
 210                 rebuild => 0,
 211         },
 212         wrappers => {
 213                 type => "internal",
 214                 default => [],
 215                 description => "wrappers to generate",
 216                 safe => 0,
 217                 rebuild => 0,
 218         },
 219         underlaydirs => {
 220                 type => "internal",
 221                 default => [],
 222                 description => "additional underlays to use",
 223                 safe => 0,
 224                 rebuild => 0,
 225         },
 226         verbose => {
 227                 type => "boolean",
 228                 example => 1,
 229                 description => "display verbose messages?",
 230                 safe => 1,
 231                 rebuild => 0,
 232         },
 233         syslog => {
 234                 type => "boolean",
 235                 example => 1,
 236                 description => "log to syslog?",
 237                 safe => 1,
 238                 rebuild => 0,
 239         },
 240         usedirs => {
 241                 type => "boolean",
 242                 default => 1,
 243                 description => "create output files named page/index.html?",
 244                 safe => 0, # changing requires manual transition
 245                 rebuild => 1,
 246         },
 247         prefix_directives => {
 248                 type => "boolean",
 249                 default => 1,
 250                 description => "use '!'-prefixed preprocessor directives?",
 251                 safe => 0, # changing requires manual transition
 252                 rebuild => 1,
 253         },
 254         indexpages => {
 255                 type => "boolean",
 256                 default => 0,
 257                 description => "use page/index.mdwn source files",
 258                 safe => 1,
 259                 rebuild => 1,
 260         },
 261         discussion => {
 262                 type => "boolean",
 263                 default => 1,
 264                 description => "enable Discussion pages?",
 265                 safe => 1,
 266                 rebuild => 1,
 267         },
 268         discussionpage => {
 269                 type => "string",
 270                 default => gettext("Discussion"),
 271                 description => "name of Discussion pages",
 272                 safe => 1,
 273                 rebuild => 1,
 274         },
 275         html5 => {
 276                 type => "boolean",
 277                 default => 0,
 278                 description => "use elements new in HTML5 like <section>?",
 279                 advanced => 0,
 280                 safe => 1,
 281                 rebuild => 1,
 282         },
 283         sslcookie => {
 284                 type => "boolean",
 285                 default => 0,
 286                 description => "only send cookies over SSL connections?",
 287                 advanced => 1,
 288                 safe => 1,
 289                 rebuild => 0,
 290         },
 291         default_pageext => {
 292                 type => "string",
 293                 default => "mdwn",
 294                 description => "extension to use for new pages",
 295                 safe => 0, # not sanitized
 296                 rebuild => 0,
 297         },
 298         htmlext => {
 299                 type => "string",
 300                 default => "html",
 301                 description => "extension to use for html files",
 302                 safe => 0, # not sanitized
 303                 rebuild => 1,
 304         },
 305         timeformat => {
 306                 type => "string",
 307                 default => '%c',
 308                 description => "strftime format string to display date",
 309                 advanced => 1,
 310                 safe => 1,
 311                 rebuild => 1,
 312         },
 313         locale => {
 314                 type => "string",
 315                 default => undef,
 316                 example => "en_US.UTF-8",
 317                 description => "UTF-8 locale to use",
 318                 advanced => 1,
 319                 safe => 0,
 320                 rebuild => 1,
 321         },
 322         userdir => {
 323                 type => "string",
 324                 default => "",
 325                 example => "users",
 326                 description => "put user pages below specified page",
 327                 safe => 1,
 328                 rebuild => 1,
 329         },
 330         numbacklinks => {
 331                 type => "integer",
 332                 default => 10,
 333                 description => "how many backlinks to show before hiding excess (0 to show all)",
 334                 safe => 1,
 335                 rebuild => 1,
 336         },
 337         hardlink => {
 338                 type => "boolean",
 339                 default => 0,
 340                 description => "attempt to hardlink source files? (optimisation for large files)",
 341                 advanced => 1,
 342                 safe => 0, # paranoia
 343                 rebuild => 0,
 344         },
 345         umask => {
 346                 type => "string",
 347                 example => "public",
 348                 description => "force ikiwiki to use a particular umask (keywords public, group or private, or a number)",
 349                 advanced => 1,
 350                 safe => 0, # paranoia
 351                 rebuild => 0,
 352         },
 353         wrappergroup => {
 354                 type => "string",
 355                 example => "ikiwiki",
 356                 description => "group for wrappers to run in",
 357                 advanced => 1,
 358                 safe => 0, # paranoia
 359                 rebuild => 0,
 360         },
 361         libdirs => {
 362                 type => "string",
 363                 default => [],
 364                 example => ["$ENV{HOME}/.local/share/ikiwiki"],
 365                 description => "extra library and plugin directories",
 366                 advanced => 1,
 367                 safe => 0, # directory
 368                 rebuild => 0,
 369         },
 370         libdir => {
 371                 type => "string",
 372                 default => "",
 373                 example => "$ENV{HOME}/.ikiwiki/",
 374                 description => "extra library and plugin directory (searched after libdirs)",
 375                 advanced => 1,
 376                 safe => 0, # directory
 377                 rebuild => 0,
 378         },
 379         ENV => {
 380                 type => "string",
 381                 default => {},
 382                 description => "environment variables",
 383                 safe => 0, # paranoia
 384                 rebuild => 0,
 385         },
 386         timezone => {
 387                 type => "string",
 388                 default => "",
 389                 example => "US/Eastern",
 390                 description => "time zone name",
 391                 safe => 1,
 392                 rebuild => 1,
 393         },
 394         include => {
 395                 type => "string",
 396                 default => undef,
 397                 example => '^\.htaccess$',
 398                 description => "regexp of normally excluded files to include",
 399                 advanced => 1,
 400                 safe => 0, # regexp
 401                 rebuild => 1,
 402         },
 403         exclude => {
 404                 type => "string",
 405                 default => undef,
 406                 example => '^(*\.private|Makefile)$',
 407                 description => "regexp of files that should be skipped",
 408                 advanced => 1,
 409                 safe => 0, # regexp
 410                 rebuild => 1,
 411         },
 412         wiki_file_prune_regexps => {
 413                 type => "internal",
 414                 default => [qr/(^|\/)\.\.(\/|$)/, qr/^\//, qr/^\./, qr/\/\./,
 415                         qr/\.x?html?$/, qr/\.ikiwiki-new$/,
 416                         qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//,
 417                         qr/(^|\/)_MTN\//, qr/(^|\/)_darcs\//,
 418                         qr/(^|\/)CVS\//, qr/\.dpkg-tmp$/],
 419                 description => "regexps of source files to ignore",
 420                 safe => 0,
 421                 rebuild => 1,
 422         },
 423         wiki_file_chars => {
 424                 type => "string",
 425                 description => "specifies the characters that are allowed in source filenames",
 426                 default => "-[:alnum:]+/.:_",
 427                 safe => 0,
 428                 rebuild => 1,
 429         },
 430         wiki_file_regexp => {
 431                 type => "internal",
 432                 description => "regexp of legal source files",
 433                 safe => 0,
 434                 rebuild => 1,
 435         },
 436         web_commit_regexp => {
 437                 type => "internal",
 438                 default => qr/^web commit (by (.*?(?=: |$))|from ([0-9a-fA-F:.]+[0-9a-fA-F])):?(.*)/,
 439                 description => "regexp to parse web commits from logs",
 440                 safe => 0,
 441                 rebuild => 0,
 442         },
 443         cgi => {
 444                 type => "internal",
 445                 default => 0,
 446                 description => "run as a cgi",
 447                 safe => 0,
 448                 rebuild => 0,
 449         },
 450         cgi_disable_uploads => {
 451                 type => "internal",
 452                 default => 1,
 453                 description => "whether CGI should accept file uploads",
 454                 safe => 0,
 455                 rebuild => 0,
 456         },
 457         post_commit => {
 458                 type => "internal",
 459                 default => 0,
 460                 description => "run as a post-commit hook",
 461                 safe => 0,
 462                 rebuild => 0,
 463         },
 464         rebuild => {
 465                 type => "internal",
 466                 default => 0,
 467                 description => "running in rebuild mode",
 468                 safe => 0,
 469                 rebuild => 0,
 470         },
 471         setup => {
 472                 type => "internal",
 473                 default => undef,
 474                 description => "running in setup mode",
 475                 safe => 0,
 476                 rebuild => 0,
 477         },
 478         clean => {
 479                 type => "internal",
 480                 default => 0,
 481                 description => "running in clean mode",
 482                 safe => 0,
 483                 rebuild => 0,
 484         },
 485         refresh => {
 486                 type => "internal",
 487                 default => 0,
 488                 description => "running in refresh mode",
 489                 safe => 0,
 490                 rebuild => 0,
 491         },
 492         test_receive => {
 493                 type => "internal",
 494                 default => 0,
 495                 description => "running in receive test mode",
 496                 safe => 0,
 497                 rebuild => 0,
 498         },
 499         wrapper_background_command => {
 500                 type => "internal",
 501                 default => '',
 502                 description => "background shell command to run",
 503                 safe => 0,
 504                 rebuild => 0,
 505         },
 506         gettime => {
 507                 type => "internal",
 508                 description => "running in gettime mode",
 509                 safe => 0,
 510                 rebuild => 0,
 511         },
 512         w3mmode => {
 513                 type => "internal",
 514                 default => 0,
 515                 description => "running in w3mmode",
 516                 safe => 0,
 517                 rebuild => 0,
 518         },
 519         wikistatedir => {
 520                 type => "internal",
 521                 default => undef,
 522                 description => "path to the .ikiwiki directory holding ikiwiki state",
 523                 safe => 0,
 524                 rebuild => 0,
 525         },
 526         setupfile => {
 527                 type => "internal",
 528                 default => undef,
 529                 description => "path to setup file",
 530                 safe => 0,
 531                 rebuild => 0,
 532         },
 533         setuptype => {
 534                 type => "internal",
 535                 default => "Yaml",
 536                 description => "perl class to use to dump setup file",
 537                 safe => 0,
 538                 rebuild => 0,
 539         },
 540         allow_symlinks_before_srcdir => {
 541                 type => "boolean",
 542                 default => 0,
 543                 description => "allow symlinks in the path leading to the srcdir (potentially insecure)",
 544                 safe => 0,
 545                 rebuild => 0,
 546         },
 547         cookiejar => {
 548                 type => "string",
 549                 default => { file => "$ENV{HOME}/.ikiwiki/cookies" },
 550                 description => "cookie control",
 551                 safe => 0, # hooks into perl module internals
 552                 rebuild => 0,
 553         },
 554         useragent => {
 555                 type => "string",
 556                 default => "ikiwiki/$version",
 557                 example => "Wget/1.13.4 (linux-gnu)",
 558                 description => "set custom user agent string for outbound HTTP requests e.g. when fetching aggregated RSS feeds",
 559                 safe => 0,
 560                 rebuild => 0,
 561         },
 562         responsive_layout => {
 563                 type => "boolean",
 564                 default => 1,
 565                 description => "theme has a responsive layout? (mobile-optimized)",
 566                 safe => 1,
 567                 rebuild => 1,
 568         },
 569 }
 570
 571 sub getlibdirs () {
 572         my @libdirs;
 573         if ($config{libdirs}) {
 574                 @libdirs = @{$config{libdirs}};
 575         }
 576         if (length $config{libdir}) {
 577                 push @libdirs, $config{libdir};
 578         }
 579         return @libdirs;
 580 }
 581
 582 sub defaultconfig () {
 583         my %s=getsetup();
 584         my @ret;
 585         foreach my $key (keys %s) {
 586                 push @ret, $key, $s{$key}->{default};
 587         }
 588         return @ret;
 589 }
 590
 591 # URL to top of wiki as a path starting with /, valid from any wiki page or
 592 # the CGI; if that's not possible, an absolute URL. Either way, it ends with /
 593 my $local_url;
 594 # URL to CGI script, similar to $local_url
 595 my $local_cgiurl;
 596
 597 sub checkconfig () {
 598         # locale stuff; avoid LC_ALL since it overrides everything
 599         if (defined $ENV{LC_ALL}) {
 600                 $ENV{LANG} = $ENV{LC_ALL};
 601                 delete $ENV{LC_ALL};
 602         }
 603         if (defined $config{locale}) {
 604                 if (POSIX::setlocale(&POSIX::LC_ALL, $config{locale})) {
 605                         $ENV{LANG}=$config{locale};
 606                         define_gettext();
 607                 }
 608         }
 609
 610         if (! defined $config{wiki_file_regexp}) {
 611                 $config{wiki_file_regexp}=qr/(^[$config{wiki_file_chars}]+$)/;
 612         }
 613
 614         if (ref $config{ENV} eq 'HASH') {
 615                 foreach my $val (keys %{$config{ENV}}) {
 616                         $ENV{$val}=$config{ENV}{$val};
 617                 }
 618         }
 619         if (defined $config{timezone} && length $config{timezone}) {
 620                 $ENV{TZ}=$config{timezone};
 621         }
 622         elsif (defined $ENV{TZ} && length $ENV{TZ}) {
 623                 $config{timezone}=$ENV{TZ};
 624         }
 625         else {
 626                 eval q{use Config qw()};
 627                 error($@) if $@;
 628
 629                 if ($Config::Config{d_gnulibc} && -e '/etc/localtime') {
 630                         $config{timezone}=$ENV{TZ}=':/etc/localtime';
 631                 }
 632                 else {
 633                         $config{timezone}=$ENV{TZ}='GMT';
 634                 }
 635         }
 636
 637         if ($config{w3mmode}) {
 638                 eval q{use Cwd q{abs_path}};
 639                 error($@) if $@;
 640                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
 641                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
 642                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
 643                         unless $config{cgiurl} =~ m!file:///!;
 644                 $config{url}="file://".$config{destdir};
 645         }
 646
 647         if ($config{cgi} && ! length $config{url}) {
 648                 error(gettext("Must specify url to wiki with --url when using --cgi"));
 649         }
 650
 651         if (defined $config{url} && length $config{url}) {
 652                 eval q{use URI};
 653                 my $baseurl = URI->new($config{url});
 654
 655                 $local_url = $baseurl->path . "/";
 656                 $local_cgiurl = undef;
 657
 658                 if (length $config{cgiurl}) {
 659                         my $cgiurl = URI->new($config{cgiurl});
 660
 661                         $local_cgiurl = $cgiurl->path;
 662
 663                         if ($cgiurl->scheme eq 'https' &&
 664                                 $baseurl->scheme eq 'http') {
 665                                 # We assume that the same content is available
 666                                 # over both http and https, because if it
 667                                 # wasn't, accessing the static content
 668                                 # from the CGI would be mixed-content,
 669                                 # which would be a security flaw.
 670
 671                                 if ($cgiurl->authority ne $baseurl->authority) {
 672                                         # use protocol-relative URL for
 673                                         # static content
 674                                         $local_url = "$config{url}/";
 675                                         $local_url =~ s{^http://}{//};
 676                                 }
 677                                 # else use host-relative URL for static content
 678
 679                                 # either way, CGI needs to be absolute
 680                                 $local_cgiurl = $config{cgiurl};
 681                         }
 682                         elsif ($cgiurl->scheme ne $baseurl->scheme) {
 683                                 # too far apart, fall back to absolute URLs
 684                                 $local_url = "$config{url}/";
 685                                 $local_cgiurl = $config{cgiurl};
 686                         }
 687                         elsif ($cgiurl->authority ne $baseurl->authority) {
 688                                 # slightly too far apart, fall back to
 689                                 # protocol-relative URLs
 690                                 $local_url = "$config{url}/";
 691                                 $local_url =~ s{^https?://}{//};
 692                                 $local_cgiurl = $config{cgiurl};
 693                                 $local_cgiurl =~ s{^https?://}{//};
 694                         }
 695                         # else keep host-relative URLs
 696                 }
 697
 698                 $local_url =~ s{//$}{/};
 699         }
 700         else {
 701                 $local_cgiurl = $config{cgiurl};
 702         }
 703
 704         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 705                 unless exists $config{wikistatedir} && defined $config{wikistatedir};
 706
 707         if (defined $config{umask}) {
 708                 my $u = possibly_foolish_untaint($config{umask});
 709
 710                 if ($u =~ m/^\d+$/) {
 711                         umask($u);
 712                 }
 713                 elsif ($u eq 'private') {
 714                         umask(077);
 715                 }
 716                 elsif ($u eq 'group') {
 717                         umask(027);
 718                 }
 719                 elsif ($u eq 'public') {
 720                         umask(022);
 721                 }
 722                 else {
 723                         error(sprintf(gettext("unsupported umask setting %s"), $u));
 724                 }
 725         }
 726
 727         run_hooks(checkconfig => sub { shift->() });
 728
 729         return 1;
 730 }
 731
 732 sub listplugins () {
 733         my %ret;
 734
 735         foreach my $dir (@INC, getlibdirs()) {
 736                 next unless defined $dir && length $dir;
 737                 foreach my $file (glob("$dir/IkiWiki/Plugin/*.pm")) {
 738                         my ($plugin)=$file=~/.*\/(.*)\.pm$/;
 739                         $ret{$plugin}=1;
 740                 }
 741         }
 742         foreach my $dir (getlibdirs(), "$installdir/lib/ikiwiki") {
 743                 next unless defined $dir && length $dir;
 744                 foreach my $file (glob("$dir/plugins/*")) {
 745                         $ret{basename($file)}=1 if -x $file;
 746                 }
 747         }
 748
 749         return keys %ret;
 750 }
 751
 752 sub loadplugins () {
 753         foreach my $dir (getlibdirs()) {
 754                 unshift @INC, possibly_foolish_untaint($dir);
 755         }
 756
 757         foreach my $plugin (@{$config{default_plugins}}, @{$config{add_plugins}}) {
 758                 loadplugin($plugin);
 759         }
 760
 761         if ($config{rcs}) {
 762                 if (exists $hooks{rcs}) {
 763                         error(gettext("cannot use multiple rcs plugins"));
 764                 }
 765                 loadplugin($config{rcs});
 766         }
 767         if (! exists $hooks{rcs}) {
 768                 loadplugin("norcs");
 769         }
 770
 771         run_hooks(getopt => sub { shift->() });
 772         if (grep /^-/, @ARGV) {
 773                 print STDERR "Unknown option (or missing parameter): $_\n"
 774                         foreach grep /^-/, @ARGV;
 775                 usage();
 776         }
 777
 778         return 1;
 779 }
 780
 781 sub loadplugin ($;$) {
 782         my $plugin=shift;
 783         my $force=shift;
 784
 785         return if ! $force && grep { $_ eq $plugin} @{$config{disable_plugins}};
 786
 787         foreach my $possiblytainteddir (getlibdirs(), "$installdir/lib/ikiwiki") {
 788                 my $dir = possibly_foolish_untaint($possiblytainteddir);
 789                 if (defined $dir && -x "$dir/plugins/$plugin") {
 790                         eval { require IkiWiki::Plugin::external };
 791                         if ($@) {
 792                                 my $reason=$@;
 793                                 error(sprintf(gettext("failed to load external plugin needed for %s plugin: %s"), $plugin, $reason));
 794                         }
 795                         import IkiWiki::Plugin::external "$dir/plugins/$plugin";
 796                         $loaded_plugins{$plugin}=1;
 797                         return 1;
 798                 }
 799         }
 800
 801         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 802         eval qq{use $mod};
 803         if ($@) {
 804                 error("Failed to load plugin $mod: $@");
 805         }
 806         $loaded_plugins{$plugin}=1;
 807         return 1;
 808 }
 809
 810 sub error ($;$) {
 811         my $message=shift;
 812         my $cleaner=shift;
 813         log_message('err' => $message) if $config{syslog};
 814         if (defined $cleaner) {
 815                 $cleaner->();
 816         }
 817         die $message."\n";
 818 }
 819
 820 sub debug ($) {
 821         return unless $config{verbose};
 822         return log_message(debug => @_);
 823 }
 824
 825 my $log_open=0;
 826 my $log_failed=0;
 827 sub log_message ($$) {
 828         my $type=shift;
 829
 830         if ($config{syslog}) {
 831                 require Sys::Syslog;
 832                 if (! $log_open) {
 833                         Sys::Syslog::setlogsock('unix');
 834                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 835                         $log_open=1;
 836                 }
 837                 eval {
 838                         # keep a copy to avoid editing the original config repeatedly
 839                         my $wikiname = $config{wikiname};
 840                         utf8::encode($wikiname);
 841                         Sys::Syslog::syslog($type, "[$wikiname] %s", join(" ", @_));
 842                 };
 843                 if ($@) {
 844                     print STDERR "failed to syslog: $@" unless $log_failed;
 845                     $log_failed=1;
 846                     print STDERR "@_\n";
 847                 }
 848                 return $@;
 849         }
 850         elsif (! $config{cgi}) {
 851                 return print "@_\n";
 852         }
 853         else {
 854                 return print STDERR "@_\n";
 855         }
 856 }
 857
 858 sub possibly_foolish_untaint ($) {
 859         my $tainted=shift;
 860         my ($untainted)=$tainted=~/(.*)/s;
 861         return $untainted;
 862 }
 863
 864 sub basename ($) {
 865         my $file=shift;
 866
 867         $file=~s!.*/+!!;
 868         return $file;
 869 }
 870
 871 sub dirname ($) {
 872         my $file=shift;
 873
 874         $file=~s!/*[^/]+$!!;
 875         return $file;
 876 }
 877
 878 sub isinternal ($) {
 879         my $page=shift;
 880         return exists $pagesources{$page} &&
 881                 $pagesources{$page} =~ /\._([^.]+)$/;
 882 }
 883
 884 sub pagetype ($) {
 885         my $file=shift;
 886
 887         if ($file =~ /\.([^.]+)$/) {
 888                 return $1 if exists $hooks{htmlize}{$1};
 889         }
 890         my $base=basename($file);
 891         if (exists $hooks{htmlize}{$base} &&
 892             $hooks{htmlize}{$base}{noextension}) {
 893                 return $base;
 894         }
 895         return;
 896 }
 897
 898 my %pagename_cache;
 899
 900 sub pagename ($) {
 901         my $file=shift;
 902
 903         if (exists $pagename_cache{$file}) {
 904                 return $pagename_cache{$file};
 905         }
 906
 907         my $type=pagetype($file);
 908         my $page=$file;
 909         $page=~s/\Q.$type\E*$//
 910                 if defined $type && !$hooks{htmlize}{$type}{keepextension}
 911                         && !$hooks{htmlize}{$type}{noextension};
 912         if ($config{indexpages} && $page=~/(.*)\/index$/) {
 913                 $page=$1;
 914         }
 915
 916         $pagename_cache{$file} = $page;
 917         return $page;
 918 }
 919
 920 sub newpagefile ($$) {
 921         my $page=shift;
 922         my $type=shift;
 923
 924         if (! $config{indexpages} || $page eq 'index') {
 925                 return $page.".".$type;
 926         }
 927         else {
 928                 return $page."/index.".$type;
 929         }
 930 }
 931
 932 sub targetpage ($$;$) {
 933         my $page=shift;
 934         my $ext=shift;
 935         my $filename=shift;
 936
 937         if (defined $filename) {
 938                 return $page."/".$filename.".".$ext;
 939         }
 940         elsif (! $config{usedirs} || $page eq 'index') {
 941                 return $page.".".$ext;
 942         }
 943         else {
 944                 return $page."/index.".$ext;
 945         }
 946 }
 947
 948 sub htmlpage ($) {
 949         my $page=shift;
 950
 951         return targetpage($page, $config{htmlext});
 952 }
 953
 954 sub srcfile_stat {
 955         my $file=shift;
 956         my $nothrow=shift;
 957
 958         return "$config{srcdir}/$file", stat(_) if -e "$config{srcdir}/$file";
 959         foreach my $dir (@{$config{underlaydirs}}, $config{underlaydir}) {
 960                 return "$dir/$file", stat(_) if -e "$dir/$file";
 961         }
 962         error("internal error: $file cannot be found in $config{srcdir} or underlay") unless $nothrow;
 963         return;
 964 }
 965
 966 sub srcfile ($;$) {
 967         return (srcfile_stat(@_))[0];
 968 }
 969
 970 sub add_literal_underlay ($) {
 971         my $dir=shift;
 972
 973         if (! grep { $_ eq $dir } @{$config{underlaydirs}}) {
 974                 unshift @{$config{underlaydirs}}, $dir;
 975         }
 976 }
 977
 978 sub add_underlay ($) {
 979         my $dir = shift;
 980
 981         if ($dir !~ /^\//) {
 982                 $dir="$config{underlaydirbase}/$dir";
 983         }
 984
 985         add_literal_underlay($dir);
 986         # why does it return 1? we just don't know
 987         return 1;
 988 }
 989
 990 sub readfile ($;$$) {
 991         my $file=shift;
 992         my $binary=shift;
 993         my $wantfd=shift;
 994
 995         if (-l $file) {
 996                 error("cannot read a symlink ($file)");
 997         }
 998
 999         local $/=undef;
1000         open (my $in, "<", $file) || error("failed to read $file: $!");
1001         binmode($in) if ($binary);
1002         return \*$in if $wantfd;
1003         my $ret=<$in>;
1004         # check for invalid utf-8, and toss it back to avoid crashes
1005         if (! utf8::valid($ret)) {
1006                 $ret=encode_utf8($ret);
1007         }
1008         close $in || error("failed to read $file: $!");
1009         return $ret;
1010 }
1011
1012 sub prep_writefile ($$) {
1013         my $file=shift;
1014         my $destdir=shift;
1015
1016         my $test=$file;
1017         while (length $test) {
1018                 if (-l "$destdir/$test") {
1019                         error("cannot write to a symlink ($test)");
1020                 }
1021                 if (-f _ && $test ne $file) {
1022                         # Remove conflicting file.
1023                         foreach my $p (keys %renderedfiles, keys %oldrenderedfiles) {
1024                                 foreach my $f (@{$renderedfiles{$p}}, @{$oldrenderedfiles{$p}}) {
1025                                         if ($f eq $test) {
1026                                                 unlink("$destdir/$test");
1027                                                 last;
1028                                         }
1029                                 }
1030                         }
1031                 }
1032                 $test=dirname($test);
1033         }
1034
1035         my $dir=dirname("$destdir/$file");
1036         if (! -d $dir) {
1037                 my $d="";
1038                 foreach my $s (split(m!/+!, $dir)) {
1039                         $d.="$s/";
1040                         if (! -d $d) {
1041                                 mkdir($d) || error("failed to create directory $d: $!");
1042                         }
1043                 }
1044         }
1045
1046         return 1;
1047 }
1048
1049 sub writefile ($$$;$$) {
1050         my $file=shift; # can include subdirs
1051         my $destdir=shift; # directory to put file in
1052         my $content=shift;
1053         my $binary=shift;
1054         my $writer=shift;
1055
1056         prep_writefile($file, $destdir);
1057
1058         my $newfile="$destdir/$file.ikiwiki-new";
1059         if (-l $newfile) {
1060                 error("cannot write to a symlink ($newfile)");
1061         }
1062
1063         my $cleanup = sub { unlink($newfile) };
1064         open (my $out, '>', $newfile) || error("failed to write $newfile: $!", $cleanup);
1065         binmode($out) if ($binary);
1066         if ($writer) {
1067                 $writer->(\*$out, $cleanup);
1068         }
1069         else {
1070                 print $out $content or error("failed writing to $newfile: $!", $cleanup);
1071         }
1072         close $out || error("failed saving $newfile: $!", $cleanup);
1073         rename($newfile, "$destdir/$file") ||
1074                 error("failed renaming $newfile to $destdir/$file: $!", $cleanup);
1075
1076         return 1;
1077 }
1078
1079 my %cleared;
1080 sub will_render ($$;$) {
1081         my $page=shift;
1082         my $dest=shift;
1083         my $clear=shift;
1084
1085         # Important security check for independently created files.
1086         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
1087             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}}, @{$wikistate{editpage}{previews}})) {
1088                 my $from_other_page=0;
1089                 # Expensive, but rarely runs.
1090                 foreach my $p (keys %renderedfiles, keys %oldrenderedfiles) {
1091                         if (grep {
1092                                 $_ eq $dest ||
1093                                 dirname($_) eq $dest
1094                             } @{$renderedfiles{$p}}, @{$oldrenderedfiles{$p}}) {
1095                                 $from_other_page=1;
1096                                 last;
1097                         }
1098                 }
1099
1100                 error("$config{destdir}/$dest independently created, not overwriting with version from $page")
1101                         unless $from_other_page;
1102         }
1103
1104         # If $dest exists as a directory, remove conflicting files in it
1105         # rendered from other pages.
1106         if (-d _) {
1107                 foreach my $p (keys %renderedfiles, keys %oldrenderedfiles) {
1108                         foreach my $f (@{$renderedfiles{$p}}, @{$oldrenderedfiles{$p}}) {
1109                                 if (dirname($f) eq $dest) {
1110                                         unlink("$config{destdir}/$f");
1111                                         rmdir(dirname("$config{destdir}/$f"));
1112                                 }
1113                         }
1114                 }
1115         }
1116
1117         if (! $clear || $cleared{$page}) {
1118                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
1119         }
1120         else {
1121                 foreach my $old (@{$renderedfiles{$page}}) {
1122                         delete $destsources{$old};
1123                 }
1124                 $renderedfiles{$page}=[$dest];
1125                 $cleared{$page}=1;
1126         }
1127         $destsources{$dest}=$page;
1128
1129         return 1;
1130 }
1131
1132 sub bestlink ($$) {
1133         my $page=shift;
1134         my $link=shift;
1135
1136         my $cwd=$page;
1137         if ($link=~s/^\/+//) {
1138                 # absolute links
1139                 $cwd="";
1140         }
1141         $link=~s/\/$//;
1142
1143         do {
1144                 my $l=$cwd;
1145                 $l.="/" if length $l;
1146                 $l.=$link;
1147
1148                 if (exists $pagesources{$l}) {
1149                         return $l;
1150                 }
1151                 elsif (exists $pagecase{lc $l}) {
1152                         return $pagecase{lc $l};
1153                 }
1154         } while $cwd=~s{/?[^/]+$}{};
1155
1156         if (length $config{userdir}) {
1157                 my $l = "$config{userdir}/".lc($link);
1158                 if (exists $pagesources{$l}) {
1159                         return $l;
1160                 }
1161                 elsif (exists $pagecase{lc $l}) {
1162                         return $pagecase{lc $l};
1163                 }
1164         }
1165
1166         #print STDERR "warning: page $page, broken link: $link\n";
1167         return "";
1168 }
1169
1170 sub isinlinableimage ($) {
1171         my $file=shift;
1172
1173         return $file =~ /\.(png|gif|jpg|jpeg|svg)$/i;
1174 }
1175
1176 sub pagetitle ($;$) {
1177         my $page=shift;
1178         my $unescaped=shift;
1179
1180         if ($unescaped) {
1181                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : chr($2)/eg;
1182         }
1183         else {
1184                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : "&#$2;"/eg;
1185         }
1186
1187         return $page;
1188 }
1189
1190 sub titlepage ($) {
1191         my $title=shift;
1192         # support use w/o %config set
1193         my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
1194         $title=~s/([^$chars]|_)/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
1195         return $title;
1196 }
1197
1198 sub linkpage ($) {
1199         my $link=shift;
1200         my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
1201         $link=~s/([^$chars])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
1202         return $link;
1203 }
1204
1205 sub cgiurl (@) {
1206         my %params=@_;
1207
1208         my $cgiurl=$local_cgiurl;
1209
1210         if (exists $params{cgiurl}) {
1211                 $cgiurl=$params{cgiurl};
1212                 delete $params{cgiurl};
1213         }
1214
1215         unless (%params) {
1216                 return $cgiurl;
1217         }
1218
1219         return $cgiurl."?".
1220                 join("&amp;", map $_."=".uri_escape_utf8($params{$_}), keys %params);
1221 }
1222
1223 sub cgiurl_abs (@) {
1224         eval q{use URI};
1225         URI->new_abs(cgiurl(@_), $config{cgiurl});
1226 }
1227
1228 sub baseurl (;$) {
1229         my $page=shift;
1230
1231         return $local_url if ! defined $page;
1232
1233         $page=htmlpage($page);
1234         $page=~s/[^\/]+$//;
1235         $page=~s/[^\/]+\//..\//g;
1236         return $page;
1237 }
1238
1239 sub urlabs ($$) {
1240         my $url=shift;
1241         my $urlbase=shift;
1242
1243         return $url unless defined $urlbase && length $urlbase;
1244
1245         eval q{use URI};
1246         URI->new_abs($url, $urlbase)->as_string;
1247 }
1248
1249 sub abs2rel ($$) {
1250         # Work around very innefficient behavior in File::Spec if abs2rel
1251         # is passed two relative paths. It's much faster if paths are
1252         # absolute! (Debian bug #376658; fixed in debian unstable now)
1253         my $path="/".shift;
1254         my $base="/".shift;
1255
1256         require File::Spec;
1257         my $ret=File::Spec->abs2rel($path, $base);
1258         $ret=~s/^// if defined $ret;
1259         return $ret;
1260 }
1261
1262 sub displaytime ($;$$) {
1263         # Plugins can override this function to mark up the time to
1264         # display.
1265         my $time=formattime($_[0], $_[1]);
1266         if ($config{html5}) {
1267                 return '<time datetime="'.date_3339($_[0]).'"'.
1268                         ($_[2] ? ' pubdate="pubdate"' : '').
1269                         '>'.$time.'</time>';
1270         }
1271         else {
1272                 return '<span class="date">'.$time.'</span>';
1273         }
1274 }
1275
1276 sub formattime ($;$) {
1277         # Plugins can override this function to format the time.
1278         my $time=shift;
1279         my $format=shift;
1280         if (! defined $format) {
1281                 $format=$config{timeformat};
1282         }
1283
1284         return strftime_utf8($format, localtime($time));
1285 }
1286
1287 my $strftime_encoding;
1288 sub strftime_utf8 {
1289         # strftime doesn't know about encodings, so make sure
1290         # its output is properly treated as utf8.
1291         # Note that this does not handle utf-8 in the format string.
1292         ($strftime_encoding) = POSIX::setlocale(&POSIX::LC_TIME) =~ m#\.([^@]+)#
1293                 unless defined $strftime_encoding;
1294         $strftime_encoding
1295                 ? Encode::decode($strftime_encoding, POSIX::strftime(@_))
1296                 : POSIX::strftime(@_);
1297 }
1298
1299 sub date_3339 ($) {
1300         my $time=shift;
1301
1302         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
1303         POSIX::setlocale(&POSIX::LC_TIME, "C");
1304         my $ret=POSIX::strftime("%Y-%m-%dT%H:%M:%SZ", gmtime($time));
1305         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
1306         return $ret;
1307 }
1308
1309 sub beautify_urlpath ($) {
1310         my $url=shift;
1311
1312         # Ensure url is not an empty link, and if necessary,
1313         # add ./ to avoid colon confusion.
1314         if ($url !~ /^\// && $url !~ /^\.\.?\//) {
1315                 $url="./$url";
1316         }
1317
1318         if ($config{usedirs}) {
1319                 $url =~ s!/index.$config{htmlext}$!/!;
1320         }
1321
1322         return $url;
1323 }
1324
1325 sub urlto ($;$$) {
1326         my $to=shift;
1327         my $from=shift;
1328         my $absolute=shift;
1329
1330         if (! length $to) {
1331                 $to = 'index';
1332         }
1333
1334         if (! $destsources{$to}) {
1335                 $to=htmlpage($to);
1336         }
1337
1338         if ($absolute) {
1339                 return $config{url}.beautify_urlpath("/".$to);
1340         }
1341
1342         if (! defined $from) {
1343                 my $u = $local_url || '';
1344                 $u =~ s{/$}{};
1345                 return $u.beautify_urlpath("/".$to);
1346         }
1347
1348         my $link = abs2rel($to, dirname(htmlpage($from)));
1349
1350         return beautify_urlpath($link);
1351 }
1352
1353 sub isselflink ($$) {
1354         # Plugins can override this function to support special types
1355         # of selflinks.
1356         my $page=shift;
1357         my $link=shift;
1358
1359         return $page eq $link;
1360 }
1361
1362 sub htmllink ($$$;@) {
1363         my $lpage=shift; # the page doing the linking
1364         my $page=shift; # the page that will contain the link (different for inline)
1365         my $link=shift;
1366         my %opts=@_;
1367
1368         $link=~s/\/$//;
1369
1370         my $bestlink;
1371         if (! $opts{forcesubpage}) {
1372                 $bestlink=bestlink($lpage, $link);
1373         }
1374         else {
1375                 $bestlink="$lpage/".lc($link);
1376         }
1377
1378         my $linktext;
1379         if (defined $opts{linktext}) {
1380                 $linktext=$opts{linktext};
1381         }
1382         else {
1383                 $linktext=pagetitle(basename($link));
1384         }
1385
1386         return "<span class=\"selflink\">$linktext</span>"
1387                 if length $bestlink && isselflink($page, $bestlink) &&
1388                    ! defined $opts{anchor};
1389
1390         if (! $destsources{$bestlink}) {
1391                 $bestlink=htmlpage($bestlink);
1392
1393                 if (! $destsources{$bestlink}) {
1394                         my $cgilink = "";
1395                         if (length $config{cgiurl}) {
1396                                 $cgilink = "<a href=\"".
1397                                         cgiurl(
1398                                                 do => "create",
1399                                                 page => $link,
1400                                                 from => $lpage
1401                                         )."\" rel=\"nofollow\">?</a>";
1402                         }
1403                         return "<span class=\"createlink\">$cgilink$linktext</span>"
1404                 }
1405         }
1406
1407         $bestlink=abs2rel($bestlink, dirname(htmlpage($page)));
1408         $bestlink=beautify_urlpath($bestlink);
1409
1410         if (! $opts{noimageinline} && isinlinableimage($bestlink)) {
1411                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
1412         }
1413
1414         if (defined $opts{anchor}) {
1415                 $bestlink.="#".$opts{anchor};
1416         }
1417
1418         my @attrs;
1419         foreach my $attr (qw{rel class title}) {
1420                 if (defined $opts{$attr}) {
1421                         push @attrs, " $attr=\"$opts{$attr}\"";
1422                 }
1423         }
1424
1425         return "<a href=\"$bestlink\"@attrs>$linktext</a>";
1426 }
1427
1428 sub userpage ($) {
1429         my $user=shift;
1430         return length $config{userdir} ? "$config{userdir}/$user" : $user;
1431 }
1432
1433 # Username to display for openid accounts.
1434 sub openiduser ($) {
1435         my $user=shift;
1436
1437         if (defined $user && $user =~ m!^https?://! &&
1438             eval q{use Net::OpenID::VerifiedIdentity; 1} && !$@) {
1439                 my $display;
1440
1441                 if (Net::OpenID::VerifiedIdentity->can("DisplayOfURL")) {
1442                         $display = Net::OpenID::VerifiedIdentity::DisplayOfURL($user);
1443                 }
1444                 else {
1445                         # backcompat with old version
1446                         my $oid=Net::OpenID::VerifiedIdentity->new(identity => $user);
1447                         $display=$oid->display;
1448                 }
1449
1450                 # Convert "user.somehost.com" to "user [somehost.com]"
1451                 # (also "user.somehost.co.uk")
1452                 if ($display !~ /\[/) {
1453                         $display=~s/^([-a-zA-Z0-9]+?)\.([-.a-zA-Z0-9]+\.[a-z]+)$/$1 [$2]/;
1454                 }
1455                 # Convert "http://somehost.com/user" to "user [somehost.com]".
1456                 # (also "https://somehost.com/user/")
1457                 if ($display !~ /\[/) {
1458                         $display=~s/^https?:\/\/(.+)\/([^\/#?]+)\/?(?:[#?].*)?$/$2 [$1]/;
1459                 }
1460                 $display=~s!^https?://!!; # make sure this is removed
1461                 eval q{use CGI 'escapeHTML'};
1462                 error($@) if $@;
1463                 return escapeHTML($display);
1464         }
1465         return;
1466 }
1467
1468 # Username to display for emailauth accounts.
1469 sub emailuser ($) {
1470         my $user=shift;
1471         if (defined $user && $user =~ m/(.+)@/) {
1472                 my $nick=$1;
1473                 # remove any characters from not allowed in wiki files
1474                 $nick=~s/[^$config{wiki_file_chars}]/_/g;
1475                 return $nick;
1476         }
1477         return;
1478 }
1479
1480 # Some user information should not be exposed in commit metadata, etc.
1481 # This generates a cloaked form of such information.
1482 sub cloak ($) {
1483         my $user=shift;
1484         # cloak email address using http://xmlns.com/foaf/spec/#term_mbox_sha1sum
1485         if ($user=~m/(.+)@/) {
1486                 my $nick=$1;
1487                 eval q{use Digest::SHA};
1488                 return $user if $@;
1489                 return $nick.'@'.Digest::SHA::sha1_hex("mailto:$user");
1490         }
1491         else {
1492                 return $user;
1493         }
1494 }
1495
1496 sub htmlize ($$$$) {
1497         my $page=shift;
1498         my $destpage=shift;
1499         my $type=shift;
1500         my $content=shift;
1501
1502         my $oneline = $content !~ /\n/;
1503
1504         if (exists $hooks{htmlize}{$type}) {
1505                 $content=$hooks{htmlize}{$type}{call}->(
1506                         page => $page,
1507                         content => $content,
1508                 );
1509         }
1510         else {
1511                 error("htmlization of $type not supported");
1512         }
1513
1514         run_hooks(sanitize => sub {
1515                 $content=shift->(
1516                         page => $page,
1517                         destpage => $destpage,
1518                         content => $content,
1519                 );
1520         });
1521
1522         if ($oneline) {
1523                 # hack to get rid of enclosing junk added by markdown
1524                 # and other htmlizers/sanitizers
1525                 $content=~s/^<p>//i;
1526                 $content=~s/<\/p>\n*$//i;
1527         }
1528
1529         return $content;
1530 }
1531
1532 sub linkify ($$$) {
1533         my $page=shift;
1534         my $destpage=shift;
1535         my $content=shift;
1536
1537         run_hooks(linkify => sub {
1538                 $content=shift->(
1539                         page => $page,
1540                         destpage => $destpage,
1541                         content => $content,
1542                 );
1543         });
1544
1545         return $content;
1546 }
1547
1548 our %preprocessing;
1549 our $preprocess_preview=0;
1550 sub preprocess ($$$;$$) {
1551         my $page=shift; # the page the data comes from
1552         my $destpage=shift; # the page the data will appear in (different for inline)
1553         my $content=shift;
1554         my $scan=shift;
1555         my $preview=shift;
1556
1557         # Using local because it needs to be set within any nested calls
1558         # of this function.
1559         local $preprocess_preview=$preview if defined $preview;
1560
1561         my $handle=sub {
1562                 my $escape=shift;
1563                 my $prefix=shift;
1564                 my $command=shift;
1565                 my $params=shift;
1566                 $params="" if ! defined $params;
1567
1568                 if (length $escape) {
1569                         return "[[$prefix$command $params]]";
1570                 }
1571                 elsif (exists $hooks{preprocess}{$command}) {
1572                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
1573                         # Note: preserve order of params, some plugins may
1574                         # consider it significant.
1575                         my @params;
1576                         while ($params =~ m{
1577                                 (?:([-.\w]+)=)?         # 1: named parameter key?
1578                                 (?:
1579                                         """(.*?)"""     # 2: triple-quoted value
1580                                 |
1581                                         "([^"]*?)"      # 3: single-quoted value
1582                                 |
1583                                         '''(.*?)'''     # 4: triple-single-quote
1584                                 |
1585                                         <<([a-zA-Z]+)\n # 5: heredoc start
1586                                         (.*?)\n\5       # 6: heredoc value
1587                                 |
1588                                         (\S+)           # 7: unquoted value
1589                                 )
1590                                 (?:\s+|$)               # delimiter to next param
1591                         }msgx) {
1592                                 my $key=$1;
1593                                 my $val;
1594                                 if (defined $2) {
1595                                         $val=$2;
1596                                         $val=~s/\r\n/\n/mg;
1597                                         $val=~s/^\n+//g;
1598                                         $val=~s/\n+$//g;
1599                                 }
1600                                 elsif (defined $3) {
1601                                         $val=$3;
1602                                 }
1603                                 elsif (defined $4) {
1604                                         $val=$4;
1605                                 }
1606                                 elsif (defined $7) {
1607                                         $val=$7;
1608                                 }
1609                                 elsif (defined $6) {
1610                                         $val=$6;
1611                                 }
1612
1613                                 if (defined $key) {
1614                                         push @params, $key, $val;
1615                                 }
1616                                 else {
1617                                         push @params, $val, '';
1618                                 }
1619                         }
1620                         if ($preprocessing{$page}++ > 8) {
1621                                 # Avoid loops of preprocessed pages preprocessing
1622                                 # other pages that preprocess them, etc.
1623                                 return "[[!$command <span class=\"error\">".
1624                                         sprintf(gettext("preprocessing loop detected on %s at depth %i"),
1625                                                 $page, $preprocessing{$page}).
1626                                         "</span>]]";
1627                         }
1628                         my $ret;
1629                         if (! $scan) {
1630                                 $ret=eval {
1631                                         $hooks{preprocess}{$command}{call}->(
1632                                                 @params,
1633                                                 page => $page,
1634                                                 destpage => $destpage,
1635                                                 preview => $preprocess_preview,
1636                                         );
1637                                 };
1638                                 if ($@) {
1639                                         my $error=$@;
1640                                         chomp $error;
1641                                         $ret="[[!$command <span class=\"error\">".
1642                                                 gettext("Error").": $error"."</span>]]";
1643                                 }
1644                         }
1645                         else {
1646                                 # use void context during scan pass
1647                                 eval {
1648                                         $hooks{preprocess}{$command}{call}->(
1649                                                 @params,
1650                                                 page => $page,
1651                                                 destpage => $destpage,
1652                                                 preview => $preprocess_preview,
1653                                         );
1654                                 };
1655                                 $ret="";
1656                         }
1657                         $preprocessing{$page}--;
1658                         return $ret;
1659                 }
1660                 else {
1661                         return "[[$prefix$command $params]]";
1662                 }
1663         };
1664
1665         my $regex;
1666         if ($config{prefix_directives}) {
1667                 $regex = qr{
1668                         (\\?)           # 1: escape?
1669                         \[\[(!)         # directive open; 2: prefix
1670                         ([-\w]+)        # 3: command
1671                         (               # 4: the parameters..
1672                                 \s+     # Must have space if parameters present
1673                                 (?:
1674                                         (?:[-.\w]+=)?           # named parameter key?
1675                                         (?:
1676                                                 """.*?"""       # triple-quoted value
1677                                                 |
1678                                                 "[^"]*?"        # single-quoted value
1679                                                 |
1680                                                 '''.*?'''       # triple-single-quote
1681                                                 |
1682                                                 <<([a-zA-Z]+)\n # 5: heredoc start
1683                                                 (?:.*?)\n\5     # heredoc value
1684                                                 |
1685                                                 [^"\s\]]+       # unquoted value
1686                                         )
1687                                         \s*                     # whitespace or end
1688                                                                 # of directive
1689                                 )
1690                         *)?             # 0 or more parameters
1691                         \]\]            # directive closed
1692                 }sx;
1693         }
1694         else {
1695                 $regex = qr{
1696                         (\\?)           # 1: escape?
1697                         \[\[(!?)        # directive open; 2: optional prefix
1698                         ([-\w]+)        # 3: command
1699                         \s+
1700                         (               # 4: the parameters..
1701                                 (?:
1702                                         (?:[-.\w]+=)?           # named parameter key?
1703                                         (?:
1704                                                 """.*?"""       # triple-quoted value
1705                                                 |
1706                                                 "[^"]*?"        # single-quoted value
1707                                                 |
1708                                                 '''.*?'''       # triple-single-quote
1709                                                 |
1710                                                 <<([a-zA-Z]+)\n # 5: heredoc start
1711                                                 (?:.*?)\n\5     # heredoc value
1712                                                 |
1713                                                 [^"\s\]]+       # unquoted value
1714                                         )
1715                                         \s*                     # whitespace or end
1716                                                                 # of directive
1717                                 )
1718                         *)              # 0 or more parameters
1719                         \]\]            # directive closed
1720                 }sx;
1721         }
1722
1723         $content =~ s{$regex}{$handle->($1, $2, $3, $4)}eg;
1724         return $content;
1725 }
1726
1727 sub filter ($$$) {
1728         my $page=shift;
1729         my $destpage=shift;
1730         my $content=shift;
1731
1732         run_hooks(filter => sub {
1733                 $content=shift->(page => $page, destpage => $destpage,
1734                         content => $content);
1735         });
1736
1737         return $content;
1738 }
1739
1740 sub check_canedit ($$$;$) {
1741         my $page=shift;
1742         my $q=shift;
1743         my $session=shift;
1744         my $nonfatal=shift;
1745
1746         my $canedit;
1747         run_hooks(canedit => sub {
1748                 return if defined $canedit;
1749                 my $ret=shift->($page, $q, $session);
1750                 if (defined $ret) {
1751                         if ($ret eq "") {
1752                                 $canedit=1;
1753                         }
1754                         elsif (ref $ret eq 'CODE') {
1755                                 $ret->() unless $nonfatal;
1756                                 $canedit=0;
1757                         }
1758                         elsif (defined $ret) {
1759                                 error($ret) unless $nonfatal;
1760                                 $canedit=0;
1761                         }
1762                 }
1763         });
1764         return defined $canedit ? $canedit : 1;
1765 }
1766
1767 sub check_content (@) {
1768         my %params=@_;
1769
1770         return 1 if ! exists $hooks{checkcontent}; # optimisation
1771
1772         if (exists $pagesources{$params{page}}) {
1773                 my @diff;
1774                 my %old=map { $_ => 1 }
1775                         split("\n", readfile(srcfile($pagesources{$params{page}})));
1776                 foreach my $line (split("\n", $params{content})) {
1777                         push @diff, $line if ! exists $old{$line};
1778                 }
1779                 $params{diff}=join("\n", @diff);
1780         }
1781
1782         my $ok;
1783         run_hooks(checkcontent => sub {
1784                 return if defined $ok;
1785                 my $ret=shift->(%params);
1786                 if (defined $ret) {
1787                         if ($ret eq "") {
1788                                 $ok=1;
1789                         }
1790                         elsif (ref $ret eq 'CODE') {
1791                                 $ret->() unless $params{nonfatal};
1792                                 $ok=0;
1793                         }
1794                         elsif (defined $ret) {
1795                                 error($ret) unless $params{nonfatal};
1796                                 $ok=0;
1797                         }
1798                 }
1799
1800         });
1801         return defined $ok ? $ok : 1;
1802 }
1803
1804 sub check_canchange (@) {
1805         my %params = @_;
1806         my $cgi = $params{cgi};
1807         my $session = $params{session};
1808         my @changes = @{$params{changes}};
1809
1810         my %newfiles;
1811         foreach my $change (@changes) {
1812                 # This untaint is safe because we check file_pruned and
1813                 # wiki_file_regexp.
1814                 my ($file)=$change->{file}=~/$config{wiki_file_regexp}/;
1815                 $file=possibly_foolish_untaint($file);
1816                 if (! defined $file || ! length $file ||
1817                     file_pruned($file)) {
1818                         error(gettext("bad file name %s"), $file);
1819                 }
1820
1821                 my $type=pagetype($file);
1822                 my $page=pagename($file) if defined $type;
1823
1824                 if ($change->{action} eq 'add') {
1825                         $newfiles{$file}=1;
1826                 }
1827
1828                 if ($change->{action} eq 'change' ||
1829                     $change->{action} eq 'add') {
1830                         if (defined $page) {
1831                                 check_canedit($page, $cgi, $session);
1832                                 next;
1833                         }
1834                         else {
1835                                 if (IkiWiki::Plugin::attachment->can("check_canattach")) {
1836                                         IkiWiki::Plugin::attachment::check_canattach($session, $file, $change->{path});
1837                                         check_canedit($file, $cgi, $session);
1838                                         next;
1839                                 }
1840                         }
1841                 }
1842                 elsif ($change->{action} eq 'remove') {
1843                         # check_canremove tests to see if the file is present
1844                         # on disk. This will fail when a single commit adds a
1845                         # file and then removes it again. Avoid the problem
1846                         # by not testing the removal in such pairs of changes.
1847                         # (The add is still tested, just to make sure that
1848                         # no data is added to the repo that a web edit
1849                         # could not add.)
1850                         next if $newfiles{$file};
1851
1852                         if (IkiWiki::Plugin::remove->can("check_canremove")) {
1853                                 IkiWiki::Plugin::remove::check_canremove(defined $page ? $page : $file, $cgi, $session);
1854                                 check_canedit(defined $page ? $page : $file, $cgi, $session);
1855                                 next;
1856                         }
1857                 }
1858                 else {
1859                         error "unknown action ".$change->{action};
1860                 }
1861
1862                 error sprintf(gettext("you are not allowed to change %s"), $file);
1863         }
1864 }
1865
1866
1867 my $wikilock;
1868
1869 sub lockwiki () {
1870         # Take an exclusive lock on the wiki to prevent multiple concurrent
1871         # run issues. The lock will be dropped on program exit.
1872         if (! -d $config{wikistatedir}) {
1873                 mkdir($config{wikistatedir});
1874         }
1875         open($wikilock, '>', "$config{wikistatedir}/lockfile") ||
1876                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
1877         if (! flock($wikilock, LOCK_EX | LOCK_NB)) {
1878                 debug("failed to get lock; waiting...");
1879                 if (! flock($wikilock, LOCK_EX)) {
1880                         error("failed to get lock");
1881                 }
1882         }
1883         return 1;
1884 }
1885
1886 sub unlockwiki () {
1887         POSIX::close($ENV{IKIWIKI_CGILOCK_FD}) if exists $ENV{IKIWIKI_CGILOCK_FD};
1888         return close($wikilock) if $wikilock;
1889         return;
1890 }
1891
1892 my $commitlock;
1893
1894 sub commit_hook_enabled () {
1895         open($commitlock, '+>', "$config{wikistatedir}/commitlock") ||
1896                 error("cannot write to $config{wikistatedir}/commitlock: $!");
1897         if (! flock($commitlock, 1 | 4)) { # LOCK_SH | LOCK_NB to test
1898                 close($commitlock) || error("failed closing commitlock: $!");
1899                 return 0;
1900         }
1901         close($commitlock) || error("failed closing commitlock: $!");
1902         return 1;
1903 }
1904
1905 sub disable_commit_hook () {
1906         open($commitlock, '>', "$config{wikistatedir}/commitlock") ||
1907                 error("cannot write to $config{wikistatedir}/commitlock: $!");
1908         if (! flock($commitlock, 2)) { # LOCK_EX
1909                 error("failed to get commit lock");
1910         }
1911         return 1;
1912 }
1913
1914 sub enable_commit_hook () {
1915         return close($commitlock) if $commitlock;
1916         return;
1917 }
1918
1919 sub loadindex () {
1920         %oldrenderedfiles=%pagectime=();
1921         my $rebuild=$config{rebuild};
1922         if (! $rebuild) {
1923                 %pagesources=%pagemtime=%oldlinks=%links=%depends=
1924                 %destsources=%renderedfiles=%pagecase=%pagestate=
1925                 %depends_simple=%typedlinks=%oldtypedlinks=();
1926         }
1927         my $in;
1928         if (! open ($in, "<", "$config{wikistatedir}/indexdb")) {
1929                 if (-e "$config{wikistatedir}/index") {
1930                         system("ikiwiki-transition", "indexdb", $config{srcdir});
1931                         open ($in, "<", "$config{wikistatedir}/indexdb") || return;
1932                 }
1933                 else {
1934                         # gettime on first build
1935                         $config{gettime}=1 unless defined $config{gettime};
1936                         return;
1937                 }
1938         }
1939
1940         my $index=Storable::fd_retrieve($in);
1941         if (! defined $index) {
1942                 return 0;
1943         }
1944
1945         my $pages;
1946         if (exists $index->{version} && ! ref $index->{version}) {
1947                 $pages=$index->{page};
1948                 %wikistate=%{$index->{state}};
1949                 # Handle plugins that got disabled by loading a new setup.
1950                 if (exists $config{setupfile}) {
1951                         require IkiWiki::Setup;
1952                         IkiWiki::Setup::disabled_plugins(
1953                                 grep { ! $loaded_plugins{$_} } keys %wikistate);
1954                 }
1955         }
1956         else {
1957                 $pages=$index;
1958                 %wikistate=();
1959         }
1960
1961         foreach my $src (keys %$pages) {
1962                 my $d=$pages->{$src};
1963                 my $page;
1964                 if (exists $d->{page} && ! $rebuild) {
1965                         $page=$d->{page};
1966                 }
1967                 else {
1968                         $page=pagename($src);
1969                 }
1970                 $pagectime{$page}=$d->{ctime};
1971                 $pagesources{$page}=$src;
1972                 if (! $rebuild) {
1973                         $pagemtime{$page}=$d->{mtime};
1974                         $renderedfiles{$page}=$d->{dest};
1975                         if (exists $d->{links} && ref $d->{links}) {
1976                                 $links{$page}=$d->{links};
1977                                 $oldlinks{$page}=[@{$d->{links}}];
1978                         }
1979                         if (ref $d->{depends_simple} eq 'ARRAY') {
1980                                 # old format
1981                                 $depends_simple{$page}={
1982                                         map { $_ => 1 } @{$d->{depends_simple}}
1983                                 };
1984                         }
1985                         elsif (exists $d->{depends_simple}) {
1986                                 $depends_simple{$page}=$d->{depends_simple};
1987                         }
1988                         if (exists $d->{dependslist}) {
1989                                 # old format
1990                                 $depends{$page}={
1991                                         map { $_ => $DEPEND_CONTENT }
1992                                                 @{$d->{dependslist}}
1993                                 };
1994                         }
1995                         elsif (exists $d->{depends} && ! ref $d->{depends}) {
1996                                 # old format
1997                                 $depends{$page}={$d->{depends} => $DEPEND_CONTENT };
1998                         }
1999                         elsif (exists $d->{depends}) {
2000                                 $depends{$page}=$d->{depends};
2001                         }
2002                         if (exists $d->{state}) {
2003                                 $pagestate{$page}=$d->{state};
2004                         }
2005                         if (exists $d->{typedlinks}) {
2006                                 $typedlinks{$page}=$d->{typedlinks};
2007
2008                                 while (my ($type, $links) = each %{$typedlinks{$page}}) {
2009                                         next unless %$links;
2010                                         $oldtypedlinks{$page}{$type} = {%$links};
2011                                 }
2012                         }
2013                 }
2014                 $oldrenderedfiles{$page}=[@{$d->{dest}}];
2015         }
2016         foreach my $page (keys %pagesources) {
2017                 $pagecase{lc $page}=$page;
2018         }
2019         foreach my $page (keys %renderedfiles) {
2020                 $destsources{$_}=$page foreach @{$renderedfiles{$page}};
2021         }
2022         $lastrev=$index->{lastrev};
2023         @underlayfiles=@{$index->{underlayfiles}} if ref $index->{underlayfiles};
2024         return close($in);
2025 }
2026
2027 sub saveindex () {
2028         run_hooks(savestate => sub { shift->() });
2029
2030         my @plugins=keys %loaded_plugins;
2031
2032         if (! -d $config{wikistatedir}) {
2033                 mkdir($config{wikistatedir});
2034         }
2035         my $newfile="$config{wikistatedir}/indexdb.new";
2036         my $cleanup = sub { unlink($newfile) };
2037         open (my $out, '>', $newfile) || error("cannot write to $newfile: $!", $cleanup);
2038
2039         my %index;
2040         foreach my $page (keys %pagemtime) {
2041                 next unless $pagemtime{$page};
2042                 my $src=$pagesources{$page};
2043
2044                 $index{page}{$src}={
2045                         page => $page,
2046                         ctime => $pagectime{$page},
2047                         mtime => $pagemtime{$page},
2048                         dest => $renderedfiles{$page},
2049                         links => $links{$page},
2050                 };
2051
2052                 if (exists $depends{$page}) {
2053                         $index{page}{$src}{depends} = $depends{$page};
2054                 }
2055
2056                 if (exists $depends_simple{$page}) {
2057                         $index{page}{$src}{depends_simple} = $depends_simple{$page};
2058                 }
2059
2060                 if (exists $typedlinks{$page} && %{$typedlinks{$page}}) {
2061                         $index{page}{$src}{typedlinks} = $typedlinks{$page};
2062                 }
2063
2064                 if (exists $pagestate{$page}) {
2065                         $index{page}{$src}{state}=$pagestate{$page};
2066                 }
2067         }
2068
2069         $index{state}={};
2070         foreach my $id (@plugins) {
2071                 $index{state}{$id}={}; # used to detect disabled plugins
2072                 foreach my $key (keys %{$wikistate{$id}}) {
2073                         $index{state}{$id}{$key}=$wikistate{$id}{$key};
2074                 }
2075         }
2076
2077         $index{lastrev}=$lastrev;
2078         $index{underlayfiles}=\@underlayfiles;
2079
2080         $index{version}="3";
2081         my $ret=Storable::nstore_fd(\%index, $out);
2082         return if ! defined $ret || ! $ret;
2083         close $out || error("failed saving to $newfile: $!", $cleanup);
2084         rename($newfile, "$config{wikistatedir}/indexdb") ||
2085                 error("failed renaming $newfile to $config{wikistatedir}/indexdb", $cleanup);
2086
2087         return 1;
2088 }
2089
2090 sub template_file ($) {
2091         my $name=shift;
2092
2093         my $tpage=($name =~ s/^\///) ? $name : "templates/$name";
2094         my $template;
2095         if ($name !~ /\.tmpl$/ && exists $pagesources{$tpage}) {
2096                 $template=srcfile($pagesources{$tpage}, 1);
2097                 $name.=".tmpl";
2098         }
2099         else {
2100                 $template=srcfile($tpage, 1);
2101         }
2102
2103         if (defined $template) {
2104                 return $template, $tpage, 1 if wantarray;
2105                 return $template;
2106         }
2107         else {
2108                 $name=~s:/::; # avoid path traversal
2109                 foreach my $dir ($config{templatedir},
2110                                  "$installdir/share/ikiwiki/templates") {
2111                         if (-e "$dir/$name") {
2112                                 $template="$dir/$name";
2113                                 last;
2114                         }
2115                 }
2116                 if (defined $template) {
2117                         return $template, $tpage if wantarray;
2118                         return $template;
2119                 }
2120         }
2121
2122         return;
2123 }
2124
2125 sub template_depends ($$;@) {
2126         my $name=shift;
2127         my $page=shift;
2128
2129         my ($filename, $tpage, $untrusted)=template_file($name);
2130         if (! defined $filename) {
2131                 error(sprintf(gettext("template %s not found"), $name))
2132         }
2133
2134         if (defined $page && defined $tpage) {
2135                 add_depends($page, $tpage);
2136         }
2137
2138         my @opts=(
2139                 filter => sub {
2140                         my $text_ref = shift;
2141                         ${$text_ref} = decode_utf8(${$text_ref});
2142                         run_hooks(readtemplate => sub {
2143                                 ${$text_ref} = shift->(
2144                                         id => $name,
2145                                         page => $tpage,
2146                                         content => ${$text_ref},
2147                                         untrusted => $untrusted,
2148                                 );
2149                         });
2150                 },
2151                 loop_context_vars => 1,
2152                 die_on_bad_params => 0,
2153                 parent_global_vars => 1,
2154                 filename => $filename,
2155                 @_,
2156                 ($untrusted ? (no_includes => 1) : ()),
2157         );
2158         return @opts if wantarray;
2159
2160         require HTML::Template;
2161         return HTML::Template->new(@opts);
2162 }
2163
2164 sub template ($;@) {
2165         template_depends(shift, undef, @_);
2166 }
2167
2168 sub templateactions ($$) {
2169         my $template=shift;
2170         my $page=shift;
2171
2172         my $have_actions=0;
2173         my @actions;
2174         run_hooks(pageactions => sub {
2175                 push @actions, map { { action => $_ } }
2176                         grep { defined } shift->(page => $page);
2177         });
2178         $template->param(actions => \@actions);
2179
2180         if ($config{cgiurl} && exists $hooks{auth}) {
2181                 $template->param(prefsurl => cgiurl(do => "prefs"));
2182                 $have_actions=1;
2183         }
2184
2185         if ($have_actions || @actions) {
2186                 $template->param(have_actions => 1);
2187         }
2188 }
2189
2190 sub hook (@) {
2191         my %param=@_;
2192
2193         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
2194                 error 'hook requires type, call, and id parameters';
2195         }
2196
2197         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
2198
2199         $hooks{$param{type}}{$param{id}}=\%param;
2200         return 1;
2201 }
2202
2203 sub run_hooks ($$) {
2204         # Calls the given sub for each hook of the given type,
2205         # passing it the hook function to call.
2206         my $type=shift;
2207         my $sub=shift;
2208
2209         if (exists $hooks{$type}) {
2210                 my (@first, @middle, @last);
2211                 foreach my $id (keys %{$hooks{$type}}) {
2212                         if ($hooks{$type}{$id}{first}) {
2213                                 push @first, $id;
2214                         }
2215                         elsif ($hooks{$type}{$id}{last}) {
2216                                 push @last, $id;
2217                         }
2218                         else {
2219                                 push @middle, $id;
2220                         }
2221                 }
2222                 foreach my $id (@first, @middle, @last) {
2223                         $sub->($hooks{$type}{$id}{call});
2224                 }
2225         }
2226
2227         return 1;
2228 }
2229
2230 sub rcs_update () {
2231         $hooks{rcs}{rcs_update}{call}->(@_);
2232 }
2233
2234 sub rcs_prepedit ($) {
2235         $hooks{rcs}{rcs_prepedit}{call}->(@_);
2236 }
2237
2238 sub rcs_commit (@) {
2239         $hooks{rcs}{rcs_commit}{call}->(@_);
2240 }
2241
2242 sub rcs_commit_staged (@) {
2243         $hooks{rcs}{rcs_commit_staged}{call}->(@_);
2244 }
2245
2246 sub rcs_add ($) {
2247         $hooks{rcs}{rcs_add}{call}->(@_);
2248 }
2249
2250 sub rcs_remove ($) {
2251         $hooks{rcs}{rcs_remove}{call}->(@_);
2252 }
2253
2254 sub rcs_rename ($$) {
2255         $hooks{rcs}{rcs_rename}{call}->(@_);
2256 }
2257
2258 sub rcs_recentchanges ($) {
2259         $hooks{rcs}{rcs_recentchanges}{call}->(@_);
2260 }
2261
2262 sub rcs_diff ($;$) {
2263         $hooks{rcs}{rcs_diff}{call}->(@_);
2264 }
2265
2266 sub rcs_getctime ($) {
2267         $hooks{rcs}{rcs_getctime}{call}->(@_);
2268 }
2269
2270 sub rcs_getmtime ($) {
2271         $hooks{rcs}{rcs_getmtime}{call}->(@_);
2272 }
2273
2274 sub rcs_receive () {
2275         $hooks{rcs}{rcs_receive}{call}->();
2276 }
2277
2278 sub add_depends ($$;$) {
2279         my $page=shift;
2280         my $pagespec=shift;
2281         my $deptype=shift || $DEPEND_CONTENT;
2282
2283         # Is the pagespec a simple page name?
2284         if ($pagespec =~ /$config{wiki_file_regexp}/ &&
2285             $pagespec !~ /[\s*?()!]/) {
2286                 $depends_simple{$page}{lc $pagespec} |= $deptype;
2287                 return 1;
2288         }
2289
2290         # Add explicit dependencies for influences.
2291         my $sub=pagespec_translate($pagespec);
2292         return unless defined $sub;
2293         foreach my $p (keys %pagesources) {
2294                 my $r=$sub->($p, location => $page);
2295                 my $i=$r->influences;
2296                 my $static=$r->influences_static;
2297                 foreach my $k (keys %$i) {
2298                         next unless $r || $static || $k eq $page;
2299                         $depends_simple{$page}{lc $k} |= $i->{$k};
2300                 }
2301                 last if $static;
2302         }
2303
2304         $depends{$page}{$pagespec} |= $deptype;
2305         return 1;
2306 }
2307
2308 sub deptype (@) {
2309         my $deptype=0;
2310         foreach my $type (@_) {
2311                 if ($type eq 'presence') {
2312                         $deptype |= $DEPEND_PRESENCE;
2313                 }
2314                 elsif ($type eq 'links') {
2315                         $deptype |= $DEPEND_LINKS;
2316                 }
2317                 elsif ($type eq 'content') {
2318                         $deptype |= $DEPEND_CONTENT;
2319                 }
2320         }
2321         return $deptype;
2322 }
2323
2324 my $file_prune_regexp;
2325 sub file_pruned ($) {
2326         my $file=shift;
2327
2328         if (defined $config{include} && length $config{include}) {
2329                 return 0 if $file =~ m/$config{include}/;
2330         }
2331
2332         if (! defined $file_prune_regexp) {
2333                 $file_prune_regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
2334                 $file_prune_regexp=qr/$file_prune_regexp/;
2335         }
2336         return $file =~ m/$file_prune_regexp/;
2337 }
2338
2339 sub define_gettext () {
2340         # If translation is needed, redefine the gettext function to do it.
2341         # Otherwise, it becomes a quick no-op.
2342         my $gettext_obj;
2343         my $getobj;
2344         if ((exists $ENV{LANG} && length $ENV{LANG}) ||
2345             (exists $ENV{LC_ALL} && length $ENV{LC_ALL}) ||
2346             (exists $ENV{LC_MESSAGES} && length $ENV{LC_MESSAGES})) {
2347                 $getobj=sub {
2348                         $gettext_obj=eval q{
2349                                 use Locale::gettext q{textdomain};
2350                                 Locale::gettext->domain('ikiwiki')
2351                         };
2352                 };
2353         }
2354
2355         no warnings 'redefine';
2356         *gettext=sub {
2357                 $getobj->() if $getobj;
2358                 if ($gettext_obj) {
2359                         $gettext_obj->get(shift);
2360                 }
2361                 else {
2362                         return shift;
2363                 }
2364         };
2365         *ngettext=sub {
2366                 $getobj->() if $getobj;
2367                 if ($gettext_obj) {
2368                         $gettext_obj->nget(@_);
2369                 }
2370                 else {
2371                         return ($_[2] == 1 ? $_[0] : $_[1])
2372                 }
2373         };
2374 }
2375
2376 sub gettext {
2377         define_gettext();
2378         gettext(@_);
2379 }
2380
2381 sub ngettext {
2382         define_gettext();
2383         ngettext(@_);
2384 }
2385
2386 sub yesno ($) {
2387         my $val=shift;
2388
2389         return (defined $val && (lc($val) eq gettext("yes") || lc($val) eq "yes" || $val eq "1"));
2390 }
2391
2392 sub inject {
2393         # Injects a new function into the symbol table to replace an
2394         # exported function.
2395         my %params=@_;
2396
2397         # This is deep ugly perl foo, beware.
2398         no strict;
2399         no warnings;
2400         if (! defined $params{parent}) {
2401                 $params{parent}='::';
2402                 $params{old}=\&{$params{name}};
2403                 $params{name}=~s/.*:://;
2404         }
2405         my $parent=$params{parent};
2406         foreach my $ns (grep /^\w+::/, keys %{$parent}) {
2407                 $ns = $params{parent} . $ns;
2408                 inject(%params, parent => $ns) unless $ns eq '::main::';
2409                 *{$ns . $params{name}} = $params{call}
2410                         if exists ${$ns}{$params{name}} &&
2411                            \&{${$ns}{$params{name}}} == $params{old};
2412         }
2413         use strict;
2414         use warnings;
2415 }
2416
2417 sub add_link ($$;$) {
2418         my $page=shift;
2419         my $link=shift;
2420         my $type=shift;
2421
2422         push @{$links{$page}}, $link
2423                 unless grep { $_ eq $link } @{$links{$page}};
2424
2425         if (defined $type) {
2426                 $typedlinks{$page}{$type}{$link} = 1;
2427         }
2428 }
2429
2430 sub add_autofile ($$$) {
2431         my $file=shift;
2432         my $plugin=shift;
2433         my $generator=shift;
2434
2435         $autofiles{$file}{plugin}=$plugin;
2436         $autofiles{$file}{generator}=$generator;
2437 }
2438
2439 sub useragent () {
2440         return LWP::UserAgent->new(
2441                 cookie_jar => $config{cookiejar},
2442                 env_proxy => 1,         # respect proxy env vars
2443                 agent => $config{useragent},
2444         );
2445 }
2446
2447 sub sortspec_translate ($$) {
2448         my $spec = shift;
2449         my $reverse = shift;
2450
2451         my $code = "";
2452         my @data;
2453         while ($spec =~ m{
2454                 \s*
2455                 (-?)            # group 1: perhaps negated
2456                 \s*
2457                 (               # group 2: a word
2458                         \w+\([^\)]*\)   # command(params)
2459                         |
2460                         [^\s]+          # or anything else
2461                 )
2462                 \s*
2463         }gx) {
2464                 my $negated = $1;
2465                 my $word = $2;
2466                 my $params = undef;
2467
2468                 if ($word =~ m/^(\w+)\((.*)\)$/) {
2469                         # command with parameters
2470                         $params = $2;
2471                         $word = $1;
2472                 }
2473                 elsif ($word !~ m/^\w+$/) {
2474                         error(sprintf(gettext("invalid sort type %s"), $word));
2475                 }
2476
2477                 if (length $code) {
2478                         $code .= " || ";
2479                 }
2480
2481                 if ($negated) {
2482                         $code .= "-";
2483                 }
2484
2485                 if (exists $IkiWiki::SortSpec::{"cmp_$word"}) {
2486                         if (defined $params) {
2487                                 push @data, $params;
2488                                 $code .= "IkiWiki::SortSpec::cmp_$word(\$data[$#data])";
2489                         }
2490                         else {
2491                                 $code .= "IkiWiki::SortSpec::cmp_$word(undef)";
2492                         }
2493                 }
2494                 else {
2495                         error(sprintf(gettext("unknown sort type %s"), $word));
2496                 }
2497         }
2498
2499         if (! length $code) {
2500                 # undefined sorting method... sort arbitrarily
2501                 return sub { 0 };
2502         }
2503
2504         if ($reverse) {
2505                 $code="-($code)";
2506         }
2507
2508         no warnings;
2509         return eval 'sub { '.$code.' }';
2510 }
2511
2512 sub pagespec_translate ($) {
2513         my $spec=shift;
2514
2515         # Convert spec to perl code.
2516         my $code="";
2517         my @data;
2518         while ($spec=~m{
2519                 \s*             # ignore whitespace
2520                 (               # 1: match a single word
2521                         \!              # !
2522                 |
2523                         \(              # (
2524                 |
2525                         \)              # )
2526                 |
2527                         \w+\([^\)]*\)   # command(params)
2528                 |
2529                         [^\s()]+        # any other text
2530                 )
2531                 \s*             # ignore whitespace
2532         }gx) {
2533                 my $word=$1;
2534                 if (lc $word eq 'and') {
2535                         $code.=' &';
2536                 }
2537                 elsif (lc $word eq 'or') {
2538                         $code.=' |';
2539                 }
2540                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
2541                         $code.=' '.$word;
2542                 }
2543                 elsif ($word =~ /^(\w+)\((.*)\)$/) {
2544                         if (exists $IkiWiki::PageSpec::{"match_$1"}) {
2545                                 push @data, $2;
2546                                 $code.="IkiWiki::PageSpec::match_$1(\$page, \$data[$#data], \@_)";
2547                         }
2548                         else {
2549                                 push @data, qq{unknown function in pagespec "$word"};
2550                                 $code.="IkiWiki::ErrorReason->new(\$data[$#data])";
2551                         }
2552                 }
2553                 else {
2554                         push @data, $word;
2555                         $code.=" IkiWiki::PageSpec::match_glob(\$page, \$data[$#data], \@_)";
2556                 }
2557         }
2558
2559         if (! length $code) {
2560                 $code="IkiWiki::FailReason->new('empty pagespec')";
2561         }
2562
2563         no warnings;
2564         return eval 'sub { my $page=shift; '.$code.' }';
2565 }
2566
2567 sub pagespec_match ($$;@) {
2568         my $page=shift;
2569         my $spec=shift;
2570         my @params=@_;
2571
2572         # Backwards compatability with old calling convention.
2573         if (@params == 1) {
2574                 unshift @params, 'location';
2575         }
2576
2577         my $sub=pagespec_translate($spec);
2578         return IkiWiki::ErrorReason->new("syntax error in pagespec \"$spec\"")
2579                 if ! defined $sub;
2580         return $sub->($page, @params);
2581 }
2582
2583 # e.g. @pages = sort_pages("title", \@pages, reverse => "yes")
2584 #
2585 # Not exported yet, but could be in future if it is generally useful.
2586 # Note that this signature is not the same as IkiWiki::SortSpec::sort_pages,
2587 # which is "more internal".
2588 sub sort_pages ($$;@) {
2589         my $sort = shift;
2590         my $list = shift;
2591         my %params = @_;
2592         $sort = sortspec_translate($sort, $params{reverse});
2593         return IkiWiki::SortSpec::sort_pages($sort, @$list);
2594 }
2595
2596 sub pagespec_match_list ($$;@) {
2597         my $page=shift;
2598         my $pagespec=shift;
2599         my %params=@_;
2600
2601         # Backwards compatability with old calling convention.
2602         if (ref $page) {
2603                 print STDERR "warning: a plugin (".caller().") is using pagespec_match_list in an obsolete way, and needs to be updated\n";
2604                 $params{list}=$page;
2605                 $page=$params{location}; # ugh!
2606         }
2607
2608         my $sub=pagespec_translate($pagespec);
2609         error "syntax error in pagespec \"$pagespec\""
2610                 if ! defined $sub;
2611         my $sort=sortspec_translate($params{sort}, $params{reverse})
2612                 if defined $params{sort};
2613
2614         my @candidates;
2615         if (exists $params{list}) {
2616                 @candidates=exists $params{filter}
2617                         ? grep { ! $params{filter}->($_) } @{$params{list}}
2618                         : @{$params{list}};
2619         }
2620         else {
2621                 @candidates=exists $params{filter}
2622                         ? grep { ! $params{filter}->($_) } keys %pagesources
2623                         : keys %pagesources;
2624         }
2625
2626         # clear params, remainder is passed to pagespec
2627         $depends{$page}{$pagespec} |= ($params{deptype} || $DEPEND_CONTENT);
2628         my $num=$params{num};
2629         delete @params{qw{num deptype reverse sort filter list}};
2630
2631         # when only the top matches will be returned, it's efficient to
2632         # sort before matching to pagespec,
2633         if (defined $num && defined $sort) {
2634                 @candidates=IkiWiki::SortSpec::sort_pages(
2635                         $sort, @candidates);
2636         }
2637
2638         my @matches;
2639         my $firstfail;
2640         my $count=0;
2641         my $accum=IkiWiki::SuccessReason->new();
2642         foreach my $p (@candidates) {
2643                 my $r=$sub->($p, %params, location => $page);
2644                 error(sprintf(gettext("cannot match pages: %s"), $r))
2645                         if $r->isa("IkiWiki::ErrorReason");
2646                 unless ($r || $r->influences_static) {
2647                         $r->remove_influence($p);
2648                 }
2649                 $accum |= $r;
2650                 if ($r) {
2651                         push @matches, $p;
2652                         last if defined $num && ++$count == $num;
2653                 }
2654         }
2655
2656         # Add simple dependencies for accumulated influences.
2657         my $i=$accum->influences;
2658         foreach my $k (keys %$i) {
2659                 $depends_simple{$page}{lc $k} |= $i->{$k};
2660         }
2661
2662         # when all matches will be returned, it's efficient to
2663         # sort after matching
2664         if (! defined $num && defined $sort) {
2665                 return IkiWiki::SortSpec::sort_pages(
2666                         $sort, @matches);
2667         }
2668         else {
2669                 return @matches;
2670         }
2671 }
2672
2673 sub pagespec_valid ($) {
2674         my $spec=shift;
2675
2676         return defined pagespec_translate($spec);
2677 }
2678
2679 sub glob2re ($) {
2680         my $re=quotemeta(shift);
2681         $re=~s/\\\*/.*/g;
2682         $re=~s/\\\?/./g;
2683         return qr/^$re$/i;
2684 }
2685
2686 package IkiWiki::FailReason;
2687
2688 use overload (
2689         '""'    => sub { $_[0][0] },
2690         '0+'    => sub { 0 },
2691         '!'     => sub { bless $_[0], 'IkiWiki::SuccessReason'},
2692         '&'     => sub { $_[0]->merge_influences($_[1], 1); $_[0] },
2693         '|'     => sub { $_[1]->merge_influences($_[0]); $_[1] },
2694         fallback => 1,
2695 );
2696
2697 our @ISA = 'IkiWiki::SuccessReason';
2698
2699 package IkiWiki::SuccessReason;
2700
2701 # A blessed array-ref:
2702 #
2703 # [0]: human-readable reason for success (or, in FailReason subclass, failure)
2704 # [1]{""}:
2705 #      - if absent or false, the influences of this evaluation are "static",
2706 #        see the influences_static method
2707 #      - if true, they are dynamic (not static)
2708 # [1]{any other key}:
2709 #      the dependency types of influences, as returned by the influences method
2710
2711 use overload (
2712         # in string context, it's the human-readable reason
2713         '""'    => sub { $_[0][0] },
2714         # in boolean context, SuccessReason is 1 and FailReason is 0
2715         '0+'    => sub { 1 },
2716         # negating a result gives the opposite result with the same influences
2717         '!'     => sub { bless $_[0], 'IkiWiki::FailReason'},
2718         # A & B = (A ? B : A) with the influences of both
2719         '&'     => sub { $_[1]->merge_influences($_[0], 1); $_[1] },
2720         # A | B = (A ? A : B) with the influences of both
2721         '|'     => sub { $_[0]->merge_influences($_[1]); $_[0] },
2722         fallback => 1,
2723 );
2724
2725 # SuccessReason->new("human-readable reason", page => deptype, ...)
2726
2727 sub new {
2728         my $class = shift;
2729         my $value = shift;
2730         return bless [$value, {@_}], $class;
2731 }
2732
2733 # influences(): return a reference to a copy of the hash
2734 # { page => dependency type } describing the pages that indirectly influenced
2735 # this result, but would not cause a dependency through ikiwiki's core
2736 # dependency logic.
2737 #
2738 # See [[todo/dependency_types]] for extensive discussion of what this means.
2739 #
2740 # influences(page => deptype, ...): remove all influences, replace them
2741 # with the arguments, and return a reference to a copy of the new influences.
2742
2743 sub influences {
2744         my $this=shift;
2745         $this->[1]={@_} if @_;
2746         my %i=%{$this->[1]};
2747         delete $i{""};
2748         return \%i;
2749 }
2750
2751 # True if this result has the same influences whichever page it matches,
2752 # For instance, whether bar matches backlink(foo) is influenced only by
2753 # the set of links in foo, so its only influence is { foo => DEPEND_LINKS },
2754 # which does not mention bar anywhere.
2755 #
2756 # False if this result would have different influences when matching
2757 # different pages. For instance, when testing whether link(foo) matches bar,
2758 # { bar => DEPEND_LINKS } is an influence on that result, because changing
2759 # bar's links could change the outcome; so its influences are not the same
2760 # as when testing whether link(foo) matches baz.
2761 #
2762 # Static influences are one of the things that make pagespec_match_list
2763 # more efficient than repeated calls to pagespec_match.
2764
2765 sub influences_static {
2766         return ! $_[0][1]->{""};
2767 }
2768
2769 # Change the influences of $this to be the influences of "$this & $other"
2770 # or "$this | $other".
2771 #
2772 # If both $this and $other are either successful or have influences,
2773 # or this is an "or" operation, the result has all the influences from
2774 # either of the arguments. It has dynamic influences if either argument
2775 # has dynamic influences.
2776 #
2777 # If this is an "and" operation, and at least one argument is a
2778 # FailReason with no influences, the result has no influences, and they
2779 # are not dynamic. For instance, link(foo) matching bar is influenced
2780 # by bar, but enabled(ddate) has no influences. Suppose ddate is disabled;
2781 # then (link(foo) and enabled(ddate)) not matching bar is not influenced by
2782 # bar, because it would be false however often you edit bar.
2783
2784 sub merge_influences {
2785         my $this=shift;
2786         my $other=shift;
2787         my $anded=shift;
2788
2789         # This "if" is odd because it needs to avoid negating $this
2790         # or $other, which would alter the objects in-place. Be careful.
2791         if (! $anded || (($this || %{$this->[1]}) &&
2792                          ($other || %{$other->[1]}))) {
2793                 foreach my $influence (keys %{$other->[1]}) {
2794                         $this->[1]{$influence} |= $other->[1]{$influence};
2795                 }
2796         }
2797         else {
2798                 # influence blocker
2799                 $this->[1]={};
2800         }
2801 }
2802
2803 # Change $this so it is not considered to be influenced by $torm.
2804
2805 sub remove_influence {
2806         my $this=shift;
2807         my $torm=shift;
2808
2809         delete $this->[1]{$torm};
2810 }
2811
2812 package IkiWiki::ErrorReason;
2813
2814 our @ISA = 'IkiWiki::FailReason';
2815
2816 package IkiWiki::PageSpec;
2817
2818 sub derel ($$) {
2819         my $path=shift;
2820         my $from=shift;
2821
2822         if ($path =~ m!^\.(/|$)!) {
2823                 if ($1) {
2824                         $from=~s#/?[^/]+$## if defined $from;
2825                         $path=~s#^\./##;
2826                         $path="$from/$path" if defined $from && length $from;
2827                 }
2828                 else {
2829                         $path = $from;
2830                         $path = "" unless defined $path;
2831                 }
2832         }
2833
2834         return $path;
2835 }
2836
2837 my %glob_cache;
2838
2839 sub match_glob ($$;@) {
2840         my $page=shift;
2841         my $glob=shift;
2842         my %params=@_;
2843
2844         $glob=derel($glob, $params{location});
2845
2846         # Instead of converting the glob to a regex every time,
2847         # cache the compiled regex to save time.
2848         my $re=$glob_cache{$glob};
2849         unless (defined $re) {
2850                 $glob_cache{$glob} = $re = IkiWiki::glob2re($glob);
2851         }
2852         if ($page =~ $re) {
2853                 if (! IkiWiki::isinternal($page) || $params{internal}) {
2854                         return IkiWiki::SuccessReason->new("$glob matches $page");
2855                 }
2856                 else {
2857                         return IkiWiki::FailReason->new("$glob matches $page, but the page is an internal page");
2858                 }
2859         }
2860         else {
2861                 return IkiWiki::FailReason->new("$glob does not match $page");
2862         }
2863 }
2864
2865 sub match_internal ($$;@) {
2866         return match_glob(shift, shift, @_, internal => 1)
2867 }
2868
2869 sub match_page ($$;@) {
2870         my $page=shift;
2871         my $match=match_glob($page, shift, @_);
2872         if ($match) {
2873                 my $source=exists $IkiWiki::pagesources{$page} ?
2874                         $IkiWiki::pagesources{$page} :
2875                         $IkiWiki::delpagesources{$page};
2876                 my $type=defined $source ? IkiWiki::pagetype($source) : undef;
2877                 if (! defined $type) {
2878                         return IkiWiki::FailReason->new("$page is not a page");
2879                 }
2880         }
2881         return $match;
2882 }
2883
2884 sub match_link ($$;@) {
2885         my $page=shift;
2886         my $link=lc(shift);
2887         my %params=@_;
2888
2889         $link=derel($link, $params{location});
2890         my $from=exists $params{location} ? $params{location} : '';
2891         my $linktype=$params{linktype};
2892         my $qualifier='';
2893         if (defined $linktype) {
2894                 $qualifier=" with type $linktype";
2895         }
2896
2897         my $links = $IkiWiki::links{$page};
2898         return IkiWiki::FailReason->new("$page has no links", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2899                 unless $links && @{$links};
2900         my $bestlink = IkiWiki::bestlink($from, $link);
2901         foreach my $p (@{$links}) {
2902                 next unless (! defined $linktype || exists $IkiWiki::typedlinks{$page}{$linktype}{$p});
2903
2904                 if (length $bestlink) {
2905                         if ($bestlink eq IkiWiki::bestlink($page, $p)) {
2906                                 return IkiWiki::SuccessReason->new("$page links to $link$qualifier", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2907                         }
2908                 }
2909                 else {
2910                         if (match_glob($p, $link, %params)) {
2911                                 return IkiWiki::SuccessReason->new("$page links to page $p$qualifier, matching $link", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2912                         }
2913                         my ($p_rel)=$p=~/^\/?(.*)/;
2914                         $link=~s/^\///;
2915                         if (match_glob($p_rel, $link, %params)) {
2916                                 return IkiWiki::SuccessReason->new("$page links to page $p_rel$qualifier, matching $link", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2917                         }
2918                 }
2919         }
2920         return IkiWiki::FailReason->new("$page does not link to $link$qualifier", $page => $IkiWiki::DEPEND_LINKS, "" => 1);
2921 }
2922
2923 sub match_backlink ($$;@) {
2924         my $page=shift;
2925         my $testpage=shift;
2926         my %params=@_;
2927         if ($testpage eq '.') {
2928                 $testpage = $params{'location'}
2929         }
2930         my $ret=match_link($testpage, $page, @_);
2931         $ret->influences($testpage => $IkiWiki::DEPEND_LINKS);
2932         return $ret;
2933 }
2934
2935 sub match_created_before ($$;@) {
2936         my $page=shift;
2937         my $testpage=shift;
2938         my %params=@_;
2939
2940         $testpage=derel($testpage, $params{location});
2941
2942         if (exists $IkiWiki::pagectime{$testpage}) {
2943                 if ($IkiWiki::pagectime{$page} < $IkiWiki::pagectime{$testpage}) {
2944                         return IkiWiki::SuccessReason->new("$page created before $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2945                 }
2946                 else {
2947                         return IkiWiki::FailReason->new("$page not created before $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2948                 }
2949         }
2950         else {
2951                 return IkiWiki::ErrorReason->new("$testpage does not exist", $testpage => $IkiWiki::DEPEND_PRESENCE);
2952         }
2953 }
2954
2955 sub match_created_after ($$;@) {
2956         my $page=shift;
2957         my $testpage=shift;
2958         my %params=@_;
2959
2960         $testpage=derel($testpage, $params{location});
2961
2962         if (exists $IkiWiki::pagectime{$testpage}) {
2963                 if ($IkiWiki::pagectime{$page} > $IkiWiki::pagectime{$testpage}) {
2964                         return IkiWiki::SuccessReason->new("$page created after $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2965                 }
2966                 else {
2967                         return IkiWiki::FailReason->new("$page not created after $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2968                 }
2969         }
2970         else {
2971                 return IkiWiki::ErrorReason->new("$testpage does not exist", $testpage => $IkiWiki::DEPEND_PRESENCE);
2972         }
2973 }
2974
2975 sub match_creation_day ($$;@) {
2976         my $page=shift;
2977         my $d=shift;
2978         if ($d !~ /^\d+$/) {
2979                 return IkiWiki::ErrorReason->new("invalid day $d");
2980         }
2981         if ((localtime($IkiWiki::pagectime{$page}))[3] == $d) {
2982                 return IkiWiki::SuccessReason->new('creation_day matched');
2983         }
2984         else {
2985                 return IkiWiki::FailReason->new('creation_day did not match');
2986         }
2987 }
2988
2989 sub match_creation_month ($$;@) {
2990         my $page=shift;
2991         my $m=shift;
2992         if ($m !~ /^\d+$/) {
2993                 return IkiWiki::ErrorReason->new("invalid month $m");
2994         }
2995         if ((localtime($IkiWiki::pagectime{$page}))[4] + 1 == $m) {
2996                 return IkiWiki::SuccessReason->new('creation_month matched');
2997         }
2998         else {
2999                 return IkiWiki::FailReason->new('creation_month did not match');
3000         }
3001 }
3002
3003 sub match_creation_year ($$;@) {
3004         my $page=shift;
3005         my $y=shift;
3006         if ($y !~ /^\d+$/) {
3007                 return IkiWiki::ErrorReason->new("invalid year $y");
3008         }
3009         if ((localtime($IkiWiki::pagectime{$page}))[5] + 1900 == $y) {
3010                 return IkiWiki::SuccessReason->new('creation_year matched');
3011         }
3012         else {
3013                 return IkiWiki::FailReason->new('creation_year did not match');
3014         }
3015 }
3016
3017 sub match_user ($$;@) {
3018         shift;
3019         my $user=shift;
3020         my %params=@_;
3021
3022         if (! exists $params{user}) {
3023                 return IkiWiki::ErrorReason->new("no user specified");
3024         }
3025
3026         my $regexp=IkiWiki::glob2re($user);
3027
3028         if (defined $params{user} && $params{user}=~$regexp) {
3029                 return IkiWiki::SuccessReason->new("user is $user");
3030         }
3031         elsif (! defined $params{user}) {
3032                 return IkiWiki::FailReason->new("not logged in");
3033         }
3034         else {
3035                 return IkiWiki::FailReason->new("user is $params{user}, not $user");
3036         }
3037 }
3038
3039 sub match_admin ($$;@) {
3040         shift;
3041         shift;
3042         my %params=@_;
3043
3044         if (! exists $params{user}) {
3045                 return IkiWiki::ErrorReason->new("no user specified");
3046         }
3047
3048         if (defined $params{user} && IkiWiki::is_admin($params{user})) {
3049                 return IkiWiki::SuccessReason->new("user is an admin");
3050         }
3051         elsif (! defined $params{user}) {
3052                 return IkiWiki::FailReason->new("not logged in");
3053         }
3054         else {
3055                 return IkiWiki::FailReason->new("user is not an admin");
3056         }
3057 }
3058
3059 sub match_ip ($$;@) {
3060         shift;
3061         my $ip=shift;
3062         my %params=@_;
3063
3064         if (! exists $params{ip}) {
3065                 return IkiWiki::ErrorReason->new("no IP specified");
3066         }
3067
3068         my $regexp=IkiWiki::glob2re(lc $ip);
3069
3070         if (defined $params{ip} && lc $params{ip}=~$regexp) {
3071                 return IkiWiki::SuccessReason->new("IP is $ip");
3072         }
3073         else {
3074                 return IkiWiki::FailReason->new("IP is $params{ip}, not $ip");
3075         }
3076 }
3077
3078 package IkiWiki::SortSpec;
3079
3080 # This is in the SortSpec namespace so that the $a and $b that sort() uses
3081 # are easily available in this namespace, for cmp functions to use them.
3082 sub sort_pages {
3083         my $f=shift;
3084         sort $f @_
3085 }
3086
3087 sub cmp_title {
3088         IkiWiki::pagetitle(IkiWiki::basename($a))
3089         cmp
3090         IkiWiki::pagetitle(IkiWiki::basename($b))
3091 }
3092
3093 sub cmp_path { IkiWiki::pagetitle($a) cmp IkiWiki::pagetitle($b) }
3094 sub cmp_mtime { $IkiWiki::pagemtime{$b} <=> $IkiWiki::pagemtime{$a} }
3095 sub cmp_age { $IkiWiki::pagectime{$b} <=> $IkiWiki::pagectime{$a} }
3096
3097 1